gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.59)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files and targets accumulated by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41 CONFIG_SRCS=
  42 ENABLE_CFLAGS=
  43
  44 CONFIG_ALL=
  45 CONFIG_CLEAN=
  46 CONFIG_INSTALL=
  47 CONFIG_UNINSTALL=
  48
  49 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  50
  51 CY_GNU_GETTEXT
  52
  53 localedir='${datadir}/locale'
  54 AC_SUBST(localedir)
  55
  56 if test "x$POSUB" != x; then
  57
  58   dnl Lifted from GCC's config/gettext.m4.
  59   AC_MSG_CHECKING(for catalogs to be installed)
  60   # Look for .po and .gmo files in the source directory.
  61   CATALOGS=  AC_SUBST(CATALOGS)
  62   XLINGUAS=
  63   for cat in $srcdir/po/*.gmo $srcdir/po/*.po; do
  64     # If there aren't any .gmo files the shell will give us the
  65     # literal string "../path/to/srcdir/po/*.gmo" which has to be
  66     # weeded out.
  67     case "$cat" in *\**)
  68       continue;;
  69     esac
  70     # The quadruple backslash is collapsed to a double backslash
  71     # by the backticks, then collapsed again by the double quotes,
  72     # leaving us with one backslash in the sed expression (right
  73     # before the dot that mustn't act as a wildcard).
  74     cat=`echo $cat | sed -e "s!$srcdir/!!" -e "s!\\\\.po!.gmo!"`
  75     lang=`echo $cat | sed -e 's!po/!!' -e "s!\\\\.gmo!!"`
  76     # The user is allowed to set LINGUAS to a list of languages to
  77     # install catalogs for.  If it's empty that means "all of them."
  78     if test "x$LINGUAS" = x; then
  79       CATALOGS="$CATALOGS $cat"
  80       XLINGUAS="$XLINGUAS $lang"
  81     else
  82       case "$LINGUAS" in *$lang*)
  83         CATALOGS="$CATALOGS $cat"
  84         XLINGUAS="$XLINGUAS $lang"
  85         ;;
  86       esac
  87     fi
  88   done
  89   LINGUAS="$XLINGUAS"
  90   AC_MSG_RESULT($LINGUAS)
  91
  92    CONFIG_ALL="$CONFIG_ALL all-po"
  93    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  94    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  95    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  96 fi
  97
  98 PACKAGE=gdb
  99 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 100 AC_SUBST(PACKAGE)
 101
 102 debugdir=${libdir}/debug
 103
 104 AC_ARG_WITH(separate-debug-dir,
 105 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
 106 [debugdir="${withval}"])
 107
 108 AC_DEFINE_DIR(DEBUGDIR, debugdir,
 109               [Global directory for separate debug files. ])
 110 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
 111
 112 AC_CONFIG_SUBDIRS(doc testsuite)
 113
 114 . $srcdir/configure.host
 115
 116 . $srcdir/configure.tgt
 117
 118 # Fetch the default architecture and default target vector from BFD.
 119 targ=$target; . $srcdir/../bfd/config.bfd
 120
 121 # We only want the first architecture, so strip off the others if
 122 # there is more than one.
 123 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 124
 125 if test "x$targ_archs" != x; then
 126   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 127     [Define to BFD's default architecture. ])
 128 fi
 129 if test "x$targ_defvec" != x; then
 130   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 131     [Define to BFD's default target vector. ])
 132 fi
 133
 134 AC_ARG_PROGRAM
 135
 136 # The CLI cannot be disabled yet, but may be in the future.
 137
 138 # Enable CLI.
 139 AC_ARG_ENABLE(gdbcli,
 140 [  --disable-gdbcli        disable command-line interface (CLI)],
 141   [case $enableval in
 142     yes)
 143       ;;
 144     no)
 145       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 146     *)
 147       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 148   esac],
 149   [enable_gdbcli=yes])
 150 if test x"$enable_gdbcli" = xyes; then
 151   if test -d $srcdir/cli; then
 152     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 153     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 154     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 155     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 156   fi
 157 fi
 158
 159 # Enable MI.
 160 AC_ARG_ENABLE(gdbmi,
 161 [  --disable-gdbmi         disable machine-interface (MI)],
 162   [case $enableval in
 163     yes | no)
 164       ;;
 165     *)
 166       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 167   esac],
 168   [enable_gdbmi=yes])
 169 if test x"$enable_gdbmi" = xyes; then
 170   if test -d $srcdir/mi; then
 171     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 172     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 173     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 174     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 175   fi
 176 fi
 177
 178 # Enable TUI.
 179 AC_ARG_ENABLE(tui,
 180 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 181   [case $enableval in
 182     yes | no)
 183       ;;
 184     *)
 185       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 186   esac],enable_tui=yes)
 187
 188 # Enable gdbtk.
 189 AC_ARG_ENABLE(gdbtk,
 190 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 191   [case $enableval in
 192     yes | no)
 193       ;;
 194     *)
 195       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 196   esac],
 197   [if test -d $srcdir/gdbtk -a -d $srcdir/../itcl; then
 198     enable_gdbtk=yes
 199   else
 200     enable_gdbtk=no
 201   fi])
 202 # We unconditionally disable gdbtk tests on selected platforms.
 203 case $host_os in
 204   go32* | windows*)
 205     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 206     enable_gdbtk=no ;;
 207 esac
 208
 209 # Libunwind support.
 210 AC_ARG_WITH(libunwind,
 211 [  --with-libunwind            Use libunwind frame unwinding support],
 212 [case "${withval}" in
 213   yes)  enable_libunwind=yes ;;
 214   no)   enable_libunwind=no ;;
 215   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 216 esac],[
 217   AC_CHECK_HEADERS(libunwind.h)
 218   AC_CHECK_HEADERS(libunwind-ia64.h)
 219   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 220     enable_libunwind=yes;
 221   fi
 222 ])
 223
 224 if test x"$enable_libunwind" = xyes; then
 225   AC_CHECK_HEADERS(libunwind.h)
 226   AC_CHECK_HEADERS(libunwind-ia64.h)
 227   AC_DEFINE(HAVE_LIBUNWIND, 1)
 228   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 229   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 230   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 231 fi
 232
 233 # Profiling support.
 234 AC_ARG_ENABLE(profiling,
 235 [  --enable-profiling      enable profiling of GDB],
 236   [case $enableval in
 237     yes | no)
 238       ;;
 239     *)
 240       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 241   esac],
 242  [enable_profiling=no])
 243
 244 AC_CHECK_FUNCS(monstartup _mcleanup)
 245 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 246 [AC_TRY_LINK(
 247 [#include <stdlib.h>
 248 extern char _etext;
 249 ],
 250 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 251 if test $ac_cv_var__etext = yes; then
 252   AC_DEFINE(HAVE__ETEXT, 1,
 253             [Define to 1 if your system has the _etext variable. ])
 254 fi
 255 if test "$enable_profiling" = yes ; then
 256   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 257     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 258   fi
 259   PROFILE_CFLAGS=-pg
 260   OLD_CFLAGS="$CFLAGS"
 261   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 262
 263   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 264     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 265      ac_cv_cc_supports_pg=no)])
 266
 267   if test $ac_cv_cc_supports_pg = no; then
 268     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 269   fi
 270
 271   CFLAGS="$OLD_CFLAGS"
 272 fi
 273
 274 # --------------------- #
 275 # Checks for programs.  #
 276 # --------------------- #
 277
 278 AC_PROG_AWK
 279 AC_PROG_INSTALL
 280 AC_PROG_LN_S
 281 AC_PROG_RANLIB
 282 AC_PROG_YACC
 283
 284 AC_CHECK_TOOL(AR, ar)
 285 AC_CHECK_TOOL(DLLTOOL, dlltool)
 286 AC_CHECK_TOOL(WINDRES, windres)
 287
 288 # Needed for GNU/Hurd.
 289 AC_CHECK_TOOL(MIG, mig)
 290
 291 # ---------------------- #
 292 # Checks for libraries.  #
 293 # ---------------------- #
 294
 295 # We might need to link with -lm; most simulators need it.
 296 AC_CHECK_LIB(m, main)
 297
 298 # We need to link with -lw to get `wctype' on Solaris before Solaris
 299 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 300 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 301 # is known to have this problem).  Therefore we avoid libw if we can.
 302 AC_CHECK_FUNC(wctype, [],
 303   [AC_CHECK_LIB(w, wctype)])
 304
 305 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 306 AC_SEARCH_LIBS(gethostbyname, nsl)
 307
 308 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 309 AC_SEARCH_LIBS(socketpair, socket)
 310
 311 # For the TUI, we need enhanced curses functionality.
 312 #
 313 # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 314 # curses library because the latter might not provide all the
 315 # functionality we need.  However, this leads to problems on systems
 316 # where the linker searches /usr/local/lib, but the compiler doesn't
 317 # search /usr/local/include, if ncurses is installed in /usr/local.  A
 318 # default installation of ncurses on alpha*-dec-osf* will lead to such
 319 # a situation.
 320 AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 321
 322 # Since GDB uses Readline, we need termcap functionality.  In many
 323 # cases this will be provided by the curses library, but some systems
 324 # have a seperate termcap library, or no curses library at all.
 325
 326 case $host_os in
 327   cygwin*)
 328     if test -d $srcdir/libtermcap; then
 329       LIBS="../libtermcap/libtermcap.a $LIBS"
 330       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 331     fi ;;
 332   go32* | *djgpp*)
 333     ac_cv_search_tgetent="none required"
 334     ;;
 335 esac
 336
 337 # These are the libraries checked by Readline.
 338 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 339
 340 if test "$ac_cv_search_tgetent" = no; then
 341   AC_MSG_ERROR([no termcap library found])
 342 fi
 343
 344 # ------------------------- #
 345 # Checks for header files.  #
 346 # ------------------------- #
 347
 348 AC_HEADER_DIRENT
 349 AC_HEADER_STAT
 350 AC_HEADER_STDC
 351 AC_CHECK_HEADERS(nlist.h)
 352 AC_CHECK_HEADERS(link.h, [], [],
 353 [#if HAVE_SYS_TYPES_H
 354 # include <sys/types.h>
 355 #endif
 356 #if HAVE_NLIST_H
 357 # include <nlist.h>
 358 #endif
 359 ])
 360 AC_CHECK_HEADERS(machine/reg.h)
 361 AC_CHECK_HEADERS(poll.h sys/poll.h)
 362 AC_CHECK_HEADERS(proc_service.h thread_db.h gnu/libc-version.h)
 363 AC_CHECK_HEADERS(stddef.h)
 364 AC_CHECK_HEADERS(stdlib.h)
 365 AC_CHECK_HEADERS(stdint.h)
 366 AC_CHECK_HEADERS(string.h memory.h strings.h)
 367 AC_CHECK_HEADERS(sys/fault.h)
 368 AC_CHECK_HEADERS(sys/file.h)
 369 AC_CHECK_HEADERS(sys/filio.h)
 370 AC_CHECK_HEADERS(sys/ioctl.h)
 371 AC_CHECK_HEADERS(sys/param.h)
 372 AC_CHECK_HEADERS(sys/proc.h, [], [],
 373 [#if HAVE_SYS_PARAM_H
 374 # include <sys/param.h>
 375 #endif
 376 ])
 377 AC_CHECK_HEADERS(sys/procfs.h)
 378 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 379 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 380 AC_CHECK_HEADERS(sys/select.h)
 381 AC_CHECK_HEADERS(sys/syscall.h)
 382 AC_CHECK_HEADERS(sys/types.h)
 383 AC_CHECK_HEADERS(sys/user.h, [], [],
 384 [#if HAVE_SYS_PARAM_H
 385 # include <sys/param.h>
 386 #endif
 387 ])
 388 AC_CHECK_HEADERS(sys/wait.h wait.h)
 389 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 390 AC_CHECK_HEADERS(unistd.h)
 391
 392 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
 393 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 394 # think that we don't have <curses.h> if we're using GCC.
 395 case $host_os in
 396   solaris2.[[789]])
 397     if test "$GCC" = yes; then
 398       AC_DEFINE(_MSE_INT_H, 1,
 399         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 400    Solaris 2.[789] when using GCC. ])
 401     fi ;;
 402 esac
 403 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h)
 404 AC_CHECK_HEADERS(ncurses/term.h)
 405 AC_CHECK_HEADERS(term.h, [], [],
 406 [#if HAVE_CURSES_H
 407 # include <curses.h>
 408 #endif
 409 ])
 410
 411 # FIXME: kettenis/20030102: In most cases we include these
 412 # unconditionally, so what's the point in checking these?
 413 AC_CHECK_HEADERS(ctype.h time.h)
 414
 415 # ------------------------- #
 416 # Checks for declarations.  #
 417 # ------------------------- #
 418
 419 AC_CHECK_DECLS([free, malloc, realloc])
 420 AC_CHECK_DECLS([strerror, strstr])
 421 AC_CHECK_DECLS([getopt, snprintf, vsnprintf])
 422
 423 # ----------------------- #
 424 # Checks for structures.  #
 425 # ----------------------- #
 426
 427 AC_CHECK_MEMBERS([struct stat.st_blocks])
 428 AC_CHECK_MEMBERS([struct stat.st_blksize])
 429
 430 # ------------------ #
 431 # Checks for types.  #
 432 # ------------------ #
 433
 434 AC_TYPE_SIGNAL
 435 AC_CHECK_TYPES(socklen_t, [], [],
 436 [#include <sys/types.h>
 437 #include <sys/socket.h>
 438 ])
 439 AC_CHECK_TYPES(uintptr_t, [], [], [#include <stdint.h>])
 440
 441 # ------------------------------------- #
 442 # Checks for compiler characteristics.  #
 443 # ------------------------------------- #
 444
 445 AC_C_CONST
 446 AC_C_INLINE
 447
 448 # ------------------------------ #
 449 # Checks for library functions.  #
 450 # ------------------------------ #
 451
 452 AC_FUNC_ALLOCA
 453 AC_FUNC_MMAP
 454 AC_FUNC_VFORK
 455 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 456 AC_CHECK_FUNCS(getuid getgid)
 457 AC_CHECK_FUNCS(poll)
 458 AC_CHECK_FUNCS(pread64)
 459 AC_CHECK_FUNCS(sbrk)
 460 AC_CHECK_FUNCS(setpgid setpgrp)
 461 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 462 AC_CHECK_FUNCS(socketpair)
 463 AC_CHECK_FUNCS(syscall)
 464 AC_CHECK_FUNCS(ttrace)
 465 AC_CHECK_FUNCS(wborder)
 466
 467 # Check the return and argument types of ptrace.  No canned test for
 468 # this, so roll our own.
 469 gdb_ptrace_headers='
 470 #if HAVE_SYS_TYPES_H
 471 # include <sys/types.h>
 472 #endif
 473 #if HAVE_SYS_PTRACE_H
 474 # include <sys/ptrace.h>
 475 #endif
 476 #if HAVE_UNISTD_H
 477 # include <unistd.h>
 478 #endif
 479 '
 480 # There is no point in checking if we don't have a prototype.
 481 AC_CHECK_DECLS(ptrace, [], [
 482   : ${gdb_cv_func_ptrace_ret='int'}
 483   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 484 ], $gdb_ptrace_headers)
 485 # Check return type.
 486 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
 487   AC_TRY_COMPILE($gdb_ptrace_headers,
 488     [extern int ptrace ();],
 489     gdb_cv_func_ptrace_ret='int',
 490     gdb_cv_func_ptrace_ret='long'))
 491 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
 492   [Define as the return type of ptrace.])
 493 # Check argument types.
 494 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
 495 for gdb_arg1 in 'int' 'long'; do
 496  for gdb_arg2 in 'pid_t' 'int' 'long'; do
 497   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long'; do
 498    for gdb_arg4 in 'int' 'long'; do
 499      AC_TRY_COMPILE($gdb_ptrace_headers, [
 500 extern $gdb_cv_func_ptrace_ret
 501   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
 502 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
 503     break 4;])
 504     for gdb_arg5 in 'int *' 'int' 'long'; do
 505      AC_TRY_COMPILE($gdb_ptrace_headers, [
 506 extern $gdb_cv_func_ptrace_ret
 507   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
 508 ], [
 509 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
 510     break 5;])
 511     done
 512    done
 513   done
 514  done
 515 done
 516 # Provide a safe default value.
 517 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
 518 ])
 519 ac_save_IFS=$IFS; IFS=','
 520 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
 521 IFS=$ac_save_IFS
 522 shift
 523 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
 524   [Define to the type of arg 3 for ptrace.])
 525 if test -n "$[5]"; then
 526   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
 527     [Define to the type of arg 5 for ptrace.])
 528 fi
 529
 530 dnl AC_FUNC_SETPGRP does not work when cross compiling
 531 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 532 if test "$cross_compiling" = no; then
 533   AC_FUNC_SETPGRP
 534 else
 535   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 536     [AC_TRY_COMPILE([
 537 #include <unistd.h>
 538 ], [
 539   if (setpgrp(1,1) == -1)
 540     exit (0);
 541   else
 542     exit (1);
 543 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 544 if test $ac_cv_func_setpgrp_void = yes; then
 545   AC_DEFINE(SETPGRP_VOID, 1)
 546 fi
 547 fi
 548
 549 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 550 # since sigsetjmp might only be defined as a macro.
 551 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 552 [AC_TRY_COMPILE([
 553 #include <setjmp.h>
 554 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 555 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 556 if test $gdb_cv_func_sigsetjmp = yes; then
 557   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 558 fi
 559
 560 # Assume we'll default to using the included libiberty regex.
 561 gdb_use_included_regex=yes
 562
 563 # However, if the system regex is GNU regex, then default to *not*
 564 # using the included regex.
 565 AC_CACHE_CHECK(
 566   [for GNU regex],
 567   [gdb_cv_have_gnu_regex],
 568   [AC_TRY_COMPILE(
 569     [#include <gnu-versions.h>],
 570     [#define REGEX_INTERFACE_VERSION 1
 571 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 572 # error "Version mismatch"
 573 #endif],
 574     gdb_cv_have_gnu_regex=yes,
 575     gdb_cv_have_gnu_regex=no)])
 576 if test $gdb_cv_have_gnu_regex = yes; then
 577   gdb_use_included_regex=no
 578 fi
 579
 580 AC_ARG_WITH(included-regex,
 581   [  --without-included-regex don't use included regex; this is the default
 582                           on systems with version 2 of the GNU C library
 583                           (use with caution on other system)],
 584   gdb_with_regex=$withval,
 585   gdb_with_regex=$gdb_use_included_regex)
 586 if test "$gdb_with_regex" = yes; then
 587   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 588     [Define to 1 if the regex included in libiberty should be used.])
 589 fi
 590
 591 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
 592 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
 593 [#include <sys/param.h>
 594 #include <sys/proc.h>
 595 ])
 596
 597 # See if <sys/lwp.h> defines `struct lwp`.
 598 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
 599 [AC_TRY_COMPILE([#include <sys/param.h>
 600 #include <sys/lwp.h>], [struct lwp l;],
 601 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
 602 if test $gdb_cv_struct_lwp = yes; then
 603   AC_DEFINE(HAVE_STRUCT_LWP, 1,
 604             [Define to 1 if your system has struct lwp.])
 605 fi
 606
 607 # See if <machine/reg.h> degines `struct reg'.
 608 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 609 [AC_TRY_COMPILE([#include <sys/types.h>
 610 #include <machine/reg.h>], [struct reg r;],
 611 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 612 if test $gdb_cv_struct_reg = yes; then
 613   AC_DEFINE(HAVE_STRUCT_REG, 1,
 614             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 615 fi
 616
 617 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 618 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 619 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
 620                  [#include <machine/reg.h>])
 621
 622 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 623 AC_MSG_CHECKING(for PTRACE_GETREGS)
 624 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 625 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 626                 [PTRACE_GETREGS;],
 627                 [gdb_cv_have_ptrace_getregs=yes],
 628                 [gdb_cv_have_ptrace_getregs=no])])
 629 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 630 if test $gdb_cv_have_ptrace_getregs = yes; then
 631   AC_DEFINE(HAVE_PTRACE_GETREGS)
 632 fi
 633
 634 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 635 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 636 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 637 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 638                 [PTRACE_GETFPXREGS;],
 639                 [gdb_cv_have_ptrace_getfpxregs=yes],
 640                 [gdb_cv_have_ptrace_getfpxregs=no])])
 641 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 642 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 643   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 644 fi
 645
 646 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 647 AC_MSG_CHECKING(for PT_GETDBREGS)
 648 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 649 [AC_TRY_COMPILE([#include <sys/types.h>
 650 #include <sys/ptrace.h>],
 651                 [PT_GETDBREGS;],
 652                 [gdb_cv_have_pt_getdbregs=yes],
 653                 [gdb_cv_have_pt_getdbregs=no])])
 654 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 655 if test $gdb_cv_have_pt_getdbregs = yes; then
 656   AC_DEFINE(HAVE_PT_GETDBREGS)
 657 fi
 658
 659 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 660 AC_MSG_CHECKING(for PT_GETXMMREGS)
 661 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 662 [AC_TRY_COMPILE([#include <sys/types.h>
 663 #include <sys/ptrace.h>],
 664                 [PT_GETXMMREGS;],
 665                 [gdb_cv_have_pt_getxmmregs=yes],
 666                 [gdb_cv_have_pt_getxmmregs=no])])
 667 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 668 if test $gdb_cv_have_pt_getxmmregs = yes; then
 669   AC_DEFINE(HAVE_PT_GETXMMREGS)
 670 fi
 671
 672 # If we are configured native on GNU/Linux, work around problems with
 673 # sys/procfs.h
 674 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 675
 676 if test "${target}" = "${host}"; then
 677   case "${host}" in
 678   i[[3456]]86-*-linux*)
 679         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 680         AC_DEFINE(sys_quotactl)
 681         ;;
 682   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 683       AC_DEFINE(NEW_PROC_API)
 684       ;;
 685   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]])
 686       AC_DEFINE(NEW_PROC_API)
 687       ;;
 688   mips-sgi-irix5*)
 689       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
 690       AC_DEFINE([_KMEMUSER], 1)
 691       ;;
 692   esac
 693 fi
 694
 695 if test "$ac_cv_header_sys_procfs_h" = yes; then
 696   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 697   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 698   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 699   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 700   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 701   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 702   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 703   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 704   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 705   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 706   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 707   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 708   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 709   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 710
 711
 712   dnl Check for broken prfpregset_t type
 713
 714   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 715   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 716   dnl instead of the struct itself).  We detect this here, and work
 717   dnl around it in gdb_proc_service.h.
 718
 719   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 720     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 721     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 722       [AC_TRY_RUN([#include <sys/procfs.h>
 723        int main ()
 724        {
 725          if (sizeof (prfpregset_t) == sizeof (void *))
 726            return 1;
 727          return 0;
 728        }],
 729        gdb_cv_prfpregset_t_broken=no,
 730        gdb_cv_prfpregset_t_broken=yes,
 731        gdb_cv_prfpregset_t_broken=yes)])
 732     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 733     if test $gdb_cv_prfpregset_t_broken = yes; then
 734       AC_DEFINE(PRFPREGSET_T_BROKEN)
 735     fi
 736   fi
 737
 738   dnl Check for PIOCSET ioctl entry
 739
 740   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 741   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 742   [AC_TRY_COMPILE([#include <unistd.h>
 743 #include <sys/types.h>
 744 #include <sys/procfs.h>
 745 ], [
 746     int dummy;;
 747     dummy = ioctl(0, PIOCSET, &dummy);
 748   ],
 749   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 750   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 751   if test $gdb_cv_have_procfs_piocset = yes; then
 752     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 753   fi
 754 fi
 755
 756 dnl For native ports (host == target), check to see what kind of
 757 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 758 if test ${host} = ${target} ; then
 759   dnl Check for struct link_map with l_ members which are indicative
 760   dnl of SVR4-like shared libraries
 761
 762   AC_MSG_CHECKING(for member l_addr in struct link_map)
 763   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 764     [AC_TRY_COMPILE([#include <link.h>],
 765                     [struct link_map lm; (void) lm.l_addr;],
 766                     gdb_cv_have_struct_link_map_with_l_members=yes,
 767                     gdb_cv_have_struct_link_map_with_l_members=no)])
 768   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 769   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 770     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 771   fi
 772
 773   dnl Check for struct link_map with lm_ members which are indicative
 774   dnl of SunOS-like shared libraries
 775
 776   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 777   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 778     [AC_TRY_COMPILE([#include <sys/types.h>
 779 #include <link.h>],
 780                     [struct link_map lm; (void) lm.lm_addr;],
 781                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 782                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 783   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 784   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 785     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 786   fi
 787
 788   dnl Check for struct so_map with som_ members which are found on
 789   dnl some *BSD systems.
 790
 791   AC_MSG_CHECKING(for member som_addr in struct so_map)
 792   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 793     [AC_TRY_COMPILE([#include <sys/types.h>
 794 #ifdef HAVE_NLIST_H
 795 #include <nlist.h>
 796 #endif
 797 #include <link.h>],
 798                     [struct so_map lm; (void) lm.som_addr;],
 799                     gdb_cv_have_struct_so_map_with_som_members=yes,
 800                     gdb_cv_have_struct_so_map_with_som_members=no)])
 801   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 802   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 803     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 804   fi
 805
 806   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 807   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 808
 809   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 810   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 811     [AC_TRY_COMPILE([#define _SYSCALL32
 812 #include <sys/link.h>], [struct link_map32 l;],
 813      gdb_cv_have_struct_link_map32=yes,
 814      gdb_cv_have_struct_link_map32=no)])
 815   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 816   if test $gdb_cv_have_struct_link_map32 = yes; then
 817     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 818     AC_DEFINE(_SYSCALL32)
 819   fi
 820 fi
 821
 822 # Check if the compiler supports the `long long' type.
 823
 824 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
 825                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 826 [[extern long long foo;]],
 827 [[switch (foo & 2) { case 0: return 1; }]])],
 828                                   gdb_cv_c_long_long=yes,
 829                                   gdb_cv_c_long_long=no)])
 830 if test $gdb_cv_c_long_long = yes; then
 831   AC_DEFINE(CC_HAS_LONG_LONG, 1,
 832             [Define to 1 if the compiler supports long long.])
 833 fi
 834
 835 # Check if the compiler and runtime support printing long longs.
 836
 837 AC_CACHE_CHECK([for long long support in printf],
 838                gdb_cv_printf_has_long_long,
 839                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 840 [[char buf[32];
 841   long long l = 0;
 842   l = (l << 16) + 0x0123;
 843   l = (l << 16) + 0x4567;
 844   l = (l << 16) + 0x89ab;
 845   l = (l << 16) + 0xcdef;
 846   sprintf (buf, "0x%016llx", l);
 847   return (strcmp ("0x0123456789abcdef", buf));]])],
 848                               gdb_cv_printf_has_long_long=yes,
 849                               gdb_cv_printf_has_long_long=no,
 850                               gdb_cv_printf_has_long_long=no)])
 851 if test $gdb_cv_printf_has_long_long = yes; then
 852   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
 853             [Define to 1 if the "%ll" format works to print long longs.])
 854 fi
 855
 856 # Check if the compiler supports the `long double' type.  We can't use
 857 # AC_C_LONG_DOUBLE because that one does additional checks on the
 858 # constants defined in <float.h> that fail on some systems,
 859 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
 860
 861 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
 862                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
 863                                   gdb_cv_c_long_double=yes,
 864                                   gdb_cv_c_long_double=no)])
 865 if test $gdb_cv_c_long_double = yes; then
 866   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
 867            [Define to 1 if the compiler supports long double.])
 868 fi
 869
 870 # Check if the compiler and runtime support printing long doubles.
 871
 872 AC_CACHE_CHECK([for long double support in printf],
 873                gdb_cv_printf_has_long_double,
 874                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 875 [[char buf[16];
 876   long double f = 3.141592653;
 877   sprintf (buf, "%Lg", f);
 878   return (strncmp ("3.14159", buf, 7));]])],
 879                               gdb_cv_printf_has_long_double=yes,
 880                               gdb_cv_printf_has_long_double=no,
 881                               gdb_cv_printf_has_long_double=no)])
 882 if test $gdb_cv_printf_has_long_double = yes; then
 883   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
 884             [Define to 1 if the "%Lg" format works to print long doubles.])
 885 fi
 886
 887 # Check if the compiler and runtime support scanning long doubles.
 888
 889 AC_CACHE_CHECK([for long double support in scanf],
 890                gdb_cv_scanf_has_long_double,
 891                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 892 [[#include <stdio.h>]],
 893 [[char *buf = "3.141592653";
 894   long double f = 0;
 895   sscanf (buf, "%Lg", &f);
 896   return !(f > 3.14159 && f < 3.14160);]])],
 897                               gdb_cv_scanf_has_long_double=yes,
 898                               gdb_cv_scanf_has_long_double=no,
 899                               gdb_cv_scanf_has_long_double=no)])
 900 if test $gdb_cv_scanf_has_long_double = yes; then
 901   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
 902             [Define to 1 if the "%Lg" format works to scan long doubles.])
 903 fi
 904
 905 case ${host_os} in
 906 aix*)
 907   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 908     SAVE_LDFLAGS=$LDFLAGS
 909
 910     case $GCC in
 911     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 912     *) gdb_cv_bigtoc=-bbigtoc ;;
 913     esac
 914
 915     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 916     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 917     LDFLAGS="${SAVE_LDFLAGS}"
 918   ])
 919   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 920   ;;
 921 esac
 922
 923
 924 dnl For certain native configurations, we need to check whether thread
 925 dnl support can be built in or not.
 926 dnl
 927 dnl Note that we only want this if we are both native (host == target),
 928 dnl and not doing a canadian cross build (build == host).
 929
 930 if test ${build} = ${host} -a ${host} = ${target} ; then
 931    case ${host_os} in
 932    hpux*)
 933       AC_MSG_CHECKING(for HPUX/OSF thread support)
 934       if test -f /usr/include/dce/cma_config.h ; then
 935          if test "$GCC" = "yes" ; then
 936             AC_MSG_RESULT(yes)
 937             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 938             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 939             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 940          else
 941             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 942          fi
 943       else
 944          AC_MSG_RESULT(no)
 945       fi
 946       ;;
 947    solaris*)
 948       # See if thread_db library is around for Solaris thread debugging.
 949       # Note that we must explicitly test for version 1 of the library
 950       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 951       # the same API.
 952       AC_MSG_CHECKING(for Solaris thread debugging library)
 953       if test -f /usr/lib/libthread_db.so.1 ; then
 954          AC_MSG_RESULT(yes)
 955          AC_DEFINE(HAVE_THREAD_DB_LIB)
 956          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 957          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 958          AC_CHECK_LIB(dl, dlopen)
 959          if test "$GCC" = "yes" ; then
 960             # The GNU linker requires the -export-dynamic option to make
 961             # all symbols visible in the dynamic symbol table.
 962             hold_ldflags=$LDFLAGS
 963             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 964             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 965             AC_TRY_LINK(, [int i;], found=yes, found=no)
 966             LDFLAGS=$hold_ldflags
 967             AC_MSG_RESULT($found)
 968             if test $found = yes; then
 969                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 970             fi
 971          fi
 972          # Sun randomly tweaked the prototypes in <proc_service.h>
 973          # at one point.
 974          AC_MSG_CHECKING(if <proc_service.h> is old)
 975          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 976             AC_TRY_COMPILE([
 977                 #include <proc_service.h>
 978                 ps_err_e ps_pdwrite
 979                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 980             ],, gdb_cv_proc_service_is_old=no,
 981                 gdb_cv_proc_service_is_old=yes)
 982          ])
 983          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 984          if test $gdb_cv_proc_service_is_old = yes; then
 985             AC_DEFINE(PROC_SERVICE_IS_OLD)
 986          fi
 987       else
 988          AC_MSG_RESULT(no)
 989       fi
 990       ;;
 991    aix*)
 992       AC_MSG_CHECKING(for AiX thread debugging library)
 993       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 994                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 995                                    [#ifndef PTHDB_VERSION_3
 996                                     #error
 997                                     #endif],
 998                                    gdb_cv_have_aix_thread_debug=yes,
 999                                    gdb_cv_have_aix_thread_debug=no)])
1000       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1001       if test $gdb_cv_have_aix_thread_debug = yes; then
1002          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1003          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1004          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
1005       fi
1006       ;;
1007    esac
1008    AC_SUBST(CONFIG_LDFLAGS)
1009 fi
1010
1011 dnl See if we have a thread_db header file that has TD_NOTALLOC.
1012 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1013    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1014                   gdb_cv_thread_db_h_has_td_notalloc,
1015      AC_TRY_COMPILE(
1016        [#include <thread_db.h>],
1017        [int i = TD_NOTALLOC;],
1018        gdb_cv_thread_db_h_has_td_notalloc=yes,
1019        gdb_cv_thread_db_h_has_td_notalloc=no
1020      )
1021    )
1022 fi
1023 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1024   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1025             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1026 fi
1027
1028 dnl See if we have a sys/syscall header file that has __NR_tkill.
1029 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1030    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1031                   gdb_cv_sys_syscall_h_has_tkill,
1032      AC_TRY_COMPILE(
1033        [#include <sys/syscall.h>],
1034        [int i = __NR_tkill;],
1035        gdb_cv_sys_syscall_h_has_tkill=yes,
1036        gdb_cv_sys_syscall_h_has_tkill=no
1037      )
1038    )
1039 fi
1040 dnl See if we can issue tkill syscall.
1041 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
1042   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
1043             [Define if we can use the tkill syscall.])
1044 fi
1045
1046 dnl Handle optional features that can be enabled.
1047
1048 AC_ARG_WITH(sysroot,
1049 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
1050 [
1051  case ${with_sysroot} in
1052  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
1053  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
1054  esac
1055
1056  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
1057
1058  if test "x$exec_prefix" = xNONE; then
1059   if test "x$prefix" = xNONE; then
1060    test_prefix=/usr/local
1061   else
1062    test_prefix=$prefix
1063   fi
1064  else
1065   test_prefix=$exec_prefix
1066  fi
1067  case ${TARGET_SYSTEM_ROOT} in
1068  "${test_prefix}"|"${test_prefix}/"*|\
1069  '${exec_prefix}'|'${exec_prefix}/'*)
1070    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
1071    TARGET_SYSTEM_ROOT_DEFINE="$t"
1072    ;;
1073  esac
1074 ], [
1075  TARGET_SYSTEM_ROOT=
1076  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1077 ])
1078 AC_SUBST(TARGET_SYSTEM_ROOT)
1079 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1080
1081 # NOTE: Don't add -Wall or -Wunused, they both include
1082 # -Wunused-parameter which reports bogus warnings.
1083 # NOTE: If you add to this list, remember to update
1084 # gdb/doc/gdbint.texinfo.
1085 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1086 -Wformat -Wparentheses -Wpointer-arith -Wformat-nonliteral \
1087 -Wunused-label -Wunused-function"
1088
1089 # GCC supports -Wuninitialized only with -O or -On, n != 0.
1090 if test x${CFLAGS+set} = xset; then
1091   case "${CFLAGS}" in
1092     *"-O0"* ) ;;
1093     *"-O"* )
1094       build_warnings="${build_warnings} -Wuninitialized"
1095     ;;
1096   esac
1097 else
1098   build_warnings="${build_warnings} -Wuninitialized"
1099 fi
1100
1101 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1102 # -Wunused-function -Wunused-variable -Wunused-value
1103 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1104 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1105 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1106 # -Woverloaded-virtual -Winline -Werror"
1107 AC_ARG_ENABLE(build-warnings,
1108 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1109 [case "${enableval}" in
1110   yes)  ;;
1111   no)   build_warnings="-w";;
1112   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1113         build_warnings="${build_warnings} ${t}";;
1114   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1115         build_warnings="${t} ${build_warnings}";;
1116   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1117 esac
1118 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1119   echo "Setting compiler warning flags = $build_warnings" 6>&1
1120 fi])dnl
1121 AC_ARG_ENABLE(gdb-build-warnings,
1122 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1123 [case "${enableval}" in
1124   yes)  ;;
1125   no)   build_warnings="-w";;
1126   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1127         build_warnings="${build_warnings} ${t}";;
1128   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1129         build_warnings="${t} ${build_warnings}";;
1130   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1131 esac
1132 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1133   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1134 fi])dnl
1135 WARN_CFLAGS=""
1136 WERROR_CFLAGS=""
1137 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1138 then
1139     AC_MSG_CHECKING(compiler warning flags)
1140     # Separate out the -Werror flag as some files just cannot be
1141     # compiled with it enabled.
1142     for w in ${build_warnings}; do
1143         case $w in
1144         -Werr*) WERROR_CFLAGS=-Werror ;;
1145         *) # Check that GCC accepts it
1146             saved_CFLAGS="$CFLAGS"
1147             CFLAGS="$CFLAGS $w"
1148             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1149             CFLAGS="$saved_CFLAGS"
1150         esac
1151     done
1152     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1153 fi
1154 AC_SUBST(WARN_CFLAGS)
1155 AC_SUBST(WERROR_CFLAGS)
1156
1157 # In the Cygwin environment, we need some additional flags.
1158 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1159 [AC_EGREP_CPP(lose, [
1160 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1161 lose
1162 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1163
1164
1165 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1166 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1167 case ${host} in
1168   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1169   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1170   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o" ;;
1171 esac
1172 AC_SUBST(SER_HARDWIRE)
1173
1174 # libreadline needs libuser32.a in a cygwin environment
1175 WIN32LIBS=
1176 if test x$gdb_cv_os_cygwin = xyes; then
1177     WIN32LIBS="-luser32"
1178     case "${target}" in
1179         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1180         ;;
1181     esac
1182 fi
1183
1184 # The ser-tcp.c module requires sockets.
1185 case ${host} in
1186   *mingw32*)
1187     AC_DEFINE(USE_WIN32API, 1,
1188               [Define if we should use the Windows API, instead of the
1189                POSIX API.  On Windows, we use the Windows API when
1190                building for MinGW, but the POSIX API when building
1191                for Cygwin.])
1192     WIN32LIBS="$WIN32LIBS -lws2_32"
1193     ;;
1194 esac
1195 AC_SUBST(WIN32LIBS)
1196
1197 LIBGUI="../libgui/src/libgui.a"
1198 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1199 AC_SUBST(LIBGUI)
1200 AC_SUBST(GUI_CFLAGS_X)
1201
1202 WIN32LDAPP=
1203 AC_SUBST(WIN32LIBS)
1204 AC_SUBST(WIN32LDAPP)
1205
1206 case "${host}" in
1207 *-*-cygwin*)
1208     configdir="win"
1209     ;;
1210 *)
1211     configdir="unix"
1212     ;;
1213 esac
1214
1215 GDBTKLIBS=
1216 if test "${enable_gdbtk}" = "yes"; then
1217
1218     # Gdbtk must have an absolute path to srcdir in order to run
1219     # properly when not installed.
1220     here=`pwd`
1221     cd ${srcdir}
1222     GDBTK_SRC_DIR=`pwd`
1223     cd $here
1224
1225     CY_AC_PATH_TCLCONFIG
1226     if test -z "${no_tcl}"; then
1227         CY_AC_LOAD_TCLCONFIG
1228         CY_AC_PATH_TKCONFIG
1229
1230         # now look for Tcl library stuff
1231
1232         tcldir="../tcl/${configdir}/"
1233
1234         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1235
1236         # If $no_tk is nonempty, then we can't do Tk, and there is no
1237         # point to doing Tcl.
1238         if test -z "${no_tk}"; then
1239            CY_AC_LOAD_TKCONFIG
1240            CY_AC_PATH_TCLH
1241            CY_AC_PATH_TKH
1242            CY_AC_PATH_ITCLH
1243            CY_AC_PATH_ITKH
1244
1245
1246            # now look for Tk library stuff
1247
1248            tkdir="../tk/${configdir}/"
1249
1250            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1251
1252            # now look for Itcl library stuff
1253
1254            CY_AC_PATH_ITCLCONFIG
1255            if test -z "${no_itcl}"; then
1256              CY_AC_LOAD_ITCLCONFIG
1257
1258              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1259              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1260            fi
1261
1262
1263            # now look for Itk library stuff
1264            CY_AC_PATH_ITKCONFIG
1265            if test -z "${no_itcl}"; then
1266              CY_AC_LOAD_ITKCONFIG
1267
1268              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1269              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1270            fi
1271
1272            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1273
1274            # Include some libraries that Tcl and Tk want.
1275            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1276            # Yes, the ordering seems wrong here.  But it isn't.
1277            # TK_LIBS is the list of libraries that need to be linked
1278            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1279            # were in LIBS then any link tests after this point would
1280            # try to include things like `$(LIBGUI)', which wouldn't work.
1281            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1282
1283            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1284            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1285            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1286            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1287            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1288            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1289            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1290
1291            if test x$gdb_cv_os_cygwin = xyes; then
1292               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1293               WIN32LDAPP="-Wl,--subsystem,console"
1294               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1295            fi
1296         fi
1297     fi
1298
1299     AC_CONFIG_SUBDIRS(gdbtk)
1300 fi
1301
1302 AC_SUBST(X_CFLAGS)
1303 AC_SUBST(X_LDFLAGS)
1304 AC_SUBST(X_LIBS)
1305 AC_SUBST(TCL_DEPS)
1306 AC_SUBST(TK_DEPS)
1307 AC_SUBST(ITCLLIB)
1308 AC_SUBST(ITCL_DEPS)
1309 AC_SUBST(ITKLIB)
1310 AC_SUBST(ITK_DEPS)
1311 AC_SUBST(GDBTKLIBS)
1312 AC_SUBST(GDBTK_CFLAGS)
1313 AC_SUBST(GDBTK_SRC_DIR)
1314
1315 AC_PATH_X
1316
1317 # Check whether we should enable the TUI, but only do so if we really
1318 # can.
1319 if test x"$enable_tui" = xyes; then
1320   if test -d $srcdir/tui; then
1321     if test "$ac_cv_search_waddstr" != no; then
1322       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
1323       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
1324       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
1325       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
1326       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
1327       CONFIG_ALL="${CONFIG_ALL} all-tui"
1328       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
1329       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
1330       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
1331     else
1332       AC_MSG_WARN([no enhanced curses library found; disabling TUI])
1333     fi
1334   fi
1335 fi
1336
1337 # Unlike the sim directory, whether a simulator is linked is controlled by
1338 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1339 # This code just checks for a few cases where we'd like to ignore those
1340 # definitions, even when they're present in the '.mt' file.  These cases
1341 # are when --disable-sim is specified, or if the simulator directory is
1342 # not part of the source tree.
1343 #
1344 AC_ARG_ENABLE(sim,
1345 [  --enable-sim            Link gdb with simulator],
1346 [echo "enable_sim = $enable_sim";
1347  echo "enableval = ${enableval}";
1348  case "${enableval}" in
1349   yes) ignore_sim=false ;;
1350   no)  ignore_sim=true ;;
1351   *)   ignore_sim=false ;;
1352  esac],
1353 [ignore_sim=false])
1354
1355 if test ! -d "${srcdir}/../sim"; then
1356   ignore_sim=true
1357 fi
1358
1359 if test "${ignore_sim}" = "true"; then
1360     IGNORE_SIM="SIM="
1361     IGNORE_SIM_OBS="SIM_OBS="
1362 else
1363     IGNORE_SIM=""
1364     IGNORE_SIM_OBS=""
1365     AC_DEFINE(WITH_SIM)
1366 fi
1367 AC_SUBST(IGNORE_SIM)
1368 AC_SUBST(IGNORE_SIM_OBS)
1369
1370 AC_SUBST(ENABLE_CFLAGS)
1371 AC_SUBST(PROFILE_CFLAGS)
1372
1373 AC_SUBST(CONFIG_OBS)
1374 AC_SUBST(CONFIG_DEPS)
1375 AC_SUBST(CONFIG_SRCS)
1376 AC_SUBST(CONFIG_ALL)
1377 AC_SUBST(CONFIG_CLEAN)
1378 AC_SUBST(CONFIG_INSTALL)
1379 AC_SUBST(CONFIG_UNINSTALL)
1380
1381 # List of host floatformats.
1382 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1383 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
1384 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
1385
1386 # target_subdir is used by the testsuite to find the target libraries.
1387 target_subdir=
1388 if test "${host}" != "${target}"; then
1389     target_subdir="${target_alias}/"
1390 fi
1391 AC_SUBST(target_subdir)
1392
1393 frags=
1394 if test "${target}" = "${host}"; then
1395   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1396   if test ! -f ${host_makefile_frag}; then
1397     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1398   fi
1399   frags="$frags $host_makefile_frag"
1400 else
1401   host_makefile_frag=/dev/null
1402 fi
1403
1404 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1405 if test ! -f ${target_makefile_frag}; then
1406   AC_MSG_ERROR("*** Gdb does not support target ${target}")
1407 fi
1408 frags="$frags $target_makefile_frag"
1409
1410 AC_SUBST_FILE(host_makefile_frag)
1411 AC_SUBST_FILE(target_makefile_frag)
1412 AC_SUBST(frags)
1413
1414 changequote(,)dnl
1415 hostfile=`sed -n '
1416 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1417 ' ${host_makefile_frag}`
1418
1419 targetfile=`sed -n '
1420 s/DEPRECATED_TM_FILE[   ]*=[    ]*\([^  ]*\)/\1/p
1421 ' ${target_makefile_frag}`
1422
1423 if test "${target}" = "${host}"; then
1424 # We pick this up from the host configuration file (.mh) because we
1425 # do not have a native configuration Makefile fragment.
1426 nativefile=`sed -n '
1427 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1428 ' ${host_makefile_frag}`
1429 fi
1430 changequote([,])
1431
1432 if test x"${gdb_osabi}" != x ; then
1433     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1434                        [Define to the default OS ABI for this configuration.])
1435 fi
1436
1437 # Enable multi-ice-gdb-server.
1438 AC_ARG_ENABLE(multi-ice,
1439 [  --enable-multi-ice      build the multi-ice-gdb-server],
1440   [case $enableval in
1441     yes | no)
1442       ;;
1443     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1444   esac])
1445 if test "x$enable_multi_ice" = xyes; then
1446    AC_CONFIG_SUBDIRS(multi-ice)
1447 fi
1448
1449 # We only build gdbserver automatically if host and target are the same.
1450 if test "x$target" = "x$host"; then
1451   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1452   if test "x$build_gdbserver" = xyes; then
1453     AC_MSG_RESULT(yes)
1454     AC_CONFIG_SUBDIRS(gdbserver)
1455   else
1456     AC_MSG_RESULT(no)
1457   fi
1458 fi
1459
1460 # We build rdi-share on ARM-based targets, as instructed by configure.tgt.
1461 if test "x$build_rdi_share" = xyes; then
1462    AC_CONFIG_SUBDIRS(rdi-share)
1463 fi
1464
1465 # We configure the nlm subdirectory on netware targets, as instructed
1466 # by configure.tgt.
1467 if test "x$build_nlm" = xyes; then
1468    AC_CONFIG_SUBDIRS(nlm)
1469 fi
1470
1471 # If hostfile (XM_FILE) and/or targetfile (DEPRECATED_TM_FILE) and/or
1472 # nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
1473 # to an empty version.
1474
1475 files=
1476 links=
1477
1478 rm -f xm.h
1479 xm_h=""
1480 if test "${hostfile}" != ""; then
1481     xm_h=xm.h
1482     case "${hostfile}" in
1483       xm-*.h ) GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" ;;
1484       * ) GDB_XM_FILE="${hostfile}"
1485     esac
1486     files="${files} ${GDB_XM_FILE}"
1487     links="${links} xm.h"
1488     AC_DEFINE_UNQUOTED(GDB_XM_FILE, "${GDB_XM_FILE}")
1489 fi
1490 AC_SUBST(xm_h)
1491
1492 rm -f tm.h
1493 tm_h=""
1494 if test "${targetfile}" != ""; then
1495     tm_h=tm.h
1496     case "${targetfile}" in
1497       tm-*.h ) GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" ;;
1498       * ) GDB_TM_FILE="${targetfile}"
1499     esac
1500     files="${files} ${GDB_TM_FILE}"
1501     links="${links} tm.h"
1502     AC_DEFINE_UNQUOTED(GDB_TM_FILE, "${GDB_TM_FILE}")
1503 fi
1504 AC_SUBST(tm_h)
1505
1506 rm -f nm.h
1507 nm_h=""
1508 if test "${nativefile}" != ""; then
1509     nm_h=nm.h
1510     case "${nativefile}" in
1511       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
1512       * ) GDB_NM_FILE="${nativefile}"
1513     esac
1514     files="${files} ${GDB_NM_FILE}"
1515     links="${links} nm.h"
1516     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}")
1517 fi
1518 AC_SUBST(nm_h)
1519
1520 AC_LINK_FILES($files, $links)
1521
1522 dnl Check for exe extension set on certain hosts (e.g. Win32)
1523 AC_EXEEXT
1524
1525 dnl  Detect the character set used by this host.
1526
1527 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1528 dnl  superset of ASCII containing the characters needed for French,
1529 dnl  German, Spanish, Italian, and possibly others), but if were
1530 dnl  *were* to support any host character sets other than ISO-8859-1,
1531 dnl  here's where we'd detect it.
1532 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1533           [Define to be a string naming the default host character set.])
1534
1535 AM_ICONV
1536
1537 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1538 [
1539 dnl Autoconf doesn't provide a mechanism for modifying definitions
1540 dnl provided by makefile fragments.
1541 dnl
1542
1543 changequote(,)dnl
1544 sed -e '/^DEPRECATED_TM_FILE[   ]*=/s,^DEPRECATED_TM_FILE[      ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1545 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1546 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1547 mv -f Makefile.tmp Makefile
1548 changequote([,])dnl
1549
1550
1551 case x$CONFIG_HEADERS in
1552 xconfig.h:config.in)
1553 echo > stamp-h ;;
1554 esac
1555 ],
1556 [
1557 gdb_host_cpu=$gdb_host_cpu
1558 gdb_target_cpu=$gdb_target_cpu
1559 nativefile=$nativefile
1560 ])
1561
1562 exit 0