gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   3 dnl 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # Dependency checking.
  38 ZW_CREATE_DEPDIR
  39 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  40
  41 # Check for the 'make' the user wants to use.
  42 AC_CHECK_PROGS(MAKE, make)
  43 MAKE_IS_GNU=
  44 case "`$MAKE --version 2>&1 | sed 1q`" in
  45   *GNU*)
  46     MAKE_IS_GNU=yes
  47     ;;
  48 esac
  49 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  50 AC_PROG_MAKE_SET
  51
  52 dnl List of object files and targets accumulated by configure.
  53
  54 CONFIG_OBS=
  55 CONFIG_DEPS=
  56 CONFIG_SRCS=
  57 ENABLE_CFLAGS=
  58
  59 CONFIG_ALL=
  60 CONFIG_CLEAN=
  61 CONFIG_INSTALL=
  62 CONFIG_UNINSTALL=
  63
  64 dnl Set up for gettext.
  65 ZW_GNU_GETTEXT_SISTER_DIR
  66
  67 localedir='${datadir}/locale'
  68 AC_SUBST(localedir)
  69
  70 if test x"$USE_NLS" = xyes; then
  71    CONFIG_ALL="$CONFIG_ALL all-po"
  72    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  73    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  74    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  75 fi
  76
  77 gl_INIT
  78
  79 # For Makefile dependencies.
  80 GNULIB_STDINT_H=
  81 if test x"$STDINT_H" != x; then
  82   GNULIB_STDINT_H=gnulib/$STDINT_H
  83 fi
  84 AC_SUBST(GNULIB_STDINT_H)
  85
  86 PACKAGE=gdb
  87 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  88 AC_SUBST(PACKAGE)
  89
  90 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  91 # rely on it - libiberty is built before texinfo.
  92 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  93 if test "x$MAKEINFO" = "x"; then
  94   AC_ERROR([makeinfo is required for compilation])
  95 else
  96   case "$MAKEINFO" in
  97     */missing\ makeinfo*)
  98       AC_ERROR([makeinfo is required for compilation])
  99       ;;
 100   esac
 101 fi
 102 AC_SUBST(MAKEINFO)
 103
 104 # --split-size=5000000 may be already in $MAKEINFO from parent configure.
 105 # Re-running configure in gdb/ would lose it so ensure it stays present.
 106 MAKEINFOFLAGS=${MAKEINFOFLAGS---split-size=5000000}
 107 AC_SUBST(MAKEINFOFLAGS)
 108
 109 MAKEINFO_EXTRA_FLAGS=""
 110 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 111   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 112   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 113     gdb_cv_have_makeinfo_click=yes
 114   else
 115     gdb_cv_have_makeinfo_click=no
 116   fi])
 117 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 118   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 119 fi
 120 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 121
 122 # GDB does not use automake, but gnulib does.  This line lets us
 123 # generate its Makefile.in.
 124 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
 125
 126 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 127     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 128     [${libdir}/debug])
 129
 130 # GDB's datadir relocation
 131
 132 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 133     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 134     [${datadir}/gdb])
 135
 136 AC_ARG_WITH(relocated-sources,
 137 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 138 [reloc_srcdir="${withval}"
 139  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 140               [Relocated directory for source files. ])
 141 ])
 142
 143 AC_CONFIG_SUBDIRS(testsuite)
 144
 145 # Check whether to support alternative target configurations
 146 AC_ARG_ENABLE(targets,
 147 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 148 [case "${enableval}" in
 149   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 150             ;;
 151   no)       enable_targets= ;;
 152   *)        enable_targets=$enableval ;;
 153 esac])
 154
 155 # Check whether to enable 64-bit support on 32-bit hosts
 156 AC_ARG_ENABLE(64-bit-bfd,
 157 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 158 [case "${enableval}" in
 159   yes)  want64=true  ;;
 160   no)   want64=false ;;
 161   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 162 esac],[want64=false])dnl
 163
 164 # Provide defaults for some variables set by the per-host and per-target
 165 # configuration.
 166 gdb_host_obs=posix-hdep.o
 167
 168 if test "${target}" = "${host}"; then
 169   gdb_native=yes
 170 else
 171   gdb_native=no
 172 fi
 173
 174 . $srcdir/configure.host
 175
 176 # Accumulate some settings from configure.tgt over all enabled targets
 177
 178 TARGET_OBS=
 179 all_targets=
 180
 181 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 182 do
 183   if test "$targ_alias" = "all"; then
 184     all_targets=true
 185   else
 186     # Canonicalize the secondary target names.
 187     result=`$ac_config_sub $targ_alias 2>/dev/null`
 188     if test -n "$result"; then
 189         targ=$result
 190     else
 191         targ=$targ_alias
 192     fi
 193
 194     . ${srcdir}/configure.tgt
 195
 196     AS_IF([test -z "${gdb_target_obs}"],
 197       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 198
 199     # Target-specific object files
 200     for i in ${gdb_target_obs}; do
 201         case " $TARGET_OBS " in
 202         *" ${i} "*) ;;
 203         *)
 204           TARGET_OBS="$TARGET_OBS ${i}"
 205           ;;
 206         esac
 207     done
 208
 209     # Check whether this target needs 64-bit CORE_ADDR
 210     if test x${want64} = xfalse; then
 211       . ${srcdir}/../bfd/config.bfd
 212     fi
 213   fi
 214 done
 215
 216 if test x${all_targets} = xtrue; then
 217
 218   # We want all 64-bit targets if we either:
 219   #  - run on a 64-bit host  or
 220   #  - already require 64-bit support for some other target  or
 221   #  - the --enable-64-bit-bfd option was supplied
 222   # Otherwise we only support all 32-bit targets.
 223   #
 224   # NOTE: This test must be in sync with the corresponding
 225   #       tests in BFD!
 226
 227   if test x${want64} = xfalse; then
 228     AC_CHECK_SIZEOF(long)
 229     if test "x${ac_cv_sizeof_long}" = "x8"; then
 230       want64=true
 231     fi
 232   fi
 233   if test x${want64} = xtrue; then
 234     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 235   else
 236     TARGET_OBS='$(ALL_TARGET_OBS)'
 237   fi
 238 fi
 239
 240 AC_SUBST(TARGET_OBS)
 241
 242 # For other settings, only the main target counts.
 243 gdb_sim=
 244 gdb_osabi=
 245 build_gdbserver=
 246 targ=$target; . ${srcdir}/configure.tgt
 247
 248 # Fetch the default architecture and default target vector from BFD.
 249 targ=$target; . $srcdir/../bfd/config.bfd
 250
 251 # We only want the first architecture, so strip off the others if
 252 # there is more than one.
 253 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 254
 255 if test "x$targ_archs" != x; then
 256   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 257     [Define to BFD's default architecture. ])
 258 fi
 259 if test "x$targ_defvec" != x; then
 260   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 261     [Define to BFD's default target vector. ])
 262 fi
 263
 264 # The CLI cannot be disabled yet, but may be in the future.
 265
 266 # Enable CLI.
 267 AC_ARG_ENABLE(gdbcli,
 268 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 269   [case $enableval in
 270     yes)
 271       ;;
 272     no)
 273       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 274     *)
 275       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 276   esac],
 277   [enable_gdbcli=yes])
 278 if test x"$enable_gdbcli" = xyes; then
 279   if test -d $srcdir/cli; then
 280     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 281     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 282     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 283     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 284   fi
 285 fi
 286
 287 # Enable MI.
 288 AC_ARG_ENABLE(gdbmi,
 289 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 290   [case $enableval in
 291     yes | no)
 292       ;;
 293     *)
 294       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 295   esac],
 296   [enable_gdbmi=yes])
 297 if test x"$enable_gdbmi" = xyes; then
 298   if test -d $srcdir/mi; then
 299     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 300     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 301     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 302     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 303   fi
 304 fi
 305
 306 # Enable TUI.
 307 AC_ARG_ENABLE(tui,
 308 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 309   [case $enableval in
 310     yes | no | auto)
 311       ;;
 312     *)
 313       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 314   esac],enable_tui=auto)
 315
 316 # Enable gdbtk.
 317 AC_ARG_ENABLE(gdbtk,
 318 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 319   [case $enableval in
 320     yes | no)
 321       ;;
 322     *)
 323       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 324   esac],
 325   [if test -d $srcdir/gdbtk; then
 326     enable_gdbtk=yes
 327   else
 328     enable_gdbtk=no
 329   fi])
 330 # We unconditionally disable gdbtk tests on selected platforms.
 331 case $host_os in
 332   go32* | windows*)
 333     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 334     enable_gdbtk=no ;;
 335 esac
 336
 337 # Libunwind support.
 338 AC_ARG_WITH(libunwind,
 339 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 340 [case "${withval}" in
 341   yes)  enable_libunwind=yes ;;
 342   no)   enable_libunwind=no ;;
 343   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 344 esac],[
 345   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 346   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 347     enable_libunwind=yes;
 348   fi
 349 ])
 350
 351 if test x"$enable_libunwind" = xyes; then
 352   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 353   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 354   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 355   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 356   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 357 fi
 358
 359 opt_curses=no
 360 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 361
 362 prefer_curses=no
 363 if test "$opt_curses" = "yes"; then
 364   prefer_curses=yes
 365 fi
 366
 367 # Profiling support.
 368 AC_ARG_ENABLE(profiling,
 369 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 370   [case $enableval in
 371     yes | no)
 372       ;;
 373     *)
 374       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 375   esac],
 376  [enable_profiling=no])
 377
 378 AC_CHECK_FUNCS(monstartup _mcleanup)
 379 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 380 [AC_TRY_LINK(
 381 [#include <stdlib.h>
 382 extern char _etext;
 383 ],
 384 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 385 if test $ac_cv_var__etext = yes; then
 386   AC_DEFINE(HAVE__ETEXT, 1,
 387             [Define to 1 if your system has the _etext variable. ])
 388 fi
 389 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 390 [AC_TRY_LINK(
 391 [#include <stdlib.h>
 392 extern char etext;
 393 ],
 394 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 395 if test $ac_cv_var_etext = yes; then
 396   AC_DEFINE(HAVE_ETEXT, 1,
 397             [Define to 1 if your system has the etext variable. ])
 398 fi
 399 if test "$enable_profiling" = yes ; then
 400   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 401     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 402   fi
 403   PROFILE_CFLAGS=-pg
 404   OLD_CFLAGS="$CFLAGS"
 405   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 406
 407   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 408     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 409      ac_cv_cc_supports_pg=no)])
 410
 411   if test $ac_cv_cc_supports_pg = no; then
 412     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 413   fi
 414
 415   CFLAGS="$OLD_CFLAGS"
 416 fi
 417
 418 ACX_PKGVERSION([GDB])
 419 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 420 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 421 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 422
 423 # --------------------- #
 424 # Checks for programs.  #
 425 # --------------------- #
 426
 427 AC_PROG_AWK
 428 AC_PROG_INSTALL
 429 AC_PROG_LN_S
 430 AC_PROG_RANLIB
 431 AC_PROG_YACC
 432
 433 AC_CHECK_TOOL(AR, ar)
 434 AC_CHECK_TOOL(DLLTOOL, dlltool)
 435 AC_CHECK_TOOL(WINDRES, windres)
 436
 437 # Needed for GNU/Hurd.
 438 AC_CHECK_TOOL(MIG, mig)
 439
 440 # ---------------------- #
 441 # Checks for libraries.  #
 442 # ---------------------- #
 443
 444 # We might need to link with -lm; most simulators need it.
 445 AC_CHECK_LIB(m, main)
 446
 447 # We need to link with -lw to get `wctype' on Solaris before Solaris
 448 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 449 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 450 # is known to have this problem).  Therefore we avoid libw if we can.
 451 AC_CHECK_FUNC(wctype, [],
 452   [AC_CHECK_LIB(w, wctype)])
 453
 454 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 455 AC_SEARCH_LIBS(gethostbyname, nsl)
 456
 457 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 458 AC_SEARCH_LIBS(socketpair, socket)
 459
 460 # Link in zlib if we can.  This allows us to read compressed debug sections.
 461 AM_ZLIB
 462
 463 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 464 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 465
 466 AM_ICONV
 467
 468 # GDB may fork/exec the iconv program to get the list of supported character
 469 # sets.  Allow the user to specify where to find it.
 470 # There are several factors affecting the choice of option name:
 471 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 472 #   the build-time location of libiconv files.
 473 # - The program we need to find is iconv, which comes with glibc.  The user
 474 #   doesn't necessarily have libiconv installed.  Therefore naming this
 475 #   --with-libiconv-foo feels wrong.
 476 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 477 #   defined to work on directories not files (though it really doesn't know
 478 #   the difference).
 479 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 480 #   with --with-libiconv-prefix.
 481 # Putting these together is why the option name is --with-iconv-bin.
 482
 483 AC_ARG_WITH(iconv-bin,
 484 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 485 [iconv_bin="${withval}"
 486  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 487                     [Path of directory of iconv program.])
 488  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 489 ])
 490
 491 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 492 # There is a very specific comment in /usr/include/curses.h explaining that
 493 # termcap routines built into libcurses must not be used.
 494 #
 495 # The symptoms we observed so far is GDB unexpectedly changing
 496 # the terminal settings when tgetent is called - this is particularly
 497 # visible as the output is missing carriage returns, and so rapidly
 498 # becomes very hard to read.
 499 #
 500 # The readline configure script has already decided that libtermcap
 501 # was enough for its purposes, and so decided to build readline using
 502 # libtermcap.  Since the TUI mode requires curses, building GDB with
 503 # TUI enabled results in both libraries to be used at the same time,
 504 # which is not allowed.  This basically means that GDB with TUI is
 505 # broken on alpha-osf.
 506
 507 case $host_os in
 508   osf* )
 509     if test x"$enable_tui" = xyes; then
 510       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 511     fi
 512     if test x"$enable_tui" = xauto; then
 513       enable_tui=no
 514     fi
 515     ;;
 516 esac
 517
 518 # For the TUI, we need enhanced curses functionality.
 519 if test x"$enable_tui" != xno; then
 520   prefer_curses=yes
 521 fi
 522
 523 curses_found=no
 524 if test x"$prefer_curses" = xyes; then
 525   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 526   # curses library because the latter might not provide all the
 527   # functionality we need.  However, this leads to problems on systems
 528   # where the linker searches /usr/local/lib, but the compiler doesn't
 529   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 530   # default installation of ncurses on alpha*-dec-osf* will lead to such
 531   # a situation.
 532   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 533
 534   if test "$ac_cv_search_waddstr" != no; then
 535     curses_found=yes
 536   fi
 537 fi
 538
 539 # Check whether we should enable the TUI, but only do so if we really
 540 # can.
 541 if test x"$enable_tui" != xno; then
 542   if test -d $srcdir/tui; then
 543     if test "$curses_found" != no; then
 544       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 545       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 546       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 547       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 548       CONFIG_ALL="${CONFIG_ALL} all-tui"
 549       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 550       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 551       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 552     else
 553       if test x"$enable_tui" = xyes; then
 554         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 555       else
 556         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 557       fi
 558     fi
 559   fi
 560 fi
 561
 562 # Since GDB uses Readline, we need termcap functionality.  In many
 563 # cases this will be provided by the curses library, but some systems
 564 # have a seperate termcap library, or no curses library at all.
 565
 566 case $host_os in
 567   cygwin*)
 568     if test -d $srcdir/libtermcap; then
 569       LIBS="../libtermcap/libtermcap.a $LIBS"
 570       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 571     fi ;;
 572   go32* | *djgpp*)
 573     ac_cv_search_tgetent="none required"
 574     ;;
 575   *mingw32*)
 576     ac_cv_search_tgetent="none required"
 577     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 578     ;;
 579 esac
 580
 581 # These are the libraries checked by Readline.
 582 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 583
 584 if test "$ac_cv_search_tgetent" = no; then
 585   AC_MSG_ERROR([no termcap library found])
 586 fi
 587
 588 AC_ARG_WITH([system-readline],
 589   [AS_HELP_STRING([--with-system-readline],
 590                   [use installed readline library])])
 591
 592 if test "$with_system_readline" = yes; then
 593   READLINE=-lreadline
 594   READLINE_DEPS=
 595   READLINE_CFLAGS=
 596   READLINE_TEXI_INCFLAG=
 597 else
 598   READLINE='$(READLINE_DIR)/libreadline.a'
 599   READLINE_DEPS='$(READLINE)'
 600   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 601   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 602 fi
 603 AC_SUBST(READLINE)
 604 AC_SUBST(READLINE_DEPS)
 605 AC_SUBST(READLINE_CFLAGS)
 606 AC_SUBST(READLINE_TEXI_INCFLAG)
 607
 608 # Generate jit-reader.h
 609
 610 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 611 TARGET_PTR=
 612
 613 AC_CHECK_SIZEOF(unsigned long long)
 614 AC_CHECK_SIZEOF(unsigned long)
 615 AC_CHECK_SIZEOF(unsigned __int128)
 616
 617 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 618   TARGET_PTR="unsigned long"
 619 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 620   TARGET_PTR="unsigned long long"
 621 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 622   TARGET_PTR="unsigned __int128"
 623 else
 624   TARGET_PTR="unsigned long"
 625 fi
 626
 627 AC_SUBST(TARGET_PTR)
 628 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 629
 630 AC_ARG_WITH(expat,
 631   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 632   [], [with_expat=auto])
 633 AC_MSG_CHECKING([whether to use expat])
 634 AC_MSG_RESULT([$with_expat])
 635
 636 if test "${with_expat}" = no; then
 637   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 638   HAVE_LIBEXPAT=no
 639 else
 640   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 641                         [XML_Parser p = XML_ParserCreate (0);])
 642   if test "$HAVE_LIBEXPAT" != yes; then
 643     if test "$with_expat" = yes; then
 644       AC_MSG_ERROR([expat is missing or unusable])
 645     else
 646       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 647     fi
 648   else
 649     save_LIBS=$LIBS
 650     LIBS="$LIBS $LIBEXPAT"
 651     AC_CHECK_FUNCS(XML_StopParser)
 652     LIBS=$save_LIBS
 653   fi
 654 fi
 655
 656 dnl Utility to simplify finding libpython.
 657 dnl $1 = pythonX.Y
 658 dnl $2 = the shell variable to assign the result to
 659 dnl      If libpython is found we store $version here.
 660 dnl $3 = additional flags to add to CPPFLAGS
 661 dnl $4 = additional flags to add to LIBS
 662
 663 AC_DEFUN([AC_TRY_LIBPYTHON],
 664 [
 665   version=$1
 666   define([have_libpython_var],$2)
 667   new_CPPFLAGS=$3
 668   new_LIBS=$4
 669   AC_MSG_CHECKING([for ${version}])
 670   save_CPPFLAGS=$CPPFLAGS
 671   save_LIBS=$LIBS
 672   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 673   LIBS="$LIBS $new_LIBS"
 674   found_usable_python=no
 675   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 676                                  [[Py_Initialize ();]]),
 677                  [have_libpython_var=${version}
 678                   found_usable_python=yes
 679                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 680                   PYTHON_LIBS=$new_LIBS])
 681   CPPFLAGS=$save_CPPFLAGS
 682   LIBS=$save_LIBS
 683   AC_MSG_RESULT([${found_usable_python}])
 684 ])
 685
 686 dnl There are several different values for --with-python:
 687 dnl
 688 dnl no -   Don't include python support.
 689 dnl yes -  Include python support, error if it's missing.
 690 dnl        If we find python in $PATH, use it to fetch configure options,
 691 dnl        otherwise assume the compiler can find it with no help from us.
 692 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 693 dnl auto - Same as "yes", but if python is missing from the system,
 694 dnl        fall back to "no".
 695 dnl /path/to/python/exec-prefix -
 696 dnl        Use the python located in this directory.
 697 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 698 dnl        the compilation parameters.  Otherwise use
 699 dnl        -I/path/to/python/exec-prefix/include,
 700 dnl        -L/path/to/python/exec-prefix/lib.
 701 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 702 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 703 dnl        but is deprecated.
 704 dnl /path/to/python/executable -
 705 dnl        Run python-config.py with this version of python to fetch the
 706 dnl        compilation parameters.
 707 dnl        NOTE: This needn't be the real python executable.
 708 dnl        In a cross-compilation scenario (build != host), this could be
 709 dnl        a shell script that provides what python-config.py provides for
 710 dnl        --ldflags, --includes, --exec-prefix.
 711 dnl python-executable -
 712 dnl        Find python-executable in $PATH, and then handle the same as
 713 dnl        /path/to/python/executable.
 714 dnl
 715 dnl If a python program is specified, it is used to run python-config.py and
 716 dnl is passed --ldflags, --includes, --exec-prefix.
 717
 718 AC_ARG_WITH(python,
 719   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 720   [], [with_python=auto])
 721 AC_MSG_CHECKING([whether to use python])
 722 AC_MSG_RESULT([$with_python])
 723
 724 if test "${with_python}" = no; then
 725   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 726   have_libpython=no
 727 else
 728   case "${with_python}" in
 729   /*)
 730     if test -d ${with_python}; then
 731       # Assume the python binary is ${with_python}/bin/python.
 732       python_prog="${with_python}/bin/python"
 733       python_prefix=
 734       # If python does not exit ${with_python}/bin, then try in
 735       # ${with_python}.  On Windows/MinGW, this is where the Python
 736       # executable is.
 737       if test ! -x "${python_prog}"; then
 738         python_prog="${with_python}/python"
 739         python_prefix=
 740       fi
 741       if test ! -x "${python_prog}"; then
 742         # Fall back to gdb 7.0/7.1 behaviour.
 743         python_prog=missing
 744         python_prefix=${with_python}
 745       fi
 746     elif test -x "${with_python}"; then
 747       # While we can't run python compiled for $host (unless host == build),
 748       # the user could write a script that provides the needed information,
 749       # so we support that.
 750       python_prog=${with_python}
 751       python_prefix=
 752     else
 753       AC_ERROR(invalid value for --with-python)
 754     fi
 755     ;;
 756   */*)
 757     # Disallow --with-python=foo/bar.
 758     AC_ERROR(invalid value for --with-python)
 759     ;;
 760   *)
 761     # The user has either specified auto, yes, or the name of the python
 762     # program assumed to be in $PATH.
 763     python_prefix=
 764     case "${with_python}" in
 765     yes | auto)
 766       if test ${build} = ${host}; then
 767         AC_PATH_PROG(python_prog_path, python, missing)
 768         if test "${python_prog_path}" = missing; then
 769           python_prog=missing
 770         else
 771           python_prog=${python_prog_path}
 772         fi
 773       else
 774         # Not much we can do except assume the cross-compiler will find the
 775         # right files.
 776         python_prog=missing
 777       fi
 778       ;;
 779     *)
 780       # While we can't run python compiled for $host (unless host == build),
 781       # the user could write a script that provides the needed information,
 782       # so we support that.
 783       python_prog="${with_python}"
 784       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 785       if test "${python_prog_path}" = missing; then
 786         AC_ERROR(unable to find python program ${python_prog})
 787       fi
 788       ;;
 789     esac
 790   esac
 791
 792   if test "${python_prog}" != missing; then
 793     # We have a python program to use, but it may be too old.
 794     # Don't flag an error for --with-python=auto (the default).
 795     have_python_config=yes
 796     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 797     if test $? != 0; then
 798       have_python_config=failed
 799       if test "${with_python}" != auto; then
 800         AC_ERROR(failure running python-config --includes)
 801       fi
 802     fi
 803     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 804     if test $? != 0; then
 805       have_python_config=failed
 806       if test "${with_python}" != auto; then
 807         AC_ERROR(failure running python-config --ldflags)
 808       fi
 809     fi
 810     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 811     if test $? != 0; then
 812       have_python_config=failed
 813       if test "${with_python}" != auto; then
 814         AC_ERROR(failure running python-config --exec-prefix)
 815       fi
 816     fi
 817   else
 818     # We do not have a python executable we can use to determine where
 819     # to find the Python headers and libs.  We cannot guess the include
 820     # path from the python_prefix either, because that include path
 821     # depends on the Python version.  So, there is nothing much we can
 822     # do except assume that the compiler will be able to find those files.
 823     python_includes=
 824     python_libs=
 825     have_python_config=no
 826   fi
 827
 828   # If we have python-config, only try the configuration it provides.
 829   # Otherwise fallback on the old way of trying different versions of
 830   # python in turn.
 831
 832   have_libpython=no
 833   if test "${have_python_config}" = yes; then
 834     # Determine the Python version by extracting "-lpython<version>"
 835     # part of the python_libs. <version> is usually X.Y with X and Y
 836     # being decimal numbers, but can also be XY (seen on Windows).
 837     #
 838     # The extraction is performed using sed with a regular expression.
 839     # Initially, the regexp used was using the '?' quantifier to make
 840     # the dot in the version number optional.  Unfortunately, this
 841     # does not work with non-GNU versions of sed because, because of
 842     # what looks like a limitation (the '?' quantifier does not work
 843     # with back-references).  We work around this limitation by using
 844     # the '*' quantifier instead.  It means that, in theory, we might
 845     # match unexpected version strings such as "-lpython2..7", but
 846     # this seems unlikely in practice.  And even if that happens,
 847     # an error will be triggered later on, when checking that version
 848     # number.
 849     python_version=`echo " ${python_libs} " \
 850                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 851     case "${python_version}" in
 852     python*)
 853       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 854                        ${python_includes}, ${python_libs})
 855       ;;
 856     *)
 857       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 858       ;;
 859     esac
 860   elif test "${have_python_config}" != failed; then
 861     if test "${have_libpython}" = no; then
 862       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 863                        ${python_includes}, "${python_libs} -lpython2.7")
 864     fi
 865     if test "${have_libpython}" = no; then
 866       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 867                        ${python_includes}, "${python_libs} -lpython2.6")
 868     fi
 869     if test ${have_libpython} = no; then
 870       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 871                        ${python_includes}, "${python_libs} -lpython2.5")
 872     fi
 873     if test ${have_libpython} = no; then
 874       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 875                        ${python_includes}, "${python_libs} -lpython2.4")
 876     fi
 877   fi
 878   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 879     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 880   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 881     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 882   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 883     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 884   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 885     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 886   fi
 887
 888   if test "${have_libpython}" = no; then
 889     case "${with_python}" in
 890     yes)
 891       AC_MSG_ERROR([python is missing or unusable])
 892       ;;
 893     auto)
 894       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 895       ;;
 896     *)
 897       AC_MSG_ERROR([no usable python found at ${with_python}])
 898       ;;
 899     esac
 900   else
 901     if test -n "${python_prefix}"; then
 902       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 903                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 904       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 905     fi
 906   fi
 907 fi
 908
 909 if test "${have_libpython}" != no; then
 910   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 911   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 912   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 913   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 914   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 915   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 916
 917   # Flags needed to compile Python code (taken from python-config --cflags).
 918   # We cannot call python-config directly because it will output whatever was
 919   # used when compiling the Python interpreter itself, including flags which
 920   # would make the python-related objects be compiled differently from the
 921   # rest of GDB (e.g., -O2 and -fPIC).
 922   if test "${GCC}" = yes; then
 923     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 924   fi
 925
 926   if test "x${tentative_python_cflags}" != x; then
 927     AC_MSG_CHECKING(compiler flags for python code)
 928     for flag in ${tentative_python_cflags}; do
 929       # Check that the compiler accepts it
 930       saved_CFLAGS="$CFLAGS"
 931       CFLAGS="$CFLAGS $flag"
 932       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 933       CFLAGS="$saved_CFLAGS"
 934     done
 935     AC_MSG_RESULT(${PYTHON_CFLAGS})
 936   fi
 937
 938   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
 939   #    #if _SGIAPI
 940   #    #define siginfo __siginfo
 941   #    #endif
 942   # The problem is that including Python causes some XOPEN macros to be
 943   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
 944   # to false.  So, we work around this issue by defining siginfo ourself
 945   # though the command-line.
 946   case "$gdb_host" in
 947     irix*) if test "${GCC}" = yes; then
 948              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
 949            fi
 950            ;;
 951   esac
 952 else
 953   # Even if Python support is not compiled in, we need to have these files
 954   # included.
 955   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
 956   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
 957         python/py-prettyprint.c python/py-auto-load.c"
 958 fi
 959 AC_SUBST(PYTHON_CFLAGS)
 960 AC_SUBST(PYTHON_CPPFLAGS)
 961 AC_SUBST(PYTHON_LIBS)
 962
 963 # ------------------------- #
 964 # Checks for header files.  #
 965 # ------------------------- #
 966
 967 AC_HEADER_DIRENT
 968 AC_HEADER_STAT
 969 AC_HEADER_STDC
 970 # elf_hp.h is for HP/UX 64-bit shared library support.
 971 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 972 # unconditionally, so what's the point in checking these?
 973 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 974                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 975                   stdlib.h string.h memory.h strings.h sys/fault.h \
 976                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 977                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 978                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 979                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 980                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 981 AC_CHECK_HEADERS(link.h, [], [],
 982 [#if HAVE_SYS_TYPES_H
 983 # include <sys/types.h>
 984 #endif
 985 #if HAVE_NLIST_H
 986 # include <nlist.h>
 987 #endif
 988 ])
 989 AC_CHECK_HEADERS(sys/proc.h, [], [],
 990 [#if HAVE_SYS_PARAM_H
 991 # include <sys/param.h>
 992 #endif
 993 ])
 994 AC_CHECK_HEADERS(sys/user.h, [], [],
 995 [#if HAVE_SYS_PARAM_H
 996 # include <sys/param.h>
 997 #endif
 998 ])
 999
1000 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1001 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1002 # think that we don't have <curses.h> if we're using GCC.
1003 case $host_os in
1004   solaris2.[[789]])
1005     if test "$GCC" = yes; then
1006       AC_DEFINE(_MSE_INT_H, 1,
1007         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1008    Solaris 2.[789] when using GCC. ])
1009     fi ;;
1010 esac
1011 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1012 AC_CHECK_HEADERS(term.h, [], [],
1013 [#if HAVE_CURSES_H
1014 # include <curses.h>
1015 #endif
1016 ])
1017
1018 # ------------------------- #
1019 # Checks for declarations.  #
1020 # ------------------------- #
1021
1022 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1023                 snprintf, vsnprintf])
1024 AM_LC_MESSAGES
1025
1026 # ----------------------- #
1027 # Checks for structures.  #
1028 # ----------------------- #
1029
1030 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1031
1032 # ------------------ #
1033 # Checks for types.  #
1034 # ------------------ #
1035
1036 AC_TYPE_SIGNAL
1037 AC_CHECK_TYPES(socklen_t, [], [],
1038 [#include <sys/types.h>
1039 #include <sys/socket.h>
1040 ])
1041
1042 # ------------------------------------- #
1043 # Checks for compiler characteristics.  #
1044 # ------------------------------------- #
1045
1046 AC_C_CONST
1047 AC_C_INLINE
1048 AC_C_BIGENDIAN
1049
1050 # ------------------------------ #
1051 # Checks for library functions.  #
1052 # ------------------------------ #
1053
1054 AC_FUNC_ALLOCA
1055 AC_FUNC_MMAP
1056 AC_FUNC_VFORK
1057 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
1058                 getgid pipe poll pread64 resize_term sbrk setpgid setpgrp setsid \
1059                 sigaction sigprocmask sigsetmask socketpair syscall \
1060                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1061                 setrlimit getrlimit posix_madvise waitpid])
1062 AM_LANGINFO_CODESET
1063
1064 # Check the return and argument types of ptrace.  No canned test for
1065 # this, so roll our own.
1066 gdb_ptrace_headers='
1067 #if HAVE_SYS_TYPES_H
1068 # include <sys/types.h>
1069 #endif
1070 #if HAVE_SYS_PTRACE_H
1071 # include <sys/ptrace.h>
1072 #endif
1073 #if HAVE_UNISTD_H
1074 # include <unistd.h>
1075 #endif
1076 '
1077 # There is no point in checking if we don't have a prototype.
1078 AC_CHECK_DECLS(ptrace, [], [
1079   : ${gdb_cv_func_ptrace_ret='int'}
1080   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1081 ], $gdb_ptrace_headers)
1082 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1083 # empty argument list, so check for that explicitly.
1084 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1085   AC_TRY_COMPILE($gdb_ptrace_headers,
1086     [extern long ptrace (enum __ptrace_request, ...);],
1087     gdb_cv_func_ptrace_ret='long',
1088     AC_TRY_COMPILE($gdb_ptrace_headers,
1089       [extern int ptrace ();],
1090       gdb_cv_func_ptrace_ret='int',
1091       gdb_cv_func_ptrace_ret='long')))
1092 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1093   [Define as the return type of ptrace.])
1094 # Check argument types.
1095 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1096   AC_TRY_COMPILE($gdb_ptrace_headers,
1097     [extern long ptrace (enum __ptrace_request, ...);],
1098     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1099 for gdb_arg1 in 'int' 'long'; do
1100  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1101   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1102    for gdb_arg4 in 'int' 'long'; do
1103      AC_TRY_COMPILE($gdb_ptrace_headers, [
1104 extern $gdb_cv_func_ptrace_ret
1105   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1106 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1107     break 4;])
1108     for gdb_arg5 in 'int *' 'int' 'long'; do
1109      AC_TRY_COMPILE($gdb_ptrace_headers, [
1110 extern $gdb_cv_func_ptrace_ret
1111   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1112 ], [
1113 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1114     break 5;])
1115     done
1116    done
1117   done
1118  done
1119 done
1120 # Provide a safe default value.
1121 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1122 ])])
1123 ac_save_IFS=$IFS; IFS=','
1124 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1125 IFS=$ac_save_IFS
1126 shift
1127 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1128   [Define to the type of arg 3 for ptrace.])
1129 if test -n "$[5]"; then
1130   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1131     [Define to the type of arg 5 for ptrace.])
1132 fi
1133
1134 dnl AC_FUNC_SETPGRP does not work when cross compiling
1135 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1136 if test "$cross_compiling" = no; then
1137   AC_FUNC_SETPGRP
1138 else
1139   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1140     [AC_TRY_COMPILE([
1141 #include <unistd.h>
1142 ], [
1143   if (setpgrp(1,1) == -1)
1144     exit (0);
1145   else
1146     exit (1);
1147 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1148 if test $ac_cv_func_setpgrp_void = yes; then
1149   AC_DEFINE(SETPGRP_VOID, 1)
1150 fi
1151 fi
1152
1153 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1154 # since sigsetjmp might only be defined as a macro.
1155 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1156 [AC_TRY_COMPILE([
1157 #include <setjmp.h>
1158 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1159 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1160 if test $gdb_cv_func_sigsetjmp = yes; then
1161   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1162 fi
1163
1164 # Assume we'll default to using the included libiberty regex.
1165 gdb_use_included_regex=yes
1166
1167 # However, if the system regex is GNU regex, then default to *not*
1168 # using the included regex.
1169 AC_CACHE_CHECK(
1170   [for GNU regex],
1171   [gdb_cv_have_gnu_regex],
1172   [AC_TRY_COMPILE(
1173     [#include <gnu-versions.h>],
1174     [#define REGEX_INTERFACE_VERSION 1
1175 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1176 # error "Version mismatch"
1177 #endif],
1178     gdb_cv_have_gnu_regex=yes,
1179     gdb_cv_have_gnu_regex=no)])
1180 if test $gdb_cv_have_gnu_regex = yes; then
1181   gdb_use_included_regex=no
1182 fi
1183
1184 AC_ARG_WITH(included-regex,
1185   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1186   gdb_with_regex=$withval,
1187   gdb_with_regex=$gdb_use_included_regex)
1188 if test "$gdb_with_regex" = yes; then
1189   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1190     [Define to 1 if the regex included in libiberty should be used.])
1191 fi
1192
1193 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1194 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1195 [#include <sys/param.h>
1196 #include <sys/proc.h>
1197 ])
1198
1199 # See if <sys/lwp.h> defines `struct lwp`.
1200 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1201 [AC_TRY_COMPILE([#include <sys/param.h>
1202 #include <sys/lwp.h>], [struct lwp l;],
1203 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1204 if test $gdb_cv_struct_lwp = yes; then
1205   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1206             [Define to 1 if your system has struct lwp.])
1207 fi
1208
1209 # See if <machine/reg.h> degines `struct reg'.
1210 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1211 [AC_TRY_COMPILE([#include <sys/types.h>
1212 #include <machine/reg.h>], [struct reg r;],
1213 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1214 if test $gdb_cv_struct_reg = yes; then
1215   AC_DEFINE(HAVE_STRUCT_REG, 1,
1216             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1217 fi
1218
1219 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1220 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1221 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1222                  [#include <machine/reg.h>])
1223
1224 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1225 AC_MSG_CHECKING(for PTRACE_GETREGS)
1226 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1227 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1228                 [PTRACE_GETREGS;],
1229                 [gdb_cv_have_ptrace_getregs=yes],
1230                 [gdb_cv_have_ptrace_getregs=no])])
1231 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1232 if test $gdb_cv_have_ptrace_getregs = yes; then
1233   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1234   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1235 fi
1236
1237 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1238 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1239 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1240 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1241                 [PTRACE_GETFPXREGS;],
1242                 [gdb_cv_have_ptrace_getfpxregs=yes],
1243                 [gdb_cv_have_ptrace_getfpxregs=no])])
1244 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1245 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1246   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1247   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1248 fi
1249
1250 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1251 AC_MSG_CHECKING(for PT_GETDBREGS)
1252 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1253 [AC_TRY_COMPILE([#include <sys/types.h>
1254 #include <sys/ptrace.h>],
1255                 [PT_GETDBREGS;],
1256                 [gdb_cv_have_pt_getdbregs=yes],
1257                 [gdb_cv_have_pt_getdbregs=no])])
1258 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1259 if test $gdb_cv_have_pt_getdbregs = yes; then
1260   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1261   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1262 fi
1263
1264 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1265 AC_MSG_CHECKING(for PT_GETXMMREGS)
1266 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1267 [AC_TRY_COMPILE([#include <sys/types.h>
1268 #include <sys/ptrace.h>],
1269                 [PT_GETXMMREGS;],
1270                 [gdb_cv_have_pt_getxmmregs=yes],
1271                 [gdb_cv_have_pt_getxmmregs=no])])
1272 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1273 if test $gdb_cv_have_pt_getxmmregs = yes; then
1274   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1275   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1276 fi
1277
1278 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1279
1280 if test "${target}" = "${host}"; then
1281   case "${host}" in
1282   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1283       AC_DEFINE(NEW_PROC_API, 1,
1284       [Define if you want to use new multi-fd /proc interface
1285        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1286       ;;
1287   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1288       AC_DEFINE(NEW_PROC_API, 1,
1289       [Define if you want to use new multi-fd /proc interface
1290        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1291       ;;
1292   mips-sgi-irix5*)
1293       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1294       AC_DEFINE([_KMEMUSER], 1,
1295       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1296        around a <sys/proc.h> problem on IRIX 5.])
1297       ;;
1298   esac
1299 fi
1300
1301 if test "$ac_cv_header_sys_procfs_h" = yes; then
1302   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1303   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1304   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1305   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1306   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1307   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1308   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1309   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1310   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1311   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1312   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1313   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1314   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1315   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1316
1317
1318   dnl Check for broken prfpregset_t type
1319
1320   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1321   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1322   dnl instead of the struct itself).  We detect this here, and work
1323   dnl around it in gdb_proc_service.h.
1324
1325   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1326     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1327     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1328       [AC_TRY_RUN([#include <sys/procfs.h>
1329        int main ()
1330        {
1331          if (sizeof (prfpregset_t) == sizeof (void *))
1332            return 1;
1333          return 0;
1334        }],
1335        gdb_cv_prfpregset_t_broken=no,
1336        gdb_cv_prfpregset_t_broken=yes,
1337        gdb_cv_prfpregset_t_broken=yes)])
1338     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1339     if test $gdb_cv_prfpregset_t_broken = yes; then
1340       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1341       [Define if the prfpregset_t type is broken.])
1342     fi
1343   fi
1344
1345   dnl Check for PIOCSET ioctl entry
1346
1347   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1348   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1349   [AC_TRY_COMPILE([#include <unistd.h>
1350 #include <sys/types.h>
1351 #include <sys/procfs.h>
1352 ], [
1353     int dummy;;
1354     dummy = ioctl(0, PIOCSET, &dummy);
1355   ],
1356   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1357   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1358   if test $gdb_cv_have_procfs_piocset = yes; then
1359     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1360     [Define if ioctl argument PIOCSET is available.])
1361   fi
1362 fi
1363
1364 dnl For native ports (host == target), check to see what kind of
1365 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1366 if test ${host} = ${target} ; then
1367   dnl Check for struct link_map with l_ members which are indicative
1368   dnl of SVR4-like shared libraries
1369
1370   AC_MSG_CHECKING(for member l_addr in struct link_map)
1371   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1372     [AC_TRY_COMPILE([#include <link.h>],
1373                     [struct link_map lm; (void) lm.l_addr;],
1374                     gdb_cv_have_struct_link_map_with_l_members=yes,
1375                     gdb_cv_have_struct_link_map_with_l_members=no)])
1376   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1377   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1378     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1379     [Define if <link.h> exists and defines struct link_map which has
1380      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1381      SVR4-like systems.)])
1382   fi
1383
1384   dnl Check for struct link_map with lm_ members which are indicative
1385   dnl of SunOS-like shared libraries
1386
1387   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1388   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1389     [AC_TRY_COMPILE([#include <sys/types.h>
1390 #include <link.h>],
1391                     [struct link_map lm; (void) lm.lm_addr;],
1392                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1393                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1394   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1395   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1396     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1397     [Define if <link.h> exists and defines struct link_map which has
1398      members with an ``lm_'' prefix.  (For SunOS.)])
1399   fi
1400
1401   dnl Check for struct so_map with som_ members which are found on
1402   dnl some *BSD systems.
1403
1404   AC_MSG_CHECKING(for member som_addr in struct so_map)
1405   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1406     [AC_TRY_COMPILE([#include <sys/types.h>
1407 #ifdef HAVE_NLIST_H
1408 #include <nlist.h>
1409 #endif
1410 #include <link.h>],
1411                     [struct so_map lm; (void) lm.som_addr;],
1412                     gdb_cv_have_struct_so_map_with_som_members=yes,
1413                     gdb_cv_have_struct_so_map_with_som_members=no)])
1414   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1415   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1416     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1417     [Define if <link.h> exists and defines a struct so_map which has
1418      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1419   fi
1420
1421   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1422   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1423
1424   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1425   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1426     [AC_TRY_COMPILE([#define _SYSCALL32
1427 #include <sys/link.h>], [struct link_map32 l;],
1428      gdb_cv_have_struct_link_map32=yes,
1429      gdb_cv_have_struct_link_map32=no)])
1430   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1431   if test $gdb_cv_have_struct_link_map32 = yes; then
1432     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1433     [Define if <sys/link.h> has struct link_map32])
1434     AC_DEFINE(_SYSCALL32, 1,
1435     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1436   fi
1437 fi
1438
1439 # Check if the compiler supports the `long long' type.
1440
1441 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1442                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1443 [[extern long long foo;]],
1444 [[switch (foo & 2) { case 0: return 1; }]])],
1445                                   gdb_cv_c_long_long=yes,
1446                                   gdb_cv_c_long_long=no)])
1447 if test $gdb_cv_c_long_long = yes; then
1448   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1449             [Define to 1 if the compiler supports long long.])
1450 fi
1451
1452 # Check if the compiler and runtime support printing long longs.
1453
1454 AC_CACHE_CHECK([for long long support in printf],
1455                gdb_cv_printf_has_long_long,
1456                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1457 [[char buf[32];
1458   long long l = 0;
1459   l = (l << 16) + 0x0123;
1460   l = (l << 16) + 0x4567;
1461   l = (l << 16) + 0x89ab;
1462   l = (l << 16) + 0xcdef;
1463   sprintf (buf, "0x%016llx", l);
1464   return (strcmp ("0x0123456789abcdef", buf));]])],
1465                               gdb_cv_printf_has_long_long=yes,
1466                               gdb_cv_printf_has_long_long=no,
1467                               gdb_cv_printf_has_long_long=no)])
1468 if test $gdb_cv_printf_has_long_long = yes; then
1469   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1470             [Define to 1 if the "%ll" format works to print long longs.])
1471 fi
1472
1473 # Check if the compiler and runtime support printing decfloats.
1474
1475 AC_CACHE_CHECK([for decfloat support in printf],
1476                gdb_cv_printf_has_decfloat,
1477                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1478 [[char buf[64];
1479   _Decimal32 d32 = 1.2345df;
1480   _Decimal64 d64 = 1.2345dd;
1481   _Decimal128 d128 = 1.2345dl;
1482   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1483   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1484                               gdb_cv_printf_has_decfloat=yes,
1485                               gdb_cv_printf_has_decfloat=no,
1486                               gdb_cv_printf_has_decfloat=no)])
1487 if test $gdb_cv_printf_has_decfloat = yes; then
1488   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1489             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1490 fi
1491
1492 # Check if the compiler supports the `long double' type.  We can't use
1493 # AC_C_LONG_DOUBLE because that one does additional checks on the
1494 # constants defined in <float.h> that fail on some systems,
1495 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1496
1497 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1498                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1499                                   gdb_cv_c_long_double=yes,
1500                                   gdb_cv_c_long_double=no)])
1501 if test $gdb_cv_c_long_double = yes; then
1502   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1503            [Define to 1 if the compiler supports long double.])
1504 fi
1505
1506 # Check if the compiler and runtime support printing long doubles.
1507
1508 AC_CACHE_CHECK([for long double support in printf],
1509                gdb_cv_printf_has_long_double,
1510                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1511 [[char buf[16];
1512   long double f = 3.141592653;
1513   sprintf (buf, "%Lg", f);
1514   return (strncmp ("3.14159", buf, 7));]])],
1515                               gdb_cv_printf_has_long_double=yes,
1516                               gdb_cv_printf_has_long_double=no,
1517                               gdb_cv_printf_has_long_double=no)])
1518 if test $gdb_cv_printf_has_long_double = yes; then
1519   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1520             [Define to 1 if the "%Lg" format works to print long doubles.])
1521 fi
1522
1523 # Check if the compiler and runtime support scanning long doubles.
1524
1525 AC_CACHE_CHECK([for long double support in scanf],
1526                gdb_cv_scanf_has_long_double,
1527                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1528 [[#include <stdio.h>]],
1529 [[char *buf = "3.141592653";
1530   long double f = 0;
1531   sscanf (buf, "%Lg", &f);
1532   return !(f > 3.14159 && f < 3.14160);]])],
1533                               gdb_cv_scanf_has_long_double=yes,
1534                               gdb_cv_scanf_has_long_double=no,
1535                               gdb_cv_scanf_has_long_double=no)])
1536 if test $gdb_cv_scanf_has_long_double = yes; then
1537   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1538             [Define to 1 if the "%Lg" format works to scan long doubles.])
1539 fi
1540
1541 case ${host_os} in
1542 aix*)
1543   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1544     SAVE_LDFLAGS=$LDFLAGS
1545
1546     case $GCC in
1547     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1548     *) gdb_cv_bigtoc=-bbigtoc ;;
1549     esac
1550
1551     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1552     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1553     LDFLAGS="${SAVE_LDFLAGS}"
1554   ])
1555   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1556   ;;
1557 esac
1558
1559 AC_MSG_CHECKING(for the dynamic export flag)
1560 dynamic_list=false
1561 if test "${gdb_native}" = yes; then
1562    # The dynamically loaded libthread_db needs access to symbols in the gdb
1563    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1564    # may not be supported there.
1565    old_LDFLAGS="$LDFLAGS"
1566    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1567    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1568    LDFLAGS="$LDFLAGS $RDYNAMIC"
1569    if test "${have_libpython}" = no; then
1570      AC_TRY_LINK([], [], [dynamic_list=true])
1571    else
1572      # Workaround http://bugs.python.org/issue4434 where static
1573      # libpythonX.Y.a would get its symbols required for
1574      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1575      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1576      old_CFLAGS="$CFLAGS"
1577      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1578      AC_RUN_IFELSE(
1579        AC_LANG_PROGRAM(
1580          [#include "]${have_libpython}[/Python.h"],
1581          [int err;
1582           Py_Initialize ();
1583           err = PyRun_SimpleString ("import itertools\n");
1584           Py_Finalize ();
1585           return err == 0 ? 0 : 1;]),
1586        [dynamic_list=true], [], [true])
1587      CFLAGS="$old_CFLAGS"
1588    fi
1589    LDFLAGS="$old_LDFLAGS"
1590 fi
1591 if $dynamic_list; then
1592   found="-Wl,--dynamic-list"
1593   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1594 else
1595   found="-rdynamic"
1596   RDYNAMIC="-rdynamic"
1597 fi
1598 AC_SUBST(RDYNAMIC)
1599 AC_MSG_RESULT($found)
1600
1601 dnl For certain native configurations, we need to check whether thread
1602 dnl support can be built in or not.
1603 dnl
1604 dnl Note that we only want this if we are both native (host == target),
1605 dnl and not doing a canadian cross build (build == host).
1606
1607 if test ${build} = ${host} -a ${host} = ${target} ; then
1608    case ${host_os} in
1609    solaris*)
1610       # See if thread_db library is around for Solaris thread debugging.
1611       # Note that we must explicitly test for version 1 of the library
1612       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1613       # the same API.
1614       AC_MSG_CHECKING(for Solaris thread debugging library)
1615       if test -f /usr/lib/libthread_db.so.1 ; then
1616          AC_MSG_RESULT(yes)
1617          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1618          [Define if using Solaris thread debugging.])
1619          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1620          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1621          AC_CHECK_LIB(dl, dlopen)
1622          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1623          # Sun randomly tweaked the prototypes in <proc_service.h>
1624          # at one point.
1625          AC_MSG_CHECKING(if <proc_service.h> is old)
1626          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1627             AC_TRY_COMPILE([
1628                 #include <proc_service.h>
1629                 ps_err_e ps_pdwrite
1630                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1631             ],, gdb_cv_proc_service_is_old=no,
1632                 gdb_cv_proc_service_is_old=yes)
1633          ])
1634          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1635          if test $gdb_cv_proc_service_is_old = yes; then
1636             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1637             [Define if <proc_service.h> on solaris uses int instead of
1638              size_t, and assorted other type changes.])
1639          fi
1640       else
1641          AC_MSG_RESULT(no)
1642       fi
1643       ;;
1644    aix*)
1645       AC_MSG_CHECKING(for AiX thread debugging library)
1646       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1647                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1648                                    [#ifndef PTHDB_VERSION_3
1649                                     #error
1650                                     #endif],
1651                                    gdb_cv_have_aix_thread_debug=yes,
1652                                    gdb_cv_have_aix_thread_debug=no)])
1653       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1654       if test $gdb_cv_have_aix_thread_debug = yes; then
1655          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1656          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1657          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1658
1659          # Older versions of AIX do not provide the declaration for
1660          # the getthrds function (it appears that it was introduced
1661          # with AIX 6.x).
1662          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1663       fi
1664       ;;
1665    esac
1666    AC_SUBST(CONFIG_LDFLAGS)
1667 fi
1668
1669 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1670 dnl other error codes.
1671 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1672    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1673                   gdb_cv_thread_db_h_has_td_notalloc,
1674      AC_TRY_COMPILE(
1675        [#include <thread_db.h>],
1676        [int i = TD_NOTALLOC;],
1677        gdb_cv_thread_db_h_has_td_notalloc=yes,
1678        gdb_cv_thread_db_h_has_td_notalloc=no
1679      )
1680    )
1681    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1682                   gdb_cv_thread_db_h_has_td_version,
1683      AC_TRY_COMPILE(
1684        [#include <thread_db.h>],
1685        [int i = TD_VERSION;],
1686        gdb_cv_thread_db_h_has_td_version=yes,
1687        gdb_cv_thread_db_h_has_td_version=no
1688      )
1689    )
1690    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1691                   gdb_cv_thread_db_h_has_td_notls,
1692      AC_TRY_COMPILE(
1693        [#include <thread_db.h>],
1694        [int i = TD_NOTLS;],
1695        gdb_cv_thread_db_h_has_td_notls=yes,
1696        gdb_cv_thread_db_h_has_td_notls=no
1697      )
1698    )
1699 fi
1700 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1701   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1702             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1703 fi
1704 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1705   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1706             [Define if <thread_db.h> has the TD_VERSION error code.])
1707 fi
1708 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1709   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1710             [Define if <thread_db.h> has the TD_NOTLS error code.])
1711 fi
1712
1713 dnl See if we have a sys/syscall header file that has __NR_tkill.
1714 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1715    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1716                   gdb_cv_sys_syscall_h_has_tkill,
1717      AC_TRY_COMPILE(
1718        [#include <sys/syscall.h>],
1719        [int i = __NR_tkill;],
1720        gdb_cv_sys_syscall_h_has_tkill=yes,
1721        gdb_cv_sys_syscall_h_has_tkill=no
1722      )
1723    )
1724 fi
1725 dnl See if we can issue tkill syscall.
1726 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1727   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1728 fi
1729
1730 dnl Check if we can disable the virtual address space randomization.
1731 dnl The functionality of setarch -R.
1732 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1733 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1734 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1735 #       define ADDR_NO_RANDOMIZE 0x0040000
1736 #      endif
1737        /* Test the flag could be set and stays set.  */
1738        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1739        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1740            return 1])])
1741 AC_RUN_IFELSE([PERSONALITY_TEST],
1742               [have_personality=true],
1743               [have_personality=false],
1744               [AC_LINK_IFELSE([PERSONALITY_TEST],
1745                               [have_personality=true],
1746                               [have_personality=false])])
1747 if $have_personality
1748 then
1749     AC_DEFINE([HAVE_PERSONALITY], 1,
1750               [Define if you support the personality syscall.])
1751 fi
1752
1753 dnl Handle optional features that can be enabled.
1754
1755 target_sysroot_reloc=0
1756 AC_ARG_WITH(sysroot,
1757 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1758 [
1759  case ${with_sysroot} in
1760  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1761  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1762  esac
1763
1764  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1765
1766  if test "x$prefix" = xNONE; then
1767   test_prefix=/usr/local
1768  else
1769   test_prefix=$prefix
1770  fi
1771  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1772   test_exec_prefix=$test_prefix
1773  else
1774   test_exec_prefix=$exec_prefix
1775  fi
1776  case ${TARGET_SYSTEM_ROOT} in
1777  "${test_prefix}"|"${test_prefix}/"*|\
1778  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1779  '${prefix}'|'${prefix}/'*|\
1780  '${exec_prefix}'|'${exec_prefix}/'*)
1781    target_sysroot_reloc=1
1782    ;;
1783  esac
1784 ], [
1785  TARGET_SYSTEM_ROOT=
1786  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1787 ])
1788 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1789 AC_SUBST(TARGET_SYSTEM_ROOT)
1790 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1791
1792 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1793     [automatically load a system-wide gdbinit file],
1794     [])
1795
1796 AC_ARG_ENABLE(werror,
1797   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1798   [case "${enableval}" in
1799      yes | y) ERROR_ON_WARNING="yes" ;;
1800      no | n)  ERROR_ON_WARNING="no" ;;
1801      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1802    esac])
1803
1804 # Enable -Werror by default when using gcc
1805 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1806     ERROR_ON_WARNING=yes
1807 fi
1808
1809 WERROR_CFLAGS=""
1810 if test "${ERROR_ON_WARNING}" = yes ; then
1811     WERROR_CFLAGS="-Werror"
1812 fi
1813
1814 # The entries after -Wno-pointer-sign are disabled warnings which may
1815 # be enabled in the future, which can not currently be used to build
1816 # GDB.
1817 # NOTE: If you change this list, remember to update
1818 # gdb/doc/gdbint.texinfo.
1819 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1820 -Wformat-nonliteral -Wno-pointer-sign \
1821 -Wno-unused -Wunused-value -Wunused-function \
1822 -Wno-switch -Wno-char-subscripts"
1823
1824 # Enable -Wno-format by default when using gcc on mingw since many
1825 # GCC versions complain about %I64.
1826 case "${host}" in
1827   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1828 esac
1829
1830 AC_ARG_ENABLE(build-warnings,
1831 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1832 [case "${enableval}" in
1833   yes)  ;;
1834   no)   build_warnings="-w";;
1835   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1836         build_warnings="${build_warnings} ${t}";;
1837   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1838         build_warnings="${t} ${build_warnings}";;
1839   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1840 esac
1841 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1842   echo "Setting compiler warning flags = $build_warnings" 6>&1
1843 fi])dnl
1844 AC_ARG_ENABLE(gdb-build-warnings,
1845 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1846 [case "${enableval}" in
1847   yes)  ;;
1848   no)   build_warnings="-w";;
1849   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1850         build_warnings="${build_warnings} ${t}";;
1851   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1852         build_warnings="${t} ${build_warnings}";;
1853   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1854 esac
1855 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1856   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1857 fi])dnl
1858 WARN_CFLAGS=""
1859 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1860 then
1861     AC_MSG_CHECKING(compiler warning flags)
1862     # Separate out the -Werror flag as some files just cannot be
1863     # compiled with it enabled.
1864     for w in ${build_warnings}; do
1865         case $w in
1866         -Werr*) WERROR_CFLAGS=-Werror ;;
1867         *) # Check that GCC accepts it
1868             saved_CFLAGS="$CFLAGS"
1869             CFLAGS="$CFLAGS $w"
1870             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1871             CFLAGS="$saved_CFLAGS"
1872         esac
1873     done
1874     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1875 fi
1876 AC_SUBST(WARN_CFLAGS)
1877 AC_SUBST(WERROR_CFLAGS)
1878
1879 # In the Cygwin environment, we need some additional flags.
1880 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1881 [AC_EGREP_CPP(lose, [
1882 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1883 lose
1884 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1885
1886
1887 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1888 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1889 case ${host} in
1890   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1891   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1892   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1893 esac
1894 AC_SUBST(SER_HARDWIRE)
1895
1896 # libreadline needs libuser32.a in a cygwin environment
1897 WIN32LIBS=
1898 if test x$gdb_cv_os_cygwin = xyes; then
1899     WIN32LIBS="-luser32"
1900     case "${target}" in
1901         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1902         ;;
1903     esac
1904 fi
1905
1906 # The ser-tcp.c module requires sockets.
1907 case ${host} in
1908   *mingw32*)
1909     AC_DEFINE(USE_WIN32API, 1,
1910               [Define if we should use the Windows API, instead of the
1911                POSIX API.  On Windows, we use the Windows API when
1912                building for MinGW, but the POSIX API when building
1913                for Cygwin.])
1914     WIN32LIBS="$WIN32LIBS -lws2_32"
1915     ;;
1916 esac
1917 AC_SUBST(WIN32LIBS)
1918
1919 # Add ELF support to GDB, but only if BFD includes ELF support.
1920 OLD_CFLAGS=$CFLAGS
1921 OLD_LDFLAGS=$LDFLAGS
1922 OLD_LIBS=$LIBS
1923 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1924 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1925 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1926 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1927 if test "$plugins" = "yes"; then
1928   LIBS="-ldl $LIBS"
1929 fi
1930 LIBS="-lbfd -liberty $intl $LIBS"
1931 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1932 [AC_TRY_LINK(
1933 [#include <stdlib.h>
1934 #include "bfd.h"
1935 #include "elf-bfd.h"
1936 ],
1937 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1938 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1939 if test $gdb_cv_var_elf = yes; then
1940   CONFIG_OBS="$CONFIG_OBS elfread.o"
1941   AC_DEFINE(HAVE_ELF, 1,
1942             [Define if ELF support should be included.])
1943   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1944   if test "$plugins" = "yes"; then
1945     OLD_LIBS="-ldl $OLD_LIBS"
1946   fi
1947 fi
1948 CFLAGS=$OLD_CFLAGS
1949 LDFLAGS=$OLD_LDFLAGS
1950 LIBS=$OLD_LIBS
1951
1952 # Add any host-specific objects to GDB.
1953 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1954
1955 LIBGUI="../libgui/src/libgui.a"
1956 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1957 AC_SUBST(LIBGUI)
1958 AC_SUBST(GUI_CFLAGS_X)
1959
1960 WIN32LDAPP=
1961 AC_SUBST(WIN32LIBS)
1962 AC_SUBST(WIN32LDAPP)
1963
1964 case "${host}" in
1965 *-*-cygwin* | *-*-mingw* )
1966     configdir="win"
1967     ;;
1968 *)
1969     configdir="unix"
1970     ;;
1971 esac
1972
1973 GDBTKLIBS=
1974 if test "${enable_gdbtk}" = "yes"; then
1975
1976     # Gdbtk must have an absolute path to srcdir in order to run
1977     # properly when not installed.
1978     here=`pwd`
1979     cd ${srcdir}
1980     GDBTK_SRC_DIR=`pwd`
1981     cd $here
1982
1983     SC_PATH_TCLCONFIG
1984
1985     # If $no_tk is nonempty, then we can't do Tk, and there is no
1986     # point to doing Tcl.
1987     SC_PATH_TKCONFIG
1988
1989     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1990         SC_LOAD_TCLCONFIG
1991
1992         # Check for in-tree tcl
1993         here=`pwd`
1994         cd ${srcdir}/..
1995         topdir=`pwd`
1996         cd ${here}
1997
1998         intree="no"
1999         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2000           intree="yes"
2001         fi
2002
2003         # Find Tcl private headers
2004         if test x"${intree}" = xno; then
2005           CY_AC_TCL_PRIVATE_HEADERS
2006           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2007           TCL_LIBRARY="${TCL_LIB_SPEC}"
2008           TCL_DEPS=""
2009         else
2010           # If building tcl in the same src tree, private headers
2011           # are not needed, but we need to be sure to use the right
2012           # headers library
2013           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2014           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2015           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2016         fi
2017         AC_SUBST(TCL_INCLUDE)
2018         AC_SUBST(TCL_LIBRARY)
2019         AC_SUBST(TCL_DEPS)
2020
2021         SC_LOAD_TKCONFIG
2022
2023         # Check for in-tree Tk
2024         intree="no"
2025         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2026           intree="yes"
2027         fi
2028
2029         # Find Tk private headers
2030         if test x"${intree}" = xno; then
2031           CY_AC_TK_PRIVATE_HEADERS
2032           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2033           TK_LIBRARY=${TK_LIB_SPEC}
2034           TK_DEPS=""
2035         else
2036           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2037           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2038           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2039         fi
2040         AC_SUBST(TK_INCLUDE)
2041         AC_SUBST(TK_LIBRARY)
2042         AC_SUBST(TK_DEPS)
2043         AC_SUBST(TK_XINCLUDES)
2044
2045         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2046
2047         # Include some libraries that Tcl and Tk want.
2048         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2049         # Yes, the ordering seems wrong here.  But it isn't.
2050         # TK_LIBS is the list of libraries that need to be linked
2051         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2052         # were in LIBS then any link tests after this point would
2053         # try to include things like `$(LIBGUI)', which wouldn't work.
2054         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2055
2056         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2057         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2058         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2059         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2060         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2061         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2062         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2063
2064         if test x$gdb_cv_os_cygwin = xyes; then
2065           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2066           WIN32LDAPP="-Wl,--subsystem,console"
2067           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2068         fi
2069
2070         AC_CONFIG_SUBDIRS(gdbtk)
2071     fi
2072 fi
2073
2074 AC_SUBST(X_CFLAGS)
2075 AC_SUBST(X_LDFLAGS)
2076 AC_SUBST(X_LIBS)
2077 AC_SUBST(GDBTKLIBS)
2078 AC_SUBST(GDBTK_CFLAGS)
2079 AC_SUBST(GDBTK_SRC_DIR)
2080
2081 AC_PATH_X
2082
2083 # Unlike the sim directory, whether a simulator is linked is controlled by
2084 # presence of a gdb_sim definition in the target configure.tgt entry.
2085 # This code just checks for a few cases where we'd like to ignore those
2086 # definitions, even when they're present in the '.mt' file.  These cases
2087 # are when --disable-sim is specified, or if the simulator directory is
2088 # not part of the source tree.
2089 #
2090 AC_ARG_ENABLE(sim,
2091 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2092 [echo "enable_sim = $enable_sim";
2093  echo "enableval = ${enableval}";
2094  case "${enableval}" in
2095   yes) ignore_sim=false ;;
2096   no)  ignore_sim=true ;;
2097   *)   ignore_sim=false ;;
2098  esac],
2099 [ignore_sim=false])
2100
2101 if test ! -d "${srcdir}/../sim"; then
2102   ignore_sim=true
2103 fi
2104
2105 SIM=
2106 SIM_OBS=
2107 if test "${ignore_sim}" = "false"; then
2108   if test x"${gdb_sim}" != x ; then
2109     SIM="${gdb_sim}"
2110     SIM_OBS="remote-sim.o"
2111     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2112   fi
2113 fi
2114 AC_SUBST(SIM)
2115 AC_SUBST(SIM_OBS)
2116
2117 AC_SUBST(ENABLE_CFLAGS)
2118 AC_SUBST(PROFILE_CFLAGS)
2119
2120 AC_SUBST(CONFIG_OBS)
2121 AC_SUBST(CONFIG_DEPS)
2122 AC_SUBST(CONFIG_SRCS)
2123 AC_SUBST(CONFIG_ALL)
2124 AC_SUBST(CONFIG_CLEAN)
2125 AC_SUBST(CONFIG_INSTALL)
2126 AC_SUBST(CONFIG_UNINSTALL)
2127
2128 # List of host floatformats.
2129 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2130 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2131 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2132
2133 # target_subdir is used by the testsuite to find the target libraries.
2134 target_subdir=
2135 if test "${host}" != "${target}"; then
2136     target_subdir="${target_alias}/"
2137 fi
2138 AC_SUBST(target_subdir)
2139
2140 frags=
2141 if test "${gdb_native}" = "yes"; then
2142   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2143   if test ! -f ${host_makefile_frag}; then
2144     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2145   fi
2146   frags="$frags $host_makefile_frag"
2147 else
2148   host_makefile_frag=/dev/null
2149 fi
2150
2151 AC_SUBST_FILE(host_makefile_frag)
2152 AC_SUBST(frags)
2153
2154 changequote(,)dnl
2155 if test "${gdb_native}" = "yes"; then
2156 # We pick this up from the host configuration file (.mh) because we
2157 # do not have a native configuration Makefile fragment.
2158 nativefile=`sed -n '
2159 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2160 ' ${host_makefile_frag}`
2161 fi
2162 changequote([,])
2163
2164 if test x"${gdb_osabi}" != x ; then
2165     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2166                        [Define to the default OS ABI for this configuration.])
2167 fi
2168
2169 # Enable multi-ice-gdb-server.
2170 AC_ARG_ENABLE(multi-ice,
2171 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2172   [case $enableval in
2173     yes | no)
2174       ;;
2175     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2176   esac])
2177 if test "x$enable_multi_ice" = xyes; then
2178    AC_CONFIG_SUBDIRS(multi-ice)
2179 fi
2180
2181 AC_ARG_ENABLE(gdbserver,
2182 AS_HELP_STRING([--enable-gdbserver],
2183                [automatically build gdbserver (yes/no/auto, default is auto)]),
2184 [case "${enableval}" in
2185   yes| no|auto) ;;
2186   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2187 esac],[enable_gdbserver=auto])
2188
2189 # We only build gdbserver automatically in a native configuration, and
2190 # only if the user did not explicitly disable its build.
2191 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2192   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2193   if test "x$build_gdbserver" = xyes; then
2194     AC_MSG_RESULT(yes)
2195     AC_CONFIG_SUBDIRS(gdbserver)
2196     gdbserver_build_enabled=yes
2197   else
2198     AC_MSG_RESULT(no)
2199   fi
2200 fi
2201
2202 # If the user explicitly request the gdbserver to be built, verify that
2203 # we were in fact able to enable it.
2204 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2205   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2206 fi
2207
2208 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2209 # to an empty version.
2210
2211 files=
2212 links=
2213
2214 rm -f nm.h
2215 if test "${nativefile}" != ""; then
2216     case "${nativefile}" in
2217       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2218       * ) GDB_NM_FILE="${nativefile}"
2219     esac
2220     files="${files} ${GDB_NM_FILE}"
2221     links="${links} nm.h"
2222     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2223 fi
2224 AC_SUBST(GDB_NM_FILE)
2225
2226 AC_LINK_FILES($files, $links)
2227
2228 dnl Check for exe extension set on certain hosts (e.g. Win32)
2229 AC_EXEEXT
2230
2231 dnl  Detect the character set used by this host.
2232 dnl  At the moment, we just assume it's UTF-8.
2233 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2234           [Define to be a string naming the default host character set.])
2235
2236 AC_OUTPUT(Makefile .gdbinit:gdbinit.in doc/Makefile gnulib/Makefile data-directory/Makefile,
2237 [
2238 case x$CONFIG_HEADERS in
2239 xconfig.h:config.in)
2240 echo > stamp-h ;;
2241 esac
2242 ])
2243
2244 exit 0