gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(1.118)dnl
   8 AC_INIT(as.h)dnl
   9 dnl
  10 bfd_gas=no
  11 user_bfd_gas=
  12 AC_ARG_ENABLE(bfd-assembler,
  13 [    bfd-assembler      use BFD back end for writing object files],
  14 [case "${enableval}" in
  15   yes) need_bfd=yes user_bfd_gas=yes ;;
  16   no)  user_bfd_gas=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  18 esac])dnl
  19
  20 # Generate a header file -- gets more post-processing by Makefile later.
  21 AC_CONFIG_HEADER(conf)
  22
  23 dnl For recursion to work right, this must be an absolute pathname.
  24 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  25 AC_CANONICAL_SYSTEM
  26 AC_ARG_PROGRAM
  27
  28 emulation=generic
  29
  30 # assign cpu type
  31
  32 # check for architecture variants
  33 case ${target_cpu} in
  34   hppa*)        cpu_type=hppa ;;
  35 changequote(,)dnl
  36   i[45]86)      cpu_type=i386 ;;
  37   m680[012346]0) cpu_type=m68k ;;
  38   m68008)       cpu_type=m68k ;;
  39   m683??)       cpu_type=m68k ;;
  40 changequote([,])dnl
  41   m8*)          cpu_type=m88k ;;
  42   mips*el)      cpu_type=mips endian=little;;
  43   mips*)        cpu_type=mips endian=big ;;
  44   powerpc*eabi*) cpu_type=ppc obj_format=elf;;
  45   powerpc*)     cpu_type=ppc ;;
  46   rs6000*)      cpu_type=ppc ;;
  47   sparc64)      cpu_type=sparc obj_format=elf
  48                 AC_DEFINE(sparcv9) ;;
  49   sparclite*)   cpu_type=sparc ;;
  50   *)            cpu_type=${target_cpu} ;;
  51 esac
  52
  53 # do we need the opcodes library?
  54 case ${cpu_type} in
  55   alpha | vax)
  56     ;;
  57   *)
  58     OPCODES_LIB="../opcodes/libopcodes.a"
  59     ;;
  60 esac
  61 AC_SUBST(OPCODES_LIB)
  62
  63 gas_target=${cpu_type}
  64 generic_target=${cpu_type}-${target_vendor}-${target_os}
  65 dev=no
  66
  67 # assign object format
  68 case ${generic_target} in
  69   a29k-amd-udi)         obj_format=coff gas_target=ebmon29k ;;
  70   a29k-amd-ebmon)       obj_format=coff gas_target=ebmon29k ;;
  71
  72   alpha-*-netware*)     obj_format=ecoff ;;
  73   alpha-*-osf*)         obj_format=ecoff ;;
  74
  75 # start-sanitize-arc
  76   arc-*-elf*)           obj_format=elf bfd_gas=yes ;;
  77 # end-sanitize-arc
  78
  79   arm-*-riscix*)        obj_format=aout ;;
  80
  81   hppa-*-*elf*)         obj_format=elf emulation=hppa ;;
  82   hppa-*-osf*)          obj_format=som emulation=hppa ;;
  83   hppa-*-hpux*)         obj_format=som emulation=hppa ;;
  84   hppa-*-bsd*)          obj_format=som emulation=hppa ;;
  85   hppa-*-hiux*)         obj_format=som emulation=hppa ;;
  86
  87   h8300-*-coff)         obj_format=coff ;;
  88
  89   i386-ibm-aix*)        obj_format=coff gas_target=i386coff
  90                          emulation=i386aix ;;
  91   i386-*-bsd*)          obj_format=aout emulation=386bsd ;;
  92   i386-*-netbsd0.8)     obj_format=aout emulation=386bsd ;;
  93   i386-*-netbsd*)       obj_format=aout emulation=nbsd bfd_gas=yes;;
  94   i386-*-linux*elf*)    obj_format=elf  emulation=linux ;;
  95   i386-*-linux*coff*)   obj_format=coff emulation=linux
  96                          gas_target=i386coff ;;
  97   i386-*-linux*)        obj_format=aout emulation=linux ;;
  98   i386-*-lynxos*)       obj_format=coff gas_target=i386coff
  99                          emulation=lynx ;;
 100   i386-*-sysv4* | i386-*-solaris* | i386-*-elf)
 101                         obj_format=elf ;;
 102   i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 103                         obj_format=coff gas_target=i386coff ;;
 104   i386-*-vsta)          obj_format=aout ;;
 105   i386-*-go32)          obj_format=coff gas_target=i386coff ;;
 106   i386-*-gnu*elf*)      obj_format=elf ;;
 107   i386-*-mach* | i386-*-gnu*)
 108                         obj_format=aout emulation=mach bfd_gas=yes ;;
 109   i386-*-msdos*)        obj_format=aout ;;
 110
 111   i960-*-bout)          obj_format=bout ;;
 112   i960-*-coff)          obj_format=coff emulation=ic960 gas_target=ic960coff ;;
 113   i960-*-nindy*)        obj_format=bout ;;
 114   i960-*-vxworks4*)     obj_format=bout ;;
 115   i960-*-vxworks5.0)    obj_format=bout ;;
 116   i960-*-vxworks5.*)    obj_format=coff emulation=ic960 gas_target=ic960coff ;;
 117   i960-*-vxworks*)      obj_format=bout ;;
 118
 119   m68k-wrs-vxworks | m68k-ericsson-ose | m68k-*-sunos*)
 120                         obj_format=aout emulation=sun3 ;;
 121   m68k-motorola-sysv)   obj_format=coff gas_target=m68kcoff emulation=delta ;;
 122   m68k-bull-sysv3*)     obj_format=coff gas_target=m68kcoff emulation=dpx2 ;;
 123   m68k-apollo-*)        obj_format=coff gas_target=apollo emulation=apollo ;;
 124   m68k-*-coff | m68k-*-sysv*)
 125                         obj_format=coff gas_target=m68kcoff ;;
 126   m68k-*-hpux*)         obj_format=hp300 emulation=hp300 ;;
 127   m68k-*-lynxos*)       obj_format=coff gas_target=m68kcoff
 128                          emulation=lynx ;;
 129   m68k-*-netbsd*)       obj_format=aout emulation=nbsd bfd_gas=yes ;;
 130
 131   m88k-*-coff*)         obj_format=coff gas_target=m88kcoff ;;
 132
 133   # don't change emulation like *-*-bsd does
 134   mips-dec-bsd*)        obj_format=aout gas_target=mips-lit ;;
 135   mips-sony-bsd*)       obj_format=ecoff gas_target=mips-big ;;
 136   mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 137   mips-*-ultrix*)       obj_format=ecoff gas_target=mips-lit ;;
 138   mips-*-ecoff*)        obj_format=ecoff
 139                         case "$endian" in
 140                         big) gas_target=mips-big ;;
 141                         *)   gas_target=mips-lit ;;
 142                         esac
 143                         ;;
 144   mips-*-ecoff*)        obj_format=ecoff gas_target=mips-big ;;
 145   mips-*-gnu*)          obj_format=aout
 146                         case "$endian" in
 147                         big) gas_target=mips-big ;;
 148                         *)   gas_target=mips-lit ;;
 149                         esac
 150                         ;;
 151   mips-*-irix5*)        obj_format=elf gas_target=mips-big ;;
 152   mips-*-irix*)         obj_format=ecoff gas_target=mips-big ;;
 153   mips-*-riscos*)       obj_format=ecoff gas_target=mips-big ;;
 154   mips-*-sysv*)         obj_format=ecoff gas_target=mips-big ;;
 155   mips-*-elf*)          obj_format=elf
 156                         case "$endian" in
 157                         big) gas_target=mips-big ;;
 158                         *)   gas_target=mips-lit ;;
 159                         esac
 160                         ;;
 161   ppc-*-aix*)           obj_format=coff ;;
 162   ppc-*-elf*)           obj_format=elf ;;
 163   ppc-*-netware*)       obj_format=elf emulation=ppcnw ;;
 164   ppc-*-sysv4*)         obj_format=elf ;;
 165
 166   sh-*-coff)            obj_format=coff ;;
 167
 168 # start-sanitize-rce
 169   rce-*-aout)           obj_format=aout ;;
 170 # end-sanitize-rce
 171
 172   ns32k-pc532-mach*)    obj_format=aout emulation=pc532mach ;;
 173   ns32k-pc532-netbsd*)  obj_format=aout emulation=nbsd532 ;;
 174
 175   sparc-*-sunos4*)      obj_format=aout emulation=sun3 ;;
 176   sparc-*-aout | sparc*-*-vxworks)
 177                         obj_format=aout ;;
 178   sparc-*-coff)         obj_format=coff ;;
 179   sparc-*-lynxos*)      obj_format=coff emulation=lynx ;;
 180   sparc-fujitsu-none)   obj_format=aout ;;
 181   sparc-*-elf | sparc*-*-solaris*)
 182                         obj_format=elf ;;
 183   sparc-*-netbsd*)      obj_format=aout emulation=nbsd bfd_gas=yes ;;
 184
 185   vax-*-bsd* | vax-*-ultrix*)
 186                         obj_format=aout ;;
 187   vax-*-vms)            obj_format=vms ;;
 188
 189   z8k-*-coff | z8k-*-sim)
 190                         obj_format=coff ;;
 191
 192   w65-*-*)              obj_format=coff ;;
 193
 194   *-*-aout | *-*-scout)
 195                         obj_format=aout ;;
 196   *-*-nindy*)
 197                         obj_format=bout ;;
 198   *-*-bsd*)
 199                         obj_format=aout emulation=sun3 ;;
 200   *-*-generic)          obj_format=generic ;;
 201   *-*-xray | *-*-hms)   obj_format=coff ;;
 202   *-*-sim)              obj_format=coff ;;
 203   *-*-elf | *-*-sysv4* | *-*-solaris*)
 204                         AC_MSG_WARN(GAS support for ELF format is incomplete)
 205                         obj_format=elf dev=yes ;;
 206   *-*-vxworks)          obj_format=aout ;;
 207   *-*-netware)          obj_format=elf ;;
 208 esac
 209
 210 # Assign floating point type.  Most processors with FP support
 211 # IEEE FP.  On those that don't support FP at all, usually IEEE
 212 # is emulated.
 213 case ${target_cpu} in
 214   vax | tahoe ) atof=${target_cpu} ;;
 215   *)                    atof=ieee ;;
 216 esac
 217
 218 case "${obj_format}" in
 219   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 220 esac
 221
 222 dnl
 223 dnl Make sure the desired support files exist.
 224 dnl
 225
 226 if test ! -r ${srcdir}/config/tc-${cpu_type}.c; then
 227   AC_MSG_ERROR(GAS does not support target CPU ${cpu_type})
 228 fi
 229
 230 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 231   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 232 fi
 233
 234 # and target makefile frag
 235
 236 target_frag=${srcdir}/config/${gas_target}.mt
 237 if test ! -r ${target_frag}; then
 238   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 239 fi
 240 AC_SUBST_FILE(target_frag)
 241
 242 case ${cpu_type}-${obj_format} in
 243   arm-*)        bfd_gas=yes ;;
 244 # not yet
 245 # i386-aout)    bfd_gas=preferred ;;
 246   mips-*)       bfd_gas=yes ;;
 247   ns32k-*)      bfd_gas=yes ;;
 248   ppc-*)        bfd_gas=yes ;;
 249   sparc-*)      bfd_gas=yes ;;
 250   *-elf)        bfd_gas=yes ;;
 251   *-ecoff)      bfd_gas=yes ;;
 252   *-som)        bfd_gas=yes ;;
 253   *)            ;;
 254 esac
 255
 256 case ${user_bfd_gas}-${bfd_gas} in
 257   yes-yes | no-no)
 258     # We didn't override user's choice.
 259     ;;
 260   no-yes)
 261     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 262     ;;
 263   no-preferred)
 264     bfd_gas=no
 265     ;;
 266   *-preferred)
 267     bfd_gas=yes
 268     ;;
 269   yes-*)
 270     bfd_gas=yes
 271     ;;
 272   -*)
 273     # User specified nothing.
 274     ;;
 275 esac
 276
 277 case ${bfd_gas}-${cpu_type}-${obj_format} in
 278   yes-*-coff)   need_bfd=yes ;;
 279   no-*-coff)    need_bfd=yes
 280                 AC_DEFINE(MANY_SEGMENTS) ;;
 281 esac
 282
 283 reject_dev_configs=yes
 284
 285 case ${reject_dev_configs}-${dev} in
 286   yes-yes) # Oops.
 287     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 288     ;;
 289 esac
 290
 291 AC_LINK_FILES(config/tc-${cpu_type}.c   config/tc-${cpu_type}.h \
 292         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 293         config/te-${emulation}.h config/atof-${atof}.c,
 294         targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c)
 295
 296 case "${bfd_gas}" in
 297   yes)  AC_DEFINE(BFD_ASSEMBLER)
 298         need_bfd=yes ;;
 299 esac
 300
 301 case "${need_bfd}" in
 302   yes)  BFDLIB=../bfd/libbfd.a
 303         ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 304         ;;
 305 esac
 306 AC_SUBST(BFDLIB)
 307 AC_SUBST(ALL_OBJ_DEPS)
 308
 309 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 310 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 311 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 312 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 313 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 314
 315 AC_PROG_CC
 316 AC_PROG_INSTALL
 317
 318 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 319
 320 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 321 # people who are not cross-compiling but are compiling cross-assemblers.
 322 AC_MSG_CHECKING(whether compiling a cross-assembler)
 323 if test "${host}" = "${target}"; then
 324   cross_gas=no
 325 else
 326   cross_gas=yes
 327   AC_DEFINE(CROSS_COMPILE)
 328 fi
 329 AC_MSG_RESULT($cross_gas)
 330
 331 dnl ansidecl.h will deal with const
 332 dnl AC_CONST
 333 AC_FUNC_ALLOCA
 334 AC_C_INLINE
 335
 336 # VMS doesn't have unlink.
 337 AC_CHECK_FUNCS(unlink remove, break)
 338
 339 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 340 # enough, but on some of those systems, the assert macro relies on requoting
 341 # working properly!
 342 GAS_WORKING_ASSERT
 343
 344 # On some systems, the system header files may not declare malloc, realloc,
 345 # and free.  There are places where gas needs these functions to have been
 346 # declared -- such as when taking their addresses.
 347 gas_test_headers="
 348 #ifdef HAVE_MEMORY_H
 349 #include <memory.h>
 350 #endif
 351 #ifdef HAVE_STRING_H
 352 #include <string.h>
 353 #endif
 354 #ifdef HAVE_STDLIB_H
 355 #include <stdlib.h>
 356 #endif
 357 #ifdef HAVE_UNISTD_H
 358 #include <unistd.h>
 359 #endif
 360 "
 361 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 362 GAS_CHECK_DECL_NEEDED(free, f, int f, $gas_test_headers)
 363
 364 # Does errno.h declare errno, or do we have to add a separate declaration
 365 # for it?
 366 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 367 #ifdef HAVE_ERRNO_H
 368 #include <errno.h>
 369 #endif
 370 ])
 371
 372 AC_CONFIG_SUBDIRS(testsuite)
 373
 374 dnl This must come last.
 375 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)