gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       arm*b|xscale*b|strongarm*b) cpu_type=arm endian=big ;;
 119       arm*|xscale*|strongarm*)    cpu_type=arm endian=little ;;
 120       hppa*)            cpu_type=hppa ;;
 121 changequote(,)dnl
 122       i[3456]86)        cpu_type=i386 arch=i386;;
 123       x86_64)           cpu_type=i386 arch=x86_64;;
 124       ia64)             cpu_type=ia64 ;;
 125       ip2k)             cpu_type=ip2k endian=big ;;
 126       iq2000)           cpu_type=iq2000 endian=big ;;
 127       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 128       m680[012346]0)    cpu_type=m68k ;;
 129 changequote([,])dnl
 130       m68008)           cpu_type=m68k ;;
 131       m683??)           cpu_type=m68k ;;
 132       m5200)            cpu_type=m68k ;;
 133       m8*)              cpu_type=m88k ;;
 134       mips*el)          cpu_type=mips endian=little ;;
 135       mips*)            cpu_type=mips endian=big ;;
 136       or32*)            cpu_type=or32 endian=big ;;
 137       pjl*)             cpu_type=pj endian=little ;;
 138       pj*)              cpu_type=pj endian=big ;;
 139       powerpc*le*)      cpu_type=ppc endian=little ;;
 140       powerpc*)         cpu_type=ppc endian=big ;;
 141       rs6000*)          cpu_type=ppc ;;
 142       s390x*)           cpu_type=s390 arch=s390x ;;
 143       s390*)            cpu_type=s390 arch=s390 ;;
 144       sh5*)             cpu_type=sh64 endian=big ;;
 145       sh5le*)           cpu_type=sh64 endian=little ;;
 146       sh64*)            cpu_type=sh64 endian=big ;;
 147       sh64le*)          cpu_type=sh64 endian=little ;;
 148       sh*le)            cpu_type=sh endian=little ;;
 149       sh*)              cpu_type=sh endian=big ;;
 150       sparclite*)       cpu_type=sparc arch=sparclite ;;
 151       sparclet*)        cpu_type=sparc arch=sparclet ;;
 152       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 153       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 154       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 155       v850*)            cpu_type=v850 ;;
 156       *)                cpu_type=${cpu} ;;
 157     esac
 158
 159     if test ${this_target} = $target ; then
 160       target_cpu_type=${cpu_type}
 161     elif test ${target_cpu_type} != ${cpu_type} ; then
 162       continue
 163     fi
 164
 165     generic_target=${cpu_type}-$vendor-$os
 166     dev=no
 167     bfd_gas=no
 168     em=generic
 169
 170     # assign object format
 171     case ${generic_target} in
 172       a29k-*-coff)                      fmt=coff ;;
 173       a29k-amd-udi)                     fmt=coff ;;
 174       a29k-amd-ebmon)                   fmt=coff ;;
 175       a29k-nyu-sym1)                    fmt=coff ;;
 176       a29k-*-rtems*)                    fmt=coff ;;
 177       a29k-*-vxworks*)                  fmt=coff ;;
 178
 179       alpha*-*-*vms*)                   fmt=evax ;;
 180       alpha*-*-netware*)                fmt=ecoff ;;
 181       alpha*-*-osf*)                    fmt=ecoff ;;
 182       alpha*-*-linuxecoff*)             fmt=ecoff ;;
 183       alpha*-*-linux-gnu*)              fmt=elf em=linux ;;
 184       alpha*-*-netbsd*)                 fmt=elf em=nbsd ;;
 185       alpha*-*-openbsd*)                fmt=elf em=obsd ;;
 186
 187       arc-*-elf*)                       fmt=elf ;;
 188
 189       arm-*-aout)                       fmt=aout ;;
 190       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 191       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 192       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 193       arm*-*-conix*)                    fmt=elf ;;
 194       arm-*-linux*aout*)                fmt=aout em=linux ;;
 195       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 196       arm*-*-uclinux*)                  fmt=elf  em=linux ;;
 197       arm-*-netbsdelf*)                 fmt=elf  em=nbsd ;;
 198       arm-*-*n*bsd*)                    fmt=aout em=nbsd ;;
 199       arm-**-nto*)                      fmt=elf ;;
 200       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 201       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 202       arm-*-wince)                      fmt=coff em=wince-pe ;;
 203       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 204       arm-*-riscix*)                    fmt=aout em=riscix ;;
 205       arm-*-vxworks)                    fmt=coff ;;
 206
 207       avr-*-*)                          fmt=elf ;;
 208
 209       cris-*-*)                         fmt=multi bfd_gas=yes ;;
 210
 211       d10v-*-*)                         fmt=elf ;;
 212       d30v-*-*)                         fmt=elf ;;
 213       dlx-*-*)                          fmt=elf ;;
 214
 215       fr30-*-*)                         fmt=elf ;;
 216       frv-*-*)                          fmt=elf ;;
 217
 218       hppa-*-linux*)    case ${cpu} in
 219                             hppa*64*)   fmt=elf em=hppalinux64;;
 220                             hppa*)      fmt=elf em=linux;;
 221                         esac ;;
 222       hppa-*-*elf*)                     fmt=elf em=hppa ;;
 223       hppa-*-lites*)                    fmt=elf em=hppa ;;
 224       hppa-*-netbsd*)                   fmt=elf em=nbsd ;;
 225       hppa-*-openbsd*)                  fmt=elf em=hppa ;;
 226       hppa-*-osf*)                      fmt=som em=hppa ;;
 227       hppa-*-rtems*)                    fmt=elf em=hppa ;;
 228       hppa-*-hpux11*)   case ${cpu} in
 229                             hppa*64*)   fmt=elf em=hppa64 ;;
 230                             hppa*)      fmt=som em=hppa ;;
 231                         esac ;;
 232       hppa-*-hpux*)                     fmt=som em=hppa ;;
 233       hppa-*-mpeix*)                    fmt=som em=hppa ;;
 234       hppa-*-bsd*)                      fmt=som em=hppa ;;
 235       hppa-*-hiux*)                     fmt=som em=hppa ;;
 236
 237       h8300-*-rtems*)                   fmt=coff ;;
 238       h8300-*-coff)                     fmt=coff ;;
 239       h8300-*-elf)                      fmt=elf ;;
 240       h8500-*-rtems*)                   fmt=coff ;;
 241       h8500-*-coff)                     fmt=coff ;;
 242
 243       i370-*-elf* | i370-*-linux*)      fmt=elf ;;
 244       i386-ibm-aix*)                    fmt=coff em=i386aix ;;
 245       i386-sequent-bsd*)                fmt=aout em=dynix ;;
 246       i386-*-beospe*)                   fmt=coff em=pe ;;
 247       i386-*-beos*)                     fmt=elf ;;
 248       i386-*-coff)                      fmt=coff ;;
 249       i386-*-elf)                       fmt=elf ;;
 250       i386-*-bsd*)                      fmt=aout em=386bsd ;;
 251       i386-*-netbsd0.8)                 fmt=aout em=386bsd ;;
 252       i386-*-netbsdpe*)                 fmt=coff em=pe ;;
 253       i386-*-netbsdelf*)                fmt=elf em=nbsd ;;
 254       i386-*-*n*bsd*)   case ${cpu} in
 255                             x86_64)     fmt=elf em=nbsd ;;
 256                             *)          fmt=aout em=nbsd ;;
 257                         esac ;;
 258       i386-*-linux*aout*)               fmt=aout em=linux ;;
 259       i386-*-linux*oldld)               fmt=aout em=linux ;;
 260       i386-*-linux*coff*)               fmt=coff em=linux ;;
 261       i386-*-linux-gnu*)                fmt=elf em=linux ;;
 262       x86_64-*-linux-gnu*)              fmt=elf em=linux ;;
 263       i386-*-lynxos*)                   fmt=coff em=lynx ;;
 264 changequote(,)dnl
 265       i386-*-sysv[45]*)                 fmt=elf ;;
 266       i386-*-solaris*)                  fmt=elf ;;
 267       i386-*-freebsdaout*)              fmt=aout em=386bsd ;;
 268       i386-*-freebsd[12].*)             fmt=aout em=386bsd ;;
 269       i386-*-freebsd[12])               fmt=aout em=386bsd ;;
 270 changequote([,])dnl
 271       i386-*-sysv*)                     fmt=coff ;;
 272       i386-*-sco3.2v5*coff)             fmt=coff ;;
 273       i386-*-isc*)                      fmt=coff ;;
 274       i386-*-sco3.2v5*)                 fmt=elf
 275           if test ${this_target} = $target; then
 276             AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 277           fi ;;
 278       i386-*-sco3.2*)                   fmt=coff ;;
 279       i386-*-vsta)                      fmt=aout ;;
 280       i386-*-msdosdjgpp* \
 281       | i386-*-go32* \
 282       | i386-go32-rtems*)               fmt=coff em=go32
 283             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?]) ;;
 284       i386-*-rtemself*)                 fmt=elf ;;
 285       i386-*-rtemscoff*)                fmt=coff ;;
 286       i386-*-rtems*)                    fmt=elf ;;
 287       i386-*-gnu*)                      fmt=elf ;;
 288       i386-*-mach*)                     fmt=aout em=mach ;;
 289       i386-*-msdos*)                    fmt=aout ;;
 290       i386-*-moss*)                     fmt=elf ;;
 291       i386-*-pe)                        fmt=coff em=pe ;;
 292       i386-*-cygwin*)                   fmt=coff em=pe ;;
 293       i386-*-interix*)                  fmt=coff em=interix ;;
 294       i386-*-mingw32*)                  fmt=coff em=pe ;;
 295       i386-*-nto-qnx*)                  fmt=elf ;;
 296       i386-*-*nt*)                      fmt=coff em=pe ;;
 297       i386-*-vxworks*)                  fmt=aout ;;
 298       i386-*-chaos)                     fmt=elf ;;
 299
 300       i860-*-*)                         fmt=elf endian=little
 301                 AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 302       i960-*-bout)                      fmt=bout ;;
 303       i960-*-coff)                      fmt=coff em=ic960 ;;
 304       i960-*-rtems*)                    fmt=coff em=ic960 ;;
 305       i960-*-nindy*)                    fmt=bout ;;
 306       i960-*-vxworks5.0)                fmt=bout ;;
 307       i960-*-vxworks5.*)                fmt=coff em=ic960 ;;
 308       i960-*-vxworks*)                  fmt=bout ;;
 309       i960-*-elf*)                      fmt=elf ;;
 310
 311       ia64-*-elf*)                      fmt=elf ;;
 312       ia64-*-aix*)                      fmt=elf em=ia64aix ;;
 313       ia64-*-linux-gnu*)                fmt=elf em=linux ;;
 314       ia64-*-hpux*)                     fmt=elf em=hpux ;;
 315       ia64-*-netbsd*)                   fmt=elf em=nbsd ;;
 316
 317       ip2k-*-*)                         fmt=elf ;;
 318
 319       iq2000-*-elf)                     fmt=elf bfd_gas=yes ;;
 320
 321       m32r-*-*)                         fmt=elf ;;
 322
 323       m68hc11-*-* | m6811-*-*)          fmt=elf ;;
 324       m68hc12-*-* | m6812-*-*)          fmt=elf ;;
 325
 326       m68k-*-vxworks*)                  fmt=aout em=sun3 ;;
 327       m68k-ericsson-ose)                fmt=aout em=sun3 ;;
 328       m68k-*-sunos*)                    fmt=aout em=sun3 ;;
 329       m68k-motorola-sysv*)              fmt=coff em=delta ;;
 330       m68k-bull-sysv3*)                 fmt=coff em=dpx2 ;;
 331       m68k-apollo-*)                    fmt=coff em=apollo ;;
 332       m68k-*-elf*)                      fmt=elf ;;
 333       m68k-*-sysv4*)                    fmt=elf em=svr4 ;;
 334       m68k-*-sysv*)                     fmt=coff ;;
 335       m68k-*-coff | m68k-*-rtemscoff*)  fmt=coff ;;
 336       m68k-*-rtems*)                    fmt=elf ;;
 337       m68k-*-hpux*)                     fmt=hp300 em=hp300 ;;
 338       m68k-*-linux*aout*)               fmt=aout em=linux ;;
 339       m68k-*-linux-gnu*)                fmt=elf em=linux ;;
 340       m68k-*-gnu*)                      fmt=elf ;;
 341       m68k-*-lynxos*)                   fmt=coff em=lynx ;;
 342       m68k-*-netbsdelf*)                fmt=elf em=nbsd ;;
 343       m68k-*-netbsd*)                   fmt=aout em=nbsd bfd_gas=yes ;;
 344       m68k-*-openbsd*)                  fmt=aout em=nbsd bfd_gas=yes ;;
 345       m68k-apple-aux*)                  fmt=coff em=aux ;;
 346       m68k-*-psos*)                     fmt=elf em=psos;;
 347
 348       m88k-motorola-sysv3*)             fmt=coff em=delt88 ;;
 349       m88k-*-coff*)                     fmt=coff ;;
 350
 351       mcore-*-elf)                      fmt=elf ;;
 352       mcore-*-pe)                       fmt=coff em=pe bfd_gas=yes ;;
 353
 354       # don't change em like *-*-bsd does
 355       mips-dec-openbsd*)                fmt=elf endian=little ;;
 356       mips-dec-bsd*)                    fmt=aout endian=little ;;
 357       mips-sony-bsd*)                   fmt=ecoff ;;
 358       mips-*-bsd*)
 359             AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 360       mips-*-ultrix*)                   fmt=ecoff endian=little ;;
 361       mips-*-osf*)                      fmt=ecoff endian=little ;;
 362       mips-*-ecoff*)                    fmt=ecoff ;;
 363       mips-*-pe*)                       fmt=coff endian=little em=pe ;;
 364       mips-*-irix6*)                    fmt=elf em=irix ;;
 365       mips-*-irix5*)                    fmt=elf em=irix ;;
 366       mips-*-irix*)                     fmt=ecoff em=irix ;;
 367       mips-*-lnews*)                    fmt=ecoff em=lnews ;;
 368       mips-*-riscos*)                   fmt=ecoff ;;
 369       mips*-*-linux*)                   fmt=elf em=tmips ;;
 370       mips-*-sysv4*MP* | mips-*-gnu*)   fmt=elf em=tmips ;;
 371       mips-*-sysv*)                     fmt=ecoff ;;
 372       mips-*-elf* | mips-*-rtems*)      fmt=elf ;;
 373       mips-*-*n*bsd*)                   fmt=elf ;;
 374       mips-*-vxworks*)                  fmt=elf ;;
 375
 376       mmix-*-*)                         fmt=elf ;;
 377       mn10200-*-*)                      fmt=elf ;;
 378       mn10300-*-*)                      fmt=elf ;;
 379       msp430-*-*)                       fmt=elf ;;
 380       openrisc-*-*)                     fmt=elf ;;
 381       or32-*-rtems*)                    fmt=coff ;;
 382       or32-*-coff)                      fmt=coff ;;
 383       or32-*-elf)                       fmt=elf ;;
 384       pj*)                              fmt=elf ;;
 385
 386       ppc-*-pe | ppc-*-cygwin*)         fmt=coff em=pe ;;
 387       ppc-*-winnt*)                     fmt=coff em=pe ;;
 388       ppc-*-aix5*)                      fmt=coff em=aix5 ;;
 389       ppc-*-aix*)                       fmt=coff ;;
 390       ppc-*-beos*)                      fmt=coff ;;
 391       ppc-*-*n*bsd* | ppc-*-elf*)       fmt=elf ;;
 392       ppc-*-eabi* | ppc-*-sysv4*)       fmt=elf ;;
 393       ppc-*-linux-gnu*)                 fmt=elf
 394             case "$endian" in
 395                 big)  ;;
 396                 *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 397             esac ;;
 398       ppc-*-solaris*)                   fmt=elf
 399             if test ${this_target} = $target; then
 400                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 401                           [Define if default target is PowerPC Solaris.])
 402             fi
 403             if test x${endian} = xbig; then
 404                 AC_MSG_ERROR(Solaris must be configured little endian)
 405             fi ;;
 406       ppc-*-rtems*)                     fmt=elf ;;
 407       ppc-*-macos* | ppc-*-mpw*)        fmt=coff em=macos ;;
 408       ppc-*-netware*)                   fmt=elf em=ppcnw ;;
 409       ppc-**-nto*)                      fmt=elf ;;
 410       ppc-*-vxworks*)                   fmt=elf ;;
 411       ppc-*-windiss*)                   fmt=elf ;;
 412
 413       s390x-*-linux-gnu*)               fmt=elf em=linux ;;
 414       s390-*-linux-gnu*)                fmt=elf em=linux ;;
 415
 416       sh*-*-linux*)                     fmt=elf em=linux
 417             case ${cpu} in
 418                 sh*eb)  endian=big ;;
 419                 *)      endian=little ;;
 420             esac ;;
 421       sh5*-*-netbsd*)                   fmt=elf em=nbsd ;;
 422       sh64*-*-netbsd*)                  fmt=elf em=nbsd ;;
 423       sh*-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 424       sh-*-elf*)                        fmt=elf ;;
 425       sh-*-coff*)                       fmt=coff ;;
 426       sh-*-nto*)                        fmt=elf ;;
 427       sh-*-pe*)                         fmt=coff em=pe bfd_gas=yes endian=little ;;
 428       sh-*-rtemself*)                   fmt=elf ;;
 429       sh-*-rtems*)                      fmt=coff ;;
 430       sh64-*-elf*)                      fmt=elf ;;
 431
 432       ns32k-pc532-mach*)                fmt=aout em=pc532mach ;;
 433       ns32k-pc532-ux*)                  fmt=aout em=pc532mach ;;
 434       ns32k-pc532-lites*)               fmt=aout em=nbsd532 ;;
 435       ns32k-*-*n*bsd*)                  fmt=aout em=nbsd532 ;;
 436
 437       sparc-*-rtemsaout*)               fmt=aout ;;
 438       sparc-*-rtemself*)                fmt=elf ;;
 439       sparc-*-rtems*)                   fmt=elf ;;
 440       sparc-*-sunos4*)                  fmt=aout em=sun3 ;;
 441       sparc-*-aout | sparc*-*-vxworks*) fmt=aout em=sparcaout ;;
 442       sparc-*-coff)                     fmt=coff ;;
 443       sparc-*-linux*aout*)              fmt=aout em=linux ;;
 444       sparc-*-linux-gnu*)               fmt=elf em=linux ;;
 445       sparc-*-lynxos*)                  fmt=coff em=lynx ;;
 446       sparc-fujitsu-none)               fmt=aout ;;
 447       sparc-*-elf)                      fmt=elf ;;
 448       sparc-*-sysv4*)                   fmt=elf ;;
 449       sparc-*-solaris*)                 fmt=elf ;;
 450       sparc-*-netbsdelf*)               fmt=elf em=nbsd ;;
 451       sparc-*-*n*bsd*)  case ${cpu} in
 452                             sparc64)    fmt=elf em=nbsd ;;
 453                             *)          fmt=aout em=nbsd ;;
 454                         esac ;;
 455       strongarm-*-coff)                 fmt=coff ;;
 456       strongarm-*-elf)                  fmt=elf ;;
 457       xscale-*-coff)                    fmt=coff ;;
 458       xscale-*-elf)                     fmt=elf ;;
 459
 460       tic30-*-*aout*)                   fmt=aout bfd_gas=yes ;;
 461       tic30-*-*coff*)                   fmt=coff bfd_gas=yes ;;
 462       tic4x-*-* | c4x-*-*)              fmt=coff bfd_gas=yes ;;
 463       tic54x-*-* | c54x*-*-*)           fmt=coff bfd_gas=yes need_libm=yes;;
 464       tic80-*-*)                        fmt=coff ;;
 465
 466       v850-*-*)                         fmt=elf ;;
 467       v850e-*-*)                        fmt=elf ;;
 468       v850ea-*-*)                       fmt=elf ;;
 469
 470       vax-*-netbsdelf*)                 fmt=elf em=nbsd ;;
 471       vax-*-netbsd*)                    fmt=aout em=nbsd ;;
 472       vax-*-bsd* | vax-*-ultrix*)       fmt=aout ;;
 473       vax-*-vms)                        fmt=vms ;;
 474
 475       w65-*-*)                          fmt=coff ;;
 476
 477       xstormy16-*-*)                    fmt=elf ;;
 478
 479       z8k-*-coff | z8k-*-sim)           fmt=coff ;;
 480
 481       *-*-aout | *-*-scout)             fmt=aout ;;
 482       *-*-freebsd*)                     fmt=elf em=freebsd ;;
 483       *-*-nindy*)                       fmt=bout ;;
 484       *-*-bsd*)                         fmt=aout em=sun3 ;;
 485       *-*-generic)                      fmt=generic ;;
 486       *-*-xray | *-*-hms)               fmt=coff ;;
 487       *-*-sim)                          fmt=coff ;;
 488       *-*-elf | *-*-sysv4* | *-*-solaris*) fmt=elf dev=yes ;;
 489       *-*-aros*)                                fmt=elf em=linux bfd_gas=yes ;;
 490       *-*-vxworks)                      fmt=aout ;;
 491       *-*-netware)                      fmt=elf ;;
 492     esac
 493
 494     if test ${this_target} = $target ; then
 495       endian_def=
 496       if test x${endian} = xbig; then
 497         endian_def=1
 498       elif test x${endian} = xlittle; then
 499         endian_def=0
 500       fi
 501       if test x${endian_def} != x; then
 502         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 503                            [Define as 1 if big endian.])
 504       fi
 505     fi
 506
 507     case ${cpu_type}-${fmt} in
 508         alpha*-* | arm-* | i386-* | ia64*-* | mips-* | ns32k-* \
 509                 | pdp11-* | ppc-* | sparc-* | strongarm-* | xscale-* \
 510                 | *-elf | *-ecoff | *-som)
 511             bfd_gas=yes ;;
 512     esac
 513
 514 # Other random stuff.
 515
 516     case ${cpu_type} in
 517       mips)
 518         # Set mips_cpu to the name of the default CPU.
 519         case ${target_cpu} in
 520           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 521             mips_cpu=from-abi
 522             ;;
 523           mipsisa32 | mipsisa32el)
 524             mips_cpu=mips32
 525             ;;
 526           mipsisa32r2 | mipsisa32r2el)
 527             mips_cpu=mips32r2
 528             ;;
 529           mipsisa64 | mipsisa64el)
 530             mips_cpu=mips64
 531             ;;
 532           mipstx39 | mipstx39el)
 533             mips_cpu=r3900
 534             ;;
 535           mips64vr | mips64vrel)
 536             mips_cpu=vr4100
 537             ;;
 538           mipsisa32r2*)
 539 changequote(,)dnl
 540             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 541 changequote([,])dnl
 542             ;;
 543           mips64* | mipsisa64* | mipsisa32*)
 544 changequote(,)dnl
 545             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 546 changequote([,])dnl
 547             ;;
 548           *)
 549             AC_ERROR($target_cpu isn't a supported MIPS CPU name)
 550             ;;
 551         esac
 552         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 553         # binaries.  It's a GNU extension that some OSes don't understand.
 554         # The value only matters on ELF targets.
 555         case ${target} in
 556           *-*-irix*)
 557             use_e_mips_abi_o32=0
 558             ;;
 559           *)
 560             use_e_mips_abi_o32=1
 561             ;;
 562         esac
 563         # Decide whether to generate 32-bit or 64-bit code by default.
 564         # Used to resolve -march=from-abi when an embedded ABI is selected.
 565         case ${target} in
 566           mips64*-*-* | mipsisa64*-*-*)
 567             mips_default_64bit=1
 568             ;;
 569           *)
 570             mips_default_64bit=0
 571             ;;
 572         esac
 573         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 574                            [Default CPU for MIPS targets. ])
 575         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 576                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 577         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 578                            [Generate 64-bit code by default on MIPS targets. ])
 579         ;;
 580     esac
 581
 582     # Do we need the opcodes library?
 583     case ${cpu_type} in
 584       vax | i386 | tic30)
 585         ;;
 586
 587       *)
 588         need_opcodes=yes
 589
 590         case "${enable_shared}" in
 591         yes) shared_opcodes=true ;;
 592         *opcodes*) shared_opcodes=true ;;
 593         *) shared_opcodes=false ;;
 594         esac
 595         if test "${shared_opcodes}" = "true"; then
 596           # A shared libopcodes must be linked against libbfd.
 597           need_bfd=yes
 598         fi
 599         ;;
 600     esac
 601
 602     # Any other special object files needed ?
 603     case ${cpu_type} in
 604       fr30 | ip2k | iq2000 | m32r | openrisc)
 605         using_cgen=yes
 606         ;;
 607
 608       frv)
 609         using_cgen=yes
 610         ;;
 611       m68k)
 612         case ${extra_objects} in
 613         *m68k-parse.o*) ;;
 614         *) extra_objects="$extra_objects m68k-parse.o" ;;
 615         esac
 616         ;;
 617
 618       mips)
 619         echo ${extra_objects} | grep -s "itbl-parse.o"
 620         if test $? -ne 0 ; then
 621           extra_objects="$extra_objects itbl-parse.o"
 622         fi
 623
 624         echo ${extra_objects} | grep -s "itbl-lex.o"
 625         if test $? -ne 0 ; then
 626           extra_objects="$extra_objects itbl-lex.o"
 627         fi
 628
 629         echo ${extra_objects} | grep -s "itbl-ops.o"
 630         if test $? -ne 0 ; then
 631           extra_objects="$extra_objects itbl-ops.o"
 632         fi
 633         ;;
 634
 635       i386 | s390 | sparc)
 636         if test $this_target = $target ; then
 637           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 638         fi
 639         ;;
 640
 641       xstormy16)
 642         using_cgen=yes
 643         ;;
 644
 645       *)
 646         ;;
 647     esac
 648
 649     if test $using_cgen = yes ; then
 650         case "x${extra_objects}" in
 651         *cgen.o*) ;;
 652         *) extra_objects="$extra_objects cgen.o" ;;
 653         esac
 654     fi
 655
 656 # See if we really can support this configuration with the emulation code.
 657
 658     if test $this_target = $target ; then
 659       primary_bfd_gas=$bfd_gas
 660       obj_format=$fmt
 661       te_file=$em
 662
 663       if test $bfd_gas = no ; then
 664         # Can't support other configurations this way.
 665         break
 666       fi
 667     elif test $bfd_gas = no ; then
 668       # Can't support this configuration.
 669       break
 670     fi
 671
 672 # From target name and format, produce a list of supported emulations.
 673
 674     case ${generic_target}-${fmt} in
 675       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 676       mips*-*-linux*-*) case "$endian" in
 677                         big)    emulation="mipsbelf mipslelf mipself" ;;
 678                         *)      emulation="mipslelf mipsbelf mipself" ;;
 679                         esac ;;
 680       mips-*-lnews*-ecoff) ;;
 681       mips-*-*-ecoff)   case "$endian" in
 682                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 683                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 684                         esac ;;
 685       mips-*-*-elf)     case "$endian" in
 686                         big)    emulation="mipsbelf mipslelf mipself" ;;
 687                         *)      emulation="mipslelf mipsbelf mipself" ;;
 688                         esac ;;
 689       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 690       # i386-pc-pe-coff != i386-pc-coff.
 691       i386-*-pe-coff)   ;;
 692       # Uncommenting the next line will turn on support for i386 AOUT
 693       # for the default linux configuration
 694       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 695       #
 696       i386-*-aout)      emulation="i386aout" ;;
 697       i386-*-coff)      emulation="i386coff" ;;
 698       i386-*-elf)       emulation="i386elf" ;;
 699
 700       # Always all formats.  The first stated emulation becomes the default.
 701       cris-*-*aout*)    emulation="crisaout criself" ;;
 702       cris-*-*)         emulation="criself crisaout" ;;
 703     esac
 704
 705     emulations="$emulations $emulation"
 706
 707 done
 708
 709 # Turn on all targets if possible
 710 if test ${all_targets} = "yes"; then
 711   case ${target_cpu_type} in
 712   i386)
 713     case ${obj_format} in
 714     aout)
 715       emulations="$emulations i386coff i386elf"
 716       ;;
 717     coff)
 718       emulations="$emulations i386aout i386elf"
 719     ;;
 720     elf)
 721       emulations="$emulations i386aout i386coff"
 722       ;;
 723     esac
 724   ;;
 725   esac
 726 fi
 727
 728 # Assign floating point type.  Most processors with FP support
 729 # IEEE FP.  On those that don't support FP at all, usually IEEE
 730 # is emulated.
 731 case ${target_cpu} in
 732   vax | tahoe ) atof=${target_cpu} ;;
 733   pdp11)        atof=vax ;;
 734   *)            atof=ieee ;;
 735 esac
 736
 737 case "${obj_format}" in
 738   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 739 esac
 740
 741 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 742 cgen_cpu_prefix=""
 743 if test $using_cgen = yes ; then
 744   case ${target_cpu} in
 745     *) cgen_cpu_prefix=${target_cpu} ;;
 746   esac
 747   AC_SUBST(cgen_cpu_prefix)
 748   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 749 fi
 750
 751 dnl
 752 dnl Make sure the desired support files exist.
 753 dnl
 754
 755 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 756   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 757 fi
 758
 759 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 760   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 761 fi
 762
 763 case ${user_bfd_gas}-${primary_bfd_gas} in
 764   yes-yes | no-no)
 765     # We didn't override user's choice.
 766     ;;
 767   no-yes)
 768     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 769     ;;
 770   no-preferred)
 771     primary_bfd_gas=no
 772     ;;
 773   *-preferred)
 774     primary_bfd_gas=yes
 775     ;;
 776   yes-*)
 777     primary_bfd_gas=yes
 778     ;;
 779   -*)
 780     # User specified nothing.
 781     ;;
 782 esac
 783
 784 # Some COFF configurations want these random other flags set.
 785 case ${obj_format} in
 786   coff)
 787     case ${target_cpu_type} in
 788       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 789       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 790       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 791     esac
 792     ;;
 793 esac
 794
 795 # Getting this done right is going to be a bitch.  Each configuration specified
 796 # with --enable-targets=... should be checked for environment, format, cpu, and
 797 # bfd_gas setting.
 798 #
 799 # For each configuration, the necessary object file support code must be linked
 800 # in.  This might be only one, it might be up to four.  The necessary emulation
 801 # code needs to be provided, too.
 802 #
 803 # And then there's "--enable-targets=all"....
 804 #
 805 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 806
 807 formats="${obj_format}"
 808 emfiles=""
 809 EMULATIONS=""
 810 GAS_UNIQ(emulations)
 811 for em in . $emulations ; do
 812   case $em in
 813     .)  continue ;;
 814     mipsbelf | mipslelf | mipself)
 815         fmt=elf   file=mipself ;;
 816     mipsbecoff | mipslecoff | mipsecoff)
 817         fmt=ecoff file=mipsecoff ;;
 818     *coff)
 819         fmt=coff  file=$em ;;
 820     *aout)
 821         fmt=aout file=$em ;;
 822     *elf)
 823         fmt=elf file=$em ;;
 824   esac
 825   formats="$formats $fmt"
 826   emfiles="$emfiles e-$file.o"
 827   EMULATIONS="$EMULATIONS &$em,"
 828 done
 829 GAS_UNIQ(formats)
 830 GAS_UNIQ(emfiles)
 831 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 832   for fmt in $formats ; do
 833     case $fmt in
 834       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 835       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 836       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 837       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 838       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 839       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 840       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 841       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 842       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 843       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 844     esac
 845     extra_objects="$extra_objects obj-$fmt.o"
 846   done
 847   obj_format=multi
 848 fi
 849 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 850   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 851   # e-mips* has more than one emulation per file, e-i386* has just one at the
 852   # moment.  If only one emulation is specified, then don't define
 853   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 854   case "${obj_format}${emfiles}" in
 855     multi* | *mips*)
 856       extra_objects="$extra_objects $emfiles"
 857       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 858   esac
 859 fi
 860 AC_SUBST(extra_objects)
 861 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 862 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 863                    [Default emulation.])
 864
 865 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 866   yes-*-coff)   need_bfd=yes ;;
 867   no-*-coff)    need_bfd=yes
 868                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 869 esac
 870
 871 reject_dev_configs=yes
 872
 873 case ${reject_dev_configs}-${dev} in
 874   yes-yes) # Oops.
 875     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 876     ;;
 877 esac
 878
 879 AC_SUBST(target_cpu_type)
 880 AC_SUBST(obj_format)
 881 AC_SUBST(te_file)
 882 AC_SUBST(install_tooldir)
 883 AC_SUBST(atof)
 884 dnl AC_SUBST(emulation)
 885
 886 case "${primary_bfd_gas}" in
 887   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 888         need_bfd=yes ;;
 889 esac
 890
 891 # do we need the opcodes library?
 892 case "${need_opcodes}" in
 893 yes)
 894   OPCODES_LIB=../opcodes/libopcodes.la
 895   ;;
 896 esac
 897
 898 case "${need_bfd}" in
 899 yes)
 900   BFDLIB=../bfd/libbfd.la
 901   BFDVER_H=../bfd/bfdver.h
 902   ALL_OBJ_DEPS="$ALL_OBJ_DEPS"' ../bfd/bfd.h $(INCDIR)/symcat.h'
 903   ;;
 904 esac
 905
 906 AC_SUBST(BFDLIB)
 907 AC_SUBST(OPCODES_LIB)
 908
 909 AC_SUBST(BFDVER_H)
 910 AC_SUBST(ALL_OBJ_DEPS)
 911
 912 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 913 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 914 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 915 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 916 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 917
 918 AC_PROG_CC
 919
 920 AC_PROG_YACC
 921 AM_PROG_LEX
 922
 923 ALL_LINGUAS="fr tr es"
 924 CY_GNU_GETTEXT
 925
 926 AM_MAINTAINER_MODE
 927 AC_EXEEXT
 928
 929 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 930
 931 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 932 # people who are not cross-compiling but are compiling cross-assemblers.
 933 AC_MSG_CHECKING(whether compiling a cross-assembler)
 934 if test "${host}" = "${target}"; then
 935   cross_gas=no
 936 else
 937   cross_gas=yes
 938   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 939 fi
 940 AC_MSG_RESULT($cross_gas)
 941
 942 dnl ansidecl.h will deal with const
 943 dnl AC_CONST
 944 AC_FUNC_ALLOCA
 945 AC_C_INLINE
 946
 947 # VMS doesn't have unlink.
 948 AC_CHECK_FUNCS(unlink remove, break)
 949
 950 # Some systems don't have sbrk().
 951 AC_CHECK_FUNCS(sbrk)
 952
 953 # do we need the math library?
 954 case "${need_libm}" in
 955 yes)
 956   AC_CHECK_LIBM
 957   AC_SUBST(LIBM)
 958   ;;
 959 esac
 960
 961 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 962 # enough, but on some of those systems, the assert macro relies on requoting
 963 # working properly!
 964 GAS_WORKING_ASSERT
 965
 966 # On some systems, the system header files may not declare malloc, realloc,
 967 # and free.  There are places where gas needs these functions to have been
 968 # declared -- such as when taking their addresses.
 969 gas_test_headers="
 970 #ifdef HAVE_MEMORY_H
 971 #include <memory.h>
 972 #endif
 973 #ifdef HAVE_STRING_H
 974 #include <string.h>
 975 #else
 976 #ifdef HAVE_STRINGS_H
 977 #include <strings.h>
 978 #endif
 979 #endif
 980 #ifdef HAVE_STDLIB_H
 981 #include <stdlib.h>
 982 #endif
 983 #ifdef HAVE_UNISTD_H
 984 #include <unistd.h>
 985 #endif
 986 "
 987 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 988 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 989 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 990 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 991 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 992
 993 # Does errno.h declare errno, or do we have to add a separate declaration
 994 # for it?
 995 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 996 #ifdef HAVE_ERRNO_H
 997 #include <errno.h>
 998 #endif
 999 ])
1000
1001 dnl This must come last.
1002
1003 dnl We used to make symlinks to files in the source directory, but now
1004 dnl we just use the right name for .c files, and create .h files in
1005 dnl the build directory which include the right .h file.  Make sure
1006 dnl the old symlinks don't exist, so that a reconfigure in an existing
1007 dnl directory behaves reasonably.
1008
1009 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
1010 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
1011  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
1012  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
1013  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
1014  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
1015  if test "x$cgen_cpu_prefix" != x ; then
1016    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
1017  fi
1018
1019  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
1020 [target_cpu_type=${target_cpu_type}
1021  cgen_cpu_prefix=${cgen_cpu_prefix}
1022  obj_format=${obj_format}
1023  te_file=${te_file}])