gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_DEPS=
  64 CONFIG_SRCS=
  65 ENABLE_CFLAGS=
  66 CONFIG_ALL=
  67 CONFIG_CLEAN=
  68 CONFIG_INSTALL=
  69 CONFIG_UNINSTALL=
  70
  71 AC_CONFIG_SUBDIRS(doc testsuite)
  72 configdirs=
  73
  74 . $srcdir/configure.host
  75
  76 . $srcdir/configure.tgt
  77
  78 # Fetch the default architecture and default target vector from BFD.
  79 targ=$target; . $srcdir/../bfd/config.bfd
  80
  81 # We only want the first architecture, so strip off the others if
  82 # there is more than one.
  83 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  84
  85 if test "x$targ_archs" != x; then
  86   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  87     [Define to BFD's default architecture. ])
  88 fi
  89 if test "x$targ_defvec" != x; then
  90   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  91     [Define to BFD's default target vector. ])
  92 fi
  93
  94 AC_ARG_PROGRAM
  95
  96 # The CLI cannot be disabled yet, but may be in the future.
  97
  98 # Enable CLI.
  99 AC_ARG_ENABLE(gdbcli,
 100 [  --disable-gdbcli        disable command-line interface (CLI)],
 101   [case $enableval in
 102     yes)
 103       ;;
 104     no)
 105       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 106     *)
 107       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 108   esac],
 109   [enable_gdbcli=yes])
 110 if test x"$enable_gdbcli" = xyes; then
 111   if test -d $srcdir/cli; then
 112     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 113     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 114     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 115     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 116   fi
 117 fi
 118
 119 # Enable MI.
 120 AC_ARG_ENABLE(gdbmi,
 121 [  --disable-gdbmi         disable machine-interface (MI)],
 122   [case $enableval in
 123     yes | no)
 124       ;;
 125     *)
 126       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 127   esac],
 128   [enable_gdbmi=yes])
 129 if test x"$enable_gdbmi" = xyes; then
 130   if test -d $srcdir/mi; then
 131     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 132     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 133     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 134     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 135   fi
 136 fi
 137
 138 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 139 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 140 # Makefile fragments.  That's why we need to have `Hcurses' before
 141 # `curses'.  I don't see why we should use HP curses if a more
 142 # standard curses is available, except that according to HP's
 143 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 144 # HP-UX 10.10 and 10.20.
 145
 146 AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses pdcurses], [],
 147     [AC_MSG_WARN([no curses library found])])
 148
 149 # Enable TUI.
 150 AC_ARG_ENABLE(tui,
 151 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 152   [case $enableval in
 153     yes | no)
 154       ;;
 155     *)
 156       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 157   esac],enable_tui=yes)
 158 if test x"$enable_tui" = xyes; then
 159   if test -d $srcdir/tui; then
 160     if test "$ac_cv_search_initscr" != no; then
 161       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 162       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 163       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 164       CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 165       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 166       CONFIG_ALL="${CONFIG_ALL} all-tui"
 167       CONFIG_CLEAN="${CONFIG_CLEAN} clean-tui"
 168       CONFIG_INSTALL="${CONFIG_INSTALL} install-tui"
 169       CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-tui"
 170     fi
 171   fi
 172 fi
 173
 174 # Enable gdbtk.
 175 AC_ARG_ENABLE(gdbtk,
 176 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 177   [case $enableval in
 178     yes | no)
 179       ;;
 180     *)
 181       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 182   esac],
 183   [if test -d $srcdir/gdbtk; then
 184     enable_gdbtk=yes
 185   else
 186     enable_gdbtk=no
 187   fi])
 188 # We unconditionally disable gdbtk tests on selected platforms.
 189 case $host_os in
 190   go32* | windows*)
 191     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 192     enable_gdbtk=no ;;
 193 esac
 194
 195 # Libunwind support.
 196 AC_ARG_WITH(libunwind,
 197 [  --with-libunwind            Use libunwind frame unwinding support],
 198 [case "${withval}" in
 199   yes)  enable_libunwind=yes ;;
 200   no)   enable_libunwind=no ;;
 201   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-libunwind option) ;;
 202 esac],[
 203   AC_CHECK_HEADERS(libunwind.h)
 204   AC_CHECK_HEADERS(libunwind-ia64.h)
 205   if test x"$ac_cv_header_libunwind_h" = xyes -a x"$ac_cv_header_libunwind_ia64_h" = xyes; then
 206     enable_libunwind=yes;
 207   fi
 208 ])
 209
 210 if test x"$enable_libunwind" = xyes; then
 211   AC_CHECK_HEADERS(libunwind.h)
 212   AC_CHECK_HEADERS(libunwind-ia64.h)
 213   AC_DEFINE(HAVE_LIBUNWIND, 1)
 214   CONFIG_OBS="$CONFIG_OBS libunwind-frame.o"
 215   CONFIG_DEPS="$CONFIG_DEPS libunwind-frame.o"
 216   CONFIG_SRCS="$CONFIG_SRCS libunwind-frame.c"
 217 fi
 218
 219 # Profiling support.
 220 AC_ARG_ENABLE(profiling,
 221 [  --enable-profiling      enable profiling of GDB],
 222   [case $enableval in
 223     yes | no)
 224       ;;
 225     *)
 226       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 227   esac],
 228  [enable_profiling=no])
 229
 230 AC_CHECK_FUNCS(monstartup _mcleanup)
 231 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 232 [AC_TRY_LINK(
 233 [#include <stdlib.h>
 234 extern char _etext;
 235 ],
 236 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 237 if test $ac_cv_var__etext = yes; then
 238   AC_DEFINE(HAVE__ETEXT, 1,
 239             [Define to 1 if your system has the _etext variable. ])
 240 fi
 241 if test "$enable_profiling" = yes ; then
 242   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 243     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 244   fi
 245   PROFILE_CFLAGS=-pg
 246   OLD_CFLAGS="$CFLAGS"
 247   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 248
 249   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 250     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 251      ac_cv_cc_supports_pg=no)])
 252
 253   if test $ac_cv_cc_supports_pg = no; then
 254     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 255   fi
 256
 257   CFLAGS="$OLD_CFLAGS"
 258 fi
 259
 260 # --------------------- #
 261 # Checks for programs.  #
 262 # --------------------- #
 263
 264 AC_PROG_AWK
 265 AC_PROG_INSTALL
 266 AC_PROG_LN_S
 267 AC_PROG_RANLIB
 268 AC_PROG_YACC
 269
 270 AC_CHECK_TOOL(AR, ar)
 271 AC_CHECK_TOOL(DLLTOOL, dlltool)
 272 AC_CHECK_TOOL(WINDRES, windres)
 273
 274 # Needed for GNU/Hurd.
 275 AC_CHECK_TOOL(MIG, mig)
 276
 277 # ---------------------- #
 278 # Checks for libraries.  #
 279 # ---------------------- #
 280
 281 # We might need to link with -lm; most simulators need it.
 282 AC_CHECK_LIB(m, main)
 283
 284 # We need to link with -lw to get `wctype' on Solaris before Solaris
 285 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 286 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 287 # is known to have this problem).  Therefore we avoid libw if we can.
 288 AC_CHECK_FUNC(wctype, [],
 289   [AC_CHECK_LIB(w, wctype)])
 290
 291 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 292 AC_SEARCH_LIBS(gethostbyname, nsl)
 293
 294 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 295 AC_SEARCH_LIBS(socketpair, socket)
 296
 297 # Since GDB uses Readline, we need termcap functionality, so we need
 298 # to find a library that provides that.  When GDB is configured with
 299 # the TUI, we need full curses functionality.
 300
 301 case $host_os in
 302   cygwin*)
 303     if test -d $srcdir/libtermcap; then
 304       LIBS="../libtermcap/libtermcap.a $LIBS"
 305       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 306     fi ;;
 307   go32* | *djgpp*)
 308     ac_cv_search_tgetent="none required"
 309     ;;
 310   aix*)
 311     # Readline prefers curses over termcap on AIX.
 312     # ??? Why?
 313     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 314     ;;
 315 esac
 316
 317 # Note: We used to check for libtermlib and libterminfo too, but
 318 # Readline doesn't, so I think we're safe with leaving them out.
 319 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 320
 321 if test "$ac_cv_search_tgetent" = no; then
 322   AC_MSG_ERROR([no termcap library found])
 323 fi
 324
 325 # ------------------------- #
 326 # Checks for header files.  #
 327 # ------------------------- #
 328
 329 AC_HEADER_DIRENT
 330 AC_HEADER_STAT
 331 AC_HEADER_STDC
 332 AC_CHECK_HEADERS(link.h)
 333 AC_CHECK_HEADERS(machine/reg.h)
 334 AC_CHECK_HEADERS(nlist.h)
 335 AC_CHECK_HEADERS(poll.h sys/poll.h)
 336 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 337 AC_CHECK_HEADERS(stddef.h)
 338 AC_CHECK_HEADERS(stdlib.h)
 339 AC_CHECK_HEADERS(stdint.h)
 340 AC_CHECK_HEADERS(string.h memory.h strings.h)
 341 AC_CHECK_HEADERS(sys/fault.h)
 342 AC_CHECK_HEADERS(sys/file.h)
 343 AC_CHECK_HEADERS(sys/filio.h)
 344 AC_CHECK_HEADERS(sys/ioctl.h)
 345 AC_CHECK_HEADERS(sys/param.h)
 346 AC_CHECK_HEADERS(sys/proc.h)
 347 AC_CHECK_HEADERS(sys/procfs.h)
 348 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 349 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 350 AC_CHECK_HEADERS(sys/select.h)
 351 AC_CHECK_HEADERS(sys/syscall.h)
 352 AC_CHECK_HEADERS(sys/user.h)
 353 AC_CHECK_HEADERS(sys/wait.h wait.h)
 354 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 355 AC_CHECK_HEADERS(unistd.h)
 356
 357 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 358 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 359 # think that we don't have <curses.h> if we're using GCC.
 360 case $host_os in
 361   solaris2.[[78]])
 362     if test "$GCC" = yes; then
 363       AC_DEFINE(_MSE_INT_H, 1,
 364         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 365    Solaris 2.[78] when using GCC. ]])
 366     fi ;;
 367 esac
 368 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 369
 370 # FIXME: kettenis/20030102: In most cases we include these
 371 # unconditionally, so what's the point in checking these?
 372 AC_CHECK_HEADERS(ctype.h time.h)
 373
 374 dnl Check for struct stat with an st_blocks member
 375 AC_MSG_CHECKING(for member st_blocks in struct stat)
 376 AC_CACHE_VAL(gdb_cv_have_struct_stat_with_st_blocks_member,
 377   [AC_TRY_COMPILE([#include <sys/types.h>
 378 #include <sys/stat.h>],
 379                   [struct stat st; (void) st.st_blocks;],
 380                   gdb_cv_have_struct_stat_with_st_blocks_member=yes,
 381                   gdb_cv_have_struct_stat_with_st_blocks_member=no)])
 382 AC_MSG_RESULT($gdb_cv_have_struct_stat_with_st_blocks_member)
 383 if test $gdb_cv_have_struct_stat_with_st_blocks_member = yes; then
 384   AC_DEFINE(HAVE_STRUCT_STAT_ST_BLOCKS)
 385 fi
 386 # ------------------------- #
 387 # Checks for declarations.  #
 388 # ------------------------- #
 389
 390 gcc_AC_CHECK_DECLS(getopt)
 391
 392 # ------------------ #
 393 # Checks for types.  #
 394 # ------------------ #
 395
 396 AC_TYPE_SIGNAL
 397
 398 # ------------------------------------- #
 399 # Checks for compiler characteristics.  #
 400 # ------------------------------------- #
 401
 402 AC_C_CONST
 403 AC_C_INLINE
 404
 405 # ------------------------------ #
 406 # Checks for library functions.  #
 407 # ------------------------------ #
 408
 409 AC_FUNC_ALLOCA
 410 AC_FUNC_MMAP
 411 AC_FUNC_VFORK
 412 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 413 AC_CHECK_FUNCS(poll)
 414 AC_CHECK_FUNCS(pread64)
 415 AC_CHECK_FUNCS(sbrk)
 416 AC_CHECK_FUNCS(setpgid setpgrp)
 417 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 418 AC_CHECK_FUNCS(socketpair)
 419 AC_CHECK_FUNCS(syscall)
 420
 421 dnl AC_FUNC_SETPGRP does not work when cross compiling
 422 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 423 if test "$cross_compiling" = no; then
 424   AC_FUNC_SETPGRP
 425 else
 426   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 427     [AC_TRY_COMPILE([
 428 #include <unistd.h>
 429 ], [
 430   if (setpgrp(1,1) == -1)
 431     exit (0);
 432   else
 433     exit (1);
 434 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 435 if test $ac_cv_func_setpgrp_void = yes; then
 436   AC_DEFINE(SETPGRP_VOID, 1)
 437 fi
 438 fi
 439
 440 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 441 # since sigsetjmp might only be defined as a macro.
 442 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 443 [AC_TRY_COMPILE([
 444 #include <setjmp.h>
 445 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 446 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 447 if test $gdb_cv_func_sigsetjmp = yes; then
 448   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 449 fi
 450
 451 # Assume we'll default to using the included libiberty regex.
 452 gdb_use_included_regex=yes
 453
 454 # However, if the system regex is GNU regex, then default to *not*
 455 # using the included regex.
 456 AC_CACHE_CHECK(
 457   [for GNU regex],
 458   [gdb_cv_have_gnu_regex],
 459   [AC_TRY_COMPILE(
 460     [#include <gnu-versions.h>],
 461     [#define REGEX_INTERFACE_VERSION 1
 462 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 463 # error "Version mismatch"
 464 #endif],
 465     gdb_cv_have_gnu_regex=yes,
 466     gdb_cv_have_gnu_regex=no)])
 467 if test $gdb_cv_have_gnu_regex = yes; then
 468   gdb_use_included_regex=no
 469 fi
 470
 471 AC_ARG_WITH(included-regex,
 472   [  --without-included-regex don't use included regex; this is the default
 473                           on systems with version 2 of the GNU C library
 474                           (use with caution on other system)],
 475   gdb_with_regex=$withval,
 476   gdb_with_regex=$gdb_use_included_regex)
 477 if test "$gdb_with_regex" = yes; then
 478   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 479     [Define to 1 if the regex included in libiberty should be used.])
 480 fi
 481
 482 # See if <machine/reg.h> degines `struct reg'.
 483 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
 484 [AC_TRY_COMPILE([#include <sys/types.h>
 485 #include <machine/reg.h>], [struct reg r;],
 486 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
 487 if test $gdb_cv_struct_reg = yes; then
 488   AC_DEFINE(HAVE_STRUCT_REG, 1,
 489             [Define to 1 if your system has struct reg in <machine/reg.h>.])
 490 fi
 491
 492 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 493 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 494 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 495 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 496 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 497 if test $gdb_cv_struct_reg_r_fs = yes; then
 498   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 499 fi
 500 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 501 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 502 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 503 if test $gdb_cv_struct_reg_r_gs = yes; then
 504   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 505 fi
 506
 507 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 508 AC_MSG_CHECKING(for PTRACE_GETREGS)
 509 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 510 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 511                 [PTRACE_GETREGS;],
 512                 [gdb_cv_have_ptrace_getregs=yes],
 513                 [gdb_cv_have_ptrace_getregs=no])])
 514 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 515 if test $gdb_cv_have_ptrace_getregs = yes; then
 516   AC_DEFINE(HAVE_PTRACE_GETREGS)
 517 fi
 518
 519 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 520 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 521 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 522 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 523                 [PTRACE_GETFPXREGS;],
 524                 [gdb_cv_have_ptrace_getfpxregs=yes],
 525                 [gdb_cv_have_ptrace_getfpxregs=no])])
 526 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 527 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 528   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 529 fi
 530
 531 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 532 AC_MSG_CHECKING(for PT_GETDBREGS)
 533 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 534 [AC_TRY_COMPILE([#include <sys/types.h>
 535 #include <sys/ptrace.h>],
 536                 [PT_GETDBREGS;],
 537                 [gdb_cv_have_pt_getdbregs=yes],
 538                 [gdb_cv_have_pt_getdbregs=no])])
 539 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 540 if test $gdb_cv_have_pt_getdbregs = yes; then
 541   AC_DEFINE(HAVE_PT_GETDBREGS)
 542 fi
 543
 544 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 545 AC_MSG_CHECKING(for PT_GETXMMREGS)
 546 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 547 [AC_TRY_COMPILE([#include <sys/types.h>
 548 #include <sys/ptrace.h>],
 549                 [PT_GETXMMREGS;],
 550                 [gdb_cv_have_pt_getxmmregs=yes],
 551                 [gdb_cv_have_pt_getxmmregs=no])])
 552 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 553 if test $gdb_cv_have_pt_getxmmregs = yes; then
 554   AC_DEFINE(HAVE_PT_GETXMMREGS)
 555 fi
 556
 557 # See if stdint.h provides the uintptr_t type.
 558 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 559 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 560   [AC_TRY_COMPILE(
 561     [#include <stdint.h>],
 562     [uintptr_t foo = 0;],
 563     gdb_cv_have_uintptr_t=yes,
 564     gdb_cv_have_uintptr_t=no)])
 565 if test $gdb_cv_have_uintptr_t = yes; then
 566   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 567 fi
 568
 569 BFD_NEED_DECLARATION(malloc)
 570 BFD_NEED_DECLARATION(realloc)
 571 BFD_NEED_DECLARATION(free)
 572 BFD_NEED_DECLARATION(strerror)
 573 BFD_NEED_DECLARATION(strdup)
 574 BFD_NEED_DECLARATION(strstr)
 575 BFD_NEED_DECLARATION(canonicalize_file_name)
 576
 577 # The following save_state_t checkery is only necessary for HPUX
 578 # versions earlier than 10.20.  When those fade from memory, this
 579 # could be expunged. --jsm 1999-03-22
 580
 581 AC_MSG_CHECKING(for HPUX save_state structure)
 582 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 583                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 584 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 585                 gdb_cv_hpux_sswide=no)
 586 if test $gdb_cv_hpux_savestate = yes
 587 then
 588   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 589 fi
 590 if test $gdb_cv_hpux_sswide = yes
 591 then
 592   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 593 fi
 594 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 595
 596
 597 # If we are configured native on GNU/Linux, work around problems with
 598 # sys/procfs.h
 599 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 600
 601 if test "${target}" = "${host}"; then
 602   case "${host}" in
 603   i[[3456]]86-*-linux*)
 604         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 605         AC_DEFINE(sys_quotactl)
 606         ;;
 607   ia64-*-aix*)
 608       AC_DEFINE(NEW_PROC_API)
 609       ;;
 610   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 611       AC_DEFINE(NEW_PROC_API)
 612       ;;
 613   *-*-solaris2.[[6789]])
 614       AC_DEFINE(NEW_PROC_API)
 615       ;;
 616   esac
 617 fi
 618
 619 if test "$ac_cv_header_sys_procfs_h" = yes; then
 620   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 621   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 622   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 623   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 624   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 625   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 626   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 627   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 628   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 629   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 630   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 631   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 632   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 633   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 634
 635
 636   dnl Check for broken prfpregset_t type
 637
 638   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 639   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 640   dnl instead of the struct itself).  We detect this here, and work
 641   dnl around it in gdb_proc_service.h.
 642
 643   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 644     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 645     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 646       [AC_TRY_RUN([#include <sys/procfs.h>
 647        int main ()
 648        {
 649          if (sizeof (prfpregset_t) == sizeof (void *))
 650            return 1;
 651          return 0;
 652        }],
 653        gdb_cv_prfpregset_t_broken=no,
 654        gdb_cv_prfpregset_t_broken=yes,
 655        gdb_cv_prfpregset_t_broken=yes)])
 656     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 657     if test $gdb_cv_prfpregset_t_broken = yes; then
 658       AC_DEFINE(PRFPREGSET_T_BROKEN)
 659     fi
 660   fi
 661
 662   dnl Check for PIOCSET ioctl entry
 663
 664   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 665   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 666   [AC_TRY_COMPILE([#include <unistd.h>
 667 #include <sys/types.h>
 668 #include <sys/procfs.h>
 669 ], [
 670     int dummy;;
 671     dummy = ioctl(0, PIOCSET, &dummy);
 672   ],
 673   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 674   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 675   if test $gdb_cv_have_procfs_piocset = yes; then
 676     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 677   fi
 678 fi
 679
 680 dnl For native ports (host == target), check to see what kind of
 681 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 682 if test ${host} = ${target} ; then
 683   dnl Check for struct link_map with l_ members which are indicative
 684   dnl of SVR4-like shared libraries
 685
 686   AC_MSG_CHECKING(for member l_addr in struct link_map)
 687   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 688     [AC_TRY_COMPILE([#include <link.h>],
 689                     [struct link_map lm; (void) lm.l_addr;],
 690                     gdb_cv_have_struct_link_map_with_l_members=yes,
 691                     gdb_cv_have_struct_link_map_with_l_members=no)])
 692   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 693   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 694     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 695   fi
 696
 697   dnl Check for struct link_map with lm_ members which are indicative
 698   dnl of SunOS-like shared libraries
 699
 700   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 701   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 702     [AC_TRY_COMPILE([#include <sys/types.h>
 703 #include <link.h>],
 704                     [struct link_map lm; (void) lm.lm_addr;],
 705                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 706                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 707   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 708   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 709     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 710   fi
 711
 712   dnl Check for struct so_map with som_ members which are found on
 713   dnl some *BSD systems.
 714
 715   AC_MSG_CHECKING(for member som_addr in struct so_map)
 716   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 717     [AC_TRY_COMPILE([#include <sys/types.h>
 718 #ifdef HAVE_NLIST_H
 719 #include <nlist.h>
 720 #endif
 721 #include <link.h>],
 722                     [struct so_map lm; (void) lm.som_addr;],
 723                     gdb_cv_have_struct_so_map_with_som_members=yes,
 724                     gdb_cv_have_struct_so_map_with_som_members=no)])
 725   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 726   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 727     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 728   fi
 729
 730   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 731   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 732
 733   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 734   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 735     [AC_TRY_COMPILE([#define _SYSCALL32
 736 #include <sys/link.h>], [struct link_map32 l;],
 737      gdb_cv_have_struct_link_map32=yes,
 738      gdb_cv_have_struct_link_map32=no)])
 739   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 740   if test $gdb_cv_have_struct_link_map32 = yes; then
 741     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 742     AC_DEFINE(_SYSCALL32)
 743   fi
 744 fi
 745
 746 dnl See if compiler supports "long long" type.
 747
 748 AC_MSG_CHECKING(for long long support in compiler)
 749 AC_CACHE_VAL(gdb_cv_c_long_long,
 750 [AC_TRY_COMPILE(, [
 751   extern long long foo;
 752   switch (foo & 2) { case 0: return 1; }
 753 ],
 754 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 755 AC_MSG_RESULT($gdb_cv_c_long_long)
 756 if test $gdb_cv_c_long_long = yes; then
 757   AC_DEFINE(CC_HAS_LONG_LONG)
 758 fi
 759
 760 dnl See if the compiler and runtime support printing long long
 761
 762 AC_MSG_CHECKING(for long long support in printf)
 763 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 764 [AC_TRY_RUN([
 765 int main () {
 766   char buf[32];
 767   long long l = 0;
 768   l = (l << 16) + 0x0123;
 769   l = (l << 16) + 0x4567;
 770   l = (l << 16) + 0x89ab;
 771   l = (l << 16) + 0xcdef;
 772   sprintf (buf, "0x%016llx", l);
 773   return (strcmp ("0x0123456789abcdef", buf));
 774 }],
 775 gdb_cv_printf_has_long_long=yes,
 776 gdb_cv_printf_has_long_long=no,
 777 gdb_cv_printf_has_long_long=no)])
 778 if test $gdb_cv_printf_has_long_long = yes; then
 779   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 780 fi
 781 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 782
 783 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 784 dnl because autoconf complains about cross-compilation issues.  However, this
 785 dnl code uses the same variables as the macro for compatibility.
 786
 787 AC_MSG_CHECKING(for long double support in compiler)
 788 AC_CACHE_VAL(ac_cv_c_long_double,
 789 [AC_TRY_COMPILE(, [long double foo;],
 790 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 791 AC_MSG_RESULT($ac_cv_c_long_double)
 792 if test $ac_cv_c_long_double = yes; then
 793   AC_DEFINE(HAVE_LONG_DOUBLE)
 794 fi
 795
 796 dnl See if the compiler and runtime support printing long doubles
 797
 798 AC_MSG_CHECKING(for long double support in printf)
 799 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 800 [AC_TRY_RUN([
 801 int main () {
 802   char buf[16];
 803   long double f = 3.141592653;
 804   sprintf (buf, "%Lg", f);
 805   return (strncmp ("3.14159", buf, 7));
 806 }],
 807 gdb_cv_printf_has_long_double=yes,
 808 gdb_cv_printf_has_long_double=no,
 809 gdb_cv_printf_has_long_double=no)])
 810 if test $gdb_cv_printf_has_long_double = yes; then
 811   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 812 fi
 813 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 814
 815 dnl See if the compiler and runtime support scanning long doubles
 816
 817 AC_MSG_CHECKING(for long double support in scanf)
 818 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 819 [AC_TRY_RUN([
 820 int main () {
 821   char *buf = "3.141592653";
 822   long double f = 0;
 823   sscanf (buf, "%Lg", &f);
 824   return !(f > 3.14159 && f < 3.14160);
 825 }],
 826 gdb_cv_scanf_has_long_double=yes,
 827 gdb_cv_scanf_has_long_double=no,
 828 gdb_cv_scanf_has_long_double=no)])
 829 if test $gdb_cv_scanf_has_long_double = yes; then
 830   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 831 fi
 832 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 833
 834 case ${host_os} in
 835 aix*)
 836   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 837     SAVE_LDFLAGS=$LDFLAGS
 838
 839     case $GCC in
 840     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 841     *) gdb_cv_bigtoc=-bbigtoc ;;
 842     esac
 843
 844     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 845     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 846   ])
 847   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 848   ;;
 849 esac
 850
 851
 852 dnl For certain native configurations, we need to check whether thread
 853 dnl support can be built in or not.
 854 dnl
 855 dnl Note that we only want this if we are both native (host == target),
 856 dnl and not doing a canadian cross build (build == host).
 857
 858 if test ${build} = ${host} -a ${host} = ${target} ; then
 859    case ${host_os} in
 860    hpux*)
 861       AC_MSG_CHECKING(for HPUX/OSF thread support)
 862       if test -f /usr/include/dce/cma_config.h ; then
 863          if test "$GCC" = "yes" ; then
 864             AC_MSG_RESULT(yes)
 865             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 866             CONFIG_OBS="${CONFIG_OBS} hpux-thread.o"
 867             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 868          else
 869             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 870          fi
 871       else
 872          AC_MSG_RESULT(no)
 873       fi
 874       ;;
 875    solaris*)
 876       # See if thread_db library is around for Solaris thread debugging.
 877       # Note that we must explicitly test for version 1 of the library
 878       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 879       # the same API.
 880       AC_MSG_CHECKING(for Solaris thread debugging library)
 881       if test -f /usr/lib/libthread_db.so.1 ; then
 882          AC_MSG_RESULT(yes)
 883          AC_DEFINE(HAVE_THREAD_DB_LIB)
 884          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 885          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 886          AC_CHECK_LIB(dl, dlopen)
 887          if test "$GCC" = "yes" ; then
 888             # The GNU linker requires the -export-dynamic option to make
 889             # all symbols visible in the dynamic symbol table.
 890             hold_ldflags=$LDFLAGS
 891             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 892             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 893             AC_TRY_LINK(, [int i;], found=yes, found=no)
 894             LDFLAGS=$hold_ldflags
 895             AC_MSG_RESULT($found)
 896             if test $found = yes; then
 897                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 898             fi
 899          fi
 900          # Sun randomly tweaked the prototypes in <proc_service.h>
 901          # at one point.
 902          AC_MSG_CHECKING(if <proc_service.h> is old)
 903          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 904             AC_TRY_COMPILE([
 905                 #include <proc_service.h>
 906                 ps_err_e ps_pdwrite
 907                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 908             ],, gdb_cv_proc_service_is_old=no,
 909                 gdb_cv_proc_service_is_old=yes)
 910          ])
 911          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 912          if test $gdb_cv_proc_service_is_old = yes; then
 913             AC_DEFINE(PROC_SERVICE_IS_OLD)
 914          fi
 915       else
 916          AC_MSG_RESULT(no)
 917       fi
 918       ;;
 919    aix*)
 920       AC_MSG_CHECKING(for AiX thread debugging library)
 921       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 922                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 923                                    [#ifndef PTHDB_VERSION_3
 924                                     #error
 925                                     #endif],
 926                                    gdb_cv_have_aix_thread_debug=yes,
 927                                    gdb_cv_have_aix_thread_debug=no)])
 928       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 929       if test $gdb_cv_have_aix_thread_debug = yes; then
 930          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 931          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
 932          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 933       fi
 934       ;;
 935    esac
 936    AC_SUBST(CONFIG_LDFLAGS)
 937 fi
 938
 939 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 940 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 941    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 942                   gdb_cv_thread_db_h_has_td_notalloc,
 943      AC_TRY_COMPILE(
 944        [#include <thread_db.h>],
 945        [int i = TD_NOTALLOC;],
 946        gdb_cv_thread_db_h_has_td_notalloc=yes,
 947        gdb_cv_thread_db_h_has_td_notalloc=no
 948      )
 949    )
 950 fi
 951 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 952   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 953             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 954 fi
 955
 956 dnl See if we have a sys/syscall header file that has __NR_tkill.
 957 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 958    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 959                   gdb_cv_sys_syscall_h_has_tkill,
 960      AC_TRY_COMPILE(
 961        [#include <sys/syscall.h>],
 962        [int i = __NR_tkill;],
 963        gdb_cv_sys_syscall_h_has_tkill=yes,
 964        gdb_cv_sys_syscall_h_has_tkill=no
 965      )
 966    )
 967 fi
 968 dnl See if we can issue tkill syscall.
 969 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 970   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 971             [Define if we can use the tkill syscall.])
 972 fi
 973
 974 dnl Handle optional features that can be enabled.
 975
 976 AC_ARG_WITH(sysroot,
 977 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 978 [
 979  case ${with_sysroot} in
 980  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 981  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 982  esac
 983
 984  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 985
 986  if test "x$exec_prefix" = xNONE; then
 987   if test "x$prefix" = xNONE; then
 988    test_prefix=/usr/local
 989   else
 990    test_prefix=$prefix
 991   fi
 992  else
 993   test_prefix=$exec_prefix
 994  fi
 995  case ${TARGET_SYSTEM_ROOT} in
 996  "${test_prefix}"|"${test_prefix}/"*|\
 997  '${exec_prefix}'|'${exec_prefix}/'*)
 998    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 999    TARGET_SYSTEM_ROOT_DEFINE="$t"
1000    ;;
1001  esac
1002 ], [
1003  TARGET_SYSTEM_ROOT=
1004  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
1005 ])
1006 AC_SUBST(TARGET_SYSTEM_ROOT)
1007 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
1008
1009 # NOTE: Don't add -Wall or -Wunused, they both include
1010 # -Wunused-parameter which reports bogus warnings.
1011 # NOTE: If you add to this list, remember to update
1012 # gdb/doc/gdbint.texinfo.
1013 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
1014 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral \
1015 -Wunused-label -Wunused-function"
1016 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
1017 # -Wunused-function -Wunused-variable -Wunused-value
1018 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
1019 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
1020 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
1021 # -Woverloaded-virtual -Winline -Werror"
1022 AC_ARG_ENABLE(build-warnings,
1023 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
1024 [case "${enableval}" in
1025   yes)  ;;
1026   no)   build_warnings="-w";;
1027   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1028         build_warnings="${build_warnings} ${t}";;
1029   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1030         build_warnings="${t} ${build_warnings}";;
1031   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1032 esac
1033 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1034   echo "Setting compiler warning flags = $build_warnings" 6>&1
1035 fi])dnl
1036 AC_ARG_ENABLE(gdb-build-warnings,
1037 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1038 [case "${enableval}" in
1039   yes)  ;;
1040   no)   build_warnings="-w";;
1041   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1042         build_warnings="${build_warnings} ${t}";;
1043   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1044         build_warnings="${t} ${build_warnings}";;
1045   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1046 esac
1047 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1048   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1049 fi])dnl
1050 WARN_CFLAGS=""
1051 WERROR_CFLAGS=""
1052 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1053 then
1054     AC_MSG_CHECKING(compiler warning flags)
1055     # Separate out the -Werror flag as some files just cannot be
1056     # compiled with it enabled.
1057     for w in ${build_warnings}; do
1058         case $w in
1059         -Werr*) WERROR_CFLAGS=-Werror ;;
1060         *) # Check that GCC accepts it
1061             saved_CFLAGS="$CFLAGS"
1062             CFLAGS="$CFLAGS $w"
1063             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1064             CFLAGS="$saved_CFLAGS"
1065         esac
1066     done
1067     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1068 fi
1069 AC_SUBST(WARN_CFLAGS)
1070 AC_SUBST(WERROR_CFLAGS)
1071
1072 # In the Cygwin environment, we need some additional flags.
1073 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1074 [AC_EGREP_CPP(lose, [
1075 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1076 lose
1077 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1078
1079
1080 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1081 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1082 case ${host} in
1083   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1084   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1085 esac
1086 AC_SUBST(SER_HARDWIRE)
1087
1088 # libreadline needs libuser32.a in a cygwin environment
1089 WIN32LIBS=
1090 if test x$gdb_cv_os_cygwin = xyes; then
1091     WIN32LIBS="-luser32"
1092     case "${target}" in
1093         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1094         ;;
1095     esac
1096 fi
1097 AC_SUBST(WIN32LIBS)
1098
1099 LIBGUI="../libgui/src/libgui.a"
1100 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1101 AC_SUBST(LIBGUI)
1102 AC_SUBST(GUI_CFLAGS_X)
1103
1104 WIN32LDAPP=
1105 AC_SUBST(WIN32LIBS)
1106 AC_SUBST(WIN32LDAPP)
1107
1108 configdir="unix"
1109
1110 GDBTKLIBS=
1111 if test "${enable_gdbtk}" = "yes"; then
1112
1113     # Gdbtk must have an absolute path to srcdir in order to run
1114     # properly when not installed.
1115     here=`pwd`
1116     cd ${srcdir}
1117     GDBTK_SRC_DIR=`pwd`
1118     cd $here
1119
1120     CY_AC_PATH_TCLCONFIG
1121     if test -z "${no_tcl}"; then
1122         CY_AC_LOAD_TCLCONFIG
1123         CY_AC_PATH_TKCONFIG
1124
1125         # now look for Tcl library stuff
1126
1127         case "${host}" in
1128         *-*-cygwin*)
1129             tcldir=../tcl/win/
1130             ;;
1131         *)
1132             tcldir=../tcl/unix/
1133             ;;
1134         esac
1135
1136         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1137
1138         # If $no_tk is nonempty, then we can't do Tk, and there is no
1139         # point to doing Tcl.
1140         if test -z "${no_tk}"; then
1141            CY_AC_LOAD_TKCONFIG
1142            CY_AC_PATH_TCLH
1143            CY_AC_PATH_TKH
1144            CY_AC_PATH_ITCLH
1145            CY_AC_PATH_ITKH
1146
1147
1148            # now look for Tk library stuff
1149
1150            case "${host}" in
1151            *-*-cygwin*)
1152                tkdir=../tk/win/
1153                ;;
1154            *)
1155                tkdir=../tk/unix/
1156                ;;
1157            esac
1158
1159            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1160
1161            # now look for Itcl library stuff
1162
1163            CY_AC_PATH_ITCLCONFIG
1164            if test -z "${no_itcl}"; then
1165              CY_AC_LOAD_ITCLCONFIG
1166
1167              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1168              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1169            fi
1170
1171
1172            # now look for Itk library stuff
1173            CY_AC_PATH_ITKCONFIG
1174            if test -z "${no_itcl}"; then
1175              CY_AC_LOAD_ITKCONFIG
1176
1177              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1178              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1179            fi
1180
1181            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1182            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1183            # know whether 8.2 will or not, but I bet it will.
1184            # I don't have to worry about 7.x since we don't support it.
1185            GDBTK_CFLAGS=""
1186            if test "$GCC" = "yes"; then
1187                if test "$TCL_VERSION" != "8.0" ; then
1188                    GDBTK_CFLAGS="-fwritable-strings"
1189                fi
1190            fi
1191
1192            # Include some libraries that Tcl and Tk want.
1193            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1194            # Yes, the ordering seems wrong here.  But it isn't.
1195            # TK_LIBS is the list of libraries that need to be linked
1196            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1197            # were in LIBS then any link tests after this point would
1198            # try to include things like `$(LIBGUI)', which wouldn't work.
1199            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1200
1201            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1202            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1203            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1204            CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1205            CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1206            CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1207            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1208
1209            if test x$gdb_cv_os_cygwin = xyes; then
1210               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1211               WIN32LDAPP="-Wl,--subsystem,console"
1212               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1213            fi
1214         fi
1215     fi
1216
1217     configdirs="${configdirs} gdbtk"
1218 fi
1219
1220 AC_SUBST(X_CFLAGS)
1221 AC_SUBST(X_LDFLAGS)
1222 AC_SUBST(X_LIBS)
1223 AC_SUBST(TCL_DEPS)
1224 AC_SUBST(TK_DEPS)
1225 AC_SUBST(ITCLLIB)
1226 AC_SUBST(ITCL_DEPS)
1227 AC_SUBST(ITKLIB)
1228 AC_SUBST(ITK_DEPS)
1229 AC_SUBST(GDBTKLIBS)
1230 AC_SUBST(GDBTK_CFLAGS)
1231 AC_SUBST(GDBTK_SRC_DIR)
1232
1233 AC_PATH_X
1234
1235
1236 # Unlike the sim directory, whether a simulator is linked is controlled by
1237 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1238 # This code just checks for a few cases where we'd like to ignore those
1239 # definitions, even when they're present in the '.mt' file.  These cases
1240 # are when --disable-sim is specified, or if the simulator directory is
1241 # not part of the source tree.
1242 #
1243 AC_ARG_ENABLE(sim,
1244 [  --enable-sim            Link gdb with simulator],
1245 [echo "enable_sim = $enable_sim";
1246  echo "enableval = ${enableval}";
1247  case "${enableval}" in
1248   yes) ignore_sim=false ;;
1249   no)  ignore_sim=true ;;
1250   *)   ignore_sim=false ;;
1251  esac],
1252 [ignore_sim=false])
1253
1254 if test ! -d "${srcdir}/../sim"; then
1255   ignore_sim=true
1256 fi
1257
1258 if test "${ignore_sim}" = "true"; then
1259     IGNORE_SIM="SIM="
1260     IGNORE_SIM_OBS="SIM_OBS="
1261 else
1262     IGNORE_SIM=""
1263     IGNORE_SIM_OBS=""
1264     AC_DEFINE(WITH_SIM)
1265 fi
1266 AC_SUBST(IGNORE_SIM)
1267 AC_SUBST(IGNORE_SIM_OBS)
1268
1269 AC_SUBST(ENABLE_CFLAGS)
1270 AC_SUBST(PROFILE_CFLAGS)
1271
1272 AC_SUBST(CONFIG_OBS)
1273 AC_SUBST(CONFIG_DEPS)
1274 AC_SUBST(CONFIG_SRCS)
1275 AC_SUBST(CONFIG_ALL)
1276 AC_SUBST(CONFIG_CLEAN)
1277 AC_SUBST(CONFIG_INSTALL)
1278 AC_SUBST(CONFIG_UNINSTALL)
1279
1280 # target_subdir is used by the testsuite to find the target libraries.
1281 target_subdir=
1282 if test "${host}" != "${target}"; then
1283     target_subdir="${target_alias}/"
1284 fi
1285 AC_SUBST(target_subdir)
1286
1287 frags=
1288 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1289 if test ! -f ${host_makefile_frag}; then
1290     # When building a native debuger the .mh file containing things
1291     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1292     # since it no longer contains anything useful.
1293     if test "${target}" = "${host}"; then
1294         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1295     else
1296         host_makefile_frag=/dev/null
1297     fi
1298 fi
1299 frags="$frags $host_makefile_frag"
1300
1301 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1302 if test ! -f ${target_makefile_frag}; then
1303 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1304 fi
1305 frags="$frags $target_makefile_frag"
1306
1307 AC_SUBST_FILE(host_makefile_frag)
1308 AC_SUBST_FILE(target_makefile_frag)
1309 AC_SUBST(frags)
1310
1311 changequote(,)dnl
1312 hostfile=`sed -n '
1313 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1314 ' ${host_makefile_frag}`
1315
1316 targetfile=`sed -n '
1317 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1318 ' ${target_makefile_frag}`
1319
1320 if test "${target}" = "${host}"; then
1321 # We pick this up from the host configuration file (.mh) because we
1322 # do not have a native configuration Makefile fragment.
1323 nativefile=`sed -n '
1324 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1325 ' ${host_makefile_frag}`
1326 fi
1327 changequote([,])
1328
1329 if test x"${gdb_osabi}" != x ; then
1330     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1331                        [Define to the default OS ABI for this configuration.])
1332 fi
1333
1334 # Enable multi-ice-gdb-server.
1335 AC_ARG_ENABLE(multi-ice,
1336 [  --enable-multi-ice      build the multi-ice-gdb-server],
1337   [case $enableval in
1338     yes | no)
1339       ;;
1340     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1341   esac])
1342 if test "x$enable_multi_ice" = xyes; then
1343   configdirs="$configdirs multi-ice"
1344 fi
1345
1346 # We only build gdbserver automatically if host and target are the same.
1347 if test "x$target" = "x$host"; then
1348   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1349   if test "x$build_gdbserver" = xyes; then
1350     configdirs="$configdirs gdbserver"
1351     AC_MSG_RESULT(yes)
1352   else
1353     AC_MSG_RESULT(no)
1354   fi
1355 fi
1356
1357 AC_CONFIG_SUBDIRS($configdirs)
1358
1359 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1360 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1361 # version.
1362
1363 files=
1364 links=
1365
1366 rm -f xm.h
1367 xm_h=""
1368 if test "${hostfile}" != ""; then
1369     xm_h=xm.h
1370     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1371     files="${files} ${GDB_XM_FILE}"
1372     links="${links} xm.h"
1373     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1374 fi
1375 AC_SUBST(xm_h)
1376
1377 rm -f tm.h
1378 tm_h=""
1379 if test "${targetfile}" != ""; then
1380     tm_h=tm.h
1381     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1382     files="${files} ${GDB_TM_FILE}"
1383     links="${links} tm.h"
1384     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1385 fi
1386 AC_SUBST(tm_h)
1387
1388 rm -f nm.h
1389 nm_h=""
1390 if test "${nativefile}" != ""; then
1391     nm_h=nm.h
1392     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1393     files="${files} ${GDB_NM_FILE}"
1394     links="${links} nm.h"
1395     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1396 fi
1397 AC_SUBST(nm_h)
1398
1399 AC_LINK_FILES($files, $links)
1400
1401 dnl Check for exe extension set on certain hosts (e.g. Win32)
1402 AC_EXEEXT
1403
1404 dnl  Detect the character set used by this host.
1405
1406 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1407 dnl  superset of ASCII containing the characters needed for French,
1408 dnl  German, Spanish, Italian, and possibly others), but if were
1409 dnl  *were* to support any host character sets other than ISO-8859-1,
1410 dnl  here's where we'd detect it.
1411 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1412           [Define to be a string naming the default host character set.])
1413
1414 AM_ICONV
1415
1416 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1417 [
1418 dnl Autoconf doesn't provide a mechanism for modifying definitions
1419 dnl provided by makefile fragments.
1420 dnl
1421 if test "${nativefile}" = ""; then
1422         < Makefile \
1423         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1424             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1425         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1426         > Makefile.tem
1427 mv -f Makefile.tem Makefile
1428 fi
1429
1430 changequote(,)dnl
1431 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1432 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1433 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1434 mv -f Makefile.tmp Makefile
1435 changequote([,])dnl
1436
1437
1438 case x$CONFIG_HEADERS in
1439 xconfig.h:config.in)
1440 echo > stamp-h ;;
1441 esac
1442 ],
1443 [
1444 gdb_host_cpu=$gdb_host_cpu
1445 gdb_target_cpu=$gdb_target_cpu
1446 nativefile=$nativefile
1447 ])
1448
1449 exit 0