gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   3 dnl 2005, 2006, 2007, 2008, 2009
   4 dnl Free Software Foundation, Inc.
   5 dnl
   6 dnl This file is part of GDB.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or modify
   9 dnl it under the terms of the GNU General Public License as published by
  10 dnl the Free Software Foundation; either version 3 of the License, or
  11 dnl (at your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful,
  14 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl GNU General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_USE_SYSTEM_EXTENSIONS
  30 gl_EARLY
  31 AM_PROG_CC_STDC
  32
  33 AC_CONFIG_AUX_DIR(..)
  34 AC_CANONICAL_SYSTEM
  35
  36 # Dependency checking.
  37 ZW_CREATE_DEPDIR
  38 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  39
  40 # Check for the 'make' the user wants to use.
  41 AC_CHECK_PROGS(MAKE, make)
  42 MAKE_IS_GNU=
  43 case "`$MAKE --version 2>&1 | sed 1q`" in
  44   *GNU*)
  45     MAKE_IS_GNU=yes
  46     ;;
  47 esac
  48 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  49 AC_PROG_MAKE_SET
  50
  51 dnl List of object files and targets accumulated by configure.
  52
  53 CONFIG_OBS=
  54 CONFIG_DEPS=
  55 CONFIG_SRCS=
  56 ENABLE_CFLAGS=
  57
  58 CONFIG_ALL=
  59 CONFIG_CLEAN=
  60 CONFIG_INSTALL=
  61 CONFIG_UNINSTALL=
  62
  63 dnl Set up for gettext.
  64 ZW_GNU_GETTEXT_SISTER_DIR
  65
  66 localedir='${datadir}/locale'
  67 AC_SUBST(localedir)
  68
  69 if test x"$USE_NLS" = xyes; then
  70    CONFIG_ALL="$CONFIG_ALL all-po"
  71    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  72    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  73    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  74 fi
  75
  76 gl_INIT
  77
  78 # For Makefile dependencies.
  79 GNULIB_STDINT_H=
  80 if test x"$STDINT_H" != x; then
  81   GNULIB_STDINT_H=gnulib/$STDINT_H
  82 fi
  83 AC_SUBST(GNULIB_STDINT_H)
  84
  85 PACKAGE=gdb
  86 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  87 AC_SUBST(PACKAGE)
  88
  89 # GDB does not use automake, but gnulib does.  This line lets us
  90 # generate its Makefile.in.
  91 AM_INIT_AUTOMAKE(gdb, UNUSED-VERSION, [no-define])
  92
  93 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  94     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  95     [${libdir}/debug])
  96
  97 # GDB's datadir relocation
  98
  99 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 100     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 101     [${datadir}/gdb])
 102
 103 AC_ARG_WITH(relocated-sources,
 104 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 105 [reloc_srcdir="${withval}"
 106  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 107               [Relocated directory for source files. ])
 108 ])
 109
 110 AC_CONFIG_SUBDIRS(doc testsuite)
 111
 112 # Check whether to support alternative target configurations
 113 AC_ARG_ENABLE(targets,
 114 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 115 [case "${enableval}" in
 116   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 117             ;;
 118   no)       enable_targets= ;;
 119   *)        enable_targets=$enableval ;;
 120 esac])
 121
 122 # Check whether to enable 64-bit support on 32-bit hosts
 123 AC_ARG_ENABLE(64-bit-bfd,
 124 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 125 [case "${enableval}" in
 126   yes)  want64=true  ;;
 127   no)   want64=false ;;
 128   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 129 esac],[want64=false])dnl
 130
 131 # Provide defaults for some variables set by the per-host and per-target
 132 # configuration.
 133 gdb_host_obs=posix-hdep.o
 134
 135 if test "${target}" = "${host}"; then
 136   gdb_native=yes
 137 else
 138   gdb_native=no
 139 fi
 140
 141 . $srcdir/configure.host
 142
 143 # Accumulate some settings from configure.tgt over all enabled targets
 144
 145 TARGET_OBS=
 146 all_targets=
 147
 148 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 149 do
 150   if test "$targ_alias" = "all"; then
 151     all_targets=true
 152   else
 153     # Canonicalize the secondary target names.
 154     result=`$ac_config_sub $targ_alias 2>/dev/null`
 155     if test -n "$result"; then
 156         targ=$result
 157     else
 158         targ=$targ_alias
 159     fi
 160
 161     . ${srcdir}/configure.tgt
 162
 163     # Target-specific object files
 164     for i in ${gdb_target_obs}; do
 165         case " $TARGET_OBS " in
 166         *" ${i} "*) ;;
 167         *)
 168           TARGET_OBS="$TARGET_OBS ${i}"
 169           ;;
 170         esac
 171     done
 172
 173     # Check whether this target needs 64-bit CORE_ADDR
 174     if test x${want64} = xfalse; then
 175       . ${srcdir}/../bfd/config.bfd
 176     fi
 177   fi
 178 done
 179
 180 if test x${all_targets} = xtrue; then
 181
 182   # We want all 64-bit targets if we either:
 183   #  - run on a 64-bit host  or
 184   #  - already require 64-bit support for some other target  or
 185   #  - the --enable-64-bit-bfd option was supplied
 186   # Otherwise we only support all 32-bit targets.
 187   #
 188   # NOTE: This test must be in sync with the corresponding
 189   #       tests in BFD!
 190
 191   if test x${want64} = xfalse; then
 192     AC_CHECK_SIZEOF(long)
 193     if test "x${ac_cv_sizeof_long}" = "x8"; then
 194       want64=true
 195     fi
 196   fi
 197   if test x${want64} = xtrue; then
 198     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 199   else
 200     TARGET_OBS='$(ALL_TARGET_OBS)'
 201   fi
 202 fi
 203
 204 AC_SUBST(TARGET_OBS)
 205
 206 # For other settings, only the main target counts.
 207 gdb_sim=
 208 gdb_osabi=
 209 build_gdbserver=
 210 targ=$target; . ${srcdir}/configure.tgt
 211
 212 # Fetch the default architecture and default target vector from BFD.
 213 targ=$target; . $srcdir/../bfd/config.bfd
 214
 215 # We only want the first architecture, so strip off the others if
 216 # there is more than one.
 217 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 218
 219 if test "x$targ_archs" != x; then
 220   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 221     [Define to BFD's default architecture. ])
 222 fi
 223 if test "x$targ_defvec" != x; then
 224   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 225     [Define to BFD's default target vector. ])
 226 fi
 227
 228 # The CLI cannot be disabled yet, but may be in the future.
 229
 230 # Enable CLI.
 231 AC_ARG_ENABLE(gdbcli,
 232 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 233   [case $enableval in
 234     yes)
 235       ;;
 236     no)
 237       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 238     *)
 239       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 240   esac],
 241   [enable_gdbcli=yes])
 242 if test x"$enable_gdbcli" = xyes; then
 243   if test -d $srcdir/cli; then
 244     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 245     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 246     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 247     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 248   fi
 249 fi
 250
 251 # Enable MI.
 252 AC_ARG_ENABLE(gdbmi,
 253 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 254   [case $enableval in
 255     yes | no)
 256       ;;
 257     *)
 258       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 259   esac],
 260   [enable_gdbmi=yes])
 261 if test x"$enable_gdbmi" = xyes; then
 262   if test -d $srcdir/mi; then
 263     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 264     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 265     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 266     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 267   fi
 268 fi
 269
 270 # Enable TUI.
 271 AC_ARG_ENABLE(tui,
 272 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 273   [case $enableval in
 274     yes | no | auto)
 275       ;;
 276     *)
 277       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 278   esac],enable_tui=auto)
 279
 280 # Enable gdbtk.
 281 AC_ARG_ENABLE(gdbtk,
 282 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 283   [case $enableval in
 284     yes | no)
 285       ;;
 286     *)
 287       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 288   esac],
 289   [if test -d $srcdir/gdbtk; then
 290     enable_gdbtk=yes
 291   else
 292     enable_gdbtk=no
 293   fi])
 294 # We unconditionally disable gdbtk tests on selected platforms.
 295 case $host_os in
 296   go32* | windows*)
 297     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 298     enable_gdbtk=no ;;
 299 esac
 300
 301 # Libunwind support.
 302 AC_ARG_WITH(libunwind,
 303 AS_HELP_STRING([--with-libunwind], [use libunwind frame unwinding support]),
 304 [case "${withval}" in
 305   yes)  enable_libunwind=yes ;;
 306   no)   enable_libunwind=no ;;
 307   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 308 esac],[
 309   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 310   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 311     enable_libunwind=yes;
 312   fi
 313 ])
 314
 315 if test x"$enable_libunwind" = xyes; then
 316   AC_CHECK_HEADERS(libunwind.h libunwind-ia64.h)
 317   AC_DEFINE(HAVE_LIBUNWIND, 1, [Define if libunwind library is being used.])
 318   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 319   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 320   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 321 fi
 322
 323 opt_curses=no
 324 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 325
 326 prefer_curses=no
 327 if test "$opt_curses" = "yes"; then
 328   prefer_curses=yes
 329 fi
 330
 331 # Profiling support.
 332 AC_ARG_ENABLE(profiling,
 333 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 334   [case $enableval in
 335     yes | no)
 336       ;;
 337     *)
 338       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 339   esac],
 340  [enable_profiling=no])
 341
 342 AC_CHECK_FUNCS(monstartup _mcleanup)
 343 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 344 [AC_TRY_LINK(
 345 [#include <stdlib.h>
 346 extern char _etext;
 347 ],
 348 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 349 if test $ac_cv_var__etext = yes; then
 350   AC_DEFINE(HAVE__ETEXT, 1,
 351             [Define to 1 if your system has the _etext variable. ])
 352 fi
 353 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 354 [AC_TRY_LINK(
 355 [#include <stdlib.h>
 356 extern char etext;
 357 ],
 358 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 359 if test $ac_cv_var_etext = yes; then
 360   AC_DEFINE(HAVE_ETEXT, 1,
 361             [Define to 1 if your system has the etext variable. ])
 362 fi
 363 if test "$enable_profiling" = yes ; then
 364   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 365     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 366   fi
 367   PROFILE_CFLAGS=-pg
 368   OLD_CFLAGS="$CFLAGS"
 369   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 370
 371   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 372     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 373      ac_cv_cc_supports_pg=no)])
 374
 375   if test $ac_cv_cc_supports_pg = no; then
 376     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 377   fi
 378
 379   CFLAGS="$OLD_CFLAGS"
 380 fi
 381
 382 ACX_PKGVERSION([GDB])
 383 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 384 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 385 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 386
 387 # --------------------- #
 388 # Checks for programs.  #
 389 # --------------------- #
 390
 391 AC_PROG_AWK
 392 AC_PROG_INSTALL
 393 AC_PROG_LN_S
 394 AC_PROG_RANLIB
 395 AC_PROG_YACC
 396
 397 AC_CHECK_TOOL(AR, ar)
 398 AC_CHECK_TOOL(DLLTOOL, dlltool)
 399 AC_CHECK_TOOL(WINDRES, windres)
 400
 401 # Needed for GNU/Hurd.
 402 AC_CHECK_TOOL(MIG, mig)
 403
 404 # ---------------------- #
 405 # Checks for libraries.  #
 406 # ---------------------- #
 407
 408 # We might need to link with -lm; most simulators need it.
 409 AC_CHECK_LIB(m, main)
 410
 411 # We need to link with -lw to get `wctype' on Solaris before Solaris
 412 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 413 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 414 # is known to have this problem).  Therefore we avoid libw if we can.
 415 AC_CHECK_FUNC(wctype, [],
 416   [AC_CHECK_LIB(w, wctype)])
 417
 418 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 419 AC_SEARCH_LIBS(gethostbyname, nsl)
 420
 421 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 422 AC_SEARCH_LIBS(socketpair, socket)
 423
 424 # Link in zlib if we can.  This allows us to read compressed debug sections.
 425 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 426
 427 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 428 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 429
 430 AM_ICONV
 431
 432 # On alpha-osf, it appears that libtermcap and libcurses are not compatible.
 433 # There is a very specific comment in /usr/include/curses.h explaining that
 434 # termcap routines built into libcurses must not be used.
 435 #
 436 # The symptoms we observed so far is GDB unexpectedly changing
 437 # the terminal settings when tgetent is called - this is particularly
 438 # visible as the output is missing carriage returns, and so rapidly
 439 # becomes very hard to read.
 440 #
 441 # The readline configure script has already decided that libtermcap
 442 # was enough for its purposes, and so decided to build readline using
 443 # libtermcap.  Since the TUI mode requires curses, building GDB with
 444 # TUI enabled results in both libraries to be used at the same time,
 445 # which is not allowed.  This basically means that GDB with TUI is
 446 # broken on alpha-osf.
 447
 448 case $host_os in
 449   alpha*-*-osf* )
 450     if "$enable_tui" = "yes"; then
 451       AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host])
 452     fi
 453     if "$enable_tui" = "auto"; then
 454       enable_tui=no
 455     fi
 456     ;;
 457 esac
 458
 459 # For the TUI, we need enhanced curses functionality.
 460 if test x"$enable_tui" != xno; then
 461   prefer_curses=yes
 462 fi
 463
 464 curses_found=no
 465 if test x"$prefer_curses" = xyes; then
 466   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 467   # curses library because the latter might not provide all the
 468   # functionality we need.  However, this leads to problems on systems
 469   # where the linker searches /usr/local/lib, but the compiler doesn't
 470   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 471   # default installation of ncurses on alpha*-dec-osf* will lead to such
 472   # a situation.
 473   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 474
 475   if test "$ac_cv_search_waddstr" != no; then
 476     curses_found=yes
 477   fi
 478 fi
 479
 480 # Check whether we should enable the TUI, but only do so if we really
 481 # can.
 482 if test x"$enable_tui" != xno; then
 483   if test -d $srcdir/tui; then
 484     if test "$curses_found" != no; then
 485       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 486       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 487       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 488       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 489       CONFIG_ALL="${CONFIG_ALL} all-tui"
 490       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 491       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 492       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 493     else
 494       if test x"$enable_tui" = xyes; then
 495         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 496       else
 497         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 498       fi
 499     fi
 500   fi
 501 fi
 502
 503 # Since GDB uses Readline, we need termcap functionality.  In many
 504 # cases this will be provided by the curses library, but some systems
 505 # have a seperate termcap library, or no curses library at all.
 506
 507 case $host_os in
 508   cygwin*)
 509     if test -d $srcdir/libtermcap; then
 510       LIBS="../libtermcap/libtermcap.a $LIBS"
 511       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 512     fi ;;
 513   go32* | *djgpp*)
 514     ac_cv_search_tgetent="none required"
 515     ;;
 516   *mingw32*)
 517     ac_cv_search_tgetent="none required"
 518     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 519     ;;
 520 esac
 521
 522 # These are the libraries checked by Readline.
 523 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 524
 525 if test "$ac_cv_search_tgetent" = no; then
 526   AC_MSG_ERROR([no termcap library found])
 527 fi
 528
 529 AC_ARG_WITH([system-readline],
 530   [AS_HELP_STRING([--with-system-readline],
 531                   [use installed readline library])])
 532
 533 if test "$with_system_readline" = yes; then
 534   READLINE=-lreadline
 535   READLINE_DEPS=
 536   READLINE_CFLAGS=
 537
 538   # readline-6.0 started to use the name `_rl_echoing_p'.
 539   # `$(READLINE_DIR)/' of bundled readline would not resolve in configure.
 540
 541   AC_MSG_CHECKING([for readline_echoing_p])
 542   save_LIBS=$LIBS
 543   LIBS="$LIBS $READLINE"
 544   AC_LINK_IFELSE(AC_LANG_PROGRAM(,[[extern int readline_echoing_p;
 545                                     return readline_echoing_p;]]),
 546                  [READLINE_ECHOING_P=yes],
 547                  [READLINE_ECHOING_P=no
 548                   AC_DEFINE([readline_echoing_p], [_rl_echoing_p],
 549                             [readline-6.0 started to use different name.])])
 550   LIBS="$save_LIBS"
 551   AC_MSG_RESULT([$READLINE_ECHOING_P])
 552 else
 553   READLINE='$(READLINE_DIR)/libreadline.a'
 554   READLINE_DEPS='$(READLINE)'
 555   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 556 fi
 557 AC_SUBST(READLINE)
 558 AC_SUBST(READLINE_DEPS)
 559 AC_SUBST(READLINE_CFLAGS)
 560
 561 AC_ARG_WITH(expat,
 562   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 563   [], [with_expat=auto])
 564 AC_MSG_CHECKING([whether to use expat])
 565 AC_MSG_RESULT([$with_expat])
 566
 567 if test "${with_expat}" = no; then
 568   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 569   HAVE_LIBEXPAT=no
 570 else
 571   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 572                         [XML_Parser p = XML_ParserCreate (0);])
 573   if test "$HAVE_LIBEXPAT" != yes; then
 574     if test "$with_expat" = yes; then
 575       AC_MSG_ERROR([expat is missing or unusable])
 576     else
 577       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 578     fi
 579   else
 580     save_LIBS=$LIBS
 581     LIBS="$LIBS $LIBEXPAT"
 582     AC_CHECK_FUNCS(XML_StopParser)
 583     LIBS=$save_LIBS
 584   fi
 585 fi
 586
 587 dnl Utility to simplify finding libpython.
 588 AC_DEFUN([AC_TRY_LIBPYTHON],
 589 [
 590   version=$1
 591   define([have_libpython_var],$2)
 592   define([VERSION],[translit([$1],[abcdefghijklmnopqrstuvwxyz./-],
 593                                   [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])])
 594   [HAVE_LIB]VERSION=no
 595   AC_MSG_CHECKING([for ${version}])
 596   save_LIBS=$LIBS
 597   LIBS="$LIBS -l${version}"
 598   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "${version}/Python.h"]],
 599                                  [[Py_Initialize ();]]),
 600                  [[HAVE_LIB]VERSION=yes
 601                   have_libpython_var=yes],
 602                  [LIBS=$save_LIBS])
 603   AC_MSG_RESULT([$[HAVE_LIB]VERSION])
 604 ])
 605
 606 AC_ARG_WITH(python,
 607   AS_HELP_STRING([--with-python], [include python support (auto/yes/no/<path>)]),
 608   [], [with_python=auto])
 609 AC_MSG_CHECKING([whether to use python])
 610 AC_MSG_RESULT([$with_python])
 611
 612 if test "${with_python}" = no; then
 613   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 614   have_libpython=no
 615 else
 616   case "${with_python}" in
 617   yes | auto)
 618     # Leave as empty, use defaults.
 619     python_includes=
 620     python_libs=
 621     ;;
 622   /*)
 623     python_includes="-I${with_python}/include"
 624     python_libs="-L${with_python}/lib"
 625     ;;
 626   *)
 627     AC_ERROR(invalid value for --with-python)
 628     ;;
 629   esac
 630
 631   save_CPPFLAGS=$CPPFLAGS
 632   CPPFLAGS="$CPPFLAGS ${python_includes}"
 633   save_LIBS=$LIBS
 634   LIBS="$LIBS ${python_libs}"
 635   have_libpython=no
 636   if test "${have_libpython}" = no; then
 637     AC_TRY_LIBPYTHON(python2.6, have_libpython)
 638     if test "${HAVE_LIBPYTHON2_6}" = yes; then
 639       AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 640     fi
 641   fi
 642   if test ${have_libpython} = no; then
 643     AC_TRY_LIBPYTHON(python2.5, have_libpython)
 644     if test "${HAVE_LIBPYTHON2_5}" = yes; then
 645       AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 646     fi
 647   fi
 648   if test ${have_libpython} = no; then
 649     AC_TRY_LIBPYTHON(python2.4, have_libpython)
 650     if test "${HAVE_LIBPYTHON2_4}" = yes; then
 651       AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 652     fi
 653   fi
 654   if test ${have_libpython} = no; then
 655     case "${with_python}" in
 656     yes)
 657       AC_MSG_ERROR([python is missing or unusable])
 658       ;;
 659     auto)
 660       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 661       ;;
 662     *)
 663       AC_MSG_ERROR([no usable python found at ${with_python}])
 664       ;;
 665     esac
 666     CPPFLAGS=$save_CPPFLAGS
 667     LIBS=$save_LIBS
 668   fi
 669 fi
 670
 671 if test "${have_libpython}" = yes; then
 672   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 673   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 674   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 675   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 676   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 677
 678   # Flags needed to compile Python code (taken from python-config --cflags).
 679   # We cannot call python-config directly because it will output whatever was
 680   # used when compiling the Python interpreter itself, including flags which
 681   # would make the python-related objects be compiled differently from the
 682   # rest of GDB (e.g., -O2 and -fPIC).
 683   if test "${GCC}" = yes; then
 684     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 685   fi
 686
 687   if test "x${tentative_python_cflags}" != x; then
 688     AC_MSG_CHECKING(compiler flags for python code)
 689     for flag in ${tentative_python_cflags}; do
 690       # Check that the compiler accepts it
 691       saved_CFLAGS="$CFLAGS"
 692       CFLAGS="$CFLAGS $flag"
 693       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 694       CFLAGS="$saved_CFLAGS"
 695     done
 696     AC_MSG_RESULT(${PYTHON_CFLAGS})
 697   fi
 698 else
 699   # Even if Python support is not compiled in, we need to have these files
 700   # included in order to recognize the GDB command "python".
 701   CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o"
 702   CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c python/py-prettyprint.c"
 703 fi
 704 AC_SUBST(PYTHON_CFLAGS)
 705
 706 # ------------------------- #
 707 # Checks for header files.  #
 708 # ------------------------- #
 709
 710 AC_HEADER_DIRENT
 711 AC_HEADER_STAT
 712 AC_HEADER_STDC
 713 # elf_hp.h is for HP/UX 64-bit shared library support.
 714 # FIXME: kettenis/20030102: In most cases we include these (ctype.h, time.h)
 715 # unconditionally, so what's the point in checking these?
 716 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
 717                   thread_db.h gnu/libc-version.h signal.h stddef.h \
 718                   stdlib.h string.h memory.h strings.h sys/fault.h \
 719                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
 720                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
 721                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
 722                   sys/types.h sys/wait.h wait.h termios.h termio.h \
 723                   sgtty.h unistd.h elf_hp.h ctype.h time.h locale.h])
 724 AC_CHECK_HEADERS(link.h, [], [],
 725 [#if HAVE_SYS_TYPES_H
 726 # include <sys/types.h>
 727 #endif
 728 #if HAVE_NLIST_H
 729 # include <nlist.h>
 730 #endif
 731 ])
 732 AC_CHECK_HEADERS(sys/proc.h, [], [],
 733 [#if HAVE_SYS_PARAM_H
 734 # include <sys/param.h>
 735 #endif
 736 ])
 737 AC_CHECK_HEADERS(sys/user.h, [], [],
 738 [#if HAVE_SYS_PARAM_H
 739 # include <sys/param.h>
 740 #endif
 741 ])
 742
 743 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 744 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 745 # think that we don't have <curses.h> if we're using GCC.
 746 case $host_os in
 747   solaris2.[[789]])
 748     if test "$GCC" = yes; then
 749       AC_DEFINE(_MSE_INT_H, 1,
 750         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 751    Solaris 2.[789] when using GCC. ])
 752     fi ;;
 753 esac
 754 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
 755 AC_CHECK_HEADERS(term.h, [], [],
 756 [#if HAVE_CURSES_H
 757 # include <curses.h>
 758 #endif
 759 ])
 760
 761 # ------------------------- #
 762 # Checks for declarations.  #
 763 # ------------------------- #
 764
 765 AC_CHECK_DECLS([free, malloc, realloc, strerror, strstr, getopt,
 766                 snprintf, vsnprintf])
 767 AM_LC_MESSAGES
 768
 769 # ----------------------- #
 770 # Checks for structures.  #
 771 # ----------------------- #
 772
 773 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 774
 775 # ------------------ #
 776 # Checks for types.  #
 777 # ------------------ #
 778
 779 AC_TYPE_SIGNAL
 780 AC_CHECK_TYPES(socklen_t, [], [],
 781 [#include <sys/types.h>
 782 #include <sys/socket.h>
 783 ])
 784
 785 # ------------------------------------- #
 786 # Checks for compiler characteristics.  #
 787 # ------------------------------------- #
 788
 789 AC_C_CONST
 790 AC_C_INLINE
 791 AC_C_BIGENDIAN
 792
 793 # ------------------------------ #
 794 # Checks for library functions.  #
 795 # ------------------------------ #
 796
 797 AC_FUNC_ALLOCA
 798 AC_FUNC_MMAP
 799 AC_FUNC_VFORK
 800 AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid \
 801                 getgid pipe poll pread64 sbrk setpgid setpgrp setsid \
 802                 sigaction sigprocmask sigsetmask socketpair syscall \
 803                 ttrace wborder setlocale iconvlist libiconvlist btowc])
 804 AM_LANGINFO_CODESET
 805
 806 # Check the return and argument types of ptrace.  No canned test for
 807 # this, so roll our own.
 808 gdb_ptrace_headers='
 809 #if HAVE_SYS_TYPES_H
 810 # include <sys/types.h>
 811 #endif
 812 #if HAVE_SYS_PTRACE_H
 813 # include <sys/ptrace.h>
 814 #endif
 815 #if HAVE_UNISTD_H
 816 # include <unistd.h>
 817 #endif
 818 '
 819 # There is no point in checking if we don't have a prototype.
 820 AC_CHECK_DECLS(ptrace, [], [
 821   : ${gdb_cv_func_ptrace_ret='int'}
 822   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 823 ], $gdb_ptrace_headers)
 824 # Check return type.  Varargs (used on GNU/Linux) conflict with the
 825 # empty argument list, so check for that explicitly.
 826 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 827   AC_TRY_COMPILE($gdb_ptrace_headers,
 828     [extern long ptrace (enum __ptrace_request, ...);],
 829     gdb_cv_func_ptrace_ret='long',
 830     AC_TRY_COMPILE($gdb_ptrace_headers,
 831       [extern int ptrace ();],
 832       gdb_cv_func_ptrace_ret='int',
 833       gdb_cv_func_ptrace_ret='long')))
 834 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 835   [Define as the return type of ptrace.])
 836 # Check argument types.
 837 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 838   AC_TRY_COMPILE($gdb_ptrace_headers,
 839     [extern long ptrace (enum __ptrace_request, ...);],
 840     [gdb_cv_func_ptrace_args='int,int,long,long'],[
 841 for gdb_arg1 in 'int' 'long'; do
 842  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 843   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
 844    for gdb_arg4 in 'int' 'long'; do
 845      AC_TRY_COMPILE($gdb_ptrace_headers, [
 846 extern $gdb_cv_func_ptrace_ret
 847   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 848 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 849     break 4;])
 850     for gdb_arg5 in 'int *' 'int' 'long'; do
 851      AC_TRY_COMPILE($gdb_ptrace_headers, [
 852 extern $gdb_cv_func_ptrace_ret
 853   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 854 ], [
 855 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 856     break 5;])
 857     done
 858    done
 859   done
 860  done
 861 done
 862 # Provide a safe default value.
 863 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 864 ])])
 865 ac_save_IFS=$IFS; IFS=','
 866 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 867 IFS=$ac_save_IFS
 868 shift
 869 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 870   [Define to the type of arg 3 for ptrace.])
 871 if test -n "$[5]"; then
 872   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 873     [Define to the type of arg 5 for ptrace.])
 874 fi
 875
 876 dnl AC_FUNC_SETPGRP does not work when cross compiling
 877 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 878 if test "$cross_compiling" = no; then
 879   AC_FUNC_SETPGRP
 880 else
 881   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 882     [AC_TRY_COMPILE([
 883 #include <unistd.h>
 884 ], [
 885   if (setpgrp(1,1) == -1)
 886     exit (0);
 887   else
 888     exit (1);
 889 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 890 if test $ac_cv_func_setpgrp_void = yes; then
 891   AC_DEFINE(SETPGRP_VOID, 1)
 892 fi
 893 fi
 894
 895 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 896 # since sigsetjmp might only be defined as a macro.
 897 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 898 [AC_TRY_COMPILE([
 899 #include <setjmp.h>
 900 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 901 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 902 if test $gdb_cv_func_sigsetjmp = yes; then
 903   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 904 fi
 905
 906 # Assume we'll default to using the included libiberty regex.
 907 gdb_use_included_regex=yes
 908
 909 # However, if the system regex is GNU regex, then default to *not*
 910 # using the included regex.
 911 AC_CACHE_CHECK(
 912   [for GNU regex],
 913   [gdb_cv_have_gnu_regex],
 914   [AC_TRY_COMPILE(
 915     [#include <gnu-versions.h>],
 916     [#define REGEX_INTERFACE_VERSION 1
 917 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 918 # error "Version mismatch"
 919 #endif],
 920     gdb_cv_have_gnu_regex=yes,
 921     gdb_cv_have_gnu_regex=no)])
 922 if test $gdb_cv_have_gnu_regex = yes; then
 923   gdb_use_included_regex=no
 924 fi
 925
 926 AC_ARG_WITH(included-regex,
 927   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
 928   gdb_with_regex=$withval,
 929   gdb_with_regex=$gdb_use_included_regex)
 930 if test "$gdb_with_regex" = yes; then
 931   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 932     [Define to 1 if the regex included in libiberty should be used.])
 933 fi
 934
 935 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 936 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 937 [#include <sys/param.h>
 938 #include <sys/proc.h>
 939 ])
 940
 941 # See if <sys/lwp.h> defines `struct lwp`.
 942 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 943 [AC_TRY_COMPILE([#include <sys/param.h>
 944 #include <sys/lwp.h>], [struct lwp l;],
 945 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 946 if test $gdb_cv_struct_lwp = yes; then
 947   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 948             [Define to 1 if your system has struct lwp.])
 949 fi
 950
 951 # See if <machine/reg.h> degines `struct reg'.
 952 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 953 [AC_TRY_COMPILE([#include <sys/types.h>
 954 #include <machine/reg.h>], [struct reg r;],
 955 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 956 if test $gdb_cv_struct_reg = yes; then
 957   AC_DEFINE(HAVE_STRUCT_REG, 1,
 958             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 959 fi
 960
 961 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 962 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 963 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 964                  [#include <machine/reg.h>])
 965
 966 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 967 AC_MSG_CHECKING(for PTRACE_GETREGS)
 968 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 969 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 970                 [PTRACE_GETREGS;],
 971                 [gdb_cv_have_ptrace_getregs=yes],
 972                 [gdb_cv_have_ptrace_getregs=no])])
 973 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 974 if test $gdb_cv_have_ptrace_getregs = yes; then
 975   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 976   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
 977 fi
 978
 979 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 980 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 981 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 982 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 983                 [PTRACE_GETFPXREGS;],
 984                 [gdb_cv_have_ptrace_getfpxregs=yes],
 985                 [gdb_cv_have_ptrace_getfpxregs=no])])
 986 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 987 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 988   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 989   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
 990 fi
 991
 992 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 993 AC_MSG_CHECKING(for PT_GETDBREGS)
 994 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 995 [AC_TRY_COMPILE([#include <sys/types.h>
 996 #include <sys/ptrace.h>],
 997                 [PT_GETDBREGS;],
 998                 [gdb_cv_have_pt_getdbregs=yes],
 999                 [gdb_cv_have_pt_getdbregs=no])])
1000 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1001 if test $gdb_cv_have_pt_getdbregs = yes; then
1002   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1003   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1004 fi
1005
1006 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1007 AC_MSG_CHECKING(for PT_GETXMMREGS)
1008 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1009 [AC_TRY_COMPILE([#include <sys/types.h>
1010 #include <sys/ptrace.h>],
1011                 [PT_GETXMMREGS;],
1012                 [gdb_cv_have_pt_getxmmregs=yes],
1013                 [gdb_cv_have_pt_getxmmregs=no])])
1014 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1015 if test $gdb_cv_have_pt_getxmmregs = yes; then
1016   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1017   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1018 fi
1019
1020 # Detect which type of /proc is in use, such as for Unixware or Solaris.
1021
1022 if test "${target}" = "${host}"; then
1023   case "${host}" in
1024   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
1025       AC_DEFINE(NEW_PROC_API, 1,
1026       [Define if you want to use new multi-fd /proc interface
1027        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1028       ;;
1029   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1030       AC_DEFINE(NEW_PROC_API, 1,
1031       [Define if you want to use new multi-fd /proc interface
1032        (replaces HAVE_MULTIPLE_PROC_FDS as well as other macros).])
1033       ;;
1034   mips-sgi-irix5*)
1035       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1036       AC_DEFINE([_KMEMUSER], 1,
1037       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1038        around a <sys/proc.h> problem on IRIX 5.])
1039       ;;
1040   esac
1041 fi
1042
1043 if test "$ac_cv_header_sys_procfs_h" = yes; then
1044   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
1045   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
1046   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1047   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1048   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1049   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1050   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1051   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
1052   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1053   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1054   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1055   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1056   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1057   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1058
1059
1060   dnl Check for broken prfpregset_t type
1061
1062   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1063   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1064   dnl instead of the struct itself).  We detect this here, and work
1065   dnl around it in gdb_proc_service.h.
1066
1067   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1068     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1069     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1070       [AC_TRY_RUN([#include <sys/procfs.h>
1071        int main ()
1072        {
1073          if (sizeof (prfpregset_t) == sizeof (void *))
1074            return 1;
1075          return 0;
1076        }],
1077        gdb_cv_prfpregset_t_broken=no,
1078        gdb_cv_prfpregset_t_broken=yes,
1079        gdb_cv_prfpregset_t_broken=yes)])
1080     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1081     if test $gdb_cv_prfpregset_t_broken = yes; then
1082       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1083       [Define if the prfpregset_t type is broken.])
1084     fi
1085   fi
1086
1087   dnl Check for PIOCSET ioctl entry
1088
1089   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
1090   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
1091   [AC_TRY_COMPILE([#include <unistd.h>
1092 #include <sys/types.h>
1093 #include <sys/procfs.h>
1094 ], [
1095     int dummy;;
1096     dummy = ioctl(0, PIOCSET, &dummy);
1097   ],
1098   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
1099   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
1100   if test $gdb_cv_have_procfs_piocset = yes; then
1101     AC_DEFINE(HAVE_PROCFS_PIOCSET, 1,
1102     [Define if ioctl argument PIOCSET is available.])
1103   fi
1104 fi
1105
1106 dnl For native ports (host == target), check to see what kind of
1107 dnl legacy link.h support is needed.  (See solib-legacy.c.)
1108 if test ${host} = ${target} ; then
1109   dnl Check for struct link_map with l_ members which are indicative
1110   dnl of SVR4-like shared libraries
1111
1112   AC_MSG_CHECKING(for member l_addr in struct link_map)
1113   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
1114     [AC_TRY_COMPILE([#include <link.h>],
1115                     [struct link_map lm; (void) lm.l_addr;],
1116                     gdb_cv_have_struct_link_map_with_l_members=yes,
1117                     gdb_cv_have_struct_link_map_with_l_members=no)])
1118   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
1119   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
1120     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS,1,
1121     [Define if <link.h> exists and defines struct link_map which has
1122      members with an ``l_'' prefix.  (For Solaris, SVR4, and
1123      SVR4-like systems.)])
1124   fi
1125
1126   dnl Check for struct link_map with lm_ members which are indicative
1127   dnl of SunOS-like shared libraries
1128
1129   AC_MSG_CHECKING(for member lm_addr in struct link_map)
1130   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
1131     [AC_TRY_COMPILE([#include <sys/types.h>
1132 #include <link.h>],
1133                     [struct link_map lm; (void) lm.lm_addr;],
1134                     gdb_cv_have_struct_link_map_with_lm_members=yes,
1135                     gdb_cv_have_struct_link_map_with_lm_members=no)])
1136   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
1137   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
1138     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS, 1,
1139     [Define if <link.h> exists and defines struct link_map which has
1140      members with an ``lm_'' prefix.  (For SunOS.)])
1141   fi
1142
1143   dnl Check for struct so_map with som_ members which are found on
1144   dnl some *BSD systems.
1145
1146   AC_MSG_CHECKING(for member som_addr in struct so_map)
1147   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
1148     [AC_TRY_COMPILE([#include <sys/types.h>
1149 #ifdef HAVE_NLIST_H
1150 #include <nlist.h>
1151 #endif
1152 #include <link.h>],
1153                     [struct so_map lm; (void) lm.som_addr;],
1154                     gdb_cv_have_struct_so_map_with_som_members=yes,
1155                     gdb_cv_have_struct_so_map_with_som_members=no)])
1156   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
1157   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
1158     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS, 1,
1159     [Define if <link.h> exists and defines a struct so_map which has
1160      members with an ``som_'' prefix.  (Found on older *BSD systems.)])
1161   fi
1162
1163   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
1164   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
1165
1166   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
1167   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
1168     [AC_TRY_COMPILE([#define _SYSCALL32
1169 #include <sys/link.h>], [struct link_map32 l;],
1170      gdb_cv_have_struct_link_map32=yes,
1171      gdb_cv_have_struct_link_map32=no)])
1172   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
1173   if test $gdb_cv_have_struct_link_map32 = yes; then
1174     AC_DEFINE(HAVE_STRUCT_LINK_MAP32, 1,
1175     [Define if <sys/link.h> has struct link_map32])
1176     AC_DEFINE(_SYSCALL32, 1,
1177     [Define if <sys/link.h> has link_map32 (solaris sparc-64 target)])
1178   fi
1179 fi
1180
1181 # Check if the compiler supports the `long long' type.
1182
1183 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1184                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1185 [[extern long long foo;]],
1186 [[switch (foo & 2) { case 0: return 1; }]])],
1187                                   gdb_cv_c_long_long=yes,
1188                                   gdb_cv_c_long_long=no)])
1189 if test $gdb_cv_c_long_long = yes; then
1190   AC_DEFINE(CC_HAS_LONG_LONG, 1,
1191             [Define to 1 if the compiler supports long long.])
1192 fi
1193
1194 # Check if the compiler and runtime support printing long longs.
1195
1196 AC_CACHE_CHECK([for long long support in printf],
1197                gdb_cv_printf_has_long_long,
1198                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1199 [[char buf[32];
1200   long long l = 0;
1201   l = (l << 16) + 0x0123;
1202   l = (l << 16) + 0x4567;
1203   l = (l << 16) + 0x89ab;
1204   l = (l << 16) + 0xcdef;
1205   sprintf (buf, "0x%016llx", l);
1206   return (strcmp ("0x0123456789abcdef", buf));]])],
1207                               gdb_cv_printf_has_long_long=yes,
1208                               gdb_cv_printf_has_long_long=no,
1209                               gdb_cv_printf_has_long_long=no)])
1210 if test $gdb_cv_printf_has_long_long = yes; then
1211   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1212             [Define to 1 if the "%ll" format works to print long longs.])
1213 fi
1214
1215 # Check if the compiler and runtime support printing decfloats.
1216
1217 AC_CACHE_CHECK([for decfloat support in printf],
1218                gdb_cv_printf_has_decfloat,
1219                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1220 [[char buf[64];
1221   _Decimal32 d32 = 1.2345df;
1222   _Decimal64 d64 = 1.2345dd;
1223   _Decimal128 d128 = 1.2345dl;
1224   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1225   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1226                               gdb_cv_printf_has_decfloat=yes,
1227                               gdb_cv_printf_has_decfloat=no,
1228                               gdb_cv_printf_has_decfloat=no)])
1229 if test $gdb_cv_printf_has_decfloat = yes; then
1230   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1231             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1232 fi
1233
1234 # Check if the compiler supports the `long double' type.  We can't use
1235 # AC_C_LONG_DOUBLE because that one does additional checks on the
1236 # constants defined in <float.h> that fail on some systems,
1237 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1238
1239 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1240                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1241                                   gdb_cv_c_long_double=yes,
1242                                   gdb_cv_c_long_double=no)])
1243 if test $gdb_cv_c_long_double = yes; then
1244   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1245            [Define to 1 if the compiler supports long double.])
1246 fi
1247
1248 # Check if the compiler and runtime support printing long doubles.
1249
1250 AC_CACHE_CHECK([for long double support in printf],
1251                gdb_cv_printf_has_long_double,
1252                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1253 [[char buf[16];
1254   long double f = 3.141592653;
1255   sprintf (buf, "%Lg", f);
1256   return (strncmp ("3.14159", buf, 7));]])],
1257                               gdb_cv_printf_has_long_double=yes,
1258                               gdb_cv_printf_has_long_double=no,
1259                               gdb_cv_printf_has_long_double=no)])
1260 if test $gdb_cv_printf_has_long_double = yes; then
1261   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1262             [Define to 1 if the "%Lg" format works to print long doubles.])
1263 fi
1264
1265 # Check if the compiler and runtime support scanning long doubles.
1266
1267 AC_CACHE_CHECK([for long double support in scanf],
1268                gdb_cv_scanf_has_long_double,
1269                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1270 [[#include <stdio.h>]],
1271 [[char *buf = "3.141592653";
1272   long double f = 0;
1273   sscanf (buf, "%Lg", &f);
1274   return !(f > 3.14159 && f < 3.14160);]])],
1275                               gdb_cv_scanf_has_long_double=yes,
1276                               gdb_cv_scanf_has_long_double=no,
1277                               gdb_cv_scanf_has_long_double=no)])
1278 if test $gdb_cv_scanf_has_long_double = yes; then
1279   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1280             [Define to 1 if the "%Lg" format works to scan long doubles.])
1281 fi
1282
1283 case ${host_os} in
1284 aix*)
1285   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1286     SAVE_LDFLAGS=$LDFLAGS
1287
1288     case $GCC in
1289     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1290     *) gdb_cv_bigtoc=-bbigtoc ;;
1291     esac
1292
1293     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1294     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1295     LDFLAGS="${SAVE_LDFLAGS}"
1296   ])
1297   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1298   ;;
1299 esac
1300
1301
1302 dnl For certain native configurations, we need to check whether thread
1303 dnl support can be built in or not.
1304 dnl
1305 dnl Note that we only want this if we are both native (host == target),
1306 dnl and not doing a canadian cross build (build == host).
1307
1308 if test ${build} = ${host} -a ${host} = ${target} ; then
1309    case ${host_os} in
1310    hpux*)
1311       AC_MSG_CHECKING(for HPUX/OSF thread support)
1312       if test -f /usr/include/dce/cma_config.h ; then
1313          if test "$GCC" = "yes" ; then
1314             AC_MSG_RESULT(yes)
1315             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT, 1,
1316             [Define if you have HPUX threads])
1317             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
1318             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
1319          else
1320             AC_MSG_RESULT(no (suppressed because you are not using GCC))
1321          fi
1322       else
1323          AC_MSG_RESULT(no)
1324       fi
1325       ;;
1326    solaris*)
1327       # See if thread_db library is around for Solaris thread debugging.
1328       # Note that we must explicitly test for version 1 of the library
1329       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1330       # the same API.
1331       AC_MSG_CHECKING(for Solaris thread debugging library)
1332       if test -f /usr/lib/libthread_db.so.1 ; then
1333          AC_MSG_RESULT(yes)
1334          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1335          [Define if using Solaris thread debugging.])
1336          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1337          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1338          AC_CHECK_LIB(dl, dlopen)
1339          if test "$GCC" = "yes" ; then
1340             # The GNU linker requires the -export-dynamic option to make
1341             # all symbols visible in the dynamic symbol table.
1342             hold_ldflags=$LDFLAGS
1343             AC_MSG_CHECKING(for the ld -export-dynamic flag)
1344             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
1345             AC_TRY_LINK(, [int i;], found=yes, found=no)
1346             LDFLAGS=$hold_ldflags
1347             AC_MSG_RESULT($found)
1348             if test $found = yes; then
1349                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
1350             fi
1351          fi
1352          # Sun randomly tweaked the prototypes in <proc_service.h>
1353          # at one point.
1354          AC_MSG_CHECKING(if <proc_service.h> is old)
1355          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1356             AC_TRY_COMPILE([
1357                 #include <proc_service.h>
1358                 ps_err_e ps_pdwrite
1359                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1360             ],, gdb_cv_proc_service_is_old=no,
1361                 gdb_cv_proc_service_is_old=yes)
1362          ])
1363          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1364          if test $gdb_cv_proc_service_is_old = yes; then
1365             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1366             [Define if <proc_service.h> on solaris uses int instead of
1367              size_t, and assorted other type changes.])
1368          fi
1369       else
1370          AC_MSG_RESULT(no)
1371       fi
1372       ;;
1373    aix*)
1374       AC_MSG_CHECKING(for AiX thread debugging library)
1375       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1376                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1377                                    [#ifndef PTHDB_VERSION_3
1378                                     #error
1379                                     #endif],
1380                                    gdb_cv_have_aix_thread_debug=yes,
1381                                    gdb_cv_have_aix_thread_debug=no)])
1382       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1383       if test $gdb_cv_have_aix_thread_debug = yes; then
1384          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1385          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1386          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1387       fi
1388       ;;
1389    esac
1390    AC_SUBST(CONFIG_LDFLAGS)
1391 fi
1392
1393 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1394 dnl other error codes.
1395 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1396    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1397                   gdb_cv_thread_db_h_has_td_notalloc,
1398      AC_TRY_COMPILE(
1399        [#include <thread_db.h>],
1400        [int i = TD_NOTALLOC;],
1401        gdb_cv_thread_db_h_has_td_notalloc=yes,
1402        gdb_cv_thread_db_h_has_td_notalloc=no
1403      )
1404    )
1405    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1406                   gdb_cv_thread_db_h_has_td_version,
1407      AC_TRY_COMPILE(
1408        [#include <thread_db.h>],
1409        [int i = TD_VERSION;],
1410        gdb_cv_thread_db_h_has_td_version=yes,
1411        gdb_cv_thread_db_h_has_td_version=no
1412      )
1413    )
1414    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1415                   gdb_cv_thread_db_h_has_td_notls,
1416      AC_TRY_COMPILE(
1417        [#include <thread_db.h>],
1418        [int i = TD_NOTLS;],
1419        gdb_cv_thread_db_h_has_td_notls=yes,
1420        gdb_cv_thread_db_h_has_td_notls=no
1421      )
1422    )
1423 fi
1424 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1425   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1426             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1427 fi
1428 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1429   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1430             [Define if <thread_db.h> has the TD_VERSION error code.])
1431 fi
1432 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1433   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1434             [Define if <thread_db.h> has the TD_NOTLS error code.])
1435 fi
1436
1437 dnl See if we have a sys/syscall header file that has __NR_tkill.
1438 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1439    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1440                   gdb_cv_sys_syscall_h_has_tkill,
1441      AC_TRY_COMPILE(
1442        [#include <sys/syscall.h>],
1443        [int i = __NR_tkill;],
1444        gdb_cv_sys_syscall_h_has_tkill=yes,
1445        gdb_cv_sys_syscall_h_has_tkill=no
1446      )
1447    )
1448 fi
1449 dnl See if we can issue tkill syscall.
1450 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1451   AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1452 fi
1453
1454 dnl Check if we can disable the virtual address space randomization.
1455 dnl The functionality of setarch -R.
1456 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1457 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1458 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1459 #       define ADDR_NO_RANDOMIZE 0x0040000
1460 #      endif
1461        /* Test the flag could be set and stays set.  */
1462        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1463        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1464            return 1])])
1465 AC_RUN_IFELSE([PERSONALITY_TEST],
1466               [have_personality=true],
1467               [have_personality=false],
1468               [AC_LINK_IFELSE([PERSONALITY_TEST],
1469                               [have_personality=true],
1470                               [have_personality=false])])
1471 if $have_personality
1472 then
1473     AC_DEFINE([HAVE_PERSONALITY], 1,
1474               [Define if you support the personality syscall.])
1475 fi
1476
1477 dnl Handle optional features that can be enabled.
1478
1479 target_sysroot_reloc=0
1480 AC_ARG_WITH(sysroot,
1481 AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], [search for usr/lib et al within DIR]),
1482 [
1483  case ${with_sysroot} in
1484  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1485  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1486  esac
1487
1488  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1489
1490  if test "x$prefix" = xNONE; then
1491   test_prefix=/usr/local
1492  else
1493   test_prefix=$prefix
1494  fi
1495  if test "x$exec_prefix" = xNONE || test "x$exec_prefix" = 'x${prefix}'; then
1496   test_exec_prefix=$test_prefix
1497  else
1498   test_exec_prefix=$exec_prefix
1499  fi
1500  case ${TARGET_SYSTEM_ROOT} in
1501  "${test_prefix}"|"${test_prefix}/"*|\
1502  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
1503  '${prefix}'|'${prefix}/'*|\
1504  '${exec_prefix}'|'${exec_prefix}/'*)
1505    target_sysroot_reloc=1
1506    ;;
1507  esac
1508 ], [
1509  TARGET_SYSTEM_ROOT=
1510  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1511 ])
1512 TARGET_SYSTEM_ROOT_DEFINE="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE=$target_sysroot_reloc"
1513 AC_SUBST(TARGET_SYSTEM_ROOT)
1514 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1515
1516 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1517     [automatically load a system-wide gdbinit file],
1518     [])
1519
1520 AC_ARG_ENABLE(werror,
1521   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1522   [case "${enableval}" in
1523      yes | y) ERROR_ON_WARNING="yes" ;;
1524      no | n)  ERROR_ON_WARNING="no" ;;
1525      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1526    esac])
1527
1528 # Enable -Werror by default when using gcc
1529 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
1530     ERROR_ON_WARNING=yes
1531 fi
1532
1533 WERROR_CFLAGS=""
1534 if test "${ERROR_ON_WARNING}" = yes ; then
1535     WERROR_CFLAGS="-Werror"
1536 fi
1537
1538 # The entries after -Wno-pointer-sign are disabled warnings which may
1539 # be enabled in the future, which can not currently be used to build
1540 # GDB.
1541 # NOTE: If you change this list, remember to update
1542 # gdb/doc/gdbint.texinfo.
1543 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1544 -Wformat-nonliteral -Wno-pointer-sign \
1545 -Wno-unused -Wunused-value -Wno-switch -Wno-char-subscripts"
1546
1547 # Enable -Wno-format by default when using gcc on mingw since many
1548 # GCC versions complain about %I64.
1549 case "${host}" in
1550   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1551 esac
1552
1553 AC_ARG_ENABLE(build-warnings,
1554 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1555 [case "${enableval}" in
1556   yes)  ;;
1557   no)   build_warnings="-w";;
1558   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1559         build_warnings="${build_warnings} ${t}";;
1560   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1561         build_warnings="${t} ${build_warnings}";;
1562   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1563 esac
1564 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1565   echo "Setting compiler warning flags = $build_warnings" 6>&1
1566 fi])dnl
1567 AC_ARG_ENABLE(gdb-build-warnings,
1568 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1569 [case "${enableval}" in
1570   yes)  ;;
1571   no)   build_warnings="-w";;
1572   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1573         build_warnings="${build_warnings} ${t}";;
1574   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1575         build_warnings="${t} ${build_warnings}";;
1576   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1577 esac
1578 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1579   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1580 fi])dnl
1581 WARN_CFLAGS=""
1582 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1583 then
1584     AC_MSG_CHECKING(compiler warning flags)
1585     # Separate out the -Werror flag as some files just cannot be
1586     # compiled with it enabled.
1587     for w in ${build_warnings}; do
1588         case $w in
1589         -Werr*) WERROR_CFLAGS=-Werror ;;
1590         *) # Check that GCC accepts it
1591             saved_CFLAGS="$CFLAGS"
1592             CFLAGS="$CFLAGS $w"
1593             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1594             CFLAGS="$saved_CFLAGS"
1595         esac
1596     done
1597     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
1598 fi
1599 AC_SUBST(WARN_CFLAGS)
1600 AC_SUBST(WERROR_CFLAGS)
1601
1602 # In the Cygwin environment, we need some additional flags.
1603 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1604 [AC_EGREP_CPP(lose, [
1605 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1606 lose
1607 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1608
1609
1610 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1611 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1612 case ${host} in
1613   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1614   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1615   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1616 esac
1617 AC_SUBST(SER_HARDWIRE)
1618
1619 # libreadline needs libuser32.a in a cygwin environment
1620 WIN32LIBS=
1621 if test x$gdb_cv_os_cygwin = xyes; then
1622     WIN32LIBS="-luser32"
1623     case "${target}" in
1624         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1625         ;;
1626     esac
1627 fi
1628
1629 # The ser-tcp.c module requires sockets.
1630 case ${host} in
1631   *mingw32*)
1632     AC_DEFINE(USE_WIN32API, 1,
1633               [Define if we should use the Windows API, instead of the
1634                POSIX API.  On Windows, we use the Windows API when
1635                building for MinGW, but the POSIX API when building
1636                for Cygwin.])
1637     WIN32LIBS="$WIN32LIBS -lws2_32"
1638     ;;
1639 esac
1640 AC_SUBST(WIN32LIBS)
1641
1642 # Add ELF support to GDB, but only if BFD includes ELF support.
1643 OLD_CFLAGS=$CFLAGS
1644 OLD_LDFLAGS=$LDFLAGS
1645 OLD_LIBS=$LIBS
1646 CFLAGS="$CFLAGS -I${srcdir}/../include -I../bfd -I${srcdir}/../bfd"
1647 LDFLAGS="$LDFLAGS -L../bfd -L../libiberty"
1648 intl=`echo $LIBINTL | sed 's,${top_builddir}/,,g'`
1649 LIBS="-lbfd -liberty $intl $LIBS"
1650 AC_CACHE_CHECK([for ELF support in BFD], gdb_cv_var_elf,
1651 [AC_TRY_LINK(
1652 [#include <stdlib.h>
1653 #include "bfd.h"
1654 #include "elf-bfd.h"
1655 ],
1656 [bfd *abfd = NULL; bfd_get_elf_phdr_upper_bound (abfd); ],
1657 gdb_cv_var_elf=yes, gdb_cv_var_elf=no)])
1658 if test $gdb_cv_var_elf = yes; then
1659   CONFIG_OBS="$CONFIG_OBS elfread.o"
1660   AC_DEFINE(HAVE_ELF, 1,
1661             [Define if ELF support should be included.])
1662 fi
1663 CFLAGS=$OLD_CFLAGS
1664 LDFLAGS=$OLD_LDFLAGS
1665 LIBS=$OLD_LIBS
1666
1667 # Add any host-specific objects to GDB.
1668 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1669
1670 LIBGUI="../libgui/src/libgui.a"
1671 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1672 AC_SUBST(LIBGUI)
1673 AC_SUBST(GUI_CFLAGS_X)
1674
1675 WIN32LDAPP=
1676 AC_SUBST(WIN32LIBS)
1677 AC_SUBST(WIN32LDAPP)
1678
1679 case "${host}" in
1680 *-*-cygwin* | *-*-mingw* )
1681     configdir="win"
1682     ;;
1683 *)
1684     configdir="unix"
1685     ;;
1686 esac
1687
1688 GDBTKLIBS=
1689 if test "${enable_gdbtk}" = "yes"; then
1690
1691     # Gdbtk must have an absolute path to srcdir in order to run
1692     # properly when not installed.
1693     here=`pwd`
1694     cd ${srcdir}
1695     GDBTK_SRC_DIR=`pwd`
1696     cd $here
1697
1698     SC_PATH_TCLCONFIG
1699
1700     # If $no_tk is nonempty, then we can't do Tk, and there is no
1701     # point to doing Tcl.
1702     SC_PATH_TKCONFIG
1703
1704     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1705         SC_LOAD_TCLCONFIG
1706
1707         # Check for in-tree tcl
1708         here=`pwd`
1709         cd ${srcdir}/..
1710         topdir=`pwd`
1711         cd ${here}
1712
1713         intree="no"
1714         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1715           intree="yes"
1716         fi
1717
1718         # Find Tcl private headers
1719         if test x"${intree}" = xno; then
1720           CY_AC_TCL_PRIVATE_HEADERS
1721           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1722           TCL_LIBRARY="${TCL_LIB_SPEC}"
1723           TCL_DEPS=""
1724         else
1725           # If building tcl in the same src tree, private headers
1726           # are not needed, but we need to be sure to use the right
1727           # headers library
1728           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1729           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1730           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1731         fi
1732         AC_SUBST(TCL_INCLUDE)
1733         AC_SUBST(TCL_LIBRARY)
1734         AC_SUBST(TCL_DEPS)
1735
1736         SC_LOAD_TKCONFIG
1737
1738         # Check for in-tree Tk
1739         intree="no"
1740         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1741           intree="yes"
1742         fi
1743
1744         # Find Tk private headers
1745         if test x"${intree}" = xno; then
1746           CY_AC_TK_PRIVATE_HEADERS
1747           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1748           TK_LIBRARY=${TK_LIB_SPEC}
1749           TK_DEPS=""
1750         else
1751           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1752           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1753           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1754         fi
1755         AC_SUBST(TK_INCLUDE)
1756         AC_SUBST(TK_LIBRARY)
1757         AC_SUBST(TK_DEPS)
1758         AC_SUBST(TK_XINCLUDES)
1759
1760         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1761
1762         # Include some libraries that Tcl and Tk want.
1763         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1764         # Yes, the ordering seems wrong here.  But it isn't.
1765         # TK_LIBS is the list of libraries that need to be linked
1766         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1767         # were in LIBS then any link tests after this point would
1768         # try to include things like `$(LIBGUI)', which wouldn't work.
1769         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1770
1771         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1772         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1773         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1774         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1775         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1776         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1777         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1778
1779         if test x$gdb_cv_os_cygwin = xyes; then
1780           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1781           WIN32LDAPP="-Wl,--subsystem,console"
1782           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1783         fi
1784
1785         AC_CONFIG_SUBDIRS(gdbtk)
1786     fi
1787 fi
1788
1789 AC_SUBST(X_CFLAGS)
1790 AC_SUBST(X_LDFLAGS)
1791 AC_SUBST(X_LIBS)
1792 AC_SUBST(GDBTKLIBS)
1793 AC_SUBST(GDBTK_CFLAGS)
1794 AC_SUBST(GDBTK_SRC_DIR)
1795
1796 AC_PATH_X
1797
1798 # Unlike the sim directory, whether a simulator is linked is controlled by
1799 # presence of a gdb_sim definition in the target configure.tgt entry.
1800 # This code just checks for a few cases where we'd like to ignore those
1801 # definitions, even when they're present in the '.mt' file.  These cases
1802 # are when --disable-sim is specified, or if the simulator directory is
1803 # not part of the source tree.
1804 #
1805 AC_ARG_ENABLE(sim,
1806 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1807 [echo "enable_sim = $enable_sim";
1808  echo "enableval = ${enableval}";
1809  case "${enableval}" in
1810   yes) ignore_sim=false ;;
1811   no)  ignore_sim=true ;;
1812   *)   ignore_sim=false ;;
1813  esac],
1814 [ignore_sim=false])
1815
1816 if test ! -d "${srcdir}/../sim"; then
1817   ignore_sim=true
1818 fi
1819
1820 SIM=
1821 SIM_OBS=
1822 if test "${ignore_sim}" = "false"; then
1823   if test x"${gdb_sim}" != x ; then
1824     SIM="${gdb_sim}"
1825     SIM_OBS="remote-sim.o"
1826     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1827   fi
1828 fi
1829 AC_SUBST(SIM)
1830 AC_SUBST(SIM_OBS)
1831
1832 AC_SUBST(ENABLE_CFLAGS)
1833 AC_SUBST(PROFILE_CFLAGS)
1834
1835 AC_SUBST(CONFIG_OBS)
1836 AC_SUBST(CONFIG_DEPS)
1837 AC_SUBST(CONFIG_SRCS)
1838 AC_SUBST(CONFIG_ALL)
1839 AC_SUBST(CONFIG_CLEAN)
1840 AC_SUBST(CONFIG_INSTALL)
1841 AC_SUBST(CONFIG_UNINSTALL)
1842
1843 # List of host floatformats.
1844 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1845 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1846 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1847
1848 # target_subdir is used by the testsuite to find the target libraries.
1849 target_subdir=
1850 if test "${host}" != "${target}"; then
1851     target_subdir="${target_alias}/"
1852 fi
1853 AC_SUBST(target_subdir)
1854
1855 frags=
1856 if test "${gdb_native}" = "yes"; then
1857   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1858   if test ! -f ${host_makefile_frag}; then
1859     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1860   fi
1861   frags="$frags $host_makefile_frag"
1862 else
1863   host_makefile_frag=/dev/null
1864 fi
1865
1866 AC_SUBST_FILE(host_makefile_frag)
1867 AC_SUBST(frags)
1868
1869 changequote(,)dnl
1870 if test "${gdb_native}" = "yes"; then
1871 # We pick this up from the host configuration file (.mh) because we
1872 # do not have a native configuration Makefile fragment.
1873 nativefile=`sed -n '
1874 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1875 ' ${host_makefile_frag}`
1876 fi
1877 changequote([,])
1878
1879 if test x"${gdb_osabi}" != x ; then
1880     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1881                        [Define to the default OS ABI for this configuration.])
1882 fi
1883
1884 # Enable multi-ice-gdb-server.
1885 AC_ARG_ENABLE(multi-ice,
1886 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
1887   [case $enableval in
1888     yes | no)
1889       ;;
1890     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1891   esac])
1892 if test "x$enable_multi_ice" = xyes; then
1893    AC_CONFIG_SUBDIRS(multi-ice)
1894 fi
1895
1896 # We only build gdbserver automatically in a native configuration.
1897 if test "$gdb_native" = "yes"; then
1898   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1899   if test "x$build_gdbserver" = xyes; then
1900     AC_MSG_RESULT(yes)
1901     AC_CONFIG_SUBDIRS(gdbserver)
1902   else
1903     AC_MSG_RESULT(no)
1904   fi
1905 fi
1906
1907 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1908 # to an empty version.
1909
1910 files=
1911 links=
1912
1913 rm -f nm.h
1914 if test "${nativefile}" != ""; then
1915     case "${nativefile}" in
1916       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1917       * ) GDB_NM_FILE="${nativefile}"
1918     esac
1919     files="${files} ${GDB_NM_FILE}"
1920     links="${links} nm.h"
1921     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
1922 fi
1923 AC_SUBST(GDB_NM_FILE)
1924
1925 AC_LINK_FILES($files, $links)
1926
1927 dnl Check for exe extension set on certain hosts (e.g. Win32)
1928 AC_EXEEXT
1929
1930 dnl  Detect the character set used by this host.
1931 dnl  At the moment, we just assume it's UTF-8.
1932 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
1933           [Define to be a string naming the default host character set.])
1934
1935 AC_OUTPUT(Makefile .gdbinit:gdbinit.in gnulib/Makefile,
1936 [
1937 case x$CONFIG_HEADERS in
1938 xconfig.h:config.in)
1939 echo > stamp-h ;;
1940 esac
1941 ])
1942
1943 exit 0