gdb/acinclude.m4

   1 dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support
   2 dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov>
   3
   4 # Keep these includes in sync with the aclocal_m4_deps list in
   5 # Makefile.in.
   6
   7 sinclude(acx_configure_dir.m4)
   8
   9 # This gets GDB_AC_LIBMCHECK.
  10 sinclude(libmcheck.m4)
  11
  12 # This gets GDB_AC_TRANSFORM.
  13 sinclude(transform.m4)
  14
  15 dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition.
  16 sinclude(../bfd/bfd.m4)
  17
  18 dnl This gets the standard macros.
  19 sinclude(../config/acinclude.m4)
  20
  21 dnl This gets AC_PLUGINS, needed by ACX_LARGEFILE.
  22 sinclude(../config/plugins.m4)
  23
  24 dnl For ACX_LARGEFILE.
  25 sinclude(../config/largefile.m4)
  26
  27 dnl For AM_SET_LEADING_DOT.
  28 sinclude(../config/lead-dot.m4)
  29
  30 dnl This gets autoconf bugfixes.
  31 sinclude(../config/override.m4)
  32
  33 dnl For ZW_GNU_GETTEXT_SISTER_DIR.
  34 sinclude(../config/gettext-sister.m4)
  35
  36 dnl For AC_LIB_HAVE_LINKFLAGS.
  37 sinclude(../config/lib-ld.m4)
  38 sinclude(../config/lib-prefix.m4)
  39 sinclude(../config/lib-link.m4)
  40
  41 dnl For ACX_PKGVERSION and ACX_BUGURL.
  42 sinclude(../config/acx.m4)
  43
  44 dnl for TCL definitions
  45 sinclude(../config/tcl.m4)
  46
  47 dnl For dependency tracking macros.
  48 sinclude([../config/depstand.m4])
  49
  50 dnl For AM_LC_MESSAGES
  51 sinclude([../config/lcmessage.m4])
  52
  53 dnl For AM_LANGINFO_CODESET.
  54 sinclude([../config/codeset.m4])
  55
  56 sinclude([../config/zlib.m4])
  57
  58 m4_include([common/common.m4])
  59
  60 ## ----------------------------------------- ##
  61 ## ANSIfy the C compiler whenever possible.  ##
  62 ## From Franc,ois Pinard                     ##
  63 ## ----------------------------------------- ##
  64
  65 # Copyright (C) 1996-2015 Free Software Foundation, Inc.
  66
  67 # This program is free software; you can redistribute it and/or modify
  68 # it under the terms of the GNU General Public License as published by
  69 # the Free Software Foundation; either version 2, or (at your option)
  70 # any later version.
  71
  72 # This program is distributed in the hope that it will be useful,
  73 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  74 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  75 # GNU General Public License for more details.
  76
  77 # You should have received a copy of the GNU General Public License
  78 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  79
  80 # serial 1
  81
  82 # @defmac AC_PROG_CC_STDC
  83 # @maindex PROG_CC_STDC
  84 # @ovindex CC
  85 # If the C compiler in not in ANSI C mode by default, try to add an option
  86 # to output variable @code{CC} to make it so.  This macro tries various
  87 # options that select ANSI C on some system or another.  It considers the
  88 # compiler to be in ANSI C mode if it handles function prototypes correctly.
  89 #
  90 # If you use this macro, you should check after calling it whether the C
  91 # compiler has been set to accept ANSI C; if not, the shell variable
  92 # @code{am_cv_prog_cc_stdc} is set to @samp{no}.  If you wrote your source
  93 # code in ANSI C, you can make an un-ANSIfied copy of it by using the
  94 # program @code{ansi2knr}, which comes with Ghostscript.
  95 # @end defmac
  96
  97 AC_DEFUN([AM_PROG_CC_STDC],
  98 [AC_REQUIRE([AC_PROG_CC])
  99 AC_BEFORE([$0], [AC_C_INLINE])
 100 AC_BEFORE([$0], [AC_C_CONST])
 101 dnl Force this before AC_PROG_CPP.  Some cpp's, eg on HPUX, require
 102 dnl a magic option to avoid problems with ANSI preprocessor commands
 103 dnl like #elif.
 104 dnl FIXME: can't do this because then AC_AIX won't work due to a
 105 dnl circular dependency.
 106 dnl AC_BEFORE([$0], [AC_PROG_CPP])
 107 AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C])
 108 AC_CACHE_VAL(am_cv_prog_cc_stdc,
 109 [am_cv_prog_cc_stdc=no
 110 ac_save_CC="$CC"
 111 # Don't try gcc -ansi; that turns off useful extensions and
 112 # breaks some systems' header files.
 113 # AIX                   -qlanglvl=ansi
 114 # Ultrix and OSF/1      -std1
 115 # HP-UX 10.20 and later -Ae
 116 # HP-UX older versions  -Aa -D_HPUX_SOURCE
 117 # SVR4                  -Xc -D__EXTENSIONS__
 118 for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__"
 119 do
 120   CC="$ac_save_CC $ac_arg"
 121   AC_TRY_COMPILE(
 122 [#include <stdarg.h>
 123 #include <stdio.h>
 124 #include <sys/types.h>
 125 #include <sys/stat.h>
 126 /* Most of the following tests are stolen from RCS 5.7's src/conf.sh.  */
 127 struct buf { int x; };
 128 FILE * (*rcsopen) (struct buf *, struct stat *, int);
 129 static char *e (p, i)
 130      char **p;
 131      int i;
 132 {
 133   return p[i];
 134 }
 135 static char *f (char * (*g) (char **, int), char **p, ...)
 136 {
 137   char *s;
 138   va_list v;
 139   va_start (v,p);
 140   s = g (p, va_arg (v,int));
 141   va_end (v);
 142   return s;
 143 }
 144 int test (int i, double x);
 145 struct s1 {int (*f) (int a);};
 146 struct s2 {int (*f) (double a);};
 147 int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int);
 148 int argc;
 149 char **argv;
 150 ], [
 151 return f (e, argv, 0) != argv[0]  ||  f (e, argv, 1) != argv[1];
 152 ],
 153 [am_cv_prog_cc_stdc="$ac_arg"; break])
 154 done
 155 CC="$ac_save_CC"
 156 ])
 157 if test -z "$am_cv_prog_cc_stdc"; then
 158   AC_MSG_RESULT([none needed])
 159 else
 160   AC_MSG_RESULT([$am_cv_prog_cc_stdc])
 161 fi
 162 case "x$am_cv_prog_cc_stdc" in
 163   x|xno) ;;
 164   *) CC="$CC $am_cv_prog_cc_stdc" ;;
 165 esac
 166 ])
 167
 168 dnl Originally from Bruno Haible, but with some modifications
 169 dnl for the GDB project.
 170
 171 AC_DEFUN([AM_ICONV],
 172 [
 173   dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
 174   dnl those with the standalone portable GNU libiconv installed).
 175
 176   AC_ARG_WITH([libiconv-prefix],
 177     AS_HELP_STRING([--with-libiconv-prefix=DIR], [search for libiconv in DIR/include and DIR/lib]), [
 178     for dir in `echo "$withval" | tr : ' '`; do
 179       if test -d $dir/include; then LIBICONV_INCLUDE="-I$dir/include"; fi
 180       if test -d $dir/lib; then LIBICONV_LIBDIR="-L$dir/lib"; fi
 181     done
 182    ])
 183
 184   BUILD_LIBICONV_LIBDIRS="../libiconv/lib/.libs ../libiconv/lib/_libs"
 185   BUILD_LIBICONV_INCLUDE="-I../libiconv/include"
 186
 187   AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [
 188     am_cv_func_iconv="no, consider installing GNU libiconv"
 189     am_cv_lib_iconv=no
 190     am_cv_use_build_libiconv=no
 191     am_cv_build_libiconv_path=
 192
 193     # If libiconv is part of the build tree, then try using it over
 194     # any system iconv.
 195     if test -d ../libiconv; then
 196       for lib_dir in $BUILD_LIBICONV_LIBDIRS; do
 197         am_save_LIBS="$LIBS"
 198         am_save_CPPFLAGS="$CPPFLAGS"
 199         LIBS="$LIBS $lib_dir/libiconv.a"
 200         CPPFLAGS="$CPPFLAGS $BUILD_LIBICONV_INCLUDE"
 201         AC_TRY_LINK([#include <stdlib.h>
 202 #include <iconv.h>],
 203           [iconv_t cd = iconv_open("","");
 204            iconv(cd,NULL,NULL,NULL,NULL);
 205            iconv_close(cd);],
 206           am_cv_use_build_libiconv=yes
 207           am_cv_build_libiconv_path=$lib_dir/libiconv.a
 208           am_cv_lib_iconv=yes
 209           am_cv_func_iconv=yes)
 210         LIBS="$am_save_LIBS"
 211         CPPFLAGS="$am_save_CPPFLAGS"
 212         if test "$am_cv_use_build_libiconv" = "yes"; then
 213           break
 214         fi
 215       done
 216     fi
 217
 218     # Next, try to find iconv in libc.
 219     if test "$am_cv_func_iconv" != yes; then
 220       AC_TRY_LINK([#include <stdlib.h>
 221 #include <iconv.h>],
 222         [iconv_t cd = iconv_open("","");
 223          iconv(cd,NULL,NULL,NULL,NULL);
 224          iconv_close(cd);],
 225         am_cv_func_iconv=yes)
 226     fi
 227
 228     # If iconv was not in libc, try -liconv.  In this case, arrange to
 229     # look in the libiconv prefix, if it was specified by the user.
 230     if test "$am_cv_func_iconv" != yes; then
 231       am_save_CPPFLAGS="$CPPFLAGS"
 232       am_save_LIBS="$LIBS"
 233       if test -n "$LIBICONV_INCLUDE"; then
 234         CPPFLAGS="$CPPFLAGS $LIBICONV_INCLUDE"
 235         LIBS="$LIBS $LIBICONV_LIBDIR"
 236       fi
 237       LIBS="$LIBS -liconv"
 238       AC_TRY_LINK([#include <stdlib.h>
 239 #include <iconv.h>],
 240         [iconv_t cd = iconv_open("","");
 241          iconv(cd,NULL,NULL,NULL,NULL);
 242          iconv_close(cd);],
 243         am_cv_lib_iconv=yes
 244         am_cv_func_iconv=yes)
 245       LIBS="$am_save_LIBS"
 246       CPPFLAGS="$am_save_CPPFLAGS"
 247     fi
 248   ])
 249
 250   # Set the various flags based on the cache variables.  We can't rely
 251   # on the flags to remain set from the above code, due to caching.
 252   LIBICONV=
 253   if test "$am_cv_lib_iconv" = yes; then
 254     LIBICONV="-liconv"
 255   else
 256     LIBICONV_LIBDIR=
 257     LIBICONV_INCLUDE=
 258   fi
 259   if test "$am_cv_use_build_libiconv" = yes; then
 260     LIBICONV="$am_cv_build_libiconv_path"
 261     LIBICONV_LIBDIR=""
 262     LIBICONV_INCLUDE="$BUILD_LIBICONV_INCLUDE"
 263   fi
 264   CPPFLAGS="$CPPFLAGS $LIBICONV_INCLUDE"
 265   LIBS="$LIBS $LIBICONV_LIBDIR $LIBICONV"
 266
 267   if test "$am_cv_func_iconv" = yes; then
 268     AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.])
 269     AC_MSG_CHECKING([for iconv declaration])
 270     AC_CACHE_VAL(am_cv_proto_iconv, [
 271       AC_TRY_COMPILE([
 272 #include <stdlib.h>
 273 #include <iconv.h>
 274 extern
 275 #ifdef __cplusplus
 276 "C"
 277 #endif
 278 #if defined(__STDC__) || defined(__cplusplus)
 279 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 280 #else
 281 size_t iconv();
 282 #endif
 283 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 284       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 285     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 286     AC_MSG_RESULT([$]{ac_t:-
 287          }[$]am_cv_proto_iconv)
 288     AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 289       [Define as const if the declaration of iconv() needs const.])
 290   fi
 291 ])
 292
 293 dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva
 294 dnl Version 1.3 (2001/03/02)
 295 dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html
 296
 297 AC_DEFUN([AC_DEFINE_DIR], [
 298   test "x$prefix" = xNONE && prefix="$ac_default_prefix"
 299   test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 300   ac_define_dir=`eval echo [$]$2`
 301   ac_define_dir=`eval echo [$]ac_define_dir`
 302   ifelse($3, ,
 303     AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
 304     AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
 305 ])
 306
 307 dnl See whether we need a declaration for a function.
 308 dnl The result is highly dependent on the INCLUDES passed in, so make sure
 309 dnl to use a different cache variable name in this macro if it is invoked
 310 dnl in a different context somewhere else.
 311 dnl gcc_AC_CHECK_DECL(SYMBOL,
 312 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
 313 AC_DEFUN([gcc_AC_CHECK_DECL],
 314 [AC_MSG_CHECKING([whether $1 is declared])
 315 AC_CACHE_VAL(gcc_cv_have_decl_$1,
 316 [AC_TRY_COMPILE([$4],
 317 [#ifndef $1
 318 char *(*pfn) = (char *(*)) $1 ;
 319 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
 320 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
 321   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
 322 else
 323   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
 324 fi
 325 ])dnl
 326
 327 dnl Check multiple functions to see whether each needs a declaration.
 328 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
 329 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
 330 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
 331 AC_DEFUN([gcc_AC_CHECK_DECLS],
 332 [for ac_func in $1
 333 do
 334 changequote(, )dnl
 335   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 336 changequote([, ])dnl
 337 gcc_AC_CHECK_DECL($ac_func,
 338   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
 339   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
 340 dnl It is possible that the include files passed in here are local headers
 341 dnl which supply a backup declaration for the relevant prototype based on
 342 dnl the definition of (or lack of) the HAVE_DECL_ macro.  If so, this test
 343 dnl will always return success.  E.g. see libiberty.h's handling of
 344 dnl `basename'.  To avoid this, we define the relevant HAVE_DECL_ macro to
 345 dnl 1 so that any local headers used do not provide their own prototype
 346 dnl during this test.
 347 #undef $ac_tr_decl
 348 #define $ac_tr_decl 1
 349   $4
 350 )
 351 done
 352 dnl Automatically generate config.h entries via autoheader.
 353 if test x = y ; then
 354   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
 355     [AC_DEFINE([HAVE_DECL_\&], 1,
 356       [Define to 1 if we found this declaration otherwise define to 0.])])dnl
 357 fi
 358 ])
 359
 360 dnl Find the location of the private Tcl headers
 361 dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic
 362 dnl When Tcl is in the build tree, this is not needed.
 363 dnl
 364 dnl Note: you must use first use SC_LOAD_TCLCONFIG!
 365 AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [
 366   AC_MSG_CHECKING([for Tcl private headers])
 367   private_dir=""
 368   dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//`
 369   if test -f ${dir}/tclInt.h ; then
 370     private_dir=${dir}
 371   fi
 372
 373   if test x"${private_dir}" = x; then
 374     AC_ERROR(could not find private Tcl headers)
 375   else
 376     TCL_PRIVATE_INCLUDE="-I${private_dir}"
 377     AC_MSG_RESULT(${private_dir})
 378   fi
 379 ])
 380
 381 dnl Find the location of the private Tk headers
 382 dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic
 383 dnl When Tk is in the build tree, this not needed.
 384 dnl
 385 dnl Note: you must first use SC_LOAD_TKCONFIG
 386 AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [
 387   AC_MSG_CHECKING([for Tk private headers])
 388   private_dir=""
 389   dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//`
 390   if test -f ${dir}/tkInt.h; then
 391     private_dir=${dir}
 392   fi
 393
 394   if test x"${private_dir}" = x; then
 395     AC_ERROR(could not find Tk private headers)
 396   else
 397     TK_PRIVATE_INCLUDE="-I${private_dir}"
 398     AC_MSG_RESULT(${private_dir})
 399   fi
 400 ])
 401
 402 dnl GDB_AC_DEFINE_RELOCATABLE([VARIABLE], [ARG-NAME], [SHELL-VARIABLE])
 403 dnl For use in processing directory values for --with-foo.
 404 dnl If the path in SHELL_VARIABLE is relative to the prefix, then the
 405 dnl result is relocatable, then this will define the C macro
 406 dnl VARIABLE_RELOCATABLE to 1; otherwise it is defined as 0.
 407 AC_DEFUN([GDB_AC_DEFINE_RELOCATABLE], [
 408   if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 409      if test "x$prefix" = xNONE; then
 410         test_prefix=/usr/local
 411      else
 412         test_prefix=$prefix
 413      fi
 414   else
 415      test_prefix=$exec_prefix
 416   fi
 417   value=0
 418   case [$3] in
 419      "${test_prefix}"|"${test_prefix}/"*|\
 420         '${exec_prefix}'|'${exec_prefix}/'*)
 421      value=1
 422      ;;
 423   esac
 424   AC_DEFINE_UNQUOTED([$1]_RELOCATABLE, $value, [Define if the $2 directory should be relocated when GDB is moved.])
 425 ])
 426
 427 dnl GDB_AC_WITH_DIR([VARIABLE], [ARG-NAME], [HELP], [DEFAULT])
 428 dnl Add a new --with option that defines a directory.
 429 dnl The result is stored in VARIABLE.  AC_DEFINE_DIR is called
 430 dnl on this variable, as is AC_SUBST.
 431 dnl ARG-NAME is the base name of the argument (without "--with").
 432 dnl HELP is the help text to use.
 433 dnl If the user's choice is relative to the prefix, then the
 434 dnl result is relocatable, then this will define the C macro
 435 dnl VARIABLE_RELOCATABLE to 1; otherwise it is defined as 0.
 436 dnl DEFAULT is the default value, which is used if the user
 437 dnl does not specify the argument.
 438 AC_DEFUN([GDB_AC_WITH_DIR], [
 439   AC_ARG_WITH([$2], AS_HELP_STRING([--with-][$2][=PATH], [$3]), [
 440     [$1]=$withval], [[$1]=[$4]])
 441   AC_DEFINE_DIR([$1], [$1], [$3])
 442   AC_SUBST([$1])
 443   GDB_AC_DEFINE_RELOCATABLE([$1], [$2], ${ac_define_dir})
 444   ])
 445
 446 dnl GDB_AC_CHECK_BFD([MESSAGE], [CV], [CODE], [HEADER])
 447 dnl Check whether BFD provides a feature.
 448 dnl MESSAGE is the "checking" message to display.
 449 dnl CV is the name of the cache variable where the result is stored.
 450 dnl The result will be "yes" or "no".
 451 dnl CODE is some code to compile that checks for the feature.
 452 dnl A link test is run.
 453 dnl HEADER is the name of an extra BFD header to include.
 454 AC_DEFUN([GDB_AC_CHECK_BFD], [
 455   OLD_CFLAGS=$CFLAGS
 456   OLD_LDFLAGS=$LDFLAGS
 457   OLD_LIBS=$LIBS
 458   # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
 459   # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
 460   # always want our bfd.
 461   CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
 462   LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
 463   intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
 464   LIBS="-lbfd -liberty $intl $LIBS"
 465   AC_CACHE_CHECK([$1], [$2],
 466   [AC_TRY_LINK(
 467   [#include <stdlib.h>
 468   #include "bfd.h"
 469   #include "$4"
 470   ],
 471   [return $3;], [[$2]=yes], [[$2]=no])])
 472   CFLAGS=$OLD_CFLAGS
 473   LDFLAGS=$OLD_LDFLAGS
 474   LIBS=$OLD_LIBS])
 475
 476 dnl GDB_GUILE_PROGRAM_NAMES([PKG-CONFIG], [VERSION])
 477 dnl
 478 dnl Define and substitute 'GUILD' to contain the absolute file name of
 479 dnl the 'guild' command for VERSION, using PKG-CONFIG.  (This is
 480 dnl similar to Guile's 'GUILE_PROGS' macro.)
 481 AC_DEFUN([GDB_GUILE_PROGRAM_NAMES], [
 482   AC_CACHE_CHECK([for the absolute file name of the 'guild' command],
 483     [ac_cv_guild_program_name],
 484     [ac_cv_guild_program_name="`$1 --variable guild $2`"
 485
 486      # In Guile up to 2.0.11 included, guile-2.0.pc would not define
 487      # the 'guild' and 'bindir' variables.  In that case, try to guess
 488      # what the program name is, at the risk of getting it wrong if
 489      # Guile was configured with '--program-suffix' or similar.
 490      if test "x$ac_cv_guild_program_name" = "x"; then
 491        guile_exec_prefix="`$1 --variable exec_prefix $2`"
 492        ac_cv_guild_program_name="$guile_exec_prefix/bin/guild"
 493      fi
 494   ])
 495
 496   if ! "$ac_cv_guild_program_name" --version >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 497     AC_MSG_ERROR(['$ac_cv_guild_program_name' appears to be unusable])
 498   fi
 499
 500   GUILD="$ac_cv_guild_program_name"
 501   AC_SUBST([GUILD])
 502 ])
 503
 504 dnl GDB_GUILD_TARGET_FLAG
 505 dnl
 506 dnl Compute the value of GUILD_TARGET_FLAG.
 507 dnl For native builds this is empty.
 508 dnl For cross builds this is --target=<host>.
 509 AC_DEFUN([GDB_GUILD_TARGET_FLAG], [
 510   if test "$cross_compiling" = no; then
 511     GUILD_TARGET_FLAG=
 512   else
 513     GUILD_TARGET_FLAG="--target=$host"
 514   fi
 515   AC_SUBST(GUILD_TARGET_FLAG)
 516 ])
 517
 518 dnl GDB_TRY_GUILD([SRC-FILE])
 519 dnl
 520 dnl We precompile the .scm files and install them with gdb, so make sure
 521 dnl guild works for this host.
 522 dnl The .scm files are precompiled for several reasons:
 523 dnl 1) To silence Guile during gdb startup (Guile's auto-compilation output
 524 dnl    is unnecessarily verbose).
 525 dnl 2) Make gdb developers see compilation errors/warnings during the build,
 526 dnl    and not leave it to later when the user runs gdb.
 527 dnl 3) As a convenience for the user, so that one copy of the files is built
 528 dnl    instead of one copy per user.
 529 dnl
 530 dnl Make sure guild can handle this host by trying to compile SRC-FILE, and
 531 dnl setting ac_cv_guild_ok to yes or no.
 532 dnl Note that guild can handle cross-compilation.
 533 dnl It could happen that guild can't handle the host, but guile would still
 534 dnl work.  For the time being we're conservative, and if guild doesn't work
 535 dnl we punt.
 536 AC_DEFUN([GDB_TRY_GUILD], [
 537   AC_REQUIRE([GDB_GUILD_TARGET_FLAG])
 538   AC_CACHE_CHECK([whether guild supports this host],
 539     [ac_cv_guild_ok],
 540     [echo "$ac_cv_guild_program_name compile $GUILD_TARGET_FLAG -o conftest.go $1" >&AS_MESSAGE_LOG_FD
 541      if "$ac_cv_guild_program_name" compile $GUILD_TARGET_FLAG -o conftest.go "$1" >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 542        ac_cv_guild_ok=yes
 543      else
 544        ac_cv_guild_ok=no
 545      fi])
 546 ])