gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ISC_POSIX
  13
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17 AM_INIT_AUTOMAKE(gas, ${BFD_VERSION})
  18
  19 AM_PROG_LIBTOOL
  20
  21 user_bfd_gas=
  22 AC_ARG_ENABLE(bfd-assembler,
  23 [  --enable-bfd-assembler  use BFD back end for writing object files],
  24 [case "${enableval}" in
  25   yes) need_bfd=yes user_bfd_gas=yes ;;
  26   no)  user_bfd_gas=no ;;
  27   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(targets,
  30 [    targets            alternative target configurations besides the primary],
  31 [case "${enableval}" in
  32   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  33             ;;
  34   no)       enable_targets= ;;
  35   *)        enable_targets=$enableval ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 using_cgen=no
  46
  47 build_warnings="-W -Wall"
  48 AC_ARG_ENABLE(build-warnings,
  49 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  50 [case "${enableval}" in
  51   yes)  ;;
  52   no)   build_warnings="-w";;
  53   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  54         build_warnings="${build_warnings} ${t}";;
  55   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  56         build_warnings="${t} ${build_warnings}";;
  57   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  58 esac
  59 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  60   echo "Setting warning flags = $build_warnings" 6>&1
  61 fi])dnl
  62 WARN_CFLAGS=""
  63 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  64     WARN_CFLAGS="${build_warnings}"
  65 fi
  66 AC_SUBST(WARN_CFLAGS)
  67
  68 # Generate a header file
  69 AM_CONFIG_HEADER(config.h:config.in)
  70
  71 # If we are on a DOS filesystem, we must use gdb.ini rather than
  72 # .gdbinit.
  73 GDBINIT=".gdbinit"
  74 case "${host}" in
  75   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  76     GDBINIT="gdb.ini"
  77     ;;
  78 esac
  79 AC_SUBST(GDBINIT)
  80
  81 te_file=generic
  82
  83 # Makefile target for installing gas in $(tooldir)/bin.
  84 install_tooldir=install-exec-tooldir
  85
  86 canon_targets=""
  87 all_targets=no
  88 if test -n "$enable_targets" ; then
  89   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  90     if test $t = "all"; then
  91       all_targets=yes
  92       continue
  93     fi
  94     result=`$ac_config_sub $t 2>/dev/null`
  95     if test -n "$result" ; then
  96       canon_targets="$canon_targets $result"
  97 #    else
  98 #      # Permit "all", etc.  We don't support it yet though.
  99 #      canon_targets="$canon_targets $t"
 100     fi
 101   done
 102   GAS_UNIQ(canon_targets)
 103 fi
 104
 105 emulations=""
 106
 107 for this_target in $target $canon_targets ; do
 108
 109 changequote(,)dnl
 110     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
 111 changequote([,])dnl
 112
 113     # check for architecture variants
 114     arch=
 115     endian=
 116     case ${cpu} in
 117       alpha*)           cpu_type=alpha ;;
 118       armeb)            cpu_type=arm endian=big ;;
 119       arm*)             cpu_type=arm endian=little ;;
 120       armb*)            cpu_type=arm endian=little ;;
 121       armv*l)           cpu_type=arm endian=little ;;
 122       armv*b)           cpu_type=arm endian=big ;;
 123       xscale*)          cpu_type=arm endian=little ;;
 124       strongarm*)       cpu_type=arm endian=little ;;
 125       thumb*)           cpu_type=arm endian=little ;;
 126       hppa*)            cpu_type=hppa ;;
 127 changequote(,)dnl
 128       i[3456]86)        cpu_type=i386 arch=i386;;
 129       x86_64)           cpu_type=i386 arch=x86_64;;
 130       ia64)             cpu_type=ia64 ;;
 131       m6811|m6812|m68hc12) cpu_type=m68hc11 ;;
 132       m680[012346]0)    cpu_type=m68k ;;
 133 changequote([,])dnl
 134       m68008)           cpu_type=m68k ;;
 135       m683??)           cpu_type=m68k ;;
 136       m5200)            cpu_type=m68k ;;
 137       m8*)              cpu_type=m88k ;;
 138       mips*el)          cpu_type=mips endian=little ;;
 139       mips*)            cpu_type=mips endian=big ;;
 140       pjl*)             cpu_type=pj endian=little ;;
 141       pj*)              cpu_type=pj endian=big ;;
 142       powerpcle*)       cpu_type=ppc endian=little ;;
 143       powerpc*)         cpu_type=ppc endian=big ;;
 144       rs6000*)          cpu_type=ppc ;;
 145       s390x*)           cpu_type=s390 arch=s390x ;;
 146       s390*)            cpu_type=s390 arch=s390 ;;
 147       sparclite*)       cpu_type=sparc arch=sparclite ;;
 148       sparclet*)        cpu_type=sparc arch=sparclet ;;
 149       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 150       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 151       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 152       v850*)            cpu_type=v850 ;;
 153       *)                cpu_type=${cpu} ;;
 154     esac
 155
 156     if test ${this_target} = $target ; then
 157       target_cpu_type=${cpu_type}
 158     elif test ${target_cpu_type} != ${cpu_type} ; then
 159       continue
 160     fi
 161
 162     generic_target=${cpu_type}-$vendor-$os
 163     dev=no
 164     bfd_gas=no
 165     em=generic
 166
 167     # assign object format
 168     case ${generic_target} in
 169       a29k-*-coff)          fmt=coff ;;
 170       a29k-amd-udi)         fmt=coff ;;
 171       a29k-amd-ebmon)       fmt=coff ;;
 172       a29k-nyu-sym1)        fmt=coff ;;
 173       a29k-*-rtems*)        fmt=coff ;;
 174       a29k-*-vxworks*)      fmt=coff ;;
 175
 176       alpha*-*-*vms*)       fmt=evax ;;
 177       alpha*-*-netware*)    fmt=ecoff ;;
 178       alpha*-*-openbsd*)    fmt=ecoff ;;
 179       alpha*-*-osf*)        fmt=ecoff ;;
 180       alpha*-*-linuxecoff*) fmt=ecoff ;;
 181       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 182       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 183
 184       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 185
 186       arm-*-aout)                       fmt=aout ;;
 187       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 188       arm-*-rtems | thumb-*-rtems)      fmt=elf ;;
 189       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 190       arm*-*-conix*)                    fmt=elf ;;
 191       arm-*-linux*aout*)                fmt=aout em=linux ;;
 192       arm*-*-linux-gnu* | arm*-*-uclinux*)
 193                                         fmt=elf  em=linux ;;
 194       arm-*-netbsd*)                    fmt=aout em=nbsd ;;
 195       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 196       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 197       arm-*-wince)                      fmt=coff em=wince-pe ;;
 198       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 199       arm-*-riscix*)                    fmt=aout em=riscix ;;
 200       arm-*-vxworks)                    fmt=coff ;;
 201
 202       avr-*-*)              fmt=elf bfd_gas=yes ;;
 203
 204       cris-*-*)             fmt=multi bfd_gas=yes ;;
 205
 206       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 207       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 208
 209
 210       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 211
 212       hppa-*-linux-gnu*)    case ${cpu} in
 213                                 hppa*64*)
 214                                         fmt=elf em=hppalinux64;;
 215                                 hppa*)
 216                                         fmt=elf em=linux;;
 217                             esac ;;
 218       hppa-*-*elf*)         fmt=elf em=hppa ;;
 219       hppa-*-lites*)        fmt=elf em=hppa ;;
 220       hppa-*-osf*)          fmt=som em=hppa ;;
 221       hppa-*-rtems*)        fmt=elf em=hppa ;;
 222       hppa-*-hpux11*)       case ${cpu} in
 223                                 hppa*64*)
 224                                         fmt=elf em=hppa64 ;;
 225                                 hppa*)
 226                                         fmt=som em=hppa ;;
 227                             esac ;;
 228       hppa-*-hpux*)         fmt=som em=hppa ;;
 229       hppa-*-mpeix*)        fmt=som em=hppa ;;
 230       hppa-*-bsd*)          fmt=som em=hppa ;;
 231       hppa-*-hiux*)         fmt=som em=hppa ;;
 232
 233       h8300-*-rtems*)       fmt=coff ;;
 234       h8300-*-coff)         fmt=coff ;;
 235       h8500-*-rtems*)       fmt=coff ;;
 236       h8500-*-coff)         fmt=coff ;;
 237
 238       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 239       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 240       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 241       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 242       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 243       i386-*-bsd*)          fmt=aout em=386bsd ;;
 244       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 245       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 246       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 247       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 248       i386-*-linux*coff*)   fmt=coff em=linux ;;
 249       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 250       x86_64-*-linux-gnu*)  fmt=elf em=linux bfd_gas=yes ;;
 251       i386-*-lynxos*)       fmt=coff em=lynx ;;
 252 changequote(,)dnl
 253       i386-*-sysv[45]* | i386-*-solaris* | i386-*-elf)
 254                             fmt=elf bfd_gas=yes ;;
 255       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 256                             fmt=aout em=386bsd ;;
 257 changequote([,])dnl
 258       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 259                           fmt=coff ;;
 260       i386-*-sco3.2v5*)      fmt=elf
 261                             if test ${this_target} = $target; then
 262                                 AC_DEFINE(SCO_ELF, 1,
 263                                     [Define if defaulting to ELF on SCO 5.])
 264                             fi
 265                             ;;
 266       i386-*-sco3.2*)       fmt=coff ;;
 267       i386-*-vsta)          fmt=aout ;;
 268       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 269                             fmt=coff em=go32 bfd_gas=yes
 270                             AC_DEFINE(STRICTCOFF, 1, [Using strict COFF?])
 271                             ;;
 272       i386-*-rtemself*)     fmt=elf ;;
 273       i386-*-rtems*)        fmt=coff ;;
 274       i386-*-gnu*)          fmt=elf ;;
 275       i386-*-mach*)
 276                             fmt=aout em=mach bfd_gas=yes ;;
 277       i386-*-msdos*)        fmt=aout ;;
 278       i386-*-moss*)         fmt=elf ;;
 279       i386-*-pe)            fmt=coff em=pe bfd_gas=yes ;;
 280       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 281       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 282       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 283       i386-*-*nt*)          fmt=coff em=pe bfd_gas=yes ;;
 284       i386-*-vxworks*)      fmt=aout ;;
 285       i386-*-chaos)         fmt=elf ;;
 286       i860-stardent-sysv4* | i860-stardent-elf*)
 287                             fmt=elf bfd_gas=yes endian=little
 288                             AC_MSG_WARN(GAS support for ${generic_target} is preliminary and a work in progress) ;;
 289       i960-*-bout)          fmt=bout ;;
 290       i960-*-coff)          fmt=coff em=ic960 ;;
 291       i960-*-rtems*)        fmt=coff em=ic960 ;;
 292       i960-*-nindy*)        fmt=bout ;;
 293       i960-*-vxworks4*)     fmt=bout ;;
 294       i960-*-vxworks5.0)    fmt=bout ;;
 295       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 296       i960-*-vxworks*)      fmt=bout ;;
 297       i960-*-elf*)          fmt=elf ;;
 298
 299       ia64-*-elf*)          fmt=elf ;;
 300       ia64-*-aix*)          fmt=elf em=ia64aix ;;
 301       ia64-*-linux-gnu*)    fmt=elf em=linux ;;
 302       ia64-*-hpux*)         fmt=elf em=hpux ;;
 303
 304       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 305
 306       m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)fmt=elf bfd_gas=yes ;;
 307
 308       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 309                             fmt=aout em=sun3 ;;
 310       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 311       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 312       m68k-apollo-*)        fmt=coff em=apollo ;;
 313       m68k-*-sysv4*) # must be before -sysv*
 314                             fmt=elf em=svr4 ;;
 315       m68k-*-elf*)          fmt=elf ;;
 316       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 317                             fmt=coff ;;
 318       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 319       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 320       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 321       m68k-*-gnu*)          fmt=elf ;;
 322       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 323       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 324       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 325       m68k-apple-aux*)      fmt=coff em=aux ;;
 326       m68k-*-psos*)         fmt=elf em=psos;;
 327
 328       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 329       m88k-*-coff*)         fmt=coff ;;
 330
 331       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 332       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 333
 334       # don't change em like *-*-bsd does
 335       mips-dec-netbsd*)     fmt=elf endian=little ;;
 336       mips-dec-openbsd*)    fmt=elf endian=little ;;
 337       mips-dec-bsd*)        fmt=aout endian=little ;;
 338       mips-sony-bsd*)       fmt=ecoff ;;
 339       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 340       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 341       mips-*-osf*)          fmt=ecoff endian=little ;;
 342       mips-*-ecoff*)        fmt=ecoff ;;
 343       mips-*-ecoff*)        fmt=ecoff ;;
 344       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 345       mips-*-irix6*)        fmt=elf ;;
 346       mips-*-irix5*)        fmt=elf ;;
 347       mips-*-irix*)         fmt=ecoff ;;
 348       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 349       mips-*-riscos*)       fmt=ecoff ;;
 350       mips-*-sysv4*MP* | mips-*-linux-gnu* | mips-*-gnu*)
 351                             fmt=elf em=tmips ;;
 352       mips-*-sysv*)         fmt=ecoff ;;
 353       mips-*-elf* | mips-*-rtems* | mips-*-openbsd*)
 354                             fmt=elf ;;
 355       mips-*-vxworks*)      fmt=elf
 356                             AC_DEFINE(MIPS_STABS_ELF, 1,
 357                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 358                             ;;
 359       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 360       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 361       openrisc-*-*)         fmt=elf bfd_gas=yes ;;
 362       pj*)                  fmt=elf ;;
 363       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 364                             fmt=coff em=pe ;;
 365       ppc-*-aix*)           fmt=coff ;;
 366       ppc-*-beos*)          fmt=coff ;;
 367       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 368                             fmt=elf ;;
 369       ppc-*-linux-gnu*)     fmt=elf
 370                             case "$endian" in
 371                             big)  ;;
 372                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 373                             esac
 374                             ;;
 375       ppc-*-solaris*)       fmt=elf
 376                             if test ${this_target} = $target; then
 377                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 378                                 [Define if default target is PowerPC Solaris.])
 379                             fi
 380                             if test x${endian} = xbig; then
 381                                 AC_MSG_ERROR(Solaris must be configured little endian)
 382                             fi
 383                             ;;
 384       ppc-*-rtems*)         fmt=elf ;;
 385       ppc-*-macos* | ppc-*-mpw*)
 386                             fmt=coff em=macos ;;
 387       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 388       ppc-*-vxworks*)       fmt=elf ;;
 389
 390       s390x-*-linux-gnu*)   fmt=elf em=linux ;;
 391       s390-*-linux-gnu*)    fmt=elf em=linux ;;
 392
 393       sh-*-linux*)          fmt=elf em=linux ;;
 394       sh-*-elf*)            fmt=elf ;;
 395       sh-*-coff*)           fmt=coff bfd_gas=yes;;
 396       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes;;
 397       sh-*-rtemself*)       fmt=elf ;;
 398       sh-*-rtems*)          fmt=coff bfd_gas=yes;;
 399
 400       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 401       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 402       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 403
 404       sparc-*-rtemsaout*)   fmt=aout ;;
 405       sparc-*-rtemself*)    fmt=elf ;;
 406       sparc-*-rtems*)       fmt=elf ;;
 407       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 408       sparc-*-aout | sparc*-*-vxworks*)
 409                             fmt=aout em=sparcaout ;;
 410       sparc-*-coff)         fmt=coff ;;
 411       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 412       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 413       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 414       sparc-fujitsu-none)   fmt=aout ;;
 415       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 416                             fmt=elf ;;
 417       sparc-*-netbsd*)      em=nbsd bfd_gas=yes
 418                             case ${cpu} in
 419                                 sparc) case ${os} in
 420                                            *elf*) fmt=elf ;;
 421                                            *)     fmt=aout ;;
 422                                        esac ;;
 423                                 sparc64) fmt=elf ;;
 424                             esac
 425                             ;;
 426       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 427
 428       strongarm-*-coff)     fmt=coff ;;
 429       strongarm-*-elf)      fmt=elf ;;
 430       xscale-*-coff)     fmt=coff ;;
 431       xscale-*-elf)      fmt=elf ;;
 432
 433       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 434       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 435       tic54x-*-* | c54x*-*-*)
 436                             fmt=coff bfd_gas=yes need_libm=yes;;
 437       tic80-*-*)            fmt=coff ;;
 438
 439       v850-*-*)             fmt=elf bfd_gas=yes ;;
 440       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 441       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 442
 443       vax-*-bsd* | vax-*-ultrix*)
 444                             fmt=aout ;;
 445       vax-*-vms)            fmt=vms ;;
 446
 447
 448       z8k-*-coff | z8k-*-sim)
 449                             fmt=coff ;;
 450
 451       w65-*-*)              fmt=coff ;;
 452
 453       *-*-aout | *-*-scout)
 454                             fmt=aout ;;
 455       *-*-freebsd*)         fmt=elf em=freebsd bfd_gas=yes ;;
 456       *-*-nindy*)
 457                             fmt=bout ;;
 458       *-*-bsd*)
 459                             fmt=aout em=sun3 ;;
 460       *-*-generic)          fmt=generic ;;
 461       *-*-xray | *-*-hms)   fmt=coff ;;
 462       *-*-sim)              fmt=coff ;;
 463       *-*-elf | *-*-sysv4* | *-*-solaris*)
 464                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 465                             fmt=elf dev=yes ;;
 466       *-*-vxworks)          fmt=aout ;;
 467       *-*-netware)          fmt=elf ;;
 468     esac
 469
 470     if test ${this_target} = $target ; then
 471       endian_def=
 472       if test x${endian} = xbig; then
 473         endian_def=1
 474       elif test x${endian} = xlittle; then
 475         endian_def=0
 476       fi
 477       if test x${endian_def} != x; then
 478         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 479                            [Define as 1 if big endian.])
 480       fi
 481     fi
 482
 483     case ${cpu_type}-${fmt} in
 484       alpha*-*) bfd_gas=yes ;;
 485       arm-*)    bfd_gas=yes ;;
 486     # not yet
 487     # i386-aout)        bfd_gas=preferred ;;
 488       ia64*-*)  bfd_gas=yes ;;
 489       mips-*)   bfd_gas=yes ;;
 490       ns32k-*)  bfd_gas=yes ;;
 491       pdp11-*)  bfd_gas=yes ;;
 492       ppc-*)    bfd_gas=yes ;;
 493       sparc-*)  bfd_gas=yes ;;
 494       strongarm-*)      bfd_gas=yes ;;
 495       xscale-*) bfd_gas=yes ;;
 496       *-elf)    bfd_gas=yes ;;
 497       *-ecoff)  bfd_gas=yes ;;
 498       *-som)    bfd_gas=yes ;;
 499     #enable bfd for coff and aout to allow testing if a bfd target is
 500     #the primary target, but not for coff or aout as the primary target
 501       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 502       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 503       *)                ;;
 504     esac
 505
 506 # Other random stuff.
 507
 508     # Do we need the opcodes library?
 509     case ${cpu_type} in
 510       vax | i386 | tic30)
 511         ;;
 512
 513       *)
 514         need_opcodes=yes
 515
 516         case "${enable_shared}" in
 517         yes) shared_opcodes=true ;;
 518         *opcodes*) shared_opcodes=true ;;
 519         *) shared_opcodes=false ;;
 520         esac
 521         if test "${shared_opcodes}" = "true"; then
 522           # A shared libopcodes must be linked against libbfd.
 523           need_bfd=yes
 524         fi
 525         ;;
 526     esac
 527
 528     # Any other special object files needed ?
 529     case ${cpu_type} in
 530       fr30 | m32r | openrisc)
 531         using_cgen=yes
 532         ;;
 533
 534       m68k)
 535         case ${extra_objects} in
 536         *m68k-parse.o*) ;;
 537         *) extra_objects="$extra_objects m68k-parse.o" ;;
 538         esac
 539         ;;
 540
 541       s390)
 542        if test $this_target = $target ; then
 543           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 544        fi
 545        ;;
 546
 547       mips)
 548         echo ${extra_objects} | grep -s "itbl-parse.o"
 549         if test $? -ne 0 ; then
 550           extra_objects="$extra_objects itbl-parse.o"
 551         fi
 552
 553         echo ${extra_objects} | grep -s "itbl-lex.o"
 554         if test $? -ne 0 ; then
 555           extra_objects="$extra_objects itbl-lex.o"
 556         fi
 557
 558         echo ${extra_objects} | grep -s "itbl-ops.o"
 559         if test $? -ne 0 ; then
 560           extra_objects="$extra_objects itbl-ops.o"
 561         fi
 562         ;;
 563
 564       i386)
 565         if test $this_target = $target ; then
 566           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 567         fi
 568         ;;
 569       sparc)
 570         if test $this_target = $target ; then
 571           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 572         fi
 573         ;;
 574       *)
 575         ;;
 576     esac
 577
 578     if test $using_cgen = yes ; then
 579         case "x${extra_objects}" in
 580         *cgen.o*) ;;
 581         *) extra_objects="$extra_objects cgen.o" ;;
 582         esac
 583     fi
 584
 585 # See if we really can support this configuration with the emulation code.
 586
 587     if test $this_target = $target ; then
 588       primary_bfd_gas=$bfd_gas
 589       obj_format=$fmt
 590       te_file=$em
 591
 592       if test $bfd_gas = no ; then
 593         # Can't support other configurations this way.
 594         break
 595       fi
 596     elif test $bfd_gas = no ; then
 597       # Can't support this configuration.
 598       break
 599     fi
 600
 601 # From target name and format, produce a list of supported emulations.
 602
 603     case ${generic_target}-${fmt} in
 604       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 605       mips-*-linux-gnu*-*) case "$endian" in
 606                         big)    emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 607                         *)      emulation="mipslelf mipsbelf mipself mipslecoff mipsbecoff mipsecoff" ;;
 608                         esac ;;
 609       mips-*-lnews*-ecoff) ;;
 610       mips-*-*-ecoff)   case "$endian" in
 611                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 612                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 613                         esac ;;
 614       mips-*-*-elf)     case "$endian" in
 615                         big)    emulation="mipsbelf mipslelf mipself" ;;
 616                         *)      emulation="mipslelf mipsbelf mipself" ;;
 617                         esac ;;
 618       mips-*-sysv4*MP*-*) emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 619       # i386-pc-pe-coff != i386-pc-coff.
 620       i386-*-pe-coff)   ;;
 621       # Uncommenting the next line will turn on support for i386 AOUT
 622       # for the default linux configuration
 623       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 624       #
 625       i386-*-aout)      emulation="i386aout" ;;
 626       i386-*-coff)      emulation="i386coff" ;;
 627       i386-*-elf)       emulation="i386elf" ;;
 628
 629       # Always all formats.  The first stated emulation becomes the default.
 630       cris-*-*aout*)    emulation="crisaout criself" ;;
 631       cris-*-*)         emulation="criself crisaout" ;;
 632     esac
 633
 634     emulations="$emulations $emulation"
 635
 636 done
 637
 638 # Turn on all targets if possible
 639 if test ${all_targets} = "yes"; then
 640   case ${target_cpu_type} in
 641   i386)
 642     case ${obj_format} in
 643     aout)
 644       emulations="$emulations i386coff i386elf"
 645       ;;
 646     coff)
 647       emulations="$emulations i386aout i386elf"
 648     ;;
 649     elf)
 650       emulations="$emulations i386aout i386coff"
 651       ;;
 652     esac
 653   ;;
 654   esac
 655 fi
 656
 657 # Assign floating point type.  Most processors with FP support
 658 # IEEE FP.  On those that don't support FP at all, usually IEEE
 659 # is emulated.
 660 case ${target_cpu} in
 661   vax | tahoe ) atof=${target_cpu} ;;
 662   pdp11)        atof=vax ;;
 663   *)            atof=ieee ;;
 664 esac
 665
 666 case "${obj_format}" in
 667   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 668 esac
 669
 670 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 671 cgen_cpu_prefix=""
 672 if test $using_cgen = yes ; then
 673   case ${target_cpu} in
 674     *) cgen_cpu_prefix=${target_cpu} ;;
 675   esac
 676   AC_SUBST(cgen_cpu_prefix)
 677   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 678 fi
 679
 680 dnl
 681 dnl Make sure the desired support files exist.
 682 dnl
 683
 684 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 685   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 686 fi
 687
 688 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 689   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 690 fi
 691
 692 case ${user_bfd_gas}-${primary_bfd_gas} in
 693   yes-yes | no-no)
 694     # We didn't override user's choice.
 695     ;;
 696   no-yes)
 697     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 698     ;;
 699   no-preferred)
 700     primary_bfd_gas=no
 701     ;;
 702   *-preferred)
 703     primary_bfd_gas=yes
 704     ;;
 705   yes-*)
 706     primary_bfd_gas=yes
 707     ;;
 708   -*)
 709     # User specified nothing.
 710     ;;
 711 esac
 712
 713 # Some COFF configurations want these random other flags set.
 714 case ${obj_format} in
 715   coff)
 716     case ${target_cpu_type} in
 717       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 718       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 719       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 720     esac
 721     ;;
 722 esac
 723
 724 # Getting this done right is going to be a bitch.  Each configuration specified
 725 # with --enable-targets=... should be checked for environment, format, cpu, and
 726 # bfd_gas setting.
 727 #
 728 # For each configuration, the necessary object file support code must be linked
 729 # in.  This might be only one, it might be up to four.  The necessary emulation
 730 # code needs to be provided, too.
 731 #
 732 # And then there's "--enable-targets=all"....
 733 #
 734 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 735
 736 formats="${obj_format}"
 737 emfiles=""
 738 EMULATIONS=""
 739 GAS_UNIQ(emulations)
 740 for em in . $emulations ; do
 741   case $em in
 742     .)  continue ;;
 743     mipsbelf | mipslelf | mipself)
 744         fmt=elf   file=mipself ;;
 745     mipsbecoff | mipslecoff | mipsecoff)
 746         fmt=ecoff file=mipsecoff ;;
 747     *coff)
 748         fmt=coff  file=$em ;;
 749     *aout)
 750         fmt=aout file=$em ;;
 751     *elf)
 752         fmt=elf file=$em ;;
 753   esac
 754   formats="$formats $fmt"
 755   emfiles="$emfiles e-$file.o"
 756   EMULATIONS="$EMULATIONS &$em,"
 757 done
 758 GAS_UNIQ(formats)
 759 GAS_UNIQ(emfiles)
 760 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 761   for fmt in $formats ; do
 762     case $fmt in
 763       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 764       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 765       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 766       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 767       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 768       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 769       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 770       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 771       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 772       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 773     esac
 774     extra_objects="$extra_objects obj-$fmt.o"
 775   done
 776   obj_format=multi
 777 fi
 778 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 779   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 780   # e-mips* has more than one emulation per file, e-i386* has just one at the
 781   # moment.  If only one emulation is specified, then don't define
 782   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 783   case "${obj_format}${emfiles}" in
 784     multi* | *mips*)
 785       extra_objects="$extra_objects $emfiles"
 786       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 787   esac
 788 fi
 789 AC_SUBST(extra_objects)
 790 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 791 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 792                    [Default emulation.])
 793
 794 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 795   yes-*-coff)   need_bfd=yes ;;
 796   no-*-coff)    need_bfd=yes
 797                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 798 esac
 799
 800 reject_dev_configs=yes
 801
 802 case ${reject_dev_configs}-${dev} in
 803   yes-yes) # Oops.
 804     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 805     ;;
 806 esac
 807
 808 AC_SUBST(target_cpu_type)
 809 AC_SUBST(obj_format)
 810 AC_SUBST(te_file)
 811 AC_SUBST(install_tooldir)
 812 AC_SUBST(atof)
 813 dnl AC_SUBST(emulation)
 814
 815 case "${primary_bfd_gas}" in
 816   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 817         need_bfd=yes ;;
 818 esac
 819
 820 # do we need the opcodes library?
 821 case "${need_opcodes}" in
 822 yes)
 823   OPCODES_LIB=../opcodes/libopcodes.la
 824   ;;
 825 esac
 826
 827 case "${need_bfd}" in
 828 yes)
 829   BFDLIB=../bfd/libbfd.la
 830   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 831   ;;
 832 esac
 833
 834 AC_SUBST(BFDLIB)
 835 AC_SUBST(OPCODES_LIB)
 836
 837 AC_SUBST(ALL_OBJ_DEPS)
 838
 839 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 840 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 841 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 842 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 843 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 844
 845 AC_PROG_CC
 846
 847 AC_PROG_YACC
 848 AM_PROG_LEX
 849
 850 ALL_LINGUAS=
 851 CY_GNU_GETTEXT
 852
 853 AM_MAINTAINER_MODE
 854 AC_EXEEXT
 855
 856 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 857
 858 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 859 # people who are not cross-compiling but are compiling cross-assemblers.
 860 AC_MSG_CHECKING(whether compiling a cross-assembler)
 861 if test "${host}" = "${target}"; then
 862   cross_gas=no
 863 else
 864   cross_gas=yes
 865   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 866 fi
 867 AC_MSG_RESULT($cross_gas)
 868
 869 dnl ansidecl.h will deal with const
 870 dnl AC_CONST
 871 AC_FUNC_ALLOCA
 872 AC_C_INLINE
 873
 874 # VMS doesn't have unlink.
 875 AC_CHECK_FUNCS(unlink remove, break)
 876
 877 # Some systems don't have sbrk().
 878 AC_CHECK_FUNCS(sbrk)
 879
 880 # do we need the math library?
 881 case "${need_libm}" in
 882 yes)
 883   AC_CHECK_LIBM
 884   AC_SUBST(LIBM)
 885   ;;
 886 esac
 887
 888 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 889 # enough, but on some of those systems, the assert macro relies on requoting
 890 # working properly!
 891 GAS_WORKING_ASSERT
 892
 893 # On some systems, the system header files may not declare malloc, realloc,
 894 # and free.  There are places where gas needs these functions to have been
 895 # declared -- such as when taking their addresses.
 896 gas_test_headers="
 897 #ifdef HAVE_MEMORY_H
 898 #include <memory.h>
 899 #endif
 900 #ifdef HAVE_STRING_H
 901 #include <string.h>
 902 #else
 903 #ifdef HAVE_STRINGS_H
 904 #include <strings.h>
 905 #endif
 906 #endif
 907 #ifdef HAVE_STDLIB_H
 908 #include <stdlib.h>
 909 #endif
 910 #ifdef HAVE_UNISTD_H
 911 #include <unistd.h>
 912 #endif
 913 "
 914 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 915 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 916 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 917 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 918 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 919
 920 # Does errno.h declare errno, or do we have to add a separate declaration
 921 # for it?
 922 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 923 #ifdef HAVE_ERRNO_H
 924 #include <errno.h>
 925 #endif
 926 ])
 927
 928 dnl This must come last.
 929
 930 dnl We used to make symlinks to files in the source directory, but now
 931 dnl we just use the right name for .c files, and create .h files in
 932 dnl the build directory which include the right .h file.  Make sure
 933 dnl the old symlinks don't exist, so that a reconfigure in an existing
 934 dnl directory behaves reasonably.
 935
 936 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 937 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 938  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 939  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 940  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 941  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 942  if test "x$cgen_cpu_prefix" != x ; then
 943    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 944  fi
 945
 946  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 947 [target_cpu_type=${target_cpu_type}
 948  cgen_cpu_prefix=${cgen_cpu_prefix}
 949  obj_format=${obj_format}
 950  te_file=${te_file}])