gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 dnl List of object files and targets accumulated by configure.
  54
  55 CONFIG_OBS=
  56 CONFIG_DEPS=
  57 CONFIG_SRCS=
  58 ENABLE_CFLAGS=
  59
  60 CONFIG_ALL=
  61 CONFIG_CLEAN=
  62 CONFIG_INSTALL=
  63 CONFIG_UNINSTALL=
  64
  65 dnl Set up for gettext.
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67
  68 localedir='${datadir}/locale'
  69 AC_SUBST(localedir)
  70
  71 if test x"$USE_NLS" = xyes; then
  72    CONFIG_ALL="$CONFIG_ALL all-po"
  73    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  74    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  75    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  76 fi
  77
  78 gl_INIT
  79
  80 # For Makefile dependencies.
  81 GNULIB_STDINT_H=
  82 if test x"$STDINT_H" != x; then
  83   GNULIB_STDINT_H=gnulib/$STDINT_H
  84 fi
  85 AC_SUBST(GNULIB_STDINT_H)
  86
  87 PACKAGE=gdb
  88 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  89 AC_SUBST(PACKAGE)
  90
  91 # GDB does not use automake, but gnulib does.  This line lets us
  92 # generate its Makefile.in.
  93 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  94
  95 debugdir=${libdir}/debug
  96
  97 AC_ARG_WITH(separate-debug-dir,
  98 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  99 [debugdir="${withval}"])
 100
 101 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 102               [Global directory for separate debug files. ])
 103 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 104
 105 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 106   if test "x$prefix" = xNONE; then
 107     test_prefix=/usr/local
 108   else
 109     test_prefix=$prefix
 110   fi
 111 else
 112   test_prefix=$exec_prefix
 113 fi
 114 case ${debugdir} in
 115 "${test_prefix}"|"${test_prefix}/"*|\
 116 '${exec_prefix}'|'${exec_prefix}/'*)
 117   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
 118   ;;
 119 esac
 120
 121 AC_CONFIG_SUBDIRS(doc testsuite)
 122
 123 # Check whether to support alternative target configurations
 124 AC_ARG_ENABLE(targets,
 125 [  --enable-targets        alternative target configurations],
 126 [case "${enableval}" in
 127   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 128             ;;
 129   no)       enable_targets= ;;
 130   *)        enable_targets=$enableval ;;
 131 esac])
 132
 133 # Check whether to enable 64-bit support on 32-bit hosts
 134 AC_ARG_ENABLE(64-bit-bfd,
 135 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 136 [case "${enableval}" in
 137   yes)  want64=true  ;;
 138   no)   want64=false ;;
 139   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 140 esac],[want64=false])dnl
 141
 142 # Provide defaults for some variables set by the per-host and per-target
 143 # configuration.
 144 gdb_host_obs=posix-hdep.o
 145
 146 if test "${target}" = "${host}"; then
 147   gdb_native=yes
 148 else
 149   gdb_native=no
 150 fi
 151
 152 . $srcdir/configure.host
 153
 154 # Accumulate some settings from configure.tgt over all enabled targets
 155
 156 TARGET_OBS=
 157 all_targets=
 158
 159 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 160 do
 161   if test "$targ_alias" = "all"; then
 162     all_targets=true
 163   else
 164     # Canonicalize the secondary target names.
 165     result=`$ac_config_sub $targ_alias 2>/dev/null`
 166     if test -n "$result"; then
 167         targ=$result
 168     else
 169         targ=$targ_alias
 170     fi
 171
 172     . ${srcdir}/configure.tgt
 173
 174     # Target-specific object files
 175     for i in ${gdb_target_obs}; do
 176         case " $TARGET_OBS " in
 177         *" ${i} "*) ;;
 178         *)
 179           TARGET_OBS="$TARGET_OBS ${i}"
 180           ;;
 181         esac
 182     done
 183
 184     # Check whether this target needs 64-bit CORE_ADDR
 185     if test x${want64} = xfalse; then
 186       . ${srcdir}/../bfd/config.bfd
 187     fi
 188   fi
 189 done
 190
 191 if test x${all_targets} = xtrue; then
 192
 193   # We want all 64-bit targets if we either:
 194   #  - run on a 64-bit host  or
 195   #  - already require 64-bit support for some other target  or
 196   #  - the --enable-64-bit-bfd option was supplied
 197   # Otherwise we only support all 32-bit targets.
 198   #
 199   # NOTE: This test must be in sync with the corresponding
 200   #       tests in BFD!
 201
 202   if test x${want64} = xfalse; then
 203     AC_CHECK_SIZEOF(long)
 204     if test "x${ac_cv_sizeof_long}" = "x8"; then
 205       want64=true
 206     fi
 207   fi
 208   if test x${want64} = xtrue; then
 209     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 210   else
 211     TARGET_OBS='$(ALL_TARGET_OBS)'
 212   fi
 213 fi
 214
 215 AC_SUBST(TARGET_OBS)
 216
 217 # For other settings, only the main target counts.
 218 gdb_sim=
 219 gdb_osabi=
 220 build_gdbserver=
 221 targ=$target; . ${srcdir}/configure.tgt
 222
 223 # Fetch the default architecture and default target vector from BFD.
 224 targ=$target; . $srcdir/../bfd/config.bfd
 225
 226 # We only want the first architecture, so strip off the others if
 227 # there is more than one.
 228 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 229
 230 if test "x$targ_archs" != x; then
 231   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 232     [Define to BFD's default architecture. ])
 233 fi
 234 if test "x$targ_defvec" != x; then
 235   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 236     [Define to BFD's default target vector. ])
 237 fi
 238
 239 # The CLI cannot be disabled yet, but may be in the future.
 240
 241 # Enable CLI.
 242 AC_ARG_ENABLE(gdbcli,
 243 [  --disable-gdbcli        disable command-line interface (CLI)],
 244   [case $enableval in
 245     yes)
 246       ;;
 247     no)
 248       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 249     *)
 250       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 251   esac],
 252   [enable_gdbcli=yes])
 253 if test x"$enable_gdbcli" = xyes; then
 254   if test -d $srcdir/cli; then
 255     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 256     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 257     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 258     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 259   fi
 260 fi
 261
 262 # Enable MI.
 263 AC_ARG_ENABLE(gdbmi,
 264 [  --disable-gdbmi         disable machine-interface (MI)],
 265   [case $enableval in
 266     yes | no)
 267       ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 270   esac],
 271   [enable_gdbmi=yes])
 272 if test x"$enable_gdbmi" = xyes; then
 273   if test -d $srcdir/mi; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable TUI.
 282 AC_ARG_ENABLE(tui,
 283 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 284   [case $enableval in
 285     yes | no | auto)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 289   esac],enable_tui=auto)
 290
 291 # Enable gdbtk.
 292 AC_ARG_ENABLE(gdbtk,
 293 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 294   [case $enableval in
 295     yes | no)
 296       ;;
 297     *)
 298       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 299   esac],
 300   [if test -d $srcdir/gdbtk; then
 301     enable_gdbtk=yes
 302   else
 303     enable_gdbtk=no
 304   fi])
 305 # We unconditionally disable gdbtk tests on selected platforms.
 306 case $host_os in
 307   go32* | windows*)
 308     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 309     enable_gdbtk=no ;;
 310 esac
 311
 312 # Libunwind support.
 313 AC_ARG_WITH(libunwind,
 314 [  --with-libunwind            Use libunwind frame unwinding support],
 315 [case "${withval}" in
 316   yes)  enable_libunwind=yes ;;
 317   no)   enable_libunwind=no ;;
 318   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 319 esac],[
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 322     enable_libunwind=yes;
 323   fi
 324 ])
 325
 326 if test x"$enable_libunwind" = xyes; then
 327   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 328   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 329   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 330   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 331   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 332 fi
 333
 334 opt_curses=no
 335 AC_ARG_WITH(curses, AC_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 336
 337 if test "$opt_curses" = "yes"; then
 338         prefer_curses=yes
 339 fi
 340
 341 # Profiling support.
 342 AC_ARG_ENABLE(profiling,
 343 [  --enable-profiling      enable profiling of GDB],
 344   [case $enableval in
 345     yes | no)
 346       ;;
 347     *)
 348       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 349   esac],
 350  [enable_profiling=no])
 351
 352 AC_CHECK_FUNCS(monstartup _mcleanup)
 353 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 354 [AC_TRY_LINK(
 355 [#include <stdlib.h>
 356 extern char _etext;
 357 ],
 358 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 359 if test $ac_cv_var__etext = yes; then
 360   AC_DEFINE(HAVE__ETEXT, 1,
 361             [Define to 1 if your system has the _etext variable. ])
 362 fi
 363 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 364 [AC_TRY_LINK(
 365 [#include <stdlib.h>
 366 extern char etext;
 367 ],
 368 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 369 if test $ac_cv_var_etext = yes; then
 370   AC_DEFINE(HAVE_ETEXT, 1,
 371             [Define to 1 if your system has the etext variable. ])
 372 fi
 373 if test "$enable_profiling" = yes ; then
 374   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 375     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 376   fi
 377   PROFILE_CFLAGS=-pg
 378   OLD_CFLAGS="$CFLAGS"
 379   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 380
 381   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 382     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 383      ac_cv_cc_supports_pg=no)])
 384
 385   if test $ac_cv_cc_supports_pg = no; then
 386     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 387   fi
 388
 389   CFLAGS="$OLD_CFLAGS"
 390 fi
 391
 392 ACX_PKGVERSION([GDB])
 393 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 394 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 395 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 396
 397 # --------------------- #
 398 # Checks for programs.  #
 399 # --------------------- #
 400
 401 AC_PROG_AWK
 402 AC_PROG_INSTALL
 403 AC_PROG_LN_S
 404 AC_PROG_RANLIB
 405 AC_PROG_YACC
 406
 407 AC_CHECK_TOOL(AR, ar)
 408 AC_CHECK_TOOL(DLLTOOL, dlltool)
 409 AC_CHECK_TOOL(WINDRES, windres)
 410
 411 # Needed for GNU/Hurd.
 412 AC_CHECK_TOOL(MIG, mig)
 413
 414 # ---------------------- #
 415 # Checks for libraries.  #
 416 # ---------------------- #
 417
 418 # We might need to link with -lm; most simulators need it.
 419 AC_CHECK_LIB(m, main)
 420
 421 # We need to link with -lw to get `wctype' on Solaris before Solaris
 422 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 423 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 424 # is known to have this problem).  Therefore we avoid libw if we can.
 425 AC_CHECK_FUNC(wctype, [],
 426   [AC_CHECK_LIB(w, wctype)])
 427
 428 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 429 AC_SEARCH_LIBS(gethostbyname, nsl)
 430
 431 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 432 AC_SEARCH_LIBS(socketpair, socket)
 433
 434 # Link in zlib if we can.  This allows us to read compressed debug sections.
 435 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 436
 437 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 438 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 439
 440 AM_ICONV
 441
 442 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 443 # There is a very specific comment in /usr/include/curses.h explaining that
 444 # termcap routines built into libcurses must not be used.
 445 #
 446 # The symptoms we observed so far is GDB unexpectedly changing
 447 # the terminal settings when tgetent is called - this is particularly
 448 # visible as the output is missing carriage returns, and so rapidly
 449 # becomes very hard to read.
 450 #
 451 # The readline configure script has already decided that libtermcap
 452 # was enough for its purposes, and so decided to build readline using
 453 # libtermcap.  Since the TUI mode requires curses, building GDB with
 454 # TUI enabled results in both libraries to be used at the same time,
 455 # which is not allowed.  This basically means that GDB with TUI is
 456 # broken on alpha-osf.
 457
 458 case $host_os in
 459   alpha*-*-osf* )
 460     if "$enable_tui" = "yes"; then
 461       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 462     fi
 463     if "$enable_tui" = "auto"; then
 464       enable_tui=no
 465     fi
 466     ;;
 467 esac
 468
 469 # For the TUI, we need enhanced curses functionality.
 470 if test x"$enable_tui" = xyes; then
 471   prefer_curses=yes
 472 fi
 473
 474 curses_found=no
 475 if test x"$prefer_curses" = xyes; then
 476   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 477   # curses library because the latter might not provide all the
 478   # functionality we need.  However, this leads to problems on systems
 479   # where the linker searches /usr/local/lib, but the compiler doesn't
 480   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 481   # default installation of ncurses on alpha*-dec-osf* will lead to such
 482   # a situation.
 483   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 484
 485   if test "$ac_cv_search_waddstr" != no; then
 486     curses_found=yes
 487   fi
 488 fi
 489
 490 # Check whether we should enable the TUI, but only do so if we really
 491 # can.
 492 if test x"$enable_tui" != xno; then
 493   if test -d $srcdir/tui; then
 494     if test "$curses_found" != no; then
 495       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 496       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 497       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 498       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 499       CONFIG_ALL="${CONFIG_ALL} all-tui"
 500       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 501       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 502       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 503     else
 504       if test x"$enable_tui" = xyes; then
 505         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 506       else
 507         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 508       fi
 509     fi
 510   fi
 511 fi
 512
 513 # Since GDB uses Readline, we need termcap functionality.  In many
 514 # cases this will be provided by the curses library, but some systems
 515 # have a seperate termcap library, or no curses library at all.
 516
 517 case $host_os in
 518   cygwin*)
 519     if test -d $srcdir/libtermcap; then
 520       LIBS="../libtermcap/libtermcap.a $LIBS"
 521       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 522     fi ;;
 523   go32* | *djgpp*)
 524     ac_cv_search_tgetent="none required"
 525     ;;
 526   *mingw32*)
 527     ac_cv_search_tgetent="none required"
 528     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 529     ;;
 530 esac
 531
 532 # These are the libraries checked by Readline.
 533 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 534
 535 if test "$ac_cv_search_tgetent" = no; then
 536   AC_MSG_ERROR([no termcap library found])
 537 fi
 538
 539 AC_ARG_WITH([system-readline],
 540   [AS_HELP_STRING([--with-system-readline],
 541                   [use installed readline library])])
 542
 543 if test "$with_system_readline" = yes; then
 544   READLINE=-lreadline
 545   READLINE_DEPS=
 546   READLINE_CFLAGS=
 547 else
 548   READLINE='$(READLINE_DIR)/libreadline.a'
 549   READLINE_DEPS='$(READLINE)'
 550   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 551 fi
 552 AC_SUBST(READLINE)
 553 AC_SUBST(READLINE_DEPS)
 554 AC_SUBST(READLINE_CFLAGS)
 555
 556 AC_ARG_WITH(expat,
 557   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 558   [], [with_expat=auto])
 559 AC_MSG_CHECKING([whether to use expat])
 560 AC_MSG_RESULT([$with_expat])
 561
 562 if test "${with_expat}" = no; then
 563   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 564   HAVE_LIBEXPAT=no
 565 else
 566   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 567                         [XML_Parser p = XML_ParserCreate (0);])
 568   if test "$HAVE_LIBEXPAT" != yes; then
 569     if test "$with_expat" = yes; then
 570       AC_MSG_ERROR([expat is missing or unusable])
 571     else
 572       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 573     fi
 574   else
 575     save_LIBS=$LIBS
 576     LIBS="$LIBS $LIBEXPAT"
 577     AC_CHECK_FUNCS(XML_StopParser)
 578     LIBS=$save_LIBS
 579   fi
 580 fi
 581
 582 dnl Utility to simplify finding libpython.
 583 AC_DEFUN([AC_TRY_LIBPYTHON],
 584 [
 585   version=$1
 586   define([have_libpython_var],$2)
 587   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 588                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 589   [HAVE_LIB]VERSION=no
 590   AC_MSG_CHECKING([for ${version}])
 591   save_LIBS=$LIBS
 592   LIBS="$LIBS -l${version}"
 593   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 594                                  [[Py_Initialize ();]]),
 595                  [[HAVE_LIB]VERSION=yes
 596                   have_libpython_var=yes],
 597                  [LIBS=$save_LIBS])
 598   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 599 ])
 600
 601 AC_ARG_WITH(python,
 602   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 603   [], [with_python=auto])
 604 AC_MSG_CHECKING([whether to use python])
 605 AC_MSG_RESULT([$with_python])
 606
 607 if test "${with_python}" = no; then
 608   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 609   have_libpython=no
 610 else
 611   case "${with_python}" in
 612   yes | auto)
 613     # Leave as empty, use defaults.
 614     python_includes=
 615     python_libs=
 616     ;;
 617   /*)
 618     python_includes="-I${with_python}/include"
 619     python_libs="-L${with_python}/lib"
 620     ;;
 621   *)
 622     AC_ERROR(invalid value for --with-python)
 623     ;;
 624   esac
 625
 626   save_CPPFLAGS=$CPPFLAGS
 627   CPPFLAGS="$CPPFLAGS ${python_includes}"
 628   save_LIBS=$LIBS
 629   LIBS="$LIBS ${python_libs}"
 630   have_libpython=no
 631   if test "${have_libpython}" = no; then
 632     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 633     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 634       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 635     fi
 636   fi
 637   if test ${have_libpython} = no; then
 638     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 639     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 640       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 641     fi
 642   fi
 643   if test ${have_libpython} = no; then
 644     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 645     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 646       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 647     fi
 648   fi
 649   if test ${have_libpython} = no; then
 650     case "${with_python}" in
 651     yes)
 652       AC_MSG_ERROR([python is missing or unusable])
 653       ;;
 654     auto)
 655       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 656       ;;
 657     *)
 658       AC_MSG_ERROR([no usable python found at ${with_python}])
 659       ;;
 660     esac
 661     CPPFLAGS=$save_CPPFLAGS
 662     LIBS=$save_LIBS
 663   fi
 664 fi
 665
 666 if test "${have_libpython}" = yes; then
 667   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 668   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 669   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 670   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 671   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 672
 673   # Flags needed to compile Python code (taken from python-config --cflags).
 674   # We cannot call python-config directly because it will output whatever was
 675   # used when compiling the Python interpreter itself, including flags which
 676   # would make the python-related objects be compiled differently from the
 677   # rest of GDB (e.g., -O2 and -fPIC).
 678   if test "${GCC}" = yes; then
 679     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 680   fi
 681
 682   if test "x${tentative_python_cflags}" != x; then
 683     AC_MSG_CHECKING(compiler flags for python code)
 684     for flag in ${tentative_python_cflags}; do
 685       # Check that the compiler accepts it
 686       saved_CFLAGS="$CFLAGS"
 687       CFLAGS="$CFLAGS $flag"
 688       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 689       CFLAGS="$saved_CFLAGS"
 690     done
 691     AC_MSG_RESULT(${PYTHON_CFLAGS})
 692   fi
 693 else
 694   # Even if Python support is not compiled in, we need to have these files
 695   # included in order to recognize the GDB command "python".
 696   CONFIG_OBS="$CONFIG_OBS python.o python-value.o"
 697   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/python-value.c"
 698 fi
 699 AC_SUBST(PYTHON_CFLAGS)
 700
 701 # ------------------------- #
 702 # Checks for header files.  #
 703 # ------------------------- #
 704
 705 AC_HEADER_DIRENT
 706 AC_HEADER_STAT
 707 AC_HEADER_STDC
 708 # elf_hp.h is for HP/UX 64-bit shared library support.
 709 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 710 # unconditionally, so what's the point in checking these?
 711 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 712                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 713                   stdlib.h string.h memory.h strings.h sys/fault.h \
 714                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 715                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 716                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 717                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 718                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 719 AC_CHECK_HEADERS(link.h, [], [],
 720 [#if HAVE_SYS_TYPES_H
 721 # include <sys/types.h>
 722 #endif
 723 #if HAVE_NLIST_H
 724 # include <nlist.h>
 725 #endif
 726 ])
 727 AC_CHECK_HEADERS(sys/proc.h, [], [],
 728 [#if HAVE_SYS_PARAM_H
 729 # include <sys/param.h>
 730 #endif
 731 ])
 732 AC_CHECK_HEADERS(sys/user.h, [], [],
 733 [#if HAVE_SYS_PARAM_H
 734 # include <sys/param.h>
 735 #endif
 736 ])
 737
 738 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 739 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 740 # think that we don't have <curses.h> if we're using GCC.
 741 case $host_os in
 742   solaris2.[[789]])
 743     if test "$GCC" = yes; then
 744       AC_DEFINE(_MSE_INT_H, 1,
 745         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 746    Solaris 2.[789] when using GCC. ])
 747     fi ;;
 748 esac
 749 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 750 AC_CHECK_HEADERS(term.h, [], [],
 751 [#if HAVE_CURSES_H
 752 # include <curses.h>
 753 #endif
 754 ])
 755
 756 # ------------------------- #
 757 # Checks for declarations.  #
 758 # ------------------------- #
 759
 760 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 761                 snprintf, vsnprintf])
 762 AM_LC_MESSAGES
 763
 764 # ----------------------- #
 765 # Checks for structures.  #
 766 # ----------------------- #
 767
 768 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 769
 770 # ------------------ #
 771 # Checks for types.  #
 772 # ------------------ #
 773
 774 AC_TYPE_SIGNAL
 775 AC_CHECK_TYPES(socklen_t, [], [],
 776 [#include <sys/types.h>
 777 #include <sys/socket.h>
 778 ])
 779
 780 # ------------------------------------- #
 781 # Checks for compiler characteristics.  #
 782 # ------------------------------------- #
 783
 784 AC_C_CONST
 785 AC_C_INLINE
 786 AC_C_BIGENDIAN
 787
 788 # ------------------------------ #
 789 # Checks for library functions.  #
 790 # ------------------------------ #
 791
 792 AC_FUNC_ALLOCA
 793 AC_FUNC_MMAP
 794 AC_FUNC_VFORK
 795 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 796                 getgid poll pread64 sbrk setpgid setpgrp setsid \
 797                 sigaction sigprocmask sigsetmask socketpair syscall \
 798                 ttrace wborder setlocale iconvlist])
 799 AM_LANGINFO_CODESET
 800
 801 # Check the return and argument types of ptrace.  No canned test for
 802 # this, so roll our own.
 803 gdb_ptrace_headers='
 804 #if HAVE_SYS_TYPES_H
 805 # include <sys/types.h>
 806 #endif
 807 #if HAVE_SYS_PTRACE_H
 808 # include <sys/ptrace.h>
 809 #endif
 810 #if HAVE_UNISTD_H
 811 # include <unistd.h>
 812 #endif
 813 '
 814 # There is no point in checking if we don't have a prototype.
 815 AC_CHECK_DECLS(ptrace, [], [
 816   : ${gdb_cv_func_ptrace_ret='int'}
 817   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 818 ], $gdb_ptrace_headers)
 819 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 820 # empty argument list, so check for that explicitly.
 821 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 822   AC_TRY_COMPILE($gdb_ptrace_headers,
 823     [extern long ptrace (enum __ptrace_request, ...);],
 824     gdb_cv_func_ptrace_ret='long',
 825     AC_TRY_COMPILE($gdb_ptrace_headers,
 826       [extern int ptrace ();],
 827       gdb_cv_func_ptrace_ret='int',
 828       gdb_cv_func_ptrace_ret='long')))
 829 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 830   [Define as the return type of ptrace.])
 831 # Check argument types.
 832 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 833   AC_TRY_COMPILE($gdb_ptrace_headers,
 834     [extern long ptrace (enum __ptrace_request, ...);],
 835     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 836 for gdb_arg1 in 'int' 'long'; do
 837  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 838   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 839    for gdb_arg4 in 'int' 'long'; do
 840      AC_TRY_COMPILE($gdb_ptrace_headers, [
 841 extern $gdb_cv_func_ptrace_ret
 842   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 843 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 844     break 4;])
 845     for gdb_arg5 in 'int *' 'int' 'long'; do
 846      AC_TRY_COMPILE($gdb_ptrace_headers, [
 847 extern $gdb_cv_func_ptrace_ret
 848   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 849 ], [
 850 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 851     break 5;])
 852     done
 853    done
 854   done
 855  done
 856 done
 857 # Provide a safe default value.
 858 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 859 ])])
 860 ac_save_IFS=$IFS; IFS=','
 861 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 862 IFS=$ac_save_IFS
 863 shift
 864 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 865   [Define to the type of arg 3 for ptrace.])
 866 if test -n "$[5]"; then
 867   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 868     [Define to the type of arg 5 for ptrace.])
 869 fi
 870
 871 dnl AC_FUNC_SETPGRP does not work when cross compiling
 872 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 873 if test "$cross_compiling" = no; then
 874   AC_FUNC_SETPGRP
 875 else
 876   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 877     [AC_TRY_COMPILE([
 878 #include <unistd.h>
 879 ], [
 880   if (setpgrp(1,1) == -1)
 881     exit (0);
 882   else
 883     exit (1);
 884 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 885 if test $ac_cv_func_setpgrp_void = yes; then
 886   AC_DEFINE(SETPGRP_VOID, 1)
 887 fi
 888 fi
 889
 890 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 891 # since sigsetjmp might only be defined as a macro.
 892 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 893 [AC_TRY_COMPILE([
 894 #include <setjmp.h>
 895 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 896 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 897 if test $gdb_cv_func_sigsetjmp = yes; then
 898   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 899 fi
 900
 901 # Assume we'll default to using the included libiberty regex.
 902 gdb_use_included_regex=yes
 903
 904 # However, if the system regex is GNU regex, then default to *not*
 905 # using the included regex.
 906 AC_CACHE_CHECK(
 907   [for GNU regex],
 908   [gdb_cv_have_gnu_regex],
 909   [AC_TRY_COMPILE(
 910     [#include <gnu-versions.h>],
 911     [#define REGEX_INTERFACE_VERSION 1
 912 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 913 # error "Version mismatch"
 914 #endif],
 915     gdb_cv_have_gnu_regex=yes,
 916     gdb_cv_have_gnu_regex=no)])
 917 if test $gdb_cv_have_gnu_regex = yes; then
 918   gdb_use_included_regex=no
 919 fi
 920
 921 AC_ARG_WITH(included-regex,
 922   [  --without-included-regex don't use included regex; this is the default
 923                           on systems with version 2 of the GNU C library
 924                           (use with caution on other system)],
 925   gdb_with_regex=$withval,
 926   gdb_with_regex=$gdb_use_included_regex)
 927 if test "$gdb_with_regex" = yes; then
 928   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 929     [Define to 1 if the regex included in libiberty should be used.])
 930 fi
 931
 932 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 933 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 934 [#include <sys/param.h>
 935 #include <sys/proc.h>
 936 ])
 937
 938 # See if <sys/lwp.h> defines `struct lwp`.
 939 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 940 [AC_TRY_COMPILE([#include <sys/param.h>
 941 #include <sys/lwp.h>], [struct lwp l;],
 942 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 943 if test $gdb_cv_struct_lwp = yes; then
 944   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 945             [Define to 1 if your system has struct lwp.])
 946 fi
 947
 948 # See if <machine/reg.h> degines `struct reg'.
 949 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 950 [AC_TRY_COMPILE([#include <sys/types.h>
 951 #include <machine/reg.h>], [struct reg r;],
 952 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 953 if test $gdb_cv_struct_reg = yes; then
 954   AC_DEFINE(HAVE_STRUCT_REG, 1,
 955             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 956 fi
 957
 958 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 959 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 960 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 961                  [#include <machine/reg.h>])
 962
 963 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 964 AC_MSG_CHECKING(for PTRACE_GETREGS)
 965 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 966 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 967                 [PTRACE_GETREGS;],
 968                 [gdb_cv_have_ptrace_getregs=yes],
 969                 [gdb_cv_have_ptrace_getregs=no])])
 970 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 971 if test $gdb_cv_have_ptrace_getregs = yes; then
 972   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 973   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 974 fi
 975
 976 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 977 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 978 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 979 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 980                 [PTRACE_GETFPXREGS;],
 981                 [gdb_cv_have_ptrace_getfpxregs=yes],
 982                 [gdb_cv_have_ptrace_getfpxregs=no])])
 983 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 984 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 985   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 986   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 987 fi
 988
 989 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 990 AC_MSG_CHECKING(for PT_GETDBREGS)
 991 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 992 [AC_TRY_COMPILE([#include <sys/types.h>
 993 #include <sys/ptrace.h>],
 994                 [PT_GETDBREGS;],
 995                 [gdb_cv_have_pt_getdbregs=yes],
 996                 [gdb_cv_have_pt_getdbregs=no])])
 997 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 998 if test $gdb_cv_have_pt_getdbregs = yes; then
 999   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1000   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1001 fi
1002
1003 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1004 AC_MSG_CHECKING(for PT_GETXMMREGS)
1005 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1006 [AC_TRY_COMPILE([#include <sys/types.h>
1007 #include <sys/ptrace.h>],
1008                 [PT_GETXMMREGS;],
1009                 [gdb_cv_have_pt_getxmmregs=yes],
1010                 [gdb_cv_have_pt_getxmmregs=no])])
1011 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1012 if test $gdb_cv_have_pt_getxmmregs = yes; then
1013   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1014   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1015 fi
1016
1017 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1018
1019 if test "${target}" = "${host}"; then
1020   case "${host}" in
1021   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1022       AC_DEFINE(NEW_PROC_API, 1,
1023       [Define if you want to use new multi-fd /proc interface
1024        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1025       ;;
1026   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1027       AC_DEFINE(NEW_PROC_API, 1,
1028       [Define if you want to use new multi-fd /proc interface
1029        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1030       ;;
1031   mips-sgi-irix5*)
1032       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1033       AC_DEFINE([_KMEMUSER], 1,
1034       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1035        around a <sys/proc.h> problem on IRIX 5.])
1036       ;;
1037   esac
1038 fi
1039
1040 if test "$ac_cv_header_sys_procfs_h" = yes; then
1041   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1042   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1043   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1044   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1045   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1046   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1047   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1048   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1049   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1050   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1051   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1052   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1053   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1054   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1055
1056
1057   dnl Check for broken prfpregset_t type
1058
1059   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1060   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1061   dnl instead of the struct itself).  We detect this here, and work
1062   dnl around it in gdb_proc_service.h.
1063
1064   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1065     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1066     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1067       [AC_TRY_RUN([#include <sys/procfs.h>
1068        int main ()
1069        {
1070          if (sizeof (prfpregset_t) == sizeof (void *))
1071            return 1;
1072          return 0;
1073        }],
1074        gdb_cv_prfpregset_t_broken=no,
1075        gdb_cv_prfpregset_t_broken=yes,
1076        gdb_cv_prfpregset_t_broken=yes)])
1077     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1078     if test $gdb_cv_prfpregset_t_broken = yes; then
1079       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1080       [Define if the prfpregset_t type is broken.])
1081     fi
1082   fi
1083
1084   dnl Check for PIOCSET ioctl entry
1085
1086   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1087   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1088   [AC_TRY_COMPILE([#include <unistd.h>
1089 #include <sys/types.h>
1090 #include <sys/procfs.h>
1091 ], [
1092     int dummy;;
1093     dummy = ioctl(0, PIOCSET, &dummy);
1094   ],
1095   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1096   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1097   if test $gdb_cv_have_procfs_piocset = yes; then
1098     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1099     [Define if ioctl argument PIOCSET is available.])
1100   fi
1101 fi
1102
1103 dnl For native ports (host == target), check to see what kind of
1104 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1105 if test ${host} = ${target} ; then
1106   dnl Check for struct link_map with l_ members which are indicative
1107   dnl of SVR4-like shared libraries
1108
1109   AC_MSG_CHECKING(for member l_addr in struct link_map)
1110   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1111     [AC_TRY_COMPILE([#include <link.h>],
1112                     [struct link_map lm; (void) lm.l_addr;],
1113                     gdb_cv_have_struct_link_map_with_l_members=yes,
1114                     gdb_cv_have_struct_link_map_with_l_members=no)])
1115   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1116   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1117     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1118     [Define if <link.h> exists and defines struct link_map which has
1119      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1120      SVR4-like systems.)])
1121   fi
1122
1123   dnl Check for struct link_map with lm_ members which are indicative
1124   dnl of SunOS-like shared libraries
1125
1126   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1127   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1128     [AC_TRY_COMPILE([#include <sys/types.h>
1129 #include <link.h>],
1130                     [struct link_map lm; (void) lm.lm_addr;],
1131                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1132                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1133   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1134   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1135     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1136     [Define if <link.h> exists and defines struct link_map which has
1137      members with an ``lm_'' prefix.  (For SunOS.)])
1138   fi
1139
1140   dnl Check for struct so_map with som_ members which are found on
1141   dnl some *BSD systems.
1142
1143   AC_MSG_CHECKING(for member som_addr in struct so_map)
1144   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1145     [AC_TRY_COMPILE([#include <sys/types.h>
1146 #ifdef HAVE_NLIST_H
1147 #include <nlist.h>
1148 #endif
1149 #include <link.h>],
1150                     [struct so_map lm; (void) lm.som_addr;],
1151                     gdb_cv_have_struct_so_map_with_som_members=yes,
1152                     gdb_cv_have_struct_so_map_with_som_members=no)])
1153   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1154   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1155     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1156     [Define if <link.h> exists and defines a struct so_map which has
1157      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1158   fi
1159
1160   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1161   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1162
1163   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1164   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1165     [AC_TRY_COMPILE([#define _SYSCALL32
1166 #include <sys/link.h>], [struct link_map32 l;],
1167      gdb_cv_have_struct_link_map32=yes,
1168      gdb_cv_have_struct_link_map32=no)])
1169   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1170   if test $gdb_cv_have_struct_link_map32 = yes; then
1171     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1172     [Define if <sys/link.h> has struct link_map32])
1173     AC_DEFINE(_SYSCALL32, 1,
1174     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1175   fi
1176 fi
1177
1178 # Check if the compiler supports the `long long' type.
1179
1180 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1181                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1182 [[extern long long foo;]],
1183 [[switch (foo & 2) { case 0: return 1; }]])],
1184                                   gdb_cv_c_long_long=yes,
1185                                   gdb_cv_c_long_long=no)])
1186 if test $gdb_cv_c_long_long = yes; then
1187   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1188             [Define to 1 if the compiler supports long long.])
1189 fi
1190
1191 # Check if the compiler and runtime support printing long longs.
1192
1193 AC_CACHE_CHECK([for long long support in printf],
1194                gdb_cv_printf_has_long_long,
1195                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1196 [[char buf[32];
1197   long long l = 0;
1198   l = (l << 16) + 0x0123;
1199   l = (l << 16) + 0x4567;
1200   l = (l << 16) + 0x89ab;
1201   l = (l << 16) + 0xcdef;
1202   sprintf (buf, "0x%016llx", l);
1203   return (strcmp ("0x0123456789abcdef", buf));]])],
1204                               gdb_cv_printf_has_long_long=yes,
1205                               gdb_cv_printf_has_long_long=no,
1206                               gdb_cv_printf_has_long_long=no)])
1207 if test $gdb_cv_printf_has_long_long = yes; then
1208   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1209             [Define to 1 if the "%ll" format works to print long longs.])
1210 fi
1211
1212 # Check if the compiler and runtime support printing decfloats.
1213
1214 AC_CACHE_CHECK([for decfloat support in printf],
1215                gdb_cv_printf_has_decfloat,
1216                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1217 [[char buf[64];
1218   _Decimal32 d32 = 1.2345df;
1219   _Decimal64 d64 = 1.2345dd;
1220   _Decimal128 d128 = 1.2345dl;
1221   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1222   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1223                               gdb_cv_printf_has_decfloat=yes,
1224                               gdb_cv_printf_has_decfloat=no,
1225                               gdb_cv_printf_has_decfloat=no)])
1226 if test $gdb_cv_printf_has_decfloat = yes; then
1227   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1228             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1229 fi
1230
1231 # Check if the compiler supports the `long double' type.  We can't use
1232 # AC_C_LONG_DOUBLE because that one does additional checks on the
1233 # constants defined in <float.h> that fail on some systems,
1234 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1235
1236 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1237                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1238                                   gdb_cv_c_long_double=yes,
1239                                   gdb_cv_c_long_double=no)])
1240 if test $gdb_cv_c_long_double = yes; then
1241   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1242            [Define to 1 if the compiler supports long double.])
1243 fi
1244
1245 # Check if the compiler and runtime support printing long doubles.
1246
1247 AC_CACHE_CHECK([for long double support in printf],
1248                gdb_cv_printf_has_long_double,
1249                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1250 [[char buf[16];
1251   long double f = 3.141592653;
1252   sprintf (buf, "%Lg", f);
1253   return (strncmp ("3.14159", buf, 7));]])],
1254                               gdb_cv_printf_has_long_double=yes,
1255                               gdb_cv_printf_has_long_double=no,
1256                               gdb_cv_printf_has_long_double=no)])
1257 if test $gdb_cv_printf_has_long_double = yes; then
1258   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1259             [Define to 1 if the "%Lg" format works to print long doubles.])
1260 fi
1261
1262 # Check if the compiler and runtime support scanning long doubles.
1263
1264 AC_CACHE_CHECK([for long double support in scanf],
1265                gdb_cv_scanf_has_long_double,
1266                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1267 [[#include <stdio.h>]],
1268 [[char *buf = "3.141592653";
1269   long double f = 0;
1270   sscanf (buf, "%Lg", &f);
1271   return !(f > 3.14159 && f < 3.14160);]])],
1272                               gdb_cv_scanf_has_long_double=yes,
1273                               gdb_cv_scanf_has_long_double=no,
1274                               gdb_cv_scanf_has_long_double=no)])
1275 if test $gdb_cv_scanf_has_long_double = yes; then
1276   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1277             [Define to 1 if the "%Lg" format works to scan long doubles.])
1278 fi
1279
1280 case ${host_os} in
1281 aix*)
1282   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1283     SAVE_LDFLAGS=$LDFLAGS
1284
1285     case $GCC in
1286     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1287     *) gdb_cv_bigtoc=-bbigtoc ;;
1288     esac
1289
1290     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1291     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1292     LDFLAGS="${SAVE_LDFLAGS}"
1293   ])
1294   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1295   ;;
1296 esac
1297
1298
1299 dnl For certain native configurations, we need to check whether thread
1300 dnl support can be built in or not.
1301 dnl
1302 dnl Note that we only want this if we are both native (host == target),
1303 dnl and not doing a canadian cross build (build == host).
1304
1305 if test ${build} = ${host} -a ${host} = ${target} ; then
1306    case ${host_os} in
1307    hpux*)
1308       AC_MSG_CHECKING(for HPUX/OSF thread support)
1309       if test -f /usr/include/dce/cma_config.h ; then
1310          if test "$GCC" = "yes" ; then
1311             AC_MSG_RESULT(yes)
1312             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1313             [Define if you have HPUX threads])
1314             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1315             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1316          else
1317             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1318          fi
1319       else
1320          AC_MSG_RESULT(no)
1321       fi
1322       ;;
1323    solaris*)
1324       # See if thread_db library is around for Solaris thread debugging.
1325       # Note that we must explicitly test for version 1 of the library
1326       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1327       # the same API.
1328       AC_MSG_CHECKING(for Solaris thread debugging library)
1329       if test -f /usr/lib/libthread_db.so.1 ; then
1330          AC_MSG_RESULT(yes)
1331          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1332          [Define if using Solaris thread debugging.])
1333          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1334          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1335          AC_CHECK_LIB(dl, dlopen)
1336          if test "$GCC" = "yes" ; then
1337             # The GNU linker requires the -export-dynamic option to make
1338             # all symbols visible in the dynamic symbol table.
1339             hold_ldflags=$LDFLAGS
1340             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1341             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1342             AC_TRY_LINK(, [int i;], found=yes, found=no)
1343             LDFLAGS=$hold_ldflags
1344             AC_MSG_RESULT($found)
1345             if test $found = yes; then
1346                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1347             fi
1348          fi
1349          # Sun randomly tweaked the prototypes in <proc_service.h>
1350          # at one point.
1351          AC_MSG_CHECKING(if <proc_service.h> is old)
1352          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1353             AC_TRY_COMPILE([
1354                 #include <proc_service.h>
1355                 ps_err_e ps_pdwrite
1356                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1357             ],, gdb_cv_proc_service_is_old=no,
1358                 gdb_cv_proc_service_is_old=yes)
1359          ])
1360          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1361          if test $gdb_cv_proc_service_is_old = yes; then
1362             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1363             [Define if <proc_service.h> on solaris uses int instead of
1364              size_t, and assorted other type changes.])
1365          fi
1366       else
1367          AC_MSG_RESULT(no)
1368       fi
1369       ;;
1370    aix*)
1371       AC_MSG_CHECKING(for AiX thread debugging library)
1372       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1373                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1374                                    [#ifndef PTHDB_VERSION_3
1375                                     #error
1376                                     #endif],
1377                                    gdb_cv_have_aix_thread_debug=yes,
1378                                    gdb_cv_have_aix_thread_debug=no)])
1379       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1380       if test $gdb_cv_have_aix_thread_debug = yes; then
1381          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1382          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1383          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1384       fi
1385       ;;
1386    esac
1387    AC_SUBST(CONFIG_LDFLAGS)
1388 fi
1389
1390 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1391 dnl other error codes.
1392 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1393    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1394                   gdb_cv_thread_db_h_has_td_notalloc,
1395      AC_TRY_COMPILE(
1396        [#include <thread_db.h>],
1397        [int i = TD_NOTALLOC;],
1398        gdb_cv_thread_db_h_has_td_notalloc=yes,
1399        gdb_cv_thread_db_h_has_td_notalloc=no
1400      )
1401    )
1402    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1403                   gdb_cv_thread_db_h_has_td_version,
1404      AC_TRY_COMPILE(
1405        [#include <thread_db.h>],
1406        [int i = TD_VERSION;],
1407        gdb_cv_thread_db_h_has_td_version=yes,
1408        gdb_cv_thread_db_h_has_td_version=no
1409      )
1410    )
1411    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1412                   gdb_cv_thread_db_h_has_td_notls,
1413      AC_TRY_COMPILE(
1414        [#include <thread_db.h>],
1415        [int i = TD_NOTLS;],
1416        gdb_cv_thread_db_h_has_td_notls=yes,
1417        gdb_cv_thread_db_h_has_td_notls=no
1418      )
1419    )
1420 fi
1421 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1422   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1423             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1424 fi
1425 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1426   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1427             [Define if <thread_db.h> has the TD_VERSION error code.])
1428 fi
1429 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1430   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1431             [Define if <thread_db.h> has the TD_NOTLS error code.])
1432 fi
1433
1434 dnl See if we have a sys/syscall header file that has __NR_tkill.
1435 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1436    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1437                   gdb_cv_sys_syscall_h_has_tkill,
1438      AC_TRY_COMPILE(
1439        [#include <sys/syscall.h>],
1440        [int i = __NR_tkill;],
1441        gdb_cv_sys_syscall_h_has_tkill=yes,
1442        gdb_cv_sys_syscall_h_has_tkill=no
1443      )
1444    )
1445 fi
1446 dnl See if we can issue tkill syscall.
1447 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1448   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1449 fi
1450
1451 dnl Check if we can disable the virtual address space randomization.
1452 dnl The functionality of setarch -R.
1453 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1454 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1455 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1456 #       define ADDR_NO_RANDOMIZE 0x0040000
1457 #      endif
1458        /* Test the flag could be set and stays set.  */
1459        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1460        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1461            return 1])])
1462 AC_RUN_IFELSE([PERSONALITY_TEST],
1463               [have_personality=true],
1464               [have_personality=false],
1465               [AC_LINK_IFELSE([PERSONALITY_TEST],
1466                               [have_personality=true],
1467                               [have_personality=false])])
1468 if $have_personality
1469 then
1470     AC_DEFINE([HAVE_PERSONALITY], 1,
1471               [Define if you support the personality syscall.])
1472 fi
1473
1474 dnl Handle optional features that can be enabled.
1475
1476 AC_ARG_WITH(sysroot,
1477 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1478 [
1479  case ${with_sysroot} in
1480  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1481  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1482  esac
1483
1484  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1485
1486  if test "x$prefix" = xNONE; then
1487   test_prefix=/usr/local
1488  else
1489   test_prefix=$prefix
1490  fi
1491  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1492   test_exec_prefix=$test_prefix
1493  else
1494   test_exec_prefix=$exec_prefix
1495  fi
1496  case ${TARGET_SYSTEM_ROOT} in
1497  "${test_prefix}"|"${test_prefix}/"*|\
1498  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1499  '${prefix}'|'${prefix}/'*|\
1500  '${exec_prefix}'|'${exec_prefix}/'*)
1501    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1502    TARGET_SYSTEM_ROOT_DEFINE="$t"
1503    ;;
1504  esac
1505 ], [
1506  TARGET_SYSTEM_ROOT=
1507  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1508 ])
1509 AC_SUBST(TARGET_SYSTEM_ROOT)
1510 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1511
1512 system_gdbinit=
1513 AC_ARG_WITH(system-gdbinit,
1514 [  --with-system-gdbinit=file       Automatically load a system-wide gdbinit file],
1515 [system_gdbinit=${withval}])
1516
1517 AC_DEFINE_DIR(SYSTEM_GDBINIT, system_gdbinit,
1518               [System-wide gdbinit file.])
1519
1520 if test "x$prefix" = xNONE; then
1521   test_prefix=$ac_default_prefix
1522 else
1523   test_prefix=$prefix
1524 fi
1525 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1526   test_exec_prefix=$test_prefix
1527 else
1528   test_exec_prefix=$exec_prefix
1529 fi
1530 case ${system_gdbinit} in
1531  "${test_prefix}"|"${test_prefix}/"*|\
1532  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1533  '${prefix}'|'${prefix}/'*|\
1534  '${exec_prefix}'|'${exec_prefix}/'*)
1535   AC_DEFINE(SYSTEM_GDBINIT_RELOCATABLE, 1,
1536             [Define if the system-wide gdbinit file should be relocated when GDB is moved.])
1537    ;;
1538 esac
1539
1540 AC_ARG_ENABLE(werror,
1541   [  --enable-werror    treat compile warnings as errors],
1542   [case "${enableval}" in
1543      yes | y) ERROR_ON_WARNING="yes" ;;
1544      no | n)  ERROR_ON_WARNING="no" ;;
1545      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1546    esac])
1547
1548 # Enable -Werror by default when using gcc
1549 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1550     ERROR_ON_WARNING=yes
1551 fi
1552
1553 WERROR_CFLAGS=""
1554 if test "${ERROR_ON_WARNING}" = yes ; then
1555     WERROR_CFLAGS="-Werror"
1556 fi
1557
1558 # The entries after -Wno-pointer-sign are disabled warnings which may
1559 # be enabled in the future, which can not currently be used to build
1560 # GDB.
1561 # NOTE: If you change this list, remember to update
1562 # gdb/doc/gdbint.texinfo.
1563 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1564 -Wformat-nonliteral -Wno-pointer-sign \
1565 -Wno-unused -Wno-switch -Wno-char-subscripts"
1566
1567 # Enable -Wno-format by default when using gcc on mingw since many
1568 # GCC versions complain about %I64.
1569 case "${host}" in
1570   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1571 esac
1572
1573 AC_ARG_ENABLE(build-warnings,
1574 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1575 [case "${enableval}" in
1576   yes)  ;;
1577   no)   build_warnings="-w";;
1578   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1579         build_warnings="${build_warnings} ${t}";;
1580   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1581         build_warnings="${t} ${build_warnings}";;
1582   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1583 esac
1584 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1585   echo "Setting compiler warning flags = $build_warnings" 6>&1
1586 fi])dnl
1587 AC_ARG_ENABLE(gdb-build-warnings,
1588 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1589 [case "${enableval}" in
1590   yes)  ;;
1591   no)   build_warnings="-w";;
1592   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1593         build_warnings="${build_warnings} ${t}";;
1594   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1595         build_warnings="${t} ${build_warnings}";;
1596   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1597 esac
1598 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1599   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1600 fi])dnl
1601 WARN_CFLAGS=""
1602 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1603 then
1604     AC_MSG_CHECKING(compiler warning flags)
1605     # Separate out the -Werror flag as some files just cannot be
1606     # compiled with it enabled.
1607     for w in ${build_warnings}; do
1608         case $w in
1609         -Werr*) WERROR_CFLAGS=-Werror ;;
1610         *) # Check that GCC accepts it
1611             saved_CFLAGS="$CFLAGS"
1612             CFLAGS="$CFLAGS $w"
1613             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1614             CFLAGS="$saved_CFLAGS"
1615         esac
1616     done
1617     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1618 fi
1619 AC_SUBST(WARN_CFLAGS)
1620 AC_SUBST(WERROR_CFLAGS)
1621
1622 # In the Cygwin environment, we need some additional flags.
1623 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1624 [AC_EGREP_CPP(lose, [
1625 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1626 lose
1627 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1628
1629
1630 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1631 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1632 case ${host} in
1633   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1634   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1635   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1636 esac
1637 AC_SUBST(SER_HARDWIRE)
1638
1639 # libreadline needs libuser32.a in a cygwin environment
1640 WIN32LIBS=
1641 if test x$gdb_cv_os_cygwin = xyes; then
1642     WIN32LIBS="-luser32"
1643     case "${target}" in
1644         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1645         ;;
1646     esac
1647 fi
1648
1649 # The ser-tcp.c module requires sockets.
1650 case ${host} in
1651   *mingw32*)
1652     AC_DEFINE(USE_WIN32API, 1,
1653               [Define if we should use the Windows API, instead of the
1654                POSIX API.  On Windows, we use the Windows API when
1655                building for MinGW, but the POSIX API when building
1656                for Cygwin.])
1657     WIN32LIBS="$WIN32LIBS -lws2_32"
1658     ;;
1659 esac
1660 AC_SUBST(WIN32LIBS)
1661
1662 # Add ELF support to GDB, but only if BFD includes ELF support.
1663 OLD_CFLAGS=$CFLAGS
1664 OLD_LDFLAGS=$LDFLAGS
1665 OLD_LIBS=$LIBS
1666 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1667 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1668 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1669 LIBS="-lbfd -liberty $intl $LIBS"
1670 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1671 [AC_TRY_LINK(
1672 [#include <stdlib.h>
1673 #include "bfd.h"
1674 #include "elf-bfd.h"
1675 ],
1676 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1677 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1678 if test $gdb_cv_var_elf = yes; then
1679   CONFIG_OBS="$CONFIG_OBS elfread.o"
1680   AC_DEFINE(HAVE_ELF, 1,
1681             [Define if ELF support should be included.])
1682 fi
1683 CFLAGS=$OLD_CFLAGS
1684 LDFLAGS=$OLD_LDFLAGS
1685 LIBS=$OLD_LIBS
1686
1687 # Add any host-specific objects to GDB.
1688 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1689
1690 LIBGUI="../libgui/src/libgui.a"
1691 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1692 AC_SUBST(LIBGUI)
1693 AC_SUBST(GUI_CFLAGS_X)
1694
1695 WIN32LDAPP=
1696 AC_SUBST(WIN32LIBS)
1697 AC_SUBST(WIN32LDAPP)
1698
1699 case "${host}" in
1700 *-*-cygwin* | *-*-mingw* )
1701     configdir="win"
1702     ;;
1703 *)
1704     configdir="unix"
1705     ;;
1706 esac
1707
1708 GDBTKLIBS=
1709 if test "${enable_gdbtk}" = "yes"; then
1710
1711     # Gdbtk must have an absolute path to srcdir in order to run
1712     # properly when not installed.
1713     here=`pwd`
1714     cd ${srcdir}
1715     GDBTK_SRC_DIR=`pwd`
1716     cd $here
1717
1718     SC_PATH_TCLCONFIG
1719
1720     # If $no_tk is nonempty, then we can't do Tk, and there is no
1721     # point to doing Tcl.
1722     SC_PATH_TKCONFIG
1723
1724     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1725         SC_LOAD_TCLCONFIG
1726
1727         # Check for in-tree tcl
1728         here=`pwd`
1729         cd ${srcdir}/..
1730         topdir=`pwd`
1731         cd ${here}
1732
1733         intree="no"
1734         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1735           intree="yes"
1736         fi
1737
1738         # Find Tcl private headers
1739         if test x"${intree}" = xno; then
1740           CY_AC_TCL_PRIVATE_HEADERS
1741           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1742           TCL_LIBRARY="${TCL_LIB_SPEC}"
1743           TCL_DEPS=""
1744         else
1745           # If building tcl in the same src tree, private headers
1746           # are not needed, but we need to be sure to use the right
1747           # headers library
1748           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1749           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1750           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1751         fi
1752         AC_SUBST(TCL_INCLUDE)
1753         AC_SUBST(TCL_LIBRARY)
1754         AC_SUBST(TCL_DEPS)
1755
1756         SC_LOAD_TKCONFIG
1757
1758         # Check for in-tree Tk
1759         intree="no"
1760         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1761           intree="yes"
1762         fi
1763
1764         # Find Tk private headers
1765         if test x"${intree}" = xno; then
1766           CY_AC_TK_PRIVATE_HEADERS
1767           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1768           TK_LIBRARY=${TK_LIB_SPEC}
1769           TK_DEPS=""
1770         else
1771           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1772           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1773           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1774         fi
1775         AC_SUBST(TK_INCLUDE)
1776         AC_SUBST(TK_LIBRARY)
1777         AC_SUBST(TK_DEPS)
1778         AC_SUBST(TK_XINCLUDES)
1779
1780         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1781
1782         # Include some libraries that Tcl and Tk want.
1783         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1784         # Yes, the ordering seems wrong here.  But it isn't.
1785         # TK_LIBS is the list of libraries that need to be linked
1786         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1787         # were in LIBS then any link tests after this point would
1788         # try to include things like `$(LIBGUI)', which wouldn't work.
1789         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1790
1791         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1792         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1793         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1794         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1795         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1796         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1797         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1798
1799         if test x$gdb_cv_os_cygwin = xyes; then
1800           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1801           WIN32LDAPP="-Wl,--subsystem,console"
1802           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1803         fi
1804
1805         AC_CONFIG_SUBDIRS(gdbtk)
1806     fi
1807 fi
1808
1809 AC_SUBST(X_CFLAGS)
1810 AC_SUBST(X_LDFLAGS)
1811 AC_SUBST(X_LIBS)
1812 AC_SUBST(GDBTKLIBS)
1813 AC_SUBST(GDBTK_CFLAGS)
1814 AC_SUBST(GDBTK_SRC_DIR)
1815
1816 AC_PATH_X
1817
1818 # Unlike the sim directory, whether a simulator is linked is controlled by
1819 # presence of a gdb_sim definition in the target configure.tgt entry.
1820 # This code just checks for a few cases where we'd like to ignore those
1821 # definitions, even when they're present in the '.mt' file.  These cases
1822 # are when --disable-sim is specified, or if the simulator directory is
1823 # not part of the source tree.
1824 #
1825 AC_ARG_ENABLE(sim,
1826 [  --enable-sim            Link gdb with simulator],
1827 [echo "enable_sim = $enable_sim";
1828  echo "enableval = ${enableval}";
1829  case "${enableval}" in
1830   yes) ignore_sim=false ;;
1831   no)  ignore_sim=true ;;
1832   *)   ignore_sim=false ;;
1833  esac],
1834 [ignore_sim=false])
1835
1836 if test ! -d "${srcdir}/../sim"; then
1837   ignore_sim=true
1838 fi
1839
1840 SIM=
1841 SIM_OBS=
1842 if test "${ignore_sim}" = "false"; then
1843   if test x"${gdb_sim}" != x ; then
1844     SIM="${gdb_sim}"
1845     SIM_OBS="remote-sim.o"
1846     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1847   fi
1848 fi
1849 AC_SUBST(SIM)
1850 AC_SUBST(SIM_OBS)
1851
1852 AC_SUBST(ENABLE_CFLAGS)
1853 AC_SUBST(PROFILE_CFLAGS)
1854
1855 AC_SUBST(CONFIG_OBS)
1856 AC_SUBST(CONFIG_DEPS)
1857 AC_SUBST(CONFIG_SRCS)
1858 AC_SUBST(CONFIG_ALL)
1859 AC_SUBST(CONFIG_CLEAN)
1860 AC_SUBST(CONFIG_INSTALL)
1861 AC_SUBST(CONFIG_UNINSTALL)
1862
1863 # List of host floatformats.
1864 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1865 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1866 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1867
1868 # target_subdir is used by the testsuite to find the target libraries.
1869 target_subdir=
1870 if test "${host}" != "${target}"; then
1871     target_subdir="${target_alias}/"
1872 fi
1873 AC_SUBST(target_subdir)
1874
1875 frags=
1876 if test "${gdb_native}" = "yes"; then
1877   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1878   if test ! -f ${host_makefile_frag}; then
1879     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1880   fi
1881   frags="$frags $host_makefile_frag"
1882 else
1883   host_makefile_frag=/dev/null
1884 fi
1885
1886 AC_SUBST_FILE(host_makefile_frag)
1887 AC_SUBST(frags)
1888
1889 changequote(,)dnl
1890 if test "${gdb_native}" = "yes"; then
1891 # We pick this up from the host configuration file (.mh) because we
1892 # do not have a native configuration Makefile fragment.
1893 nativefile=`sed -n '
1894 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1895 ' ${host_makefile_frag}`
1896 fi
1897 changequote([,])
1898
1899 if test x"${gdb_osabi}" != x ; then
1900     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1901                        [Define to the default OS ABI for this configuration.])
1902 fi
1903
1904 # Enable multi-ice-gdb-server.
1905 AC_ARG_ENABLE(multi-ice,
1906 [  --enable-multi-ice      build the multi-ice-gdb-server],
1907   [case $enableval in
1908     yes | no)
1909       ;;
1910     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1911   esac])
1912 if test "x$enable_multi_ice" = xyes; then
1913    AC_CONFIG_SUBDIRS(multi-ice)
1914 fi
1915
1916 # We only build gdbserver automatically in a native configuration.
1917 if test "$gdb_native" = "yes"; then
1918   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1919   if test "x$build_gdbserver" = xyes; then
1920     AC_MSG_RESULT(yes)
1921     AC_CONFIG_SUBDIRS(gdbserver)
1922   else
1923     AC_MSG_RESULT(no)
1924   fi
1925 fi
1926
1927 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1928 # to an empty version.
1929
1930 files=
1931 links=
1932
1933 rm -f nm.h
1934 nm_h=""
1935 if test "${nativefile}" != ""; then
1936     nm_h=nm.h
1937     case "${nativefile}" in
1938       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1939       * ) GDB_NM_FILE="${nativefile}"
1940     esac
1941     files="${files} ${GDB_NM_FILE}"
1942     links="${links} nm.h"
1943     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1944 fi
1945 AC_SUBST(nm_h)
1946
1947 AC_LINK_FILES($files, $links)
1948
1949 dnl Check for exe extension set on certain hosts (e.g. Win32)
1950 AC_EXEEXT
1951
1952 dnl  Detect the character set used by this host.
1953 dnl  At the moment, we just assume it's UTF-8.
1954 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
1955           [Define to be a string naming the default host character set.])
1956
1957 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1958 [
1959 dnl Autoconf doesn't provide a mechanism for modifying definitions
1960 dnl provided by makefile fragments.
1961 dnl
1962
1963 changequote(,)dnl
1964 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1965 mv -f Makefile.tmp Makefile
1966 changequote([,])dnl
1967
1968
1969 case x$CONFIG_HEADERS in
1970 xconfig.h:config.in)
1971 echo > stamp-h ;;
1972 esac
1973 ],
1974 [
1975 gdb_host_cpu=$gdb_host_cpu
1976 nativefile=$nativefile
1977 ])
1978
1979 exit 0