gdb/c-exp.y

   1 /* YACC parser for C expressions, for GDB.
   2    Copyright (C) 1986, 1989, 1990, 1991 Free Software Foundation, Inc.
   3
   4 This file is part of GDB.
   5
   6 This program is free software; you can redistribute it and/or modify
   7 it under the terms of the GNU General Public License as published by
   8 the Free Software Foundation; either version 2 of the License, or
   9 (at your option) any later version.
  10
  11 This program is distributed in the hope that it will be useful,
  12 but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 GNU General Public License for more details.
  15
  16 You should have received a copy of the GNU General Public License
  17 along with this program; if not, write to the Free Software
  18 Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.  */
  19
  20 /* Parse a C expression from text in a string,
  21    and return the result as a  struct expression  pointer.
  22    That structure contains arithmetic operations in reverse polish,
  23    with constants represented by operations that are followed by special data.
  24    See expression.h for the details of the format.
  25    What is important here is that it can be built up sequentially
  26    during the process of parsing; the lower levels of the tree always
  27    come first in the result.
  28
  29    Note that malloc's and realloc's in this file are transformed to
  30    xmalloc and xrealloc respectively by the same sed command in the
  31    makefile that remaps any other malloc/realloc inserted by the parser
  32    generator.  Doing this with #defines and trying to control the interaction
  33    with include files (<malloc.h> and <stdlib.h> for example) just became
  34    too messy, particularly when such includes can be inserted at random
  35    times by the parser generator.  */
  36
  37 %{
  38
  39 #include "defs.h"
  40 #include "expression.h"
  41 #include "parser-defs.h"
  42 #include "value.h"
  43 #include "language.h"
  44 #include "c-lang.h"
  45
  46 /* Remap normal yacc parser interface names (yyparse, yylex, yyerror, etc),
  47    as well as gratuitiously global symbol names, so we can have multiple
  48    yacc generated parsers in gdb.  Note that these are only the variables
  49    produced by yacc.  If other parser generators (bison, byacc, etc) produce
  50    additional global names that conflict at link time, then those parser
  51    generators need to be fixed instead of adding those names to this list. */
  52
  53 #define yymaxdepth c_maxdepth
  54 #define yyparse c_parse
  55 #define yylex   c_lex
  56 #define yyerror c_error
  57 #define yylval  c_lval
  58 #define yychar  c_char
  59 #define yydebug c_debug
  60 #define yypact  c_pact
  61 #define yyr1    c_r1
  62 #define yyr2    c_r2
  63 #define yydef   c_def
  64 #define yychk   c_chk
  65 #define yypgo   c_pgo
  66 #define yyact   c_act
  67 #define yyexca  c_exca
  68 #define yyerrflag c_errflag
  69 #define yynerrs c_nerrs
  70 #define yyps    c_ps
  71 #define yypv    c_pv
  72 #define yys     c_s
  73 #define yy_yys  c_yys
  74 #define yystate c_state
  75 #define yytmp   c_tmp
  76 #define yyv     c_v
  77 #define yy_yyv  c_yyv
  78 #define yyval   c_val
  79 #define yylloc  c_lloc
  80 #define yyreds  c_reds          /* With YYDEBUG defined */
  81 #define yytoks  c_toks          /* With YYDEBUG defined */
  82
  83 #ifndef YYDEBUG
  84 #define YYDEBUG 0               /* Default to no yydebug support */
  85 #endif
  86
  87 int
  88 yyparse PARAMS ((void));
  89
  90 static int
  91 yylex PARAMS ((void));
  92
  93 void
  94 yyerror PARAMS ((char *));
  95
  96 %}
  97
  98 /* Although the yacc "value" of an expression is not used,
  99    since the result is stored in the structure being created,
 100    other node types do have values.  */
 101
 102 %union
 103   {
 104     LONGEST lval;
 105     struct {
 106       LONGEST val;
 107       struct type *type;
 108     } typed_val;
 109     double dval;
 110     struct symbol *sym;
 111     struct type *tval;
 112     struct stoken sval;
 113     struct ttype tsym;
 114     struct symtoken ssym;
 115     int voidval;
 116     struct block *bval;
 117     enum exp_opcode opcode;
 118     struct internalvar *ivar;
 119
 120     struct type **tvec;
 121     int *ivec;
 122   }
 123
 124 %{
 125 /* YYSTYPE gets defined by %union */
 126 static int
 127 parse_number PARAMS ((char *, int, int, YYSTYPE *));
 128 %}
 129
 130 %type <voidval> exp exp1 type_exp start variable qualified_name lcurly
 131 %type <lval> rcurly
 132 %type <tval> type typebase
 133 %type <tvec> nonempty_typelist
 134 /* %type <bval> block */
 135
 136 /* Fancy type parsing.  */
 137 %type <voidval> func_mod direct_abs_decl abs_decl
 138 %type <tval> ptype
 139 %type <lval> array_mod
 140
 141 %token <typed_val> INT
 142 %token <dval> FLOAT
 143
 144 /* Both NAME and TYPENAME tokens represent symbols in the input,
 145    and both convey their data as strings.
 146    But a TYPENAME is a string that happens to be defined as a typedef
 147    or builtin type name (such as int or char)
 148    and a NAME is any other symbol.
 149    Contexts where this distinction is not important can use the
 150    nonterminal "name", which matches either NAME or TYPENAME.  */
 151
 152 %token <sval> STRING
 153 %token <ssym> NAME /* BLOCKNAME defined below to give it higher precedence. */
 154 %token <tsym> TYPENAME
 155 %type <sval> name
 156 %type <ssym> name_not_typename
 157 %type <tsym> typename
 158
 159 /* A NAME_OR_INT is a symbol which is not known in the symbol table,
 160    but which would parse as a valid number in the current input radix.
 161    E.g. "c" when input_radix==16.  Depending on the parse, it will be
 162    turned into a name or into a number.  */
 163
 164 %token <ssym> NAME_OR_INT
 165
 166 %token STRUCT CLASS UNION ENUM SIZEOF UNSIGNED COLONCOLON
 167 %token TEMPLATE
 168 %token ERROR
 169
 170 /* Special type cases, put in to allow the parser to distinguish different
 171    legal basetypes.  */
 172 %token SIGNED_KEYWORD LONG SHORT INT_KEYWORD CONST_KEYWORD VOLATILE_KEYWORD
 173 %token <lval> LAST REGNAME
 174
 175 %token <ivar> VARIABLE
 176
 177 %token <opcode> ASSIGN_MODIFY
 178
 179 /* C++ */
 180 %token THIS
 181
 182 %left ','
 183 %left ABOVE_COMMA
 184 %right '=' ASSIGN_MODIFY
 185 %right '?'
 186 %left OROR
 187 %left ANDAND
 188 %left '|'
 189 %left '^'
 190 %left '&'
 191 %left EQUAL NOTEQUAL
 192 %left '<' '>' LEQ GEQ
 193 %left LSH RSH
 194 %left '@'
 195 %left '+' '-'
 196 %left '*' '/' '%'
 197 %right UNARY INCREMENT DECREMENT
 198 %right ARROW '.' '[' '('
 199 %token <ssym> BLOCKNAME
 200 %type <bval> block
 201 %left COLONCOLON
 202
 203 \f
 204 %%
 205
 206 start   :       exp1
 207         |       type_exp
 208         ;
 209
 210 type_exp:       type
 211                         { write_exp_elt_opcode(OP_TYPE);
 212                           write_exp_elt_type($1);
 213                           write_exp_elt_opcode(OP_TYPE);}
 214         ;
 215
 216 /* Expressions, including the comma operator.  */
 217 exp1    :       exp
 218         |       exp1 ',' exp
 219                         { write_exp_elt_opcode (BINOP_COMMA); }
 220         ;
 221
 222 /* Expressions, not including the comma operator.  */
 223 exp     :       '*' exp    %prec UNARY
 224                         { write_exp_elt_opcode (UNOP_IND); }
 225
 226 exp     :       '&' exp    %prec UNARY
 227                         { write_exp_elt_opcode (UNOP_ADDR); }
 228
 229 exp     :       '-' exp    %prec UNARY
 230                         { write_exp_elt_opcode (UNOP_NEG); }
 231         ;
 232
 233 exp     :       '!' exp    %prec UNARY
 234                         { write_exp_elt_opcode (UNOP_LOGICAL_NOT); }
 235         ;
 236
 237 exp     :       '~' exp    %prec UNARY
 238                         { write_exp_elt_opcode (UNOP_COMPLEMENT); }
 239         ;
 240
 241 exp     :       INCREMENT exp    %prec UNARY
 242                         { write_exp_elt_opcode (UNOP_PREINCREMENT); }
 243         ;
 244
 245 exp     :       DECREMENT exp    %prec UNARY
 246                         { write_exp_elt_opcode (UNOP_PREDECREMENT); }
 247         ;
 248
 249 exp     :       exp INCREMENT    %prec UNARY
 250                         { write_exp_elt_opcode (UNOP_POSTINCREMENT); }
 251         ;
 252
 253 exp     :       exp DECREMENT    %prec UNARY
 254                         { write_exp_elt_opcode (UNOP_POSTDECREMENT); }
 255         ;
 256
 257 exp     :       SIZEOF exp       %prec UNARY
 258                         { write_exp_elt_opcode (UNOP_SIZEOF); }
 259         ;
 260
 261 exp     :       exp ARROW name
 262                         { write_exp_elt_opcode (STRUCTOP_PTR);
 263                           write_exp_string ($3);
 264                           write_exp_elt_opcode (STRUCTOP_PTR); }
 265         ;
 266
 267 exp     :       exp ARROW qualified_name
 268                         { /* exp->type::name becomes exp->*(&type::name) */
 269                           /* Note: this doesn't work if name is a
 270                              static member!  FIXME */
 271                           write_exp_elt_opcode (UNOP_ADDR);
 272                           write_exp_elt_opcode (STRUCTOP_MPTR); }
 273         ;
 274 exp     :       exp ARROW '*' exp
 275                         { write_exp_elt_opcode (STRUCTOP_MPTR); }
 276         ;
 277
 278 exp     :       exp '.' name
 279                         { write_exp_elt_opcode (STRUCTOP_STRUCT);
 280                           write_exp_string ($3);
 281                           write_exp_elt_opcode (STRUCTOP_STRUCT); }
 282         ;
 283
 284 exp     :       exp '.' qualified_name
 285                         { /* exp.type::name becomes exp.*(&type::name) */
 286                           /* Note: this doesn't work if name is a
 287                              static member!  FIXME */
 288                           write_exp_elt_opcode (UNOP_ADDR);
 289                           write_exp_elt_opcode (STRUCTOP_MEMBER); }
 290         ;
 291
 292 exp     :       exp '.' '*' exp
 293                         { write_exp_elt_opcode (STRUCTOP_MEMBER); }
 294         ;
 295
 296 exp     :       exp '[' exp1 ']'
 297                         { write_exp_elt_opcode (BINOP_SUBSCRIPT); }
 298         ;
 299
 300 exp     :       exp '('
 301                         /* This is to save the value of arglist_len
 302                            being accumulated by an outer function call.  */
 303                         { start_arglist (); }
 304                 arglist ')'     %prec ARROW
 305                         { write_exp_elt_opcode (OP_FUNCALL);
 306                           write_exp_elt_longcst ((LONGEST) end_arglist ());
 307                           write_exp_elt_opcode (OP_FUNCALL); }
 308         ;
 309
 310 lcurly  :       '{'
 311                         { start_arglist (); }
 312         ;
 313
 314 arglist :
 315         ;
 316
 317 arglist :       exp
 318                         { arglist_len = 1; }
 319         ;
 320
 321 arglist :       arglist ',' exp   %prec ABOVE_COMMA
 322                         { arglist_len++; }
 323         ;
 324
 325 rcurly  :       '}'
 326                         { $$ = end_arglist () - 1; }
 327         ;
 328 exp     :       lcurly arglist rcurly   %prec ARROW
 329                         { write_exp_elt_opcode (OP_ARRAY);
 330                           write_exp_elt_longcst ((LONGEST) 0);
 331                           write_exp_elt_longcst ((LONGEST) $3);
 332                           write_exp_elt_opcode (OP_ARRAY); }
 333         ;
 334
 335 exp     :       lcurly type rcurly exp  %prec UNARY
 336                         { write_exp_elt_opcode (UNOP_MEMVAL);
 337                           write_exp_elt_type ($2);
 338                           write_exp_elt_opcode (UNOP_MEMVAL); }
 339         ;
 340
 341 exp     :       '(' type ')' exp  %prec UNARY
 342                         { write_exp_elt_opcode (UNOP_CAST);
 343                           write_exp_elt_type ($2);
 344                           write_exp_elt_opcode (UNOP_CAST); }
 345         ;
 346
 347 exp     :       '(' exp1 ')'
 348                         { }
 349         ;
 350
 351 /* Binary operators in order of decreasing precedence.  */
 352
 353 exp     :       exp '@' exp
 354                         { write_exp_elt_opcode (BINOP_REPEAT); }
 355         ;
 356
 357 exp     :       exp '*' exp
 358                         { write_exp_elt_opcode (BINOP_MUL); }
 359         ;
 360
 361 exp     :       exp '/' exp
 362                         { write_exp_elt_opcode (BINOP_DIV); }
 363         ;
 364
 365 exp     :       exp '%' exp
 366                         { write_exp_elt_opcode (BINOP_REM); }
 367         ;
 368
 369 exp     :       exp '+' exp
 370                         { write_exp_elt_opcode (BINOP_ADD); }
 371         ;
 372
 373 exp     :       exp '-' exp
 374                         { write_exp_elt_opcode (BINOP_SUB); }
 375         ;
 376
 377 exp     :       exp LSH exp
 378                         { write_exp_elt_opcode (BINOP_LSH); }
 379         ;
 380
 381 exp     :       exp RSH exp
 382                         { write_exp_elt_opcode (BINOP_RSH); }
 383         ;
 384
 385 exp     :       exp EQUAL exp
 386                         { write_exp_elt_opcode (BINOP_EQUAL); }
 387         ;
 388
 389 exp     :       exp NOTEQUAL exp
 390                         { write_exp_elt_opcode (BINOP_NOTEQUAL); }
 391         ;
 392
 393 exp     :       exp LEQ exp
 394                         { write_exp_elt_opcode (BINOP_LEQ); }
 395         ;
 396
 397 exp     :       exp GEQ exp
 398                         { write_exp_elt_opcode (BINOP_GEQ); }
 399         ;
 400
 401 exp     :       exp '<' exp
 402                         { write_exp_elt_opcode (BINOP_LESS); }
 403         ;
 404
 405 exp     :       exp '>' exp
 406                         { write_exp_elt_opcode (BINOP_GTR); }
 407         ;
 408
 409 exp     :       exp '&' exp
 410                         { write_exp_elt_opcode (BINOP_BITWISE_AND); }
 411         ;
 412
 413 exp     :       exp '^' exp
 414                         { write_exp_elt_opcode (BINOP_BITWISE_XOR); }
 415         ;
 416
 417 exp     :       exp '|' exp
 418                         { write_exp_elt_opcode (BINOP_BITWISE_IOR); }
 419         ;
 420
 421 exp     :       exp ANDAND exp
 422                         { write_exp_elt_opcode (BINOP_LOGICAL_AND); }
 423         ;
 424
 425 exp     :       exp OROR exp
 426                         { write_exp_elt_opcode (BINOP_LOGICAL_OR); }
 427         ;
 428
 429 exp     :       exp '?' exp ':' exp     %prec '?'
 430                         { write_exp_elt_opcode (TERNOP_COND); }
 431         ;
 432
 433 exp     :       exp '=' exp
 434                         { write_exp_elt_opcode (BINOP_ASSIGN); }
 435         ;
 436
 437 exp     :       exp ASSIGN_MODIFY exp
 438                         { write_exp_elt_opcode (BINOP_ASSIGN_MODIFY);
 439                           write_exp_elt_opcode ($2);
 440                           write_exp_elt_opcode (BINOP_ASSIGN_MODIFY); }
 441         ;
 442
 443 exp     :       INT
 444                         { write_exp_elt_opcode (OP_LONG);
 445                           write_exp_elt_type ($1.type);
 446                           write_exp_elt_longcst ((LONGEST)($1.val));
 447                           write_exp_elt_opcode (OP_LONG); }
 448         ;
 449
 450 exp     :       NAME_OR_INT
 451                         { YYSTYPE val;
 452                           parse_number ($1.stoken.ptr, $1.stoken.length, 0, &val);
 453                           write_exp_elt_opcode (OP_LONG);
 454                           write_exp_elt_type (val.typed_val.type);
 455                           write_exp_elt_longcst ((LONGEST)val.typed_val.val);
 456                           write_exp_elt_opcode (OP_LONG);
 457                         }
 458         ;
 459
 460
 461 exp     :       FLOAT
 462                         { write_exp_elt_opcode (OP_DOUBLE);
 463                           write_exp_elt_type (builtin_type_double);
 464                           write_exp_elt_dblcst ($1);
 465                           write_exp_elt_opcode (OP_DOUBLE); }
 466         ;
 467
 468 exp     :       variable
 469         ;
 470
 471 exp     :       LAST
 472                         { write_exp_elt_opcode (OP_LAST);
 473                           write_exp_elt_longcst ((LONGEST) $1);
 474                           write_exp_elt_opcode (OP_LAST); }
 475         ;
 476
 477 exp     :       REGNAME
 478                         { write_exp_elt_opcode (OP_REGISTER);
 479                           write_exp_elt_longcst ((LONGEST) $1);
 480                           write_exp_elt_opcode (OP_REGISTER); }
 481         ;
 482
 483 exp     :       VARIABLE
 484                         { write_exp_elt_opcode (OP_INTERNALVAR);
 485                           write_exp_elt_intern ($1);
 486                           write_exp_elt_opcode (OP_INTERNALVAR); }
 487         ;
 488
 489 exp     :       SIZEOF '(' type ')'     %prec UNARY
 490                         { write_exp_elt_opcode (OP_LONG);
 491                           write_exp_elt_type (builtin_type_int);
 492                           write_exp_elt_longcst ((LONGEST) TYPE_LENGTH ($3));
 493                           write_exp_elt_opcode (OP_LONG); }
 494         ;
 495
 496 exp     :       STRING
 497                         { /* C strings are converted into array constants with
 498                              an explicit null byte added at the end.  Thus
 499                              the array upper bound is the string length.
 500                              There is no such thing in C as a completely empty
 501                              string. */
 502                           char *sp = $1.ptr; int count = $1.length;
 503                           while (count-- > 0)
 504                             {
 505                               write_exp_elt_opcode (OP_LONG);
 506                               write_exp_elt_type (builtin_type_char);
 507                               write_exp_elt_longcst ((LONGEST)(*sp++));
 508                               write_exp_elt_opcode (OP_LONG);
 509                             }
 510                           write_exp_elt_opcode (OP_LONG);
 511                           write_exp_elt_type (builtin_type_char);
 512                           write_exp_elt_longcst ((LONGEST)'\0');
 513                           write_exp_elt_opcode (OP_LONG);
 514                           write_exp_elt_opcode (OP_ARRAY);
 515                           write_exp_elt_longcst ((LONGEST) 0);
 516                           write_exp_elt_longcst ((LONGEST) ($1.length));
 517                           write_exp_elt_opcode (OP_ARRAY); }
 518         ;
 519
 520 /* C++.  */
 521 exp     :       THIS
 522                         { write_exp_elt_opcode (OP_THIS);
 523                           write_exp_elt_opcode (OP_THIS); }
 524         ;
 525
 526 /* end of C++.  */
 527
 528 block   :       BLOCKNAME
 529                         {
 530                           if ($1.sym != 0)
 531                               $$ = SYMBOL_BLOCK_VALUE ($1.sym);
 532                           else
 533                             {
 534                               struct symtab *tem =
 535                                   lookup_symtab (copy_name ($1.stoken));
 536                               if (tem)
 537                                 $$ = BLOCKVECTOR_BLOCK
 538                                          (BLOCKVECTOR (tem), STATIC_BLOCK);
 539                               else
 540                                 error ("No file or function \"%s\".",
 541                                        copy_name ($1.stoken));
 542                             }
 543                         }
 544         ;
 545
 546 block   :       block COLONCOLON name
 547                         { struct symbol *tem
 548                             = lookup_symbol (copy_name ($3), $1,
 549                                              VAR_NAMESPACE, 0, NULL);
 550                           if (!tem || SYMBOL_CLASS (tem) != LOC_BLOCK)
 551                             error ("No function \"%s\" in specified context.",
 552                                    copy_name ($3));
 553                           $$ = SYMBOL_BLOCK_VALUE (tem); }
 554         ;
 555
 556 variable:       block COLONCOLON name
 557                         { struct symbol *sym;
 558                           sym = lookup_symbol (copy_name ($3), $1,
 559                                                VAR_NAMESPACE, 0, NULL);
 560                           if (sym == 0)
 561                             error ("No symbol \"%s\" in specified context.",
 562                                    copy_name ($3));
 563
 564                           write_exp_elt_opcode (OP_VAR_VALUE);
 565                           write_exp_elt_sym (sym);
 566                           write_exp_elt_opcode (OP_VAR_VALUE); }
 567         ;
 568
 569 qualified_name: typebase COLONCOLON name
 570                         {
 571                           struct type *type = $1;
 572                           if (TYPE_CODE (type) != TYPE_CODE_STRUCT
 573                               && TYPE_CODE (type) != TYPE_CODE_UNION)
 574                             error ("`%s' is not defined as an aggregate type.",
 575                                    TYPE_NAME (type));
 576
 577                           write_exp_elt_opcode (OP_SCOPE);
 578                           write_exp_elt_type (type);
 579                           write_exp_string ($3);
 580                           write_exp_elt_opcode (OP_SCOPE);
 581                         }
 582         |       typebase COLONCOLON '~' name
 583                         {
 584                           struct type *type = $1;
 585                           struct stoken tmp_token;
 586                           if (TYPE_CODE (type) != TYPE_CODE_STRUCT
 587                               && TYPE_CODE (type) != TYPE_CODE_UNION)
 588                             error ("`%s' is not defined as an aggregate type.",
 589                                    TYPE_NAME (type));
 590
 591                           if (!STREQ (type_name_no_tag (type), $4.ptr))
 592                             error ("invalid destructor `%s::~%s'",
 593                                    type_name_no_tag (type), $4.ptr);
 594
 595                           tmp_token.ptr = (char*) alloca ($4.length + 2);
 596                           tmp_token.length = $4.length + 1;
 597                           tmp_token.ptr[0] = '~';
 598                           memcpy (tmp_token.ptr+1, $4.ptr, $4.length);
 599                           tmp_token.ptr[tmp_token.length] = 0;
 600                           write_exp_elt_opcode (OP_SCOPE);
 601                           write_exp_elt_type (type);
 602                           write_exp_string (tmp_token);
 603                           write_exp_elt_opcode (OP_SCOPE);
 604                         }
 605         ;
 606
 607 variable:       qualified_name
 608         |       COLONCOLON name
 609                         {
 610                           char *name = copy_name ($2);
 611                           struct symbol *sym;
 612                           struct minimal_symbol *msymbol;
 613
 614                           sym =
 615                             lookup_symbol (name, 0, VAR_NAMESPACE, 0, NULL);
 616                           if (sym)
 617                             {
 618                               write_exp_elt_opcode (OP_VAR_VALUE);
 619                               write_exp_elt_sym (sym);
 620                               write_exp_elt_opcode (OP_VAR_VALUE);
 621                               break;
 622                             }
 623
 624                           msymbol = lookup_minimal_symbol (name,
 625                                       (struct objfile *) NULL);
 626                           if (msymbol != NULL)
 627                             {
 628                               write_exp_elt_opcode (OP_LONG);
 629                               write_exp_elt_type (builtin_type_int);
 630                               write_exp_elt_longcst ((LONGEST) SYMBOL_VALUE_ADDRESS (msymbol));
 631                               write_exp_elt_opcode (OP_LONG);
 632                               write_exp_elt_opcode (UNOP_MEMVAL);
 633                               if (msymbol -> type == mst_data ||
 634                                   msymbol -> type == mst_bss)
 635                                 write_exp_elt_type (builtin_type_int);
 636                               else if (msymbol -> type == mst_text)
 637                                 write_exp_elt_type (lookup_function_type (builtin_type_int));
 638                               else
 639                                 write_exp_elt_type (builtin_type_char);
 640                               write_exp_elt_opcode (UNOP_MEMVAL);
 641                             }
 642                           else
 643                             if (!have_full_symbols () && !have_partial_symbols ())
 644                               error ("No symbol table is loaded.  Use the \"file\" command.");
 645                             else
 646                               error ("No symbol \"%s\" in current context.", name);
 647                         }
 648         ;
 649
 650 variable:       name_not_typename
 651                         { struct symbol *sym = $1.sym;
 652
 653                           if (sym)
 654                             {
 655                               switch (SYMBOL_CLASS (sym))
 656                                 {
 657                                 case LOC_REGISTER:
 658                                 case LOC_ARG:
 659                                 case LOC_REF_ARG:
 660                                 case LOC_REGPARM:
 661                                 case LOC_LOCAL:
 662                                 case LOC_LOCAL_ARG:
 663                                   if (innermost_block == 0 ||
 664                                       contained_in (block_found,
 665                                                     innermost_block))
 666                                     innermost_block = block_found;
 667                                 case LOC_UNDEF:
 668                                 case LOC_CONST:
 669                                 case LOC_STATIC:
 670                                 case LOC_TYPEDEF:
 671                                 case LOC_LABEL:
 672                                 case LOC_BLOCK:
 673                                 case LOC_CONST_BYTES:
 674
 675                                   /* In this case the expression can
 676                                      be evaluated regardless of what
 677                                      frame we are in, so there is no
 678                                      need to check for the
 679                                      innermost_block.  These cases are
 680                                      listed so that gcc -Wall will
 681                                      report types that may not have
 682                                      been considered.  */
 683
 684                                   break;
 685                                 }
 686                               write_exp_elt_opcode (OP_VAR_VALUE);
 687                               write_exp_elt_sym (sym);
 688                               write_exp_elt_opcode (OP_VAR_VALUE);
 689                             }
 690                           else if ($1.is_a_field_of_this)
 691                             {
 692                               /* C++: it hangs off of `this'.  Must
 693                                  not inadvertently convert from a method call
 694                                  to data ref.  */
 695                               if (innermost_block == 0 ||
 696                                   contained_in (block_found, innermost_block))
 697                                 innermost_block = block_found;
 698                               write_exp_elt_opcode (OP_THIS);
 699                               write_exp_elt_opcode (OP_THIS);
 700                               write_exp_elt_opcode (STRUCTOP_PTR);
 701                               write_exp_string ($1.stoken);
 702                               write_exp_elt_opcode (STRUCTOP_PTR);
 703                             }
 704                           else
 705                             {
 706                               struct minimal_symbol *msymbol;
 707                               register char *arg = copy_name ($1.stoken);
 708
 709                               msymbol = lookup_minimal_symbol (arg,
 710                                           (struct objfile *) NULL);
 711                               if (msymbol != NULL)
 712                                 {
 713                                   write_exp_elt_opcode (OP_LONG);
 714                                   write_exp_elt_type (builtin_type_int);
 715                                   write_exp_elt_longcst ((LONGEST) SYMBOL_VALUE_ADDRESS (msymbol));
 716                                   write_exp_elt_opcode (OP_LONG);
 717                                   write_exp_elt_opcode (UNOP_MEMVAL);
 718                                   if (msymbol -> type == mst_data ||
 719                                       msymbol -> type == mst_bss)
 720                                     write_exp_elt_type (builtin_type_int);
 721                                   else if (msymbol -> type == mst_text)
 722                                     write_exp_elt_type (lookup_function_type (builtin_type_int));
 723                                   else
 724                                     write_exp_elt_type (builtin_type_char);
 725                                   write_exp_elt_opcode (UNOP_MEMVAL);
 726                                 }
 727                               else if (!have_full_symbols () && !have_partial_symbols ())
 728                                 error ("No symbol table is loaded.  Use the \"file\" command.");
 729                               else
 730                                 error ("No symbol \"%s\" in current context.",
 731                                        copy_name ($1.stoken));
 732                             }
 733                         }
 734         ;
 735
 736
 737 ptype   :       typebase
 738         |       typebase abs_decl
 739                 {
 740                   /* This is where the interesting stuff happens.  */
 741                   int done = 0;
 742                   int array_size;
 743                   struct type *follow_type = $1;
 744                   struct type *range_type;
 745
 746                   while (!done)
 747                     switch (pop_type ())
 748                       {
 749                       case tp_end:
 750                         done = 1;
 751                         break;
 752                       case tp_pointer:
 753                         follow_type = lookup_pointer_type (follow_type);
 754                         break;
 755                       case tp_reference:
 756                         follow_type = lookup_reference_type (follow_type);
 757                         break;
 758                       case tp_array:
 759                         array_size = pop_type_int ();
 760                         if (array_size != -1)
 761                           {
 762                             range_type =
 763                               create_range_type ((struct type *) NULL,
 764                                                  builtin_type_int, 0,
 765                                                  array_size - 1);
 766                             follow_type =
 767                               create_array_type ((struct type *) NULL,
 768                                                  follow_type, range_type);
 769                           }
 770                         else
 771                           follow_type = lookup_pointer_type (follow_type);
 772                         break;
 773                       case tp_function:
 774                         follow_type = lookup_function_type (follow_type);
 775                         break;
 776                       }
 777                   $$ = follow_type;
 778                 }
 779         ;
 780
 781 abs_decl:       '*'
 782                         { push_type (tp_pointer); $$ = 0; }
 783         |       '*' abs_decl
 784                         { push_type (tp_pointer); $$ = $2; }
 785         |       '&'
 786                         { push_type (tp_reference); $$ = 0; }
 787         |       '&' abs_decl
 788                         { push_type (tp_reference); $$ = $2; }
 789         |       direct_abs_decl
 790         ;
 791
 792 direct_abs_decl: '(' abs_decl ')'
 793                         { $$ = $2; }
 794         |       direct_abs_decl array_mod
 795                         {
 796                           push_type_int ($2);
 797                           push_type (tp_array);
 798                         }
 799         |       array_mod
 800                         {
 801                           push_type_int ($1);
 802                           push_type (tp_array);
 803                           $$ = 0;
 804                         }
 805         |       direct_abs_decl func_mod
 806                         { push_type (tp_function); }
 807         |       func_mod
 808                         { push_type (tp_function); }
 809         ;
 810
 811 array_mod:      '[' ']'
 812                         { $$ = -1; }
 813         |       '[' INT ']'
 814                         { $$ = $2.val; }
 815         ;
 816
 817 func_mod:       '(' ')'
 818                         { $$ = 0; }
 819         |       '(' nonempty_typelist ')'
 820                         { free ((PTR)$2); $$ = 0; }
 821         ;
 822
 823 type    :       ptype
 824         |       typebase COLONCOLON '*'
 825                         { $$ = lookup_member_type (builtin_type_int, $1); }
 826         |       type '(' typebase COLONCOLON '*' ')'
 827                         { $$ = lookup_member_type ($1, $3); }
 828         |       type '(' typebase COLONCOLON '*' ')' '(' ')'
 829                         { $$ = lookup_member_type
 830                             (lookup_function_type ($1), $3); }
 831         |       type '(' typebase COLONCOLON '*' ')' '(' nonempty_typelist ')'
 832                         { $$ = lookup_member_type
 833                             (lookup_function_type ($1), $3);
 834                           free ((PTR)$8); }
 835         ;
 836
 837 typebase  /* Implements (approximately): (type-qualifier)* type-specifier */
 838         :       TYPENAME
 839                         { $$ = $1.type; }
 840         |       INT_KEYWORD
 841                         { $$ = builtin_type_int; }
 842         |       LONG
 843                         { $$ = builtin_type_long; }
 844         |       SHORT
 845                         { $$ = builtin_type_short; }
 846         |       LONG INT_KEYWORD
 847                         { $$ = builtin_type_long; }
 848         |       UNSIGNED LONG INT_KEYWORD
 849                         { $$ = builtin_type_unsigned_long; }
 850         |       LONG LONG
 851                         { $$ = builtin_type_long_long; }
 852         |       LONG LONG INT_KEYWORD
 853                         { $$ = builtin_type_long_long; }
 854         |       UNSIGNED LONG LONG
 855                         { $$ = builtin_type_unsigned_long_long; }
 856         |       UNSIGNED LONG LONG INT_KEYWORD
 857                         { $$ = builtin_type_unsigned_long_long; }
 858         |       SHORT INT_KEYWORD
 859                         { $$ = builtin_type_short; }
 860         |       UNSIGNED SHORT INT_KEYWORD
 861                         { $$ = builtin_type_unsigned_short; }
 862         |       STRUCT name
 863                         { $$ = lookup_struct (copy_name ($2),
 864                                               expression_context_block); }
 865         |       CLASS name
 866                         { $$ = lookup_struct (copy_name ($2),
 867                                               expression_context_block); }
 868         |       UNION name
 869                         { $$ = lookup_union (copy_name ($2),
 870                                              expression_context_block); }
 871         |       ENUM name
 872                         { $$ = lookup_enum (copy_name ($2),
 873                                             expression_context_block); }
 874         |       UNSIGNED typename
 875                         { $$ = lookup_unsigned_typename (TYPE_NAME($2.type)); }
 876         |       UNSIGNED
 877                         { $$ = builtin_type_unsigned_int; }
 878         |       SIGNED_KEYWORD typename
 879                         { $$ = lookup_signed_typename (TYPE_NAME($2.type)); }
 880         |       SIGNED_KEYWORD
 881                         { $$ = builtin_type_int; }
 882         |       TEMPLATE name '<' type '>'
 883                         { $$ = lookup_template_type(copy_name($2), $4,
 884                                                     expression_context_block);
 885                         }
 886         /* "const" and "volatile" are curently ignored. */
 887         |       CONST_KEYWORD typebase { $$ = $2; }
 888         |       VOLATILE_KEYWORD typebase { $$ = $2; }
 889         ;
 890
 891 typename:       TYPENAME
 892         |       INT_KEYWORD
 893                 {
 894                   $$.stoken.ptr = "int";
 895                   $$.stoken.length = 3;
 896                   $$.type = builtin_type_int;
 897                 }
 898         |       LONG
 899                 {
 900                   $$.stoken.ptr = "long";
 901                   $$.stoken.length = 4;
 902                   $$.type = builtin_type_long;
 903                 }
 904         |       SHORT
 905                 {
 906                   $$.stoken.ptr = "short";
 907                   $$.stoken.length = 5;
 908                   $$.type = builtin_type_short;
 909                 }
 910         ;
 911
 912 nonempty_typelist
 913         :       type
 914                 { $$ = (struct type **) malloc (sizeof (struct type *) * 2);
 915                   $<ivec>$[0] = 1;      /* Number of types in vector */
 916                   $$[1] = $1;
 917                 }
 918         |       nonempty_typelist ',' type
 919                 { int len = sizeof (struct type *) * (++($<ivec>1[0]) + 1);
 920                   $$ = (struct type **) realloc ((char *) $1, len);
 921                   $$[$<ivec>$[0]] = $3;
 922                 }
 923         ;
 924
 925 name    :       NAME { $$ = $1.stoken; }
 926         |       BLOCKNAME { $$ = $1.stoken; }
 927         |       TYPENAME { $$ = $1.stoken; }
 928         |       NAME_OR_INT  { $$ = $1.stoken; }
 929         ;
 930
 931 name_not_typename :     NAME
 932         |       BLOCKNAME
 933 /* These would be useful if name_not_typename was useful, but it is just
 934    a fake for "variable", so these cause reduce/reduce conflicts because
 935    the parser can't tell whether NAME_OR_INT is a name_not_typename (=variable,
 936    =exp) or just an exp.  If name_not_typename was ever used in an lvalue
 937    context where only a name could occur, this might be useful.
 938         |       NAME_OR_INT
 939  */
 940         ;
 941
 942 %%
 943
 944 /* Take care of parsing a number (anything that starts with a digit).
 945    Set yylval and return the token type; update lexptr.
 946    LEN is the number of characters in it.  */
 947
 948 /*** Needs some error checking for the float case ***/
 949
 950 static int
 951 parse_number (p, len, parsed_float, putithere)
 952      register char *p;
 953      register int len;
 954      int parsed_float;
 955      YYSTYPE *putithere;
 956 {
 957   register LONGEST n = 0;
 958   register LONGEST prevn = 0;
 959   register int i;
 960   register int c;
 961   register int base = input_radix;
 962   int unsigned_p = 0;
 963   int long_p = 0;
 964   unsigned LONGEST high_bit;
 965   struct type *signed_type;
 966   struct type *unsigned_type;
 967
 968   if (parsed_float)
 969     {
 970       /* It's a float since it contains a point or an exponent.  */
 971       putithere->dval = atof (p);
 972       return FLOAT;
 973     }
 974
 975   /* Handle base-switching prefixes 0x, 0t, 0d, 0 */
 976   if (p[0] == '0')
 977     switch (p[1])
 978       {
 979       case 'x':
 980       case 'X':
 981         if (len >= 3)
 982           {
 983             p += 2;
 984             base = 16;
 985             len -= 2;
 986           }
 987         break;
 988
 989       case 't':
 990       case 'T':
 991       case 'd':
 992       case 'D':
 993         if (len >= 3)
 994           {
 995             p += 2;
 996             base = 10;
 997             len -= 2;
 998           }
 999         break;
1000
1001       default:
1002         base = 8;
1003         break;
1004       }
1005
1006   while (len-- > 0)
1007     {
1008       c = *p++;
1009       if (c >= 'A' && c <= 'Z')
1010         c += 'a' - 'A';
1011       if (c != 'l' && c != 'u')
1012         n *= base;
1013       if (c >= '0' && c <= '9')
1014         n += i = c - '0';
1015       else
1016         {
1017           if (base > 10 && c >= 'a' && c <= 'f')
1018             n += i = c - 'a' + 10;
1019           else if (len == 0 && c == 'l')
1020             long_p = 1;
1021           else if (len == 0 && c == 'u')
1022             unsigned_p = 1;
1023           else
1024             return ERROR;       /* Char not a digit */
1025         }
1026       if (i >= base)
1027         return ERROR;           /* Invalid digit in this base */
1028
1029       /* Portably test for overflow (only works for nonzero values, so make
1030          a second check for zero).  */
1031       if((prevn >= n) && n != 0)
1032          unsigned_p=1;          /* Try something unsigned */
1033       /* If range checking enabled, portably test for unsigned overflow.  */
1034       if(RANGE_CHECK && n!=0)
1035       {
1036          if((unsigned_p && (unsigned)prevn >= (unsigned)n))
1037             range_error("Overflow on numeric constant.");
1038       }
1039       prevn=n;
1040     }
1041
1042      /* If the number is too big to be an int, or it's got an l suffix
1043         then it's a long.  Work out if this has to be a long by
1044         shifting right and and seeing if anything remains, and the
1045         target int size is different to the target long size.
1046
1047         In the expression below, we could have tested
1048                 (n >> TARGET_INT_BIT)
1049         to see if it was zero,
1050         but too many compilers warn about that, when ints and longs
1051         are the same size.  So we shift it twice, with fewer bits
1052         each time, for the same result.  */
1053
1054     if (   (TARGET_INT_BIT != TARGET_LONG_BIT
1055             && ((n >> 2) >> (TARGET_INT_BIT-2)))   /* Avoid shift warning */
1056         || long_p)
1057       {
1058          high_bit = ((unsigned LONGEST)1) << (TARGET_LONG_BIT-1);
1059          unsigned_type = builtin_type_unsigned_long;
1060          signed_type = builtin_type_long;
1061       }
1062     else
1063       {
1064          high_bit = ((unsigned LONGEST)1) << (TARGET_INT_BIT-1);
1065          unsigned_type = builtin_type_unsigned_int;
1066          signed_type = builtin_type_int;
1067       }
1068
1069    putithere->typed_val.val = n;
1070
1071    /* If the high bit of the worked out type is set then this number
1072       has to be unsigned. */
1073
1074    if (unsigned_p || (n & high_bit))
1075      {
1076         putithere->typed_val.type = unsigned_type;
1077      }
1078    else
1079      {
1080         putithere->typed_val.type = signed_type;
1081      }
1082
1083    return INT;
1084 }
1085
1086 struct token
1087 {
1088   char *operator;
1089   int token;
1090   enum exp_opcode opcode;
1091 };
1092
1093 static const struct token tokentab3[] =
1094   {
1095     {">>=", ASSIGN_MODIFY, BINOP_RSH},
1096     {"<<=", ASSIGN_MODIFY, BINOP_LSH}
1097   };
1098
1099 static const struct token tokentab2[] =
1100   {
1101     {"+=", ASSIGN_MODIFY, BINOP_ADD},
1102     {"-=", ASSIGN_MODIFY, BINOP_SUB},
1103     {"*=", ASSIGN_MODIFY, BINOP_MUL},
1104     {"/=", ASSIGN_MODIFY, BINOP_DIV},
1105     {"%=", ASSIGN_MODIFY, BINOP_REM},
1106     {"|=", ASSIGN_MODIFY, BINOP_BITWISE_IOR},
1107     {"&=", ASSIGN_MODIFY, BINOP_BITWISE_AND},
1108     {"^=", ASSIGN_MODIFY, BINOP_BITWISE_XOR},
1109     {"++", INCREMENT, BINOP_END},
1110     {"--", DECREMENT, BINOP_END},
1111     {"->", ARROW, BINOP_END},
1112     {"&&", ANDAND, BINOP_END},
1113     {"||", OROR, BINOP_END},
1114     {"::", COLONCOLON, BINOP_END},
1115     {"<<", LSH, BINOP_END},
1116     {">>", RSH, BINOP_END},
1117     {"==", EQUAL, BINOP_END},
1118     {"!=", NOTEQUAL, BINOP_END},
1119     {"<=", LEQ, BINOP_END},
1120     {">=", GEQ, BINOP_END}
1121   };
1122
1123 /* Read one token, getting characters through lexptr.  */
1124
1125 static int
1126 yylex ()
1127 {
1128   int c;
1129   int namelen;
1130   unsigned int i;
1131   char *tokstart;
1132   char *tokptr;
1133   int tempbufindex;
1134   static char *tempbuf;
1135   static int tempbufsize;
1136
1137  retry:
1138
1139   tokstart = lexptr;
1140   /* See if it is a special token of length 3.  */
1141   for (i = 0; i < sizeof tokentab3 / sizeof tokentab3[0]; i++)
1142     if (STREQN (tokstart, tokentab3[i].operator, 3))
1143       {
1144         lexptr += 3;
1145         yylval.opcode = tokentab3[i].opcode;
1146         return tokentab3[i].token;
1147       }
1148
1149   /* See if it is a special token of length 2.  */
1150   for (i = 0; i < sizeof tokentab2 / sizeof tokentab2[0]; i++)
1151     if (STREQN (tokstart, tokentab2[i].operator, 2))
1152       {
1153         lexptr += 2;
1154         yylval.opcode = tokentab2[i].opcode;
1155         return tokentab2[i].token;
1156       }
1157
1158   switch (c = *tokstart)
1159     {
1160     case 0:
1161       return 0;
1162
1163     case ' ':
1164     case '\t':
1165     case '\n':
1166       lexptr++;
1167       goto retry;
1168
1169     case '\'':
1170       /* We either have a character constant ('0' or '\177' for example)
1171          or we have a quoted symbol reference ('foo(int,int)' in C++
1172          for example). */
1173       lexptr++;
1174       c = *lexptr++;
1175       if (c == '\\')
1176         c = parse_escape (&lexptr);
1177
1178       yylval.typed_val.val = c;
1179       yylval.typed_val.type = builtin_type_char;
1180
1181       c = *lexptr++;
1182       if (c != '\'')
1183         {
1184           namelen = skip_quoted (tokstart) - tokstart;
1185           if (namelen > 2)
1186             {
1187               lexptr = tokstart + namelen;
1188               namelen -= 2;
1189               tokstart++;
1190               goto tryname;
1191             }
1192           error ("Invalid character constant.");
1193         }
1194       return INT;
1195
1196     case '(':
1197       paren_depth++;
1198       lexptr++;
1199       return c;
1200
1201     case ')':
1202       if (paren_depth == 0)
1203         return 0;
1204       paren_depth--;
1205       lexptr++;
1206       return c;
1207
1208     case ',':
1209       if (comma_terminates && paren_depth == 0)
1210         return 0;
1211       lexptr++;
1212       return c;
1213
1214     case '.':
1215       /* Might be a floating point number.  */
1216       if (lexptr[1] < '0' || lexptr[1] > '9')
1217         goto symbol;            /* Nope, must be a symbol. */
1218       /* FALL THRU into number case.  */
1219
1220     case '0':
1221     case '1':
1222     case '2':
1223     case '3':
1224     case '4':
1225     case '5':
1226     case '6':
1227     case '7':
1228     case '8':
1229     case '9':
1230       {
1231         /* It's a number.  */
1232         int got_dot = 0, got_e = 0, toktype;
1233         register char *p = tokstart;
1234         int hex = input_radix > 10;
1235
1236         if (c == '0' && (p[1] == 'x' || p[1] == 'X'))
1237           {
1238             p += 2;
1239             hex = 1;
1240           }
1241         else if (c == '0' && (p[1]=='t' || p[1]=='T' || p[1]=='d' || p[1]=='D'))
1242           {
1243             p += 2;
1244             hex = 0;
1245           }
1246
1247         for (;; ++p)
1248           {
1249             if (!hex && !got_e && (*p == 'e' || *p == 'E'))
1250               got_dot = got_e = 1;
1251             else if (!hex && !got_dot && *p == '.')
1252               got_dot = 1;
1253             else if (got_e && (p[-1] == 'e' || p[-1] == 'E')
1254                      && (*p == '-' || *p == '+'))
1255               /* This is the sign of the exponent, not the end of the
1256                  number.  */
1257               continue;
1258             /* We will take any letters or digits.  parse_number will
1259                complain if past the radix, or if L or U are not final.  */
1260             else if ((*p < '0' || *p > '9')
1261                      && ((*p < 'a' || *p > 'z')
1262                                   && (*p < 'A' || *p > 'Z')))
1263               break;
1264           }
1265         toktype = parse_number (tokstart, p - tokstart, got_dot|got_e, &yylval);
1266         if (toktype == ERROR)
1267           {
1268             char *err_copy = (char *) alloca (p - tokstart + 1);
1269
1270             memcpy (err_copy, tokstart, p - tokstart);
1271             err_copy[p - tokstart] = 0;
1272             error ("Invalid number \"%s\".", err_copy);
1273           }
1274         lexptr = p;
1275         return toktype;
1276       }
1277
1278     case '+':
1279     case '-':
1280     case '*':
1281     case '/':
1282     case '%':
1283     case '|':
1284     case '&':
1285     case '^':
1286     case '~':
1287     case '!':
1288     case '@':
1289     case '<':
1290     case '>':
1291     case '[':
1292     case ']':
1293     case '?':
1294     case ':':
1295     case '=':
1296     case '{':
1297     case '}':
1298     symbol:
1299       lexptr++;
1300       return c;
1301
1302     case '"':
1303
1304       /* Build the gdb internal form of the input string in tempbuf,
1305          translating any standard C escape forms seen.  Note that the
1306          buffer is null byte terminated *only* for the convenience of
1307          debugging gdb itself and printing the buffer contents when
1308          the buffer contains no embedded nulls.  Gdb does not depend
1309          upon the buffer being null byte terminated, it uses the length
1310          string instead.  This allows gdb to handle C strings (as well
1311          as strings in other languages) with embedded null bytes */
1312
1313       tokptr = ++tokstart;
1314       tempbufindex = 0;
1315
1316       do {
1317         /* Grow the static temp buffer if necessary, including allocating
1318            the first one on demand. */
1319         if (tempbufindex + 1 >= tempbufsize)
1320           {
1321             tempbuf = (char *) realloc (tempbuf, tempbufsize += 64);
1322           }
1323         switch (*tokptr)
1324           {
1325           case '\0':
1326           case '"':
1327             /* Do nothing, loop will terminate. */
1328             break;
1329           case '\\':
1330             tokptr++;
1331             c = parse_escape (&tokptr);
1332             if (c == -1)
1333               {
1334                 continue;
1335               }
1336             tempbuf[tempbufindex++] = c;
1337             break;
1338           default:
1339             tempbuf[tempbufindex++] = *tokptr++;
1340             break;
1341           }
1342       } while ((*tokptr != '"') && (*tokptr != '\0'));
1343       if (*tokptr++ != '"')
1344         {
1345           error ("Unterminated string in expression.");
1346         }
1347       tempbuf[tempbufindex] = '\0';     /* See note above */
1348       yylval.sval.ptr = tempbuf;
1349       yylval.sval.length = tempbufindex;
1350       lexptr = tokptr;
1351       return (STRING);
1352     }
1353
1354   if (!(c == '_' || c == '$'
1355         || (c >= 'a' && c <= 'z') || (c >= 'A' && c <= 'Z')))
1356     /* We must have come across a bad character (e.g. ';').  */
1357     error ("Invalid character '%c' in expression.", c);
1358
1359   /* It's a name.  See how long it is.  */
1360   namelen = 0;
1361   for (c = tokstart[namelen];
1362        (c == '_' || c == '$' || (c >= '0' && c <= '9')
1363         || (c >= 'a' && c <= 'z') || (c >= 'A' && c <= 'Z'));
1364        c = tokstart[++namelen])
1365     ;
1366
1367   /* The token "if" terminates the expression and is NOT
1368      removed from the input stream.  */
1369   if (namelen == 2 && tokstart[0] == 'i' && tokstart[1] == 'f')
1370     {
1371       return 0;
1372     }
1373
1374   lexptr += namelen;
1375
1376   /* Handle the tokens $digits; also $ (short for $0) and $$ (short for $$1)
1377      and $$digits (equivalent to $<-digits> if you could type that).
1378      Make token type LAST, and put the number (the digits) in yylval.  */
1379
1380   tryname:
1381   if (*tokstart == '$')
1382     {
1383       register int negate = 0;
1384       c = 1;
1385       /* Double dollar means negate the number and add -1 as well.
1386          Thus $$ alone means -1.  */
1387       if (namelen >= 2 && tokstart[1] == '$')
1388         {
1389           negate = 1;
1390           c = 2;
1391         }
1392       if (c == namelen)
1393         {
1394           /* Just dollars (one or two) */
1395           yylval.lval = - negate;
1396           return LAST;
1397         }
1398       /* Is the rest of the token digits?  */
1399       for (; c < namelen; c++)
1400         if (!(tokstart[c] >= '0' && tokstart[c] <= '9'))
1401           break;
1402       if (c == namelen)
1403         {
1404           yylval.lval = atoi (tokstart + 1 + negate);
1405           if (negate)
1406             yylval.lval = - yylval.lval;
1407           return LAST;
1408         }
1409     }
1410
1411   /* Handle tokens that refer to machine registers:
1412      $ followed by a register name.  */
1413
1414   if (*tokstart == '$') {
1415     for (c = 0; c < NUM_REGS; c++)
1416       if (namelen - 1 == strlen (reg_names[c])
1417           && STREQN (tokstart + 1, reg_names[c], namelen - 1))
1418         {
1419           yylval.lval = c;
1420           return REGNAME;
1421         }
1422     for (c = 0; c < num_std_regs; c++)
1423      if (namelen - 1 == strlen (std_regs[c].name)
1424          && STREQN (tokstart + 1, std_regs[c].name, namelen - 1))
1425        {
1426          yylval.lval = std_regs[c].regnum;
1427          return REGNAME;
1428        }
1429   }
1430   /* Catch specific keywords.  Should be done with a data structure.  */
1431   switch (namelen)
1432     {
1433     case 8:
1434       if (STREQN (tokstart, "unsigned", 8))
1435         return UNSIGNED;
1436       if (current_language->la_language == language_cplus
1437           && STREQN (tokstart, "template", 8))
1438         return TEMPLATE;
1439       if (STREQN (tokstart, "volatile", 8))
1440         return VOLATILE_KEYWORD;
1441       break;
1442     case 6:
1443       if (STREQN (tokstart, "struct", 6))
1444         return STRUCT;
1445       if (STREQN (tokstart, "signed", 6))
1446         return SIGNED_KEYWORD;
1447       if (STREQN (tokstart, "sizeof", 6))
1448         return SIZEOF;
1449       break;
1450     case 5:
1451       if (current_language->la_language == language_cplus
1452           && STREQN (tokstart, "class", 5))
1453         return CLASS;
1454       if (STREQN (tokstart, "union", 5))
1455         return UNION;
1456       if (STREQN (tokstart, "short", 5))
1457         return SHORT;
1458       if (STREQN (tokstart, "const", 5))
1459         return CONST_KEYWORD;
1460       break;
1461     case 4:
1462       if (STREQN (tokstart, "enum", 4))
1463         return ENUM;
1464       if (STREQN (tokstart, "long", 4))
1465         return LONG;
1466       if (current_language->la_language == language_cplus
1467           && STREQN (tokstart, "this", 4))
1468         {
1469           static const char this_name[] =
1470                                  { CPLUS_MARKER, 't', 'h', 'i', 's', '\0' };
1471
1472           if (lookup_symbol (this_name, expression_context_block,
1473                              VAR_NAMESPACE, 0, NULL))
1474             return THIS;
1475         }
1476       break;
1477     case 3:
1478       if (STREQN (tokstart, "int", 3))
1479         return INT_KEYWORD;
1480       break;
1481     default:
1482       break;
1483     }
1484
1485   yylval.sval.ptr = tokstart;
1486   yylval.sval.length = namelen;
1487
1488   /* Any other names starting in $ are debugger internal variables.  */
1489
1490   if (*tokstart == '$')
1491     {
1492       yylval.ivar =  lookup_internalvar (copy_name (yylval.sval) + 1);
1493       return VARIABLE;
1494     }
1495
1496   /* Use token-type BLOCKNAME for symbols that happen to be defined as
1497      functions or symtabs.  If this is not so, then ...
1498      Use token-type TYPENAME for symbols that happen to be defined
1499      currently as names of types; NAME for other symbols.
1500      The caller is not constrained to care about the distinction.  */
1501   {
1502     char *tmp = copy_name (yylval.sval);
1503     struct symbol *sym;
1504     int is_a_field_of_this = 0;
1505     int hextype;
1506
1507     sym = lookup_symbol (tmp, expression_context_block,
1508                          VAR_NAMESPACE,
1509                          current_language->la_language == language_cplus
1510                          ? &is_a_field_of_this : NULL,
1511                          NULL);
1512     if ((sym && SYMBOL_CLASS (sym) == LOC_BLOCK) ||
1513         lookup_partial_symtab (tmp))
1514       {
1515         yylval.ssym.sym = sym;
1516         yylval.ssym.is_a_field_of_this = is_a_field_of_this;
1517         return BLOCKNAME;
1518       }
1519     if (sym && SYMBOL_CLASS (sym) == LOC_TYPEDEF)
1520         {
1521           yylval.tsym.type = SYMBOL_TYPE (sym);
1522           return TYPENAME;
1523         }
1524     if ((yylval.tsym.type = lookup_primitive_typename (tmp)) != 0)
1525         return TYPENAME;
1526
1527     /* Input names that aren't symbols but ARE valid hex numbers,
1528        when the input radix permits them, can be names or numbers
1529        depending on the parse.  Note we support radixes > 16 here.  */
1530     if (!sym &&
1531         ((tokstart[0] >= 'a' && tokstart[0] < 'a' + input_radix - 10) ||
1532          (tokstart[0] >= 'A' && tokstart[0] < 'A' + input_radix - 10)))
1533       {
1534         YYSTYPE newlval;        /* Its value is ignored.  */
1535         hextype = parse_number (tokstart, namelen, 0, &newlval);
1536         if (hextype == INT)
1537           {
1538             yylval.ssym.sym = sym;
1539             yylval.ssym.is_a_field_of_this = is_a_field_of_this;
1540             return NAME_OR_INT;
1541           }
1542       }
1543
1544     /* Any other kind of symbol */
1545     yylval.ssym.sym = sym;
1546     yylval.ssym.is_a_field_of_this = is_a_field_of_this;
1547     return NAME;
1548   }
1549 }
1550
1551 void
1552 yyerror (msg)
1553      char *msg;
1554 {
1555   error (msg ? msg : "Invalid syntax in expression.");
1556 }