gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009, 2010
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # GDB does not use automake, but gnulib does.  This line lets us
  91 # generate its Makefile.in.
  92 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  93
  94 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  95     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  96     [${libdir}/debug])
  97
  98 # GDB's datadir relocation
  99
 100 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 101     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 102     [${datadir}/gdb])
 103
 104 AC_ARG_WITH(relocated-sources,
 105 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 106 [reloc_srcdir="${withval}"
 107  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 108               [Relocated directory for source files. ])
 109 ])
 110
 111 AC_CONFIG_SUBDIRS(doc testsuite)
 112
 113 # Check whether to support alternative target configurations
 114 AC_ARG_ENABLE(targets,
 115 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 116 [case "${enableval}" in
 117   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 118             ;;
 119   no)       enable_targets= ;;
 120   *)        enable_targets=$enableval ;;
 121 esac])
 122
 123 # Check whether to enable 64-bit support on 32-bit hosts
 124 AC_ARG_ENABLE(64-bit-bfd,
 125 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 126 [case "${enableval}" in
 127   yes)  want64=true  ;;
 128   no)   want64=false ;;
 129   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 130 esac],[want64=false])dnl
 131
 132 # Provide defaults for some variables set by the per-host and per-target
 133 # configuration.
 134 gdb_host_obs=posix-hdep.o
 135
 136 if test "${target}" = "${host}"; then
 137   gdb_native=yes
 138 else
 139   gdb_native=no
 140 fi
 141
 142 . $srcdir/configure.host
 143
 144 # Accumulate some settings from configure.tgt over all enabled targets
 145
 146 TARGET_OBS=
 147 all_targets=
 148
 149 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 150 do
 151   if test "$targ_alias" = "all"; then
 152     all_targets=true
 153   else
 154     # Canonicalize the secondary target names.
 155     result=`$ac_config_sub $targ_alias 2>/dev/null`
 156     if test -n "$result"; then
 157         targ=$result
 158     else
 159         targ=$targ_alias
 160     fi
 161
 162     . ${srcdir}/configure.tgt
 163
 164     AS_IF([test -z "${gdb_target_obs}"],
 165       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 166
 167     # Target-specific object files
 168     for i in ${gdb_target_obs}; do
 169         case " $TARGET_OBS " in
 170         *" ${i} "*) ;;
 171         *)
 172           TARGET_OBS="$TARGET_OBS ${i}"
 173           ;;
 174         esac
 175     done
 176
 177     # Check whether this target needs 64-bit CORE_ADDR
 178     if test x${want64} = xfalse; then
 179       . ${srcdir}/../bfd/config.bfd
 180     fi
 181   fi
 182 done
 183
 184 if test x${all_targets} = xtrue; then
 185
 186   # We want all 64-bit targets if we either:
 187   #  - run on a 64-bit host  or
 188   #  - already require 64-bit support for some other target  or
 189   #  - the --enable-64-bit-bfd option was supplied
 190   # Otherwise we only support all 32-bit targets.
 191   #
 192   # NOTE: This test must be in sync with the corresponding
 193   #       tests in BFD!
 194
 195   if test x${want64} = xfalse; then
 196     AC_CHECK_SIZEOF(long)
 197     if test "x${ac_cv_sizeof_long}" = "x8"; then
 198       want64=true
 199     fi
 200   fi
 201   if test x${want64} = xtrue; then
 202     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 203   else
 204     TARGET_OBS='$(ALL_TARGET_OBS)'
 205   fi
 206 fi
 207
 208 AC_SUBST(TARGET_OBS)
 209
 210 # For other settings, only the main target counts.
 211 gdb_sim=
 212 gdb_osabi=
 213 build_gdbserver=
 214 targ=$target; . ${srcdir}/configure.tgt
 215
 216 # Fetch the default architecture and default target vector from BFD.
 217 targ=$target; . $srcdir/../bfd/config.bfd
 218
 219 # We only want the first architecture, so strip off the others if
 220 # there is more than one.
 221 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 222
 223 if test "x$targ_archs" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 225     [Define to BFD's default architecture. ])
 226 fi
 227 if test "x$targ_defvec" != x; then
 228   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 229     [Define to BFD's default target vector. ])
 230 fi
 231
 232 # The CLI cannot be disabled yet, but may be in the future.
 233
 234 # Enable CLI.
 235 AC_ARG_ENABLE(gdbcli,
 236 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 237   [case $enableval in
 238     yes)
 239       ;;
 240     no)
 241       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 242     *)
 243       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 244   esac],
 245   [enable_gdbcli=yes])
 246 if test x"$enable_gdbcli" = xyes; then
 247   if test -d $srcdir/cli; then
 248     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 249     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 250     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 251     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 252   fi
 253 fi
 254
 255 # Enable MI.
 256 AC_ARG_ENABLE(gdbmi,
 257 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 258   [case $enableval in
 259     yes | no)
 260       ;;
 261     *)
 262       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 263   esac],
 264   [enable_gdbmi=yes])
 265 if test x"$enable_gdbmi" = xyes; then
 266   if test -d $srcdir/mi; then
 267     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 268     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 269     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 270     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 271   fi
 272 fi
 273
 274 # Enable TUI.
 275 AC_ARG_ENABLE(tui,
 276 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 277   [case $enableval in
 278     yes | no | auto)
 279       ;;
 280     *)
 281       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 282   esac],enable_tui=auto)
 283
 284 # Enable gdbtk.
 285 AC_ARG_ENABLE(gdbtk,
 286 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 287   [case $enableval in
 288     yes | no)
 289       ;;
 290     *)
 291       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 292   esac],
 293   [if test -d $srcdir/gdbtk; then
 294     enable_gdbtk=yes
 295   else
 296     enable_gdbtk=no
 297   fi])
 298 # We unconditionally disable gdbtk tests on selected platforms.
 299 case $host_os in
 300   go32* | windows*)
 301     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 302     enable_gdbtk=no ;;
 303 esac
 304
 305 # Libunwind support.
 306 AC_ARG_WITH(libunwind,
 307 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 308 [case "${withval}" in
 309   yes)  enable_libunwind=yes ;;
 310   no)   enable_libunwind=no ;;
 311   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 312 esac],[
 313   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 314   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 315     enable_libunwind=yes;
 316   fi
 317 ])
 318
 319 if test x"$enable_libunwind" = xyes; then
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 322   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 323   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 324   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 325 fi
 326
 327 opt_curses=no
 328 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 329
 330 prefer_curses=no
 331 if test "$opt_curses" = "yes"; then
 332   prefer_curses=yes
 333 fi
 334
 335 # Profiling support.
 336 AC_ARG_ENABLE(profiling,
 337 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 338   [case $enableval in
 339     yes | no)
 340       ;;
 341     *)
 342       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 343   esac],
 344  [enable_profiling=no])
 345
 346 AC_CHECK_FUNCS(monstartup _mcleanup)
 347 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 348 [AC_TRY_LINK(
 349 [#include <stdlib.h>
 350 extern char _etext;
 351 ],
 352 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 353 if test $ac_cv_var__etext = yes; then
 354   AC_DEFINE(HAVE__ETEXT, 1,
 355             [Define to 1 if your system has the _etext variable. ])
 356 fi
 357 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 358 [AC_TRY_LINK(
 359 [#include <stdlib.h>
 360 extern char etext;
 361 ],
 362 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 363 if test $ac_cv_var_etext = yes; then
 364   AC_DEFINE(HAVE_ETEXT, 1,
 365             [Define to 1 if your system has the etext variable. ])
 366 fi
 367 if test "$enable_profiling" = yes ; then
 368   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 369     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 370   fi
 371   PROFILE_CFLAGS=-pg
 372   OLD_CFLAGS="$CFLAGS"
 373   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 374
 375   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 376     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 377      ac_cv_cc_supports_pg=no)])
 378
 379   if test $ac_cv_cc_supports_pg = no; then
 380     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 381   fi
 382
 383   CFLAGS="$OLD_CFLAGS"
 384 fi
 385
 386 ACX_PKGVERSION([GDB])
 387 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 388 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 389 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 390
 391 # --------------------- #
 392 # Checks for programs.  #
 393 # --------------------- #
 394
 395 AC_PROG_AWK
 396 AC_PROG_INSTALL
 397 AC_PROG_LN_S
 398 AC_PROG_RANLIB
 399 AC_PROG_YACC
 400
 401 AC_CHECK_TOOL(AR, ar)
 402 AC_CHECK_TOOL(DLLTOOL, dlltool)
 403 AC_CHECK_TOOL(WINDRES, windres)
 404
 405 # Needed for GNU/Hurd.
 406 AC_CHECK_TOOL(MIG, mig)
 407
 408 # ---------------------- #
 409 # Checks for libraries.  #
 410 # ---------------------- #
 411
 412 # We might need to link with -lm; most simulators need it.
 413 AC_CHECK_LIB(m, main)
 414
 415 # We need to link with -lw to get `wctype' on Solaris before Solaris
 416 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 417 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 418 # is known to have this problem).  Therefore we avoid libw if we can.
 419 AC_CHECK_FUNC(wctype, [],
 420   [AC_CHECK_LIB(w, wctype)])
 421
 422 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 423 AC_SEARCH_LIBS(gethostbyname, nsl)
 424
 425 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 426 AC_SEARCH_LIBS(socketpair, socket)
 427
 428 # Link in zlib if we can.  This allows us to read compressed debug sections.
 429 AM_ZLIB
 430
 431 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 432 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 433
 434 AM_ICONV
 435
 436 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 437 # There is a very specific comment in /usr/include/curses.h explaining that
 438 # termcap routines built into libcurses must not be used.
 439 #
 440 # The symptoms we observed so far is GDB unexpectedly changing
 441 # the terminal settings when tgetent is called - this is particularly
 442 # visible as the output is missing carriage returns, and so rapidly
 443 # becomes very hard to read.
 444 #
 445 # The readline configure script has already decided that libtermcap
 446 # was enough for its purposes, and so decided to build readline using
 447 # libtermcap.  Since the TUI mode requires curses, building GDB with
 448 # TUI enabled results in both libraries to be used at the same time,
 449 # which is not allowed.  This basically means that GDB with TUI is
 450 # broken on alpha-osf.
 451
 452 case $host_os in
 453   osf* )
 454     if test x"$enable_tui" = xyes; then
 455       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 456     fi
 457     if test x"$enable_tui" = xauto; then
 458       enable_tui=no
 459     fi
 460     ;;
 461 esac
 462
 463 # For the TUI, we need enhanced curses functionality.
 464 if test x"$enable_tui" != xno; then
 465   prefer_curses=yes
 466 fi
 467
 468 curses_found=no
 469 if test x"$prefer_curses" = xyes; then
 470   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 471   # curses library because the latter might not provide all the
 472   # functionality we need.  However, this leads to problems on systems
 473   # where the linker searches /usr/local/lib, but the compiler doesn't
 474   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 475   # default installation of ncurses on alpha*-dec-osf* will lead to such
 476   # a situation.
 477   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 478
 479   if test "$ac_cv_search_waddstr" != no; then
 480     curses_found=yes
 481   fi
 482 fi
 483
 484 # Check whether we should enable the TUI, but only do so if we really
 485 # can.
 486 if test x"$enable_tui" != xno; then
 487   if test -d $srcdir/tui; then
 488     if test "$curses_found" != no; then
 489       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 490       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 491       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 492       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 493       CONFIG_ALL="${CONFIG_ALL} all-tui"
 494       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 495       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 496       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 497     else
 498       if test x"$enable_tui" = xyes; then
 499         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 500       else
 501         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 502       fi
 503     fi
 504   fi
 505 fi
 506
 507 # Since GDB uses Readline, we need termcap functionality.  In many
 508 # cases this will be provided by the curses library, but some systems
 509 # have a seperate termcap library, or no curses library at all.
 510
 511 case $host_os in
 512   cygwin*)
 513     if test -d $srcdir/libtermcap; then
 514       LIBS="../libtermcap/libtermcap.a $LIBS"
 515       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 516     fi ;;
 517   go32* | *djgpp*)
 518     ac_cv_search_tgetent="none required"
 519     ;;
 520   *mingw32*)
 521     ac_cv_search_tgetent="none required"
 522     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 523     ;;
 524 esac
 525
 526 # These are the libraries checked by Readline.
 527 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 528
 529 if test "$ac_cv_search_tgetent" = no; then
 530   AC_MSG_ERROR([no termcap library found])
 531 fi
 532
 533 AC_ARG_WITH([system-readline],
 534   [AS_HELP_STRING([--with-system-readline],
 535                   [use installed readline library])])
 536
 537 if test "$with_system_readline" = yes; then
 538   READLINE=-lreadline
 539   READLINE_DEPS=
 540   READLINE_CFLAGS=
 541
 542   # readline-6.0 started to use the name `_rl_echoing_p'.
 543   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 544
 545   AC_MSG_CHECKING([for readline_echoing_p])
 546   save_LIBS=$LIBS
 547   LIBS="$LIBS $READLINE"
 548   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 549                                     return readline_echoing_p;]]),
 550                  [READLINE_ECHOING_P=yes],
 551                  [READLINE_ECHOING_P=no
 552                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 553                             [readline-6.0 started to use different name.])])
 554   LIBS="$save_LIBS"
 555   AC_MSG_RESULT([$READLINE_ECHOING_P])
 556 else
 557   READLINE='$(READLINE_DIR)/libreadline.a'
 558   READLINE_DEPS='$(READLINE)'
 559   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 560 fi
 561 AC_SUBST(READLINE)
 562 AC_SUBST(READLINE_DEPS)
 563 AC_SUBST(READLINE_CFLAGS)
 564
 565 AC_ARG_WITH(expat,
 566   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 567   [], [with_expat=auto])
 568 AC_MSG_CHECKING([whether to use expat])
 569 AC_MSG_RESULT([$with_expat])
 570
 571 if test "${with_expat}" = no; then
 572   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 573   HAVE_LIBEXPAT=no
 574 else
 575   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 576                         [XML_Parser p = XML_ParserCreate (0);])
 577   if test "$HAVE_LIBEXPAT" != yes; then
 578     if test "$with_expat" = yes; then
 579       AC_MSG_ERROR([expat is missing or unusable])
 580     else
 581       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 582     fi
 583   else
 584     save_LIBS=$LIBS
 585     LIBS="$LIBS $LIBEXPAT"
 586     AC_CHECK_FUNCS(XML_StopParser)
 587     LIBS=$save_LIBS
 588   fi
 589 fi
 590
 591 dnl Utility to simplify finding libpython.
 592 AC_DEFUN([AC_TRY_LIBPYTHON],
 593 [
 594   version=$1
 595   define([have_libpython_var],$2)
 596   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 597                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 598   [HAVE_LIB]VERSION=no
 599   AC_MSG_CHECKING([for ${version}])
 600   save_LIBS=$LIBS
 601   LIBS="$LIBS -l${version}"
 602   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 603                                  [[Py_Initialize ();]]),
 604                  [[HAVE_LIB]VERSION=yes
 605                   have_libpython_var=yes],
 606                  [LIBS=$save_LIBS])
 607   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 608 ])
 609
 610 AC_ARG_WITH(python,
 611   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 612   [], [with_python=auto])
 613 AC_MSG_CHECKING([whether to use python])
 614 AC_MSG_RESULT([$with_python])
 615
 616 if test "${with_python}" = no; then
 617   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 618   have_libpython=no
 619 else
 620   case "${with_python}" in
 621   yes | auto)
 622     # Leave as empty, use defaults.
 623     python_includes=
 624     python_libs=
 625     ;;
 626   /*)
 627     python_includes="-I${with_python}/include"
 628     python_libs="-L${with_python}/lib"
 629     ;;
 630   *)
 631     AC_ERROR(invalid value for --with-python)
 632     ;;
 633   esac
 634
 635   save_CPPFLAGS=$CPPFLAGS
 636   CPPFLAGS="$CPPFLAGS ${python_includes}"
 637   save_LIBS=$LIBS
 638   LIBS="$LIBS ${python_libs}"
 639   have_libpython=no
 640   if test "${have_libpython}" = no; then
 641     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 642     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 643       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 644     fi
 645   fi
 646   if test ${have_libpython} = no; then
 647     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 648     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 649       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 650     fi
 651   fi
 652   if test ${have_libpython} = no; then
 653     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 654     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 655       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 656     fi
 657   fi
 658   if test ${have_libpython} = no; then
 659     case "${with_python}" in
 660     yes)
 661       AC_MSG_ERROR([python is missing or unusable])
 662       ;;
 663     auto)
 664       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 665       ;;
 666     *)
 667       AC_MSG_ERROR([no usable python found at ${with_python}])
 668       ;;
 669     esac
 670     CPPFLAGS=$save_CPPFLAGS
 671     LIBS=$save_LIBS
 672   fi
 673 fi
 674
 675 if test "${have_libpython}" = yes; then
 676   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 677   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 678   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 679   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 680   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 681
 682   # Flags needed to compile Python code (taken from python-config --cflags).
 683   # We cannot call python-config directly because it will output whatever was
 684   # used when compiling the Python interpreter itself, including flags which
 685   # would make the python-related objects be compiled differently from the
 686   # rest of GDB (e.g., -O2 and -fPIC).
 687   if test "${GCC}" = yes; then
 688     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 689   fi
 690
 691   if test "x${tentative_python_cflags}" != x; then
 692     AC_MSG_CHECKING(compiler flags for python code)
 693     for flag in ${tentative_python_cflags}; do
 694       # Check that the compiler accepts it
 695       saved_CFLAGS="$CFLAGS"
 696       CFLAGS="$CFLAGS $flag"
 697       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 698       CFLAGS="$saved_CFLAGS"
 699     done
 700     AC_MSG_RESULT(${PYTHON_CFLAGS})
 701   fi
 702 else
 703   # Even if Python support is not compiled in, we need to have these files
 704   # included.
 705   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 706   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 707         python/py-prettyprint.c python/py-auto-load.c"
 708 fi
 709 AC_SUBST(PYTHON_CFLAGS)
 710
 711 # ------------------------- #
 712 # Checks for header files.  #
 713 # ------------------------- #
 714
 715 AC_HEADER_DIRENT
 716 AC_HEADER_STAT
 717 AC_HEADER_STDC
 718 # elf_hp.h is for HP/UX 64-bit shared library support.
 719 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 720 # unconditionally, so what's the point in checking these?
 721 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 722                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 723                   stdlib.h string.h memory.h strings.h sys/fault.h \
 724                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 725                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 726                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 727                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 728                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 729 AC_CHECK_HEADERS(link.h, [], [],
 730 [#if HAVE_SYS_TYPES_H
 731 # include <sys/types.h>
 732 #endif
 733 #if HAVE_NLIST_H
 734 # include <nlist.h>
 735 #endif
 736 ])
 737 AC_CHECK_HEADERS(sys/proc.h, [], [],
 738 [#if HAVE_SYS_PARAM_H
 739 # include <sys/param.h>
 740 #endif
 741 ])
 742 AC_CHECK_HEADERS(sys/user.h, [], [],
 743 [#if HAVE_SYS_PARAM_H
 744 # include <sys/param.h>
 745 #endif
 746 ])
 747
 748 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 749 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 750 # think that we don't have <curses.h> if we're using GCC.
 751 case $host_os in
 752   solaris2.[[789]])
 753     if test "$GCC" = yes; then
 754       AC_DEFINE(_MSE_INT_H, 1,
 755         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 756    Solaris 2.[789] when using GCC. ])
 757     fi ;;
 758 esac
 759 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 760 AC_CHECK_HEADERS(term.h, [], [],
 761 [#if HAVE_CURSES_H
 762 # include <curses.h>
 763 #endif
 764 ])
 765
 766 # ------------------------- #
 767 # Checks for declarations.  #
 768 # ------------------------- #
 769
 770 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 771                 snprintf, vsnprintf])
 772 AM_LC_MESSAGES
 773
 774 # ----------------------- #
 775 # Checks for structures.  #
 776 # ----------------------- #
 777
 778 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 779
 780 # ------------------ #
 781 # Checks for types.  #
 782 # ------------------ #
 783
 784 AC_TYPE_SIGNAL
 785 AC_CHECK_TYPES(socklen_t, [], [],
 786 [#include <sys/types.h>
 787 #include <sys/socket.h>
 788 ])
 789
 790 # ------------------------------------- #
 791 # Checks for compiler characteristics.  #
 792 # ------------------------------------- #
 793
 794 AC_C_CONST
 795 AC_C_INLINE
 796 AC_C_BIGENDIAN
 797
 798 # ------------------------------ #
 799 # Checks for library functions.  #
 800 # ------------------------------ #
 801
 802 AC_FUNC_ALLOCA
 803 AC_FUNC_MMAP
 804 AC_FUNC_VFORK
 805 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 806                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 807                 sigaction sigprocmask sigsetmask socketpair syscall \
 808                 ttrace wborder setlocale iconvlist libiconvlist btowc \
 809                 setrlimit getrlimit posix_madvise])
 810 AM_LANGINFO_CODESET
 811
 812 # Check the return and argument types of ptrace.  No canned test for
 813 # this, so roll our own.
 814 gdb_ptrace_headers='
 815 #if HAVE_SYS_TYPES_H
 816 # include <sys/types.h>
 817 #endif
 818 #if HAVE_SYS_PTRACE_H
 819 # include <sys/ptrace.h>
 820 #endif
 821 #if HAVE_UNISTD_H
 822 # include <unistd.h>
 823 #endif
 824 '
 825 # There is no point in checking if we don't have a prototype.
 826 AC_CHECK_DECLS(ptrace, [], [
 827   : ${gdb_cv_func_ptrace_ret='int'}
 828   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 829 ], $gdb_ptrace_headers)
 830 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 831 # empty argument list, so check for that explicitly.
 832 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 833   AC_TRY_COMPILE($gdb_ptrace_headers,
 834     [extern long ptrace (enum __ptrace_request, ...);],
 835     gdb_cv_func_ptrace_ret='long',
 836     AC_TRY_COMPILE($gdb_ptrace_headers,
 837       [extern int ptrace ();],
 838       gdb_cv_func_ptrace_ret='int',
 839       gdb_cv_func_ptrace_ret='long')))
 840 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 841   [Define as the return type of ptrace.])
 842 # Check argument types.
 843 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 844   AC_TRY_COMPILE($gdb_ptrace_headers,
 845     [extern long ptrace (enum __ptrace_request, ...);],
 846     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 847 for gdb_arg1 in 'int' 'long'; do
 848  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 849   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 850    for gdb_arg4 in 'int' 'long'; do
 851      AC_TRY_COMPILE($gdb_ptrace_headers, [
 852 extern $gdb_cv_func_ptrace_ret
 853   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 854 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 855     break 4;])
 856     for gdb_arg5 in 'int *' 'int' 'long'; do
 857      AC_TRY_COMPILE($gdb_ptrace_headers, [
 858 extern $gdb_cv_func_ptrace_ret
 859   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 860 ], [
 861 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 862     break 5;])
 863     done
 864    done
 865   done
 866  done
 867 done
 868 # Provide a safe default value.
 869 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 870 ])])
 871 ac_save_IFS=$IFS; IFS=','
 872 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 873 IFS=$ac_save_IFS
 874 shift
 875 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 876   [Define to the type of arg 3 for ptrace.])
 877 if test -n "$[5]"; then
 878   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 879     [Define to the type of arg 5 for ptrace.])
 880 fi
 881
 882 dnl AC_FUNC_SETPGRP does not work when cross compiling
 883 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 884 if test "$cross_compiling" = no; then
 885   AC_FUNC_SETPGRP
 886 else
 887   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 888     [AC_TRY_COMPILE([
 889 #include <unistd.h>
 890 ], [
 891   if (setpgrp(1,1) == -1)
 892     exit (0);
 893   else
 894     exit (1);
 895 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 896 if test $ac_cv_func_setpgrp_void = yes; then
 897   AC_DEFINE(SETPGRP_VOID, 1)
 898 fi
 899 fi
 900
 901 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 902 # since sigsetjmp might only be defined as a macro.
 903 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 904 [AC_TRY_COMPILE([
 905 #include <setjmp.h>
 906 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 907 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 908 if test $gdb_cv_func_sigsetjmp = yes; then
 909   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 910 fi
 911
 912 # Assume we'll default to using the included libiberty regex.
 913 gdb_use_included_regex=yes
 914
 915 # However, if the system regex is GNU regex, then default to *not*
 916 # using the included regex.
 917 AC_CACHE_CHECK(
 918   [for GNU regex],
 919   [gdb_cv_have_gnu_regex],
 920   [AC_TRY_COMPILE(
 921     [#include <gnu-versions.h>],
 922     [#define REGEX_INTERFACE_VERSION 1
 923 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 924 # error "Version mismatch"
 925 #endif],
 926     gdb_cv_have_gnu_regex=yes,
 927     gdb_cv_have_gnu_regex=no)])
 928 if test $gdb_cv_have_gnu_regex = yes; then
 929   gdb_use_included_regex=no
 930 fi
 931
 932 AC_ARG_WITH(included-regex,
 933   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
 934   gdb_with_regex=$withval,
 935   gdb_with_regex=$gdb_use_included_regex)
 936 if test "$gdb_with_regex" = yes; then
 937   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 938     [Define to 1 if the regex included in libiberty should be used.])
 939 fi
 940
 941 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 942 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 943 [#include <sys/param.h>
 944 #include <sys/proc.h>
 945 ])
 946
 947 # See if <sys/lwp.h> defines `struct lwp`.
 948 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 949 [AC_TRY_COMPILE([#include <sys/param.h>
 950 #include <sys/lwp.h>], [struct lwp l;],
 951 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 952 if test $gdb_cv_struct_lwp = yes; then
 953   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 954             [Define to 1 if your system has struct lwp.])
 955 fi
 956
 957 # See if <machine/reg.h> degines `struct reg'.
 958 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 959 [AC_TRY_COMPILE([#include <sys/types.h>
 960 #include <machine/reg.h>], [struct reg r;],
 961 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 962 if test $gdb_cv_struct_reg = yes; then
 963   AC_DEFINE(HAVE_STRUCT_REG, 1,
 964             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 965 fi
 966
 967 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 968 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 969 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 970                  [#include <machine/reg.h>])
 971
 972 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 973 AC_MSG_CHECKING(for PTRACE_GETREGS)
 974 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 975 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 976                 [PTRACE_GETREGS;],
 977                 [gdb_cv_have_ptrace_getregs=yes],
 978                 [gdb_cv_have_ptrace_getregs=no])])
 979 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 980 if test $gdb_cv_have_ptrace_getregs = yes; then
 981   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 982   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 983 fi
 984
 985 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 986 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 987 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 988 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 989                 [PTRACE_GETFPXREGS;],
 990                 [gdb_cv_have_ptrace_getfpxregs=yes],
 991                 [gdb_cv_have_ptrace_getfpxregs=no])])
 992 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 993 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 994   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 995   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 996 fi
 997
 998 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 999 AC_MSG_CHECKING(for PT_GETDBREGS)
1000 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1001 [AC_TRY_COMPILE([#include <sys/types.h>
1002 #include <sys/ptrace.h>],
1003                 [PT_GETDBREGS;],
1004                 [gdb_cv_have_pt_getdbregs=yes],
1005                 [gdb_cv_have_pt_getdbregs=no])])
1006 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1007 if test $gdb_cv_have_pt_getdbregs = yes; then
1008   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1009   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1010 fi
1011
1012 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1013 AC_MSG_CHECKING(for PT_GETXMMREGS)
1014 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1015 [AC_TRY_COMPILE([#include <sys/types.h>
1016 #include <sys/ptrace.h>],
1017                 [PT_GETXMMREGS;],
1018                 [gdb_cv_have_pt_getxmmregs=yes],
1019                 [gdb_cv_have_pt_getxmmregs=no])])
1020 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1021 if test $gdb_cv_have_pt_getxmmregs = yes; then
1022   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1023   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1024 fi
1025
1026 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1027
1028 if test "${target}" = "${host}"; then
1029   case "${host}" in
1030   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1031       AC_DEFINE(NEW_PROC_API, 1,
1032       [Define if you want to use new multi-fd /proc interface
1033        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1034       ;;
1035   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1036       AC_DEFINE(NEW_PROC_API, 1,
1037       [Define if you want to use new multi-fd /proc interface
1038        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1039       ;;
1040   mips-sgi-irix5*)
1041       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1042       AC_DEFINE([_KMEMUSER], 1,
1043       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1044        around a <sys/proc.h> problem on IRIX 5.])
1045       ;;
1046   esac
1047 fi
1048
1049 if test "$ac_cv_header_sys_procfs_h" = yes; then
1050   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1051   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1052   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1053   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1054   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1055   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1056   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1057   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1058   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1059   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1060   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1061   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1062   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1063   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1064
1065
1066   dnl Check for broken prfpregset_t type
1067
1068   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1069   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1070   dnl instead of the struct itself).  We detect this here, and work
1071   dnl around it in gdb_proc_service.h.
1072
1073   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1074     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1075     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1076       [AC_TRY_RUN([#include <sys/procfs.h>
1077        int main ()
1078        {
1079          if (sizeof (prfpregset_t) == sizeof (void *))
1080            return 1;
1081          return 0;
1082        }],
1083        gdb_cv_prfpregset_t_broken=no,
1084        gdb_cv_prfpregset_t_broken=yes,
1085        gdb_cv_prfpregset_t_broken=yes)])
1086     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1087     if test $gdb_cv_prfpregset_t_broken = yes; then
1088       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1089       [Define if the prfpregset_t type is broken.])
1090     fi
1091   fi
1092
1093   dnl Check for PIOCSET ioctl entry
1094
1095   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1096   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1097   [AC_TRY_COMPILE([#include <unistd.h>
1098 #include <sys/types.h>
1099 #include <sys/procfs.h>
1100 ], [
1101     int dummy;;
1102     dummy = ioctl(0, PIOCSET, &dummy);
1103   ],
1104   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1105   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1106   if test $gdb_cv_have_procfs_piocset = yes; then
1107     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1108     [Define if ioctl argument PIOCSET is available.])
1109   fi
1110 fi
1111
1112 dnl For native ports (host == target), check to see what kind of
1113 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1114 if test ${host} = ${target} ; then
1115   dnl Check for struct link_map with l_ members which are indicative
1116   dnl of SVR4-like shared libraries
1117
1118   AC_MSG_CHECKING(for member l_addr in struct link_map)
1119   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1120     [AC_TRY_COMPILE([#include <link.h>],
1121                     [struct link_map lm; (void) lm.l_addr;],
1122                     gdb_cv_have_struct_link_map_with_l_members=yes,
1123                     gdb_cv_have_struct_link_map_with_l_members=no)])
1124   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1125   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1126     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1127     [Define if <link.h> exists and defines struct link_map which has
1128      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1129      SVR4-like systems.)])
1130   fi
1131
1132   dnl Check for struct link_map with lm_ members which are indicative
1133   dnl of SunOS-like shared libraries
1134
1135   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1136   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1137     [AC_TRY_COMPILE([#include <sys/types.h>
1138 #include <link.h>],
1139                     [struct link_map lm; (void) lm.lm_addr;],
1140                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1141                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1142   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1143   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1144     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1145     [Define if <link.h> exists and defines struct link_map which has
1146      members with an ``lm_'' prefix.  (For SunOS.)])
1147   fi
1148
1149   dnl Check for struct so_map with som_ members which are found on
1150   dnl some *BSD systems.
1151
1152   AC_MSG_CHECKING(for member som_addr in struct so_map)
1153   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1154     [AC_TRY_COMPILE([#include <sys/types.h>
1155 #ifdef HAVE_NLIST_H
1156 #include <nlist.h>
1157 #endif
1158 #include <link.h>],
1159                     [struct so_map lm; (void) lm.som_addr;],
1160                     gdb_cv_have_struct_so_map_with_som_members=yes,
1161                     gdb_cv_have_struct_so_map_with_som_members=no)])
1162   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1163   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1164     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1165     [Define if <link.h> exists and defines a struct so_map which has
1166      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1167   fi
1168
1169   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1170   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1171
1172   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1173   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1174     [AC_TRY_COMPILE([#define _SYSCALL32
1175 #include <sys/link.h>], [struct link_map32 l;],
1176      gdb_cv_have_struct_link_map32=yes,
1177      gdb_cv_have_struct_link_map32=no)])
1178   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1179   if test $gdb_cv_have_struct_link_map32 = yes; then
1180     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1181     [Define if <sys/link.h> has struct link_map32])
1182     AC_DEFINE(_SYSCALL32, 1,
1183     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1184   fi
1185 fi
1186
1187 # Check if the compiler supports the `long long' type.
1188
1189 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1190                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1191 [[extern long long foo;]],
1192 [[switch (foo & 2) { case 0: return 1; }]])],
1193                                   gdb_cv_c_long_long=yes,
1194                                   gdb_cv_c_long_long=no)])
1195 if test $gdb_cv_c_long_long = yes; then
1196   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1197             [Define to 1 if the compiler supports long long.])
1198 fi
1199
1200 # Check if the compiler and runtime support printing long longs.
1201
1202 AC_CACHE_CHECK([for long long support in printf],
1203                gdb_cv_printf_has_long_long,
1204                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1205 [[char buf[32];
1206   long long l = 0;
1207   l = (l << 16) + 0x0123;
1208   l = (l << 16) + 0x4567;
1209   l = (l << 16) + 0x89ab;
1210   l = (l << 16) + 0xcdef;
1211   sprintf (buf, "0x%016llx", l);
1212   return (strcmp ("0x0123456789abcdef", buf));]])],
1213                               gdb_cv_printf_has_long_long=yes,
1214                               gdb_cv_printf_has_long_long=no,
1215                               gdb_cv_printf_has_long_long=no)])
1216 if test $gdb_cv_printf_has_long_long = yes; then
1217   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1218             [Define to 1 if the "%ll" format works to print long longs.])
1219 fi
1220
1221 # Check if the compiler and runtime support printing decfloats.
1222
1223 AC_CACHE_CHECK([for decfloat support in printf],
1224                gdb_cv_printf_has_decfloat,
1225                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1226 [[char buf[64];
1227   _Decimal32 d32 = 1.2345df;
1228   _Decimal64 d64 = 1.2345dd;
1229   _Decimal128 d128 = 1.2345dl;
1230   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1231   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1232                               gdb_cv_printf_has_decfloat=yes,
1233                               gdb_cv_printf_has_decfloat=no,
1234                               gdb_cv_printf_has_decfloat=no)])
1235 if test $gdb_cv_printf_has_decfloat = yes; then
1236   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1237             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1238 fi
1239
1240 # Check if the compiler supports the `long double' type.  We can't use
1241 # AC_C_LONG_DOUBLE because that one does additional checks on the
1242 # constants defined in <float.h> that fail on some systems,
1243 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1244
1245 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1246                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1247                                   gdb_cv_c_long_double=yes,
1248                                   gdb_cv_c_long_double=no)])
1249 if test $gdb_cv_c_long_double = yes; then
1250   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1251            [Define to 1 if the compiler supports long double.])
1252 fi
1253
1254 # Check if the compiler and runtime support printing long doubles.
1255
1256 AC_CACHE_CHECK([for long double support in printf],
1257                gdb_cv_printf_has_long_double,
1258                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1259 [[char buf[16];
1260   long double f = 3.141592653;
1261   sprintf (buf, "%Lg", f);
1262   return (strncmp ("3.14159", buf, 7));]])],
1263                               gdb_cv_printf_has_long_double=yes,
1264                               gdb_cv_printf_has_long_double=no,
1265                               gdb_cv_printf_has_long_double=no)])
1266 if test $gdb_cv_printf_has_long_double = yes; then
1267   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1268             [Define to 1 if the "%Lg" format works to print long doubles.])
1269 fi
1270
1271 # Check if the compiler and runtime support scanning long doubles.
1272
1273 AC_CACHE_CHECK([for long double support in scanf],
1274                gdb_cv_scanf_has_long_double,
1275                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1276 [[#include <stdio.h>]],
1277 [[char *buf = "3.141592653";
1278   long double f = 0;
1279   sscanf (buf, "%Lg", &f);
1280   return !(f > 3.14159 && f < 3.14160);]])],
1281                               gdb_cv_scanf_has_long_double=yes,
1282                               gdb_cv_scanf_has_long_double=no,
1283                               gdb_cv_scanf_has_long_double=no)])
1284 if test $gdb_cv_scanf_has_long_double = yes; then
1285   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1286             [Define to 1 if the "%Lg" format works to scan long doubles.])
1287 fi
1288
1289 case ${host_os} in
1290 aix*)
1291   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1292     SAVE_LDFLAGS=$LDFLAGS
1293
1294     case $GCC in
1295     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1296     *) gdb_cv_bigtoc=-bbigtoc ;;
1297     esac
1298
1299     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1300     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1301     LDFLAGS="${SAVE_LDFLAGS}"
1302   ])
1303   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1304   ;;
1305 esac
1306
1307
1308 dnl For certain native configurations, we need to check whether thread
1309 dnl support can be built in or not.
1310 dnl
1311 dnl Note that we only want this if we are both native (host == target),
1312 dnl and not doing a canadian cross build (build == host).
1313
1314 if test ${build} = ${host} -a ${host} = ${target} ; then
1315    case ${host_os} in
1316    hpux*)
1317       AC_MSG_CHECKING(for HPUX/OSF thread support)
1318       if test -f /usr/include/dce/cma_config.h ; then
1319          if test "$GCC" = "yes" ; then
1320             AC_MSG_RESULT(yes)
1321             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1322             [Define if you have HPUX threads])
1323             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1324             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1325          else
1326             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1327          fi
1328       else
1329          AC_MSG_RESULT(no)
1330       fi
1331       ;;
1332    solaris*)
1333       # See if thread_db library is around for Solaris thread debugging.
1334       # Note that we must explicitly test for version 1 of the library
1335       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1336       # the same API.
1337       AC_MSG_CHECKING(for Solaris thread debugging library)
1338       if test -f /usr/lib/libthread_db.so.1 ; then
1339          AC_MSG_RESULT(yes)
1340          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1341          [Define if using Solaris thread debugging.])
1342          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1343          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1344          AC_CHECK_LIB(dl, dlopen)
1345          if test "$GCC" = "yes" ; then
1346             # The GNU linker requires the -export-dynamic option to make
1347             # all symbols visible in the dynamic symbol table.
1348             hold_ldflags=$LDFLAGS
1349             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1350             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1351             AC_TRY_LINK(, [int i;], found=yes, found=no)
1352             LDFLAGS=$hold_ldflags
1353             AC_MSG_RESULT($found)
1354             if test $found = yes; then
1355                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1356             fi
1357          fi
1358          # Sun randomly tweaked the prototypes in <proc_service.h>
1359          # at one point.
1360          AC_MSG_CHECKING(if <proc_service.h> is old)
1361          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1362             AC_TRY_COMPILE([
1363                 #include <proc_service.h>
1364                 ps_err_e ps_pdwrite
1365                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1366             ],, gdb_cv_proc_service_is_old=no,
1367                 gdb_cv_proc_service_is_old=yes)
1368          ])
1369          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1370          if test $gdb_cv_proc_service_is_old = yes; then
1371             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1372             [Define if <proc_service.h> on solaris uses int instead of
1373              size_t, and assorted other type changes.])
1374          fi
1375       else
1376          AC_MSG_RESULT(no)
1377       fi
1378       ;;
1379    aix*)
1380       AC_MSG_CHECKING(for AiX thread debugging library)
1381       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1382                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1383                                    [#ifndef PTHDB_VERSION_3
1384                                     #error
1385                                     #endif],
1386                                    gdb_cv_have_aix_thread_debug=yes,
1387                                    gdb_cv_have_aix_thread_debug=no)])
1388       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1389       if test $gdb_cv_have_aix_thread_debug = yes; then
1390          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1391          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1392          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1393       fi
1394       ;;
1395    esac
1396    AC_SUBST(CONFIG_LDFLAGS)
1397 fi
1398
1399 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1400 dnl other error codes.
1401 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1402    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1403                   gdb_cv_thread_db_h_has_td_notalloc,
1404      AC_TRY_COMPILE(
1405        [#include <thread_db.h>],
1406        [int i = TD_NOTALLOC;],
1407        gdb_cv_thread_db_h_has_td_notalloc=yes,
1408        gdb_cv_thread_db_h_has_td_notalloc=no
1409      )
1410    )
1411    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1412                   gdb_cv_thread_db_h_has_td_version,
1413      AC_TRY_COMPILE(
1414        [#include <thread_db.h>],
1415        [int i = TD_VERSION;],
1416        gdb_cv_thread_db_h_has_td_version=yes,
1417        gdb_cv_thread_db_h_has_td_version=no
1418      )
1419    )
1420    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1421                   gdb_cv_thread_db_h_has_td_notls,
1422      AC_TRY_COMPILE(
1423        [#include <thread_db.h>],
1424        [int i = TD_NOTLS;],
1425        gdb_cv_thread_db_h_has_td_notls=yes,
1426        gdb_cv_thread_db_h_has_td_notls=no
1427      )
1428    )
1429 fi
1430 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1431   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1432             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1433 fi
1434 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1435   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1436             [Define if <thread_db.h> has the TD_VERSION error code.])
1437 fi
1438 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1439   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1440             [Define if <thread_db.h> has the TD_NOTLS error code.])
1441 fi
1442
1443 dnl See if we have a sys/syscall header file that has __NR_tkill.
1444 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1445    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1446                   gdb_cv_sys_syscall_h_has_tkill,
1447      AC_TRY_COMPILE(
1448        [#include <sys/syscall.h>],
1449        [int i = __NR_tkill;],
1450        gdb_cv_sys_syscall_h_has_tkill=yes,
1451        gdb_cv_sys_syscall_h_has_tkill=no
1452      )
1453    )
1454 fi
1455 dnl See if we can issue tkill syscall.
1456 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1457   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1458 fi
1459
1460 dnl Check if we can disable the virtual address space randomization.
1461 dnl The functionality of setarch -R.
1462 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1463 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1464 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1465 #       define ADDR_NO_RANDOMIZE 0x0040000
1466 #      endif
1467        /* Test the flag could be set and stays set.  */
1468        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1469        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1470            return 1])])
1471 AC_RUN_IFELSE([PERSONALITY_TEST],
1472               [have_personality=true],
1473               [have_personality=false],
1474               [AC_LINK_IFELSE([PERSONALITY_TEST],
1475                               [have_personality=true],
1476                               [have_personality=false])])
1477 if $have_personality
1478 then
1479     AC_DEFINE([HAVE_PERSONALITY], 1,
1480               [Define if you support the personality syscall.])
1481 fi
1482
1483 dnl Handle optional features that can be enabled.
1484
1485 target_sysroot_reloc=0
1486 AC_ARG_WITH(sysroot,
1487 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1488 [
1489  case ${with_sysroot} in
1490  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1491  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1492  esac
1493
1494  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1495
1496  if test "x$prefix" = xNONE; then
1497   test_prefix=/usr/local
1498  else
1499   test_prefix=$prefix
1500  fi
1501  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1502   test_exec_prefix=$test_prefix
1503  else
1504   test_exec_prefix=$exec_prefix
1505  fi
1506  case ${TARGET_SYSTEM_ROOT} in
1507  "${test_prefix}"|"${test_prefix}/"*|\
1508  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1509  '${prefix}'|'${prefix}/'*|\
1510  '${exec_prefix}'|'${exec_prefix}/'*)
1511    target_sysroot_reloc=1
1512    ;;
1513  esac
1514 ], [
1515  TARGET_SYSTEM_ROOT=
1516  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1517 ])
1518 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1519 AC_SUBST(TARGET_SYSTEM_ROOT)
1520 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1521
1522 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1523     [automatically load a system-wide gdbinit file],
1524     [])
1525
1526 AC_ARG_ENABLE(werror,
1527   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1528   [case "${enableval}" in
1529      yes | y) ERROR_ON_WARNING="yes" ;;
1530      no | n)  ERROR_ON_WARNING="no" ;;
1531      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1532    esac])
1533
1534 # Enable -Werror by default when using gcc
1535 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1536     ERROR_ON_WARNING=yes
1537 fi
1538
1539 WERROR_CFLAGS=""
1540 if test "${ERROR_ON_WARNING}" = yes ; then
1541     WERROR_CFLAGS="-Werror"
1542 fi
1543
1544 # The entries after -Wno-pointer-sign are disabled warnings which may
1545 # be enabled in the future, which can not currently be used to build
1546 # GDB.
1547 # NOTE: If you change this list, remember to update
1548 # gdb/doc/gdbint.texinfo.
1549 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1550 -Wformat-nonliteral -Wno-pointer-sign \
1551 -Wno-unused -Wunused-value -Wunused-function \
1552 -Wno-switch -Wno-char-subscripts"
1553
1554 # Enable -Wno-format by default when using gcc on mingw since many
1555 # GCC versions complain about %I64.
1556 case "${host}" in
1557   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1558 esac
1559
1560 AC_ARG_ENABLE(build-warnings,
1561 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1562 [case "${enableval}" in
1563   yes)  ;;
1564   no)   build_warnings="-w";;
1565   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1566         build_warnings="${build_warnings} ${t}";;
1567   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1568         build_warnings="${t} ${build_warnings}";;
1569   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1570 esac
1571 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1572   echo "Setting compiler warning flags = $build_warnings" 6>&1
1573 fi])dnl
1574 AC_ARG_ENABLE(gdb-build-warnings,
1575 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1576 [case "${enableval}" in
1577   yes)  ;;
1578   no)   build_warnings="-w";;
1579   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1580         build_warnings="${build_warnings} ${t}";;
1581   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1582         build_warnings="${t} ${build_warnings}";;
1583   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1584 esac
1585 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1586   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1587 fi])dnl
1588 WARN_CFLAGS=""
1589 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1590 then
1591     AC_MSG_CHECKING(compiler warning flags)
1592     # Separate out the -Werror flag as some files just cannot be
1593     # compiled with it enabled.
1594     for w in ${build_warnings}; do
1595         case $w in
1596         -Werr*) WERROR_CFLAGS=-Werror ;;
1597         *) # Check that GCC accepts it
1598             saved_CFLAGS="$CFLAGS"
1599             CFLAGS="$CFLAGS $w"
1600             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1601             CFLAGS="$saved_CFLAGS"
1602         esac
1603     done
1604     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1605 fi
1606 AC_SUBST(WARN_CFLAGS)
1607 AC_SUBST(WERROR_CFLAGS)
1608
1609 # In the Cygwin environment, we need some additional flags.
1610 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1611 [AC_EGREP_CPP(lose, [
1612 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1613 lose
1614 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1615
1616
1617 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1618 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1619 case ${host} in
1620   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1621   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1622   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1623 esac
1624 AC_SUBST(SER_HARDWIRE)
1625
1626 # libreadline needs libuser32.a in a cygwin environment
1627 WIN32LIBS=
1628 if test x$gdb_cv_os_cygwin = xyes; then
1629     WIN32LIBS="-luser32"
1630     case "${target}" in
1631         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1632         ;;
1633     esac
1634 fi
1635
1636 # The ser-tcp.c module requires sockets.
1637 case ${host} in
1638   *mingw32*)
1639     AC_DEFINE(USE_WIN32API, 1,
1640               [Define if we should use the Windows API, instead of the
1641                POSIX API.  On Windows, we use the Windows API when
1642                building for MinGW, but the POSIX API when building
1643                for Cygwin.])
1644     WIN32LIBS="$WIN32LIBS -lws2_32"
1645     ;;
1646 esac
1647 AC_SUBST(WIN32LIBS)
1648
1649 # Add ELF support to GDB, but only if BFD includes ELF support.
1650 OLD_CFLAGS=$CFLAGS
1651 OLD_LDFLAGS=$LDFLAGS
1652 OLD_LIBS=$LIBS
1653 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1654 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1655 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1656 LIBS="-lbfd -liberty $intl $LIBS"
1657 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1658 [AC_TRY_LINK(
1659 [#include <stdlib.h>
1660 #include "bfd.h"
1661 #include "elf-bfd.h"
1662 ],
1663 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1664 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1665 if test $gdb_cv_var_elf = yes; then
1666   CONFIG_OBS="$CONFIG_OBS elfread.o"
1667   AC_DEFINE(HAVE_ELF, 1,
1668             [Define if ELF support should be included.])
1669 fi
1670 CFLAGS=$OLD_CFLAGS
1671 LDFLAGS=$OLD_LDFLAGS
1672 LIBS=$OLD_LIBS
1673
1674 # Add any host-specific objects to GDB.
1675 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1676
1677 LIBGUI="../libgui/src/libgui.a"
1678 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1679 AC_SUBST(LIBGUI)
1680 AC_SUBST(GUI_CFLAGS_X)
1681
1682 WIN32LDAPP=
1683 AC_SUBST(WIN32LIBS)
1684 AC_SUBST(WIN32LDAPP)
1685
1686 case "${host}" in
1687 *-*-cygwin* | *-*-mingw* )
1688     configdir="win"
1689     ;;
1690 *)
1691     configdir="unix"
1692     ;;
1693 esac
1694
1695 GDBTKLIBS=
1696 if test "${enable_gdbtk}" = "yes"; then
1697
1698     # Gdbtk must have an absolute path to srcdir in order to run
1699     # properly when not installed.
1700     here=`pwd`
1701     cd ${srcdir}
1702     GDBTK_SRC_DIR=`pwd`
1703     cd $here
1704
1705     SC_PATH_TCLCONFIG
1706
1707     # If $no_tk is nonempty, then we can't do Tk, and there is no
1708     # point to doing Tcl.
1709     SC_PATH_TKCONFIG
1710
1711     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1712         SC_LOAD_TCLCONFIG
1713
1714         # Check for in-tree tcl
1715         here=`pwd`
1716         cd ${srcdir}/..
1717         topdir=`pwd`
1718         cd ${here}
1719
1720         intree="no"
1721         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1722           intree="yes"
1723         fi
1724
1725         # Find Tcl private headers
1726         if test x"${intree}" = xno; then
1727           CY_AC_TCL_PRIVATE_HEADERS
1728           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1729           TCL_LIBRARY="${TCL_LIB_SPEC}"
1730           TCL_DEPS=""
1731         else
1732           # If building tcl in the same src tree, private headers
1733           # are not needed, but we need to be sure to use the right
1734           # headers library
1735           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1736           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1737           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1738         fi
1739         AC_SUBST(TCL_INCLUDE)
1740         AC_SUBST(TCL_LIBRARY)
1741         AC_SUBST(TCL_DEPS)
1742
1743         SC_LOAD_TKCONFIG
1744
1745         # Check for in-tree Tk
1746         intree="no"
1747         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1748           intree="yes"
1749         fi
1750
1751         # Find Tk private headers
1752         if test x"${intree}" = xno; then
1753           CY_AC_TK_PRIVATE_HEADERS
1754           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1755           TK_LIBRARY=${TK_LIB_SPEC}
1756           TK_DEPS=""
1757         else
1758           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1759           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1760           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1761         fi
1762         AC_SUBST(TK_INCLUDE)
1763         AC_SUBST(TK_LIBRARY)
1764         AC_SUBST(TK_DEPS)
1765         AC_SUBST(TK_XINCLUDES)
1766
1767         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1768
1769         # Include some libraries that Tcl and Tk want.
1770         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1771         # Yes, the ordering seems wrong here.  But it isn't.
1772         # TK_LIBS is the list of libraries that need to be linked
1773         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1774         # were in LIBS then any link tests after this point would
1775         # try to include things like `$(LIBGUI)', which wouldn't work.
1776         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1777
1778         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1779         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1780         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1781         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1782         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1783         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1784         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1785
1786         if test x$gdb_cv_os_cygwin = xyes; then
1787           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1788           WIN32LDAPP="-Wl,--subsystem,console"
1789           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1790         fi
1791
1792         AC_CONFIG_SUBDIRS(gdbtk)
1793     fi
1794 fi
1795
1796 AC_SUBST(X_CFLAGS)
1797 AC_SUBST(X_LDFLAGS)
1798 AC_SUBST(X_LIBS)
1799 AC_SUBST(GDBTKLIBS)
1800 AC_SUBST(GDBTK_CFLAGS)
1801 AC_SUBST(GDBTK_SRC_DIR)
1802
1803 AC_PATH_X
1804
1805 # Unlike the sim directory, whether a simulator is linked is controlled by
1806 # presence of a gdb_sim definition in the target configure.tgt entry.
1807 # This code just checks for a few cases where we'd like to ignore those
1808 # definitions, even when they're present in the '.mt' file.  These cases
1809 # are when --disable-sim is specified, or if the simulator directory is
1810 # not part of the source tree.
1811 #
1812 AC_ARG_ENABLE(sim,
1813 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1814 [echo "enable_sim = $enable_sim";
1815  echo "enableval = ${enableval}";
1816  case "${enableval}" in
1817   yes) ignore_sim=false ;;
1818   no)  ignore_sim=true ;;
1819   *)   ignore_sim=false ;;
1820  esac],
1821 [ignore_sim=false])
1822
1823 if test ! -d "${srcdir}/../sim"; then
1824   ignore_sim=true
1825 fi
1826
1827 SIM=
1828 SIM_OBS=
1829 if test "${ignore_sim}" = "false"; then
1830   if test x"${gdb_sim}" != x ; then
1831     SIM="${gdb_sim}"
1832     SIM_OBS="remote-sim.o"
1833     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1834   fi
1835 fi
1836 AC_SUBST(SIM)
1837 AC_SUBST(SIM_OBS)
1838
1839 AC_SUBST(ENABLE_CFLAGS)
1840 AC_SUBST(PROFILE_CFLAGS)
1841
1842 AC_SUBST(CONFIG_OBS)
1843 AC_SUBST(CONFIG_DEPS)
1844 AC_SUBST(CONFIG_SRCS)
1845 AC_SUBST(CONFIG_ALL)
1846 AC_SUBST(CONFIG_CLEAN)
1847 AC_SUBST(CONFIG_INSTALL)
1848 AC_SUBST(CONFIG_UNINSTALL)
1849
1850 # List of host floatformats.
1851 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1852 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1853 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1854
1855 # target_subdir is used by the testsuite to find the target libraries.
1856 target_subdir=
1857 if test "${host}" != "${target}"; then
1858     target_subdir="${target_alias}/"
1859 fi
1860 AC_SUBST(target_subdir)
1861
1862 frags=
1863 if test "${gdb_native}" = "yes"; then
1864   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1865   if test ! -f ${host_makefile_frag}; then
1866     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1867   fi
1868   frags="$frags $host_makefile_frag"
1869 else
1870   host_makefile_frag=/dev/null
1871 fi
1872
1873 AC_SUBST_FILE(host_makefile_frag)
1874 AC_SUBST(frags)
1875
1876 changequote(,)dnl
1877 if test "${gdb_native}" = "yes"; then
1878 # We pick this up from the host configuration file (.mh) because we
1879 # do not have a native configuration Makefile fragment.
1880 nativefile=`sed -n '
1881 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1882 ' ${host_makefile_frag}`
1883 fi
1884 changequote([,])
1885
1886 if test x"${gdb_osabi}" != x ; then
1887     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1888                        [Define to the default OS ABI for this configuration.])
1889 fi
1890
1891 # Enable multi-ice-gdb-server.
1892 AC_ARG_ENABLE(multi-ice,
1893 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
1894   [case $enableval in
1895     yes | no)
1896       ;;
1897     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1898   esac])
1899 if test "x$enable_multi_ice" = xyes; then
1900    AC_CONFIG_SUBDIRS(multi-ice)
1901 fi
1902
1903 # We only build gdbserver automatically in a native configuration.
1904 if test "$gdb_native" = "yes"; then
1905   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1906   if test "x$build_gdbserver" = xyes; then
1907     AC_MSG_RESULT(yes)
1908     AC_CONFIG_SUBDIRS(gdbserver)
1909   else
1910     AC_MSG_RESULT(no)
1911   fi
1912 fi
1913
1914 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1915 # to an empty version.
1916
1917 files=
1918 links=
1919
1920 rm -f nm.h
1921 if test "${nativefile}" != ""; then
1922     case "${nativefile}" in
1923       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1924       * ) GDB_NM_FILE="${nativefile}"
1925     esac
1926     files="${files} ${GDB_NM_FILE}"
1927     links="${links} nm.h"
1928     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1929 fi
1930 AC_SUBST(GDB_NM_FILE)
1931
1932 AC_LINK_FILES($files, $links)
1933
1934 dnl Check for exe extension set on certain hosts (e.g. Win32)
1935 AC_EXEEXT
1936
1937 dnl  Detect the character set used by this host.
1938 dnl  At the moment, we just assume it's UTF-8.
1939 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
1940           [Define to be a string naming the default host character set.])
1941
1942 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1943 [
1944 case x$CONFIG_HEADERS in
1945 xconfig.h:config.in)
1946 echo > stamp-h ;;
1947 esac
1948 ])
1949
1950 exit 0