gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl   Copyright (C) 2012-2014 Free Software Foundation, Inc.
   7 dnl
   8 dnl This file is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; see the file COPYING3.  If not see
  20 dnl <http://www.gnu.org/licenses/>.
  21 dnl
  22 dnl v2.5 needed for --bindir et al
  23 AC_PREREQ(2.59)
  24 AC_INIT
  25 AC_CONFIG_SRCDIR(as.h)
  26
  27 dnl Autoconf 2.57 will find the aux dir without this.  However, unless
  28 dnl we specify this explicitly, automake-1.7 will assume that ylwrap is in
  29 dnl gas/ instead of gas/../.
  30 AC_CONFIG_AUX_DIR(..)
  31 AC_CANONICAL_TARGET
  32 AC_ISC_POSIX
  33
  34 changequote(,)dnl
  35 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  36 changequote([,])dnl
  37 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  38
  39 AC_PROG_CC
  40 AC_GNU_SOURCE
  41 AC_USE_SYSTEM_EXTENSIONS
  42 ACX_LARGEFILE
  43
  44 LT_INIT
  45
  46 AC_ARG_ENABLE(targets,
  47 [  --enable-targets        alternative target configurations besides the primary],
  48 [case "${enableval}" in
  49   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  50             ;;
  51   no)       enable_targets= ;;
  52   *)        enable_targets=$enableval ;;
  53 esac])dnl
  54
  55 ac_checking=yes
  56 if grep '^RELEASE=y' ${srcdir}/../bfd/Makefile.am >/dev/null 2>/dev/null ; then
  57   ac_checking=
  58 fi
  59 AC_ARG_ENABLE(checking,
  60 [  --enable-checking       enable run-time checks],
  61 [case "${enableval}" in
  62   no|none)  ac_checking= ;;
  63   *)        ac_checking=yes ;;
  64 esac])dnl
  65 if test x$ac_checking != x ; then
  66   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  67 fi
  68
  69 using_cgen=no
  70
  71 AM_BINUTILS_WARNINGS
  72
  73 # Generate a header file
  74 AC_CONFIG_HEADERS(config.h:config.in)
  75
  76 # PR 14072
  77 AH_VERBATIM([00_CONFIG_H_CHECK],
  78 [/* Check that config.h is #included before system headers
  79    (this works only for glibc, but that should be enough).  */
  80 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  81 #  error config.h must be #included before system headers
  82 #endif
  83 #define __CONFIG_H__ 1])
  84
  85 # If we are on a DOS filesystem, we must use gdb.ini rather than
  86 # .gdbinit.
  87 case "${host}" in
  88   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-windows*)
  89     GDBINIT="gdb.ini"
  90     AC_CONFIG_FILES(gdb.ini:gdbinit.in)
  91     ;;
  92   *)
  93     GDBINIT=".gdbinit"
  94     AC_CONFIG_FILES(.gdbinit:gdbinit.in)
  95     ;;
  96 esac
  97 AC_SUBST(GDBINIT)
  98
  99 #We need this for the host.  BOUT header is in host order.
 100 AC_C_BIGENDIAN
 101
 102 te_file=generic
 103
 104 # Makefile target for installing gas in $(tooldir)/bin.
 105 install_tooldir=install-exec-tooldir
 106
 107 canon_targets=""
 108 all_targets=no
 109 if test -n "$enable_targets" ; then
 110   for t in `echo $enable_targets | sed 's/,/ /g'`; do
 111     if test $t = "all"; then
 112       all_targets=yes
 113       continue
 114     fi
 115     result=`$ac_config_sub $t 2>/dev/null`
 116     if test -n "$result" ; then
 117       canon_targets="$canon_targets $result"
 118 #    else
 119 #      # Permit "all", etc.  We don't support it yet though.
 120 #      canon_targets="$canon_targets $t"
 121     fi
 122   done
 123   GAS_UNIQ(canon_targets)
 124 fi
 125
 126 emulations=""
 127
 128 for this_target in $target $canon_targets ; do
 129
 130     targ=${this_target}
 131     . ${srcdir}/configure.tgt
 132
 133     case ${target_cpu} in
 134       crisv32)
 135         AC_DEFINE_UNQUOTED(DEFAULT_CRIS_ARCH, $arch,
 136                            [Default CRIS architecture.])
 137         ;;
 138     esac
 139
 140     if test ${this_target} = $target ; then
 141       target_cpu_type=${cpu_type}
 142     elif test ${target_cpu_type} != ${cpu_type} ; then
 143       continue
 144     fi
 145
 146     generic_target=${cpu_type}-${target_vendor}-${target_os}
 147     case ${generic_target} in
 148       i386-*-sco3.2v5*)
 149         if test ${this_target} = $target; then
 150           AC_DEFINE(SCO_ELF, 1, [Define if defaulting to ELF on SCO 5.])
 151         fi
 152         ;;
 153
 154       i386-*-msdosdjgpp* \
 155       | i386-*-go32* \
 156       | i386-go32-rtems*)
 157         AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 158         ;;
 159
 160       i860-*-*)
 161         AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress)
 162         ;;
 163
 164       microblaze*)
 165         ;;
 166
 167 changequote(,)dnl
 168       ppc-*-aix[5-9].*)
 169 changequote([,])dnl
 170         AC_DEFINE(AIX_WEAK_SUPPORT, 1,
 171                   [Define if using AIX 5.2 value for C_WEAKEXT.])
 172         ;;
 173       ppc-*-solaris*)
 174         if test ${this_target} = $target; then
 175           AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 176                     [Define if default target is PowerPC Solaris.])
 177         fi
 178         if test x${endian} = xbig; then
 179           AC_MSG_ERROR(Solaris must be configured little endian)
 180         fi
 181         ;;
 182
 183       sh*-*-symbianelf*)
 184         AC_DEFINE(TARGET_SYMBIAN, 1, [Define if target is Symbian OS.])
 185         ;;
 186     esac
 187
 188     if test ${this_target} = $target ; then
 189       endian_def=
 190       if test x${endian} = xbig; then
 191         endian_def=1
 192       elif test x${endian} = xlittle; then
 193         endian_def=0
 194       fi
 195       if test x${endian_def} != x; then
 196         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 197                            [Define as 1 if big endian.])
 198       fi
 199     fi
 200
 201 # Other random stuff.
 202
 203     case ${cpu_type} in
 204       mips)
 205         # Set mips_cpu to the name of the default CPU.
 206         case ${target_cpu} in
 207           mips | mipsbe | mipseb | mipsle | mipsel | mips64 | mips64el)
 208             mips_cpu=from-abi
 209             ;;
 210           mipsisa32 | mipsisa32el)
 211             mips_cpu=mips32
 212             ;;
 213           mipsisa32r2 | mipsisa32r2el)
 214             mips_cpu=mips32r2
 215             ;;
 216           mipsisa32r3 | mipsisa32r3el)
 217             mips_cpu=mips32r3
 218             ;;
 219           mipsisa32r5 | mipsisa32r5el)
 220             mips_cpu=mips32r5
 221             ;;
 222           mipsisa64 | mipsisa64el)
 223             mips_cpu=mips64
 224             ;;
 225           mipsisa64r2 | mipsisa64r2el)
 226             mips_cpu=mips64r2
 227             ;;
 228           mipsisa64r3 | mipsisa64r3el)
 229             mips_cpu=mips64r3
 230             ;;
 231           mipsisa64r5 | mipsisa64r5el)
 232             mips_cpu=mips64r5
 233             ;;
 234           mipstx39 | mipstx39el)
 235             mips_cpu=r3900
 236             ;;
 237           mips64vr | mips64vrel)
 238             mips_cpu=vr4100
 239             ;;
 240           mipsisa32r2* | mipsisa64r2*)
 241 changequote(,)dnl
 242             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..r2//' -e 's/el$//'`
 243 changequote([,])dnl
 244             ;;
 245           mips64* | mipsisa64* | mipsisa32*)
 246 changequote(,)dnl
 247             mips_cpu=`echo $target_cpu | sed -e 's/[a-z]*..//' -e 's/el$//'`
 248 changequote([,])dnl
 249             ;;
 250           mips*)
 251 changequote(,)dnl
 252             mips_cpu=`echo $target_cpu | sed -e 's/^mips//' -e 's/el$//'`
 253 changequote([,])dnl
 254             ;;
 255           *)
 256             AC_MSG_ERROR($target_cpu isn't a supported MIPS CPU name)
 257             ;;
 258         esac
 259         # See whether it's appropriate to set E_MIPS_ABI_O32 for o32
 260         # binaries.  It's a GNU extension that some OSes don't understand.
 261         case ${target} in
 262           *-*-irix*)
 263             use_e_mips_abi_o32=0
 264             ;;
 265           *)
 266             use_e_mips_abi_o32=1
 267             ;;
 268         esac
 269         # Decide whether to generate 32-bit or 64-bit code by default.
 270         # Used to resolve -march=from-abi when an embedded ABI is selected.
 271         case ${target} in
 272           mips64*-*-* | mipsisa64*-*-*)
 273             mips_default_64bit=1
 274             ;;
 275           *)
 276             mips_default_64bit=0
 277             ;;
 278         esac
 279         # Decide which ABI to target by default.
 280         case ${target} in
 281           mips64*-linux* | mips-sgi-irix6* | mips64*-freebsd* | mips64*-kfreebsd*-gnu)
 282             mips_default_abi=N32_ABI
 283             ;;
 284           mips*-linux* | mips*-freebsd* | mips*-kfreebsd*-gnu)
 285             mips_default_abi=O32_ABI
 286             ;;
 287           mips64*-openbsd*)
 288             mips_default_abi=N64_ABI
 289             ;;
 290           *)
 291             mips_default_abi=NO_ABI
 292             ;;
 293         esac
 294         AC_DEFINE_UNQUOTED(MIPS_CPU_STRING_DEFAULT, "$mips_cpu",
 295                            [Default CPU for MIPS targets. ])
 296         AC_DEFINE_UNQUOTED(USE_E_MIPS_ABI_O32, $use_e_mips_abi_o32,
 297                            [Allow use of E_MIPS_ABI_O32 on MIPS targets. ])
 298         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_64BIT, $mips_default_64bit,
 299                            [Generate 64-bit code by default on MIPS targets. ])
 300         AC_DEFINE_UNQUOTED(MIPS_DEFAULT_ABI, $mips_default_abi,
 301                            [Choose a default ABI for MIPS targets. ])
 302         ;;
 303     esac
 304
 305     # Do we need the opcodes library?
 306     case ${cpu_type} in
 307       vax | tic30)
 308         ;;
 309
 310       *)
 311         need_opcodes=yes
 312
 313         case "${enable_shared}" in
 314         yes) shared_opcodes=true ;;
 315         *opcodes*) shared_opcodes=true ;;
 316         *) shared_opcodes=false ;;
 317         esac
 318         ;;
 319     esac
 320
 321     # Any other special object files needed ?
 322     case ${cpu_type} in
 323
 324       bfin)
 325         echo ${extra_objects} | grep -s "bfin-parse.o"
 326         if test $? -ne 0 ; then
 327           extra_objects="$extra_objects bfin-parse.o"
 328         fi
 329
 330         echo ${extra_objects} | grep -s "bfin-lex-wrapper.o"
 331         if test $? -ne 0 ; then
 332           extra_objects="$extra_objects bfin-lex-wrapper.o"
 333         fi
 334         ;;
 335
 336       epiphany | fr30 | ip2k | iq2000 | lm32 | m32r | or1k)
 337         using_cgen=yes
 338         ;;
 339
 340       m32c)
 341         using_cgen=yes
 342         ;;
 343       frv)
 344         using_cgen=yes
 345         ;;
 346       m68k)
 347         case ${extra_objects} in
 348         *m68k-parse.o*) ;;
 349         *) extra_objects="$extra_objects m68k-parse.o" ;;
 350         esac
 351         ;;
 352
 353       mep)
 354         using_cgen=yes
 355         ;;
 356
 357       mips)
 358         echo ${extra_objects} | grep -s "itbl-parse.o"
 359         if test $? -ne 0 ; then
 360           extra_objects="$extra_objects itbl-parse.o"
 361         fi
 362
 363         echo ${extra_objects} | grep -s "itbl-lex-wrapper.o"
 364         if test $? -ne 0 ; then
 365           extra_objects="$extra_objects itbl-lex-wrapper.o"
 366         fi
 367
 368         echo ${extra_objects} | grep -s "itbl-ops.o"
 369         if test $? -ne 0 ; then
 370           extra_objects="$extra_objects itbl-ops.o"
 371         fi
 372         ;;
 373
 374       mt)
 375         using_cgen=yes
 376         ;;
 377
 378       nds32)
 379         # Decide BASELINE, REDUCED_REGS, FPU_DP_EXT, FPU_SP_EXT features
 380         # based on arch_name.
 381         AC_MSG_CHECKING(for default configuration of --with-arch)
 382         if test "x${with_arch}" != x; then
 383           case ${with_arch} in
 384             v2j | v2s | v2f | v2 | v3m | v3j | v3s | v3f | v3 )
 385               AC_DEFINE_UNQUOTED(NDS32_DEFAULT_ARCH_NAME, "$with_arch",
 386                                  [Define value for nds32_arch_name])
 387               ;;
 388             *)
 389               AC_MSG_ERROR(This kind of arch name does *NOT* exist!)
 390               ;;
 391           esac
 392         fi
 393         AC_MSG_RESULT($with_arch)
 394
 395         # Decide features one by one.
 396         AC_MSG_CHECKING(for default configuration of --enable-dx-regs)
 397         if test "x${enable_dx_regs}" == xyes; then
 398           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 1,
 399                     [Define value for nds32_dx_regs])
 400         else
 401           AC_DEFINE(NDS32_DEFAULT_DX_REGS, 0,
 402                     [Define default value for nds32_dx_regs])
 403         fi
 404         AC_MSG_RESULT($enable_dx_regs)
 405
 406         AC_MSG_CHECKING(for default configuration of --enable-perf-ext)
 407         if test "x${enable_perf_ext}" == xno; then
 408           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 0,
 409                     [Define value for nds32_perf_ext])
 410         else
 411           AC_DEFINE(NDS32_DEFAULT_PERF_EXT, 1,
 412                     [Define default value for nds32_perf_ext])
 413         fi
 414         AC_MSG_RESULT($enable_perf_ext)
 415
 416         AC_MSG_CHECKING(for default configuration of --enable-perf-ext2)
 417         if test "x${enable_perf_ext2}" == xno; then
 418           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 0,
 419                     [Define value for nds32_perf_ext2])
 420         else
 421           AC_DEFINE(NDS32_DEFAULT_PERF_EXT2, 1,
 422                     [Define default value for nds32_perf_ext2])
 423         fi
 424         AC_MSG_RESULT($enable_perf_ext2)
 425
 426         AC_MSG_CHECKING(for default configuration of --enable-string-ext)
 427         if test "x${enable_string_ext}" == xno; then
 428           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 0,
 429                     [Define value for nds32_string_ext])
 430         else
 431           AC_DEFINE(NDS32_DEFAULT_STRING_EXT, 1,
 432                     [Define default value for nds32_string_ext])
 433         fi
 434         AC_MSG_RESULT($enable_string_ext)
 435
 436         AC_MSG_CHECKING(for default configuration of --enable-audio-ext)
 437         if test "x${enable_audio_ext}" == xno; then
 438           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 0,
 439                     [Define value for nds32_audio_ext])
 440         else
 441           AC_DEFINE(NDS32_DEFAULT_AUDIO_EXT, 1,
 442                     [Define default value for nds32_audio_ext])
 443         fi
 444         AC_MSG_RESULT($enable_audio_ext)
 445         ;;
 446
 447       i386 | s390 | sparc)
 448         if test $this_target = $target ; then
 449           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 450         fi
 451         ;;
 452
 453       rl78)
 454         echo ${extra_objects} | grep -s "rl78-parse.o"
 455         if test $? -ne 0 ; then
 456           extra_objects="$extra_objects rl78-parse.o"
 457         fi
 458         ;;
 459
 460       rx)
 461         echo ${extra_objects} | grep -s "rx-parse.o"
 462         if test $? -ne 0 ; then
 463           extra_objects="$extra_objects rx-parse.o"
 464         fi
 465         ;;
 466
 467       xstormy16)
 468         using_cgen=yes
 469         ;;
 470
 471       xc16x)
 472         using_cgen=yes
 473         ;;
 474
 475       xtensa)
 476         echo ${extra_objects} | grep -s "xtensa-relax.o"
 477         if test $? -ne 0 ; then
 478           extra_objects="$extra_objects xtensa-relax.o"
 479         fi
 480         ;;
 481
 482       *)
 483         ;;
 484     esac
 485
 486     if test $using_cgen = yes ; then
 487         case "x${extra_objects}" in
 488         *cgen.o*) ;;
 489         *) extra_objects="$extra_objects cgen.o" ;;
 490         esac
 491     fi
 492
 493 # See if we really can support this configuration with the emulation code.
 494
 495     if test $this_target = $target ; then
 496       obj_format=$fmt
 497       te_file=$em
 498     fi
 499
 500    case ${te_file} in
 501       vms) extra_objects="$extra_objects te-vms.o" ;;
 502    esac
 503
 504 # From target name and format, produce a list of supported emulations.
 505
 506     case ${generic_target}-${fmt} in
 507       mips-*-*-*)       case "$endian" in
 508                         big)    emulation="mipsbelf mipslelf mipself" ;;
 509                         *)      emulation="mipslelf mipsbelf mipself" ;;
 510                         esac ;;
 511       # i386-pc-pe-coff != i386-pc-coff.
 512       i386-*-pe-coff)   ;;
 513       # Uncommenting the next line will turn on support for i386 AOUT
 514       # for the default linux configuration
 515       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 516       #
 517       i386-*-aout)      emulation="i386aout" ;;
 518       i386-*-coff)      emulation="i386coff" ;;
 519       i386-*-elf)       emulation="i386elf" ;;
 520
 521       # Always all formats.  The first stated emulation becomes the default.
 522       cris-*-*aout*)    emulation="crisaout criself" ;;
 523       cris-*-*)         emulation="criself crisaout" ;;
 524     esac
 525
 526     emulations="$emulations $emulation"
 527
 528 done
 529
 530 # Turn on all targets if possible
 531 if test ${all_targets} = "yes"; then
 532   case ${target_cpu_type} in
 533   i386)
 534     case ${obj_format} in
 535     aout)
 536       emulations="$emulations i386coff i386elf"
 537       ;;
 538     coff)
 539       emulations="$emulations i386aout i386elf"
 540     ;;
 541     elf)
 542       emulations="$emulations i386aout i386coff"
 543       ;;
 544     esac
 545   ;;
 546   x86_64)
 547     case ${obj_format} in
 548     aout)
 549       emulations="$emulations i386coff i386elf"
 550       ;;
 551     coff)
 552       emulations="$emulations i386aout i386elf"
 553     ;;
 554     elf)
 555       emulations="$emulations i386aout i386coff"
 556       ;;
 557     esac
 558   ;;
 559   esac
 560 fi
 561
 562 # PE code has way too many macros tweaking behaviour
 563 case ${te_file} in
 564   pe*) emulations="" ;;
 565 esac
 566
 567 # Assign floating point type.  Most processors with FP support
 568 # IEEE FP.  On those that don't support FP at all, usually IEEE
 569 # is emulated.
 570 case ${target_cpu} in
 571   vax | pdp11 ) atof=vax ;;
 572   *)            atof=ieee ;;
 573 esac
 574
 575 case "${obj_format}" in
 576   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 577 esac
 578
 579 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 580 cgen_cpu_prefix=""
 581 if test $using_cgen = yes ; then
 582   case ${target_cpu} in
 583     or1knd)
 584        cgen_cpu_prefix=or1k ;;
 585     *) cgen_cpu_prefix=${target_cpu} ;;
 586   esac
 587   AC_SUBST(cgen_cpu_prefix)
 588   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 589 fi
 590
 591 dnl
 592 dnl Make sure the desired support files exist.
 593 dnl
 594
 595 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 596   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 597 fi
 598
 599 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 600   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 601 fi
 602
 603 # Some COFF configurations want these random other flags set.
 604 case ${obj_format} in
 605   coff)
 606     case ${target_cpu_type} in
 607       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 608       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 609       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 610       x86_64) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 611     esac
 612     ;;
 613 esac
 614
 615 # Getting this done right is going to be a bitch.  Each configuration specified
 616 # with --enable-targets=... should be checked for environment, format, cpu
 617 # setting.
 618 #
 619 # For each configuration, the necessary object file support code must be linked
 620 # in.  This might be only one, it might be up to four.  The necessary emulation
 621 # code needs to be provided, too.
 622 #
 623 # And then there's "--enable-targets=all"....
 624 #
 625 # For now, just always do it for MIPS ELF configurations.  Sigh.
 626
 627 formats="${obj_format}"
 628 emfiles=""
 629 EMULATIONS=""
 630 GAS_UNIQ(emulations)
 631 for em in . $emulations ; do
 632   case $em in
 633     .)  continue ;;
 634     mipsbelf | mipslelf | mipself)
 635         fmt=elf   file=mipself ;;
 636     *coff)
 637         fmt=coff  file=$em ;;
 638     *aout)
 639         fmt=aout file=$em ;;
 640     *elf)
 641         fmt=elf file=$em ;;
 642   esac
 643   formats="$formats $fmt"
 644   emfiles="$emfiles e-$file.o"
 645   EMULATIONS="$EMULATIONS &$em,"
 646 done
 647 GAS_UNIQ(formats)
 648 GAS_UNIQ(emfiles)
 649 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 650   for fmt in $formats ; do
 651     case $fmt in
 652       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 653       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 654       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 655       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 656       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 657       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 658       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 659     esac
 660     extra_objects="$extra_objects obj-$fmt.o"
 661   done
 662   obj_format=multi
 663 fi
 664 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 665   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 666   # e-mipself has more than one emulation per file, e-i386* has just one at the
 667   # moment.  If only one emulation is specified, then don't define
 668   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 669   case "${obj_format}${emfiles}" in
 670     multi* | *mipself*)
 671       extra_objects="$extra_objects $emfiles"
 672       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 673   esac
 674 fi
 675 AC_SUBST(extra_objects)
 676 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 677 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 678                    [Default emulation.])
 679
 680 reject_dev_configs=yes
 681
 682 case ${reject_dev_configs}-${dev} in
 683   yes-yes) # Oops.
 684     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 685     ;;
 686 esac
 687
 688 AC_SUBST(target_cpu_type)
 689 AC_SUBST(obj_format)
 690 AC_SUBST(te_file)
 691 AC_SUBST(install_tooldir)
 692 AC_SUBST(atof)
 693 dnl AC_SUBST(emulation)
 694
 695 # do we need the opcodes library?
 696 case "${need_opcodes}" in
 697 yes)
 698   OPCODES_LIB=../opcodes/libopcodes.la
 699   ;;
 700 esac
 701
 702 AC_SUBST(OPCODES_LIB)
 703
 704 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 705 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 706 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 707 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 708 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 709
 710 AC_PROG_YACC
 711 AM_PROG_LEX
 712
 713 ALL_LINGUAS="fr tr es rw id ru fi ja"
 714 ZW_GNU_GETTEXT_SISTER_DIR
 715 AM_PO_SUBDIRS
 716
 717 AM_MAINTAINER_MODE
 718 AM_CONDITIONAL(GENINSRC_NEVER, false)
 719 AC_EXEEXT
 720
 721 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h errno.h sys/types.h limits.h locale.h time.h sys/stat.h)
 722 ACX_HEADER_STRING
 723
 724 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 725 # people who are not cross-compiling but are compiling cross-assemblers.
 726 AC_MSG_CHECKING(whether compiling a cross-assembler)
 727 if test "${host}" = "${target}"; then
 728   cross_gas=no
 729 else
 730   cross_gas=yes
 731   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 732 fi
 733 AC_MSG_RESULT($cross_gas)
 734
 735 dnl ansidecl.h will deal with const
 736 dnl AC_C_CONST
 737 AC_FUNC_ALLOCA
 738 AC_C_INLINE
 739
 740 # VMS doesn't have unlink.
 741 AC_CHECK_FUNCS(unlink remove, break)
 742 AC_CHECK_FUNCS(sbrk setlocale)
 743
 744 AM_LC_MESSAGES
 745
 746 # do we need the math library?
 747 case "${need_libm}" in
 748 yes)
 749   LT_LIB_M
 750   AC_SUBST(LIBM)
 751   ;;
 752 esac
 753
 754 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 755 # enough, but on some of those systems, the assert macro relies on requoting
 756 # working properly!
 757 GAS_WORKING_ASSERT
 758
 759 # On some systems, the system header files may not declare malloc, realloc,
 760 # and free.  There are places where gas needs these functions to have been
 761 # declared -- such as when taking their addresses.
 762 gas_test_headers="
 763 #ifdef HAVE_MEMORY_H
 764 #include <memory.h>
 765 #endif
 766 #ifdef HAVE_STRING_H
 767 #include <string.h>
 768 #else
 769 #ifdef HAVE_STRINGS_H
 770 #include <strings.h>
 771 #endif
 772 #endif
 773 #ifdef HAVE_STDLIB_H
 774 #include <stdlib.h>
 775 #endif
 776 #ifdef HAVE_UNISTD_H
 777 #include <unistd.h>
 778 #endif
 779 "
 780
 781 # Does errno.h declare errno, or do we have to add a separate declaration
 782 # for it?
 783 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 784 #ifdef HAVE_ERRNO_H
 785 #include <errno.h>
 786 #endif
 787 ])
 788
 789 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 790 AC_CACHE_VAL(gas_cv_decl_getopt_unistd_h,
 791 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 792 gas_cv_decl_getopt_unistd_h=yes, gas_cv_decl_getopt_unistd_h=no)])
 793 AC_MSG_RESULT($gas_cv_decl_getopt_unistd_h)
 794 if test $gas_cv_decl_getopt_unistd_h = yes; then
 795   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 796             [Is the prototype for getopt in <unistd.h> in the expected format?])
 797 fi
 798
 799 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 800 GAS_CHECK_DECL_NEEDED(ffs, f, int (*f)(int), $gas_test_headers)
 801 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 802 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 803 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 804 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 805
 806 AC_CHECK_DECLS([free, getenv, malloc, mempcpy, realloc, stpcpy, strstr, vsnprintf])
 807
 808 BFD_BINARY_FOPEN
 809
 810 # Link in zlib if we can.  This allows us to write compressed debug sections.
 811 AM_ZLIB
 812
 813 # Support for VMS timestamps via cross compile
 814
 815 if test "$ac_cv_header_time_h" = yes; then
 816   GAS_HAVE_TIME_TYPE_MEMBER(struct tm, tm_gmtoff)
 817 fi
 818
 819 if test "$ac_cv_header_sys_stat_h" = yes; then
 820     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_sec)
 821     GAS_HAVE_SYS_STAT_TYPE_MEMBER(struct stat, st_mtim, tv_nsec)
 822 fi
 823
 824
 825 dnl Required for html, pdf, install-pdf and install-html targets.
 826 AC_SUBST(datarootdir)
 827 AC_SUBST(docdir)
 828 AC_SUBST(htmldir)
 829 AC_SUBST(pdfdir)
 830
 831 dnl This must come last.
 832
 833 dnl We used to make symlinks to files in the source directory, but now
 834 dnl we just use the right name for .c files, and create .h files in
 835 dnl the build directory which include the right .h file.  Make sure
 836 dnl the old symlinks don't exist, so that a reconfigure in an existing
 837 dnl directory behaves reasonably.
 838
 839 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 840 AC_CONFIG_COMMANDS([default],
 841 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 842  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 843  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 844  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 845  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 846  if test "x$cgen_cpu_prefix" != x ; then
 847    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 848  fi],
 849 [target_cpu_type=${target_cpu_type}
 850  cgen_cpu_prefix=${cgen_cpu_prefix}
 851  obj_format=${obj_format}
 852  te_file=${te_file}])
 853
 854 AC_OUTPUT