gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 gl_EARLY
  33 AM_PROG_CC_STDC
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37
  38 # Dependency checking.
  39 ZW_CREATE_DEPDIR
  40 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  41
  42 # Check for the 'make' the user wants to use.
  43 AC_CHECK_PROGS(MAKE, make)
  44 MAKE_IS_GNU=
  45 case "`$MAKE --version 2>&1 | sed 1q`" in
  46   *GNU*)
  47     MAKE_IS_GNU=yes
  48     ;;
  49 esac
  50 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  51 AC_PROG_MAKE_SET
  52
  53 dnl List of object files and targets accumulated by configure.
  54
  55 CONFIG_OBS=
  56 CONFIG_DEPS=
  57 CONFIG_SRCS=
  58 ENABLE_CFLAGS=
  59
  60 CONFIG_ALL=
  61 CONFIG_CLEAN=
  62 CONFIG_INSTALL=
  63 CONFIG_UNINSTALL=
  64
  65 dnl Set up for gettext.
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67
  68 localedir='${datadir}/locale'
  69 AC_SUBST(localedir)
  70
  71 if test x"$USE_NLS" = xyes; then
  72    CONFIG_ALL="$CONFIG_ALL all-po"
  73    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  74    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  75    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  76 fi
  77
  78 gl_INIT
  79
  80 # For Makefile dependencies.
  81 GNULIB_STDINT_H=
  82 if test x"$STDINT_H" != x; then
  83   GNULIB_STDINT_H=gnulib/$STDINT_H
  84 fi
  85 AC_SUBST(GNULIB_STDINT_H)
  86
  87 PACKAGE=gdb
  88 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  89 AC_SUBST(PACKAGE)
  90
  91 # GDB does not use automake, but gnulib does.  This line lets us
  92 # generate its Makefile.in.
  93 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  94
  95 debugdir=${libdir}/debug
  96
  97 AC_ARG_WITH(separate-debug-dir,
  98 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  99 [debugdir="${withval}"])
 100
 101 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 102               [Global directory for separate debug files. ])
 103 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 104
 105 if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
 106   if test "x$prefix" = xNONE; then
 107     test_prefix=/usr/local
 108   else
 109     test_prefix=$prefix
 110   fi
 111 else
 112   test_prefix=$exec_prefix
 113 fi
 114 case ${debugdir} in
 115 "${test_prefix}"|"${test_prefix}/"*|\
 116 '${exec_prefix}'|'${exec_prefix}/'*)
 117   AC_DEFINE(DEBUGDIR_RELOCATABLE, 1, [Define if the debug directory should be relocated when GDB is moved.])
 118   ;;
 119 esac
 120
 121 AC_CONFIG_SUBDIRS(doc testsuite)
 122
 123 # Check whether to support alternative target configurations
 124 AC_ARG_ENABLE(targets,
 125 [  --enable-targets        alternative target configurations],
 126 [case "${enableval}" in
 127   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 128             ;;
 129   no)       enable_targets= ;;
 130   *)        enable_targets=$enableval ;;
 131 esac])
 132
 133 # Check whether to enable 64-bit support on 32-bit hosts
 134 AC_ARG_ENABLE(64-bit-bfd,
 135 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
 136 [case "${enableval}" in
 137   yes)  want64=true  ;;
 138   no)   want64=false ;;
 139   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 140 esac],[want64=false])dnl
 141
 142 # Provide defaults for some variables set by the per-host and per-target
 143 # configuration.
 144 gdb_host_obs=posix-hdep.o
 145
 146 if test "${target}" = "${host}"; then
 147   gdb_native=yes
 148 else
 149   gdb_native=no
 150 fi
 151
 152 . $srcdir/configure.host
 153
 154 # Accumulate some settings from configure.tgt over all enabled targets
 155
 156 TARGET_OBS=
 157 all_targets=
 158
 159 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 160 do
 161   if test "$targ_alias" = "all"; then
 162     all_targets=true
 163   else
 164     # Canonicalize the secondary target names.
 165     result=`$ac_config_sub $targ_alias 2>/dev/null`
 166     if test -n "$result"; then
 167         targ=$result
 168     else
 169         targ=$targ_alias
 170     fi
 171
 172     . ${srcdir}/configure.tgt
 173
 174     # Target-specific object files
 175     for i in ${gdb_target_obs}; do
 176         case " $TARGET_OBS " in
 177         *" ${i} "*) ;;
 178         *)
 179           TARGET_OBS="$TARGET_OBS ${i}"
 180           ;;
 181         esac
 182     done
 183
 184     # Check whether this target needs 64-bit CORE_ADDR
 185     if test x${want64} = xfalse; then
 186       . ${srcdir}/../bfd/config.bfd
 187     fi
 188   fi
 189 done
 190
 191 if test x${all_targets} = xtrue; then
 192
 193   # We want all 64-bit targets if we either:
 194   #  - run on a 64-bit host  or
 195   #  - already require 64-bit support for some other target  or
 196   #  - the --enable-64-bit-bfd option was supplied
 197   # Otherwise we only support all 32-bit targets.
 198   #
 199   # NOTE: This test must be in sync with the corresponding
 200   #       tests in BFD!
 201
 202   if test x${want64} = xfalse; then
 203     AC_CHECK_SIZEOF(long)
 204     if test "x${ac_cv_sizeof_long}" = "x8"; then
 205       want64=true
 206     fi
 207   fi
 208   if test x${want64} = xtrue; then
 209     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 210   else
 211     TARGET_OBS='$(ALL_TARGET_OBS)'
 212   fi
 213 fi
 214
 215 AC_SUBST(TARGET_OBS)
 216
 217 # For other settings, only the main target counts.
 218 gdb_sim=
 219 gdb_osabi=
 220 build_gdbserver=
 221 targ=$target; . ${srcdir}/configure.tgt
 222
 223 # Fetch the default architecture and default target vector from BFD.
 224 targ=$target; . $srcdir/../bfd/config.bfd
 225
 226 # We only want the first architecture, so strip off the others if
 227 # there is more than one.
 228 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 229
 230 if test "x$targ_archs" != x; then
 231   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 232     [Define to BFD's default architecture. ])
 233 fi
 234 if test "x$targ_defvec" != x; then
 235   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 236     [Define to BFD's default target vector. ])
 237 fi
 238
 239 # The CLI cannot be disabled yet, but may be in the future.
 240
 241 # Enable CLI.
 242 AC_ARG_ENABLE(gdbcli,
 243 [  --disable-gdbcli        disable command-line interface (CLI)],
 244   [case $enableval in
 245     yes)
 246       ;;
 247     no)
 248       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 249     *)
 250       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 251   esac],
 252   [enable_gdbcli=yes])
 253 if test x"$enable_gdbcli" = xyes; then
 254   if test -d $srcdir/cli; then
 255     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 256     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 257     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 258     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 259   fi
 260 fi
 261
 262 # Enable MI.
 263 AC_ARG_ENABLE(gdbmi,
 264 [  --disable-gdbmi         disable machine-interface (MI)],
 265   [case $enableval in
 266     yes | no)
 267       ;;
 268     *)
 269       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 270   esac],
 271   [enable_gdbmi=yes])
 272 if test x"$enable_gdbmi" = xyes; then
 273   if test -d $srcdir/mi; then
 274     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 275     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 276     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 277     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 278   fi
 279 fi
 280
 281 # Enable TUI.
 282 AC_ARG_ENABLE(tui,
 283 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 284   [case $enableval in
 285     yes | no | auto)
 286       ;;
 287     *)
 288       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 289   esac],enable_tui=auto)
 290
 291 # Enable gdbtk.
 292 AC_ARG_ENABLE(gdbtk,
 293 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 294   [case $enableval in
 295     yes | no)
 296       ;;
 297     *)
 298       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 299   esac],
 300   [if test -d $srcdir/gdbtk; then
 301     enable_gdbtk=yes
 302   else
 303     enable_gdbtk=no
 304   fi])
 305 # We unconditionally disable gdbtk tests on selected platforms.
 306 case $host_os in
 307   go32* | windows*)
 308     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 309     enable_gdbtk=no ;;
 310 esac
 311
 312 # Libunwind support.
 313 AC_ARG_WITH(libunwind,
 314 [  --with-libunwind            Use libunwind frame unwinding support],
 315 [case "${withval}" in
 316   yes)  enable_libunwind=yes ;;
 317   no)   enable_libunwind=no ;;
 318   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 319 esac],[
 320   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 321   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 322     enable_libunwind=yes;
 323   fi
 324 ])
 325
 326 if test x"$enable_libunwind" = xyes; then
 327   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 328   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 329   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 330   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 331   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 332 fi
 333
 334 # Profiling support.
 335 AC_ARG_ENABLE(profiling,
 336 [  --enable-profiling      enable profiling of GDB],
 337   [case $enableval in
 338     yes | no)
 339       ;;
 340     *)
 341       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 342   esac],
 343  [enable_profiling=no])
 344
 345 AC_CHECK_FUNCS(monstartup _mcleanup)
 346 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 347 [AC_TRY_LINK(
 348 [#include <stdlib.h>
 349 extern char _etext;
 350 ],
 351 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 352 if test $ac_cv_var__etext = yes; then
 353   AC_DEFINE(HAVE__ETEXT, 1,
 354             [Define to 1 if your system has the _etext variable. ])
 355 fi
 356 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 357 [AC_TRY_LINK(
 358 [#include <stdlib.h>
 359 extern char etext;
 360 ],
 361 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 362 if test $ac_cv_var_etext = yes; then
 363   AC_DEFINE(HAVE_ETEXT, 1,
 364             [Define to 1 if your system has the etext variable. ])
 365 fi
 366 if test "$enable_profiling" = yes ; then
 367   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 368     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 369   fi
 370   PROFILE_CFLAGS=-pg
 371   OLD_CFLAGS="$CFLAGS"
 372   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 373
 374   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 375     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 376      ac_cv_cc_supports_pg=no)])
 377
 378   if test $ac_cv_cc_supports_pg = no; then
 379     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 380   fi
 381
 382   CFLAGS="$OLD_CFLAGS"
 383 fi
 384
 385 ACX_PKGVERSION([GDB])
 386 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 387 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 388 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 389
 390 # --------------------- #
 391 # Checks for programs.  #
 392 # --------------------- #
 393
 394 AC_PROG_AWK
 395 AC_PROG_INSTALL
 396 AC_PROG_LN_S
 397 AC_PROG_RANLIB
 398 AC_PROG_YACC
 399
 400 AC_CHECK_TOOL(AR, ar)
 401 AC_CHECK_TOOL(DLLTOOL, dlltool)
 402 AC_CHECK_TOOL(WINDRES, windres)
 403
 404 # Needed for GNU/Hurd.
 405 AC_CHECK_TOOL(MIG, mig)
 406
 407 # ---------------------- #
 408 # Checks for libraries.  #
 409 # ---------------------- #
 410
 411 # We might need to link with -lm; most simulators need it.
 412 AC_CHECK_LIB(m, main)
 413
 414 # We need to link with -lw to get `wctype' on Solaris before Solaris
 415 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 416 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 417 # is known to have this problem).  Therefore we avoid libw if we can.
 418 AC_CHECK_FUNC(wctype, [],
 419   [AC_CHECK_LIB(w, wctype)])
 420
 421 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 422 AC_SEARCH_LIBS(gethostbyname, nsl)
 423
 424 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 425 AC_SEARCH_LIBS(socketpair, socket)
 426
 427 # Link in zlib if we can.  This allows us to read compressed debug sections.
 428 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 429
 430 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 431 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 432
 433 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 434 # There is a very specific comment in /usr/include/curses.h explaining that
 435 # termcap routines built into libcurses must not be used.
 436 #
 437 # The symptoms we observed so far is GDB unexpectedly changing
 438 # the terminal settings when tgetent is called - this is particularly
 439 # visible as the output is missing carriage returns, and so rapidly
 440 # becomes very hard to read.
 441 #
 442 # The readline configure script has already decided that libtermcap
 443 # was enough for its purposes, and so decided to build readline using
 444 # libtermcap.  Since the TUI mode requires curses, building GDB with
 445 # TUI enabled results in both libraries to be used at the same time,
 446 # which is not allowed.  This basically means that GDB with TUI is
 447 # broken on alpha-osf.
 448
 449 case $host_os in
 450   alpha*-*-osf* )
 451     if "$enable_tui" = "yes"; then
 452       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 453     fi
 454     if "$enable_tui" = "auto"; then
 455       enable_tui=no
 456     fi
 457     ;;
 458 esac
 459
 460 # Check whether we should enable the TUI, but only do so if we really
 461 # can.
 462 if test x"$enable_tui" != xno; then
 463   if test -d $srcdir/tui; then
 464     # For the TUI, we need enhanced curses functionality.
 465     #
 466     # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 467     # curses library because the latter might not provide all the
 468     # functionality we need.  However, this leads to problems on systems
 469     # where the linker searches /usr/local/lib, but the compiler doesn't
 470     # search /usr/local/include, if ncurses is installed in /usr/local.  A
 471     # default installation of ncurses on alpha*-dec-osf* will lead to such
 472     # a situation.
 473     AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 474
 475     if test "$ac_cv_search_waddstr" != no; then
 476       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 477       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 478       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 479       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 480       CONFIG_ALL="${CONFIG_ALL} all-tui"
 481       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 482       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 483       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 484     else
 485       if test x"$enable_tui" = xyes; then
 486         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 487       else
 488         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 489       fi
 490     fi
 491   fi
 492 fi
 493
 494 # Since GDB uses Readline, we need termcap functionality.  In many
 495 # cases this will be provided by the curses library, but some systems
 496 # have a seperate termcap library, or no curses library at all.
 497
 498 case $host_os in
 499   cygwin*)
 500     if test -d $srcdir/libtermcap; then
 501       LIBS="../libtermcap/libtermcap.a $LIBS"
 502       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 503     fi ;;
 504   go32* | *djgpp*)
 505     ac_cv_search_tgetent="none required"
 506     ;;
 507   *mingw32*)
 508     ac_cv_search_tgetent="none required"
 509     CONFIG_OBS="$CONFIG_OBS win32-termcap.o"
 510     ;;
 511 esac
 512
 513 # These are the libraries checked by Readline.
 514 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 515
 516 if test "$ac_cv_search_tgetent" = no; then
 517   AC_MSG_ERROR([no termcap library found])
 518 fi
 519
 520 AC_ARG_WITH([system-readline],
 521   [AS_HELP_STRING([--with-system-readline],
 522                   [use installed readline library])])
 523
 524 if test "$with_system_readline" = yes; then
 525   READLINE=-lreadline
 526   READLINE_DEPS=
 527   READLINE_CFLAGS=
 528 else
 529   READLINE='$(READLINE_DIR)/libreadline.a'
 530   READLINE_DEPS='$(READLINE)'
 531   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 532 fi
 533 AC_SUBST(READLINE)
 534 AC_SUBST(READLINE_DEPS)
 535 AC_SUBST(READLINE_CFLAGS)
 536
 537 AC_ARG_WITH(expat,
 538   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 539   [], [with_expat=auto])
 540 AC_MSG_CHECKING([whether to use expat])
 541 AC_MSG_RESULT([$with_expat])
 542
 543 if test "${with_expat}" = no; then
 544   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 545   HAVE_LIBEXPAT=no
 546 else
 547   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 548                         [XML_Parser p = XML_ParserCreate (0);])
 549   if test "$HAVE_LIBEXPAT" != yes; then
 550     if test "$with_expat" = yes; then
 551       AC_MSG_ERROR([expat is missing or unusable])
 552     else
 553       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 554     fi
 555   else
 556     save_LIBS=$LIBS
 557     LIBS="$LIBS $LIBEXPAT"
 558     AC_CHECK_FUNCS(XML_StopParser)
 559     LIBS=$save_LIBS
 560   fi
 561 fi
 562
 563 dnl Utility to simplify finding libpython.
 564 AC_DEFUN([AC_TRY_LIBPYTHON],
 565 [
 566   version=$1
 567   define([have_libpython_var],$2)
 568   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 569                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 570   [HAVE_LIB]VERSION=no
 571   AC_MSG_CHECKING([for ${version}])
 572   save_LIBS=$LIBS
 573   LIBS="$LIBS -l${version}"
 574   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 575                                  [[Py_Initialize ();]]),
 576                  [[HAVE_LIB]VERSION=yes
 577                   have_libpython_var=yes],
 578                  [LIBS=$save_LIBS])
 579   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 580 ])
 581
 582 AC_ARG_WITH(python,
 583   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 584   [], [with_python=auto])
 585 AC_MSG_CHECKING([whether to use python])
 586 AC_MSG_RESULT([$with_python])
 587
 588 if test "${with_python}" = no; then
 589   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 590   have_libpython=no
 591 else
 592   case "${with_python}" in
 593   yes | auto)
 594     # Leave as empty, use defaults.
 595     python_includes=
 596     python_libs=
 597     ;;
 598   /*)
 599     python_includes="-I${with_python}/include"
 600     python_libs="-L${with_python}/lib"
 601     ;;
 602   *)
 603     AC_ERROR(invalid value for --with-python)
 604     ;;
 605   esac
 606
 607   save_CPPFLAGS=$CPPFLAGS
 608   CPPFLAGS="$CPPFLAGS ${python_includes}"
 609   save_LIBS=$LIBS
 610   LIBS="$LIBS ${python_libs}"
 611   have_libpython=no
 612   if test "${have_libpython}" = no; then
 613     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 614     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 615       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 616     fi
 617   fi
 618   if test ${have_libpython} = no; then
 619     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 620     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 621       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 622     fi
 623   fi
 624   if test ${have_libpython} = no; then
 625     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 626     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 627       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 628     fi
 629   fi
 630   if test ${have_libpython} = no; then
 631     case "${with_python}" in
 632     yes)
 633       AC_MSG_ERROR([python is missing or unusable])
 634       ;;
 635     auto)
 636       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 637       ;;
 638     *)
 639       AC_MSG_ERROR([no usable python found at ${with_python}])
 640       ;;
 641     esac
 642     CPPFLAGS=$save_CPPFLAGS
 643     LIBS=$save_LIBS
 644   fi
 645 fi
 646
 647 if test "${have_libpython}" = yes; then
 648   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 649   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 650   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 651   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 652   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 653
 654   # Flags needed to compile Python code (taken from python-config --cflags).
 655   # We cannot call python-config directly because it will output whatever was
 656   # used when compiling the Python interpreter itself, including flags which
 657   # would make the python-related objects be compiled differently from the
 658   # rest of GDB (e.g., -O2 and -fPIC).
 659   if test "${GCC}" = yes; then
 660     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 661   fi
 662
 663   if test "x${tentative_python_cflags}" != x; then
 664     AC_MSG_CHECKING(compiler flags for python code)
 665     for flag in ${tentative_python_cflags}; do
 666       # Check that the compiler accepts it
 667       saved_CFLAGS="$CFLAGS"
 668       CFLAGS="$CFLAGS $flag"
 669       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 670       CFLAGS="$saved_CFLAGS"
 671     done
 672     AC_MSG_RESULT(${PYTHON_CFLAGS})
 673   fi
 674 else
 675   # Even if Python support is not compiled in, we need to have these files
 676   # included in order to recognize the GDB command "python".
 677   CONFIG_OBS="$CONFIG_OBS python.o python-value.o"
 678   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/python-value.c"
 679 fi
 680 AC_SUBST(PYTHON_CFLAGS)
 681
 682 # ------------------------- #
 683 # Checks for header files.  #
 684 # ------------------------- #
 685
 686 AC_HEADER_DIRENT
 687 AC_HEADER_STAT
 688 AC_HEADER_STDC
 689 # elf_hp.h is for HP/UX 64-bit shared library support.
 690 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 691 # unconditionally, so what's the point in checking these?
 692 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 693                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 694                   stdlib.h string.h memory.h strings.h sys/fault.h \
 695                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 696                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 697                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 698                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 699                   sgtty.h unistd.h elf_hp.h ctype.h time.h])
 700 AC_CHECK_HEADERS(link.h, [], [],
 701 [#if HAVE_SYS_TYPES_H
 702 # include <sys/types.h>
 703 #endif
 704 #if HAVE_NLIST_H
 705 # include <nlist.h>
 706 #endif
 707 ])
 708 AC_CHECK_HEADERS(sys/proc.h, [], [],
 709 [#if HAVE_SYS_PARAM_H
 710 # include <sys/param.h>
 711 #endif
 712 ])
 713 AC_CHECK_HEADERS(sys/user.h, [], [],
 714 [#if HAVE_SYS_PARAM_H
 715 # include <sys/param.h>
 716 #endif
 717 ])
 718
 719 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 720 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 721 # think that we don't have <curses.h> if we're using GCC.
 722 case $host_os in
 723   solaris2.[[789]])
 724     if test "$GCC" = yes; then
 725       AC_DEFINE(_MSE_INT_H, 1,
 726         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 727    Solaris 2.[789] when using GCC. ])
 728     fi ;;
 729 esac
 730 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 731 AC_CHECK_HEADERS(term.h, [], [],
 732 [#if HAVE_CURSES_H
 733 # include <curses.h>
 734 #endif
 735 ])
 736
 737 # ------------------------- #
 738 # Checks for declarations.  #
 739 # ------------------------- #
 740
 741 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 742                 snprintf, vsnprintf])
 743
 744 # ----------------------- #
 745 # Checks for structures.  #
 746 # ----------------------- #
 747
 748 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 749
 750 # ------------------ #
 751 # Checks for types.  #
 752 # ------------------ #
 753
 754 AC_TYPE_SIGNAL
 755 AC_CHECK_TYPES(socklen_t, [], [],
 756 [#include <sys/types.h>
 757 #include <sys/socket.h>
 758 ])
 759
 760 # ------------------------------------- #
 761 # Checks for compiler characteristics.  #
 762 # ------------------------------------- #
 763
 764 AC_C_CONST
 765 AC_C_INLINE
 766 AC_C_BIGENDIAN
 767
 768 # ------------------------------ #
 769 # Checks for library functions.  #
 770 # ------------------------------ #
 771
 772 AC_FUNC_ALLOCA
 773 AC_FUNC_MMAP
 774 AC_FUNC_VFORK
 775 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 776                 getgid poll pread64 sbrk setpgid setpgrp setsid \
 777                 sigaction sigprocmask sigsetmask socketpair syscall \
 778                 ttrace wborder])
 779
 780 # Check the return and argument types of ptrace.  No canned test for
 781 # this, so roll our own.
 782 gdb_ptrace_headers='
 783 #if HAVE_SYS_TYPES_H
 784 # include <sys/types.h>
 785 #endif
 786 #if HAVE_SYS_PTRACE_H
 787 # include <sys/ptrace.h>
 788 #endif
 789 #if HAVE_UNISTD_H
 790 # include <unistd.h>
 791 #endif
 792 '
 793 # There is no point in checking if we don't have a prototype.
 794 AC_CHECK_DECLS(ptrace, [], [
 795   : ${gdb_cv_func_ptrace_ret='int'}
 796   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 797 ], $gdb_ptrace_headers)
 798 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 799 # empty argument list, so check for that explicitly.
 800 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 801   AC_TRY_COMPILE($gdb_ptrace_headers,
 802     [extern long ptrace (enum __ptrace_request, ...);],
 803     gdb_cv_func_ptrace_ret='long',
 804     AC_TRY_COMPILE($gdb_ptrace_headers,
 805       [extern int ptrace ();],
 806       gdb_cv_func_ptrace_ret='int',
 807       gdb_cv_func_ptrace_ret='long')))
 808 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 809   [Define as the return type of ptrace.])
 810 # Check argument types.
 811 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 812   AC_TRY_COMPILE($gdb_ptrace_headers,
 813     [extern long ptrace (enum __ptrace_request, ...);],
 814     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 815 for gdb_arg1 in 'int' 'long'; do
 816  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 817   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 818    for gdb_arg4 in 'int' 'long'; do
 819      AC_TRY_COMPILE($gdb_ptrace_headers, [
 820 extern $gdb_cv_func_ptrace_ret
 821   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 822 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 823     break 4;])
 824     for gdb_arg5 in 'int *' 'int' 'long'; do
 825      AC_TRY_COMPILE($gdb_ptrace_headers, [
 826 extern $gdb_cv_func_ptrace_ret
 827   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 828 ], [
 829 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 830     break 5;])
 831     done
 832    done
 833   done
 834  done
 835 done
 836 # Provide a safe default value.
 837 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 838 ])])
 839 ac_save_IFS=$IFS; IFS=','
 840 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 841 IFS=$ac_save_IFS
 842 shift
 843 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 844   [Define to the type of arg 3 for ptrace.])
 845 if test -n "$[5]"; then
 846   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 847     [Define to the type of arg 5 for ptrace.])
 848 fi
 849
 850 dnl AC_FUNC_SETPGRP does not work when cross compiling
 851 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 852 if test "$cross_compiling" = no; then
 853   AC_FUNC_SETPGRP
 854 else
 855   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 856     [AC_TRY_COMPILE([
 857 #include <unistd.h>
 858 ], [
 859   if (setpgrp(1,1) == -1)
 860     exit (0);
 861   else
 862     exit (1);
 863 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 864 if test $ac_cv_func_setpgrp_void = yes; then
 865   AC_DEFINE(SETPGRP_VOID, 1)
 866 fi
 867 fi
 868
 869 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 870 # since sigsetjmp might only be defined as a macro.
 871 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 872 [AC_TRY_COMPILE([
 873 #include <setjmp.h>
 874 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 875 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 876 if test $gdb_cv_func_sigsetjmp = yes; then
 877   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 878 fi
 879
 880 # Assume we'll default to using the included libiberty regex.
 881 gdb_use_included_regex=yes
 882
 883 # However, if the system regex is GNU regex, then default to *not*
 884 # using the included regex.
 885 AC_CACHE_CHECK(
 886   [for GNU regex],
 887   [gdb_cv_have_gnu_regex],
 888   [AC_TRY_COMPILE(
 889     [#include <gnu-versions.h>],
 890     [#define REGEX_INTERFACE_VERSION 1
 891 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 892 # error "Version mismatch"
 893 #endif],
 894     gdb_cv_have_gnu_regex=yes,
 895     gdb_cv_have_gnu_regex=no)])
 896 if test $gdb_cv_have_gnu_regex = yes; then
 897   gdb_use_included_regex=no
 898 fi
 899
 900 AC_ARG_WITH(included-regex,
 901   [  --without-included-regex don't use included regex; this is the default
 902                           on systems with version 2 of the GNU C library
 903                           (use with caution on other system)],
 904   gdb_with_regex=$withval,
 905   gdb_with_regex=$gdb_use_included_regex)
 906 if test "$gdb_with_regex" = yes; then
 907   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 908     [Define to 1 if the regex included in libiberty should be used.])
 909 fi
 910
 911 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 912 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 913 [#include <sys/param.h>
 914 #include <sys/proc.h>
 915 ])
 916
 917 # See if <sys/lwp.h> defines `struct lwp`.
 918 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 919 [AC_TRY_COMPILE([#include <sys/param.h>
 920 #include <sys/lwp.h>], [struct lwp l;],
 921 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 922 if test $gdb_cv_struct_lwp = yes; then
 923   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 924             [Define to 1 if your system has struct lwp.])
 925 fi
 926
 927 # See if <machine/reg.h> degines `struct reg'.
 928 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 929 [AC_TRY_COMPILE([#include <sys/types.h>
 930 #include <machine/reg.h>], [struct reg r;],
 931 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 932 if test $gdb_cv_struct_reg = yes; then
 933   AC_DEFINE(HAVE_STRUCT_REG, 1,
 934             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 935 fi
 936
 937 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 938 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 939 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 940                  [#include <machine/reg.h>])
 941
 942 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 943 AC_MSG_CHECKING(for PTRACE_GETREGS)
 944 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 945 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 946                 [PTRACE_GETREGS;],
 947                 [gdb_cv_have_ptrace_getregs=yes],
 948                 [gdb_cv_have_ptrace_getregs=no])])
 949 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 950 if test $gdb_cv_have_ptrace_getregs = yes; then
 951   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 952   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 953 fi
 954
 955 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 956 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 957 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 958 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 959                 [PTRACE_GETFPXREGS;],
 960                 [gdb_cv_have_ptrace_getfpxregs=yes],
 961                 [gdb_cv_have_ptrace_getfpxregs=no])])
 962 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 963 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 964   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 965   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 966 fi
 967
 968 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 969 AC_MSG_CHECKING(for PT_GETDBREGS)
 970 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 971 [AC_TRY_COMPILE([#include <sys/types.h>
 972 #include <sys/ptrace.h>],
 973                 [PT_GETDBREGS;],
 974                 [gdb_cv_have_pt_getdbregs=yes],
 975                 [gdb_cv_have_pt_getdbregs=no])])
 976 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 977 if test $gdb_cv_have_pt_getdbregs = yes; then
 978   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
 979   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
 980 fi
 981
 982 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 983 AC_MSG_CHECKING(for PT_GETXMMREGS)
 984 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 985 [AC_TRY_COMPILE([#include <sys/types.h>
 986 #include <sys/ptrace.h>],
 987                 [PT_GETXMMREGS;],
 988                 [gdb_cv_have_pt_getxmmregs=yes],
 989                 [gdb_cv_have_pt_getxmmregs=no])])
 990 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 991 if test $gdb_cv_have_pt_getxmmregs = yes; then
 992   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
 993   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
 994 fi
 995
 996 # Detect which type of /proc is in use, such as for Unixware or Solaris.
 997
 998 if test "${target}" = "${host}"; then
 999   case "${host}" in
1000   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1001       AC_DEFINE(NEW_PROC_API, 1,
1002       [Define if you want to use new multi-fd /proc interface
1003        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1004       ;;
1005   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1006       AC_DEFINE(NEW_PROC_API, 1,
1007       [Define if you want to use new multi-fd /proc interface
1008        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1009       ;;
1010   mips-sgi-irix5*)
1011       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1012       AC_DEFINE([_KMEMUSER], 1,
1013       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1014        around a <sys/proc.h> problem on IRIX 5.])
1015       ;;
1016   esac
1017 fi
1018
1019 if test "$ac_cv_header_sys_procfs_h" = yes; then
1020   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1021   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1022   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1023   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1024   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1025   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1026   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1027   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1028   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1029   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1030   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1031   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1032   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1033   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1034
1035
1036   dnl Check for broken prfpregset_t type
1037
1038   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1039   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1040   dnl instead of the struct itself).  We detect this here, and work
1041   dnl around it in gdb_proc_service.h.
1042
1043   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1044     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1045     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1046       [AC_TRY_RUN([#include <sys/procfs.h>
1047        int main ()
1048        {
1049          if (sizeof (prfpregset_t) == sizeof (void *))
1050            return 1;
1051          return 0;
1052        }],
1053        gdb_cv_prfpregset_t_broken=no,
1054        gdb_cv_prfpregset_t_broken=yes,
1055        gdb_cv_prfpregset_t_broken=yes)])
1056     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1057     if test $gdb_cv_prfpregset_t_broken = yes; then
1058       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1059       [Define if the prfpregset_t type is broken.])
1060     fi
1061   fi
1062
1063   dnl Check for PIOCSET ioctl entry
1064
1065   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1066   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1067   [AC_TRY_COMPILE([#include <unistd.h>
1068 #include <sys/types.h>
1069 #include <sys/procfs.h>
1070 ], [
1071     int dummy;;
1072     dummy = ioctl(0, PIOCSET, &dummy);
1073   ],
1074   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1075   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1076   if test $gdb_cv_have_procfs_piocset = yes; then
1077     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1078     [Define if ioctl argument PIOCSET is available.])
1079   fi
1080 fi
1081
1082 dnl For native ports (host == target), check to see what kind of
1083 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1084 if test ${host} = ${target} ; then
1085   dnl Check for struct link_map with l_ members which are indicative
1086   dnl of SVR4-like shared libraries
1087
1088   AC_MSG_CHECKING(for member l_addr in struct link_map)
1089   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1090     [AC_TRY_COMPILE([#include <link.h>],
1091                     [struct link_map lm; (void) lm.l_addr;],
1092                     gdb_cv_have_struct_link_map_with_l_members=yes,
1093                     gdb_cv_have_struct_link_map_with_l_members=no)])
1094   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1095   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1096     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1097     [Define if <link.h> exists and defines struct link_map which has
1098      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1099      SVR4-like systems.)])
1100   fi
1101
1102   dnl Check for struct link_map with lm_ members which are indicative
1103   dnl of SunOS-like shared libraries
1104
1105   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1106   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1107     [AC_TRY_COMPILE([#include <sys/types.h>
1108 #include <link.h>],
1109                     [struct link_map lm; (void) lm.lm_addr;],
1110                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1111                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1112   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1113   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1114     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1115     [Define if <link.h> exists and defines struct link_map which has
1116      members with an ``lm_'' prefix.  (For SunOS.)])
1117   fi
1118
1119   dnl Check for struct so_map with som_ members which are found on
1120   dnl some *BSD systems.
1121
1122   AC_MSG_CHECKING(for member som_addr in struct so_map)
1123   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1124     [AC_TRY_COMPILE([#include <sys/types.h>
1125 #ifdef HAVE_NLIST_H
1126 #include <nlist.h>
1127 #endif
1128 #include <link.h>],
1129                     [struct so_map lm; (void) lm.som_addr;],
1130                     gdb_cv_have_struct_so_map_with_som_members=yes,
1131                     gdb_cv_have_struct_so_map_with_som_members=no)])
1132   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1133   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1134     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1135     [Define if <link.h> exists and defines a struct so_map which has
1136      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1137   fi
1138
1139   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1140   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1141
1142   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1143   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1144     [AC_TRY_COMPILE([#define _SYSCALL32
1145 #include <sys/link.h>], [struct link_map32 l;],
1146      gdb_cv_have_struct_link_map32=yes,
1147      gdb_cv_have_struct_link_map32=no)])
1148   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1149   if test $gdb_cv_have_struct_link_map32 = yes; then
1150     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1151     [Define if <sys/link.h> has struct link_map32])
1152     AC_DEFINE(_SYSCALL32, 1,
1153     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1154   fi
1155 fi
1156
1157 # Check if the compiler supports the `long long' type.
1158
1159 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1160                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1161 [[extern long long foo;]],
1162 [[switch (foo & 2) { case 0: return 1; }]])],
1163                                   gdb_cv_c_long_long=yes,
1164                                   gdb_cv_c_long_long=no)])
1165 if test $gdb_cv_c_long_long = yes; then
1166   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1167             [Define to 1 if the compiler supports long long.])
1168 fi
1169
1170 # Check if the compiler and runtime support printing long longs.
1171
1172 AC_CACHE_CHECK([for long long support in printf],
1173                gdb_cv_printf_has_long_long,
1174                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1175 [[char buf[32];
1176   long long l = 0;
1177   l = (l << 16) + 0x0123;
1178   l = (l << 16) + 0x4567;
1179   l = (l << 16) + 0x89ab;
1180   l = (l << 16) + 0xcdef;
1181   sprintf (buf, "0x%016llx", l);
1182   return (strcmp ("0x0123456789abcdef", buf));]])],
1183                               gdb_cv_printf_has_long_long=yes,
1184                               gdb_cv_printf_has_long_long=no,
1185                               gdb_cv_printf_has_long_long=no)])
1186 if test $gdb_cv_printf_has_long_long = yes; then
1187   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1188             [Define to 1 if the "%ll" format works to print long longs.])
1189 fi
1190
1191 # Check if the compiler and runtime support printing decfloats.
1192
1193 AC_CACHE_CHECK([for decfloat support in printf],
1194                gdb_cv_printf_has_decfloat,
1195                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1196 [[char buf[64];
1197   _Decimal32 d32 = 1.2345df;
1198   _Decimal64 d64 = 1.2345dd;
1199   _Decimal128 d128 = 1.2345dl;
1200   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1201   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1202                               gdb_cv_printf_has_decfloat=yes,
1203                               gdb_cv_printf_has_decfloat=no,
1204                               gdb_cv_printf_has_decfloat=no)])
1205 if test $gdb_cv_printf_has_decfloat = yes; then
1206   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1207             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1208 fi
1209
1210 # Check if the compiler supports the `long double' type.  We can't use
1211 # AC_C_LONG_DOUBLE because that one does additional checks on the
1212 # constants defined in <float.h> that fail on some systems,
1213 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1214
1215 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1216                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1217                                   gdb_cv_c_long_double=yes,
1218                                   gdb_cv_c_long_double=no)])
1219 if test $gdb_cv_c_long_double = yes; then
1220   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1221            [Define to 1 if the compiler supports long double.])
1222 fi
1223
1224 # Check if the compiler and runtime support printing long doubles.
1225
1226 AC_CACHE_CHECK([for long double support in printf],
1227                gdb_cv_printf_has_long_double,
1228                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1229 [[char buf[16];
1230   long double f = 3.141592653;
1231   sprintf (buf, "%Lg", f);
1232   return (strncmp ("3.14159", buf, 7));]])],
1233                               gdb_cv_printf_has_long_double=yes,
1234                               gdb_cv_printf_has_long_double=no,
1235                               gdb_cv_printf_has_long_double=no)])
1236 if test $gdb_cv_printf_has_long_double = yes; then
1237   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1238             [Define to 1 if the "%Lg" format works to print long doubles.])
1239 fi
1240
1241 # Check if the compiler and runtime support scanning long doubles.
1242
1243 AC_CACHE_CHECK([for long double support in scanf],
1244                gdb_cv_scanf_has_long_double,
1245                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1246 [[#include <stdio.h>]],
1247 [[char *buf = "3.141592653";
1248   long double f = 0;
1249   sscanf (buf, "%Lg", &f);
1250   return !(f > 3.14159 && f < 3.14160);]])],
1251                               gdb_cv_scanf_has_long_double=yes,
1252                               gdb_cv_scanf_has_long_double=no,
1253                               gdb_cv_scanf_has_long_double=no)])
1254 if test $gdb_cv_scanf_has_long_double = yes; then
1255   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1256             [Define to 1 if the "%Lg" format works to scan long doubles.])
1257 fi
1258
1259 case ${host_os} in
1260 aix*)
1261   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1262     SAVE_LDFLAGS=$LDFLAGS
1263
1264     case $GCC in
1265     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1266     *) gdb_cv_bigtoc=-bbigtoc ;;
1267     esac
1268
1269     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1270     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1271     LDFLAGS="${SAVE_LDFLAGS}"
1272   ])
1273   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1274   ;;
1275 esac
1276
1277
1278 dnl For certain native configurations, we need to check whether thread
1279 dnl support can be built in or not.
1280 dnl
1281 dnl Note that we only want this if we are both native (host == target),
1282 dnl and not doing a canadian cross build (build == host).
1283
1284 if test ${build} = ${host} -a ${host} = ${target} ; then
1285    case ${host_os} in
1286    hpux*)
1287       AC_MSG_CHECKING(for HPUX/OSF thread support)
1288       if test -f /usr/include/dce/cma_config.h ; then
1289          if test "$GCC" = "yes" ; then
1290             AC_MSG_RESULT(yes)
1291             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1292             [Define if you have HPUX threads])
1293             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1294             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1295          else
1296             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1297          fi
1298       else
1299          AC_MSG_RESULT(no)
1300       fi
1301       ;;
1302    solaris*)
1303       # See if thread_db library is around for Solaris thread debugging.
1304       # Note that we must explicitly test for version 1 of the library
1305       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1306       # the same API.
1307       AC_MSG_CHECKING(for Solaris thread debugging library)
1308       if test -f /usr/lib/libthread_db.so.1 ; then
1309          AC_MSG_RESULT(yes)
1310          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1311          [Define if using Solaris thread debugging.])
1312          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1313          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1314          AC_CHECK_LIB(dl, dlopen)
1315          if test "$GCC" = "yes" ; then
1316             # The GNU linker requires the -export-dynamic option to make
1317             # all symbols visible in the dynamic symbol table.
1318             hold_ldflags=$LDFLAGS
1319             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1320             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1321             AC_TRY_LINK(, [int i;], found=yes, found=no)
1322             LDFLAGS=$hold_ldflags
1323             AC_MSG_RESULT($found)
1324             if test $found = yes; then
1325                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1326             fi
1327          fi
1328          # Sun randomly tweaked the prototypes in <proc_service.h>
1329          # at one point.
1330          AC_MSG_CHECKING(if <proc_service.h> is old)
1331          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1332             AC_TRY_COMPILE([
1333                 #include <proc_service.h>
1334                 ps_err_e ps_pdwrite
1335                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1336             ],, gdb_cv_proc_service_is_old=no,
1337                 gdb_cv_proc_service_is_old=yes)
1338          ])
1339          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1340          if test $gdb_cv_proc_service_is_old = yes; then
1341             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1342             [Define if <proc_service.h> on solaris uses int instead of
1343              size_t, and assorted other type changes.])
1344          fi
1345       else
1346          AC_MSG_RESULT(no)
1347       fi
1348       ;;
1349    aix*)
1350       AC_MSG_CHECKING(for AiX thread debugging library)
1351       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1352                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1353                                    [#ifndef PTHDB_VERSION_3
1354                                     #error
1355                                     #endif],
1356                                    gdb_cv_have_aix_thread_debug=yes,
1357                                    gdb_cv_have_aix_thread_debug=no)])
1358       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1359       if test $gdb_cv_have_aix_thread_debug = yes; then
1360          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1361          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1362          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1363       fi
1364       ;;
1365    esac
1366    AC_SUBST(CONFIG_LDFLAGS)
1367 fi
1368
1369 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1370 dnl other error codes.
1371 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1372    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1373                   gdb_cv_thread_db_h_has_td_notalloc,
1374      AC_TRY_COMPILE(
1375        [#include <thread_db.h>],
1376        [int i = TD_NOTALLOC;],
1377        gdb_cv_thread_db_h_has_td_notalloc=yes,
1378        gdb_cv_thread_db_h_has_td_notalloc=no
1379      )
1380    )
1381    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1382                   gdb_cv_thread_db_h_has_td_version,
1383      AC_TRY_COMPILE(
1384        [#include <thread_db.h>],
1385        [int i = TD_VERSION;],
1386        gdb_cv_thread_db_h_has_td_version=yes,
1387        gdb_cv_thread_db_h_has_td_version=no
1388      )
1389    )
1390    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1391                   gdb_cv_thread_db_h_has_td_notls,
1392      AC_TRY_COMPILE(
1393        [#include <thread_db.h>],
1394        [int i = TD_NOTLS;],
1395        gdb_cv_thread_db_h_has_td_notls=yes,
1396        gdb_cv_thread_db_h_has_td_notls=no
1397      )
1398    )
1399 fi
1400 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1401   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1402             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1403 fi
1404 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1405   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1406             [Define if <thread_db.h> has the TD_VERSION error code.])
1407 fi
1408 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1409   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1410             [Define if <thread_db.h> has the TD_NOTLS error code.])
1411 fi
1412
1413 dnl See if we have a sys/syscall header file that has __NR_tkill.
1414 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1415    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1416                   gdb_cv_sys_syscall_h_has_tkill,
1417      AC_TRY_COMPILE(
1418        [#include <sys/syscall.h>],
1419        [int i = __NR_tkill;],
1420        gdb_cv_sys_syscall_h_has_tkill=yes,
1421        gdb_cv_sys_syscall_h_has_tkill=no
1422      )
1423    )
1424 fi
1425 dnl See if we can issue tkill syscall.
1426 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1427   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1428 fi
1429
1430 dnl Check if we can disable the virtual address space randomization.
1431 dnl The functionality of setarch -R.
1432 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1433 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1434 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1435 #       define ADDR_NO_RANDOMIZE 0x0040000
1436 #      endif
1437        /* Test the flag could be set and stays set.  */
1438        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1439        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1440            return 1])])
1441 AC_RUN_IFELSE([PERSONALITY_TEST],
1442               [have_personality=true],
1443               [have_personality=false],
1444               [AC_LINK_IFELSE([PERSONALITY_TEST],
1445                               [have_personality=true],
1446                               [have_personality=false])])
1447 if $have_personality
1448 then
1449     AC_DEFINE([HAVE_PERSONALITY], 1,
1450               [Define if you support the personality syscall.])
1451 fi
1452
1453 dnl Handle optional features that can be enabled.
1454
1455 AC_ARG_WITH(sysroot,
1456 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1457 [
1458  case ${with_sysroot} in
1459  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1460  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1461  esac
1462
1463  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1464
1465  if test "x$prefix" = xNONE; then
1466   test_prefix=/usr/local
1467  else
1468   test_prefix=$prefix
1469  fi
1470  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1471   test_exec_prefix=$test_prefix
1472  else
1473   test_exec_prefix=$exec_prefix
1474  fi
1475  case ${TARGET_SYSTEM_ROOT} in
1476  "${test_prefix}"|"${test_prefix}/"*|\
1477  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1478  '${prefix}'|'${prefix}/'*|\
1479  '${exec_prefix}'|'${exec_prefix}/'*)
1480    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1481    TARGET_SYSTEM_ROOT_DEFINE="$t"
1482    ;;
1483  esac
1484 ], [
1485  TARGET_SYSTEM_ROOT=
1486  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1487 ])
1488 AC_SUBST(TARGET_SYSTEM_ROOT)
1489 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1490
1491 AC_ARG_ENABLE(werror,
1492   [  --enable-werror    treat compile warnings as errors],
1493   [case "${enableval}" in
1494      yes | y) ERROR_ON_WARNING="yes" ;;
1495      no | n)  ERROR_ON_WARNING="no" ;;
1496      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1497    esac])
1498
1499 # Enable -Werror by default when using gcc
1500 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1501     ERROR_ON_WARNING=yes
1502 fi
1503
1504 WERROR_CFLAGS=""
1505 if test "${ERROR_ON_WARNING}" = yes ; then
1506     WERROR_CFLAGS="-Werror"
1507 fi
1508
1509 # The entries after -Wno-pointer-sign are disabled warnings which may
1510 # be enabled in the future, which can not currently be used to build
1511 # GDB.
1512 # NOTE: If you change this list, remember to update
1513 # gdb/doc/gdbint.texinfo.
1514 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1515 -Wformat-nonliteral -Wno-pointer-sign \
1516 -Wno-unused -Wno-switch -Wno-char-subscripts"
1517
1518 # Enable -Wno-format by default when using gcc on mingw since many
1519 # GCC versions complain about %I64.
1520 case "${host}" in
1521   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1522 esac
1523
1524 AC_ARG_ENABLE(build-warnings,
1525 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1526 [case "${enableval}" in
1527   yes)  ;;
1528   no)   build_warnings="-w";;
1529   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1530         build_warnings="${build_warnings} ${t}";;
1531   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1532         build_warnings="${t} ${build_warnings}";;
1533   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1534 esac
1535 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1536   echo "Setting compiler warning flags = $build_warnings" 6>&1
1537 fi])dnl
1538 AC_ARG_ENABLE(gdb-build-warnings,
1539 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1540 [case "${enableval}" in
1541   yes)  ;;
1542   no)   build_warnings="-w";;
1543   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1544         build_warnings="${build_warnings} ${t}";;
1545   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1546         build_warnings="${t} ${build_warnings}";;
1547   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1548 esac
1549 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1550   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1551 fi])dnl
1552 WARN_CFLAGS=""
1553 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1554 then
1555     AC_MSG_CHECKING(compiler warning flags)
1556     # Separate out the -Werror flag as some files just cannot be
1557     # compiled with it enabled.
1558     for w in ${build_warnings}; do
1559         case $w in
1560         -Werr*) WERROR_CFLAGS=-Werror ;;
1561         *) # Check that GCC accepts it
1562             saved_CFLAGS="$CFLAGS"
1563             CFLAGS="$CFLAGS $w"
1564             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1565             CFLAGS="$saved_CFLAGS"
1566         esac
1567     done
1568     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1569 fi
1570 AC_SUBST(WARN_CFLAGS)
1571 AC_SUBST(WERROR_CFLAGS)
1572
1573 # In the Cygwin environment, we need some additional flags.
1574 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1575 [AC_EGREP_CPP(lose, [
1576 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1577 lose
1578 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1579
1580
1581 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1582 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1583 case ${host} in
1584   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1585   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1586   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1587 esac
1588 AC_SUBST(SER_HARDWIRE)
1589
1590 # libreadline needs libuser32.a in a cygwin environment
1591 WIN32LIBS=
1592 if test x$gdb_cv_os_cygwin = xyes; then
1593     WIN32LIBS="-luser32"
1594     case "${target}" in
1595         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1596         ;;
1597     esac
1598 fi
1599
1600 # The ser-tcp.c module requires sockets.
1601 case ${host} in
1602   *mingw32*)
1603     AC_DEFINE(USE_WIN32API, 1,
1604               [Define if we should use the Windows API, instead of the
1605                POSIX API.  On Windows, we use the Windows API when
1606                building for MinGW, but the POSIX API when building
1607                for Cygwin.])
1608     WIN32LIBS="$WIN32LIBS -lws2_32"
1609     ;;
1610 esac
1611 AC_SUBST(WIN32LIBS)
1612
1613 # Add ELF support to GDB, but only if BFD includes ELF support.
1614 OLD_CFLAGS=$CFLAGS
1615 OLD_LDFLAGS=$LDFLAGS
1616 OLD_LIBS=$LIBS
1617 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1618 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1619 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1620 LIBS="-lbfd -liberty $intl $LIBS"
1621 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1622 [AC_TRY_LINK(
1623 [#include <stdlib.h>
1624 #include "bfd.h"
1625 #include "elf-bfd.h"
1626 ],
1627 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1628 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1629 if test $gdb_cv_var_elf = yes; then
1630   CONFIG_OBS="$CONFIG_OBS elfread.o"
1631   AC_DEFINE(HAVE_ELF, 1,
1632             [Define if ELF support should be included.])
1633 fi
1634 CFLAGS=$OLD_CFLAGS
1635 LDFLAGS=$OLD_LDFLAGS
1636 LIBS=$OLD_LIBS
1637
1638 # Add any host-specific objects to GDB.
1639 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1640
1641 LIBGUI="../libgui/src/libgui.a"
1642 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1643 AC_SUBST(LIBGUI)
1644 AC_SUBST(GUI_CFLAGS_X)
1645
1646 WIN32LDAPP=
1647 AC_SUBST(WIN32LIBS)
1648 AC_SUBST(WIN32LDAPP)
1649
1650 case "${host}" in
1651 *-*-cygwin* | *-*-mingw* )
1652     configdir="win"
1653     ;;
1654 *)
1655     configdir="unix"
1656     ;;
1657 esac
1658
1659 GDBTKLIBS=
1660 if test "${enable_gdbtk}" = "yes"; then
1661
1662     # Gdbtk must have an absolute path to srcdir in order to run
1663     # properly when not installed.
1664     here=`pwd`
1665     cd ${srcdir}
1666     GDBTK_SRC_DIR=`pwd`
1667     cd $here
1668
1669     SC_PATH_TCLCONFIG
1670     if test -z "${no_tcl}"; then
1671         SC_LOAD_TCLCONFIG
1672
1673         # Check for in-tree tcl
1674         here=`pwd`
1675         cd ${srcdir}/..
1676         topdir=`pwd`
1677         cd ${here}
1678
1679         intree="no"
1680         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1681           intree="yes"
1682         fi
1683
1684         # Find Tcl private headers
1685         if test x"${intree}" = xno; then
1686           CY_AC_TCL_PRIVATE_HEADERS
1687           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1688           TCL_LIBRARY="${TCL_LIB_SPEC}"
1689           TCL_DEPS=""
1690         else
1691           # If building tcl in the same src tree, private headers
1692           # are not needed, but we need to be sure to use the right
1693           # headers library
1694           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1695           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1696           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1697         fi
1698         AC_SUBST(TCL_INCLUDE)
1699         AC_SUBST(TCL_LIBRARY)
1700         AC_SUBST(TCL_DEPS)
1701
1702         # If $no_tk is nonempty, then we can't do Tk, and there is no
1703         # point to doing Tcl.
1704         if test -z "${no_tk}"; then
1705            SC_PATH_TKCONFIG
1706            SC_LOAD_TKCONFIG
1707
1708            # Check for in-tree Tk
1709            intree="no"
1710            if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1711              intree="yes"
1712            fi
1713
1714            # Find Tk private headers
1715            if test x"${intree}" = xno; then
1716              CY_AC_TK_PRIVATE_HEADERS
1717              TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1718              TK_LIBRARY=${TK_LIB_SPEC}
1719              TK_DEPS=""
1720            else
1721              TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1722              TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1723              TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1724            fi
1725            AC_SUBST(TK_INCLUDE)
1726            AC_SUBST(TK_LIBRARY)
1727            AC_SUBST(TK_DEPS)
1728            AC_SUBST(TK_XINCLUDES)
1729
1730            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1731
1732            # Include some libraries that Tcl and Tk want.
1733            TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1734            # Yes, the ordering seems wrong here.  But it isn't.
1735            # TK_LIBS is the list of libraries that need to be linked
1736            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1737            # were in LIBS then any link tests after this point would
1738            # try to include things like `$(LIBGUI)', which wouldn't work.
1739            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1740
1741            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1742            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1743            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1744            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1745            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1746            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1747            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1748
1749            if test x$gdb_cv_os_cygwin = xyes; then
1750               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1751               WIN32LDAPP="-Wl,--subsystem,console"
1752               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1753            fi
1754         fi
1755     fi
1756
1757     AC_CONFIG_SUBDIRS(gdbtk)
1758 fi
1759
1760 AC_SUBST(X_CFLAGS)
1761 AC_SUBST(X_LDFLAGS)
1762 AC_SUBST(X_LIBS)
1763 AC_SUBST(GDBTKLIBS)
1764 AC_SUBST(GDBTK_CFLAGS)
1765 AC_SUBST(GDBTK_SRC_DIR)
1766
1767 AC_PATH_X
1768
1769 # Unlike the sim directory, whether a simulator is linked is controlled by
1770 # presence of a gdb_sim definition in the target configure.tgt entry.
1771 # This code just checks for a few cases where we'd like to ignore those
1772 # definitions, even when they're present in the '.mt' file.  These cases
1773 # are when --disable-sim is specified, or if the simulator directory is
1774 # not part of the source tree.
1775 #
1776 AC_ARG_ENABLE(sim,
1777 [  --enable-sim            Link gdb with simulator],
1778 [echo "enable_sim = $enable_sim";
1779  echo "enableval = ${enableval}";
1780  case "${enableval}" in
1781   yes) ignore_sim=false ;;
1782   no)  ignore_sim=true ;;
1783   *)   ignore_sim=false ;;
1784  esac],
1785 [ignore_sim=false])
1786
1787 if test ! -d "${srcdir}/../sim"; then
1788   ignore_sim=true
1789 fi
1790
1791 SIM=
1792 SIM_OBS=
1793 if test "${ignore_sim}" = "false"; then
1794   if test x"${gdb_sim}" != x ; then
1795     SIM="${gdb_sim}"
1796     SIM_OBS="remote-sim.o"
1797     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1798   fi
1799 fi
1800 AC_SUBST(SIM)
1801 AC_SUBST(SIM_OBS)
1802
1803 AC_SUBST(ENABLE_CFLAGS)
1804 AC_SUBST(PROFILE_CFLAGS)
1805
1806 AC_SUBST(CONFIG_OBS)
1807 AC_SUBST(CONFIG_DEPS)
1808 AC_SUBST(CONFIG_SRCS)
1809 AC_SUBST(CONFIG_ALL)
1810 AC_SUBST(CONFIG_CLEAN)
1811 AC_SUBST(CONFIG_INSTALL)
1812 AC_SUBST(CONFIG_UNINSTALL)
1813
1814 # List of host floatformats.
1815 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1816 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1817 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1818
1819 # target_subdir is used by the testsuite to find the target libraries.
1820 target_subdir=
1821 if test "${host}" != "${target}"; then
1822     target_subdir="${target_alias}/"
1823 fi
1824 AC_SUBST(target_subdir)
1825
1826 frags=
1827 if test "${gdb_native}" = "yes"; then
1828   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1829   if test ! -f ${host_makefile_frag}; then
1830     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1831   fi
1832   frags="$frags $host_makefile_frag"
1833 else
1834   host_makefile_frag=/dev/null
1835 fi
1836
1837 AC_SUBST_FILE(host_makefile_frag)
1838 AC_SUBST(frags)
1839
1840 changequote(,)dnl
1841 if test "${gdb_native}" = "yes"; then
1842 # We pick this up from the host configuration file (.mh) because we
1843 # do not have a native configuration Makefile fragment.
1844 nativefile=`sed -n '
1845 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1846 ' ${host_makefile_frag}`
1847 fi
1848 changequote([,])
1849
1850 if test x"${gdb_osabi}" != x ; then
1851     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1852                        [Define to the default OS ABI for this configuration.])
1853 fi
1854
1855 # Enable multi-ice-gdb-server.
1856 AC_ARG_ENABLE(multi-ice,
1857 [  --enable-multi-ice      build the multi-ice-gdb-server],
1858   [case $enableval in
1859     yes | no)
1860       ;;
1861     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1862   esac])
1863 if test "x$enable_multi_ice" = xyes; then
1864    AC_CONFIG_SUBDIRS(multi-ice)
1865 fi
1866
1867 # We only build gdbserver automatically in a native configuration.
1868 if test "$gdb_native" = "yes"; then
1869   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1870   if test "x$build_gdbserver" = xyes; then
1871     AC_MSG_RESULT(yes)
1872     AC_CONFIG_SUBDIRS(gdbserver)
1873   else
1874     AC_MSG_RESULT(no)
1875   fi
1876 fi
1877
1878 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1879 # to an empty version.
1880
1881 files=
1882 links=
1883
1884 rm -f nm.h
1885 nm_h=""
1886 if test "${nativefile}" != ""; then
1887     nm_h=nm.h
1888     case "${nativefile}" in
1889       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1890       * ) GDB_NM_FILE="${nativefile}"
1891     esac
1892     files="${files} ${GDB_NM_FILE}"
1893     links="${links} nm.h"
1894     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1895 fi
1896 AC_SUBST(nm_h)
1897
1898 AC_LINK_FILES($files, $links)
1899
1900 dnl Check for exe extension set on certain hosts (e.g. Win32)
1901 AC_EXEEXT
1902
1903 dnl  Detect the character set used by this host.
1904
1905 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1906 dnl  superset of ASCII containing the characters needed for French,
1907 dnl  German, Spanish, Italian, and possibly others), but if were
1908 dnl  *were* to support any host character sets other than ISO-8859-1,
1909 dnl  here's where we'd detect it.
1910 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1911           [Define to be a string naming the default host character set.])
1912
1913 AM_ICONV
1914
1915 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1916 [
1917 dnl Autoconf doesn't provide a mechanism for modifying definitions
1918 dnl provided by makefile fragments.
1919 dnl
1920
1921 changequote(,)dnl
1922 sed -e '/^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1923 mv -f Makefile.tmp Makefile
1924 changequote([,])dnl
1925
1926
1927 case x$CONFIG_HEADERS in
1928 xconfig.h:config.in)
1929 echo > stamp-h ;;
1930 esac
1931 ],
1932 [
1933 gdb_host_cpu=$gdb_host_cpu
1934 nativefile=$nativefile
1935 ])
1936
1937 exit 0