gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2014 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22 AC_INIT(main.c)
  23 AC_CONFIG_HEADER(config.h:config.in)
  24 AM_MAINTAINER_MODE
  25
  26 # Set the 'development' global.
  27 . $srcdir/../bfd/development.sh
  28
  29 AC_PROG_CC
  30 AC_USE_SYSTEM_EXTENSIONS
  31 ACX_LARGEFILE
  32 AM_PROG_CC_STDC
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36 AC_CANONICAL_SYSTEM
  37 AC_ARG_PROGRAM
  38
  39 # Dependency checking.
  40 ZW_CREATE_DEPDIR
  41 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  42
  43 # Check for the 'make' the user wants to use.
  44 AC_CHECK_PROGS(MAKE, make)
  45 MAKE_IS_GNU=
  46 case "`$MAKE --version 2>&1 | sed 1q`" in
  47   *GNU*)
  48     MAKE_IS_GNU=yes
  49     ;;
  50 esac
  51 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  52 AC_PROG_MAKE_SET
  53
  54 gnulib_extra_configure_args=
  55 # If large-file support is disabled, make sure gnulib does the same.
  56 if test "$enable_largefile" = no; then
  57 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  58 fi
  59
  60 # Configure gnulib.  We need to build gnulib under some other
  61 # directory not "gnulib", to avoid the problem of both GDB and
  62 # GDBserver wanting to build it in the same directory, when building
  63 # in the source dir.
  64 ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"],
  65                   ["$gnulib_extra_configure_args"])
  66
  67 dnl List of object files and targets accumulated by configure.
  68
  69 CONFIG_OBS=
  70 CONFIG_DEPS=
  71 CONFIG_SRCS=
  72 ENABLE_CFLAGS=
  73
  74 CONFIG_ALL=
  75 CONFIG_CLEAN=
  76 CONFIG_INSTALL=
  77 CONFIG_UNINSTALL=
  78
  79 dnl Set up for gettext.
  80 ZW_GNU_GETTEXT_SISTER_DIR
  81
  82 localedir='${datadir}/locale'
  83 AC_SUBST(localedir)
  84
  85 if test x"$USE_NLS" = xyes; then
  86    CONFIG_ALL="$CONFIG_ALL all-po"
  87    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  88    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  89    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  90 fi
  91
  92 GNULIB=build-gnulib/import
  93
  94 # For Makefile dependencies.
  95 GNULIB_STDINT_H=
  96 if test x"$STDINT_H" != x; then
  97   GNULIB_STDINT_H=$GNULIB/$STDINT_H
  98 fi
  99 AC_SUBST(GNULIB_STDINT_H)
 100
 101 PACKAGE=gdb
 102 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
 103 AC_SUBST(PACKAGE)
 104
 105 # We never need to detect it in this sub-configure.
 106 # But preserve it for config.status --recheck.
 107 AC_ARG_VAR(MAKEINFO,
 108   [Parent configure detects if it is of sufficient version.])
 109 AC_ARG_VAR(MAKEINFOFLAGS,
 110   [Parameters for MAKEINFO.])
 111
 112 MAKEINFO_EXTRA_FLAGS=""
 113 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
 114   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
 115   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
 116     gdb_cv_have_makeinfo_click=yes
 117   else
 118     gdb_cv_have_makeinfo_click=no
 119   fi])
 120 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 121   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 122 fi
 123 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 124
 125 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 126     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 127     [${libdir}/debug])
 128
 129 # We can't pass paths as command line arguments.
 130 # Mingw32 tries to be clever and will convert the paths for us.
 131 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 132 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 133 # This breaks GDB's relocatable path conversions since paths passed in
 134 # config.h would not get so translated, the path prefixes no longer match.
 135 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 136
 137 # GDB's datadir relocation
 138
 139 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 140     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 141     [${datadir}/gdb])
 142
 143 AC_ARG_WITH(relocated-sources,
 144 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 145 [reloc_srcdir="${withval}"
 146  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 147               [Relocated directory for source files. ])
 148 ])
 149
 150 AC_MSG_CHECKING([for default auto-load directory])
 151 AC_ARG_WITH(auto-load-dir,
 152 AS_HELP_STRING([--with-auto-load-dir=PATH],
 153   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 154   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 155 escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 156 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 157               [Directories from which to load auto-loaded scripts.])
 158 AC_MSG_RESULT([$with_auto_load_dir])
 159
 160 AC_MSG_CHECKING([for default auto-load safe-path])
 161 AC_ARG_WITH(auto-load-safe-path,
 162 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 163   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 164 AS_HELP_STRING([--without-auto-load-safe-path],
 165                [do not restrict auto-loaded files locations]),
 166     [if test "$with_auto_load_safe_path" = "no"; then
 167      with_auto_load_safe_path="/"
 168      fi],
 169 [with_auto_load_safe_path="$with_auto_load_dir"])
 170 escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'`
 171 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 172               [Directories safe to hold auto-loaded files.])
 173 AC_MSG_RESULT([$with_auto_load_safe_path])
 174
 175 AC_CONFIG_SUBDIRS(testsuite)
 176
 177 # Check whether to support alternative target configurations
 178 AC_ARG_ENABLE(targets,
 179 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 180 [case "${enableval}" in
 181   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 182             ;;
 183   no)       enable_targets= ;;
 184   *)        enable_targets=$enableval ;;
 185 esac])
 186
 187 # Check whether to enable 64-bit support on 32-bit hosts
 188 AC_ARG_ENABLE(64-bit-bfd,
 189 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 190 [case "${enableval}" in
 191   yes)  want64=true  ;;
 192   no)   want64=false ;;
 193   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 194 esac],[want64=false])dnl
 195
 196 # Provide defaults for some variables set by the per-host and per-target
 197 # configuration.
 198 gdb_host_obs=posix-hdep.o
 199
 200 if test "${target}" = "${host}"; then
 201   gdb_native=yes
 202 else
 203   gdb_native=no
 204 fi
 205
 206 . $srcdir/configure.host
 207
 208 # Accumulate some settings from configure.tgt over all enabled targets
 209
 210 TARGET_OBS=
 211 all_targets=
 212 HAVE_NATIVE_GCORE_TARGET=
 213
 214 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 215 do
 216   if test "$targ_alias" = "all"; then
 217     all_targets=true
 218   else
 219     # Canonicalize the secondary target names.
 220     result=`$ac_config_sub $targ_alias 2>/dev/null`
 221     if test -n "$result"; then
 222         targ=$result
 223     else
 224         targ=$targ_alias
 225     fi
 226
 227     . ${srcdir}/configure.tgt
 228
 229     AS_IF([test -z "${gdb_target_obs}"],
 230       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 231
 232     # Target-specific object files
 233     for i in ${gdb_target_obs}; do
 234         case " $TARGET_OBS " in
 235         *" ${i} "*) ;;
 236         *)
 237           TARGET_OBS="$TARGET_OBS ${i}"
 238           ;;
 239         esac
 240     done
 241
 242     # Check whether this target needs 64-bit CORE_ADDR
 243     if test x${want64} = xfalse; then
 244       . ${srcdir}/../bfd/config.bfd
 245     fi
 246
 247     # Check whether this target is native and supports gcore.
 248     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 249        && $gdb_have_gcore; then
 250       HAVE_NATIVE_GCORE_TARGET=1
 251     fi
 252   fi
 253 done
 254
 255 if test x${all_targets} = xtrue; then
 256
 257   # We want all 64-bit targets if we either:
 258   #  - run on a 64-bit host  or
 259   #  - already require 64-bit support for some other target  or
 260   #  - the --enable-64-bit-bfd option was supplied
 261   # Otherwise we only support all 32-bit targets.
 262   #
 263   # NOTE: This test must be in sync with the corresponding
 264   #       tests in BFD!
 265
 266   if test x${want64} = xfalse; then
 267     AC_CHECK_SIZEOF(long)
 268     if test "x${ac_cv_sizeof_long}" = "x8"; then
 269       want64=true
 270     fi
 271   fi
 272   if test x${want64} = xtrue; then
 273     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 274   else
 275     TARGET_OBS='$(ALL_TARGET_OBS)'
 276   fi
 277 fi
 278
 279 AC_SUBST(TARGET_OBS)
 280 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 281
 282 # For other settings, only the main target counts.
 283 gdb_sim=
 284 gdb_osabi=
 285 build_gdbserver=
 286 targ=$target; . ${srcdir}/configure.tgt
 287
 288 # Fetch the default architecture and default target vector from BFD.
 289 targ=$target; . $srcdir/../bfd/config.bfd
 290
 291 # We only want the first architecture, so strip off the others if
 292 # there is more than one.
 293 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 294
 295 if test "x$targ_archs" != x; then
 296   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 297     [Define to BFD's default architecture. ])
 298 fi
 299 if test "x$targ_defvec" != x; then
 300   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 301     [Define to BFD's default target vector. ])
 302 fi
 303
 304 # The CLI cannot be disabled yet, but may be in the future.
 305
 306 # Enable CLI.
 307 AC_ARG_ENABLE(gdbcli,
 308 AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]),
 309   [case $enableval in
 310     yes)
 311       ;;
 312     no)
 313       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 314     *)
 315       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 316   esac],
 317   [enable_gdbcli=yes])
 318 if test x"$enable_gdbcli" = xyes; then
 319   if test -d $srcdir/cli; then
 320     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 321     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 322     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 323     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 324   fi
 325 fi
 326
 327 # Enable MI.
 328 AC_ARG_ENABLE(gdbmi,
 329 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 330   [case $enableval in
 331     yes | no)
 332       ;;
 333     *)
 334       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 335   esac],
 336   [enable_gdbmi=yes])
 337 if test x"$enable_gdbmi" = xyes; then
 338   if test -d $srcdir/mi; then
 339     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 340     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 341     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 342     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 343   fi
 344 fi
 345
 346 # Enable TUI.
 347 AC_ARG_ENABLE(tui,
 348 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 349   [case $enableval in
 350     yes | no | auto)
 351       ;;
 352     *)
 353       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 354   esac],enable_tui=auto)
 355
 356 # Enable gdbtk.
 357 AC_ARG_ENABLE(gdbtk,
 358 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 359   [case $enableval in
 360     yes | no)
 361       ;;
 362     *)
 363       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 364   esac],
 365   [if test -d $srcdir/gdbtk; then
 366     enable_gdbtk=yes
 367   else
 368     enable_gdbtk=no
 369   fi])
 370 # We unconditionally disable gdbtk tests on selected platforms.
 371 case $host_os in
 372   go32* | windows*)
 373     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 374     enable_gdbtk=no ;;
 375 esac
 376
 377 # Libunwind support for ia64.
 378
 379 AC_ARG_WITH(libunwind-ia64,
 380 AS_HELP_STRING([--with-libunwind-ia64],
 381                [use libunwind frame unwinding for ia64 targets]),,
 382             [with_libunwind_ia64=auto])
 383
 384 # Backward compatibility option.
 385 if test "${with_libunwind+set}" = set; then
 386   if test x"$with_libunwind_ia64" != xauto; then
 387     AC_MSG_ERROR(
 388       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 389   fi
 390   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 391   with_libunwind_ia64="$with_libunwind"
 392 fi
 393
 394 case "$with_libunwind_ia64" in
 395   yes | no)
 396     ;;
 397   auto)
 398     AC_CHECK_HEADERS(libunwind-ia64.h)
 399     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 400     ;;
 401   *)
 402     AC_MSG_ERROR(
 403       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 404     ;;
 405 esac
 406
 407 if test x"$with_libunwind_ia64" = xyes; then
 408   AC_CHECK_HEADERS(libunwind-ia64.h)
 409   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 410     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 411   fi
 412   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 413   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 414   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 415 fi
 416
 417 opt_curses=no
 418 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 419
 420 prefer_curses=no
 421 if test "$opt_curses" = "yes"; then
 422   prefer_curses=yes
 423 fi
 424
 425 # Profiling support.
 426 AC_ARG_ENABLE(profiling,
 427 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 428   [case $enableval in
 429     yes | no)
 430       ;;
 431     *)
 432       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 433   esac],
 434  [enable_profiling=no])
 435
 436 AC_CHECK_FUNCS(monstartup _mcleanup)
 437 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 438 [AC_TRY_LINK(
 439 [#include <stdlib.h>
 440 extern char _etext;
 441 ],
 442 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 443 if test $ac_cv_var__etext = yes; then
 444   AC_DEFINE(HAVE__ETEXT, 1,
 445             [Define to 1 if your system has the _etext variable. ])
 446 fi
 447 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 448 [AC_TRY_LINK(
 449 [#include <stdlib.h>
 450 extern char etext;
 451 ],
 452 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 453 if test $ac_cv_var_etext = yes; then
 454   AC_DEFINE(HAVE_ETEXT, 1,
 455             [Define to 1 if your system has the etext variable. ])
 456 fi
 457 if test "$enable_profiling" = yes ; then
 458   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 459     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 460   fi
 461   PROFILE_CFLAGS=-pg
 462   OLD_CFLAGS="$CFLAGS"
 463   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 464
 465   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 466     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 467      ac_cv_cc_supports_pg=no)])
 468
 469   if test $ac_cv_cc_supports_pg = no; then
 470     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 471   fi
 472
 473   CFLAGS="$OLD_CFLAGS"
 474 fi
 475
 476 ACX_PKGVERSION([GDB])
 477 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 478 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 479 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 480
 481 # --------------------- #
 482 # Checks for programs.  #
 483 # --------------------- #
 484
 485 AC_PROG_AWK
 486 AC_PROG_INSTALL
 487 AC_PROG_LN_S
 488 AC_PROG_RANLIB
 489 AC_PROG_YACC
 490
 491 AC_CHECK_TOOL(AR, ar)
 492 AC_CHECK_TOOL(DLLTOOL, dlltool)
 493 AC_CHECK_TOOL(WINDRES, windres)
 494
 495 case $host_os in
 496   gnu*)
 497     # Needed for GNU Hurd hosts.
 498     AC_CHECK_TOOL(MIG, mig)
 499     if test x"$MIG" = x; then
 500       AC_MSG_ERROR([MIG not found but required for $host hosts])
 501     fi
 502     ;;
 503 esac
 504
 505 # ---------------------- #
 506 # Checks for libraries.  #
 507 # ---------------------- #
 508
 509 # We might need to link with -lm; most simulators need it.
 510 AC_CHECK_LIB(m, main)
 511
 512 # We need to link with -lw to get `wctype' on Solaris before Solaris
 513 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 514 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 515 # is known to have this problem).  Therefore we avoid libw if we can.
 516 AC_CHECK_FUNC(wctype, [],
 517   [AC_CHECK_LIB(w, wctype)])
 518
 519 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 520 AC_SEARCH_LIBS(gethostbyname, nsl)
 521
 522 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 523 AC_SEARCH_LIBS(socketpair, socket)
 524
 525 # Link in zlib if we can.  This allows us to read compressed debug sections.
 526 AM_ZLIB
 527
 528 # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c).
 529 AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl])
 530
 531 AM_ICONV
 532
 533 # GDB may fork/exec the iconv program to get the list of supported character
 534 # sets.  Allow the user to specify where to find it.
 535 # There are several factors affecting the choice of option name:
 536 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 537 #   the build-time location of libiconv files.
 538 # - The program we need to find is iconv, which comes with glibc.  The user
 539 #   doesn't necessarily have libiconv installed.  Therefore naming this
 540 #   --with-libiconv-foo feels wrong.
 541 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 542 #   defined to work on directories not files (though it really doesn't know
 543 #   the difference).
 544 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 545 #   with --with-libiconv-prefix.
 546 # Putting these together is why the option name is --with-iconv-bin.
 547
 548 AC_ARG_WITH(iconv-bin,
 549 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 550 [iconv_bin="${withval}"
 551  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 552                     [Path of directory of iconv program.])
 553  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 554 ])
 555
 556 # For the TUI, we need enhanced curses functionality.
 557 if test x"$enable_tui" != xno; then
 558   prefer_curses=yes
 559 fi
 560
 561 curses_found=no
 562 if test x"$prefer_curses" = xyes; then
 563   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 564   # curses library because the latter might not provide all the
 565   # functionality we need.  However, this leads to problems on systems
 566   # where the linker searches /usr/local/lib, but the compiler doesn't
 567   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 568   # default installation of ncurses on alpha*-dec-osf* will lead to such
 569   # a situation.
 570   AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses])
 571
 572   if test "$ac_cv_search_waddstr" != no; then
 573     curses_found=yes
 574   fi
 575 fi
 576
 577 # Check whether we should enable the TUI, but only do so if we really
 578 # can.
 579 if test x"$enable_tui" != xno; then
 580   if test -d $srcdir/tui; then
 581     if test "$curses_found" != no; then
 582       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 583       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 584       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 585       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 586     else
 587       if test x"$enable_tui" = xyes; then
 588         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 589       else
 590         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 591       fi
 592     fi
 593   fi
 594 fi
 595
 596 # Since GDB uses Readline, we need termcap functionality.  In many
 597 # cases this will be provided by the curses library, but some systems
 598 # have a seperate termcap library, or no curses library at all.
 599
 600 case $host_os in
 601   cygwin*)
 602     if test -d $srcdir/libtermcap; then
 603       LIBS="../libtermcap/libtermcap.a $LIBS"
 604       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 605     fi ;;
 606   go32* | *djgpp*)
 607     ac_cv_search_tgetent="none required"
 608     ;;
 609   *mingw32*)
 610     ac_cv_search_tgetent="none required"
 611     CONFIG_OBS="$CONFIG_OBS windows-termcap.o"
 612     ;;
 613 esac
 614
 615 # These are the libraries checked by Readline.
 616 AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses])
 617
 618 if test "$ac_cv_search_tgetent" = no; then
 619   AC_MSG_ERROR([no termcap library found])
 620 fi
 621
 622 AC_ARG_WITH([system-readline],
 623   [AS_HELP_STRING([--with-system-readline],
 624                   [use installed readline library])])
 625
 626 if test "$with_system_readline" = yes; then
 627   READLINE=-lreadline
 628   READLINE_DEPS=
 629   READLINE_CFLAGS=
 630   READLINE_TEXI_INCFLAG=
 631 else
 632   READLINE='$(READLINE_DIR)/libreadline.a'
 633   READLINE_DEPS='$(READLINE)'
 634   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 635   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 636 fi
 637 AC_SUBST(READLINE)
 638 AC_SUBST(READLINE_DEPS)
 639 AC_SUBST(READLINE_CFLAGS)
 640 AC_SUBST(READLINE_TEXI_INCFLAG)
 641
 642 # Generate jit-reader.h
 643
 644 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 645 TARGET_PTR=
 646
 647 AC_CHECK_SIZEOF(unsigned long long)
 648 AC_CHECK_SIZEOF(unsigned long)
 649 AC_CHECK_SIZEOF(unsigned __int128)
 650
 651 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 652   TARGET_PTR="unsigned long"
 653 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 654   TARGET_PTR="unsigned long long"
 655 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 656   TARGET_PTR="unsigned __int128"
 657 else
 658   TARGET_PTR="unsigned long"
 659 fi
 660
 661 AC_SUBST(TARGET_PTR)
 662 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 663
 664 AC_SEARCH_LIBS(dlopen, dl)
 665
 666 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 667                 [directory to load the JIT readers from],
 668                 [${libdir}/gdb])
 669
 670 AC_ARG_WITH(expat,
 671   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 672   [], [with_expat=auto])
 673 AC_MSG_CHECKING([whether to use expat])
 674 AC_MSG_RESULT([$with_expat])
 675
 676 if test "${with_expat}" = no; then
 677   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 678   HAVE_LIBEXPAT=no
 679 else
 680   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 681                         [XML_Parser p = XML_ParserCreate (0);])
 682   if test "$HAVE_LIBEXPAT" != yes; then
 683     if test "$with_expat" = yes; then
 684       AC_MSG_ERROR([expat is missing or unusable])
 685     else
 686       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 687     fi
 688   else
 689     save_LIBS=$LIBS
 690     LIBS="$LIBS $LIBEXPAT"
 691     AC_CHECK_FUNCS(XML_StopParser)
 692     LIBS=$save_LIBS
 693   fi
 694 fi
 695
 696 # --------------------- #
 697 # Check for libpython.  #
 698 # --------------------- #
 699
 700 dnl Utility to simplify finding libpython.
 701 dnl $1 = pythonX.Y
 702 dnl $2 = the shell variable to assign the result to
 703 dnl      If libpython is found we store $version here.
 704 dnl $3 = additional flags to add to CPPFLAGS
 705 dnl $4 = additional flags to add to LIBS
 706
 707 AC_DEFUN([AC_TRY_LIBPYTHON],
 708 [
 709   version=$1
 710   define([have_libpython_var],$2)
 711   new_CPPFLAGS=$3
 712   new_LIBS=$4
 713   AC_MSG_CHECKING([for ${version}])
 714   save_CPPFLAGS=$CPPFLAGS
 715   save_LIBS=$LIBS
 716   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 717   LIBS="$LIBS $new_LIBS"
 718   found_usable_python=no
 719   AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]],
 720                                  [[Py_Initialize ();]]),
 721                  [have_libpython_var=${version}
 722                   found_usable_python=yes
 723                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 724                   PYTHON_LIBS=$new_LIBS])
 725   CPPFLAGS=$save_CPPFLAGS
 726   LIBS=$save_LIBS
 727   AC_MSG_RESULT([${found_usable_python}])
 728 ])
 729
 730 dnl There are several different values for --with-python:
 731 dnl
 732 dnl no -   Don't include python support.
 733 dnl yes -  Include python support, error if it's missing.
 734 dnl        If we find python in $PATH, use it to fetch configure options,
 735 dnl        otherwise assume the compiler can find it with no help from us.
 736 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 737 dnl auto - Same as "yes", but if python is missing from the system,
 738 dnl        fall back to "no".
 739 dnl /path/to/python/exec-prefix -
 740 dnl        Use the python located in this directory.
 741 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 742 dnl        the compilation parameters.  Otherwise use
 743 dnl        -I/path/to/python/exec-prefix/include,
 744 dnl        -L/path/to/python/exec-prefix/lib.
 745 dnl        Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn.
 746 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 747 dnl        but is deprecated.
 748 dnl /path/to/python/executable -
 749 dnl        Run python-config.py with this version of python to fetch the
 750 dnl        compilation parameters.
 751 dnl        NOTE: This needn't be the real python executable.
 752 dnl        In a cross-compilation scenario (build != host), this could be
 753 dnl        a shell script that provides what python-config.py provides for
 754 dnl        --ldflags, --includes, --exec-prefix.
 755 dnl python-executable -
 756 dnl        Find python-executable in $PATH, and then handle the same as
 757 dnl        /path/to/python/executable.
 758 dnl
 759 dnl If a python program is specified, it is used to run python-config.py and
 760 dnl is passed --ldflags, --includes, --exec-prefix.
 761
 762 AC_ARG_WITH(python,
 763   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 764   [], [with_python=auto])
 765 AC_MSG_CHECKING([whether to use python])
 766 AC_MSG_RESULT([$with_python])
 767
 768 if test "${with_python}" = no; then
 769   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 770   have_libpython=no
 771 else
 772   case "${with_python}" in
 773   [[\\/]]* | ?:[[\\/]]*)
 774     if test -d ${with_python}; then
 775       # Assume the python binary is ${with_python}/bin/python.
 776       python_prog="${with_python}/bin/python"
 777       python_prefix=
 778       # If python does not exit ${with_python}/bin, then try in
 779       # ${with_python}.  On Windows/MinGW, this is where the Python
 780       # executable is.
 781       if test ! -x "${python_prog}"; then
 782         python_prog="${with_python}/python"
 783         python_prefix=
 784       fi
 785       if test ! -x "${python_prog}"; then
 786         # Fall back to gdb 7.0/7.1 behaviour.
 787         python_prog=missing
 788         python_prefix=${with_python}
 789       fi
 790     elif test -x "${with_python}"; then
 791       # While we can't run python compiled for $host (unless host == build),
 792       # the user could write a script that provides the needed information,
 793       # so we support that.
 794       python_prog=${with_python}
 795       python_prefix=
 796     else
 797       AC_ERROR(invalid value for --with-python)
 798     fi
 799     ;;
 800   */*)
 801     # Disallow --with-python=foo/bar.
 802     AC_ERROR(invalid value for --with-python)
 803     ;;
 804   *)
 805     # The user has either specified auto, yes, or the name of the python
 806     # program assumed to be in $PATH.
 807     python_prefix=
 808     case "${with_python}" in
 809     yes | auto)
 810       if test ${build} = ${host}; then
 811         AC_PATH_PROG(python_prog_path, python, missing)
 812         if test "${python_prog_path}" = missing; then
 813           python_prog=missing
 814         else
 815           python_prog=${python_prog_path}
 816         fi
 817       else
 818         # Not much we can do except assume the cross-compiler will find the
 819         # right files.
 820         python_prog=missing
 821       fi
 822       ;;
 823     *)
 824       # While we can't run python compiled for $host (unless host == build),
 825       # the user could write a script that provides the needed information,
 826       # so we support that.
 827       python_prog="${with_python}"
 828       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 829       if test "${python_prog_path}" = missing; then
 830         AC_ERROR(unable to find python program ${python_prog})
 831       fi
 832       ;;
 833     esac
 834   esac
 835
 836   if test "${python_prog}" != missing; then
 837     # We have a python program to use, but it may be too old.
 838     # Don't flag an error for --with-python=auto (the default).
 839     have_python_config=yes
 840     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 841     if test $? != 0; then
 842       have_python_config=failed
 843       if test "${with_python}" != auto; then
 844         AC_ERROR(failure running python-config --includes)
 845       fi
 846     fi
 847     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 848     if test $? != 0; then
 849       have_python_config=failed
 850       if test "${with_python}" != auto; then
 851         AC_ERROR(failure running python-config --ldflags)
 852       fi
 853     fi
 854     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 855     if test $? != 0; then
 856       have_python_config=failed
 857       if test "${with_python}" != auto; then
 858         AC_ERROR(failure running python-config --exec-prefix)
 859       fi
 860     fi
 861   else
 862     # We do not have a python executable we can use to determine where
 863     # to find the Python headers and libs.  We cannot guess the include
 864     # path from the python_prefix either, because that include path
 865     # depends on the Python version.  So, there is nothing much we can
 866     # do except assume that the compiler will be able to find those files.
 867     python_includes=
 868     python_libs=
 869     have_python_config=no
 870   fi
 871
 872   # If we have python-config, only try the configuration it provides.
 873   # Otherwise fallback on the old way of trying different versions of
 874   # python in turn.
 875
 876   have_libpython=no
 877   if test "${have_python_config}" = yes; then
 878     # Determine the Python version by extracting "-lpython<version>"
 879     # part of the python_libs. <version> is usually X.Y with X and Y
 880     # being decimal numbers, but can also be XY (seen on Windows).
 881     #
 882     # The extraction is performed using sed with a regular expression.
 883     # Initially, the regexp used was using the '?' quantifier to make
 884     # the dot in the version number optional.  Unfortunately, this
 885     # does not work with non-GNU versions of sed because, because of
 886     # what looks like a limitation (the '?' quantifier does not work
 887     # with back-references).  We work around this limitation by using
 888     # the '*' quantifier instead.  It means that, in theory, we might
 889     # match unexpected version strings such as "-lpython2..7", but
 890     # this seems unlikely in practice.  And even if that happens,
 891     # an error will be triggered later on, when checking that version
 892     # number.
 893     python_version=`echo " ${python_libs} " \
 894                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 895     case "${python_version}" in
 896     python*)
 897       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 898                        ${python_includes}, ${python_libs})
 899       ;;
 900     *)
 901       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 902       ;;
 903     esac
 904   elif test "${have_python_config}" != failed; then
 905     if test "${have_libpython}" = no; then
 906       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 907                        ${python_includes}, "${python_libs} -lpython2.7")
 908     fi
 909     if test "${have_libpython}" = no; then
 910       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 911                        ${python_includes}, "${python_libs} -lpython2.6")
 912     fi
 913     if test ${have_libpython} = no; then
 914       AC_TRY_LIBPYTHON(python2.5, have_libpython,
 915                        ${python_includes}, "${python_libs} -lpython2.5")
 916     fi
 917     if test ${have_libpython} = no; then
 918       AC_TRY_LIBPYTHON(python2.4, have_libpython,
 919                        ${python_includes}, "${python_libs} -lpython2.4")
 920     fi
 921   fi
 922   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 923     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 924   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 925     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 926   elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then
 927     AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.])
 928   elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then
 929     AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.])
 930   fi
 931
 932   if test "${have_libpython}" = no; then
 933     case "${with_python}" in
 934     yes)
 935       AC_MSG_ERROR([python is missing or unusable])
 936       ;;
 937     auto)
 938       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 939       ;;
 940     *)
 941       AC_MSG_ERROR([no usable python found at ${with_python}])
 942       ;;
 943     esac
 944   else
 945     if test -n "${python_prefix}"; then
 946       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 947                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 948       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 949     fi
 950   fi
 951 fi
 952
 953 if test "${have_libpython}" != no; then
 954   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 955   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 956   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 957   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 958   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 959   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 960
 961   # Flags needed to compile Python code (taken from python-config --cflags).
 962   # We cannot call python-config directly because it will output whatever was
 963   # used when compiling the Python interpreter itself, including flags which
 964   # would make the python-related objects be compiled differently from the
 965   # rest of GDB (e.g., -O2 and -fPIC).
 966   if test "${GCC}" = yes; then
 967     tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv"
 968   fi
 969
 970   if test "x${tentative_python_cflags}" != x; then
 971     AC_MSG_CHECKING(compiler flags for python code)
 972     for flag in ${tentative_python_cflags}; do
 973       # Check that the compiler accepts it
 974       saved_CFLAGS="$CFLAGS"
 975       CFLAGS="$CFLAGS $flag"
 976       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 977       CFLAGS="$saved_CFLAGS"
 978     done
 979     AC_MSG_RESULT(${PYTHON_CFLAGS})
 980   fi
 981
 982   # On x64 Windows, Python's include headers, and pyconfig.h in
 983   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 984   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 985   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 986   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 987   # The issue was reported to the Python community, but still isn't
 988   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 989
 990   case "$gdb_host" in
 991     mingw64)
 992            if test "${GCC}" = yes; then
 993              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 994            fi
 995            ;;
 996   esac
 997
 998   # Note that "python -m threading" cannot be used to check for
 999   # threading support due to a bug in Python 2.7.3
1000   # (http://bugs.python.org/issue15567).
1001   AC_MSG_CHECKING(whether python supports threads)
1002   saved_CPPFLAGS="${CPPFLAGS}"
1003   CPPFLAGS="${PYTHON_CPPFLAGS}"
1004   # Note that the test is reversed so that python_has_threads=yes on
1005   # unexpected failures.
1006   AC_PREPROC_IFELSE(AC_LANG_SOURCE([[
1007 #include <Python.h>
1008 #ifdef WITH_THREAD
1009 # error
1010 #endif
1011   ]]), [python_has_threads=no], [python_has_threads=yes])
1012   AC_MSG_RESULT(${python_has_threads})
1013   CPPFLAGS="${saved_CPPFLAGS}"
1014 else
1015   # Even if Python support is not compiled in, we need to have this file
1016   # included so that the "python" command, et.al., still exists.
1017   CONFIG_OBS="$CONFIG_OBS python.o"
1018   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1019 fi
1020 AC_SUBST(PYTHON_CFLAGS)
1021 AC_SUBST(PYTHON_CPPFLAGS)
1022 AC_SUBST(PYTHON_LIBS)
1023 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1024
1025 # -------------------- #
1026 # Check for libguile.  #
1027 # -------------------- #
1028
1029 dnl Utility to simplify finding libguile.
1030 dnl $1 = pkg-config-program
1031 dnl $2 = space-separate list of guile versions to try
1032 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1033 dnl $4 = the shell variable to assign the result to
1034 dnl      If libguile is found we store "yes" here.
1035
1036 AC_DEFUN([AC_TRY_LIBGUILE],
1037 [
1038   pkg_config=$1
1039   guile_version_list=$2
1040   flag_errors=$3
1041   define([have_libguile_var],$4)
1042   found_usable_guile=checking
1043   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1044   for guile_version in ${guile_version_list}; do
1045     ${pkg_config} --exists ${guile_version} 2>/dev/null
1046     if test $? != 0; then
1047       continue
1048     fi
1049     dnl pkg-config says the package exists, so if we get an error now,
1050     dnl that's bad.
1051     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1052     if test $? != 0; then
1053       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1054     fi
1055     new_LIBS=`${pkg_config} --libs ${guile_version}`
1056     if test $? != 0; then
1057       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1058     fi
1059     dnl If we get this far, great.
1060     found_usable_guile=${guile_version}
1061     break
1062   done
1063   if test "${found_usable_guile}" = "checking"; then
1064     if test "${flag_errors}" = "yes"; then
1065       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1066     else
1067       found_usable_guile=no
1068     fi
1069   fi
1070   dnl One final sanity check.
1071   dnl The user could have said --with-guile=python-2.7.
1072   if test "${found_usable_guile}" != no; then
1073     save_CPPFLAGS=$CPPFLAGS
1074     save_LIBS=$LIBS
1075     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1076     LIBS="$LIBS $new_LIBS"
1077     AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "libguile.h"]],
1078                                    [[scm_init_guile ();]]),
1079                    [have_libguile_var=yes
1080                     GUILE_CPPFLAGS=$new_CPPFLAGS
1081                     GUILE_LIBS=$new_LIBS],
1082                    [found_usable_guile=no])
1083     CPPFLAGS=$save_CPPFLAGS
1084     LIBS=$save_LIBS
1085     if test "${found_usable_guile}" = no; then
1086       if test "${flag_errors}" = yes; then
1087         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1088       fi
1089     fi
1090   fi
1091   AC_MSG_RESULT([${found_usable_guile}])
1092 ])
1093
1094 dnl There are several different values for --with-guile:
1095 dnl
1096 dnl no -   Don't include guile support.
1097 dnl yes -  Include guile support, error if it's missing.
1098 dnl        The pkg-config program must be in $PATH.
1099 dnl auto - Same as "yes", but if guile is missing from the system,
1100 dnl        fall back to "no".
1101 dnl guile-version [guile-version-choice-2 ...] -
1102 dnl        A space-separated list of guile package versions to try.
1103 dnl        These are passed to pkg-config as-is.
1104 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1105 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1106 dnl /path/to/pkg-config -
1107 dnl        Use this pkg-config program.
1108 dnl        NOTE: This needn't be the "real" pkg-config program.
1109 dnl        It could be a shell script.  It is invoked as:
1110 dnl        pkg-config --exists $version
1111 dnl        pkg-config --cflags $version
1112 dnl        pkg-config --libs $version
1113 dnl        pkg-config --variable guild $version
1114 dnl        The script will be called with $version having each value in
1115 dnl        $try_guile_versions until --exists indicates success.
1116
1117 AC_ARG_WITH(guile,
1118   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1119   [], [with_guile=auto])
1120 AC_MSG_CHECKING([whether to use guile])
1121 AC_MSG_RESULT([$with_guile])
1122
1123 dnl We check guile with pkg-config.
1124 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1125
1126 try_guile_versions="guile-2.2 guile-2.0"
1127 have_libguile=no
1128 case "${with_guile}" in
1129 no)
1130   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1131   ;;
1132 auto)
1133   if test "${pkg_config_prog_path}" = "missing"; then
1134     AC_MSG_WARN([pkg-config not found, guile support disabled])
1135   else
1136     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1137   fi
1138   ;;
1139 yes)
1140   if test "${pkg_config_prog_path}" = "missing"; then
1141     AC_MSG_ERROR([pkg-config not found])
1142   fi
1143   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1144   ;;
1145 [[\\/]]* | ?:[[\\/]]*)
1146   if test -x "${with_guile}"; then
1147     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1148   else
1149     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1150   fi
1151   ;;
1152 "" | */*)
1153   # Disallow --with=guile="" and --with-guile=foo/bar.
1154   AC_MSG_ERROR([invalid value for --with-guile])
1155   ;;
1156 *)
1157   # A space separate list of guile versions to try, in order.
1158   if test "${pkg_config_prog_path}" = "missing"; then
1159     AC_MSG_ERROR([pkg-config not found])
1160   fi
1161   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1162   ;;
1163 esac
1164
1165 if test "${have_libguile}" != no; then
1166   dnl Get the name of the 'guild' program.
1167   case "${with_guile}" in
1168   [[\\/]]* | ?:[[\\/]]*)
1169     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1170     ;;
1171   *)
1172     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1173     ;;
1174   esac
1175
1176   dnl Make sure guild can handle this host.
1177   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1178   dnl If not, disable guile support.
1179   if test "$ac_cv_guild_ok" = no; then
1180     have_libguile=no
1181     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1182   fi
1183 fi
1184
1185 if test "${have_libguile}" != no; then
1186   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1187   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1188   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1189   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1190   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1191   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1192
1193   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1194   save_LIBS="$LIBS"
1195   save_CPPFLAGS="$CPPFLAGS"
1196   LIBS="$GUILE_LIBS"
1197   CPPFLAGS="$GUILE_CPPFLAGS"
1198   AC_CHECK_FUNCS([scm_new_smob])
1199   LIBS="$save_LIBS"
1200   CPPFLAGS="$save_CPPFLAGS"
1201 else
1202   # Even if Guile support is not compiled in, we need to have these files
1203   # included.
1204   CONFIG_OBS="$CONFIG_OBS guile.o"
1205   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1206 fi
1207 AC_SUBST(GUILE_CPPFLAGS)
1208 AC_SUBST(GUILE_LIBS)
1209 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1210
1211 # --------------------- #
1212 # Check for libmcheck.  #
1213 # --------------------- #
1214
1215 # Enable -lmcheck by default (it provides cheap-enough memory mangling),
1216 # but turn it off if Python is enabled with threads, since -lmcheck is
1217 # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939),
1218 # and for releases.
1219 if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \
1220    && $development; then
1221   libmcheck_default=yes
1222 else
1223   libmcheck_default=no
1224 fi
1225 GDB_AC_LIBMCHECK(${libmcheck_default})
1226
1227 if test "$ENABLE_LIBMCHECK" = "yes" \
1228         -a "${have_libpython}" != "no" \
1229         -a "${python_has_threads}" = "yes" ; then
1230   AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python)
1231 fi
1232
1233 # ------------------------- #
1234 # Checks for header files.  #
1235 # ------------------------- #
1236
1237 AC_HEADER_STDC
1238 # elf_hp.h is for HP/UX 64-bit shared library support.
1239 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1240                   thread_db.h \
1241                   sys/fault.h \
1242                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1243                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1244                   sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \
1245                   termios.h termio.h \
1246                   sgtty.h elf_hp.h \
1247                   dlfcn.h])
1248 AC_CHECK_HEADERS(sys/proc.h, [], [],
1249 [#if HAVE_SYS_PARAM_H
1250 # include <sys/param.h>
1251 #endif
1252 ])
1253 AC_CHECK_HEADERS(sys/user.h, [], [],
1254 [#if HAVE_SYS_PARAM_H
1255 # include <sys/param.h>
1256 #endif
1257 ])
1258
1259 # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash
1260 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
1261 # think that we don't have <curses.h> if we're using GCC.
1262 case $host_os in
1263   solaris2.[[789]])
1264     if test "$GCC" = yes; then
1265       AC_DEFINE(_MSE_INT_H, 1,
1266         [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
1267    Solaris 2.[789] when using GCC. ])
1268     fi ;;
1269 esac
1270 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h)
1271 AC_CHECK_HEADERS(term.h, [], [],
1272 [#if HAVE_CURSES_H
1273 # include <curses.h>
1274 #endif
1275 ])
1276
1277 # ------------------------- #
1278 # Checks for declarations.  #
1279 # ------------------------- #
1280
1281 AC_CHECK_DECLS([free, malloc, realloc, snprintf])
1282 AM_LC_MESSAGES
1283
1284 # ----------------------- #
1285 # Checks for structures.  #
1286 # ----------------------- #
1287
1288 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1289
1290 # ------------------ #
1291 # Checks for types.  #
1292 # ------------------ #
1293
1294 AC_TYPE_SIGNAL
1295 AC_CHECK_TYPES(socklen_t, [], [],
1296 [#include <sys/types.h>
1297 #include <sys/socket.h>
1298 ])
1299
1300 # ------------------------------------- #
1301 # Checks for compiler characteristics.  #
1302 # ------------------------------------- #
1303
1304 AC_C_CONST
1305 AC_C_INLINE
1306 AC_C_BIGENDIAN
1307
1308 # ------------------------------ #
1309 # Checks for library functions.  #
1310 # ------------------------------ #
1311
1312 AC_FUNC_MMAP
1313 AC_FUNC_VFORK
1314 AC_CHECK_FUNCS([getrusage getuid getgid \
1315                 pipe poll pread pread64 pwrite resize_term \
1316                 sbrk setpgid setpgrp setsid \
1317                 sigaction sigprocmask sigsetmask socketpair \
1318                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1319                 setrlimit getrlimit posix_madvise waitpid \
1320                 ptrace64 sigaltstack mkdtemp])
1321 AM_LANGINFO_CODESET
1322 GDB_AC_COMMON
1323
1324 # Check the return and argument types of ptrace.  No canned test for
1325 # this, so roll our own.
1326 gdb_ptrace_headers='
1327 #include <sys/types.h>
1328 #if HAVE_SYS_PTRACE_H
1329 # include <sys/ptrace.h>
1330 #endif
1331 #if HAVE_UNISTD_H
1332 # include <unistd.h>
1333 #endif
1334 '
1335 # There is no point in checking if we don't have a prototype.
1336 AC_CHECK_DECLS(ptrace, [], [
1337   : ${gdb_cv_func_ptrace_ret='int'}
1338   : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1339 ], $gdb_ptrace_headers)
1340 # Check return type.  Varargs (used on GNU/Linux) conflict with the
1341 # empty argument list, so check for that explicitly.
1342 AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
1343   AC_TRY_COMPILE($gdb_ptrace_headers,
1344     [extern long ptrace (enum __ptrace_request, ...);],
1345     gdb_cv_func_ptrace_ret='long',
1346     AC_TRY_COMPILE($gdb_ptrace_headers,
1347       [extern int ptrace ();],
1348       gdb_cv_func_ptrace_ret='int',
1349       gdb_cv_func_ptrace_ret='long')))
1350 AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
1351   [Define as the return type of ptrace.])
1352 # Check argument types.
1353 AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
1354   AC_TRY_COMPILE($gdb_ptrace_headers,
1355     [extern long ptrace (enum __ptrace_request, ...);],
1356     [gdb_cv_func_ptrace_args='int,int,long,long'],[
1357 for gdb_arg1 in 'int' 'long'; do
1358  for gdb_arg2 in 'pid_t' 'int' 'long'; do
1359   for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
1360    for gdb_arg4 in 'int' 'long' 'void *'; do
1361      AC_TRY_COMPILE($gdb_ptrace_headers, [
1362 extern $gdb_cv_func_ptrace_ret
1363   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
1364 ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
1365     break 4;])
1366     for gdb_arg5 in 'int *' 'int' 'long'; do
1367      AC_TRY_COMPILE($gdb_ptrace_headers, [
1368 extern $gdb_cv_func_ptrace_ret
1369   ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
1370 ], [
1371 gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
1372     break 5;])
1373     done
1374    done
1375   done
1376  done
1377 done
1378 # Provide a safe default value.
1379 : ${gdb_cv_func_ptrace_args='int,int,long,long'}
1380 ])])
1381 ac_save_IFS=$IFS; IFS=','
1382 set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
1383 IFS=$ac_save_IFS
1384 shift
1385 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
1386   [Define to the type of arg 3 for ptrace.])
1387 AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
1388   [Define to the type of arg 4 for ptrace.])
1389 if test -n "$[5]"; then
1390   AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
1391     [Define to the type of arg 5 for ptrace.])
1392 fi
1393
1394 dnl AC_FUNC_SETPGRP does not work when cross compiling
1395 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1396 if test "$cross_compiling" = no; then
1397   AC_FUNC_SETPGRP
1398 else
1399   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1400     [AC_TRY_COMPILE([
1401 #include <unistd.h>
1402 ], [
1403   if (setpgrp(1,1) == -1)
1404     exit (0);
1405   else
1406     exit (1);
1407 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1408 if test $ac_cv_func_setpgrp_void = yes; then
1409   AC_DEFINE(SETPGRP_VOID, 1)
1410 fi
1411 fi
1412
1413 # Assume we'll default to using the included libiberty regex.
1414 gdb_use_included_regex=yes
1415
1416 # However, if the system regex is GNU regex, then default to *not*
1417 # using the included regex.
1418 AC_CACHE_CHECK(
1419   [for GNU regex],
1420   [gdb_cv_have_gnu_regex],
1421   [AC_TRY_COMPILE(
1422     [#include <gnu-versions.h>],
1423     [#define REGEX_INTERFACE_VERSION 1
1424 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1425 # error "Version mismatch"
1426 #endif],
1427     gdb_cv_have_gnu_regex=yes,
1428     gdb_cv_have_gnu_regex=no)])
1429 if test $gdb_cv_have_gnu_regex = yes; then
1430   gdb_use_included_regex=no
1431 fi
1432
1433 AC_ARG_WITH(included-regex,
1434   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1435   gdb_with_regex=$withval,
1436   gdb_with_regex=$gdb_use_included_regex)
1437 if test "$gdb_with_regex" = yes; then
1438   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1439     [Define to 1 if the regex included in libiberty should be used.])
1440 fi
1441
1442 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1443 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1444 [#include <sys/param.h>
1445 #include <sys/proc.h>
1446 ])
1447
1448 # See if <sys/lwp.h> defines `struct lwp`.
1449 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1450 [AC_TRY_COMPILE([#include <sys/param.h>
1451 #include <sys/lwp.h>], [struct lwp l;],
1452 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1453 if test $gdb_cv_struct_lwp = yes; then
1454   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1455             [Define to 1 if your system has struct lwp.])
1456 fi
1457
1458 # See if <machine/reg.h> degines `struct reg'.
1459 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1460 [AC_TRY_COMPILE([#include <sys/types.h>
1461 #include <machine/reg.h>], [struct reg r;],
1462 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1463 if test $gdb_cv_struct_reg = yes; then
1464   AC_DEFINE(HAVE_STRUCT_REG, 1,
1465             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1466 fi
1467
1468 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1469 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1470 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1471                  [#include <machine/reg.h>])
1472
1473 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1474 # Older amd64 Linux's don't have the fs_base and gs_base members of
1475 # `struct user_regs_struct'.
1476 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1477                  [], [], [#include <sys/user.h>])
1478
1479 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1480 AC_MSG_CHECKING(for PTRACE_GETREGS)
1481 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1482 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1483                 [PTRACE_GETREGS;],
1484                 [gdb_cv_have_ptrace_getregs=yes],
1485                 [gdb_cv_have_ptrace_getregs=no])])
1486 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1487 if test $gdb_cv_have_ptrace_getregs = yes; then
1488   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1489   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1490 fi
1491
1492 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1493 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1494 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1495 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1496                 [PTRACE_GETFPXREGS;],
1497                 [gdb_cv_have_ptrace_getfpxregs=yes],
1498                 [gdb_cv_have_ptrace_getfpxregs=no])])
1499 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1500 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1501   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1502   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1503 fi
1504
1505 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1506 AC_MSG_CHECKING(for PT_GETDBREGS)
1507 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1508 [AC_TRY_COMPILE([#include <sys/types.h>
1509 #include <sys/ptrace.h>],
1510                 [PT_GETDBREGS;],
1511                 [gdb_cv_have_pt_getdbregs=yes],
1512                 [gdb_cv_have_pt_getdbregs=no])])
1513 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1514 if test $gdb_cv_have_pt_getdbregs = yes; then
1515   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1516   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1517 fi
1518
1519 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1520 AC_MSG_CHECKING(for PT_GETXMMREGS)
1521 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1522 [AC_TRY_COMPILE([#include <sys/types.h>
1523 #include <sys/ptrace.h>],
1524                 [PT_GETXMMREGS;],
1525                 [gdb_cv_have_pt_getxmmregs=yes],
1526                 [gdb_cv_have_pt_getxmmregs=no])])
1527 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1528 if test $gdb_cv_have_pt_getxmmregs = yes; then
1529   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1530   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1531 fi
1532
1533 # Detect which type of /proc is in use, such as for Solaris.
1534
1535 if test "${target}" = "${host}"; then
1536   case "${host}" in
1537   *-*-sysv4.2* | *-*-sysv5* )
1538       AC_DEFINE(NEW_PROC_API, 1,
1539       [Define if you want to use new multi-fd /proc interface.])
1540       ;;
1541   *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*)
1542       AC_DEFINE(NEW_PROC_API, 1,
1543       [Define if you want to use new multi-fd /proc interface.])
1544       ;;
1545   mips-sgi-irix5*)
1546       # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5.
1547       AC_DEFINE([_KMEMUSER], 1,
1548       [Define to 1 so <sys/proc.h> gets a definition of anon_hdl.  Works
1549        around a <sys/proc.h> problem on IRIX 5.])
1550       ;;
1551   esac
1552 fi
1553
1554 if test "$ac_cv_header_sys_procfs_h" = yes; then
1555   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1556   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1557   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1558   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1559   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1560   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1561   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1562   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
1563   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
1564   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
1565   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
1566
1567
1568   dnl Check for broken prfpregset_t type
1569
1570   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
1571   dnl prfpregset_t type (it's a typedef for the pointer to a struct
1572   dnl instead of the struct itself).  We detect this here, and work
1573   dnl around it in gdb_proc_service.h.
1574
1575   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
1576     AC_MSG_CHECKING(whether prfpregset_t type is broken)
1577     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
1578       [AC_TRY_RUN([#include <sys/procfs.h>
1579        int main ()
1580        {
1581          if (sizeof (prfpregset_t) == sizeof (void *))
1582            return 1;
1583          return 0;
1584        }],
1585        gdb_cv_prfpregset_t_broken=no,
1586        gdb_cv_prfpregset_t_broken=yes,
1587        gdb_cv_prfpregset_t_broken=yes)])
1588     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
1589     if test $gdb_cv_prfpregset_t_broken = yes; then
1590       AC_DEFINE(PRFPREGSET_T_BROKEN, 1,
1591       [Define if the prfpregset_t type is broken.])
1592     fi
1593   fi
1594 fi
1595
1596 # Check if the compiler supports the `long long' type.
1597
1598 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1599                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1600 [[extern long long foo;]],
1601 [[switch (foo & 2) { case 0: return 1; }]])],
1602                                   gdb_cv_c_long_long=yes,
1603                                   gdb_cv_c_long_long=no)])
1604 if test $gdb_cv_c_long_long != yes; then
1605   # libdecnumber requires long long.
1606   AC_MSG_ERROR([Compiler must support long long for GDB.])
1607 fi
1608
1609 # Check if the compiler and runtime support printing long longs.
1610
1611 AC_CACHE_CHECK([for long long support in printf],
1612                gdb_cv_printf_has_long_long,
1613                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1614 [[char buf[32];
1615   long long l = 0;
1616   l = (l << 16) + 0x0123;
1617   l = (l << 16) + 0x4567;
1618   l = (l << 16) + 0x89ab;
1619   l = (l << 16) + 0xcdef;
1620   sprintf (buf, "0x%016llx", l);
1621   return (strcmp ("0x0123456789abcdef", buf));]])],
1622                               gdb_cv_printf_has_long_long=yes,
1623                               gdb_cv_printf_has_long_long=no,
1624                               gdb_cv_printf_has_long_long=no)])
1625 if test $gdb_cv_printf_has_long_long = yes; then
1626   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1627             [Define to 1 if the "%ll" format works to print long longs.])
1628 fi
1629
1630 # Check if the compiler and runtime support printing decfloats.
1631
1632 AC_CACHE_CHECK([for decfloat support in printf],
1633                gdb_cv_printf_has_decfloat,
1634                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1635 [[char buf[64];
1636   _Decimal32 d32 = 1.2345df;
1637   _Decimal64 d64 = 1.2345dd;
1638   _Decimal128 d128 = 1.2345dl;
1639   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1640   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1641                               gdb_cv_printf_has_decfloat=yes,
1642                               gdb_cv_printf_has_decfloat=no,
1643                               gdb_cv_printf_has_decfloat=no)])
1644 if test $gdb_cv_printf_has_decfloat = yes; then
1645   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1646             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1647 fi
1648
1649 # Check if the compiler supports the `long double' type.  We can't use
1650 # AC_C_LONG_DOUBLE because that one does additional checks on the
1651 # constants defined in <float.h> that fail on some systems,
1652 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1653
1654 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1655                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1656                                   gdb_cv_c_long_double=yes,
1657                                   gdb_cv_c_long_double=no)])
1658 if test $gdb_cv_c_long_double = yes; then
1659   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1660            [Define to 1 if the compiler supports long double.])
1661 fi
1662
1663 # Check if the compiler and runtime support printing long doubles.
1664
1665 AC_CACHE_CHECK([for long double support in printf],
1666                gdb_cv_printf_has_long_double,
1667                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1668 [[char buf[16];
1669   long double f = 3.141592653;
1670   sprintf (buf, "%Lg", f);
1671   return (strncmp ("3.14159", buf, 7));]])],
1672                               gdb_cv_printf_has_long_double=yes,
1673                               gdb_cv_printf_has_long_double=no,
1674                               gdb_cv_printf_has_long_double=no)])
1675 if test $gdb_cv_printf_has_long_double = yes; then
1676   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1677             [Define to 1 if the "%Lg" format works to print long doubles.])
1678 fi
1679
1680 # Check if the compiler and runtime support scanning long doubles.
1681
1682 AC_CACHE_CHECK([for long double support in scanf],
1683                gdb_cv_scanf_has_long_double,
1684                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1685 [[#include <stdio.h>]],
1686 [[char *buf = "3.141592653";
1687   long double f = 0;
1688   sscanf (buf, "%Lg", &f);
1689   return !(f > 3.14159 && f < 3.14160);]])],
1690                               gdb_cv_scanf_has_long_double=yes,
1691                               gdb_cv_scanf_has_long_double=no,
1692                               gdb_cv_scanf_has_long_double=no)])
1693 if test $gdb_cv_scanf_has_long_double = yes; then
1694   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1695             [Define to 1 if the "%Lg" format works to scan long doubles.])
1696 fi
1697
1698 case ${host_os} in
1699 aix*)
1700   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1701     SAVE_LDFLAGS=$LDFLAGS
1702
1703     case $GCC in
1704     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1705     *) gdb_cv_bigtoc=-bbigtoc ;;
1706     esac
1707
1708     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1709     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1710     LDFLAGS="${SAVE_LDFLAGS}"
1711   ])
1712   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1713   ;;
1714 esac
1715
1716 AC_MSG_CHECKING(for the dynamic export flag)
1717 dynamic_list=false
1718 if test "${gdb_native}" = yes; then
1719    # The dynamically loaded libthread_db needs access to symbols in the gdb
1720    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1721    # may not be supported there.
1722    old_LDFLAGS="$LDFLAGS"
1723    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1724    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1725    LDFLAGS="$LDFLAGS $RDYNAMIC"
1726    if test "${have_libpython}" = no; then
1727      AC_TRY_LINK([], [], [dynamic_list=true])
1728    else
1729      # Workaround http://bugs.python.org/issue4434 where static
1730      # libpythonX.Y.a would get its symbols required for
1731      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1732      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1733      old_CFLAGS="$CFLAGS"
1734      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1735      old_LIBS="$LIBS"
1736      LIBS="$LIBS $PYTHON_LIBS"
1737      AC_RUN_IFELSE(
1738        AC_LANG_PROGRAM(
1739          [#include "]${have_libpython}[/Python.h"],
1740          [int err;
1741           Py_Initialize ();
1742           err = PyRun_SimpleString ("import itertools\n");
1743           Py_Finalize ();
1744           return err == 0 ? 0 : 1;]),
1745        [dynamic_list=true], [], [true])
1746      LIBS="$old_LIBS"
1747      CFLAGS="$old_CFLAGS"
1748    fi
1749    LDFLAGS="$old_LDFLAGS"
1750 fi
1751 if $dynamic_list; then
1752   found="-Wl,--dynamic-list"
1753   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1754 else
1755   found="-rdynamic"
1756   RDYNAMIC="-rdynamic"
1757 fi
1758 AC_SUBST(RDYNAMIC)
1759 AC_MSG_RESULT($found)
1760
1761 dnl For certain native configurations, we need to check whether thread
1762 dnl support can be built in or not.
1763 dnl
1764 dnl Note that we only want this if we are both native (host == target),
1765 dnl and not doing a canadian cross build (build == host).
1766
1767 if test ${build} = ${host} -a ${host} = ${target} ; then
1768    case ${host_os} in
1769    solaris*)
1770       # See if thread_db library is around for Solaris thread debugging.
1771       # Note that we must explicitly test for version 1 of the library
1772       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
1773       # the same API.
1774       AC_MSG_CHECKING(for Solaris thread debugging library)
1775       if test -f /usr/lib/libthread_db.so.1 ; then
1776          AC_MSG_RESULT(yes)
1777          AC_DEFINE(HAVE_THREAD_DB_LIB, 1,
1778          [Define if using Solaris thread debugging.])
1779          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
1780          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
1781          AC_CHECK_LIB(dl, dlopen)
1782          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC"
1783          # Sun randomly tweaked the prototypes in <proc_service.h>
1784          # at one point.
1785          AC_MSG_CHECKING(if <proc_service.h> is old)
1786          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
1787             AC_TRY_COMPILE([
1788                 #include <proc_service.h>
1789                 ps_err_e ps_pdwrite
1790                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
1791             ],, gdb_cv_proc_service_is_old=no,
1792                 gdb_cv_proc_service_is_old=yes)
1793          ])
1794          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
1795          if test $gdb_cv_proc_service_is_old = yes; then
1796             AC_DEFINE(PROC_SERVICE_IS_OLD, 1,
1797             [Define if <proc_service.h> on solaris uses int instead of
1798              size_t, and assorted other type changes.])
1799          fi
1800       else
1801          AC_MSG_RESULT(no)
1802       fi
1803       ;;
1804    aix*)
1805       AC_MSG_CHECKING(for AiX thread debugging library)
1806       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1807                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1808                                    [#ifndef PTHDB_VERSION_3
1809                                     #error
1810                                     #endif],
1811                                    gdb_cv_have_aix_thread_debug=yes,
1812                                    gdb_cv_have_aix_thread_debug=no)])
1813       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1814       if test $gdb_cv_have_aix_thread_debug = yes; then
1815          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1816          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1817          LIBS="$LIBS -lpthdebug"
1818
1819          # Older versions of AIX do not provide the declaration for
1820          # the getthrds function (it appears that it was introduced
1821          # with AIX 6.x).
1822          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1823       fi
1824       ;;
1825    esac
1826    AC_SUBST(CONFIG_LDFLAGS)
1827 fi
1828
1829 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1830 dnl other error codes.
1831 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1832    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1833                   gdb_cv_thread_db_h_has_td_notalloc,
1834      AC_TRY_COMPILE(
1835        [#include <thread_db.h>],
1836        [int i = TD_NOTALLOC;],
1837        gdb_cv_thread_db_h_has_td_notalloc=yes,
1838        gdb_cv_thread_db_h_has_td_notalloc=no
1839      )
1840    )
1841    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1842                   gdb_cv_thread_db_h_has_td_version,
1843      AC_TRY_COMPILE(
1844        [#include <thread_db.h>],
1845        [int i = TD_VERSION;],
1846        gdb_cv_thread_db_h_has_td_version=yes,
1847        gdb_cv_thread_db_h_has_td_version=no
1848      )
1849    )
1850    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1851                   gdb_cv_thread_db_h_has_td_notls,
1852      AC_TRY_COMPILE(
1853        [#include <thread_db.h>],
1854        [int i = TD_NOTLS;],
1855        gdb_cv_thread_db_h_has_td_notls=yes,
1856        gdb_cv_thread_db_h_has_td_notls=no
1857      )
1858    )
1859 fi
1860 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1861   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1862             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1863 fi
1864 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1865   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1866             [Define if <thread_db.h> has the TD_VERSION error code.])
1867 fi
1868 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1869   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1870             [Define if <thread_db.h> has the TD_NOTLS error code.])
1871 fi
1872
1873 dnl See if we have a sys/syscall header file that has __NR_tkill.
1874 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
1875    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
1876                   gdb_cv_sys_syscall_h_has_tkill,
1877      AC_TRY_COMPILE(
1878        [#include <sys/syscall.h>],
1879        [int i = __NR_tkill;],
1880        gdb_cv_sys_syscall_h_has_tkill=yes,
1881        gdb_cv_sys_syscall_h_has_tkill=no
1882      )
1883    )
1884 fi
1885 dnl See if we can issue tkill syscall.
1886 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then
1887   AC_CHECK_FUNC(syscall,
1888     AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.])
1889   )
1890 fi
1891
1892 dnl Check if we can disable the virtual address space randomization.
1893 dnl The functionality of setarch -R.
1894 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1895 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1896 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1897 #       define ADDR_NO_RANDOMIZE 0x0040000
1898 #      endif
1899        /* Test the flag could be set and stays set.  */
1900        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1901        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1902            return 1])])
1903 AC_RUN_IFELSE([PERSONALITY_TEST],
1904               [have_personality=true],
1905               [have_personality=false],
1906               [AC_LINK_IFELSE([PERSONALITY_TEST],
1907                               [have_personality=true],
1908                               [have_personality=false])])
1909 if $have_personality
1910 then
1911     AC_DEFINE([HAVE_PERSONALITY], 1,
1912               [Define if you support the personality syscall.])
1913 fi
1914
1915 dnl Set the host's .gdbinit filename.
1916 case $host_os in
1917   go32* | *djgpp*)
1918     gdbinit=gdb.ini
1919     ;;
1920   *)
1921     gdbinit=.gdbinit
1922     ;;
1923 esac
1924 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1925
1926 dnl Handle optional features that can be enabled.
1927
1928 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1929 # except that the argument to --with-sysroot is optional.
1930 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1931 if test "x$with_sysroot" = xyes; then
1932   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1933 fi
1934 AC_ARG_WITH(sysroot,
1935   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1936                  [search for usr/lib et al within DIR]),
1937   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1938 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1939               [search for usr/lib et al within DIR])
1940 AC_SUBST(TARGET_SYSTEM_ROOT)
1941 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1942
1943 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1944     [automatically load a system-wide gdbinit file],
1945     [])
1946
1947 AC_ARG_ENABLE(werror,
1948   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
1949   [case "${enableval}" in
1950      yes | y) ERROR_ON_WARNING="yes" ;;
1951      no | n)  ERROR_ON_WARNING="no" ;;
1952      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
1953    esac])
1954
1955 # Enable -Werror by default when using gcc.  Turn it off for releases.
1956 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
1957     ERROR_ON_WARNING=yes
1958 fi
1959
1960 WERROR_CFLAGS=""
1961 if test "${ERROR_ON_WARNING}" = yes ; then
1962     WERROR_CFLAGS="-Werror"
1963 fi
1964
1965 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
1966 -Wpointer-sign \
1967 -Wno-unused -Wunused-value -Wunused-function \
1968 -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \
1969 -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \
1970 -Wold-style-declaration -Wold-style-definition"
1971
1972 # Enable -Wno-format by default when using gcc on mingw since many
1973 # GCC versions complain about %I64.
1974 case "${host}" in
1975   *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;;
1976   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
1977 esac
1978
1979 AC_ARG_ENABLE(build-warnings,
1980 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
1981 [case "${enableval}" in
1982   yes)  ;;
1983   no)   build_warnings="-w";;
1984   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1985         build_warnings="${build_warnings} ${t}";;
1986   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1987         build_warnings="${t} ${build_warnings}";;
1988   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1989 esac
1990 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1991   echo "Setting compiler warning flags = $build_warnings" 6>&1
1992 fi])dnl
1993 AC_ARG_ENABLE(gdb-build-warnings,
1994 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
1995 [case "${enableval}" in
1996   yes)  ;;
1997   no)   build_warnings="-w";;
1998   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1999         build_warnings="${build_warnings} ${t}";;
2000   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
2001         build_warnings="${t} ${build_warnings}";;
2002   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
2003 esac
2004 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
2005   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
2006 fi])dnl
2007 WARN_CFLAGS=""
2008 if test "x${build_warnings}" != x -a "x$GCC" = xyes
2009 then
2010     AC_MSG_CHECKING(compiler warning flags)
2011     # Separate out the -Werror flag as some files just cannot be
2012     # compiled with it enabled.
2013     for w in ${build_warnings}; do
2014         case $w in
2015         -Werr*) WERROR_CFLAGS=-Werror ;;
2016         *) # Check that GCC accepts it
2017             saved_CFLAGS="$CFLAGS"
2018             CFLAGS="$CFLAGS $w"
2019             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
2020             CFLAGS="$saved_CFLAGS"
2021         esac
2022     done
2023     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
2024 fi
2025 AC_SUBST(WARN_CFLAGS)
2026 AC_SUBST(WERROR_CFLAGS)
2027
2028 # In the Cygwin environment, we need some additional flags.
2029 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
2030 [AC_EGREP_CPP(^lose$, [
2031 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
2032 lose
2033 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
2034
2035
2036 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
2037 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
2038 case ${host} in
2039   *go32* ) SER_HARDWIRE=ser-go32.o ;;
2040   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
2041   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
2042 esac
2043 AC_SUBST(SER_HARDWIRE)
2044
2045 # libreadline needs libuser32.a in a cygwin environment
2046 WIN32LIBS=
2047 if test x$gdb_cv_os_cygwin = xyes; then
2048     WIN32LIBS="-luser32"
2049     case "${target}" in
2050         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
2051         ;;
2052     esac
2053 fi
2054
2055 # The ser-tcp.c module requires sockets.
2056 case ${host} in
2057   *mingw32*)
2058     AC_DEFINE(USE_WIN32API, 1,
2059               [Define if we should use the Windows API, instead of the
2060                POSIX API.  On Windows, we use the Windows API when
2061                building for MinGW, but the POSIX API when building
2062                for Cygwin.])
2063     WIN32LIBS="$WIN32LIBS -lws2_32"
2064     ;;
2065 esac
2066 AC_SUBST(WIN32LIBS)
2067
2068 # Add ELF support to GDB, but only if BFD includes ELF support.
2069 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
2070                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
2071 if test $gdb_cv_var_elf = yes; then
2072   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o"
2073   AC_DEFINE(HAVE_ELF, 1,
2074             [Define if ELF support should be included.])
2075   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
2076   if test "$plugins" = "yes"; then
2077     AC_SEARCH_LIBS(dlopen, dl)
2078   fi
2079 fi
2080
2081 # Add macho support to GDB, but only if BFD includes it.
2082 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
2083                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
2084 if test $gdb_cv_var_macho = yes; then
2085   CONFIG_OBS="$CONFIG_OBS machoread.o"
2086 fi
2087
2088 # Add SOM support to GDB, but only if BFD includes it.
2089 GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som,
2090                  [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h)
2091 if test $gdb_cv_var_som = yes; then
2092   CONFIG_OBS="$CONFIG_OBS somread.o"
2093 fi
2094
2095 # Add any host-specific objects to GDB.
2096 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
2097
2098 # If building on ELF, look for lzma support for embedded compressed debug info.
2099 if test $gdb_cv_var_elf = yes; then
2100   AC_ARG_WITH(lzma,
2101     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
2102     [], [with_lzma=auto])
2103   AC_MSG_CHECKING([whether to use lzma])
2104   AC_MSG_RESULT([$with_lzma])
2105
2106   if test "${with_lzma}" != no; then
2107     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
2108                           [lzma_index_iter iter;
2109                            lzma_index_iter_init (&iter, 0);
2110                            lzma_mf_is_supported (LZMA_MF_HC3);])
2111     if test "$HAVE_LIBLZMA" != yes; then
2112       if test "$with_lzma" = yes; then
2113         AC_MSG_ERROR([missing liblzma for --with-lzma])
2114       fi
2115     fi
2116   fi
2117 fi
2118
2119 LIBGUI="../libgui/src/libgui.a"
2120 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
2121 AC_SUBST(LIBGUI)
2122 AC_SUBST(GUI_CFLAGS_X)
2123
2124 WIN32LDAPP=
2125 AC_SUBST(WIN32LIBS)
2126 AC_SUBST(WIN32LDAPP)
2127
2128 case "${host}" in
2129 *-*-cygwin* | *-*-mingw* )
2130     configdir="win"
2131     ;;
2132 *)
2133     configdir="unix"
2134     ;;
2135 esac
2136
2137 GDBTKLIBS=
2138 if test "${enable_gdbtk}" = "yes"; then
2139
2140     # Gdbtk must have an absolute path to srcdir in order to run
2141     # properly when not installed.
2142     here=`pwd`
2143     cd ${srcdir}
2144     GDBTK_SRC_DIR=`pwd`
2145     cd $here
2146
2147     SC_PATH_TCLCONFIG
2148
2149     # If $no_tk is nonempty, then we can't do Tk, and there is no
2150     # point to doing Tcl.
2151     SC_PATH_TKCONFIG
2152
2153     if test -z "${no_tcl}" -a -z "${no_tk}"; then
2154         SC_LOAD_TCLCONFIG
2155
2156         # Check for in-tree tcl
2157         here=`pwd`
2158         cd ${srcdir}/..
2159         topdir=`pwd`
2160         cd ${here}
2161
2162         intree="no"
2163         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
2164           intree="yes"
2165         fi
2166
2167         # Find Tcl private headers
2168         if test x"${intree}" = xno; then
2169           CY_AC_TCL_PRIVATE_HEADERS
2170           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
2171           TCL_LIBRARY="${TCL_LIB_SPEC}"
2172           TCL_DEPS=""
2173         else
2174           # If building tcl in the same src tree, private headers
2175           # are not needed, but we need to be sure to use the right
2176           # headers library
2177           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
2178           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
2179           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
2180         fi
2181         AC_SUBST(TCL_INCLUDE)
2182         AC_SUBST(TCL_LIBRARY)
2183         AC_SUBST(TCL_DEPS)
2184
2185         SC_LOAD_TKCONFIG
2186
2187         # Check for in-tree Tk
2188         intree="no"
2189         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
2190           intree="yes"
2191         fi
2192
2193         # Find Tk private headers
2194         if test x"${intree}" = xno; then
2195           CY_AC_TK_PRIVATE_HEADERS
2196           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2197           TK_LIBRARY=${TK_LIB_SPEC}
2198           TK_DEPS=""
2199         else
2200           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2201           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2202           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2203         fi
2204         AC_SUBST(TK_INCLUDE)
2205         AC_SUBST(TK_LIBRARY)
2206         AC_SUBST(TK_DEPS)
2207         AC_SUBST(TK_XINCLUDES)
2208
2209         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2210
2211         # Include some libraries that Tcl and Tk want.
2212         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2213         # Yes, the ordering seems wrong here.  But it isn't.
2214         # TK_LIBS is the list of libraries that need to be linked
2215         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2216         # were in LIBS then any link tests after this point would
2217         # try to include things like `$(LIBGUI)', which wouldn't work.
2218         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2219
2220         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2221         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2222         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2223         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2224         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2225         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2226         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2227
2228         if test x$gdb_cv_os_cygwin = xyes; then
2229           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2230           WIN32LDAPP="-Wl,--subsystem,console"
2231           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2232         fi
2233
2234         AC_CONFIG_SUBDIRS(gdbtk)
2235     fi
2236 fi
2237
2238 AC_SUBST(X_CFLAGS)
2239 AC_SUBST(X_LDFLAGS)
2240 AC_SUBST(X_LIBS)
2241 AC_SUBST(GDBTKLIBS)
2242 AC_SUBST(GDBTK_CFLAGS)
2243 AC_SUBST(GDBTK_SRC_DIR)
2244
2245 AC_PATH_X
2246
2247 # Unlike the sim directory, whether a simulator is linked is controlled by
2248 # presence of a gdb_sim definition in the target configure.tgt entry.
2249 # This code just checks for a few cases where we'd like to ignore those
2250 # definitions, even when they're present in the '.mt' file.  These cases
2251 # are when --disable-sim is specified, or if the simulator directory is
2252 # not part of the source tree.
2253 #
2254 AC_ARG_ENABLE(sim,
2255 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2256 [echo "enable_sim = $enable_sim";
2257  echo "enableval = ${enableval}";
2258  case "${enableval}" in
2259   yes) ignore_sim=false ;;
2260   no)  ignore_sim=true ;;
2261   *)   ignore_sim=false ;;
2262  esac],
2263 [ignore_sim=false])
2264
2265 if test ! -d "${srcdir}/../sim"; then
2266   ignore_sim=true
2267 fi
2268
2269 SIM=
2270 SIM_OBS=
2271 if test "${ignore_sim}" = "false"; then
2272   if test x"${gdb_sim}" != x ; then
2273     SIM="${gdb_sim}"
2274     SIM_OBS="remote-sim.o"
2275     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2276   fi
2277 fi
2278 AC_SUBST(SIM)
2279 AC_SUBST(SIM_OBS)
2280
2281 AC_SUBST(ENABLE_CFLAGS)
2282 AC_SUBST(PROFILE_CFLAGS)
2283
2284 AC_SUBST(CONFIG_OBS)
2285 AC_SUBST(CONFIG_DEPS)
2286 AC_SUBST(CONFIG_SRCS)
2287 AC_SUBST(CONFIG_ALL)
2288 AC_SUBST(CONFIG_CLEAN)
2289 AC_SUBST(CONFIG_INSTALL)
2290 AC_SUBST(CONFIG_UNINSTALL)
2291
2292 # List of host floatformats.
2293 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2294 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2295 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2296
2297 # target_subdir is used by the testsuite to find the target libraries.
2298 target_subdir=
2299 if test "${host}" != "${target}"; then
2300     target_subdir="${target_alias}/"
2301 fi
2302 AC_SUBST(target_subdir)
2303
2304 frags=
2305 if test "${gdb_native}" = "yes"; then
2306   host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
2307   if test ! -f ${host_makefile_frag}; then
2308     AC_MSG_ERROR("*** Gdb does not support native target ${host}")
2309   fi
2310   frags="$frags $host_makefile_frag"
2311 else
2312   host_makefile_frag=/dev/null
2313 fi
2314
2315 AC_SUBST_FILE(host_makefile_frag)
2316 AC_SUBST(frags)
2317
2318 changequote(,)dnl
2319 if test "${gdb_native}" = "yes"; then
2320 # We pick this up from the host configuration file (.mh) because we
2321 # do not have a native configuration Makefile fragment.
2322 nativefile=`sed -n '
2323 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
2324 ' ${host_makefile_frag}`
2325 fi
2326 changequote([,])
2327
2328 if test x"${gdb_osabi}" != x ; then
2329     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2330                        [Define to the default OS ABI for this configuration.])
2331 fi
2332
2333 # Enable multi-ice-gdb-server.
2334 AC_ARG_ENABLE(multi-ice,
2335 AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]),
2336   [case $enableval in
2337     yes | no)
2338       ;;
2339     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
2340   esac])
2341 if test "x$enable_multi_ice" = xyes; then
2342    AC_CONFIG_SUBDIRS(multi-ice)
2343 fi
2344
2345 AC_ARG_ENABLE(gdbserver,
2346 AS_HELP_STRING([--enable-gdbserver],
2347                [automatically build gdbserver (yes/no/auto, default is auto)]),
2348 [case "${enableval}" in
2349   yes| no|auto) ;;
2350   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2351 esac],[enable_gdbserver=auto])
2352
2353 # We only build gdbserver automatically in a native configuration, and
2354 # only if the user did not explicitly disable its build.
2355 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2356   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2357   if test "x$build_gdbserver" = xyes; then
2358     AC_MSG_RESULT(yes)
2359     AC_CONFIG_SUBDIRS(gdbserver)
2360     gdbserver_build_enabled=yes
2361   else
2362     AC_MSG_RESULT(no)
2363   fi
2364 fi
2365
2366 # If the user explicitly request the gdbserver to be built, verify that
2367 # we were in fact able to enable it.
2368 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2369   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2370 fi
2371
2372 # Check for babeltrace and babeltrace-ctf
2373 AC_ARG_WITH(babeltrace,
2374   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2375   [], [with_babeltrace=auto])
2376 AC_MSG_CHECKING([whether to use babeltrace])
2377 AC_MSG_RESULT([$with_babeltrace])
2378
2379 if test "x$with_babeltrace" = "xno"; then
2380   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2381 else
2382   # Append -Werror to CFLAGS so that configure can catch the warning
2383   # "assignment from incompatible pointer type", which is related to
2384   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2385   # in GDB, while babeltrace 1.0.3 is broken.
2386   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2387   # safe to save and restore CFLAGS here.
2388   saved_CFLAGS=$CFLAGS
2389   CFLAGS="$CFLAGS -Werror"
2390   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2391                         [#include <babeltrace/babeltrace.h>
2392                          #include <babeltrace/ctf/events.h>
2393                          #include <babeltrace/ctf/iterator.h>],
2394                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2395                         struct bt_ctf_event *event = NULL;
2396                         const struct bt_definition *scope;
2397
2398                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2399                         scope = bt_ctf_get_top_level_scope (event,
2400                                                            BT_STREAM_EVENT_HEADER);
2401                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2402                         ])
2403   CFLAGS=$saved_CFLAGS
2404
2405   if test "$HAVE_LIBBABELTRACE" != yes; then
2406      if test "$with_babeltrace" = yes; then
2407        AC_MSG_ERROR([babeltrace is missing or unusable])
2408      else
2409        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2410      fi
2411   fi
2412 fi
2413
2414 # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link
2415 # to an empty version.
2416
2417 files=
2418 links=
2419
2420 rm -f nm.h
2421 if test "${nativefile}" != ""; then
2422     case "${nativefile}" in
2423       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2424       * ) GDB_NM_FILE="${nativefile}"
2425     esac
2426     files="${files} ${GDB_NM_FILE}"
2427     links="${links} nm.h"
2428     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2429 fi
2430 AC_SUBST(GDB_NM_FILE)
2431
2432 AC_LINK_FILES($files, $links)
2433
2434 dnl Check for exe extension set on certain hosts (e.g. Win32)
2435 AC_EXEEXT
2436
2437 dnl  Detect the character set used by this host.
2438 dnl  At the moment, we just assume it's UTF-8.
2439 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2440           [Define to be a string naming the default host character set.])
2441
2442 # Undo the $ec_script escaping suitable for Makefile.
2443 transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'`
2444 GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"`
2445 if test "x$GDB_TRANSFORM_NAME" = x; then
2446   GDB_TRANSFORM_NAME=gdb
2447 fi
2448 AC_SUBST(GDB_TRANSFORM_NAME)
2449 GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"`
2450 if test "x$GCORE_TRANSFORM_NAME" = x; then
2451   GCORE_TRANSFORM_NAME=gcore
2452 fi
2453 AC_SUBST(GCORE_TRANSFORM_NAME)
2454 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2455
2456 AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile,
2457 [
2458 case x$CONFIG_HEADERS in
2459 xconfig.h:config.in)
2460 echo > stamp-h ;;
2461 esac
2462 ])
2463
2464 exit 0