1 dnl Autoconf configure script for GDB, the GNU debugger.
2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
3 dnl Free Software Foundation, Inc.
5 dnl This file is part of GDB.
7 dnl This program is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2 of the License, or
10 dnl (at your option) any later version.
12 dnl This program is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 dnl GNU General Public License for more details.
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
21 dnl Process this file with autoconf to produce a configure script.
25 AC_CONFIG_HEADER(config.h:config.in)
34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
39 # does. Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
40 # deal with the lossage. Note that CY_GNU_GETTEXT currently calls
41 # AC_PROG_RANLIB. This can be removed when we switch to Autoconf
43 AC_CHECK_TOOL(RANLIB, ranlib, :)
45 dnl List of object files and targets accumulated by configure.
57 dnl Set up for gettext. PACKAGE is used when we call bindtextdomain.
61 localedir='${datadir}/locale'
64 if test "x$POSUB" != x; then
66 dnl Lifted from GCC's config/gettext.m4.
67 AC_MSG_CHECKING(for catalogs to be installed)
68 # Look for .po and .gmo files in the source directory.
69 CATALOGS= AC_SUBST(CATALOGS)
71 for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
72 # If there aren't any .gmo files the shell will give us the
73 # literal string "../path/to/srcdir/po/*.gmo" which has to be
78 # The quadruple backslash is collapsed to a double backslash
79 # by the backticks, then collapsed again by the double quotes,
80 # leaving us with one backslash in the sed expression (right
81 # before the dot that mustn't act as a wildcard).
82 cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
83 lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
84 # The user is allowed to set LINGUAS to a list of languages to
85 # install catalogs for. If it's empty that means "all of them."
86 if test "x$LINGUAS" = x; then
87 CATALOGS="$CATALOGS $cat"
88 XLINGUAS="$XLINGUAS $lang"
90 case "$LINGUAS" in *$lang*)
91 CATALOGS="$CATALOGS $cat"
92 XLINGUAS="$XLINGUAS $lang"
98 AC_MSG_RESULT($LINGUAS)
100 CONFIG_ALL="$CONFIG_ALL all-po"
101 CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
102 CONFIG_INSTALL="$CONFIG_INSTALL install-po"
103 CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
107 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
110 debugdir=${libdir}/debug
112 AC_ARG_WITH(separate-debug-dir,
113 [ --with-separate-debug-dir=path Look for global separate debug info in this path [LIBDIR/debug]],
114 [debugdir="${withval}"])
116 AC_DEFINE_DIR(DEBUGDIR, debugdir,
117 [Global directory for separate debug files. ])
118 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
120 AC_CONFIG_SUBDIRS(doc testsuite)
122 . $srcdir/configure.host
124 . $srcdir/configure.tgt
126 # Fetch the default architecture and default target vector from BFD.
127 targ=$target; . $srcdir/../bfd/config.bfd
129 # We only want the first architecture, so strip off the others if
130 # there is more than one.
131 targ_archs=`echo $targ_archs | sed 's/ .*//'`
133 if test "x$targ_archs" != x; then
134 AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
135 [Define to BFD's default architecture. ])
137 if test "x$targ_defvec" != x; then
138 AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
139 [Define to BFD's default target vector. ])
144 # The CLI cannot be disabled yet, but may be in the future.
147 AC_ARG_ENABLE(gdbcli,
148 [ --disable-gdbcli disable command-line interface (CLI)],
153 AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
155 AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
158 if test x"$enable_gdbcli" = xyes; then
159 if test -d $srcdir/cli; then
160 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
161 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
162 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
163 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
169 [ --disable-gdbmi disable machine-interface (MI)],
174 AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
177 if test x"$enable_gdbmi" = xyes; then
178 if test -d $srcdir/mi; then
179 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
180 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
181 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
182 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
188 [ --enable-tui enable full-screen terminal user interface (TUI)],
193 AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
194 esac],enable_tui=yes)
198 [ --enable-gdbtk enable gdbtk graphical user interface (GUI)],
203 AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
205 [if test -d $srcdir/gdbtk; then
210 # We unconditionally disable gdbtk tests on selected platforms.
213 AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
218 AC_ARG_WITH(libunwind,
219 [ --with-libunwind Use libunwind frame unwinding support],
220 [case "${withval}" in
221 yes) enable_libunwind=yes ;;
222 no) enable_libunwind=no ;;
223 *) AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
225 AC_CHECK_HEADERS(libunwind.h)
226 AC_CHECK_HEADERS(libunwind-ia64.h)
227 if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
228 enable_libunwind=yes;
232 if test x"$enable_libunwind" = xyes; then
233 AC_CHECK_HEADERS(libunwind.h)
234 AC_CHECK_HEADERS(libunwind-ia64.h)
235 AC_DEFINE(HAVE_LIBUNWIND, 1)
236 CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
237 CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
238 CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
242 AC_ARG_ENABLE(profiling,
243 [ --enable-profiling enable profiling of GDB],
248 AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
250 [enable_profiling=no])
252 AC_CHECK_FUNCS(monstartup _mcleanup)
253 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
258 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
259 if test $ac_cv_var__etext = yes; then
260 AC_DEFINE(HAVE__ETEXT, 1,
261 [Define to 1 if your system has the _etext variable. ])
263 if test "$enable_profiling" = yes ; then
264 if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
265 AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
269 CFLAGS="$CFLAGS $PROFILE_CFLAGS"
271 AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
272 [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
273 ac_cv_cc_supports_pg=no)])
275 if test $ac_cv_cc_supports_pg = no; then
276 AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
282 # --------------------- #
283 # Checks for programs. #
284 # --------------------- #
292 AC_CHECK_TOOL(AR, ar)
293 AC_CHECK_TOOL(DLLTOOL, dlltool)
294 AC_CHECK_TOOL(WINDRES, windres)
296 # Needed for GNU/Hurd.
297 AC_CHECK_TOOL(MIG, mig)
299 # ---------------------- #
300 # Checks for libraries. #
301 # ---------------------- #
303 # We might need to link with -lm; most simulators need it.
304 AC_CHECK_LIB(m, main)
306 # We need to link with -lw to get `wctype' on Solaris before Solaris
307 # 2.6. Solaris 2.6 and beyond have this function in libc, and have a
308 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
309 # is known to have this problem). Therefore we avoid libw if we can.
310 AC_CHECK_FUNC(wctype, [],
311 [AC_CHECK_LIB(w, wctype)])
313 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
314 AC_SEARCH_LIBS(gethostbyname, nsl)
316 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
317 AC_SEARCH_LIBS(socketpair, socket)
319 # For the TUI, we need enhanced curses functionality.
321 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
322 # curses library because the latter might not provide all the
323 # functionality we need. However, this leads to problems on systems
324 # where the linker searches /usr/local/lib, but the compiler doesn't
325 # search /usr/local/include, if ncurses is installed in /usr/local. A
326 # default installation of ncurses on alpha*-dec-osf* will lead to such
328 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
330 # Since GDB uses Readline, we need termcap functionality. In many
331 # cases this will be provided by the curses library, but some systems
332 # have a seperate termcap library, or no curses library at all.
336 if test -d $srcdir/libtermcap; then
337 LIBS="../libtermcap/libtermcap.a $LIBS"
338 ac_cv_search_tgetent="../libtermcap/libtermcap.a"
341 ac_cv_search_tgetent="none required"
345 # These are the libraries checked by Readline.
346 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
348 if test "$ac_cv_search_tgetent" = no; then
349 AC_MSG_ERROR([no termcap library found])
352 # ------------------------- #
353 # Checks for header files. #
354 # ------------------------- #
359 AC_CHECK_HEADERS(nlist.h)
360 AC_CHECK_HEADERS(link.h, [], [],
361 [#if HAVE_SYS_TYPES_H
362 # include <sys/types.h>
368 AC_CHECK_HEADERS(machine/reg.h)
369 AC_CHECK_HEADERS(poll.h sys/poll.h)
370 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
371 AC_CHECK_HEADERS(stddef.h)
372 AC_CHECK_HEADERS(stdlib.h)
373 AC_CHECK_HEADERS(stdint.h)
374 AC_CHECK_HEADERS(string.h memory.h strings.h)
375 AC_CHECK_HEADERS(sys/fault.h)
376 AC_CHECK_HEADERS(sys/file.h)
377 AC_CHECK_HEADERS(sys/filio.h)
378 AC_CHECK_HEADERS(sys/ioctl.h)
379 AC_CHECK_HEADERS(sys/param.h)
380 AC_CHECK_HEADERS(sys/proc.h, [], [],
381 [#if HAVE_SYS_PARAM_H
382 # include <sys/param.h>
385 AC_CHECK_HEADERS(sys/procfs.h)
386 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
387 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
388 AC_CHECK_HEADERS(sys/select.h)
389 AC_CHECK_HEADERS(sys/syscall.h)
390 AC_CHECK_HEADERS(sys/types.h)
391 AC_CHECK_HEADERS(sys/user.h, [], [],
392 [#if HAVE_SYS_PARAM_H
393 # include <sys/param.h>
396 AC_CHECK_HEADERS(sys/wait.h wait.h)
397 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
398 AC_CHECK_HEADERS(unistd.h)
400 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
401 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
402 # think that we don't have <curses.h> if we're using GCC.
405 if test "$GCC" = yes; then
406 AC_DEFINE(_MSE_INT_H, 1,
407 [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
408 Solaris 2.[789] when using GCC. ]])
411 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
412 AC_CHECK_HEADERS(ncurses/term.h)
413 AC_CHECK_HEADERS(term.h, [], [],
419 # FIXME: kettenis/20030102: In most cases we include these
420 # unconditionally, so what's the point in checking these?
421 AC_CHECK_HEADERS(ctype.h time.h)
423 # ------------------------- #
424 # Checks for declarations. #
425 # ------------------------- #
427 AC_CHECK_DECLS([free, malloc, realloc])
428 AC_CHECK_DECLS([strerror, strstr])
429 AC_CHECK_DECLS(getopt)
431 # ----------------------- #
432 # Checks for structures. #
433 # ----------------------- #
435 AC_CHECK_MEMBERS([struct stat.st_blocks])
437 # ------------------ #
438 # Checks for types. #
439 # ------------------ #
443 # ------------------------------------- #
444 # Checks for compiler characteristics. #
445 # ------------------------------------- #
450 # ------------------------------ #
451 # Checks for library functions. #
452 # ------------------------------ #
457 AC_CHECK_FUNCS(canonicalize_file_name realpath)
459 AC_CHECK_FUNCS(pread64)
461 AC_CHECK_FUNCS(setpgid setpgrp)
462 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
463 AC_CHECK_FUNCS(socketpair)
464 AC_CHECK_FUNCS(syscall)
465 AC_CHECK_FUNCS(ttrace)
466 AC_CHECK_FUNCS(wborder)
468 # Check the return and argument types of ptrace. No canned test for
469 # this, so roll our own.
472 # include <sys/types.h>
474 #if HAVE_SYS_PTRACE_H
475 # include <sys/ptrace.h>
481 # There is no point in checking if we don't have a prototype.
482 AC_CHECK_DECLS(ptrace, [], [
483 : ${gdb_cv_func_ptrace_ret='int'}
484 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
485 ], $gdb_ptrace_headers)
487 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
488 AC_TRY_COMPILE($gdb_ptrace_headers,
489 [extern int ptrace ();],
490 gdb_cv_func_ptrace_ret='int',
491 gdb_cv_func_ptrace_ret='long'))
492 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
493 [Define as the return type of ptrace.])
494 # Check argument types.
495 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
496 for gdb_arg1 in 'int' 'long'; do
497 for gdb_arg2 in 'pid_t' 'int' 'long'; do
498 for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
499 for gdb_arg4 in 'int' 'long'; do
500 AC_TRY_COMPILE($gdb_ptrace_headers, [
501 extern $gdb_cv_func_ptrace_ret
502 ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
503 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
505 for gdb_arg5 in 'int *' 'int' 'long'; do
506 AC_TRY_COMPILE($gdb_ptrace_headers, [
507 extern $gdb_cv_func_ptrace_ret
508 ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
510 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
517 # Provide a safe default value.
518 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
520 ac_save_IFS=$IFS; IFS=','
521 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
524 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
525 [Define to the type of arg 3 for ptrace.])
526 if test -n "$[5]"; then
527 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
528 [Define to the type of arg 5 for ptrace.])
531 dnl AC_FUNC_SETPGRP does not work when cross compiling
532 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
533 if test "$cross_compiling" = no; then
536 AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
540 if (setpgrp(1,1) == -1)
544 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
545 if test $ac_cv_func_setpgrp_void = yes; then
546 AC_DEFINE(SETPGRP_VOID, 1)
550 # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do
551 # since sigsetjmp might only be defined as a macro.
552 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
555 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
556 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
557 if test $gdb_cv_func_sigsetjmp = yes; then
558 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
561 # Assume we'll default to using the included libiberty regex.
562 gdb_use_included_regex=yes
564 # However, if the system regex is GNU regex, then default to *not*
565 # using the included regex.
568 [gdb_cv_have_gnu_regex],
570 [#include <gnu-versions.h>],
571 [#define REGEX_INTERFACE_VERSION 1
572 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
573 # error "Version mismatch"
575 gdb_cv_have_gnu_regex=yes,
576 gdb_cv_have_gnu_regex=no)])
577 if test $gdb_cv_have_gnu_regex = yes; then
578 gdb_use_included_regex=no
581 AC_ARG_WITH(included-regex,
582 [ --without-included-regex don't use included regex; this is the default
583 on systems with version 2 of the GNU C library
584 (use with caution on other system)],
585 gdb_with_regex=$withval,
586 gdb_with_regex=$gdb_use_included_regex)
587 if test "$gdb_with_regex" = yes; then
588 AC_DEFINE(USE_INCLUDED_REGEX, 1,
589 [Define to 1 if the regex included in libiberty should be used.])
592 # See if <sys/proc.h> defines `struct thread' with a td_pcb member.
593 AC_CACHE_CHECK([for td_pcb in struct thread], gdb_cv_struct_thread_td_pcb,
594 [AC_TRY_COMPILE([#include <sys/param.h>
595 #include <sys/proc.h>], [struct thread td; td.td_pcb;],
596 gdb_cv_struct_thread_td_pcb=yes, gdb_cv_struct_thread_td_pcb=no)])
597 if test $gdb_cv_struct_thread_td_pcb = yes; then
598 AC_DEFINE(HAVE_STRUCT_THREAD_TD_PCB, 1,
599 [Define to 1 if your system has td_pcb in struct thread.])
602 # See if <sys/lwp.h> defines `struct lwp`.
603 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
604 [AC_TRY_COMPILE([#include <sys/param.h>
605 #include <sys/lwp.h>], [struct lwp l;],
606 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
607 if test $gdb_cv_struct_lwp = yes; then
608 AC_DEFINE(HAVE_STRUCT_LWP, 1,
609 [Define to 1 if your system has struct lwp.])
612 # See if <machine/reg.h> degines `struct reg'.
613 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
614 [AC_TRY_COMPILE([#include <sys/types.h>
615 #include <machine/reg.h>], [struct reg r;],
616 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
617 if test $gdb_cv_struct_reg = yes; then
618 AC_DEFINE(HAVE_STRUCT_REG, 1,
619 [Define to 1 if your system has struct reg in <machine/reg.h>.])
622 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
623 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
624 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
625 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
626 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
627 if test $gdb_cv_struct_reg_r_fs = yes; then
628 AC_DEFINE(HAVE_STRUCT_REG_R_FS)
630 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
631 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
632 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
633 if test $gdb_cv_struct_reg_r_gs = yes; then
634 AC_DEFINE(HAVE_STRUCT_REG_R_GS)
637 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
638 AC_MSG_CHECKING(for PTRACE_GETREGS)
639 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
640 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
642 [gdb_cv_have_ptrace_getregs=yes],
643 [gdb_cv_have_ptrace_getregs=no])])
644 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
645 if test $gdb_cv_have_ptrace_getregs = yes; then
646 AC_DEFINE(HAVE_PTRACE_GETREGS)
649 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
650 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
651 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
652 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
653 [PTRACE_GETFPXREGS;],
654 [gdb_cv_have_ptrace_getfpxregs=yes],
655 [gdb_cv_have_ptrace_getfpxregs=no])])
656 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
657 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
658 AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
661 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
662 AC_MSG_CHECKING(for PT_GETDBREGS)
663 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
664 [AC_TRY_COMPILE([#include <sys/types.h>
665 #include <sys/ptrace.h>],
667 [gdb_cv_have_pt_getdbregs=yes],
668 [gdb_cv_have_pt_getdbregs=no])])
669 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
670 if test $gdb_cv_have_pt_getdbregs = yes; then
671 AC_DEFINE(HAVE_PT_GETDBREGS)
674 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
675 AC_MSG_CHECKING(for PT_GETXMMREGS)
676 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
677 [AC_TRY_COMPILE([#include <sys/types.h>
678 #include <sys/ptrace.h>],
680 [gdb_cv_have_pt_getxmmregs=yes],
681 [gdb_cv_have_pt_getxmmregs=no])])
682 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
683 if test $gdb_cv_have_pt_getxmmregs = yes; then
684 AC_DEFINE(HAVE_PT_GETXMMREGS)
687 # See if stdint.h provides the uintptr_t type.
688 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
689 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
691 [#include <stdint.h>],
692 [uintptr_t foo = 0;],
693 gdb_cv_have_uintptr_t=yes,
694 gdb_cv_have_uintptr_t=no)])
695 if test $gdb_cv_have_uintptr_t = yes; then
696 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
699 # If we are configured native on GNU/Linux, work around problems with
701 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
703 if test "${target}" = "${host}"; then
705 i[[3456]]86-*-linux*)
706 AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
707 AC_DEFINE(sys_quotactl)
709 *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
710 AC_DEFINE(NEW_PROC_API)
712 *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
713 AC_DEFINE(NEW_PROC_API)
716 # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
717 AC_DEFINE([_KMEMUSER], 1)
722 if test "$ac_cv_header_sys_procfs_h" = yes; then
723 BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
724 BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
725 BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
726 BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
727 BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
728 BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
729 BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
730 BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
731 BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
732 BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
733 BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
734 BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
735 BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
736 BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
739 dnl Check for broken prfpregset_t type
741 dnl For Linux/i386, glibc 2.1.3 was released with a bogus
742 dnl prfpregset_t type (it's a typedef for the pointer to a struct
743 dnl instead of the struct itself). We detect this here, and work
744 dnl around it in gdb_proc_service.h.
746 if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
747 AC_MSG_CHECKING(whether prfpregset_t type is broken)
748 AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
749 [AC_TRY_RUN([#include <sys/procfs.h>
752 if (sizeof (prfpregset_t) == sizeof (void *))
756 gdb_cv_prfpregset_t_broken=no,
757 gdb_cv_prfpregset_t_broken=yes,
758 gdb_cv_prfpregset_t_broken=yes)])
759 AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
760 if test $gdb_cv_prfpregset_t_broken = yes; then
761 AC_DEFINE(PRFPREGSET_T_BROKEN)
765 dnl Check for PIOCSET ioctl entry
767 AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
768 AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
769 [AC_TRY_COMPILE([#include <unistd.h>
770 #include <sys/types.h>
771 #include <sys/procfs.h>
774 dummy = ioctl(0, PIOCSET, &dummy);
776 gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
777 AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
778 if test $gdb_cv_have_procfs_piocset = yes; then
779 AC_DEFINE(HAVE_PROCFS_PIOCSET)
783 dnl For native ports (host == target), check to see what kind of
784 dnl legacy link.h support is needed. (See solib-legacy.c.)
785 if test ${host} = ${target} ; then
786 dnl Check for struct link_map with l_ members which are indicative
787 dnl of SVR4-like shared libraries
789 AC_MSG_CHECKING(for member l_addr in struct link_map)
790 AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
791 [AC_TRY_COMPILE([#include <link.h>],
792 [struct link_map lm; (void) lm.l_addr;],
793 gdb_cv_have_struct_link_map_with_l_members=yes,
794 gdb_cv_have_struct_link_map_with_l_members=no)])
795 AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
796 if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
797 AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
800 dnl Check for struct link_map with lm_ members which are indicative
801 dnl of SunOS-like shared libraries
803 AC_MSG_CHECKING(for member lm_addr in struct link_map)
804 AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
805 [AC_TRY_COMPILE([#include <sys/types.h>
807 [struct link_map lm; (void) lm.lm_addr;],
808 gdb_cv_have_struct_link_map_with_lm_members=yes,
809 gdb_cv_have_struct_link_map_with_lm_members=no)])
810 AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
811 if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
812 AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
815 dnl Check for struct so_map with som_ members which are found on
816 dnl some *BSD systems.
818 AC_MSG_CHECKING(for member som_addr in struct so_map)
819 AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
820 [AC_TRY_COMPILE([#include <sys/types.h>
825 [struct so_map lm; (void) lm.som_addr;],
826 gdb_cv_have_struct_so_map_with_som_members=yes,
827 gdb_cv_have_struct_so_map_with_som_members=no)])
828 AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
829 if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
830 AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
833 dnl Check for struct link_map32 type, which allows a 64-bit Solaris
834 dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
836 AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
837 AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
838 [AC_TRY_COMPILE([#define _SYSCALL32
839 #include <sys/link.h>], [struct link_map32 l;],
840 gdb_cv_have_struct_link_map32=yes,
841 gdb_cv_have_struct_link_map32=no)])
842 AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
843 if test $gdb_cv_have_struct_link_map32 = yes; then
844 AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
845 AC_DEFINE(_SYSCALL32)
849 # Check if the compiler supports the `long long' type.
851 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
852 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
853 [[extern long long foo;]],
854 [[switch (foo & 2) { case 0: return 1; }]])],
855 gdb_cv_c_long_long=yes,
856 gdb_cv_c_long_long=no)])
857 if test $gdb_cv_c_long_long = yes; then
858 AC_DEFINE(CC_HAS_LONG_LONG, 1,
859 [Define to 1 if the compiler supports long long.])
862 # Check if the compiler and runtime support printing long longs.
864 AC_CACHE_CHECK([for long long support in printf],
865 gdb_cv_printf_has_long_long,
866 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
869 l = (l << 16) + 0x0123;
870 l = (l << 16) + 0x4567;
871 l = (l << 16) + 0x89ab;
872 l = (l << 16) + 0xcdef;
873 sprintf (buf, "0x%016llx", l);
874 return (strcmp ("0x0123456789abcdef", buf));]])],
875 gdb_cv_printf_has_long_long=yes,
876 gdb_cv_printf_has_long_long=no,
877 gdb_cv_printf_has_long_long=no)])
878 if test $gdb_cv_printf_has_long_long = yes; then
879 AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
880 [Define to 1 if the "%ll" format works to print long longs.])
883 # Check if the compiler supports the `long double' type. We can't use
884 # AC_C_LONG_DOUBLE because that one does additional checks on the
885 # constants defined in <float.h> that fail on some systems,
886 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
888 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
889 [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
890 gdb_cv_c_long_double=yes,
891 gdb_cv_c_long_double=no)])
892 if test $gdb_cv_c_long_double = yes; then
893 AC_DEFINE(HAVE_LONG_DOUBLE, 1,
894 [Define to 1 if the compiler supports long double.])
897 # Check if the compiler and runtime support printing long doubles.
899 AC_CACHE_CHECK([for long double support in printf],
900 gdb_cv_printf_has_long_double,
901 [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
903 long double f = 3.141592653;
904 sprintf (buf, "%Lg", f);
905 return (strncmp ("3.14159", buf, 7));]])],
906 gdb_cv_printf_has_long_double=yes,
907 gdb_cv_printf_has_long_double=no,
908 gdb_cv_printf_has_long_double=no)])
909 if test $gdb_cv_printf_has_long_double = yes; then
910 AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
911 [Define to 1 if the "%Lg" format works to print long doubles.])
914 # Check if the compiler and runtime support scanning long doubles.
916 AC_CACHE_CHECK([for long double support in scanf],
917 gdb_cv_scanf_has_long_double,
918 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
919 [[#include <stdio.h>]],
920 [[char *buf = "3.141592653";
922 sscanf (buf, "%Lg", &f);
923 return !(f > 3.14159 && f < 3.14160);]])],
924 gdb_cv_scanf_has_long_double=yes,
925 gdb_cv_scanf_has_long_double=no,
926 gdb_cv_scanf_has_long_double=no)])
927 if test $gdb_cv_scanf_has_long_double = yes; then
928 AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
929 [Define to 1 if the "%Lg" format works to scan long doubles.])
934 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
935 SAVE_LDFLAGS=$LDFLAGS
938 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
939 *) gdb_cv_bigtoc=-bbigtoc ;;
942 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
943 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
944 LDFLAGS="${SAVE_LDFLAGS}"
946 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
951 dnl For certain native configurations, we need to check whether thread
952 dnl support can be built in or not.
954 dnl Note that we only want this if we are both native (host == target),
955 dnl and not doing a canadian cross build (build == host).
957 if test ${build} = ${host} -a ${host} = ${target} ; then
960 AC_MSG_CHECKING(for HPUX/OSF thread support)
961 if test -f /usr/include/dce/cma_config.h ; then
962 if test "$GCC" = "yes" ; then
964 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
965 CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
966 CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
968 AC_MSG_RESULT(no (suppressed because you are not using GCC))
975 # See if thread_db library is around for Solaris thread debugging.
976 # Note that we must explicitly test for version 1 of the library
977 # because version 0 (present on Solaris 2.4 or earlier) doesn't have
979 AC_MSG_CHECKING(for Solaris thread debugging library)
980 if test -f /usr/lib/libthread_db.so.1 ; then
982 AC_DEFINE(HAVE_THREAD_DB_LIB)
983 CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
984 CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
985 AC_CHECK_LIB(dl, dlopen)
986 if test "$GCC" = "yes" ; then
987 # The GNU linker requires the -export-dynamic option to make
988 # all symbols visible in the dynamic symbol table.
989 hold_ldflags=$LDFLAGS
990 AC_MSG_CHECKING(for the ld -export-dynamic flag)
991 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
992 AC_TRY_LINK(, [int i;], found=yes, found=no)
993 LDFLAGS=$hold_ldflags
994 AC_MSG_RESULT($found)
995 if test $found = yes; then
996 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
999 # Sun randomly tweaked the prototypes in <proc_service.h>
1001 AC_MSG_CHECKING(if <proc_service.h> is old)
1002 AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1004 #include <proc_service.h>
1006 (struct ps_prochandle*, psaddr_t, const void*, size_t);
1007 ],, gdb_cv_proc_service_is_old=no,
1008 gdb_cv_proc_service_is_old=yes)
1010 AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1011 if test $gdb_cv_proc_service_is_old = yes; then
1012 AC_DEFINE(PROC_SERVICE_IS_OLD)
1019 AC_MSG_CHECKING(for AiX thread debugging library)
1020 AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1021 [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1022 [#ifndef PTHDB_VERSION_3
1025 gdb_cv_have_aix_thread_debug=yes,
1026 gdb_cv_have_aix_thread_debug=no)])
1027 AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1028 if test $gdb_cv_have_aix_thread_debug = yes; then
1029 CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1030 CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1031 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1035 AC_SUBST(CONFIG_LDFLAGS)
1038 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1039 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1040 AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1041 gdb_cv_thread_db_h_has_td_notalloc,
1043 [#include <thread_db.h>],
1044 [int i = TD_NOTALLOC;],
1045 gdb_cv_thread_db_h_has_td_notalloc=yes,
1046 gdb_cv_thread_db_h_has_td_notalloc=no
1050 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1051 AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1052 [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1055 dnl See if we have a sys/syscall header file that has __NR_tkill.
1056 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1057 AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1058 gdb_cv_sys_syscall_h_has_tkill,
1060 [#include <sys/syscall.h>],
1061 [int i = __NR_tkill;],
1062 gdb_cv_sys_syscall_h_has_tkill=yes,
1063 gdb_cv_sys_syscall_h_has_tkill=no
1067 dnl See if we can issue tkill syscall.
1068 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1069 AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1070 [Define if we can use the tkill syscall.])
1073 dnl Handle optional features that can be enabled.
1075 AC_ARG_WITH(sysroot,
1076 [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1078 case ${with_sysroot} in
1079 yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1080 *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1083 TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1085 if test "x$exec_prefix" = xNONE; then
1086 if test "x$prefix" = xNONE; then
1087 test_prefix=/usr/local
1092 test_prefix=$exec_prefix
1094 case ${TARGET_SYSTEM_ROOT} in
1095 "${test_prefix}"|"${test_prefix}/"*|\
1096 '${exec_prefix}'|'${exec_prefix}/'*)
1097 t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1098 TARGET_SYSTEM_ROOT_DEFINE="$t"
1103 TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1105 AC_SUBST(TARGET_SYSTEM_ROOT)
1106 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1108 # NOTE: Don't add -Wall or -Wunused, they both include
1109 # -Wunused-parameter which reports bogus warnings.
1110 # NOTE: If you add to this list, remember to update
1111 # gdb/doc/gdbint.texinfo.
1112 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1113 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1114 -Wunused-label -Wunused-function"
1115 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1116 # -Wunused-function -Wunused-variable -Wunused-value
1117 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1118 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1119 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1120 # -Woverloaded-virtual -Winline -Werror"
1121 AC_ARG_ENABLE(build-warnings,
1122 [ --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1123 [case "${enableval}" in
1125 no) build_warnings="-w";;
1126 ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1127 build_warnings="${build_warnings} ${t}";;
1128 *,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1129 build_warnings="${t} ${build_warnings}";;
1130 *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1132 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1133 echo "Setting compiler warning flags = $build_warnings" 6>&1
1135 AC_ARG_ENABLE(gdb-build-warnings,
1136 [ --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1137 [case "${enableval}" in
1139 no) build_warnings="-w";;
1140 ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1141 build_warnings="${build_warnings} ${t}";;
1142 *,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
1143 build_warnings="${t} ${build_warnings}";;
1144 *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1146 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1147 echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1151 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1153 AC_MSG_CHECKING(compiler warning flags)
1154 # Separate out the -Werror flag as some files just cannot be
1155 # compiled with it enabled.
1156 for w in ${build_warnings}; do
1158 -Werr*) WERROR_CFLAGS=-Werror ;;
1159 *) # Check that GCC accepts it
1160 saved_CFLAGS="$CFLAGS"
1162 AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1163 CFLAGS="$saved_CFLAGS"
1166 AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1168 AC_SUBST(WARN_CFLAGS)
1169 AC_SUBST(WERROR_CFLAGS)
1171 # In the Cygwin environment, we need some additional flags.
1172 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1173 [AC_EGREP_CPP(lose, [
1174 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1176 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1179 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1180 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1182 *go32* ) SER_HARDWIRE=ser-go32.o ;;
1183 *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1185 AC_SUBST(SER_HARDWIRE)
1187 # libreadline needs libuser32.a in a cygwin environment
1189 if test x$gdb_cv_os_cygwin = xyes; then
1190 WIN32LIBS="-luser32"
1192 *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1198 LIBGUI="../libgui/src/libgui.a"
1199 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1201 AC_SUBST(GUI_CFLAGS_X)
1205 AC_SUBST(WIN32LDAPP)
1217 if test "${enable_gdbtk}" = "yes"; then
1219 # Gdbtk must have an absolute path to srcdir in order to run
1220 # properly when not installed.
1226 CY_AC_PATH_TCLCONFIG
1227 if test -z "${no_tcl}"; then
1228 CY_AC_LOAD_TCLCONFIG
1231 # now look for Tcl library stuff
1233 tcldir="../tcl/${configdir}/"
1235 TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1237 # If $no_tk is nonempty, then we can't do Tk, and there is no
1238 # point to doing Tcl.
1239 if test -z "${no_tk}"; then
1247 # now look for Tk library stuff
1249 tkdir="../tk/${configdir}/"
1251 TK_DEPS="${tkdir}${TK_LIB_FILE}"
1253 # now look for Itcl library stuff
1255 CY_AC_PATH_ITCLCONFIG
1256 if test -z "${no_itcl}"; then
1257 CY_AC_LOAD_ITCLCONFIG
1259 ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1260 ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1264 # now look for Itk library stuff
1265 CY_AC_PATH_ITKCONFIG
1266 if test -z "${no_itcl}"; then
1267 CY_AC_LOAD_ITKCONFIG
1269 ITKLIB="${ITK_BUILD_LIB_SPEC}"
1270 ITK_DEPS="${ITK_LIB_FULL_PATH}"
1273 ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1274 # Tcl/Tk 8.1 require -fwritable strings. I don't
1275 # know whether 8.2 will or not, but I bet it will.
1276 # I don't have to worry about 7.x since we don't support it.
1278 if test "$GCC" = "yes"; then
1279 if test "$TCL_VERSION" != "8.0" ; then
1280 GDBTK_CFLAGS="-fwritable-strings"
1284 # Include some libraries that Tcl and Tk want.
1285 TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1286 # Yes, the ordering seems wrong here. But it isn't.
1287 # TK_LIBS is the list of libraries that need to be linked
1288 # after Tcl/Tk. Note that this isn't put into LIBS. If it
1289 # were in LIBS then any link tests after this point would
1290 # try to include things like `$(LIBGUI)', which wouldn't work.
1291 GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1293 CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1294 CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1295 CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1296 CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1297 CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1298 CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1299 CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1301 if test x$gdb_cv_os_cygwin = xyes; then
1302 WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1303 WIN32LDAPP="-Wl,--subsystem,console"
1304 CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1309 AC_CONFIG_SUBDIRS(gdbtk)
1322 AC_SUBST(GDBTK_CFLAGS)
1323 AC_SUBST(GDBTK_SRC_DIR)
1327 # Check whether we should enable the TUI, but only do so if we really
1329 if test x"$enable_tui" = xyes; then
1330 if test -d $srcdir/tui; then
1331 if test "$ac_cv_search_waddstr" != no; then
1332 CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1333 CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1334 CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1335 CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1336 ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1337 CONFIG_ALL="${CONFIG_ALL} all-tui"
1338 CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1339 CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1340 CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1342 AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1347 # Unlike the sim directory, whether a simulator is linked is controlled by
1348 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1349 # This code just checks for a few cases where we'd like to ignore those
1350 # definitions, even when they're present in the '.mt' file. These cases
1351 # are when --disable-sim is specified, or if the simulator directory is
1352 # not part of the source tree.
1355 [ --enable-sim Link gdb with simulator],
1356 [echo "enable_sim = $enable_sim";
1357 echo "enableval = ${enableval}";
1358 case "${enableval}" in
1359 yes) ignore_sim=false ;;
1360 no) ignore_sim=true ;;
1361 *) ignore_sim=false ;;
1365 if test ! -d "${srcdir}/../sim"; then
1369 if test "${ignore_sim}" = "true"; then
1371 IGNORE_SIM_OBS="SIM_OBS="
1377 AC_SUBST(IGNORE_SIM)
1378 AC_SUBST(IGNORE_SIM_OBS)
1380 AC_SUBST(ENABLE_CFLAGS)
1381 AC_SUBST(PROFILE_CFLAGS)
1383 AC_SUBST(CONFIG_OBS)
1384 AC_SUBST(CONFIG_DEPS)
1385 AC_SUBST(CONFIG_SRCS)
1386 AC_SUBST(CONFIG_ALL)
1387 AC_SUBST(CONFIG_CLEAN)
1388 AC_SUBST(CONFIG_INSTALL)
1389 AC_SUBST(CONFIG_UNINSTALL)
1391 # List of host floatformats.
1392 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1393 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1394 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1396 # target_subdir is used by the testsuite to find the target libraries.
1398 if test "${host}" != "${target}"; then
1399 target_subdir="${target_alias}/"
1401 AC_SUBST(target_subdir)
1404 if test "${target}" = "${host}"; then
1405 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1406 if test ! -f ${host_makefile_frag}; then
1407 AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1409 frags="$frags $host_makefile_frag"
1411 host_makefile_frag=/dev/null
1414 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1415 if test ! -f ${target_makefile_frag}; then
1416 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1418 frags="$frags $target_makefile_frag"
1420 AC_SUBST_FILE(host_makefile_frag)
1421 AC_SUBST_FILE(target_makefile_frag)
1426 s/XM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
1427 ' ${host_makefile_frag}`
1429 targetfile=`sed -n '
1430 s/DEPRECATED_TM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
1431 ' ${target_makefile_frag}`
1433 if test "${target}" = "${host}"; then
1434 # We pick this up from the host configuration file (.mh) because we
1435 # do not have a native configuration Makefile fragment.
1436 nativefile=`sed -n '
1437 s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p
1438 ' ${host_makefile_frag}`
1442 if test x"${gdb_osabi}" != x ; then
1443 AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1444 [Define to the default OS ABI for this configuration.])
1447 # Enable multi-ice-gdb-server.
1448 AC_ARG_ENABLE(multi-ice,
1449 [ --enable-multi-ice build the multi-ice-gdb-server],
1453 *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1455 if test "x$enable_multi_ice" = xyes; then
1456 AC_CONFIG_SUBDIRS(multi-ice)
1459 # We only build gdbserver automatically if host and target are the same.
1460 if test "x$target" = "x$host"; then
1461 AC_MSG_CHECKING(whether gdbserver is supported on this host)
1462 if test "x$build_gdbserver" = xyes; then
1464 AC_CONFIG_SUBDIRS(gdbserver)
1470 # We build rdi-share on ARM-based targets, as instructed by configure.tgt.
1471 if test "x$build_rdi_share" = xyes; then
1472 AC_CONFIG_SUBDIRS(rdi-share)
1475 # We configure the nlm subdirectory on netware targets, as instructed
1477 if test "x$build_nlm" = xyes; then
1478 AC_CONFIG_SUBDIRS(nlm)
1481 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1482 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1483 # to an empty version.
1490 if test "${hostfile}" != ""; then
1492 case "${hostfile}" in
1493 xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1494 * ) GDB_XM_FILE="${hostfile}"
1496 files="${files} ${GDB_XM_FILE}"
1497 links="${links} xm.h"
1498 AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}")
1504 if test "${targetfile}" != ""; then
1506 case "${targetfile}" in
1507 tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1508 * ) GDB_TM_FILE="${targetfile}"
1510 files="${files} ${GDB_TM_FILE}"
1511 links="${links} tm.h"
1512 AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}")
1518 if test "${nativefile}" != ""; then
1520 case "${nativefile}" in
1521 nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1522 * ) GDB_NM_FILE="${nativefile}"
1524 files="${files} ${GDB_NM_FILE}"
1525 links="${links} nm.h"
1526 AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}")
1530 AC_LINK_FILES($files, $links)
1532 dnl Check for exe extension set on certain hosts (e.g. Win32)
1535 dnl Detect the character set used by this host.
1537 dnl At the moment, we just assume it's ISO-8859-1 (which is a
1538 dnl superset of ASCII containing the characters needed for French,
1539 dnl German, Spanish, Italian, and possibly others), but if were
1540 dnl *were* to support any host character sets other than ISO-8859-1,
1541 dnl here's where we'd detect it.
1542 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1543 [Define to be a string naming the default host character set.])
1547 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1549 dnl Autoconf doesn't provide a mechanism for modifying definitions
1550 dnl provided by makefile fragments.
1554 sed -e '/^DEPRECATED_TM_FILE[ ]*=/s,^DEPRECATED_TM_FILE[ ]*=[ ]*,&config/'"${gdb_target_cpu}"'/,
1555 /^XM_FILE[ ]*=/s,^XM_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,
1556 /^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1557 mv -f Makefile.tmp Makefile
1561 case x$CONFIG_HEADERS in
1562 xconfig.h:config.in)
1567 gdb_host_cpu=$gdb_host_cpu
1568 gdb_target_cpu=$gdb_target_cpu
1569 nativefile=$nativefile