gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files and targets accumulated by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41 CONFIG_SRCS=
  42 ENABLE_CFLAGS=
  43
  44 CONFIG_ALL=
  45 CONFIG_CLEAN=
  46 CONFIG_INSTALL=
  47 CONFIG_UNINSTALL=
  48
  49 dnl Set up for gettext.
  50 ZW_GNU_GETTEXT_SISTER_DIR
  51
  52 localedir='${datadir}/locale'
  53 AC_SUBST(localedir)
  54
  55 if test x"$USE_NLS" = xyes; then
  56    CONFIG_ALL="$CONFIG_ALL all-po"
  57    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  58    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  59    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  60 fi
  61
  62 PACKAGE=gdb
  63 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  64 AC_SUBST(PACKAGE)
  65
  66 debugdir=${libdir}/debug
  67
  68 AC_ARG_WITH(separate-debug-dir,
  69 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  70 [debugdir="${withval}"])
  71
  72 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  73               [Global directory for separate debug files. ])
  74 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  75
  76 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
  77   if test "x$prefix" = xNONE; then
  78     test_prefix=/usr/local
  79   else
  80     test_prefix=$prefix
  81   fi
  82 else
  83   test_prefix=$exec_prefix
  84 fi
  85 case ${debugdir} in
  86 "${test_prefix}"|"${test_prefix}/"*|\
  87 '${exec_prefix}'|'${exec_prefix}/'*)
  88   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
  89   ;;
  90 esac
  91
  92 AC_CONFIG_SUBDIRS(doc testsuite)
  93
  94 # Provide defaults for some variables set by the per-host and per-target
  95 # configuration.
  96 gdb_host_obs=posix-hdep.o
  97
  98 if test "${target}" = "${host}"; then
  99   gdb_native=yes
 100 else
 101   gdb_native=no
 102 fi
 103
 104 . $srcdir/configure.host
 105
 106 . $srcdir/configure.tgt
 107
 108 # Fetch the default architecture and default target vector from BFD.
 109 targ=$target; . $srcdir/../bfd/config.bfd
 110
 111 # We only want the first architecture, so strip off the others if
 112 # there is more than one.
 113 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 114
 115 if test "x$targ_archs" != x; then
 116   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 117     [Define to BFD's default architecture. ])
 118 fi
 119 if test "x$targ_defvec" != x; then
 120   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 121     [Define to BFD's default target vector. ])
 122 fi
 123
 124 AC_ARG_PROGRAM
 125
 126 # The CLI cannot be disabled yet, but may be in the future.
 127
 128 # Enable CLI.
 129 AC_ARG_ENABLE(gdbcli,
 130 [  --disable-gdbcli        disable command-line interface (CLI)],
 131   [case $enableval in
 132     yes)
 133       ;;
 134     no)
 135       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 136     *)
 137       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 138   esac],
 139   [enable_gdbcli=yes])
 140 if test x"$enable_gdbcli" = xyes; then
 141   if test -d $srcdir/cli; then
 142     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 143     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 144     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 145     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 146   fi
 147 fi
 148
 149 # Enable MI.
 150 AC_ARG_ENABLE(gdbmi,
 151 [  --disable-gdbmi         disable machine-interface (MI)],
 152   [case $enableval in
 153     yes | no)
 154       ;;
 155     *)
 156       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 157   esac],
 158   [enable_gdbmi=yes])
 159 if test x"$enable_gdbmi" = xyes; then
 160   if test -d $srcdir/mi; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 164     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 165   fi
 166 fi
 167
 168 # Enable TUI.
 169 AC_ARG_ENABLE(tui,
 170 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 171   [case $enableval in
 172     yes | no)
 173       ;;
 174     *)
 175       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 176   esac],enable_tui=yes)
 177
 178 # Enable gdbtk.
 179 AC_ARG_ENABLE(gdbtk,
 180 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 181   [case $enableval in
 182     yes | no)
 183       ;;
 184     *)
 185       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 186   esac],
 187   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 188     enable_gdbtk=yes
 189   else
 190     enable_gdbtk=no
 191   fi])
 192 # We unconditionally disable gdbtk tests on selected platforms.
 193 case $host_os in
 194   go32* | windows*)
 195     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 196     enable_gdbtk=no ;;
 197 esac
 198
 199 # Libunwind support.
 200 AC_ARG_WITH(libunwind,
 201 [  --with-libunwind            Use libunwind frame unwinding support],
 202 [case "${withval}" in
 203   yes)  enable_libunwind=yes ;;
 204   no)   enable_libunwind=no ;;
 205   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 206 esac],[
 207   AC_CHECK_HEADERS(libunwind.h)
 208   AC_CHECK_HEADERS(libunwind-ia64.h)
 209   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 210     enable_libunwind=yes;
 211   fi
 212 ])
 213
 214 if test x"$enable_libunwind" = xyes; then
 215   AC_CHECK_HEADERS(libunwind.h)
 216   AC_CHECK_HEADERS(libunwind-ia64.h)
 217   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 218   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 219   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 220   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 221 fi
 222
 223 # Profiling support.
 224 AC_ARG_ENABLE(profiling,
 225 [  --enable-profiling      enable profiling of GDB],
 226   [case $enableval in
 227     yes | no)
 228       ;;
 229     *)
 230       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 231   esac],
 232  [enable_profiling=no])
 233
 234 AC_CHECK_FUNCS(monstartup _mcleanup)
 235 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 236 [AC_TRY_LINK(
 237 [#include <stdlib.h>
 238 extern char _etext;
 239 ],
 240 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 241 if test $ac_cv_var__etext = yes; then
 242   AC_DEFINE(HAVE__ETEXT, 1,
 243             [Define to 1 if your system has the _etext variable. ])
 244 fi
 245 if test "$enable_profiling" = yes ; then
 246   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 247     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 248   fi
 249   PROFILE_CFLAGS=-pg
 250   OLD_CFLAGS="$CFLAGS"
 251   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 252
 253   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 254     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 255      ac_cv_cc_supports_pg=no)])
 256
 257   if test $ac_cv_cc_supports_pg = no; then
 258     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 259   fi
 260
 261   CFLAGS="$OLD_CFLAGS"
 262 fi
 263
 264 # --------------------- #
 265 # Checks for programs.  #
 266 # --------------------- #
 267
 268 AC_PROG_AWK
 269 AC_PROG_INSTALL
 270 AC_PROG_LN_S
 271 AC_PROG_RANLIB
 272 AC_PROG_YACC
 273
 274 AC_CHECK_TOOL(AR, ar)
 275 AC_CHECK_TOOL(DLLTOOL, dlltool)
 276 AC_CHECK_TOOL(WINDRES, windres)
 277
 278 # Needed for GNU/Hurd.
 279 AC_CHECK_TOOL(MIG, mig)
 280
 281 # ---------------------- #
 282 # Checks for libraries.  #
 283 # ---------------------- #
 284
 285 # We might need to link with -lm; most simulators need it.
 286 AC_CHECK_LIB(m, main)
 287
 288 # We need to link with -lw to get `wctype' on Solaris before Solaris
 289 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 290 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 291 # is known to have this problem).  Therefore we avoid libw if we can.
 292 AC_CHECK_FUNC(wctype, [],
 293   [AC_CHECK_LIB(w, wctype)])
 294
 295 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 296 AC_SEARCH_LIBS(gethostbyname, nsl)
 297
 298 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 299 AC_SEARCH_LIBS(socketpair, socket)
 300
 301 # For the TUI, we need enhanced curses functionality.
 302 #
 303 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 304 # curses library because the latter might not provide all the
 305 # functionality we need.  However, this leads to problems on systems
 306 # where the linker searches /usr/local/lib, but the compiler doesn't
 307 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 308 # default installation of ncurses on alpha*-dec-osf* will lead to such
 309 # a situation.
 310 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 311
 312 # Since GDB uses Readline, we need termcap functionality.  In many
 313 # cases this will be provided by the curses library, but some systems
 314 # have a seperate termcap library, or no curses library at all.
 315
 316 case $host_os in
 317   cygwin*)
 318     if test -d $srcdir/libtermcap; then
 319       LIBS="../libtermcap/libtermcap.a $LIBS"
 320       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 321     fi ;;
 322   go32* | *djgpp*)
 323     ac_cv_search_tgetent="none required"
 324     ;;
 325   *mingw32*)
 326     ac_cv_search_tgetent="none required"
 327     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 328     ;;
 329 esac
 330
 331 # These are the libraries checked by Readline.
 332 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 333
 334 if test "$ac_cv_search_tgetent" = no; then
 335   AC_MSG_ERROR([no termcap library found])
 336 fi
 337
 338 AC_ARG_WITH([system-readline],
 339   [AS_HELP_STRING([--with-system-readline],
 340                   [use installed readline library])])
 341
 342 if test "$with_system_readline" = yes; then
 343   READLINE=-lreadline
 344   READLINE_DEPS=
 345   READLINE_CFLAGS=
 346 else
 347   READLINE='$(READLINE_DIR)/libreadline.a'
 348   READLINE_DEPS='$(READLINE)'
 349   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 350 fi
 351 AC_SUBST(READLINE)
 352 AC_SUBST(READLINE_DEPS)
 353 AC_SUBST(READLINE_CFLAGS)
 354
 355 AC_ARG_WITH(expat,
 356   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 357   [], [with_expat=auto])
 358 AC_MSG_CHECKING([whether to use expat])
 359 AC_MSG_RESULT([$with_expat])
 360
 361 if test "${with_expat}" = no; then
 362   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 363   HAVE_LIBEXPAT=no
 364 else
 365   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 366                         [XML_Parser p = XML_ParserCreate (0);])
 367   if test "$HAVE_LIBEXPAT" != yes; then
 368     if test "$with_expat" = yes; then
 369       AC_MSG_ERROR([expat is missing or unusable])
 370     else
 371       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 372     fi
 373   else
 374     save_LIBS=$LIBS
 375     LIBS="$LIBS $LIBEXPAT"
 376     AC_CHECK_FUNCS(XML_StopParser)
 377     LIBS=$save_LIBS
 378   fi
 379 fi
 380
 381 # ------------------------- #
 382 # Checks for header files.  #
 383 # ------------------------- #
 384
 385 AC_HEADER_DIRENT
 386 AC_HEADER_STAT
 387 AC_HEADER_STDC
 388 AC_CHECK_HEADERS(nlist.h)
 389 AC_CHECK_HEADERS(link.h, [], [],
 390 [#if HAVE_SYS_TYPES_H
 391 # include <sys/types.h>
 392 #endif
 393 #if HAVE_NLIST_H
 394 # include <nlist.h>
 395 #endif
 396 ])
 397 AC_CHECK_HEADERS(machine/reg.h)
 398 AC_CHECK_HEADERS(poll.h sys/poll.h)
 399 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 400 AC_CHECK_HEADERS(signal.h)
 401 AC_CHECK_HEADERS(stddef.h)
 402 AC_CHECK_HEADERS(stdlib.h)
 403 AC_CHECK_HEADERS(stdint.h)
 404 AC_CHECK_HEADERS(string.h memory.h strings.h)
 405 AC_CHECK_HEADERS(sys/fault.h)
 406 AC_CHECK_HEADERS(sys/file.h)
 407 AC_CHECK_HEADERS(sys/filio.h)
 408 AC_CHECK_HEADERS(sys/ioctl.h)
 409 AC_CHECK_HEADERS(sys/param.h)
 410 AC_CHECK_HEADERS(sys/resource.h)
 411 AC_CHECK_HEADERS(sys/proc.h, [], [],
 412 [#if HAVE_SYS_PARAM_H
 413 # include <sys/param.h>
 414 #endif
 415 ])
 416 AC_CHECK_HEADERS(sys/procfs.h)
 417 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 418 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 419 AC_CHECK_HEADERS(sys/select.h)
 420 AC_CHECK_HEADERS(sys/syscall.h)
 421 AC_CHECK_HEADERS(sys/types.h)
 422 AC_CHECK_HEADERS(sys/user.h, [], [],
 423 [#if HAVE_SYS_PARAM_H
 424 # include <sys/param.h>
 425 #endif
 426 ])
 427 AC_CHECK_HEADERS(sys/wait.h wait.h)
 428 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 429 AC_CHECK_HEADERS(unistd.h)
 430
 431 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 432 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 433 # think that we don't have <curses.h> if we're using GCC.
 434 case $host_os in
 435   solaris2.[[789]])
 436     if test "$GCC" = yes; then
 437       AC_DEFINE(_MSE_INT_H, 1,
 438         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 439    Solaris 2.[789] when using GCC. ])
 440     fi ;;
 441 esac
 442 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 443 AC_CHECK_HEADERS(ncurses/term.h)
 444 AC_CHECK_HEADERS(term.h, [], [],
 445 [#if HAVE_CURSES_H
 446 # include <curses.h>
 447 #endif
 448 ])
 449
 450 # FIXME: kettenis/20030102: In most cases we include these
 451 # unconditionally, so what's the point in checking these?
 452 AC_CHECK_HEADERS(ctype.h time.h)
 453
 454 # Create a header we can use portably to get the standard integer types.
 455 GCC_HEADER_STDINT(gdb_stdint.h)
 456
 457 # ------------------------- #
 458 # Checks for declarations.  #
 459 # ------------------------- #
 460
 461 AC_CHECK_DECLS([free, malloc, realloc])
 462 AC_CHECK_DECLS([strerror, strstr])
 463 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 464
 465 # ----------------------- #
 466 # Checks for structures.  #
 467 # ----------------------- #
 468
 469 AC_CHECK_MEMBERS([struct stat.st_blocks])
 470 AC_CHECK_MEMBERS([struct stat.st_blksize])
 471
 472 # ------------------ #
 473 # Checks for types.  #
 474 # ------------------ #
 475
 476 AC_TYPE_SIGNAL
 477 AC_CHECK_TYPES(socklen_t, [], [],
 478 [#include <sys/types.h>
 479 #include <sys/socket.h>
 480 ])
 481 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 482
 483 # ------------------------------------- #
 484 # Checks for compiler characteristics.  #
 485 # ------------------------------------- #
 486
 487 AC_C_CONST
 488 AC_C_INLINE
 489
 490 # ------------------------------ #
 491 # Checks for library functions.  #
 492 # ------------------------------ #
 493
 494 AC_FUNC_ALLOCA
 495 AC_FUNC_MMAP
 496 AC_FUNC_VFORK
 497 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 498 AC_CHECK_FUNCS(getrusage)
 499 AC_CHECK_FUNCS(getuid getgid)
 500 AC_CHECK_FUNCS(poll)
 501 AC_CHECK_FUNCS(pread64)
 502 AC_CHECK_FUNCS(sbrk)
 503 AC_CHECK_FUNCS(setpgid setpgrp)
 504 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 505 AC_CHECK_FUNCS(socketpair)
 506 AC_CHECK_FUNCS(syscall)
 507 AC_CHECK_FUNCS(ttrace)
 508 AC_CHECK_FUNCS(wborder)
 509
 510 # Check the return and argument types of ptrace.  No canned test for
 511 # this, so roll our own.
 512 gdb_ptrace_headers='
 513 #if HAVE_SYS_TYPES_H
 514 # include <sys/types.h>
 515 #endif
 516 #if HAVE_SYS_PTRACE_H
 517 # include <sys/ptrace.h>
 518 #endif
 519 #if HAVE_UNISTD_H
 520 # include <unistd.h>
 521 #endif
 522 '
 523 # There is no point in checking if we don't have a prototype.
 524 AC_CHECK_DECLS(ptrace, [], [
 525   : ${gdb_cv_func_ptrace_ret='int'}
 526   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 527 ], $gdb_ptrace_headers)
 528 # Check return type.
 529 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 530   AC_TRY_COMPILE($gdb_ptrace_headers,
 531     [extern int ptrace ();],
 532     gdb_cv_func_ptrace_ret='int',
 533     gdb_cv_func_ptrace_ret='long'))
 534 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 535   [Define as the return type of ptrace.])
 536 # Check argument types.
 537 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 538 for gdb_arg1 in 'int' 'long'; do
 539  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 540   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 541    for gdb_arg4 in 'int' 'long'; do
 542      AC_TRY_COMPILE($gdb_ptrace_headers, [
 543 extern $gdb_cv_func_ptrace_ret
 544   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 545 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 546     break 4;])
 547     for gdb_arg5 in 'int *' 'int' 'long'; do
 548      AC_TRY_COMPILE($gdb_ptrace_headers, [
 549 extern $gdb_cv_func_ptrace_ret
 550   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 551 ], [
 552 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 553     break 5;])
 554     done
 555    done
 556   done
 557  done
 558 done
 559 # Provide a safe default value.
 560 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 561 ])
 562 ac_save_IFS=$IFS; IFS=','
 563 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 564 IFS=$ac_save_IFS
 565 shift
 566 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 567   [Define to the type of arg 3 for ptrace.])
 568 if test -n "$[5]"; then
 569   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 570     [Define to the type of arg 5 for ptrace.])
 571 fi
 572
 573 dnl AC_FUNC_SETPGRP does not work when cross compiling
 574 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 575 if test "$cross_compiling" = no; then
 576   AC_FUNC_SETPGRP
 577 else
 578   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 579     [AC_TRY_COMPILE([
 580 #include <unistd.h>
 581 ], [
 582   if (setpgrp(1,1) == -1)
 583     exit (0);
 584   else
 585     exit (1);
 586 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 587 if test $ac_cv_func_setpgrp_void = yes; then
 588   AC_DEFINE(SETPGRP_VOID, 1)
 589 fi
 590 fi
 591
 592 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 593 # since sigsetjmp might only be defined as a macro.
 594 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 595 [AC_TRY_COMPILE([
 596 #include <setjmp.h>
 597 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 598 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 599 if test $gdb_cv_func_sigsetjmp = yes; then
 600   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 601 fi
 602
 603 # Assume we'll default to using the included libiberty regex.
 604 gdb_use_included_regex=yes
 605
 606 # However, if the system regex is GNU regex, then default to *not*
 607 # using the included regex.
 608 AC_CACHE_CHECK(
 609   [for GNU regex],
 610   [gdb_cv_have_gnu_regex],
 611   [AC_TRY_COMPILE(
 612     [#include <gnu-versions.h>],
 613     [#define REGEX_INTERFACE_VERSION 1
 614 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 615 # error "Version mismatch"
 616 #endif],
 617     gdb_cv_have_gnu_regex=yes,
 618     gdb_cv_have_gnu_regex=no)])
 619 if test $gdb_cv_have_gnu_regex = yes; then
 620   gdb_use_included_regex=no
 621 fi
 622
 623 AC_ARG_WITH(included-regex,
 624   [  --without-included-regex don't use included regex; this is the default
 625                           on systems with version 2 of the GNU C library
 626                           (use with caution on other system)],
 627   gdb_with_regex=$withval,
 628   gdb_with_regex=$gdb_use_included_regex)
 629 if test "$gdb_with_regex" = yes; then
 630   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 631     [Define to 1 if the regex included in libiberty should be used.])
 632 fi
 633
 634 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 635 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 636 [#include <sys/param.h>
 637 #include <sys/proc.h>
 638 ])
 639
 640 # See if <sys/lwp.h> defines `struct lwp`.
 641 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 642 [AC_TRY_COMPILE([#include <sys/param.h>
 643 #include <sys/lwp.h>], [struct lwp l;],
 644 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 645 if test $gdb_cv_struct_lwp = yes; then
 646   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 647             [Define to 1 if your system has struct lwp.])
 648 fi
 649
 650 # See if <machine/reg.h> degines `struct reg'.
 651 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 652 [AC_TRY_COMPILE([#include <sys/types.h>
 653 #include <machine/reg.h>], [struct reg r;],
 654 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 655 if test $gdb_cv_struct_reg = yes; then
 656   AC_DEFINE(HAVE_STRUCT_REG, 1,
 657             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 658 fi
 659
 660 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 661 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 662 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 663                  [#include <machine/reg.h>])
 664
 665 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 666 AC_MSG_CHECKING(for PTRACE_GETREGS)
 667 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 668 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 669                 [PTRACE_GETREGS;],
 670                 [gdb_cv_have_ptrace_getregs=yes],
 671                 [gdb_cv_have_ptrace_getregs=no])])
 672 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 673 if test $gdb_cv_have_ptrace_getregs = yes; then
 674   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 675   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 676 fi
 677
 678 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 679 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 680 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 681 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 682                 [PTRACE_GETFPXREGS;],
 683                 [gdb_cv_have_ptrace_getfpxregs=yes],
 684                 [gdb_cv_have_ptrace_getfpxregs=no])])
 685 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 686 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 687   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 688   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 689 fi
 690
 691 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 692 AC_MSG_CHECKING(for PT_GETDBREGS)
 693 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 694 [AC_TRY_COMPILE([#include <sys/types.h>
 695 #include <sys/ptrace.h>],
 696                 [PT_GETDBREGS;],
 697                 [gdb_cv_have_pt_getdbregs=yes],
 698                 [gdb_cv_have_pt_getdbregs=no])])
 699 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 700 if test $gdb_cv_have_pt_getdbregs = yes; then
 701   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 702   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 703 fi
 704
 705 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 706 AC_MSG_CHECKING(for PT_GETXMMREGS)
 707 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 708 [AC_TRY_COMPILE([#include <sys/types.h>
 709 #include <sys/ptrace.h>],
 710                 [PT_GETXMMREGS;],
 711                 [gdb_cv_have_pt_getxmmregs=yes],
 712                 [gdb_cv_have_pt_getxmmregs=no])])
 713 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 714 if test $gdb_cv_have_pt_getxmmregs = yes; then
 715   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 716   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 717 fi
 718
 719 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 720
 721 if test "${target}" = "${host}"; then
 722   case "${host}" in
 723   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 724       AC_DEFINE(NEW_PROC_API, 1,
 725       [Define if you want to use new multi-fd /proc interface
 726        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 727       ;;
 728   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 729       AC_DEFINE(NEW_PROC_API, 1,
 730       [Define if you want to use new multi-fd /proc interface
 731        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
 732       ;;
 733   mips-sgi-irix5*)
 734       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 735       AC_DEFINE([_KMEMUSER], 1,
 736       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
 737        around a <sys/proc.h> problem on IRIX 5.])
 738       ;;
 739   esac
 740 fi
 741
 742 if test "$ac_cv_header_sys_procfs_h" = yes; then
 743   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 744   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 745   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 746   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 747   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 748   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 749   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 750   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 751   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 752   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 753   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 754   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 755   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 756   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 757
 758
 759   dnl Check for broken prfpregset_t type
 760
 761   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 762   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 763   dnl instead of the struct itself).  We detect this here, and work
 764   dnl around it in gdb_proc_service.h.
 765
 766   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 767     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 768     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 769       [AC_TRY_RUN([#include <sys/procfs.h>
 770        int main ()
 771        {
 772          if (sizeof (prfpregset_t) == sizeof (void *))
 773            return 1;
 774          return 0;
 775        }],
 776        gdb_cv_prfpregset_t_broken=no,
 777        gdb_cv_prfpregset_t_broken=yes,
 778        gdb_cv_prfpregset_t_broken=yes)])
 779     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 780     if test $gdb_cv_prfpregset_t_broken = yes; then
 781       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
 782       [Define if the prfpregset_t type is broken.])
 783     fi
 784   fi
 785
 786   dnl Check for PIOCSET ioctl entry
 787
 788   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 789   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 790   [AC_TRY_COMPILE([#include <unistd.h>
 791 #include <sys/types.h>
 792 #include <sys/procfs.h>
 793 ], [
 794     int dummy;;
 795     dummy = ioctl(0, PIOCSET, &dummy);
 796   ],
 797   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 798   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 799   if test $gdb_cv_have_procfs_piocset = yes; then
 800     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
 801     [Define if ioctl argument PIOCSET is available.])
 802   fi
 803 fi
 804
 805 dnl For native ports (host == target), check to see what kind of
 806 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 807 if test ${host} = ${target} ; then
 808   dnl Check for struct link_map with l_ members which are indicative
 809   dnl of SVR4-like shared libraries
 810
 811   AC_MSG_CHECKING(for member l_addr in struct link_map)
 812   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 813     [AC_TRY_COMPILE([#include <link.h>],
 814                     [struct link_map lm; (void) lm.l_addr;],
 815                     gdb_cv_have_struct_link_map_with_l_members=yes,
 816                     gdb_cv_have_struct_link_map_with_l_members=no)])
 817   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 818   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 819     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
 820     [Define if <link.h> exists and defines struct link_map which has
 821      members with an ``l_'' prefix.  (For Solaris, SVR4, and
 822      SVR4-like systems.)])
 823   fi
 824
 825   dnl Check for struct link_map with lm_ members which are indicative
 826   dnl of SunOS-like shared libraries
 827
 828   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 829   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 830     [AC_TRY_COMPILE([#include <sys/types.h>
 831 #include <link.h>],
 832                     [struct link_map lm; (void) lm.lm_addr;],
 833                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 834                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 835   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 836   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 837     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
 838     [Define if <link.h> exists and defines struct link_map which has
 839      members with an ``lm_'' prefix.  (For SunOS.)])
 840   fi
 841
 842   dnl Check for struct so_map with som_ members which are found on
 843   dnl some *BSD systems.
 844
 845   AC_MSG_CHECKING(for member som_addr in struct so_map)
 846   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 847     [AC_TRY_COMPILE([#include <sys/types.h>
 848 #ifdef HAVE_NLIST_H
 849 #include <nlist.h>
 850 #endif
 851 #include <link.h>],
 852                     [struct so_map lm; (void) lm.som_addr;],
 853                     gdb_cv_have_struct_so_map_with_som_members=yes,
 854                     gdb_cv_have_struct_so_map_with_som_members=no)])
 855   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 856   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 857     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
 858     [Define if <link.h> exists and defines a struct so_map which has
 859      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
 860   fi
 861
 862   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 863   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 864
 865   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 866   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 867     [AC_TRY_COMPILE([#define _SYSCALL32
 868 #include <sys/link.h>], [struct link_map32 l;],
 869      gdb_cv_have_struct_link_map32=yes,
 870      gdb_cv_have_struct_link_map32=no)])
 871   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 872   if test $gdb_cv_have_struct_link_map32 = yes; then
 873     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
 874     [Define if <sys/link.h> has struct link_map32])
 875     AC_DEFINE(_SYSCALL32, 1,
 876     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
 877   fi
 878 fi
 879
 880 # Check if the compiler supports the `long long' type.
 881
 882 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 883                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 884 [[extern long long foo;]],
 885 [[switch (foo & 2) { case 0: return 1; }]])],
 886                                   gdb_cv_c_long_long=yes,
 887                                   gdb_cv_c_long_long=no)])
 888 if test $gdb_cv_c_long_long = yes; then
 889   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 890             [Define to 1 if the compiler supports long long.])
 891 fi
 892
 893 # Check if the compiler and runtime support printing long longs.
 894
 895 AC_CACHE_CHECK([for long long support in printf],
 896                gdb_cv_printf_has_long_long,
 897                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 898 [[char buf[32];
 899   long long l = 0;
 900   l = (l << 16) + 0x0123;
 901   l = (l << 16) + 0x4567;
 902   l = (l << 16) + 0x89ab;
 903   l = (l << 16) + 0xcdef;
 904   sprintf (buf, "0x%016llx", l);
 905   return (strcmp ("0x0123456789abcdef", buf));]])],
 906                               gdb_cv_printf_has_long_long=yes,
 907                               gdb_cv_printf_has_long_long=no,
 908                               gdb_cv_printf_has_long_long=no)])
 909 if test $gdb_cv_printf_has_long_long = yes; then
 910   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 911             [Define to 1 if the "%ll" format works to print long longs.])
 912 fi
 913
 914 # Check if the compiler supports the `long double' type.  We can't use
 915 # AC_C_LONG_DOUBLE because that one does additional checks on the
 916 # constants defined in <float.h> that fail on some systems,
 917 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 918
 919 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 920                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 921                                   gdb_cv_c_long_double=yes,
 922                                   gdb_cv_c_long_double=no)])
 923 if test $gdb_cv_c_long_double = yes; then
 924   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 925            [Define to 1 if the compiler supports long double.])
 926 fi
 927
 928 # Check if the compiler and runtime support printing long doubles.
 929
 930 AC_CACHE_CHECK([for long double support in printf],
 931                gdb_cv_printf_has_long_double,
 932                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 933 [[char buf[16];
 934   long double f = 3.141592653;
 935   sprintf (buf, "%Lg", f);
 936   return (strncmp ("3.14159", buf, 7));]])],
 937                               gdb_cv_printf_has_long_double=yes,
 938                               gdb_cv_printf_has_long_double=no,
 939                               gdb_cv_printf_has_long_double=no)])
 940 if test $gdb_cv_printf_has_long_double = yes; then
 941   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 942             [Define to 1 if the "%Lg" format works to print long doubles.])
 943 fi
 944
 945 # Check if the compiler and runtime support scanning long doubles.
 946
 947 AC_CACHE_CHECK([for long double support in scanf],
 948                gdb_cv_scanf_has_long_double,
 949                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 950 [[#include <stdio.h>]],
 951 [[char *buf = "3.141592653";
 952   long double f = 0;
 953   sscanf (buf, "%Lg", &f);
 954   return !(f > 3.14159 && f < 3.14160);]])],
 955                               gdb_cv_scanf_has_long_double=yes,
 956                               gdb_cv_scanf_has_long_double=no,
 957                               gdb_cv_scanf_has_long_double=no)])
 958 if test $gdb_cv_scanf_has_long_double = yes; then
 959   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 960             [Define to 1 if the "%Lg" format works to scan long doubles.])
 961 fi
 962
 963 case ${host_os} in
 964 aix*)
 965   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 966     SAVE_LDFLAGS=$LDFLAGS
 967
 968     case $GCC in
 969     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 970     *) gdb_cv_bigtoc=-bbigtoc ;;
 971     esac
 972
 973     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 974     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 975     LDFLAGS="${SAVE_LDFLAGS}"
 976   ])
 977   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 978   ;;
 979 esac
 980
 981
 982 dnl For certain native configurations, we need to check whether thread
 983 dnl support can be built in or not.
 984 dnl
 985 dnl Note that we only want this if we are both native (host == target),
 986 dnl and not doing a canadian cross build (build == host).
 987
 988 if test ${build} = ${host} -a ${host} = ${target} ; then
 989    case ${host_os} in
 990    hpux*)
 991       AC_MSG_CHECKING(for HPUX/OSF thread support)
 992       if test -f /usr/include/dce/cma_config.h ; then
 993          if test "$GCC" = "yes" ; then
 994             AC_MSG_RESULT(yes)
 995             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
 996             [Define if you have HPUX threads])
 997             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 998             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 999          else
1000             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1001          fi
1002       else
1003          AC_MSG_RESULT(no)
1004       fi
1005       ;;
1006    solaris*)
1007       # See if thread_db library is around for Solaris thread debugging.
1008       # Note that we must explicitly test for version 1 of the library
1009       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1010       # the same API.
1011       AC_MSG_CHECKING(for Solaris thread debugging library)
1012       if test -f /usr/lib/libthread_db.so.1 ; then
1013          AC_MSG_RESULT(yes)
1014          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1015          [Define if using Solaris thread debugging.])
1016          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1017          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1018          AC_CHECK_LIB(dl, dlopen)
1019          if test "$GCC" = "yes" ; then
1020             # The GNU linker requires the -export-dynamic option to make
1021             # all symbols visible in the dynamic symbol table.
1022             hold_ldflags=$LDFLAGS
1023             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1024             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1025             AC_TRY_LINK(, [int i;], found=yes, found=no)
1026             LDFLAGS=$hold_ldflags
1027             AC_MSG_RESULT($found)
1028             if test $found = yes; then
1029                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1030             fi
1031          fi
1032          # Sun randomly tweaked the prototypes in <proc_service.h>
1033          # at one point.
1034          AC_MSG_CHECKING(if <proc_service.h> is old)
1035          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1036             AC_TRY_COMPILE([
1037                 #include <proc_service.h>
1038                 ps_err_e ps_pdwrite
1039                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1040             ],, gdb_cv_proc_service_is_old=no,
1041                 gdb_cv_proc_service_is_old=yes)
1042          ])
1043          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1044          if test $gdb_cv_proc_service_is_old = yes; then
1045             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1046             [Define if <proc_service.h> on solaris uses int instead of
1047              size_t, and assorted other type changes.])
1048          fi
1049       else
1050          AC_MSG_RESULT(no)
1051       fi
1052       ;;
1053    aix*)
1054       AC_MSG_CHECKING(for AiX thread debugging library)
1055       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1056                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1057                                    [#ifndef PTHDB_VERSION_3
1058                                     #error
1059                                     #endif],
1060                                    gdb_cv_have_aix_thread_debug=yes,
1061                                    gdb_cv_have_aix_thread_debug=no)])
1062       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1063       if test $gdb_cv_have_aix_thread_debug = yes; then
1064          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1065          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1066          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1067       fi
1068       ;;
1069    esac
1070    AC_SUBST(CONFIG_LDFLAGS)
1071 fi
1072
1073 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1074 dnl other error codes.
1075 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1076    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1077                   gdb_cv_thread_db_h_has_td_notalloc,
1078      AC_TRY_COMPILE(
1079        [#include <thread_db.h>],
1080        [int i = TD_NOTALLOC;],
1081        gdb_cv_thread_db_h_has_td_notalloc=yes,
1082        gdb_cv_thread_db_h_has_td_notalloc=no
1083      )
1084    )
1085    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1086                   gdb_cv_thread_db_h_has_td_version,
1087      AC_TRY_COMPILE(
1088        [#include <thread_db.h>],
1089        [int i = TD_VERSION;],
1090        gdb_cv_thread_db_h_has_td_version=yes,
1091        gdb_cv_thread_db_h_has_td_version=no
1092      )
1093    )
1094    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1095                   gdb_cv_thread_db_h_has_td_notls,
1096      AC_TRY_COMPILE(
1097        [#include <thread_db.h>],
1098        [int i = TD_NOTLS;],
1099        gdb_cv_thread_db_h_has_td_notls=yes,
1100        gdb_cv_thread_db_h_has_td_notls=no
1101      )
1102    )
1103 fi
1104 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1105   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1106             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1107 fi
1108 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1109   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1110             [Define if <thread_db.h> has the TD_VERSION error code.])
1111 fi
1112 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1113   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1114             [Define if <thread_db.h> has the TD_NOTLS error code.])
1115 fi
1116
1117 dnl See if we have a sys/syscall header file that has __NR_tkill.
1118 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1119    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1120                   gdb_cv_sys_syscall_h_has_tkill,
1121      AC_TRY_COMPILE(
1122        [#include <sys/syscall.h>],
1123        [int i = __NR_tkill;],
1124        gdb_cv_sys_syscall_h_has_tkill=yes,
1125        gdb_cv_sys_syscall_h_has_tkill=no
1126      )
1127    )
1128 fi
1129 dnl See if we can issue tkill syscall.
1130 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1131   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1132 fi
1133
1134 dnl Handle optional features that can be enabled.
1135
1136 AC_ARG_WITH(sysroot,
1137 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1138 [
1139  case ${with_sysroot} in
1140  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1141  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1142  esac
1143
1144  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1145
1146  if test "x$prefix" = xNONE; then
1147   test_prefix=/usr/local
1148  else
1149   test_prefix=$prefix
1150  fi
1151  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1152   test_exec_prefix=$test_prefix
1153  else
1154   test_exec_prefix=$exec_prefix
1155  fi
1156  case ${TARGET_SYSTEM_ROOT} in
1157  "${test_prefix}"|"${test_prefix}/"*|\
1158  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1159  '${prefix}'|'${prefix}/'*|\
1160  '${exec_prefix}'|'${exec_prefix}/'*)
1161    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1162    TARGET_SYSTEM_ROOT_DEFINE="$t"
1163    ;;
1164  esac
1165 ], [
1166  TARGET_SYSTEM_ROOT=
1167  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1168 ])
1169 AC_SUBST(TARGET_SYSTEM_ROOT)
1170 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1171
1172 AC_ARG_ENABLE(werror,
1173   [  --enable-werror    treat compile warnings as errors],
1174   [case "${enableval}" in
1175      yes | y) ERROR_ON_WARNING="yes" ;;
1176      no | n)  ERROR_ON_WARNING="no" ;;
1177      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1178    esac])
1179
1180 # Enable -Werror by default when using gcc
1181 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1182     ERROR_ON_WARNING=yes
1183 fi
1184
1185 WERROR_CFLAGS=""
1186 if test "${ERROR_ON_WARNING}" = yes ; then
1187     WERROR_CFLAGS="-Werror"
1188 fi
1189
1190 # The entries after -Wno-pointer-sign are disabled warnings which may
1191 # be enabled in the future, which can not currently be used to build
1192 # GDB.
1193 # NOTE: If you change this list, remember to update
1194 # gdb/doc/gdbint.texinfo.
1195 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1196 -Wformat-nonliteral -Wno-pointer-sign \
1197 -Wno-unused -Wno-switch -Wno-char-subscripts"
1198
1199 AC_ARG_ENABLE(build-warnings,
1200 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1201 [case "${enableval}" in
1202   yes)  ;;
1203   no)   build_warnings="-w";;
1204   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1205         build_warnings="${build_warnings} ${t}";;
1206   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1207         build_warnings="${t} ${build_warnings}";;
1208   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1209 esac
1210 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1211   echo "Setting compiler warning flags = $build_warnings" 6>&1
1212 fi])dnl
1213 AC_ARG_ENABLE(gdb-build-warnings,
1214 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1215 [case "${enableval}" in
1216   yes)  ;;
1217   no)   build_warnings="-w";;
1218   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1219         build_warnings="${build_warnings} ${t}";;
1220   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1221         build_warnings="${t} ${build_warnings}";;
1222   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1223 esac
1224 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1225   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1226 fi])dnl
1227 WARN_CFLAGS=""
1228 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1229 then
1230     AC_MSG_CHECKING(compiler warning flags)
1231     # Separate out the -Werror flag as some files just cannot be
1232     # compiled with it enabled.
1233     for w in ${build_warnings}; do
1234         case $w in
1235         -Werr*) WERROR_CFLAGS=-Werror ;;
1236         *) # Check that GCC accepts it
1237             saved_CFLAGS="$CFLAGS"
1238             CFLAGS="$CFLAGS $w"
1239             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1240             CFLAGS="$saved_CFLAGS"
1241         esac
1242     done
1243     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1244 fi
1245 AC_SUBST(WARN_CFLAGS)
1246 AC_SUBST(WERROR_CFLAGS)
1247
1248 # In the Cygwin environment, we need some additional flags.
1249 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1250 [AC_EGREP_CPP(lose, [
1251 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1252 lose
1253 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1254
1255
1256 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1257 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1258 case ${host} in
1259   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1260   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1261   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1262 esac
1263 AC_SUBST(SER_HARDWIRE)
1264
1265 # libreadline needs libuser32.a in a cygwin environment
1266 WIN32LIBS=
1267 if test x$gdb_cv_os_cygwin = xyes; then
1268     WIN32LIBS="-luser32"
1269     case "${target}" in
1270         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1271         ;;
1272     esac
1273 fi
1274
1275 # The ser-tcp.c module requires sockets.
1276 case ${host} in
1277   *mingw32*)
1278     AC_DEFINE(USE_WIN32API, 1,
1279               [Define if we should use the Windows API, instead of the
1280                POSIX API.  On Windows, we use the Windows API when
1281                building for MinGW, but the POSIX API when building
1282                for Cygwin.])
1283     WIN32LIBS="$WIN32LIBS -lws2_32"
1284     ;;
1285 esac
1286 AC_SUBST(WIN32LIBS)
1287
1288 # Add ELF support to GDB, but only if BFD includes ELF support.
1289 OLD_CFLAGS=$CFLAGS
1290 OLD_LDFLAGS=$LDFLAGS
1291 OLD_LIBS=$LIBS
1292 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1293 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1294 LIBS="$LIBS -lbfd -liberty"
1295 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1296 [AC_TRY_LINK(
1297 [#include <stdlib.h>
1298 #include "bfd.h"
1299 #include "elf-bfd.h"
1300 ],
1301 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1302 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1303 if test $gdb_cv_var_elf = yes; then
1304   CONFIG_OBS="$CONFIG_OBS elfread.o"
1305   AC_DEFINE(HAVE_ELF, 1,
1306             [Define if ELF support should be included.])
1307 fi
1308 CFLAGS=$OLD_CFLAGS
1309 LDFLAGS=$OLD_LDFLAGS
1310 LIBS=$OLD_LIBS
1311
1312 # Add any host-specific objects to GDB.
1313 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1314
1315 LIBGUI="../libgui/src/libgui.a"
1316 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1317 AC_SUBST(LIBGUI)
1318 AC_SUBST(GUI_CFLAGS_X)
1319
1320 WIN32LDAPP=
1321 AC_SUBST(WIN32LIBS)
1322 AC_SUBST(WIN32LDAPP)
1323
1324 case "${host}" in
1325 *-*-cygwin*)
1326     configdir="win"
1327     ;;
1328 *)
1329     configdir="unix"
1330     ;;
1331 esac
1332
1333 GDBTKLIBS=
1334 if test "${enable_gdbtk}" = "yes"; then
1335
1336     # Gdbtk must have an absolute path to srcdir in order to run
1337     # properly when not installed.
1338     here=`pwd`
1339     cd ${srcdir}
1340     GDBTK_SRC_DIR=`pwd`
1341     cd $here
1342
1343     CY_AC_PATH_TCLCONFIG
1344     if test -z "${no_tcl}"; then
1345         CY_AC_LOAD_TCLCONFIG
1346         CY_AC_PATH_TKCONFIG
1347
1348         # now look for Tcl library stuff
1349
1350         tcldir="../tcl/${configdir}/"
1351
1352         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1353
1354         # If $no_tk is nonempty, then we can't do Tk, and there is no
1355         # point to doing Tcl.
1356         if test -z "${no_tk}"; then
1357            CY_AC_LOAD_TKCONFIG
1358            CY_AC_PATH_TCLH
1359            CY_AC_PATH_TKH
1360            CY_AC_PATH_ITCLH
1361            CY_AC_PATH_ITKH
1362
1363
1364            # now look for Tk library stuff
1365
1366            tkdir="../tk/${configdir}/"
1367
1368            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1369
1370            # now look for Itcl library stuff
1371
1372            CY_AC_PATH_ITCLCONFIG
1373            if test -z "${no_itcl}"; then
1374              CY_AC_LOAD_ITCLCONFIG
1375
1376              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1377              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1378            fi
1379
1380
1381            # now look for Itk library stuff
1382            CY_AC_PATH_ITKCONFIG
1383            if test -z "${no_itcl}"; then
1384              CY_AC_LOAD_ITKCONFIG
1385
1386              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1387              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1388            fi
1389
1390            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1391
1392            # Include some libraries that Tcl and Tk want.
1393            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1394            # Yes, the ordering seems wrong here.  But it isn't.
1395            # TK_LIBS is the list of libraries that need to be linked
1396            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1397            # were in LIBS then any link tests after this point would
1398            # try to include things like `$(LIBGUI)', which wouldn't work.
1399            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1400
1401            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1402            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1403            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1404            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1405            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1406            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1407            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1408
1409            if test x$gdb_cv_os_cygwin = xyes; then
1410               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1411               WIN32LDAPP="-Wl,--subsystem,console"
1412               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1413            fi
1414         fi
1415     fi
1416
1417     AC_CONFIG_SUBDIRS(gdbtk)
1418 fi
1419
1420 AC_SUBST(X_CFLAGS)
1421 AC_SUBST(X_LDFLAGS)
1422 AC_SUBST(X_LIBS)
1423 AC_SUBST(TCL_DEPS)
1424 AC_SUBST(TK_DEPS)
1425 AC_SUBST(ITCLLIB)
1426 AC_SUBST(ITCL_DEPS)
1427 AC_SUBST(ITKLIB)
1428 AC_SUBST(ITK_DEPS)
1429 AC_SUBST(GDBTKLIBS)
1430 AC_SUBST(GDBTK_CFLAGS)
1431 AC_SUBST(GDBTK_SRC_DIR)
1432
1433 AC_PATH_X
1434
1435 # Check whether we should enable the TUI, but only do so if we really
1436 # can.
1437 if test x"$enable_tui" = xyes; then
1438   if test -d $srcdir/tui; then
1439     if test "$ac_cv_search_waddstr" != no; then
1440       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1441       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1442       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1443       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1444       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1445       CONFIG_ALL="${CONFIG_ALL} all-tui"
1446       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1447       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1448       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1449     else
1450       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1451     fi
1452   fi
1453 fi
1454
1455 # Unlike the sim directory, whether a simulator is linked is controlled by
1456 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1457 # This code just checks for a few cases where we'd like to ignore those
1458 # definitions, even when they're present in the '.mt' file.  These cases
1459 # are when --disable-sim is specified, or if the simulator directory is
1460 # not part of the source tree.
1461 #
1462 AC_ARG_ENABLE(sim,
1463 [  --enable-sim            Link gdb with simulator],
1464 [echo "enable_sim = $enable_sim";
1465  echo "enableval = ${enableval}";
1466  case "${enableval}" in
1467   yes) ignore_sim=false ;;
1468   no)  ignore_sim=true ;;
1469   *)   ignore_sim=false ;;
1470  esac],
1471 [ignore_sim=false])
1472
1473 if test ! -d "${srcdir}/../sim"; then
1474   ignore_sim=true
1475 fi
1476
1477 if test "${ignore_sim}" = "true"; then
1478     IGNORE_SIM="SIM="
1479     IGNORE_SIM_OBS="SIM_OBS="
1480 else
1481     IGNORE_SIM=""
1482     IGNORE_SIM_OBS=""
1483     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1484 fi
1485 AC_SUBST(IGNORE_SIM)
1486 AC_SUBST(IGNORE_SIM_OBS)
1487
1488 AC_SUBST(ENABLE_CFLAGS)
1489 AC_SUBST(PROFILE_CFLAGS)
1490
1491 AC_SUBST(CONFIG_OBS)
1492 AC_SUBST(CONFIG_DEPS)
1493 AC_SUBST(CONFIG_SRCS)
1494 AC_SUBST(CONFIG_ALL)
1495 AC_SUBST(CONFIG_CLEAN)
1496 AC_SUBST(CONFIG_INSTALL)
1497 AC_SUBST(CONFIG_UNINSTALL)
1498
1499 # List of host floatformats.
1500 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1501 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1502 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1503
1504 # target_subdir is used by the testsuite to find the target libraries.
1505 target_subdir=
1506 if test "${host}" != "${target}"; then
1507     target_subdir="${target_alias}/"
1508 fi
1509 AC_SUBST(target_subdir)
1510
1511 frags=
1512 if test "${gdb_native}" = "yes"; then
1513   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1514   if test ! -f ${host_makefile_frag}; then
1515     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1516   fi
1517   frags="$frags $host_makefile_frag"
1518 else
1519   host_makefile_frag=/dev/null
1520 fi
1521
1522 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1523 if test ! -f ${target_makefile_frag}; then
1524   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1525 fi
1526 frags="$frags $target_makefile_frag"
1527
1528 AC_SUBST_FILE(host_makefile_frag)
1529 AC_SUBST_FILE(target_makefile_frag)
1530 AC_SUBST(frags)
1531
1532 changequote(,)dnl
1533 hostfile=`sed -n '
1534 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1535 ' ${host_makefile_frag}`
1536
1537 targetfile=`sed -n '
1538 s/^[    ]*DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1539 ' ${target_makefile_frag}`
1540
1541 if test "${gdb_native}" = "yes"; then
1542 # We pick this up from the host configuration file (.mh) because we
1543 # do not have a native configuration Makefile fragment.
1544 nativefile=`sed -n '
1545 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1546 ' ${host_makefile_frag}`
1547 fi
1548 changequote([,])
1549
1550 if test x"${gdb_osabi}" != x ; then
1551     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1552                        [Define to the default OS ABI for this configuration.])
1553 fi
1554
1555 # Enable multi-ice-gdb-server.
1556 AC_ARG_ENABLE(multi-ice,
1557 [  --enable-multi-ice      build the multi-ice-gdb-server],
1558   [case $enableval in
1559     yes | no)
1560       ;;
1561     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1562   esac])
1563 if test "x$enable_multi_ice" = xyes; then
1564    AC_CONFIG_SUBDIRS(multi-ice)
1565 fi
1566
1567 # We only build gdbserver automatically in a native configuration.
1568 if test "$gdb_native" = "yes"; then
1569   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1570   if test "x$build_gdbserver" = xyes; then
1571     AC_MSG_RESULT(yes)
1572     AC_CONFIG_SUBDIRS(gdbserver)
1573   else
1574     AC_MSG_RESULT(no)
1575   fi
1576 fi
1577
1578 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1579 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1580 # to an empty version.
1581
1582 files=
1583 links=
1584
1585 rm -f xm.h
1586 xm_h=""
1587 if test "${hostfile}" != ""; then
1588     xm_h=xm.h
1589     case "${hostfile}" in
1590       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1591       * ) GDB_XM_FILE="${hostfile}"
1592     esac
1593     files="${files} ${GDB_XM_FILE}"
1594     links="${links} xm.h"
1595     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}", [hostfile])
1596 fi
1597 AC_SUBST(xm_h)
1598
1599 rm -f tm.h
1600 tm_h=""
1601 if test "${targetfile}" != ""; then
1602     tm_h=tm.h
1603     case "${targetfile}" in
1604       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1605       * ) GDB_TM_FILE="${targetfile}"
1606     esac
1607     files="${files} ${GDB_TM_FILE}"
1608     links="${links} tm.h"
1609     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}", [targetfile])
1610 fi
1611 AC_SUBST(tm_h)
1612
1613 rm -f nm.h
1614 nm_h=""
1615 if test "${nativefile}" != ""; then
1616     nm_h=nm.h
1617     case "${nativefile}" in
1618       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1619       * ) GDB_NM_FILE="${nativefile}"
1620     esac
1621     files="${files} ${GDB_NM_FILE}"
1622     links="${links} nm.h"
1623     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1624 fi
1625 AC_SUBST(nm_h)
1626
1627 AC_LINK_FILES($files, $links)
1628
1629 dnl Check for exe extension set on certain hosts (e.g. Win32)
1630 AC_EXEEXT
1631
1632 dnl  Detect the character set used by this host.
1633
1634 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1635 dnl  superset of ASCII containing the characters needed for French,
1636 dnl  German, Spanish, Italian, and possibly others), but if were
1637 dnl  *were* to support any host character sets other than ISO-8859-1,
1638 dnl  here's where we'd detect it.
1639 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1640           [Define to be a string naming the default host character set.])
1641
1642 AM_ICONV
1643
1644 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1645 [
1646 dnl Autoconf doesn't provide a mechanism for modifying definitions
1647 dnl provided by makefile fragments.
1648 dnl
1649
1650 changequote(,)dnl
1651 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1652 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1653 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1654 mv -f Makefile.tmp Makefile
1655 changequote([,])dnl
1656
1657
1658 case x$CONFIG_HEADERS in
1659 xconfig.h:config.in)
1660 echo > stamp-h ;;
1661 esac
1662 ],
1663 [
1664 gdb_host_cpu=$gdb_host_cpu
1665 gdb_target_cpu=$gdb_target_cpu
1666 nativefile=$nativefile
1667 ])
1668
1669 exit 0