gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40
  41 configdirs="doc testsuite"
  42
  43 dnl
  44 changequote(,)dnl
  45
  46 . ${srcdir}/configure.host
  47
  48 . ${srcdir}/configure.tgt
  49
  50 dnl
  51 changequote([,])dnl
  52
  53 AC_PROG_INSTALL
  54 AC_CHECK_TOOL(AR, ar)
  55 AC_CHECK_TOOL(RANLIB, ranlib, :)
  56 AC_PROG_YACC
  57 AC_PROG_AWK
  58
  59 AC_ARG_PROGRAM
  60
  61 AC_TYPE_SIGNAL
  62
  63 AC_HEADER_STDC
  64 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  65 AC_HEADER_STAT
  66
  67 AC_C_CONST
  68
  69 AC_CHECK_FUNCS(setpgid sbrk select poll)
  70
  71 # If we are configured native on Linux, work around problems with sys/procfs.h
  72 if test "${target}" = "${host}"; then
  73   case "${host}" in
  74   i[3456]86-*-linux*)
  75         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,"2")
  76         AC_DEFINE(sys_quotactl)
  77         ;;
  78   esac
  79 fi
  80
  81 AC_MSG_CHECKING([for gregset_t type])
  82 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  83 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  84 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  85 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  86 if test $gdb_cv_have_gregset_t = yes; then
  87   AC_DEFINE(HAVE_GREGSET_T)
  88 fi
  89
  90 AC_MSG_CHECKING([for fpregset_t type])
  91 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  92 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  93 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  94 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  95 if test $gdb_cv_have_fpregset_t = yes; then
  96   AC_DEFINE(HAVE_FPREGSET_T)
  97 fi
  98
  99 dnl See if host has libm.  This is usually needed by simulators.
 100 AC_CHECK_LIB(m, main)
 101
 102 dnl See if compiler supports "long long" type.
 103
 104 AC_MSG_CHECKING(for long long support in compiler)
 105 AC_CACHE_VAL(gdb_cv_c_long_long,
 106 [AC_TRY_COMPILE(, [
 107   extern long long foo;
 108   switch (foo & 2) { case 0: return 1; }
 109 ],
 110 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 111 AC_MSG_RESULT($gdb_cv_c_long_long)
 112 if test $gdb_cv_c_long_long = yes; then
 113   AC_DEFINE(CC_HAS_LONG_LONG)
 114 fi
 115
 116 dnl See if the compiler and runtime support printing long long
 117
 118 AC_MSG_CHECKING(for long long support in printf)
 119 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 120 [AC_TRY_RUN([
 121 int main () {
 122   char buf[16];
 123   long long l = 0x12345;
 124   sprintf (buf, "%llx", l);
 125   return (strcmp ("12345", buf));
 126 }],
 127 gdb_cv_printf_has_long_long=yes,
 128 gdb_cv_printf_has_long_long=no,
 129 gdb_cv_printf_has_long_long=no)])
 130 if test $gdb_cv_printf_has_long_long = yes; then
 131   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 132 fi
 133 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 134
 135 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 136 dnl because autoconf complains about cross-compilation issues.  However, this
 137 dnl code uses the same variables as the macro for compatibility.
 138
 139 AC_MSG_CHECKING(for long double support in compiler)
 140 AC_CACHE_VAL(ac_cv_c_long_double,
 141 [AC_TRY_COMPILE(, [long double foo;],
 142 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 143 AC_MSG_RESULT($ac_cv_c_long_double)
 144 if test $ac_cv_c_long_double = yes; then
 145   AC_DEFINE(HAVE_LONG_DOUBLE)
 146 fi
 147
 148 dnl See if the compiler and runtime support printing long doubles
 149
 150 AC_MSG_CHECKING(for long double support in printf)
 151 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 152 [AC_TRY_RUN([
 153 int main () {
 154   char buf[16];
 155   long double f = 3.141592653;
 156   sprintf (buf, "%Lg", f);
 157   return (strncmp ("3.14159", buf, 7));
 158 }],
 159 gdb_cv_printf_has_long_double=yes,
 160 gdb_cv_printf_has_long_double=no,
 161 gdb_cv_printf_has_long_double=no)])
 162 if test $gdb_cv_printf_has_long_double = yes; then
 163   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 164 fi
 165 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 166
 167 AC_FUNC_MMAP
 168
 169 BFD_NEED_DECLARATION(malloc)
 170 BFD_NEED_DECLARATION(realloc)
 171 BFD_NEED_DECLARATION(free)
 172
 173 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 174 dnl we must explicitly test for version 1 of the library because version 0
 175 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 176
 177 dnl Note that we only want this if we are both native (host == target), and
 178 dnl not doing a canadian cross build (build == host).
 179
 180 if test ${build} = ${host} -a ${host} = ${target} ; then
 181         case ${host_os} in
 182         hpux*)
 183                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 184                 if test -f /usr/include/dce/cma_config.h ; then
 185                         if test "$GCC" = "yes" ; then
 186                                 AC_MSG_RESULT(yes)
 187                                 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 188                                 CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 189                         else
 190                                 AC_MSG_RESULT(no (suppressed because you are not using GCC))
 191                         fi
 192                 else
 193                         AC_MSG_RESULT(no)
 194                 fi
 195                 ;;
 196         solaris*)
 197                 AC_MSG_CHECKING(for Solaris thread debugging library)
 198                 if test -f /usr/lib/libthread_db.so.1 ; then
 199                         AC_MSG_RESULT(yes)
 200                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 201                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 202                         AC_CHECK_LIB(dl, dlopen)
 203                         if test "$GCC" = "yes" ; then
 204                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 205                         fi
 206                 else
 207                         AC_MSG_RESULT(no)
 208                 fi
 209                 ;;
 210         esac
 211         AC_SUBST(CONFIG_LDFLAGS)
 212 fi
 213
 214 dnl Handle optional features that can be enabled.
 215 ENABLE_CFLAGS=
 216
 217 AC_ARG_ENABLE(netrom,
 218 [  --enable-netrom ],
 219 [case "${enableval}" in
 220 yes)    enable_netrom=yes ;;
 221 no)     enable_netrom=no ;;
 222 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 223 esac])
 224
 225 if test "${enable_netrom}" = "yes"; then
 226         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 227 fi
 228
 229 # start-sanitize-gm
 230 ENABLE_GM=
 231
 232 AC_ARG_ENABLE(gm,
 233 [  --enable-gm ],
 234 [case "${enableval}" in
 235 yes)    CONFIG_OBS="${CONFIG_OBS} gmagic.o"
 236         ENABLE_CFLAGS=-DGENERAL_MAGIC
 237         ;;
 238 no)     ;;
 239 *)      AC_MSG_ERROR(bad value ${enableval} given for gm option) ;;
 240 esac])
 241
 242 # end-sanitize-gm
 243
 244 # start-sanitize-gdbtk
 245 ENABLE_IDE=
 246 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 247 if test "$enable_ide" = yes; then
 248    enable_ide=yes
 249    ENABLE_IDE=1
 250 else
 251    enable_ide=no
 252 fi
 253 AC_SUBST(ENABLE_IDE)
 254
 255 ENABLE_GDBTK=
 256
 257 AC_ARG_ENABLE(gdbtk,
 258 [  --enable-gdbtk ],
 259 [case "${enableval}" in
 260     yes)
 261         case "$host" in
 262         *go32*)
 263             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 264             enable_gdbtk=no ;;
 265         *windows*)
 266             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 267             enable_gdbtk=no ;;
 268         *)
 269             enable_gdbtk=yes ;;
 270         esac ;;
 271     no)
 272         enable_gdbtk=no  ;;
 273     *)
 274         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 275 esac],
 276 [
 277 # Default is on for everything but go32 and cygwin32
 278 case "$host" in
 279     *go32* | *windows*)
 280         ;;
 281     *)
 282         enable_gdbtk=yes ;;
 283     esac
 284 ])
 285
 286 # In the cygwin32 environment, we need some additional flags.
 287 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 288 [AC_EGREP_CPP(lose, [
 289 #ifdef __CYGWIN32__
 290 lose
 291 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 292
 293 WIN32LIBS=
 294 WIN32LDAPP=
 295 AC_SUBST(WIN32LIBS)
 296 AC_SUBST(WIN32LDAPP)
 297
 298 if test x$gdb_cv_os_cygwin32 = xyes; then
 299     if test x$enable_ide = xyes; then
 300         WIN32LIBS="-ladvapi32"
 301     fi
 302 fi
 303
 304 configdir="unix"
 305
 306 if test "${enable_gdbtk}" = "yes"; then
 307
 308     CY_AC_PATH_TCLCONFIG
 309     if test -z "${no_tcl}"; then
 310         CY_AC_LOAD_TCLCONFIG
 311         CY_AC_PATH_TKCONFIG
 312
 313         # If $no_tk is nonempty, then we can't do Tk, and there is no
 314         # point to doing Tcl.
 315         if test -z "${no_tk}"; then
 316            CY_AC_LOAD_TKCONFIG
 317            CY_AC_PATH_TCLH
 318            CY_AC_PATH_TKH
 319            CY_AC_PATH_ITCLH
 320            CY_AC_PATH_TIX
 321
 322            # now look for tix library stuff
 323            TIXVERSION=4.1.8.0
 324            . ${ac_cv_c_tclconfig}/tclConfig.sh
 325            case "${host}" in
 326            *-*-cygwin32*)
 327                 tixdir=../tix/win/tcl8.0
 328                 ;;
 329            *)
 330                 tixdir=../tix/unix/tk8.0
 331                 ;;
 332            esac
 333            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 334                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 335            else
 336                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 337            fi
 338
 339            ENABLE_GDBTK=1
 340
 341            # Include some libraries that Tcl and Tk want.
 342            if test "${enable_ide}" = "yes"; then
 343               TCL_LIBS='$(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 344            else
 345               TCL_LIBS='$(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 346            fi
 347            # Yes, the ordering seems wrong here.  But it isn't.
 348            # TK_LIBS is the list of libraries that need to be linked
 349            # after Tcl/Tk.
 350            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 351            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 352
 353            if test x$gdb_cv_os_cygwin32 = xyes; then
 354               WIN32LIBS="${WIN32LIBS} -luser32"
 355               WIN32LDAPP="-Wl,--subsystem,windows"
 356            fi
 357         fi
 358     fi
 359 fi
 360
 361 AC_SUBST(ENABLE_GDBTK)
 362 AC_SUBST(X_CFLAGS)
 363 AC_SUBST(X_LDFLAGS)
 364 AC_SUBST(X_LIBS)
 365 AC_SUBST(TIXLIB)
 366 # end-sanitize-gdbtk
 367
 368 AC_SUBST(ENABLE_CFLAGS)
 369
 370 AC_SUBST(CONFIG_OBS)
 371
 372 # Begin stuff to support --enable-shared
 373 AC_ARG_ENABLE(shared,
 374 [  --enable-shared         use shared libraries],
 375 [case "${enableval}" in
 376   yes) shared=true ;;
 377   no)  shared=false ;;
 378   *) shared=true ;;
 379 esac])dnl
 380
 381 HLDFLAGS=
 382 HLDENV=
 383 # If we have shared libraries, try to set rpath reasonably.
 384 if test "${shared}" = "true"; then
 385   case "${host}" in
 386   *-*-hpux*)
 387     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 388     ;;
 389   *-*-irix5* | *-*-irix6*)
 390     HLDFLAGS='-Wl,-rpath,$(libdir)'
 391     ;;
 392   *-*-linux*aout*)
 393     ;;
 394   *-*-linux* | *-pc-linux-gnu)
 395     HLDFLAGS='-Wl,-rpath,$(libdir)'
 396     ;;
 397   *-*-solaris*)
 398     HLDFLAGS='-R $(libdir)'
 399     ;;
 400   *-*-sysv4*)
 401     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 402     ;;
 403   esac
 404 fi
 405
 406 # On SunOS, if the linker supports the -rpath option, use it to
 407 # prevent ../bfd and ../opcodes from being included in the run time
 408 # search path.
 409 case "${host}" in
 410   *-*-sunos*)
 411     echo 'main () { }' > conftest.c
 412     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 413     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 414       :
 415     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 416       :
 417     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 418       :
 419     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 420       :
 421     elif test "${shared}" = "true"; then
 422       HLDFLAGS='-Wl,-rpath=$(libdir)'
 423     else
 424       HLDFLAGS='-Wl,-rpath='
 425     fi
 426     rm -f conftest.t conftest.c conftest
 427     ;;
 428 esac
 429 AC_SUBST(HLDFLAGS)
 430 AC_SUBST(HLDENV)
 431 # End stuff to support --enable-shared
 432
 433 # target_subdir is used by the testsuite to find the target libraries.
 434 target_subdir=
 435 if test "${host}" != "${target}"; then
 436     target_subdir="${target_alias}/"
 437 fi
 438 AC_SUBST(target_subdir)
 439
 440 frags=
 441 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 442 if test ! -f ${host_makefile_frag}; then
 443 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 444 fi
 445 frags="$frags $host_makefile_frag"
 446
 447 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 448 if test ! -f ${target_makefile_frag}; then
 449 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 450 fi
 451 frags="$frags $target_makefile_frag"
 452
 453 AC_SUBST_FILE(host_makefile_frag)
 454 AC_SUBST_FILE(target_makefile_frag)
 455 AC_SUBST(frags)
 456
 457 changequote(,)dnl
 458 hostfile=`sed -n '
 459 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 460 ' ${host_makefile_frag}`
 461
 462 targetfile=`sed -n '
 463 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 464 ' ${target_makefile_frag}`
 465
 466 # these really aren't orthogonal true/false values of the same condition,
 467 # but shells are slow enough that I like to reuse the test conditions
 468 # whenever possible
 469 if test "${target}" = "${host}"; then
 470 nativefile=`sed -n '
 471 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 472 ' ${host_makefile_frag}`
 473 # else
 474 # GDBserver is only useful in a "native" enviroment
 475 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 476 fi
 477 changequote([,])
 478
 479 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 480 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 481 # corresponding links.  But we have to remove the xm.h files and tm.h
 482 # files anyway, e.g. when switching from "configure host" to
 483 # "configure none".
 484
 485 files=
 486 links=
 487 rm -f xm.h
 488 if test "${hostfile}" != ""; then
 489 files="${files} config/${gdb_host_cpu}/${hostfile}"
 490 links="${links} xm.h"
 491 fi
 492 rm -f tm.h
 493 if test "${targetfile}" != ""; then
 494 files="${files} config/${gdb_target_cpu}/${targetfile}"
 495 links="${links} tm.h"
 496 fi
 497 rm -f nm.h
 498 if test "${nativefile}" != ""; then
 499 files="${files} config/${gdb_host_cpu}/${nativefile}"
 500 links="${links} nm.h"
 501 else
 502 # A cross-only configuration.
 503 files="${files} config/nm-empty.h"
 504 links="${links} nm.h"
 505 fi
 506 # start-sanitize-gdbtk
 507 AC_PROG_LN_S
 508 # Make it possible to use the GUI without doing a full install
 509 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 510   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 511   echo linking $srcdir/gdbtcl to gdbtcl
 512   $LN_S $srcdir/gdbtcl gdbtcl
 513   else
 514   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 515   echo "         " make install before you are able to run the GUI.
 516   fi
 517 fi
 518 # end-sanitize-gdbtk
 519
 520 AC_LINK_FILES($files, $links)
 521
 522 AC_CONFIG_SUBDIRS($configdirs)
 523 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 524 [
 525 dnl Autoconf doesn't provide a mechanism for modifying definitions
 526 dnl provided by makefile fragments.
 527 dnl
 528 if test "${nativefile}" = ""; then
 529 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 530         < Makefile > Makefile.tem
 531 mv -f Makefile.tem Makefile
 532 fi
 533
 534 changequote(,)dnl
 535 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 536 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 537 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 538 mv -f Makefile.tmp Makefile
 539 changequote([,])dnl
 540
 541 case x$CONFIG_HEADERS in
 542 xconfig.h:config.in)
 543 echo > stamp-h ;;
 544 esac
 545 ],
 546 [
 547 gdb_host_cpu=$gdb_host_cpu
 548 gdb_target_cpu=$gdb_target_cpu
 549 nativefile=$nativefile
 550 ])
 551
 552 exit 0
 553