gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.3)dnl We only need 2.0, but pre-2.3 loses on some AIX version.
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true ;;
  30   no)  shared=false ;;
  31   *)   AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;;
  32 esac])dnl
  33
  34 # Generate a header file -- gets more post-processing by Makefile later.
  35 AC_CONFIG_HEADER(conf)
  36
  37 dnl For recursion to work right, this must be an absolute pathname.
  38 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  39 AC_CANONICAL_SYSTEM
  40 AC_ARG_PROGRAM
  41
  42 te_file=generic
  43
  44 # assign cpu type
  45
  46 # check for architecture variants
  47 case ${target_cpu} in
  48   armeb)        cpu_type=arm endian=big ;;
  49   arm*)         cpu_type=arm endian=little ;;
  50   hppa*)        cpu_type=hppa ;;
  51 changequote(,)dnl
  52   i[45]86)      cpu_type=i386 ;;
  53   m680[012346]0) cpu_type=m68k ;;
  54   m68008)       cpu_type=m68k ;;
  55   m683??)       cpu_type=m68k ;;
  56 changequote([,])dnl
  57   m8*)          cpu_type=m88k ;;
  58   mips*el)      cpu_type=mips endian=little;;
  59   mips*)        cpu_type=mips endian=big ;;
  60   powerpcle*)   cpu_type=ppc endian=little ;;
  61   powerpc*)     cpu_type=ppc endian=big ;;
  62   rs6000*)      cpu_type=ppc ;;
  63   sparc64)      cpu_type=sparc
  64                 AC_DEFINE(SPARC_V9) ;;
  65   sparc*)       cpu_type=sparc ;;
  66   *)            cpu_type=${target_cpu} ;;
  67 esac
  68
  69 # do we need the opcodes library?
  70 case ${cpu_type} in
  71   alpha | vax)
  72     ;;
  73   *)
  74     OPCODES_DEP=../opcodes/libopcodes.a
  75     OPCODES_LIB='-L../opcodes -lopcodes'
  76
  77     # We need to handle some special cases if opcodes was built shared.
  78     if test "${shared}" = "true"; then
  79       case "${host}" in
  80       *-*-sunos*)
  81       # On SunOS, we must link against the name we are going to install,
  82       # not -lbfd, since SunOS does not support SONAME.
  83       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
  84       ;;
  85       esac
  86     fi
  87     ;;
  88 esac
  89 AC_SUBST(OPCODES_DEP)
  90 AC_SUBST(OPCODES_LIB)
  91
  92 gas_target=${cpu_type}
  93 this_target=${generic_target}
  94
  95 canon_targets=""
  96 if test -n "$enable_targets" ; then
  97   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  98     result=`$ac_config_sub $t 2>/dev/null`
  99     if test -n "$result" ; then
 100       canon_targets="$canon_targets $result"
 101 #    else
 102 #      # Permit "all", etc.  We don't support it yet though.
 103 #      canon_targets="$canon_targets $t"
 104     fi
 105   done
 106   GAS_UNIQ(canon_targets)
 107 fi
 108
 109 emulations=""
 110
 111 for this_target in $target $canon_targets ; do
 112
 113     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 114
 115     # check for architecture variants
 116     case ${cpu} in
 117       hppa*)            cpu_type=hppa ;;
 118 changequote(,)dnl
 119       i[45]86)          cpu_type=i386 ;;
 120       m680[012346]0)    cpu_type=m68k ;;
 121       m68008)           cpu_type=m68k ;;
 122       m683??)           cpu_type=m68k ;;
 123 changequote([,])dnl
 124       m8*)              cpu_type=m88k ;;
 125       mips*el)          cpu_type=mips endian=little;;
 126       mips*)            cpu_type=mips endian=big ;;
 127       powerpcle*)       cpu_type=ppc endian=little ;;
 128       powerpc*)         cpu_type=ppc endian=big ;;
 129       rs6000*)          cpu_type=ppc ;;
 130       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
 131       sparc*)           cpu_type=sparc ;;
 132       *)                cpu_type=${cpu} ;;
 133     esac
 134
 135     if test ${this_target} = $target ; then
 136       target_cpu_type=${cpu_type}
 137     elif test ${target_cpu_type} != ${cpu_type} ; then
 138       continue
 139     fi
 140
 141     targ=${cpu_type}
 142     generic_target=${cpu_type}-$vendor-$os
 143     dev=no
 144     bfd_gas=no
 145     em=generic
 146
 147     # assign object format
 148     case ${generic_target} in
 149       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 150       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 151       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 152       a29k-*-vxworks*)      fmt=coff ;;
 153
 154       alpha-*-netware*)     fmt=ecoff ;;
 155       alpha-*-osf*)         fmt=ecoff ;;
 156       alpha-*-linux*)       fmt=ecoff ;;
 157
 158 # start-sanitize-arc
 159       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 160 # end-sanitize-arc
 161
 162       arm-*-riscix*)        fmt=aout targ=arm-lit ;;
 163       arm-*-aout)           fmt=aout
 164                             case "$endian" in
 165                               big)      targ=arm-big ;;
 166                               *)        targ=arm-lit ;;
 167                             esac
 168                             ;;
 169       arm-*-coff)           fmt=coff ;;
 170       arm-*-riscix*)        fmt=aout ;;
 171       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 172
 173       hppa-*-*elf*)         fmt=elf em=hppa ;;
 174       hppa-*-lites*)        fmt=elf em=hppa ;;
 175       hppa-*-osf*)          fmt=som em=hppa ;;
 176       hppa-*-hpux*)         fmt=som em=hppa ;;
 177       hppa-*-bsd*)          fmt=som em=hppa ;;
 178       hppa-*-hiux*)         fmt=som em=hppa ;;
 179
 180       h8300-*-coff)         fmt=coff ;;
 181
 182       i386-ibm-aix*)        fmt=coff targ=i386coff
 183                              em=i386aix ;;
 184       i386-*-bsd*)          fmt=aout em=386bsd ;;
 185       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 186       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 187       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 188       i386-*-linux*coff*)   fmt=coff em=linux
 189                              targ=i386coff ;;
 190       i386-*-linux*)        fmt=elf em=linux ;;
 191       i386-*-lynxos*)       fmt=coff targ=i386coff
 192                              em=lynx ;;
 193       i386-*-sysv4* | i386-*-solaris* | i386-*-elf)
 194                             fmt=elf ;;
 195       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 196       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 197                             fmt=coff targ=i386coff ;;
 198       i386-*-vsta)          fmt=aout ;;
 199       i386-*-go32)          fmt=coff targ=i386coff ;;
 200       i386-*-gnu*)          fmt=elf ;;
 201       i386-*-mach*)
 202                             fmt=aout em=mach bfd_gas=yes ;;
 203       i386-*-msdos*)        fmt=aout ;;
 204       i386-*-moss*)         fmt=elf ;;
 205       i386-*-pe)            fmt=coff targ=i386coff em=pe bfd_gas=yes;;
 206       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe bfd_gas=yes;;
 207       i386-*-*nt)           fmt=coff targ=i386coff em=pe bfd_gas=yes;;
 208       i960-*-bout)          fmt=bout ;;
 209       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 210       i960-*-nindy*)        fmt=bout ;;
 211       i960-*-vxworks4*)     fmt=bout ;;
 212       i960-*-vxworks5.0)    fmt=bout ;;
 213       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 214       i960-*-vxworks*)      fmt=bout ;;
 215
 216       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 217                             fmt=aout em=sun3 ;;
 218       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 219       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 220       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 221       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 222                             fmt=elf ;;
 223       m68k-*-coff | m68k-*-sysv*)
 224                             fmt=coff targ=m68kcoff ;;
 225       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 226       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 227                              em=lynx ;;
 228       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 229       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 230       m68k-*-psos*)         fmt=elf em=psos;;
 231
 232       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 233       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 234
 235       # don't change em like *-*-bsd does
 236       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 237       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 238       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 239       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 240       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 241       mips-*-ecoff*)        fmt=ecoff
 242                             case "$endian" in
 243                             big) targ=mips-big ;;
 244                             *)   targ=mips-lit ;;
 245                             esac
 246                             ;;
 247       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 248       mips-*-gnu*)          fmt=aout
 249                             case "$endian" in
 250                             big) targ=mips-big ;;
 251                             *)   targ=mips-lit ;;
 252                             esac
 253                             ;;
 254       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 255       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 256       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 257       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 258       mips-*-elf*)          fmt=elf
 259                             case "$endian" in
 260                             big) targ=mips-big ;;
 261                             *)   targ=mips-lit ;;
 262                             esac
 263                             ;;
 264       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 265                             fmt=coff em=pe
 266                             case "$endian" in
 267                             big) targ=ppc-big ;;
 268                             *)   targ=ppc-lit ;;
 269                             esac
 270                             ;;
 271       ppc-*-aix*)           fmt=coff ;;
 272       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 273                             fmt=elf
 274                             case "$endian" in
 275                             big)  targ=ppc-big ;;
 276                             *)    targ=ppc-lit ;;
 277                             esac
 278                             ;;
 279       ppc-*-macos* | ppc-*-mpw*)
 280                             fmt=coff em=macos ;;
 281       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 282
 283       sh-*-coff)            fmt=coff ;;
 284
 285 # start-sanitize-rce
 286       rce-*-aout)           fmt=aout ;;
 287 # end-sanitize-rce
 288
 289       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 290       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 291
 292       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 293       sparc-*-aout | sparc*-*-vxworks)
 294                             fmt=aout ;;
 295       sparc-*-coff)         fmt=coff ;;
 296       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 297       sparc-fujitsu-none)   fmt=aout ;;
 298       sparc-*-elf | sparc*-*-solaris*)
 299                             fmt=elf ;;
 300       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 301
 302       vax-*-bsd* | vax-*-ultrix*)
 303                             fmt=aout ;;
 304       vax-*-vms)            fmt=vms ;;
 305
 306       z8k-*-coff | z8k-*-sim)
 307                             fmt=coff ;;
 308
 309       w65-*-*)              fmt=coff ;;
 310
 311       *-*-aout | *-*-scout)
 312                             fmt=aout ;;
 313       *-*-nindy*)
 314                             fmt=bout ;;
 315       *-*-bsd*)
 316                             fmt=aout em=sun3 ;;
 317       *-*-generic)          fmt=generic ;;
 318       *-*-xray | *-*-hms)   fmt=coff ;;
 319       *-*-sim)              fmt=coff ;;
 320       *-*-elf | *-*-sysv4* | *-*-solaris*)
 321                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 322                             fmt=elf dev=yes ;;
 323       *-*-vxworks)          fmt=aout ;;
 324       *-*-netware)          fmt=elf ;;
 325     esac
 326
 327     case ${cpu_type}-${fmt} in
 328       arm-*)    bfd_gas=yes ;;
 329     # not yet
 330     # i386-aout)        bfd_gas=preferred ;;
 331       mips-*)   bfd_gas=yes ;;
 332       ns32k-*)  bfd_gas=yes ;;
 333       ppc-*)    bfd_gas=yes ;;
 334       sparc-*)  bfd_gas=yes ;;
 335       *-elf)    bfd_gas=yes ;;
 336       *-ecoff)  bfd_gas=yes ;;
 337       *-som)    bfd_gas=yes ;;
 338       *)                ;;
 339     esac
 340
 341 # Other random stuff.
 342
 343     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 344
 345     case ${cpu}-${vendor}-${os} in
 346       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 347     esac
 348
 349     case ${cpu_type} in
 350       m68k)
 351         case ${extra_objects} in
 352         *m68k-parse.o*) ;;
 353         *) extra_objects="$extra_objects m68k-parse.o" ;;
 354         esac
 355         ;;
 356     esac
 357
 358 # See if we really can support this configuration with the emulation code.
 359
 360     if test $this_target = $target ; then
 361       primary_bfd_gas=$bfd_gas
 362       obj_format=$fmt
 363       gas_target=$targ
 364       te_file=$em
 365
 366       if test $bfd_gas = no ; then
 367         # Can't support other configurations this way.
 368         break
 369       fi
 370     elif test $bfd_gas = no ; then
 371       # Can't support this configuration.
 372       break
 373     fi
 374
 375 # From target name and format, produce a list of supported emulations.
 376
 377     case ${generic_target}-${fmt} in
 378       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 379       mips-*-*-ecoff)   case "$endian" in
 380                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 381                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 382                         esac ;;
 383       mips-*-*-elf)     case "$endian" in
 384                         big)    emulation="mipsbelf mipslelf mipself" ;;
 385                         *)      emulation="mipslelf mipsbelf mipself" ;;
 386                         esac ;;
 387     esac
 388
 389     emulations="$emulations $emulation"
 390
 391 done
 392
 393 # Assign floating point type.  Most processors with FP support
 394 # IEEE FP.  On those that don't support FP at all, usually IEEE
 395 # is emulated.
 396 case ${target_cpu} in
 397   vax | tahoe ) atof=${target_cpu} ;;
 398   *)            atof=ieee ;;
 399 esac
 400
 401 case "${obj_format}" in
 402   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 403 esac
 404
 405 dnl
 406 dnl Make sure the desired support files exist.
 407 dnl
 408
 409 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 410   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 411 fi
 412
 413 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 414   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 415 fi
 416
 417 # and target makefile frag
 418
 419 target_frag=${srcdir}/config/${gas_target}.mt
 420 if test ! -r ${target_frag}; then
 421   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 422 fi
 423 AC_SUBST_FILE(target_frag)
 424
 425 case ${user_bfd_gas}-${primary_bfd_gas} in
 426   yes-yes | no-no)
 427     # We didn't override user's choice.
 428     ;;
 429   no-yes)
 430     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 431     ;;
 432   no-preferred)
 433     primary_bfd_gas=no
 434     ;;
 435   *-preferred)
 436     primary_bfd_gas=yes
 437     ;;
 438   yes-*)
 439     primary_bfd_gas=yes
 440     ;;
 441   -*)
 442     # User specified nothing.
 443     ;;
 444 esac
 445
 446 # Some COFF configurations want these random other flags set.
 447 case ${obj_format} in
 448   coff)
 449     case ${target_cpu_type} in
 450       i386) AC_DEFINE(I386COFF) ;;
 451       m68k) AC_DEFINE(M68KCOFF) ;;
 452       m88k) AC_DEFINE(M88KCOFF) ;;
 453     esac
 454     ;;
 455 esac
 456
 457 # Getting this done right is going to be a bitch.  Each configuration specified
 458 # with --enable-targets=... should be checked for environment, format, cpu, and
 459 # bfd_gas setting.
 460 #
 461 # For each configuration, the necessary object file support code must be linked
 462 # in.  This might be only one, it might be up to four.  The necessary emulation
 463 # code needs to be provided, too.
 464 #
 465 # And then there's "--enable-targets=all"....
 466 #
 467 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 468
 469 formats="${obj_format}"
 470 emfiles=""
 471 EMULATIONS=""
 472 GAS_UNIQ(emulations)
 473 for em in . $emulations ; do
 474   case $em in
 475     .)  continue ;;
 476     mipsbelf | mipslelf)
 477         fmt=elf   file=mipself ;;
 478     mipsbecoff | mipslecoff)
 479         fmt=ecoff file=mipsecoff ;;
 480   esac
 481   formats="$formats $fmt"
 482   emfiles="$emfiles e-$file.o"
 483   EMULATIONS="$EMULATIONS &$em,"
 484 done
 485 GAS_UNIQ(formats)
 486 GAS_UNIQ(emfiles)
 487 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 488   for fmt in $formats ; do
 489     case $fmt in
 490       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 491       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 492       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 493       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 494       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 495       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 496       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 497       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 498       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 499       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 500     esac
 501     extra_objects="$extra_objects obj-$fmt.o"
 502   done
 503   obj_format=multi
 504 fi
 505 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 506   te_file=multi
 507   extra_objects="$extra_objects $emfiles"
 508   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 509   AC_DEFINE(USE_EMULATIONS)
 510 fi
 511 AC_SUBST(extra_objects)
 512 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 513 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 514
 515 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 516         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 517         config/te-${te_file}.h config/atof-${atof}.c \
 518         $extra_files"
 519 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 520         $extra_links"
 521
 522 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 523   yes-*-coff)   need_bfd=yes ;;
 524   no-*-coff)    need_bfd=yes
 525                 AC_DEFINE(MANY_SEGMENTS) ;;
 526 esac
 527
 528 reject_dev_configs=yes
 529
 530 case ${reject_dev_configs}-${dev} in
 531   yes-yes) # Oops.
 532     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 533     ;;
 534 esac
 535
 536 AC_SUBST(target_cpu_type)
 537 AC_SUBST(obj_format)
 538 AC_SUBST(atof)
 539 dnl AC_SUBST(emulation)
 540
 541 AC_LINK_FILES($files, $links)
 542
 543 case "${primary_bfd_gas}" in
 544   yes)  AC_DEFINE(BFD_ASSEMBLER)
 545         need_bfd=yes ;;
 546 esac
 547
 548 case "${need_bfd}" in
 549   yes)  BFDDEP=../bfd/libbfd.a
 550         BFDLIB='-L../bfd -lbfd'
 551         ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 552
 553         # We need to handle some special cases if BFD was built shared.
 554         if test "${shared}" = "true"; then
 555           case "${host}" in
 556           *-*-sunos*)
 557           # On SunOS, we must link against the name we are going to install,
 558           # not -lbfd, since SunOS does not support SONAME.
 559           BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 560           ;;
 561           esac
 562         fi
 563         ;;
 564 esac
 565 AC_SUBST(BFDDEP)
 566 AC_SUBST(BFDLIB)
 567 AC_SUBST(ALL_OBJ_DEPS)
 568
 569 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 570 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 571 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 572 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 573 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 574
 575 AC_PROG_CC
 576 AC_PROG_INSTALL
 577
 578 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 579
 580 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 581 # people who are not cross-compiling but are compiling cross-assemblers.
 582 AC_MSG_CHECKING(whether compiling a cross-assembler)
 583 if test "${host}" = "${target}"; then
 584   cross_gas=no
 585 else
 586   cross_gas=yes
 587   AC_DEFINE(CROSS_COMPILE)
 588 fi
 589 AC_MSG_RESULT($cross_gas)
 590
 591 dnl ansidecl.h will deal with const
 592 dnl AC_CONST
 593 AC_FUNC_ALLOCA
 594 AC_C_INLINE
 595
 596 # VMS doesn't have unlink.
 597 AC_CHECK_FUNCS(unlink remove, break)
 598
 599 # Some systems don't have sbrk().
 600 AC_CHECK_FUNCS(sbrk)
 601
 602 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 603 # enough, but on some of those systems, the assert macro relies on requoting
 604 # working properly!
 605 GAS_WORKING_ASSERT
 606
 607 # On some systems, the system header files may not declare malloc, realloc,
 608 # and free.  There are places where gas needs these functions to have been
 609 # declared -- such as when taking their addresses.
 610 gas_test_headers="
 611 #ifdef HAVE_MEMORY_H
 612 #include <memory.h>
 613 #endif
 614 #ifdef HAVE_STRING_H
 615 #include <string.h>
 616 #endif
 617 #ifdef HAVE_STDLIB_H
 618 #include <stdlib.h>
 619 #endif
 620 #ifdef HAVE_UNISTD_H
 621 #include <unistd.h>
 622 #endif
 623 "
 624 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 625 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 626
 627 # Does errno.h declare errno, or do we have to add a separate declaration
 628 # for it?
 629 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 630 #ifdef HAVE_ERRNO_H
 631 #include <errno.h>
 632 #endif
 633 ])
 634
 635 HLDFLAGS=
 636 # If we have shared libraries, try to set rpath reasonably.
 637 if test "${shared}" = "true"; then
 638   case "${host}" in
 639   *-*-hpux*)
 640     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 641     ;;
 642   *-*-irix5*)
 643     HLDFLAGS='-Wl,-rpath,$(libdir)'
 644     ;;
 645   *-*-linux*aout*)
 646     ;;
 647   *-*-linux*)
 648     HLDFLAGS='-Wl,-rpath,$(libdir)'
 649     ;;
 650   *-*-sysv4* | *-*-solaris*)
 651     HLDFLAGS='-R $(libdir)'
 652     ;;
 653   esac
 654 fi
 655
 656 # On SunOS, if the linker supports the -rpath option, use it to
 657 # prevent ../bfd and ../opcodes from being included in the run time
 658 # search path.
 659 case "${host}" in
 660   *-*-sunos*)
 661     echo 'main () { }' > conftest.c
 662     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 663     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 664       :
 665     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 666       :
 667     elif test "${shared}" = "true"; then
 668       HLDFLAGS='-Wl,-rpath=$(libdir)'
 669     else
 670       HLDFLAGS='-Wl,-rpath='
 671     fi
 672     rm -f conftest.t conftest.c conftest
 673     ;;
 674 esac
 675 AC_SUBST(HLDFLAGS)
 676
 677 dnl This must come last.
 678 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)