gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Provide more thorough testing by -lmcheck.
  27 # Set it to 'true' for development snapshots, 'false' for releases or
  28 # pre-releases.
  29 development=true
  30
  31 AC_PROG_CC
  32 AC_USE_SYSTEM_EXTENSIONS
  33 ACX_LARGEFILE
  34 AM_PROG_CC_STDC
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # Dependency checking.
  41 ZW_CREATE_DEPDIR
  42 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  43
  44 # Check for the 'make' the user wants to use.
  45 AC_CHECK_PROGS(MAKE, make)
  46 MAKE_IS_GNU=
  47 case "`$MAKE --version 2>&1 | sed 1q`" in
  48   *GNU*)
  49     MAKE_IS_GNU=yes
  50     ;;
  51 esac
  52 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  53 AC_PROG_MAKE_SET
  54
  55 # Configure gnulib.  We need to build gnulib under some other
  56 # directory not "gnulib", to avoid the problem of both GDB and
  57 # GDBserver wanting to build it in the same directory, when building
  58 # in the source dir.
  59 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"])
  60
  61 dnl List of object files and targets accumulated by configure.
  62
  63 CONFIG_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 ENABLE_CFLAGS=
  67
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 dnl Set up for gettext.
  74 ZW_GNU_GETTEXT_SISTER_DIR
  75
  76 localedir='${datadir}/locale'
  77 AC_SUBST(localedir)
  78
  79 if test x"$USE_NLS" = xyes; then
  80    CONFIG_ALL="$CONFIG_ALL all-po"
  81    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  82    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  83    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  84 fi
  85
  86 GNULIB=build-gnulib/import
  87
  88 # For Makefile dependencies.
  89 GNULIB_STDINT_H=
  90 if test x"$STDINT_H" != x; then
  91   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  92 fi
  93 AC_SUBST(GNULIB_STDINT_H)
  94
  95 PACKAGE=gdb
  96 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  97 AC_SUBST(PACKAGE)
  98
  99 # We never need to detect it in this sub-configure.
 100 # But preserve it for config.status --recheck.
 101 AC_ARG_VAR(MAKEINFO,
 102   [Parent configure detects if it is of sufficient version.])
 103 AC_ARG_VAR(MAKEINFOFLAGS,
 104   [Parameters for MAKEINFO.])
 105
 106 MAKEINFO_EXTRA_FLAGS=""
 107 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 108   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 109   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 110     gdb_cv_have_makeinfo_click=yes
 111   else
 112     gdb_cv_have_makeinfo_click=no
 113   fi])
 114 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 115   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 116 fi
 117 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 118
 119 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 120     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 121     [${libdir}/debug])
 122
 123 # We can't pass paths as command line arguments.
 124 # Mingw32 tries to be clever and will convert the paths for us.
 125 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 126 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 127 # This breaks GDB's relocatable path conversions since paths passed in
 128 # config.h would not get so translated, the path prefixes no longer match.
 129 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 130
 131 # GDB's datadir relocation
 132
 133 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 134     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 135     [${datadir}/gdb])
 136
 137 AC_ARG_WITH(relocated-sources,
 138 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 139 [reloc_srcdir="${withval}"
 140  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 141               [Relocated directory for source files. ])
 142 ])
 143
 144 AC_MSG_CHECKING([for default auto-load directory])
 145 AC_ARG_WITH(auto-load-dir,
 146 AS_HELP_STRING([--with-auto-load-dir=PATH],
 147   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 148   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 149 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 150 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 151               [Directories from which to load auto-loaded scripts.])
 152 AC_MSG_RESULT([$with_auto_load_dir])
 153
 154 AC_MSG_CHECKING([for default auto-load safe-path])
 155 AC_ARG_WITH(auto-load-safe-path,
 156 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 157   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 158 AS_HELP_STRING([--without-auto-load-safe-path],
 159                [do not restrict auto-loaded files locations]),
 160     [if test "$with_auto_load_safe_path" = "no"; then
 161      with_auto_load_safe_path="/"
 162      fi],
 163 [with_auto_load_safe_path="$with_auto_load_dir"])
 164 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 165 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 166               [Directories safe to hold auto-loaded files.])
 167 AC_MSG_RESULT([$with_auto_load_safe_path])
 168
 169 AC_CONFIG_SUBDIRS(testsuite)
 170
 171 # Check whether to support alternative target configurations
 172 AC_ARG_ENABLE(targets,
 173 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 174 [case "${enableval}" in
 175   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 176             ;;
 177   no)       enable_targets= ;;
 178   *)        enable_targets=$enableval ;;
 179 esac])
 180
 181 # Check whether to enable 64-bit support on 32-bit hosts
 182 AC_ARG_ENABLE(64-bit-bfd,
 183 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 184 [case "${enableval}" in
 185   yes)  want64=true  ;;
 186   no)   want64=false ;;
 187   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 188 esac],[want64=false])dnl
 189
 190 # Provide defaults for some variables set by the per-host and per-target
 191 # configuration.
 192 gdb_host_obs=posix-hdep.o
 193
 194 if test "${target}" = "${host}"; then
 195   gdb_native=yes
 196 else
 197   gdb_native=no
 198 fi
 199
 200 . $srcdir/configure.host
 201
 202 # Accumulate some settings from configure.tgt over all enabled targets
 203
 204 TARGET_OBS=
 205 all_targets=
 206
 207 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 208 do
 209   if test "$targ_alias" = "all"; then
 210     all_targets=true
 211   else
 212     # Canonicalize the secondary target names.
 213     result=`$ac_config_sub $targ_alias 2>/dev/null`
 214     if test -n "$result"; then
 215         targ=$result
 216     else
 217         targ=$targ_alias
 218     fi
 219
 220     . ${srcdir}/configure.tgt
 221
 222     AS_IF([test -z "${gdb_target_obs}"],
 223       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 224
 225     # Target-specific object files
 226     for i in ${gdb_target_obs}; do
 227         case " $TARGET_OBS " in
 228         *" ${i} "*) ;;
 229         *)
 230           TARGET_OBS="$TARGET_OBS ${i}"
 231           ;;
 232         esac
 233     done
 234
 235     # Check whether this target needs 64-bit CORE_ADDR
 236     if test x${want64} = xfalse; then
 237       . ${srcdir}/../bfd/config.bfd
 238     fi
 239   fi
 240 done
 241
 242 if test x${all_targets} = xtrue; then
 243
 244   # We want all 64-bit targets if we either:
 245   #  - run on a 64-bit host  or
 246   #  - already require 64-bit support for some other target  or
 247   #  - the --enable-64-bit-bfd option was supplied
 248   # Otherwise we only support all 32-bit targets.
 249   #
 250   # NOTE: This test must be in sync with the corresponding
 251   #       tests in BFD!
 252
 253   if test x${want64} = xfalse; then
 254     AC_CHECK_SIZEOF(long)
 255     if test "x${ac_cv_sizeof_long}" = "x8"; then
 256       want64=true
 257     fi
 258   fi
 259   if test x${want64} = xtrue; then
 260     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 261   else
 262     TARGET_OBS='$(ALL_TARGET_OBS)'
 263   fi
 264 fi
 265
 266 AC_SUBST(TARGET_OBS)
 267
 268 # For other settings, only the main target counts.
 269 gdb_sim=
 270 gdb_osabi=
 271 build_gdbserver=
 272 targ=$target; . ${srcdir}/configure.tgt
 273
 274 # Fetch the default architecture and default target vector from BFD.
 275 targ=$target; . $srcdir/../bfd/config.bfd
 276
 277 # We only want the first architecture, so strip off the others if
 278 # there is more than one.
 279 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 280
 281 if test "x$targ_archs" != x; then
 282   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 283     [Define to BFD's default architecture. ])
 284 fi
 285 if test "x$targ_defvec" != x; then
 286   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 287     [Define to BFD's default target vector. ])
 288 fi
 289
 290 # The CLI cannot be disabled yet, but may be in the future.
 291
 292 # Enable CLI.
 293 AC_ARG_ENABLE(gdbcli,
 294 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 295   [case $enableval in
 296     yes)
 297       ;;
 298     no)
 299       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 300     *)
 301       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 302   esac],
 303   [enable_gdbcli=yes])
 304 if test x"$enable_gdbcli" = xyes; then
 305   if test -d $srcdir/cli; then
 306     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 307     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 308     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 309     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 310   fi
 311 fi
 312
 313 # Enable MI.
 314 AC_ARG_ENABLE(gdbmi,
 315 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 316   [case $enableval in
 317     yes | no)
 318       ;;
 319     *)
 320       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 321   esac],
 322   [enable_gdbmi=yes])
 323 if test x"$enable_gdbmi" = xyes; then
 324   if test -d $srcdir/mi; then
 325     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 326     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 327     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 328     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 329   fi
 330 fi
 331
 332 # Enable TUI.
 333 AC_ARG_ENABLE(tui,
 334 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 335   [case $enableval in
 336     yes | no | auto)
 337       ;;
 338     *)
 339       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 340   esac],enable_tui=auto)
 341
 342 # Enable gdbtk.
 343 AC_ARG_ENABLE(gdbtk,
 344 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 345   [case $enableval in
 346     yes | no)
 347       ;;
 348     *)
 349       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 350   esac],
 351   [if test -d $srcdir/gdbtk; then
 352     enable_gdbtk=yes
 353   else
 354     enable_gdbtk=no
 355   fi])
 356 # We unconditionally disable gdbtk tests on selected platforms.
 357 case $host_os in
 358   go32* | windows*)
 359     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 360     enable_gdbtk=no ;;
 361 esac
 362
 363 # Libunwind support for ia64.
 364
 365 AC_ARG_WITH(libunwind-ia64,
 366 AS_HELP_STRING([--with-libunwind-ia64],
 367                [use libunwind frame unwinding for ia64 targets]),,
 368             [with_libunwind_ia64=auto])
 369
 370 # Backward compatibility option.
 371 if test "${with_libunwind+set}" = set; then
 372   if test x"$with_libunwind_ia64" != xauto; then
 373     AC_MSG_ERROR(
 374       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 375   fi
 376   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 377   with_libunwind_ia64="$with_libunwind"
 378 fi
 379
 380 case "$with_libunwind_ia64" in
 381   yes | no)
 382     ;;
 383   auto)
 384     AC_CHECK_HEADERS(libunwind-ia64.h)
 385     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 386     ;;
 387   *)
 388     AC_MSG_ERROR(
 389       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 390     ;;
 391 esac
 392
 393 if test x"$with_libunwind_ia64" = xyes; then
 394   AC_CHECK_HEADERS(libunwind-ia64.h)
 395   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 396     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 397   fi
 398   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 399   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 400   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 401 fi
 402
 403 opt_curses=no
 404 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 405
 406 prefer_curses=no
 407 if test "$opt_curses" = "yes"; then
 408   prefer_curses=yes
 409 fi
 410
 411 # Profiling support.
 412 AC_ARG_ENABLE(profiling,
 413 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 414   [case $enableval in
 415     yes | no)
 416       ;;
 417     *)
 418       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 419   esac],
 420  [enable_profiling=no])
 421
 422 AC_CHECK_FUNCS(monstartup _mcleanup)
 423 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 424 [AC_TRY_LINK(
 425 [#include <stdlib.h>
 426 extern char _etext;
 427 ],
 428 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 429 if test $ac_cv_var__etext = yes; then
 430   AC_DEFINE(HAVE__ETEXT, 1,
 431             [Define to 1 if your system has the _etext variable. ])
 432 fi
 433 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 434 [AC_TRY_LINK(
 435 [#include <stdlib.h>
 436 extern char etext;
 437 ],
 438 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 439 if test $ac_cv_var_etext = yes; then
 440   AC_DEFINE(HAVE_ETEXT, 1,
 441             [Define to 1 if your system has the etext variable. ])
 442 fi
 443 if test "$enable_profiling" = yes ; then
 444   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 445     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 446   fi
 447   PROFILE_CFLAGS=-pg
 448   OLD_CFLAGS="$CFLAGS"
 449   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 450
 451   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 452     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 453      ac_cv_cc_supports_pg=no)])
 454
 455   if test $ac_cv_cc_supports_pg = no; then
 456     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 457   fi
 458
 459   CFLAGS="$OLD_CFLAGS"
 460 fi
 461
 462 ACX_PKGVERSION([GDB])
 463 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 464 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 465 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 466
 467 # --------------------- #
 468 # Checks for programs.  #
 469 # --------------------- #
 470
 471 AC_PROG_AWK
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_PROG_RANLIB
 475 AC_PROG_YACC
 476
 477 AC_CHECK_TOOL(AR, ar)
 478 AC_CHECK_TOOL(DLLTOOL, dlltool)
 479 AC_CHECK_TOOL(WINDRES, windres)
 480
 481 # Needed for GNU/Hurd.
 482 AC_CHECK_TOOL(MIG, mig)
 483
 484 # ---------------------- #
 485 # Checks for libraries.  #
 486 # ---------------------- #
 487
 488 # We might need to link with -lm; most simulators need it.
 489 AC_CHECK_LIB(m, main)
 490
 491 # We need to link with -lw to get `wctype' on Solaris before Solaris
 492 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 493 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 494 # is known to have this problem).  Therefore we avoid libw if we can.
 495 AC_CHECK_FUNC(wctype, [],
 496   [AC_CHECK_LIB(w, wctype)])
 497
 498 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 499 AC_SEARCH_LIBS(gethostbyname, nsl)
 500
 501 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 502 AC_SEARCH_LIBS(socketpair, socket)
 503
 504 # Link in zlib if we can.  This allows us to read compressed debug sections.
 505 AM_ZLIB
 506
 507 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 508 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 509
 510 AM_ICONV
 511
 512 # GDB may fork/exec the iconv program to get the list of supported character
 513 # sets.  Allow the user to specify where to find it.
 514 # There are several factors affecting the choice of option name:
 515 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 516 #   the build-time location of libiconv files.
 517 # - The program we need to find is iconv, which comes with glibc.  The user
 518 #   doesn't necessarily have libiconv installed.  Therefore naming this
 519 #   --with-libiconv-foo feels wrong.
 520 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 521 #   defined to work on directories not files (though it really doesn't know
 522 #   the difference).
 523 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 524 #   with --with-libiconv-prefix.
 525 # Putting these together is why the option name is --with-iconv-bin.
 526
 527 AC_ARG_WITH(iconv-bin,
 528 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 529 [iconv_bin="${withval}"
 530  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 531                     [Path of directory of iconv program.])
 532  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 533 ])
 534
 535 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 536 # There is a very specific comment in /usr/include/curses.h explaining that
 537 # termcap routines built into libcurses must not be used.
 538 #
 539 # The symptoms we observed so far is GDB unexpectedly changing
 540 # the terminal settings when tgetent is called - this is particularly
 541 # visible as the output is missing carriage returns, and so rapidly
 542 # becomes very hard to read.
 543 #
 544 # The readline configure script has already decided that libtermcap
 545 # was enough for its purposes, and so decided to build readline using
 546 # libtermcap.  Since the TUI mode requires curses, building GDB with
 547 # TUI enabled results in both libraries to be used at the same time,
 548 # which is not allowed.  This basically means that GDB with TUI is
 549 # broken on alpha-osf.
 550
 551 case $host_os in
 552   osf* )
 553     if test x"$enable_tui" = xyes; then
 554       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 555     fi
 556     if test x"$enable_tui" = xauto; then
 557       enable_tui=no
 558     fi
 559     ;;
 560 esac
 561
 562 # For the TUI, we need enhanced curses functionality.
 563 if test x"$enable_tui" != xno; then
 564   prefer_curses=yes
 565 fi
 566
 567 curses_found=no
 568 if test x"$prefer_curses" = xyes; then
 569   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 570   # curses library because the latter might not provide all the
 571   # functionality we need.  However, this leads to problems on systems
 572   # where the linker searches /usr/local/lib, but the compiler doesn't
 573   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 574   # default installation of ncurses on alpha*-dec-osf* will lead to such
 575   # a situation.
 576   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 577
 578   if test "$ac_cv_search_waddstr" != no; then
 579     curses_found=yes
 580   fi
 581 fi
 582
 583 # Check whether we should enable the TUI, but only do so if we really
 584 # can.
 585 if test x"$enable_tui" != xno; then
 586   if test -d $srcdir/tui; then
 587     if test "$curses_found" != no; then
 588       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 589       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 590       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 591       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 592     else
 593       if test x"$enable_tui" = xyes; then
 594         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 595       else
 596         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 597       fi
 598     fi
 599   fi
 600 fi
 601
 602 # Since GDB uses Readline, we need termcap functionality.  In many
 603 # cases this will be provided by the curses library, but some systems
 604 # have a seperate termcap library, or no curses library at all.
 605
 606 case $host_os in
 607   cygwin*)
 608     if test -d $srcdir/libtermcap; then
 609       LIBS="../libtermcap/libtermcap.a $LIBS"
 610       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 611     fi ;;
 612   go32* | *djgpp*)
 613     ac_cv_search_tgetent="none required"
 614     ;;
 615   *mingw32*)
 616     ac_cv_search_tgetent="none required"
 617     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 618     ;;
 619 esac
 620
 621 # These are the libraries checked by Readline.
 622 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 623
 624 if test "$ac_cv_search_tgetent" = no; then
 625   AC_MSG_ERROR([no termcap library found])
 626 fi
 627
 628 AC_ARG_WITH([system-readline],
 629   [AS_HELP_STRING([--with-system-readline],
 630                   [use installed readline library])])
 631
 632 if test "$with_system_readline" = yes; then
 633   READLINE=-lreadline
 634   READLINE_DEPS=
 635   READLINE_CFLAGS=
 636   READLINE_TEXI_INCFLAG=
 637 else
 638   READLINE='$(READLINE_DIR)/libreadline.a'
 639   READLINE_DEPS='$(READLINE)'
 640   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 641   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 642 fi
 643 AC_SUBST(READLINE)
 644 AC_SUBST(READLINE_DEPS)
 645 AC_SUBST(READLINE_CFLAGS)
 646 AC_SUBST(READLINE_TEXI_INCFLAG)
 647
 648 # Provide a --enable-libmcheck/--disable-libmcheck set of options
 649 # allowing a user to enable this option even when building releases,
 650 # or to disable it when building a snapshot.
 651 AC_ARG_ENABLE(libmcheck,
 652   AS_HELP_STRING([--enable-libmcheck],
 653                  [Try building GDB with -lmcheck if available]),
 654   [case "${enableval}" in
 655      yes | y) ENABLE_LIBMCHECK="yes" ;;
 656      no | n)  ENABLE_LIBMCHECK="no" ;;
 657      *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmcheck) ;;
 658    esac])
 659
 660 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
 661 # but turn it off for releases.
 662 if test -z "${ENABLE_LIBMCHECK}" && $development; then
 663     ENABLE_LIBMCHECK=yes
 664 fi
 665
 666 if test "$ENABLE_LIBMCHECK" = "yes" ; then
 667   AC_CHECK_LIB(mcheck, main)
 668 fi
 669
 670 # Generate jit-reader.h
 671
 672 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 673 TARGET_PTR=
 674
 675 AC_CHECK_SIZEOF(unsigned long long)
 676 AC_CHECK_SIZEOF(unsigned long)
 677 AC_CHECK_SIZEOF(unsigned __int128)
 678
 679 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 680   TARGET_PTR="unsigned long"
 681 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 682   TARGET_PTR="unsigned long long"
 683 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 684   TARGET_PTR="unsigned __int128"
 685 else
 686   TARGET_PTR="unsigned long"
 687 fi
 688
 689 AC_SUBST(TARGET_PTR)
 690 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 691
 692 AC_SEARCH_LIBS(dlopen, dl)
 693
 694 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 695                 [directory to load the JIT readers from],
 696                 [${libdir}/gdb])
 697
 698 AC_ARG_WITH(expat,
 699   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 700   [], [with_expat=auto])
 701 AC_MSG_CHECKING([whether to use expat])
 702 AC_MSG_RESULT([$with_expat])
 703
 704 if test "${with_expat}" = no; then
 705   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 706   HAVE_LIBEXPAT=no
 707 else
 708   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 709                         [XML_Parser p = XML_ParserCreate (0);])
 710   if test "$HAVE_LIBEXPAT" != yes; then
 711     if test "$with_expat" = yes; then
 712       AC_MSG_ERROR([expat is missing or unusable])
 713     else
 714       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 715     fi
 716   else
 717     save_LIBS=$LIBS
 718     LIBS="$LIBS $LIBEXPAT"
 719     AC_CHECK_FUNCS(XML_StopParser)
 720     LIBS=$save_LIBS
 721   fi
 722 fi
 723
 724 dnl Utility to simplify finding libpython.
 725 dnl $1 = pythonX.Y
 726 dnl $2 = the shell variable to assign the result to
 727 dnl      If libpython is found we store $version here.
 728 dnl $3 = additional flags to add to CPPFLAGS
 729 dnl $4 = additional flags to add to LIBS
 730
 731 AC_DEFUN([AC_TRY_LIBPYTHON],
 732 [
 733   version=$1
 734   define([have_libpython_var],$2)
 735   new_CPPFLAGS=$3
 736   new_LIBS=$4
 737   AC_MSG_CHECKING([for ${version}])
 738   save_CPPFLAGS=$CPPFLAGS
 739   save_LIBS=$LIBS
 740   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 741   LIBS="$LIBS $new_LIBS"
 742   found_usable_python=no
 743   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 744                                  [[Py_Initialize ();]]),
 745                  [have_libpython_var=${version}
 746                   found_usable_python=yes
 747                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 748                   PYTHON_LIBS=$new_LIBS])
 749   CPPFLAGS=$save_CPPFLAGS
 750   LIBS=$save_LIBS
 751   AC_MSG_RESULT([${found_usable_python}])
 752 ])
 753
 754 dnl There are several different values for --with-python:
 755 dnl
 756 dnl no -   Don't include python support.
 757 dnl yes -  Include python support, error if it's missing.
 758 dnl        If we find python in $PATH, use it to fetch configure options,
 759 dnl        otherwise assume the compiler can find it with no help from us.
 760 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 761 dnl auto - Same as "yes", but if python is missing from the system,
 762 dnl        fall back to "no".
 763 dnl /path/to/python/exec-prefix -
 764 dnl        Use the python located in this directory.
 765 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 766 dnl        the compilation parameters.  Otherwise use
 767 dnl        -I/path/to/python/exec-prefix/include,
 768 dnl        -L/path/to/python/exec-prefix/lib.
 769 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 770 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 771 dnl        but is deprecated.
 772 dnl /path/to/python/executable -
 773 dnl        Run python-config.py with this version of python to fetch the
 774 dnl        compilation parameters.
 775 dnl        NOTE: This needn't be the real python executable.
 776 dnl        In a cross-compilation scenario (build != host), this could be
 777 dnl        a shell script that provides what python-config.py provides for
 778 dnl        --ldflags, --includes, --exec-prefix.
 779 dnl python-executable -
 780 dnl        Find python-executable in $PATH, and then handle the same as
 781 dnl        /path/to/python/executable.
 782 dnl
 783 dnl If a python program is specified, it is used to run python-config.py and
 784 dnl is passed --ldflags, --includes, --exec-prefix.
 785
 786 AC_ARG_WITH(python,
 787   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 788   [], [with_python=auto])
 789 AC_MSG_CHECKING([whether to use python])
 790 AC_MSG_RESULT([$with_python])
 791
 792 if test "${with_python}" = no; then
 793   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 794   have_libpython=no
 795 else
 796   case "${with_python}" in
 797   [[\\/]]* | ?:[[\\/]]*)
 798     if test -d ${with_python}; then
 799       # Assume the python binary is ${with_python}/bin/python.
 800       python_prog="${with_python}/bin/python"
 801       python_prefix=
 802       # If python does not exit ${with_python}/bin, then try in
 803       # ${with_python}.  On Windows/MinGW, this is where the Python
 804       # executable is.
 805       if test ! -x "${python_prog}"; then
 806         python_prog="${with_python}/python"
 807         python_prefix=
 808       fi
 809       if test ! -x "${python_prog}"; then
 810         # Fall back to gdb 7.0/7.1 behaviour.
 811         python_prog=missing
 812         python_prefix=${with_python}
 813       fi
 814     elif test -x "${with_python}"; then
 815       # While we can't run python compiled for $host (unless host == build),
 816       # the user could write a script that provides the needed information,
 817       # so we support that.
 818       python_prog=${with_python}
 819       python_prefix=
 820     else
 821       AC_ERROR(invalid value for --with-python)
 822     fi
 823     ;;
 824   */*)
 825     # Disallow --with-python=foo/bar.
 826     AC_ERROR(invalid value for --with-python)
 827     ;;
 828   *)
 829     # The user has either specified auto, yes, or the name of the python
 830     # program assumed to be in $PATH.
 831     python_prefix=
 832     case "${with_python}" in
 833     yes | auto)
 834       if test ${build} = ${host}; then
 835         AC_PATH_PROG(python_prog_path, python, missing)
 836         if test "${python_prog_path}" = missing; then
 837           python_prog=missing
 838         else
 839           python_prog=${python_prog_path}
 840         fi
 841       else
 842         # Not much we can do except assume the cross-compiler will find the
 843         # right files.
 844         python_prog=missing
 845       fi
 846       ;;
 847     *)
 848       # While we can't run python compiled for $host (unless host == build),
 849       # the user could write a script that provides the needed information,
 850       # so we support that.
 851       python_prog="${with_python}"
 852       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 853       if test "${python_prog_path}" = missing; then
 854         AC_ERROR(unable to find python program ${python_prog})
 855       fi
 856       ;;
 857     esac
 858   esac
 859
 860   if test "${python_prog}" != missing; then
 861     # We have a python program to use, but it may be too old.
 862     # Don't flag an error for --with-python=auto (the default).
 863     have_python_config=yes
 864     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 865     if test $? != 0; then
 866       have_python_config=failed
 867       if test "${with_python}" != auto; then
 868         AC_ERROR(failure running python-config --includes)
 869       fi
 870     fi
 871     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 872     if test $? != 0; then
 873       have_python_config=failed
 874       if test "${with_python}" != auto; then
 875         AC_ERROR(failure running python-config --ldflags)
 876       fi
 877     fi
 878     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 879     if test $? != 0; then
 880       have_python_config=failed
 881       if test "${with_python}" != auto; then
 882         AC_ERROR(failure running python-config --exec-prefix)
 883       fi
 884     fi
 885   else
 886     # We do not have a python executable we can use to determine where
 887     # to find the Python headers and libs.  We cannot guess the include
 888     # path from the python_prefix either, because that include path
 889     # depends on the Python version.  So, there is nothing much we can
 890     # do except assume that the compiler will be able to find those files.
 891     python_includes=
 892     python_libs=
 893     have_python_config=no
 894   fi
 895
 896   # If we have python-config, only try the configuration it provides.
 897   # Otherwise fallback on the old way of trying different versions of
 898   # python in turn.
 899
 900   have_libpython=no
 901   if test "${have_python_config}" = yes; then
 902     # Determine the Python version by extracting "-lpython<version>"
 903     # part of the python_libs. <version> is usually X.Y with X and Y
 904     # being decimal numbers, but can also be XY (seen on Windows).
 905     #
 906     # The extraction is performed using sed with a regular expression.
 907     # Initially, the regexp used was using the '?' quantifier to make
 908     # the dot in the version number optional.  Unfortunately, this
 909     # does not work with non-GNU versions of sed because, because of
 910     # what looks like a limitation (the '?' quantifier does not work
 911     # with back-references).  We work around this limitation by using
 912     # the '*' quantifier instead.  It means that, in theory, we might
 913     # match unexpected version strings such as "-lpython2..7", but
 914     # this seems unlikely in practice.  And even if that happens,
 915     # an error will be triggered later on, when checking that version
 916     # number.
 917     python_version=`echo " ${python_libs} " \
 918                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 919     case "${python_version}" in
 920     python*)
 921       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 922                        ${python_includes}, ${python_libs})
 923       ;;
 924     *)
 925       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 926       ;;
 927     esac
 928   elif test "${have_python_config}" != failed; then
 929     if test "${have_libpython}" = no; then
 930       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 931                        ${python_includes}, "${python_libs} -lpython2.7")
 932     fi
 933     if test "${have_libpython}" = no; then
 934       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 935                        ${python_includes}, "${python_libs} -lpython2.6")
 936     fi
 937     if test ${have_libpython} = no; then
 938       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 939                        ${python_includes}, "${python_libs} -lpython2.5")
 940     fi
 941     if test ${have_libpython} = no; then
 942       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 943                        ${python_includes}, "${python_libs} -lpython2.4")
 944     fi
 945   fi
 946   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 947     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 948   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 949     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 950   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 951     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 952   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 953     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 954   fi
 955
 956   if test "${have_libpython}" = no; then
 957     case "${with_python}" in
 958     yes)
 959       AC_MSG_ERROR([python is missing or unusable])
 960       ;;
 961     auto)
 962       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 963       ;;
 964     *)
 965       AC_MSG_ERROR([no usable python found at ${with_python}])
 966       ;;
 967     esac
 968   else
 969     if test -n "${python_prefix}"; then
 970       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 971                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 972       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 973     fi
 974   fi
 975 fi
 976
 977 if test "${have_libpython}" != no; then
 978   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 979   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 980   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 981   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 982   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 983   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 984
 985   # Flags needed to compile Python code (taken from python-config --cflags).
 986   # We cannot call python-config directly because it will output whatever was
 987   # used when compiling the Python interpreter itself, including flags which
 988   # would make the python-related objects be compiled differently from the
 989   # rest of GDB (e.g., -O2 and -fPIC).
 990   if test "${GCC}" = yes; then
 991     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 992   fi
 993
 994   if test "x${tentative_python_cflags}" != x; then
 995     AC_MSG_CHECKING(compiler flags for python code)
 996     for flag in ${tentative_python_cflags}; do
 997       # Check that the compiler accepts it
 998       saved_CFLAGS="$CFLAGS"
 999       CFLAGS="$CFLAGS $flag"
1000       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
1001       CFLAGS="$saved_CFLAGS"
1002     done
1003     AC_MSG_RESULT(${PYTHON_CFLAGS})
1004   fi
1005
1006   # On IRIX, type siginfo is not defined.  Instead, sys/siginfo.h provides:
1007   #    #if _SGIAPI
1008   #    #define siginfo __siginfo
1009   #    #endif
1010   # The problem is that including Python causes some XOPEN macros to be
1011   # unilaterally defined, and that in turn causes _SGIAPI to evaluate
1012   # to false.  So, we work around this issue by defining siginfo ourself
1013   # though the command-line.
1014   case "$gdb_host" in
1015     irix*) if test "${GCC}" = yes; then
1016              CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo"
1017            fi
1018            ;;
1019   esac
1020 else
1021   # Even if Python support is not compiled in, we need to have these files
1022   # included.
1023   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o"
1024   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \
1025         python/py-prettyprint.c python/py-auto-load.c"
1026 fi
1027 AC_SUBST(PYTHON_CFLAGS)
1028 AC_SUBST(PYTHON_CPPFLAGS)
1029 AC_SUBST(PYTHON_LIBS)
1030
1031 # ------------------------- #
1032 # Checks for header files.  #
1033 # ------------------------- #
1034
1035 AC_HEADER_DIRENT
1036 AC_HEADER_STAT
1037 AC_HEADER_STDC
1038 # elf_hp.h is for HP/UX 64-bit shared library support.
1039 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
1040 # unconditionally, so what's the point in checking these?
1041 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1042                   thread_db.h signal.h stddef.h \
1043                   stdlib.h string.h memory.h strings.h sys/fault.h \
1044                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1045                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1046                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1047                   sys/types.h sys/wait.h wait.h termios.h termio.h \
1048                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h \
1049                   dlfcn.h sys/socket.h sys/un.h])
1050 AC_CHECK_HEADERS(link.h, [], [],
1051 [#if HAVE_SYS_TYPES_H
1052 # include <sys/types.h>
1053 #endif
1054 #if HAVE_NLIST_H
1055 # include <nlist.h>
1056 #endif
1057 ])
1058 AC_CHECK_HEADERS(sys/proc.h, [], [],
1059 [#if HAVE_SYS_PARAM_H
1060 # include <sys/param.h>
1061 #endif
1062 ])
1063 AC_CHECK_HEADERS(sys/user.h, [], [],
1064 [#if HAVE_SYS_PARAM_H
1065 # include <sys/param.h>
1066 #endif
1067 ])
1068
1069 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1070 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1071 # think that we don't have <curses.h> if we're using GCC.
1072 case $host_os in
1073   solaris2.[[789]])
1074     if test "$GCC" = yes; then
1075       AC_DEFINE(_MSE_INT_H, 1,
1076         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1077    Solaris 2.[789] when using GCC. ])
1078     fi ;;
1079 esac
1080 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1081 AC_CHECK_HEADERS(term.h, [], [],
1082 [#if HAVE_CURSES_H
1083 # include <curses.h>
1084 #endif
1085 ])
1086
1087 # ------------------------- #
1088 # Checks for declarations.  #
1089 # ------------------------- #
1090
1091 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
1092                 snprintf, vsnprintf])
1093 AM_LC_MESSAGES
1094
1095 # ----------------------- #
1096 # Checks for structures.  #
1097 # ----------------------- #
1098
1099 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1100
1101 # ------------------ #
1102 # Checks for types.  #
1103 # ------------------ #
1104
1105 AC_TYPE_SIGNAL
1106 AC_CHECK_TYPES(socklen_t, [], [],
1107 [#include <sys/types.h>
1108 #include <sys/socket.h>
1109 ])
1110
1111 # ------------------------------------- #
1112 # Checks for compiler characteristics.  #
1113 # ------------------------------------- #
1114
1115 AC_C_CONST
1116 AC_C_INLINE
1117 AC_C_BIGENDIAN
1118
1119 # ------------------------------ #
1120 # Checks for library functions.  #
1121 # ------------------------------ #
1122
1123 AC_FUNC_ALLOCA
1124 AC_FUNC_MMAP
1125 AC_FUNC_VFORK
1126 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \
1127                 pipe poll pread pread64 pwrite readlink resize_term \
1128                 sbrk setpgid setpgrp setsid \
1129                 sigaction sigprocmask sigsetmask socketpair syscall \
1130                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1131                 setrlimit getrlimit posix_madvise waitpid lstat])
1132 AM_LANGINFO_CODESET
1133
1134 # Check the return and argument types of ptrace.  No canned test for
1135 # this, so roll our own.
1136 gdb_ptrace_headers='
1137 #if HAVE_SYS_TYPES_H
1138 # include <sys/types.h>
1139 #endif
1140 #if HAVE_SYS_PTRACE_H
1141 # include <sys/ptrace.h>
1142 #endif
1143 #if HAVE_UNISTD_H
1144 # include <unistd.h>
1145 #endif
1146 '
1147 # There is no point in checking if we don't have a prototype.
1148 AC_CHECK_DECLS(ptrace, [], [
1149   : ${gdb_cv_func_ptrace_ret='int'}
1150   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1151 ], $gdb_ptrace_headers)
1152 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1153 # empty argument list, so check for that explicitly.
1154 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1155   AC_TRY_COMPILE($gdb_ptrace_headers,
1156     [extern long ptrace (enum __ptrace_request, ...);],
1157     gdb_cv_func_ptrace_ret='long',
1158     AC_TRY_COMPILE($gdb_ptrace_headers,
1159       [extern int ptrace ();],
1160       gdb_cv_func_ptrace_ret='int',
1161       gdb_cv_func_ptrace_ret='long')))
1162 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1163   [Define as the return type of ptrace.])
1164 # Check argument types.
1165 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1166   AC_TRY_COMPILE($gdb_ptrace_headers,
1167     [extern long ptrace (enum __ptrace_request, ...);],
1168     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1169 for gdb_arg1 in 'int' 'long'; do
1170  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1171   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1172    for gdb_arg4 in 'int' 'long'; do
1173      AC_TRY_COMPILE($gdb_ptrace_headers, [
1174 extern $gdb_cv_func_ptrace_ret
1175   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1176 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1177     break 4;])
1178     for gdb_arg5 in 'int *' 'int' 'long'; do
1179      AC_TRY_COMPILE($gdb_ptrace_headers, [
1180 extern $gdb_cv_func_ptrace_ret
1181   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1182 ], [
1183 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1184     break 5;])
1185     done
1186    done
1187   done
1188  done
1189 done
1190 # Provide a safe default value.
1191 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1192 ])])
1193 ac_save_IFS=$IFS; IFS=','
1194 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1195 IFS=$ac_save_IFS
1196 shift
1197 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1198   [Define to the type of arg 3 for ptrace.])
1199 if test -n "$[5]"; then
1200   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1201     [Define to the type of arg 5 for ptrace.])
1202 fi
1203
1204 dnl AC_FUNC_SETPGRP does not work when cross compiling
1205 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1206 if test "$cross_compiling" = no; then
1207   AC_FUNC_SETPGRP
1208 else
1209   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1210     [AC_TRY_COMPILE([
1211 #include <unistd.h>
1212 ], [
1213   if (setpgrp(1,1) == -1)
1214     exit (0);
1215   else
1216     exit (1);
1217 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1218 if test $ac_cv_func_setpgrp_void = yes; then
1219   AC_DEFINE(SETPGRP_VOID, 1)
1220 fi
1221 fi
1222
1223 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
1224 # since sigsetjmp might only be defined as a macro.
1225 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
1226 [AC_TRY_COMPILE([
1227 #include <setjmp.h>
1228 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
1229 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
1230 if test $gdb_cv_func_sigsetjmp = yes; then
1231   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
1232 fi
1233
1234 # Assume we'll default to using the included libiberty regex.
1235 gdb_use_included_regex=yes
1236
1237 # However, if the system regex is GNU regex, then default to *not*
1238 # using the included regex.
1239 AC_CACHE_CHECK(
1240   [for GNU regex],
1241   [gdb_cv_have_gnu_regex],
1242   [AC_TRY_COMPILE(
1243     [#include <gnu-versions.h>],
1244     [#define REGEX_INTERFACE_VERSION 1
1245 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1246 # error "Version mismatch"
1247 #endif],
1248     gdb_cv_have_gnu_regex=yes,
1249     gdb_cv_have_gnu_regex=no)])
1250 if test $gdb_cv_have_gnu_regex = yes; then
1251   gdb_use_included_regex=no
1252 fi
1253
1254 AC_ARG_WITH(included-regex,
1255   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1256   gdb_with_regex=$withval,
1257   gdb_with_regex=$gdb_use_included_regex)
1258 if test "$gdb_with_regex" = yes; then
1259   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1260     [Define to 1 if the regex included in libiberty should be used.])
1261 fi
1262
1263 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1264 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1265 [#include <sys/param.h>
1266 #include <sys/proc.h>
1267 ])
1268
1269 # See if <sys/lwp.h> defines `struct lwp`.
1270 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1271 [AC_TRY_COMPILE([#include <sys/param.h>
1272 #include <sys/lwp.h>], [struct lwp l;],
1273 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1274 if test $gdb_cv_struct_lwp = yes; then
1275   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1276             [Define to 1 if your system has struct lwp.])
1277 fi
1278
1279 # See if <machine/reg.h> degines `struct reg'.
1280 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1281 [AC_TRY_COMPILE([#include <sys/types.h>
1282 #include <machine/reg.h>], [struct reg r;],
1283 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1284 if test $gdb_cv_struct_reg = yes; then
1285   AC_DEFINE(HAVE_STRUCT_REG, 1,
1286             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1287 fi
1288
1289 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1290 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1291 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1292                  [#include <machine/reg.h>])
1293
1294 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1295 # Older amd64 Linux's don't have the fs_base and gs_base members of
1296 # `struct user_regs_struct'.
1297 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1298                  [], [], [#include <sys/user.h>])
1299
1300 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1301 AC_MSG_CHECKING(for PTRACE_GETREGS)
1302 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1303 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1304                 [PTRACE_GETREGS;],
1305                 [gdb_cv_have_ptrace_getregs=yes],
1306                 [gdb_cv_have_ptrace_getregs=no])])
1307 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1308 if test $gdb_cv_have_ptrace_getregs = yes; then
1309   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1310   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1311 fi
1312
1313 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1314 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1315 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1316 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1317                 [PTRACE_GETFPXREGS;],
1318                 [gdb_cv_have_ptrace_getfpxregs=yes],
1319                 [gdb_cv_have_ptrace_getfpxregs=no])])
1320 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1321 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1322   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1323   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1324 fi
1325
1326 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1327 AC_MSG_CHECKING(for PT_GETDBREGS)
1328 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1329 [AC_TRY_COMPILE([#include <sys/types.h>
1330 #include <sys/ptrace.h>],
1331                 [PT_GETDBREGS;],
1332                 [gdb_cv_have_pt_getdbregs=yes],
1333                 [gdb_cv_have_pt_getdbregs=no])])
1334 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1335 if test $gdb_cv_have_pt_getdbregs = yes; then
1336   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1337   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1338 fi
1339
1340 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1341 AC_MSG_CHECKING(for PT_GETXMMREGS)
1342 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1343 [AC_TRY_COMPILE([#include <sys/types.h>
1344 #include <sys/ptrace.h>],
1345                 [PT_GETXMMREGS;],
1346                 [gdb_cv_have_pt_getxmmregs=yes],
1347                 [gdb_cv_have_pt_getxmmregs=no])])
1348 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1349 if test $gdb_cv_have_pt_getxmmregs = yes; then
1350   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1351   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1352 fi
1353
1354 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1355
1356 if test "${target}" = "${host}"; then
1357   case "${host}" in
1358   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1359       AC_DEFINE(NEW_PROC_API, 1,
1360       [Define if you want to use new multi-fd /proc interface
1361        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1362       ;;
1363   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1364       AC_DEFINE(NEW_PROC_API, 1,
1365       [Define if you want to use new multi-fd /proc interface
1366        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1367       ;;
1368   mips-sgi-irix5*)
1369       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1370       AC_DEFINE([_KMEMUSER], 1,
1371       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1372        around a <sys/proc.h> problem on IRIX 5.])
1373       ;;
1374   esac
1375 fi
1376
1377 if test "$ac_cv_header_sys_procfs_h" = yes; then
1378   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1379   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1380   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1381   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1382   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1383   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1384   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1385   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1386   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1387   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1388   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1389   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1390   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1391   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1392
1393
1394   dnl Check for broken prfpregset_t type
1395
1396   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1397   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1398   dnl instead of the struct itself).  We detect this here, and work
1399   dnl around it in gdb_proc_service.h.
1400
1401   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1402     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1403     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1404       [AC_TRY_RUN([#include <sys/procfs.h>
1405        int main ()
1406        {
1407          if (sizeof (prfpregset_t) == sizeof (void *))
1408            return 1;
1409          return 0;
1410        }],
1411        gdb_cv_prfpregset_t_broken=no,
1412        gdb_cv_prfpregset_t_broken=yes,
1413        gdb_cv_prfpregset_t_broken=yes)])
1414     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1415     if test $gdb_cv_prfpregset_t_broken = yes; then
1416       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1417       [Define if the prfpregset_t type is broken.])
1418     fi
1419   fi
1420
1421   dnl Check for PIOCSET ioctl entry
1422
1423   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1424   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1425   [AC_TRY_COMPILE([#include <unistd.h>
1426 #include <sys/types.h>
1427 #include <sys/procfs.h>
1428 ], [
1429     int dummy;;
1430     dummy = ioctl(0, PIOCSET, &dummy);
1431   ],
1432   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1433   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1434   if test $gdb_cv_have_procfs_piocset = yes; then
1435     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1436     [Define if ioctl argument PIOCSET is available.])
1437   fi
1438 fi
1439
1440 dnl For native ports (host == target), check to see what kind of
1441 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1442 if test ${host} = ${target} ; then
1443   dnl Check for struct link_map with l_ members which are indicative
1444   dnl of SVR4-like shared libraries
1445
1446   AC_MSG_CHECKING(for member l_addr in struct link_map)
1447   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1448     [AC_TRY_COMPILE([#include <link.h>],
1449                     [struct link_map lm; (void) lm.l_addr;],
1450                     gdb_cv_have_struct_link_map_with_l_members=yes,
1451                     gdb_cv_have_struct_link_map_with_l_members=no)])
1452   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1453   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1454     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1455     [Define if <link.h> exists and defines struct link_map which has
1456      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1457      SVR4-like systems.)])
1458   fi
1459
1460   dnl Check for struct link_map with lm_ members which are indicative
1461   dnl of SunOS-like shared libraries
1462
1463   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1464   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1465     [AC_TRY_COMPILE([#include <sys/types.h>
1466 #include <link.h>],
1467                     [struct link_map lm; (void) lm.lm_addr;],
1468                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1469                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1470   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1471   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1472     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1473     [Define if <link.h> exists and defines struct link_map which has
1474      members with an ``lm_'' prefix.  (For SunOS.)])
1475   fi
1476
1477   dnl Check for struct so_map with som_ members which are found on
1478   dnl some *BSD systems.
1479
1480   AC_MSG_CHECKING(for member som_addr in struct so_map)
1481   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1482     [AC_TRY_COMPILE([#include <sys/types.h>
1483 #ifdef HAVE_NLIST_H
1484 #include <nlist.h>
1485 #endif
1486 #include <link.h>],
1487                     [struct so_map lm; (void) lm.som_addr;],
1488                     gdb_cv_have_struct_so_map_with_som_members=yes,
1489                     gdb_cv_have_struct_so_map_with_som_members=no)])
1490   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1491   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1492     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1493     [Define if <link.h> exists and defines a struct so_map which has
1494      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1495   fi
1496
1497   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1498   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1499
1500   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1501   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1502     [AC_TRY_COMPILE([#define _SYSCALL32
1503 #include <sys/link.h>], [struct link_map32 l;],
1504      gdb_cv_have_struct_link_map32=yes,
1505      gdb_cv_have_struct_link_map32=no)])
1506   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1507   if test $gdb_cv_have_struct_link_map32 = yes; then
1508     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1509     [Define if <sys/link.h> has struct link_map32])
1510     AC_DEFINE(_SYSCALL32, 1,
1511     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1512   fi
1513 fi
1514
1515 # Check if the compiler supports the `long long' type.
1516
1517 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1518                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1519 [[extern long long foo;]],
1520 [[switch (foo & 2) { case 0: return 1; }]])],
1521                                   gdb_cv_c_long_long=yes,
1522                                   gdb_cv_c_long_long=no)])
1523 if test $gdb_cv_c_long_long = yes; then
1524   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1525             [Define to 1 if the compiler supports long long.])
1526 fi
1527
1528 # Check if the compiler and runtime support printing long longs.
1529
1530 AC_CACHE_CHECK([for long long support in printf],
1531                gdb_cv_printf_has_long_long,
1532                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1533 [[char buf[32];
1534   long long l = 0;
1535   l = (l << 16) + 0x0123;
1536   l = (l << 16) + 0x4567;
1537   l = (l << 16) + 0x89ab;
1538   l = (l << 16) + 0xcdef;
1539   sprintf (buf, "0x%016llx", l);
1540   return (strcmp ("0x0123456789abcdef", buf));]])],
1541                               gdb_cv_printf_has_long_long=yes,
1542                               gdb_cv_printf_has_long_long=no,
1543                               gdb_cv_printf_has_long_long=no)])
1544 if test $gdb_cv_printf_has_long_long = yes; then
1545   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1546             [Define to 1 if the "%ll" format works to print long longs.])
1547 fi
1548
1549 # Check if the compiler and runtime support printing decfloats.
1550
1551 AC_CACHE_CHECK([for decfloat support in printf],
1552                gdb_cv_printf_has_decfloat,
1553                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1554 [[char buf[64];
1555   _Decimal32 d32 = 1.2345df;
1556   _Decimal64 d64 = 1.2345dd;
1557   _Decimal128 d128 = 1.2345dl;
1558   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1559   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1560                               gdb_cv_printf_has_decfloat=yes,
1561                               gdb_cv_printf_has_decfloat=no,
1562                               gdb_cv_printf_has_decfloat=no)])
1563 if test $gdb_cv_printf_has_decfloat = yes; then
1564   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1565             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1566 fi
1567
1568 # Check if the compiler supports the `long double' type.  We can't use
1569 # AC_C_LONG_DOUBLE because that one does additional checks on the
1570 # constants defined in <float.h> that fail on some systems,
1571 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1572
1573 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1574                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1575                                   gdb_cv_c_long_double=yes,
1576                                   gdb_cv_c_long_double=no)])
1577 if test $gdb_cv_c_long_double = yes; then
1578   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1579            [Define to 1 if the compiler supports long double.])
1580 fi
1581
1582 # Check if the compiler and runtime support printing long doubles.
1583
1584 AC_CACHE_CHECK([for long double support in printf],
1585                gdb_cv_printf_has_long_double,
1586                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1587 [[char buf[16];
1588   long double f = 3.141592653;
1589   sprintf (buf, "%Lg", f);
1590   return (strncmp ("3.14159", buf, 7));]])],
1591                               gdb_cv_printf_has_long_double=yes,
1592                               gdb_cv_printf_has_long_double=no,
1593                               gdb_cv_printf_has_long_double=no)])
1594 if test $gdb_cv_printf_has_long_double = yes; then
1595   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1596             [Define to 1 if the "%Lg" format works to print long doubles.])
1597 fi
1598
1599 # Check if the compiler and runtime support scanning long doubles.
1600
1601 AC_CACHE_CHECK([for long double support in scanf],
1602                gdb_cv_scanf_has_long_double,
1603                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1604 [[#include <stdio.h>]],
1605 [[char *buf = "3.141592653";
1606   long double f = 0;
1607   sscanf (buf, "%Lg", &f);
1608   return !(f > 3.14159 && f < 3.14160);]])],
1609                               gdb_cv_scanf_has_long_double=yes,
1610                               gdb_cv_scanf_has_long_double=no,
1611                               gdb_cv_scanf_has_long_double=no)])
1612 if test $gdb_cv_scanf_has_long_double = yes; then
1613   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1614             [Define to 1 if the "%Lg" format works to scan long doubles.])
1615 fi
1616
1617 case ${host_os} in
1618 aix*)
1619   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1620     SAVE_LDFLAGS=$LDFLAGS
1621
1622     case $GCC in
1623     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1624     *) gdb_cv_bigtoc=-bbigtoc ;;
1625     esac
1626
1627     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1628     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1629     LDFLAGS="${SAVE_LDFLAGS}"
1630   ])
1631   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1632   ;;
1633 esac
1634
1635 AC_MSG_CHECKING(for the dynamic export flag)
1636 dynamic_list=false
1637 if test "${gdb_native}" = yes; then
1638    # The dynamically loaded libthread_db needs access to symbols in the gdb
1639    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1640    # may not be supported there.
1641    old_LDFLAGS="$LDFLAGS"
1642    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1643    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1644    LDFLAGS="$LDFLAGS $RDYNAMIC"
1645    if test "${have_libpython}" = no; then
1646      AC_TRY_LINK([], [], [dynamic_list=true])
1647    else
1648      # Workaround http://bugs.python.org/issue4434 where static
1649      # libpythonX.Y.a would get its symbols required for
1650      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1651      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1652      old_CFLAGS="$CFLAGS"
1653      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1654      AC_RUN_IFELSE(
1655        AC_LANG_PROGRAM(
1656          [#include "]${have_libpython}[/Python.h"],
1657          [int err;
1658           Py_Initialize ();
1659           err = PyRun_SimpleString ("import itertools\n");
1660           Py_Finalize ();
1661           return err == 0 ? 0 : 1;]),
1662        [dynamic_list=true], [], [true])
1663      CFLAGS="$old_CFLAGS"
1664    fi
1665    LDFLAGS="$old_LDFLAGS"
1666 fi
1667 if $dynamic_list; then
1668   found="-Wl,--dynamic-list"
1669   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1670 else
1671   found="-rdynamic"
1672   RDYNAMIC="-rdynamic"
1673 fi
1674 AC_SUBST(RDYNAMIC)
1675 AC_MSG_RESULT($found)
1676
1677 dnl For certain native configurations, we need to check whether thread
1678 dnl support can be built in or not.
1679 dnl
1680 dnl Note that we only want this if we are both native (host == target),
1681 dnl and not doing a canadian cross build (build == host).
1682
1683 if test ${build} = ${host} -a ${host} = ${target} ; then
1684    case ${host_os} in
1685    solaris*)
1686       # See if thread_db library is around for Solaris thread debugging.
1687       # Note that we must explicitly test for version 1 of the library
1688       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1689       # the same API.
1690       AC_MSG_CHECKING(for Solaris thread debugging library)
1691       if test -f /usr/lib/libthread_db.so.1 ; then
1692          AC_MSG_RESULT(yes)
1693          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1694          [Define if using Solaris thread debugging.])
1695          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1696          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1697          AC_CHECK_LIB(dl, dlopen)
1698          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1699          # Sun randomly tweaked the prototypes in <proc_service.h>
1700          # at one point.
1701          AC_MSG_CHECKING(if <proc_service.h> is old)
1702          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1703             AC_TRY_COMPILE([
1704                 #include <proc_service.h>
1705                 ps_err_e ps_pdwrite
1706                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1707             ],, gdb_cv_proc_service_is_old=no,
1708                 gdb_cv_proc_service_is_old=yes)
1709          ])
1710          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1711          if test $gdb_cv_proc_service_is_old = yes; then
1712             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1713             [Define if <proc_service.h> on solaris uses int instead of
1714              size_t, and assorted other type changes.])
1715          fi
1716       else
1717          AC_MSG_RESULT(no)
1718       fi
1719       ;;
1720    aix*)
1721       AC_MSG_CHECKING(for AiX thread debugging library)
1722       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1723                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1724                                    [#ifndef PTHDB_VERSION_3
1725                                     #error
1726                                     #endif],
1727                                    gdb_cv_have_aix_thread_debug=yes,
1728                                    gdb_cv_have_aix_thread_debug=no)])
1729       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1730       if test $gdb_cv_have_aix_thread_debug = yes; then
1731          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1732          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1733          LIBS="$LIBS -lpthdebug"
1734
1735          # Older versions of AIX do not provide the declaration for
1736          # the getthrds function (it appears that it was introduced
1737          # with AIX 6.x).
1738          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1739       fi
1740       ;;
1741    esac
1742    AC_SUBST(CONFIG_LDFLAGS)
1743 fi
1744
1745 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1746 dnl other error codes.
1747 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1748    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1749                   gdb_cv_thread_db_h_has_td_notalloc,
1750      AC_TRY_COMPILE(
1751        [#include <thread_db.h>],
1752        [int i = TD_NOTALLOC;],
1753        gdb_cv_thread_db_h_has_td_notalloc=yes,
1754        gdb_cv_thread_db_h_has_td_notalloc=no
1755      )
1756    )
1757    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1758                   gdb_cv_thread_db_h_has_td_version,
1759      AC_TRY_COMPILE(
1760        [#include <thread_db.h>],
1761        [int i = TD_VERSION;],
1762        gdb_cv_thread_db_h_has_td_version=yes,
1763        gdb_cv_thread_db_h_has_td_version=no
1764      )
1765    )
1766    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1767                   gdb_cv_thread_db_h_has_td_notls,
1768      AC_TRY_COMPILE(
1769        [#include <thread_db.h>],
1770        [int i = TD_NOTLS;],
1771        gdb_cv_thread_db_h_has_td_notls=yes,
1772        gdb_cv_thread_db_h_has_td_notls=no
1773      )
1774    )
1775 fi
1776 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1777   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1778             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1779 fi
1780 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1781   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1782             [Define if <thread_db.h> has the TD_VERSION error code.])
1783 fi
1784 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1785   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1786             [Define if <thread_db.h> has the TD_NOTLS error code.])
1787 fi
1788
1789 dnl See if we have a sys/syscall header file that has __NR_tkill.
1790 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1791    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1792                   gdb_cv_sys_syscall_h_has_tkill,
1793      AC_TRY_COMPILE(
1794        [#include <sys/syscall.h>],
1795        [int i = __NR_tkill;],
1796        gdb_cv_sys_syscall_h_has_tkill=yes,
1797        gdb_cv_sys_syscall_h_has_tkill=no
1798      )
1799    )
1800 fi
1801 dnl See if we can issue tkill syscall.
1802 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1803   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1804 fi
1805
1806 dnl Check if we can disable the virtual address space randomization.
1807 dnl The functionality of setarch -R.
1808 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1809 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1810 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1811 #       define ADDR_NO_RANDOMIZE 0x0040000
1812 #      endif
1813        /* Test the flag could be set and stays set.  */
1814        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1815        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1816            return 1])])
1817 AC_RUN_IFELSE([PERSONALITY_TEST],
1818               [have_personality=true],
1819               [have_personality=false],
1820               [AC_LINK_IFELSE([PERSONALITY_TEST],
1821                               [have_personality=true],
1822                               [have_personality=false])])
1823 if $have_personality
1824 then
1825     AC_DEFINE([HAVE_PERSONALITY], 1,
1826               [Define if you support the personality syscall.])
1827 fi
1828
1829 dnl Handle optional features that can be enabled.
1830
1831 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1832 # except that the argument to --with-sysroot is optional.
1833 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1834 if test "x$with_sysroot" = xyes; then
1835   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1836 fi
1837 AC_ARG_WITH(sysroot,
1838   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1839                  [search for usr/lib et al within DIR]),
1840   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1841 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1842               [search for usr/lib et al within DIR])
1843 AC_SUBST(TARGET_SYSTEM_ROOT)
1844 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1845
1846 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1847     [automatically load a system-wide gdbinit file],
1848     [])
1849
1850 AC_ARG_ENABLE(werror,
1851   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1852   [case "${enableval}" in
1853      yes | y) ERROR_ON_WARNING="yes" ;;
1854      no | n)  ERROR_ON_WARNING="no" ;;
1855      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1856    esac])
1857
1858 # Enable -Werror by default when using gcc.  Turn it off for releases.
1859 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1860     ERROR_ON_WARNING=yes
1861 fi
1862
1863 WERROR_CFLAGS=""
1864 if test "${ERROR_ON_WARNING}" = yes ; then
1865     WERROR_CFLAGS="-Werror"
1866 fi
1867
1868 # The entries after -Wno-pointer-sign are disabled warnings which may
1869 # be enabled in the future, which can not currently be used to build
1870 # GDB.
1871 # NOTE: If you change this list, remember to update
1872 # gdb/doc/gdbint.texinfo.
1873 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1874 -Wformat-nonliteral -Wno-pointer-sign \
1875 -Wno-unused -Wunused-value -Wunused-function \
1876 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1877 -Wdeclaration-after-statement"
1878
1879 # Enable -Wno-format by default when using gcc on mingw since many
1880 # GCC versions complain about %I64.
1881 case "${host}" in
1882   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1883 esac
1884
1885 AC_ARG_ENABLE(build-warnings,
1886 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1887 [case "${enableval}" in
1888   yes)  ;;
1889   no)   build_warnings="-w";;
1890   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1891         build_warnings="${build_warnings} ${t}";;
1892   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1893         build_warnings="${t} ${build_warnings}";;
1894   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1895 esac
1896 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1897   echo "Setting compiler warning flags = $build_warnings" 6>&1
1898 fi])dnl
1899 AC_ARG_ENABLE(gdb-build-warnings,
1900 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1901 [case "${enableval}" in
1902   yes)  ;;
1903   no)   build_warnings="-w";;
1904   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1905         build_warnings="${build_warnings} ${t}";;
1906   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1907         build_warnings="${t} ${build_warnings}";;
1908   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1909 esac
1910 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1911   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1912 fi])dnl
1913 WARN_CFLAGS=""
1914 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1915 then
1916     AC_MSG_CHECKING(compiler warning flags)
1917     # Separate out the -Werror flag as some files just cannot be
1918     # compiled with it enabled.
1919     for w in ${build_warnings}; do
1920         case $w in
1921         -Werr*) WERROR_CFLAGS=-Werror ;;
1922         *) # Check that GCC accepts it
1923             saved_CFLAGS="$CFLAGS"
1924             CFLAGS="$CFLAGS $w"
1925             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1926             CFLAGS="$saved_CFLAGS"
1927         esac
1928     done
1929     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1930 fi
1931 AC_SUBST(WARN_CFLAGS)
1932 AC_SUBST(WERROR_CFLAGS)
1933
1934 # In the Cygwin environment, we need some additional flags.
1935 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1936 [AC_EGREP_CPP(lose, [
1937 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1938 lose
1939 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1940
1941
1942 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1943 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1944 case ${host} in
1945   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1946   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1947   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1948 esac
1949 AC_SUBST(SER_HARDWIRE)
1950
1951 # libreadline needs libuser32.a in a cygwin environment
1952 WIN32LIBS=
1953 if test x$gdb_cv_os_cygwin = xyes; then
1954     WIN32LIBS="-luser32"
1955     case "${target}" in
1956         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1957         ;;
1958     esac
1959 fi
1960
1961 # The ser-tcp.c module requires sockets.
1962 case ${host} in
1963   *mingw32*)
1964     AC_DEFINE(USE_WIN32API, 1,
1965               [Define if we should use the Windows API, instead of the
1966                POSIX API.  On Windows, we use the Windows API when
1967                building for MinGW, but the POSIX API when building
1968                for Cygwin.])
1969     WIN32LIBS="$WIN32LIBS -lws2_32"
1970     ;;
1971 esac
1972 AC_SUBST(WIN32LIBS)
1973
1974 # Add ELF support to GDB, but only if BFD includes ELF support.
1975 OLD_CFLAGS=$CFLAGS
1976 OLD_LDFLAGS=$LDFLAGS
1977 OLD_LIBS=$LIBS
1978 # Put the old CFLAGS/LDFLAGS last, in case the user's (C|LD)FLAGS
1979 # points somewhere with bfd, with -I/foo/lib and -L/foo/lib.  We
1980 # always want our bfd.
1981 CFLAGS="-I${srcdir}/../include -I../bfd -I${srcdir}/../bfd $CFLAGS"
1982 LDFLAGS="-L../bfd -L../libiberty $LDFLAGS"
1983 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1984 # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1985 if test "$plugins" = "yes"; then
1986   LIBS="-ldl $LIBS"
1987 fi
1988 LIBS="-lbfd -liberty $intl $LIBS"
1989 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1990 [AC_TRY_LINK(
1991 [#include <stdlib.h>
1992 #include "bfd.h"
1993 #include "elf-bfd.h"
1994 ],
1995 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1996 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1997 if test $gdb_cv_var_elf = yes; then
1998   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
1999   AC_DEFINE(HAVE_ELF, 1,
2000             [Define if ELF support should be included.])
2001   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2002   if test "$plugins" = "yes"; then
2003     OLD_LIBS="-ldl $OLD_LIBS"
2004   fi
2005 fi
2006 CFLAGS=$OLD_CFLAGS
2007 LDFLAGS=$OLD_LDFLAGS
2008 LIBS=$OLD_LIBS
2009
2010 # Add any host-specific objects to GDB.
2011 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2012
2013 LIBGUI="../libgui/src/libgui.a"
2014 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2015 AC_SUBST(LIBGUI)
2016 AC_SUBST(GUI_CFLAGS_X)
2017
2018 WIN32LDAPP=
2019 AC_SUBST(WIN32LIBS)
2020 AC_SUBST(WIN32LDAPP)
2021
2022 case "${host}" in
2023 *-*-cygwin* | *-*-mingw* )
2024     configdir="win"
2025     ;;
2026 *)
2027     configdir="unix"
2028     ;;
2029 esac
2030
2031 GDBTKLIBS=
2032 if test "${enable_gdbtk}" = "yes"; then
2033
2034     # Gdbtk must have an absolute path to srcdir in order to run
2035     # properly when not installed.
2036     here=`pwd`
2037     cd ${srcdir}
2038     GDBTK_SRC_DIR=`pwd`
2039     cd $here
2040
2041     SC_PATH_TCLCONFIG
2042
2043     # If $no_tk is nonempty, then we can't do Tk, and there is no
2044     # point to doing Tcl.
2045     SC_PATH_TKCONFIG
2046
2047     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2048         SC_LOAD_TCLCONFIG
2049
2050         # Check for in-tree tcl
2051         here=`pwd`
2052         cd ${srcdir}/..
2053         topdir=`pwd`
2054         cd ${here}
2055
2056         intree="no"
2057         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2058           intree="yes"
2059         fi
2060
2061         # Find Tcl private headers
2062         if test x"${intree}" = xno; then
2063           CY_AC_TCL_PRIVATE_HEADERS
2064           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2065           TCL_LIBRARY="${TCL_LIB_SPEC}"
2066           TCL_DEPS=""
2067         else
2068           # If building tcl in the same src tree, private headers
2069           # are not needed, but we need to be sure to use the right
2070           # headers library
2071           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2072           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2073           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2074         fi
2075         AC_SUBST(TCL_INCLUDE)
2076         AC_SUBST(TCL_LIBRARY)
2077         AC_SUBST(TCL_DEPS)
2078
2079         SC_LOAD_TKCONFIG
2080
2081         # Check for in-tree Tk
2082         intree="no"
2083         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2084           intree="yes"
2085         fi
2086
2087         # Find Tk private headers
2088         if test x"${intree}" = xno; then
2089           CY_AC_TK_PRIVATE_HEADERS
2090           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2091           TK_LIBRARY=${TK_LIB_SPEC}
2092           TK_DEPS=""
2093         else
2094           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2095           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2096           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2097         fi
2098         AC_SUBST(TK_INCLUDE)
2099         AC_SUBST(TK_LIBRARY)
2100         AC_SUBST(TK_DEPS)
2101         AC_SUBST(TK_XINCLUDES)
2102
2103         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2104
2105         # Include some libraries that Tcl and Tk want.
2106         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2107         # Yes, the ordering seems wrong here.  But it isn't.
2108         # TK_LIBS is the list of libraries that need to be linked
2109         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2110         # were in LIBS then any link tests after this point would
2111         # try to include things like `$(LIBGUI)', which wouldn't work.
2112         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2113
2114         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2115         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2116         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2117         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2118         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2119         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2120         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2121
2122         if test x$gdb_cv_os_cygwin = xyes; then
2123           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2124           WIN32LDAPP="-Wl,--subsystem,console"
2125           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2126         fi
2127
2128         AC_CONFIG_SUBDIRS(gdbtk)
2129     fi
2130 fi
2131
2132 AC_SUBST(X_CFLAGS)
2133 AC_SUBST(X_LDFLAGS)
2134 AC_SUBST(X_LIBS)
2135 AC_SUBST(GDBTKLIBS)
2136 AC_SUBST(GDBTK_CFLAGS)
2137 AC_SUBST(GDBTK_SRC_DIR)
2138
2139 AC_PATH_X
2140
2141 # Unlike the sim directory, whether a simulator is linked is controlled by
2142 # presence of a gdb_sim definition in the target configure.tgt entry.
2143 # This code just checks for a few cases where we'd like to ignore those
2144 # definitions, even when they're present in the '.mt' file.  These cases
2145 # are when --disable-sim is specified, or if the simulator directory is
2146 # not part of the source tree.
2147 #
2148 AC_ARG_ENABLE(sim,
2149 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2150 [echo "enable_sim = $enable_sim";
2151  echo "enableval = ${enableval}";
2152  case "${enableval}" in
2153   yes) ignore_sim=false ;;
2154   no)  ignore_sim=true ;;
2155   *)   ignore_sim=false ;;
2156  esac],
2157 [ignore_sim=false])
2158
2159 if test ! -d "${srcdir}/../sim"; then
2160   ignore_sim=true
2161 fi
2162
2163 SIM=
2164 SIM_OBS=
2165 if test "${ignore_sim}" = "false"; then
2166   if test x"${gdb_sim}" != x ; then
2167     SIM="${gdb_sim}"
2168     SIM_OBS="remote-sim.o"
2169     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2170   fi
2171 fi
2172 AC_SUBST(SIM)
2173 AC_SUBST(SIM_OBS)
2174
2175 AC_SUBST(ENABLE_CFLAGS)
2176 AC_SUBST(PROFILE_CFLAGS)
2177
2178 AC_SUBST(CONFIG_OBS)
2179 AC_SUBST(CONFIG_DEPS)
2180 AC_SUBST(CONFIG_SRCS)
2181 AC_SUBST(CONFIG_ALL)
2182 AC_SUBST(CONFIG_CLEAN)
2183 AC_SUBST(CONFIG_INSTALL)
2184 AC_SUBST(CONFIG_UNINSTALL)
2185
2186 # List of host floatformats.
2187 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2188 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2189 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2190
2191 # target_subdir is used by the testsuite to find the target libraries.
2192 target_subdir=
2193 if test "${host}" != "${target}"; then
2194     target_subdir="${target_alias}/"
2195 fi
2196 AC_SUBST(target_subdir)
2197
2198 frags=
2199 if test "${gdb_native}" = "yes"; then
2200   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2201   if test ! -f ${host_makefile_frag}; then
2202     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2203   fi
2204   frags="$frags $host_makefile_frag"
2205 else
2206   host_makefile_frag=/dev/null
2207 fi
2208
2209 AC_SUBST_FILE(host_makefile_frag)
2210 AC_SUBST(frags)
2211
2212 changequote(,)dnl
2213 if test "${gdb_native}" = "yes"; then
2214 # We pick this up from the host configuration file (.mh) because we
2215 # do not have a native configuration Makefile fragment.
2216 nativefile=`sed -n '
2217 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2218 ' ${host_makefile_frag}`
2219 fi
2220 changequote([,])
2221
2222 if test x"${gdb_osabi}" != x ; then
2223     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2224                        [Define to the default OS ABI for this configuration.])
2225 fi
2226
2227 # Enable multi-ice-gdb-server.
2228 AC_ARG_ENABLE(multi-ice,
2229 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2230   [case $enableval in
2231     yes | no)
2232       ;;
2233     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2234   esac])
2235 if test "x$enable_multi_ice" = xyes; then
2236    AC_CONFIG_SUBDIRS(multi-ice)
2237 fi
2238
2239 AC_ARG_ENABLE(gdbserver,
2240 AS_HELP_STRING([--enable-gdbserver],
2241                [automatically build gdbserver (yes/no/auto, default is auto)]),
2242 [case "${enableval}" in
2243   yes| no|auto) ;;
2244   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2245 esac],[enable_gdbserver=auto])
2246
2247 # We only build gdbserver automatically in a native configuration, and
2248 # only if the user did not explicitly disable its build.
2249 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2250   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2251   if test "x$build_gdbserver" = xyes; then
2252     AC_MSG_RESULT(yes)
2253     AC_CONFIG_SUBDIRS(gdbserver)
2254     gdbserver_build_enabled=yes
2255   else
2256     AC_MSG_RESULT(no)
2257   fi
2258 fi
2259
2260 # If the user explicitly request the gdbserver to be built, verify that
2261 # we were in fact able to enable it.
2262 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2263   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2264 fi
2265
2266 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2267 # to an empty version.
2268
2269 files=
2270 links=
2271
2272 rm -f nm.h
2273 if test "${nativefile}" != ""; then
2274     case "${nativefile}" in
2275       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2276       * ) GDB_NM_FILE="${nativefile}"
2277     esac
2278     files="${files} ${GDB_NM_FILE}"
2279     links="${links} nm.h"
2280     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2281 fi
2282 AC_SUBST(GDB_NM_FILE)
2283
2284 AC_LINK_FILES($files, $links)
2285
2286 dnl Check for exe extension set on certain hosts (e.g. Win32)
2287 AC_EXEEXT
2288
2289 dnl  Detect the character set used by this host.
2290 dnl  At the moment, we just assume it's UTF-8.
2291 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2292           [Define to be a string naming the default host character set.])
2293
2294 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2295 [
2296 case x$CONFIG_HEADERS in
2297 xconfig.h:config.in)
2298 echo > stamp-h ;;
2299 esac
2300 ])
2301
2302 exit 0