gas/testsuite/gas/mips/mips.exp

   1 #
   2 # Some generic MIPS tests
   3 #
   4
   5 # When adding a new test to this file, try to do the following things:
   6 #
   7 # * If testing assembly and disassembly of code, don't forget to test
   8 # the actual bit encodings of the instructions (using the
   9 # --show-raw-insn flag to objdump).
  10 #
  11 # * Try to run the test for as many architectures as appropriate,
  12 # using the "run_dump_test_arches" or "run_list_test_arches" functions,
  13 # along with the output from a call to "mips_arch_list_matching."
  14 #
  15 # * Be sure to compare the test output before and after your testsuite
  16 # changes, to verify that existing and new tests were run as expected.
  17 # Look for expect ERROR messages in the testsuite .log file to make sure
  18 # the new expect code did not contain errors.
  19
  20 # To add support for a new CPU to this file, add an appropriate entry
  21 # to the sequence of "mips_arch_create" function calls below, and test
  22 # the result.  The new CPU should automatically be used when running
  23 # various tests.  If the new CPU is the default CPU for any tool
  24 # targets, make sure the call to "mips_arch_create" reflects that fact.
  25
  26
  27 # "LOSE" marks information about tests which fail at a particular point
  28 # in time, but which are not XFAILed.  Either they used to pass
  29 # and indicate either regressions or the need to tweak the tests to keep
  30 # up the with code, or they are new tests and it is unknown whether or not
  31 # they should pass as-is for the given object formats.
  32
  33
  34 # The functions below create and manipulate an "architecture data
  35 # array" which contains entries for each MIPS architecture (or CPU)
  36 # known to these tests.  The array contains the following information
  37 # for each architecture, indexed by the name of the architecture
  38 # described by the entry:
  39 #
  40 # displayname: The name of the entry to be used for pretty-printing.
  41 #
  42 # gprsize: The size in bits of General Purpose Registers provided by
  43 # the architecture (must be 32 or 64).
  44 #
  45 # props: A list of text strings which are associated with the
  46 # architecture.  These include the architecture name as well as
  47 # information about what instructions the CPU supports.  When matching
  48 # based on properties, an additional property is added to the normal
  49 # property list, "gpr<gprsize>" so that tests can match CPUs which
  50 # have GPRs of a specific size.  The following properties are most
  51 # useful when matching properties for generic (i.e., not CPU-specific)
  52 # tests:
  53 #
  54 #       mips1, mips2, mips3, mips4, mips5, mips32, mips64
  55 #               The architecture includes the instructions defined
  56 #               by that MIPS ISA.
  57 #
  58 #       gpr_ilocks
  59 #               The architecture interlocks GPRs accesses.  (That is,
  60 #               there are no load delay slots.)
  61 #
  62 #       mips3d  The architecture includes the MIPS-3D ASE.
  63 #
  64 #       ror     The architecture includes hardware rotate instructions.
  65 #
  66 #       gpr32, gpr64
  67 #               The architecture provides 32- or 64-bit General Purpose
  68 #               Registers.
  69 #
  70 # as_flags: The assembler flags used when assembling tests for this
  71 # architecture.
  72 #
  73 # objdump_flags: The objdump flags used when disassembling tests for
  74 # this architecture.
  75 #
  76 # Most entries in the architecture array will have values in all of
  77 # the fields above.  One entry, "default" represents the default CPU
  78 # based on the target of the assembler being built.  If always has
  79 # empty "as_flags" and "objdump_flags."
  80
  81 # mips_arch_init
  82 #
  83 # This function initializes the architecture data array ("mips_arches")
  84 # to be empty.
  85 proc mips_arch_init {} {
  86     global mips_arches
  87     array unset mips_arches
  88 }
  89
  90 # mips_arch_create ARCH GPRSIZE EXTENDS PROPS AS_FLAGS OBJDUMP_FLAGS \
  91 #                  (optional:) DEFAULT_FOR_TARGETS
  92 #
  93 # This function creates a new entry in the architecture data array,
  94 # for the architecture or CPU named ARCH, and fills in the entry
  95 # according to the rest of the arguments.
  96 #
  97 # The new entry's property list is initialized to contain ARCH, any
  98 # properties specified by PROPS, and the properties associated with
  99 # the entry specified by EXTENDS.  (The new architecture is considered
 100 # to extend the capabilities provided by that architecture.)
 101 #
 102 # If DEFAULT_FOR_TARGETS is specified, it is a list of targets for which
 103 # this architecture is the default architecture.  If "istarget" returns
 104 # true for any of the targets in the list, a "default" entry will be
 105 # added to the architecture array which indicates that ARCH is the default
 106 # architecture.
 107 proc mips_arch_create {arch gprsize extends props as_flags objdump_flags
 108                        {default_for_targets {}}} {
 109     global mips_arches
 110
 111     if { [info exists mips_arches($arch)] } {
 112              error "mips_arch_create: arch \"$arch\" already exists"
 113     }
 114     if { $gprsize != 32 && $gprsize != 64 } {
 115         error "mips_arch_create: invalid GPR size $gprsize"
 116     }
 117
 118     set archdata(displayname) $arch
 119     set archdata(gprsize) $gprsize
 120     set archdata(as_flags) $as_flags
 121     set archdata(objdump_flags) $objdump_flags
 122     set archdata(props) $arch
 123     eval lappend archdata(props) $props
 124     if { [string length $extends] != 0 } {
 125         eval lappend archdata(props) [mips_arch_properties $extends 0]
 126     }
 127
 128     set mips_arches($arch) [array get archdata]
 129
 130     # Set as default if appropriate.
 131     foreach target $default_for_targets {
 132         if { [istarget $target] } {
 133             if { [info exists mips_arches(default)] } {
 134                 error "mips_arch_create: default arch already exists"
 135             }
 136
 137             set archdata(displayname) "default = $arch"
 138             set archdata(as_flags) ""
 139             set archdata(objdump_flags) ""
 140
 141             set mips_arches(default) [array get archdata]
 142             break
 143         }
 144     }
 145 }
 146
 147 # mips_arch_list_all
 148 #
 149 # This function returns the list of all names of entries in the
 150 # architecture data array (including the default entry, if a default
 151 # is known).
 152 proc mips_arch_list_all {} {
 153     global mips_arches
 154     return [lsort -dictionary [array names mips_arches]]
 155 }
 156
 157 # mips_arch_data ARCH
 158 #
 159 # This function returns the information associated with ARCH
 160 # in the architecture data array, in "array get" form.
 161 proc mips_arch_data {arch} {
 162     global mips_arches
 163
 164     if { ! [info exists mips_arches($arch)] } {
 165         error "mips_arch_data: unknown arch \"$arch\""
 166     }
 167     return $mips_arches($arch)
 168 }
 169
 170 # mips_arch_displayname ARCH
 171 #
 172 # This function returns the printable name associated with ARCH in
 173 # the architecture data array.
 174 proc mips_arch_displayname {arch} {
 175     array set archdata [mips_arch_data $arch]
 176     return $archdata(displayname)
 177 }
 178
 179 # mips_arch_properties ARCH (optional:) INCLUDE_GPRSIZE
 180 #
 181 # This function returns the property list associated with ARCH in the
 182 # architecture data array.  If INCLUDE_GPRSIZE is non-zero, an additional
 183 # "gpr32" or "gpr64" property will be returned as part of the list based
 184 # on the architecture's GPR size.
 185 proc mips_arch_properties {arch {include_gprsize 1}} {
 186     array set archdata [mips_arch_data $arch]
 187     set props $archdata(props)
 188     if { $include_gprsize } {
 189         lappend props gpr$archdata(gprsize)
 190     }
 191     return $props
 192 }
 193
 194 # mips_arch_as_flags ARCH
 195 #
 196 # This function returns the assembler flags associated with ARCH in
 197 # the architecture data array.
 198 proc mips_arch_as_flags {arch} {
 199     array set archdata [mips_arch_data $arch]
 200     return $archdata(as_flags)
 201 }
 202
 203 # mips_arch_objdump_flags ARCH
 204 #
 205 # This function returns the objdump disassembly flags associated with
 206 # ARCH in the architecture data array.
 207 proc mips_arch_objdump_flags {arch} {
 208     array set archdata [mips_arch_data $arch]
 209     return $archdata(objdump_flags)
 210 }
 211
 212 # mips_arch_matches ARCH PROPMATCHLIST
 213 #
 214 # This function returns non-zero if ARCH matches the set of properties
 215 # described by PROPMATCHLIST.  Each entry in PROPMATCHLIST can either
 216 # be the name of a property which must be matched, or "!" followed by
 217 # the name of a property which must not be matched.  ARCH matches
 218 # PROPMATCHLIST if and only if all of the conditions specified by
 219 # PROPMATCHLIST are satisfied.
 220 proc mips_arch_matches {arch propmatchlist} {
 221     foreach pm $propmatchlist {
 222         if { [string match {!*} $pm] } {
 223             # fail if present.
 224             set inverted 1
 225             set p [string range $pm 1 end]
 226         } {
 227             # fail if not present.
 228             set inverted 0
 229             set p $pm
 230         }
 231
 232         set loc [lsearch -exact [mips_arch_properties $arch] $p]
 233
 234         # required-absent and found, or required-present and not found: fail.
 235         if { ($inverted && $loc != -1) || (! $inverted && $loc == -1) } {
 236             return 0
 237         }
 238     }
 239     return 1
 240 }
 241
 242 # mips_arch_list_matching ARGS
 243 #
 244 # This function returns a list of all architectures which match
 245 # the conditions described by its arguments.  Its arguments are
 246 # taken as a list and used as the PROPMATCHLIST in a call to
 247 # "mips_arch_matches" for each known architecture.
 248 proc mips_arch_list_matching {args} {
 249     set l ""
 250     foreach arch [mips_arch_list_all] {
 251         # For now, don't match default arch until we know what its
 252         # properties actually are.
 253         if { [string compare $arch default] == 0
 254              && [string length [mips_arch_properties default]] == 0} {
 255             continue;
 256         }
 257         if { [mips_arch_matches $arch $args] } {
 258             lappend l $arch
 259         }
 260     }
 261     return $l
 262 }
 263
 264
 265 # The functions below facilitate running various types of tests.
 266
 267 # run_dump_test_arch NAME ARCH
 268 #
 269 # Invoke "run_dump_test" for test NAME, with extra assembler and
 270 # disassembler flags to test architecture ARCH.
 271 proc run_dump_test_arch { name arch } {
 272     global subdir
 273
 274     if [catch {run_dump_test $name \
 275                              "{name    {([mips_arch_displayname $arch])}}
 276                               {objdump {[mips_arch_objdump_flags $arch]}}
 277                               {as      {[mips_arch_as_flags $arch]}}"} rv] {
 278         perror "$rv"
 279         untested "$subdir/$name ($arch)"
 280     }
 281 }
 282
 283 # run_dump_test_arches NAME ARCH_LIST
 284 #
 285 # Invoke "run_dump_test_arch" for test NAME, for each architecture
 286 # listed in ARCH_LIST.
 287 proc run_dump_test_arches { name arch_list } {
 288     foreach arch $arch_list {
 289         run_dump_test_arch "$name" "$arch"
 290     }
 291 }
 292
 293 # run_list_test NAME OPTS (optional): TESTNAME
 294 #
 295 # Assemble the file "NAME.d" and compare the assembler standard error
 296 # output against the regular expressions given in the file "NAME.l".
 297 # The assembler is passed the flags given in OPTS.  If TESTNAME is
 298 # provided, it will be used as the name of the test.
 299 proc run_list_test { name opts {testname {}} } {
 300     global srcdir subdir
 301     if { [string length $testname] == 0 } then {
 302             set testname "MIPS $name"
 303     }
 304     set file $srcdir/$subdir/$name
 305     gas_run ${name}.s $opts ">&dump.out"
 306     if { [regexp_diff "dump.out" "${file}.l"] } then {
 307         fail $testname
 308         verbose "output is [file_contents "dump.out"]" 2
 309         return
 310     }
 311     pass $testname
 312 }
 313
 314 # run_list_test_arch NAME OPTS ARCH
 315 #
 316 # Invoke "run_list_test" for test NAME with options OPTS, with extra
 317 # assembler flags to test architecture ARCH.
 318 proc run_list_test_arch { name opts arch } {
 319     global subdir
 320
 321     set testname "MIPS $name ([mips_arch_displayname $arch])"
 322     if [catch {run_list_test "$name" "$opts [mips_arch_as_flags $arch]" \
 323                              "$testname"} rv] {
 324         perror "$rv"
 325         untested "$testname"
 326     }
 327 }
 328
 329 # run_list_test_arches NAME OPTS ARCH_LIST
 330 #
 331 # Invoke "run_list_test_arch" for test NAME with options OPTS, for each
 332 # architecture listed in ARCH_LIST.
 333 proc run_list_test_arches { name opts arch_list } {
 334     foreach arch $arch_list {
 335         run_list_test_arch "$name" "$opts" "$arch"
 336     }
 337 }
 338
 339
 340 # Create the architecture data array by providing data for all
 341 # known architectures.
 342 #
 343 # Note that several targets pick default CPU based on ABI.  We
 344 # can't easily handle that; do NOT list those targets as defaulting
 345 # to any architecture.
 346 mips_arch_init
 347 mips_arch_create mips1  32      {}      {} \
 348                         { -march=mips1 -mtune=mips1 } { -mmips:3000 }
 349 mips_arch_create mips2  32      mips1   { gpr_ilocks } \
 350                         { -march=mips2 -mtune=mips2 } { -mmips:6000 }
 351 mips_arch_create mips3  64      mips2   {} \
 352                         { -march=mips3 -mtune=mips3 } { -mmips:4000 }
 353 mips_arch_create mips4  64      mips3   {} \
 354                         { -march=mips4 -mtune=mips4 } { -mmips:8000 }
 355 mips_arch_create mips5  64      mips4   {} \
 356                         { -march=mips5 -mtune=mips5 } { -mmips:mips5 }
 357 mips_arch_create mips32 32      mips2   {} \
 358                         { -march=mips32 -mtune=mips32 } { -mmips:isa32 } \
 359                         { mipsisa32-*-* mipsisa32el-*-* }
 360 mips_arch_create mips32r2 32    mips32  { ror } \
 361                         { -march=mips32r2 -mtune=mips32r2 } \
 362                         { -mmips:isa32r2 } \
 363                         { mipsisa32r2-*-* mipsisa32r2el-*-* }
 364 mips_arch_create mips64 64      mips5   { mips32 } \
 365                         { -march=mips64 -mtune=mips64 } { -mmips:isa64 } \
 366                         { mipsisa64-*-* mipsisa64el-*-* }
 367 mips_arch_create r3000  32      mips1   {} \
 368                         { -march=r3000 -mtune=r3000 } { -mmips:3000 }
 369 mips_arch_create r3900  32      mips1   { gpr_ilocks } \
 370                         { -march=r3900 -mtune=r3900 } { -mmips:3900 } \
 371                         { mipstx39-*-* mipstx39el-*-* }
 372 mips_arch_create r4000  64      mips3   {} \
 373                         { -march=r4000 -mtune=r4000 } { -mmips:4000 }
 374 mips_arch_create vr5400 64      mips4   { ror } \
 375                         { -march=vr5400 -mtune=vr5400 } { -mmips:5400 }
 376 mips_arch_create sb1    64      mips64  { mips3d } \
 377                         { -march=sb1 -mtune=sb1 } { -mmips:sb1 } \
 378                         { mipsisa64sb1-*-* mipsisa64sb1el-*-* }
 379
 380
 381 #
 382 # And now begin the actual tests!
 383 #
 384
 385 if { [istarget mips*-*-*] } then {
 386     set no_mips16 0
 387     set elf [expr [istarget *-*-elf*] || [istarget *-*-irix5*] || [istarget *-*-irix6* ] || [istarget *-*-linux*] || [istarget *-*-netbsd*] ]
 388     set ecoff [expr [istarget *-*-ecoff*] || [istarget *-*-ultrix*] || [istarget *-*-irix\[1-4\]*] ]
 389     set aout [expr [istarget *-*-bsd*] || [istarget *-*-openbsd*] ]
 390     set ilocks [istarget mipstx39*-*-*]
 391     set gpr_ilocks [expr [istarget mipstx39*-*-*]]
 392     set addr32 [expr [istarget mipstx39*-*-*]]
 393     set has_newabi [expr [istarget *-*-irix6*] || [istarget mips64*-*-linux*]]
 394
 395     if { [istarget "mips*-*-*linux*"] } then {
 396         set tmips "t"
 397     } else {
 398         set tmips ""
 399     }
 400     if [istarget mips*el-*-*] {
 401         set el el
 402     } {
 403         set el ""
 404     }
 405
 406     run_dump_test_arches "abs"          [mips_arch_list_matching mips1]
 407     run_dump_test_arches "add"          [mips_arch_list_matching mips1]
 408     run_dump_test_arches "and"          [mips_arch_list_matching mips1]
 409     run_dump_test "break20"
 410     run_dump_test "trap20"
 411
 412     # LOSE: As of 2002-02-08, "beq" through "bltu" fail for target mips-ecoff.
 413     # See http://sources.redhat.com/ml/binutils/2001-10/msg00418.html for
 414     # more information.  Not sure if the fixes there are correct; should
 415     # branches to external labels be allowed for ECOFF?
 416     # XXX FIXME: the following tests require -mips2 disasm for
 417     # branch-likely instructions.  They should be split.
 418     run_dump_test_arches "beq"          [mips_arch_list_matching mips2]
 419     run_dump_test_arches "bge"          [mips_arch_list_matching mips2]
 420     run_dump_test_arches "bgeu"         [mips_arch_list_matching mips2]
 421     run_dump_test_arches "blt"          [mips_arch_list_matching mips2]
 422     run_dump_test_arches "bltu"         [mips_arch_list_matching mips2]
 423     run_dump_test_arches "branch-misc-1" [mips_arch_list_matching mips1]
 424     run_list_test_arches "branch-misc-2" "" [mips_arch_list_matching mips1]
 425
 426     if $ilocks {
 427         run_dump_test "div-ilocks"
 428     } else {
 429         run_dump_test "div"
 430     }
 431     run_dump_test_arches "dli"          [mips_arch_list_matching mips3]
 432     if $elf {
 433         run_dump_test_arches "elf-jal"  [mips_arch_list_matching mips1]
 434     } else {
 435         run_dump_test "jal"
 436     }
 437     if $elf { run_dump_test "jal-svr4pic" }
 438     if $elf { run_dump_test "jal-xgot" }
 439     # LOSE: As of 2002-02-08, the jal-empic test fails for target mips-ecoff.
 440     # It appears that it broke between 2000-03-11 00:00UTC and
 441     # 2000-03-12 00:00 UTC.
 442     if $ecoff { run_dump_test "jal-empic" }
 443     if $elf {
 444         run_dump_test_arches "jal-empic-elf" [mips_arch_list_matching mips1]
 445         run_dump_test_arches "jal-empic-elf-2" [mips_arch_list_matching mips1]
 446         run_dump_test_arches "jal-empic-elf-3" [mips_arch_list_matching mips1]
 447     }
 448     run_list_test_arches "jal-range" "" [mips_arch_list_matching mips1]
 449     if !$aout { run_dump_test "la" }
 450     if $elf { run_dump_test "la-svr4pic" }
 451     if $elf { run_dump_test "la-xgot" }
 452     # LOSE: As of 2002-02-08, the la-empic test fails for target mips-ecoff.
 453     # Not sure when it first cropped up, but may be related to addition of
 454     # "la" -> "addiu" pattern in MIPS opcode table long ago.
 455     if $ecoff { run_dump_test "la-empic" }
 456     if !$aout {
 457         # XXX FIXME: Has mips2 and later insns with mips1 disassemblies.
 458         # (Should split and then use appropriate arch lists.)
 459         run_dump_test_arches "lb"       [mips_arch_list_matching !mips2]
 460     }
 461     if $elf {
 462         run_dump_test_arches "lb-svr4pic" [mips_arch_list_matching mips1]
 463     }
 464     if $elf {
 465         # Both versions specify the cpu, so we can run both regardless of
 466         # the interlocking in the configured default cpu.
 467         run_dump_test "lb-xgot"
 468         run_dump_test "lb-xgot-ilocks"
 469     }
 470     if $ecoff { run_dump_test "lb-empic" }
 471     if !$aout {
 472         if !$gpr_ilocks {
 473             run_dump_test "ld"
 474         } else {
 475             if !$addr32 {
 476                 run_dump_test "ld-ilocks"
 477             } else {
 478                 run_dump_test "ld-ilocks-addr32"
 479             }
 480         }
 481     }
 482     if $elf { run_dump_test "ld-svr4pic" }
 483     if $elf { run_dump_test "ld-xgot" }
 484     if $ecoff { run_dump_test "ld-empic" }
 485     run_dump_test_arches "li"           [mips_arch_list_matching mips1]
 486     if !$aout { run_dump_test "lifloat" }
 487     if $elf { run_dump_test "lif-svr4pic" }
 488     if $elf { run_dump_test "lif-xgot" }
 489     # LOSE: As of 2002-02-08, the lif-empic test fails for target mips-ecoff.
 490     # It appears that it broke between 2000-03-11 00:00UTC and
 491     # 2000-03-12 00:00 UTC.
 492     if $ecoff { run_dump_test "lif-empic" }
 493     run_dump_test_arches "mips4"        [mips_arch_list_matching mips4]
 494     run_dump_test_arches "mips5"        [mips_arch_list_matching mips5]
 495     if $ilocks {
 496         run_dump_test "mul-ilocks"
 497     } else {
 498         run_dump_test "mul"
 499     }
 500
 501     run_dump_test_arches "rol"          [mips_arch_list_matching !ror]
 502     run_dump_test_arches "rol-hw"       [mips_arch_list_matching ror]
 503
 504     run_dump_test_arches "rol64"        [mips_arch_list_matching gpr64 !ror]
 505     run_dump_test_arches "rol64-hw"     [mips_arch_list_matching gpr64 ror]
 506
 507     if !$aout { run_dump_test "sb" }
 508     run_dump_test "trunc"
 509     if !$aout { run_dump_test "ulh" }
 510     run_dump_test_arches "ulh2-eb"      [mips_arch_list_matching mips1]
 511     run_dump_test_arches "ulh2-el"      [mips_arch_list_matching mips1]
 512     if $elf { run_dump_test "ulh-svr4pic" }
 513     if $elf { run_dump_test "ulh-xgot" }
 514     if $ecoff { run_dump_test "ulh-empic" }
 515     if !$aout {
 516         run_dump_test "ulw"
 517         run_dump_test "uld"
 518         run_dump_test "ush"
 519         run_dump_test "usw"
 520         run_dump_test "usd"
 521     }
 522     run_dump_test_arches "ulw2-eb"      [mips_arch_list_matching !gpr_ilocks]
 523     run_dump_test_arches "ulw2-eb-ilocks" [mips_arch_list_matching gpr_ilocks]
 524     run_dump_test_arches "ulw2-el"      [mips_arch_list_matching !gpr_ilocks]
 525     run_dump_test_arches "ulw2-el-ilocks" [mips_arch_list_matching gpr_ilocks]
 526
 527     run_dump_test_arches "uld2-eb" [mips_arch_list_matching mips3]
 528     run_dump_test_arches "uld2-el" [mips_arch_list_matching mips3]
 529
 530     # The mips16 test can only be run on ELF, because only ELF
 531     # supports the necessary mips16 reloc.
 532     if { $elf && !$no_mips16 } {
 533         run_dump_test "mips16"
 534         # Check jalx handling
 535         run_dump_test "mips16-jalx"
 536         run_dump_test "mips-jalx"
 537     }
 538     run_list_test "mips-no-jalx" ""
 539     run_dump_test "delay"
 540     run_dump_test "nodelay"
 541     run_dump_test "mips4010"
 542     run_dump_test "mips4650"
 543     run_dump_test "mips4100"
 544     run_dump_test "vr4111"
 545     run_dump_test "vr4120"
 546     run_dump_test "vr4122"
 547     run_dump_test "vr5400"
 548     run_dump_test "vr5500"
 549     run_dump_test "perfcount"
 550     run_dump_test "lineno"
 551     run_dump_test "sync"
 552
 553     run_dump_test_arches "mips32"       [mips_arch_list_matching mips32]
 554
 555     run_dump_test_arches "mips32r2"     [mips_arch_list_matching mips32r2]
 556     run_list_test_arches "mips32r2-ill" "" [mips_arch_list_matching mips32r2]
 557
 558     run_dump_test_arches "mips64"       [mips_arch_list_matching mips64]
 559
 560     run_dump_test "mips64-mips3d"
 561     run_dump_test_arches "mips64-mips3d-incl" [mips_arch_list_matching mips3d]
 562
 563     run_dump_test "mips64-mdmx"
 564     run_dump_test "sb1-ext-mdmx"
 565     run_dump_test "sb1-ext-ps"
 566
 567     run_dump_test "relax"
 568
 569     run_list_test "illegal" ""
 570     run_list_test "baddata1" ""
 571
 572     # LOSE: As of 2002-02-08, the next 4 tests fail for target mips-ecoff.
 573     # It's unknown whether they _should_ pass as-is, or whether different
 574     # variants are needed for ELF and ECOFF.
 575     run_dump_test "mips-gp32-fp32"
 576     run_dump_test "mips-gp32-fp64"
 577     run_dump_test "mips-gp64-fp32"
 578     run_dump_test "mips-gp64-fp64"
 579
 580     if $elf {
 581         # Make sure that -mcpu=FOO and -mFOO are equivalent.  Assemble a file
 582         # containing 4650-specific instructions with -m4650 and -mcpu=4650,
 583         # and verify that they're the same.  Specifically, we're checking
 584         # that the EF_MIPS_MACH field is set, and that the 4650 'mul'
 585         # instruction does get used.  In previous versions of GAS,
 586         # only -mcpu=4650 would set the EF_MIPS_MACH field; -m4650 wouldn't.
 587         run_dump_test "elf_e_flags1"
 588         run_dump_test "elf_e_flags2"
 589         run_dump_test "elf_e_flags3"
 590         run_dump_test "elf_e_flags4"
 591
 592         # Check EF_MIPS_ARCH markings for each supported architecture.
 593         run_dump_test "elf_arch_mips1"
 594         run_dump_test "elf_arch_mips2"
 595         run_dump_test "elf_arch_mips3"
 596         run_dump_test "elf_arch_mips4"
 597         run_dump_test "elf_arch_mips5"
 598         run_dump_test "elf_arch_mips32"
 599         run_dump_test "elf_arch_mips32r2"
 600         run_dump_test "elf_arch_mips64"
 601
 602         # Verify that ASE markings are handled properly.
 603         if { !$no_mips16 } { run_dump_test "elf_ase_mips16" }
 604
 605         run_dump_test "mips-gp32-fp32-pic"
 606         run_dump_test "mips-gp32-fp64-pic"
 607         run_dump_test "mips-gp64-fp32-pic"
 608         run_dump_test "mips-gp64-fp64-pic"
 609
 610         run_dump_test "mips-abi32"
 611         run_dump_test "mips-abi32-pic"
 612         run_dump_test "mips-abi32-pic2"
 613
 614         run_dump_test "elf${el}-rel"
 615         if {[istarget mips64*-*-*] || [istarget mipsisa32*-*-*]
 616             || [istarget mipsisa64*-*-*]} {
 617             run_dump_test "elf${el}-rel2"
 618         } else {
 619             run_dump_test "e32${el}-rel2"
 620         }
 621         run_dump_test "elf${el}-rel3"
 622         if {[istarget mips64*-*-*]} {
 623             run_dump_test "elf-rel4"
 624         } else {
 625             run_dump_test "e32-rel4"
 626         }
 627         run_dump_test "elf-rel5"
 628         run_dump_test "elf-rel6"
 629         run_dump_test "elf-rel7"
 630         run_dump_test "elf-rel8"
 631         run_dump_test "elf-rel9"
 632         if $has_newabi {
 633             run_dump_test "elf-rel10"
 634             run_dump_test "elf-rel11"
 635         }
 636         run_dump_test "elf-rel12"
 637         run_dump_test "elf-rel13"
 638         run_dump_test "elf-rel14"
 639
 640         if $has_newabi {
 641             run_dump_test "elf-rel-got-n32"
 642             run_dump_test "elf-rel-xgot-n32"
 643             run_dump_test "elf-rel-got-n64"
 644             run_dump_test "elf-rel-xgot-n64"
 645         }
 646
 647         run_dump_test "${tmips}${el}empic"
 648         run_dump_test "empic2"
 649         run_dump_test "empic3_e"
 650         run_dump_test "empic3_g1"
 651         run_dump_test "empic3_g2"
 652         if { !$no_mips16 } {
 653             run_dump_test "${tmips}mips${el}16-e"
 654             run_dump_test "${tmips}mips${el}16-f"
 655         }
 656         run_dump_test "elf-consthilo"
 657         run_dump_test "expr1"
 658     }
 659
 660     if $has_newabi {
 661         run_dump_test "n32-consec"
 662     }
 663
 664     # tests of objdump's ability to disassemble using different
 665     # register names.
 666     run_dump_test "gpr-names-numeric"
 667     run_dump_test "gpr-names-32"
 668     run_dump_test "gpr-names-n32"
 669     run_dump_test "gpr-names-64"
 670
 671     run_dump_test "fpr-names-numeric"
 672     run_dump_test "fpr-names-32"
 673     run_dump_test "fpr-names-n32"
 674     run_dump_test "fpr-names-64"
 675
 676     run_dump_test "cp0-names-numeric"
 677     run_dump_test "cp0-names-mips32"
 678     run_dump_test "cp0-names-mips32r2"
 679     run_dump_test "cp0-names-mips64"
 680     run_dump_test "cp0-names-sb1"
 681
 682     run_dump_test "cp0sel-names-numeric"
 683     run_dump_test "cp0sel-names-mips32"
 684     run_dump_test "cp0sel-names-mips32r2"
 685     run_dump_test "cp0sel-names-mips64"
 686     run_dump_test "cp0sel-names-sb1"
 687
 688     run_dump_test "hwr-names-numeric"
 689     run_dump_test "hwr-names-mips32r2"
 690 }