gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41
  42 configdirs="doc testsuite"
  43
  44 dnl
  45 changequote(,)dnl
  46
  47 . ${srcdir}/configure.host
  48
  49 . ${srcdir}/configure.tgt
  50
  51 dnl
  52 changequote([,])dnl
  53
  54 AC_PROG_INSTALL
  55 AC_CHECK_TOOL(AR, ar)
  56 AC_CHECK_TOOL(RANLIB, ranlib, :)
  57 AC_PROG_YACC
  58 AC_PROG_AWK
  59
  60 AC_ARG_PROGRAM
  61
  62 AC_TYPE_SIGNAL
  63
  64 AC_HEADER_STDC
  65 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  66 AC_HEADER_STAT
  67
  68 AC_C_CONST
  69
  70 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction)
  71
  72 # If we are configured native on Linux, work around problems with sys/procfs.h
  73 if test "${target}" = "${host}"; then
  74   case "${host}" in
  75   i[[3456]]86-*-linux*)
  76         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  77         AC_DEFINE(sys_quotactl)
  78         ;;
  79   esac
  80 fi
  81
  82 AC_MSG_CHECKING([for gregset_t type])
  83 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  84 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  85 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  86 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  87 if test $gdb_cv_have_gregset_t = yes; then
  88   AC_DEFINE(HAVE_GREGSET_T)
  89 fi
  90
  91 AC_MSG_CHECKING([for fpregset_t type])
  92 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  93 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  94 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  95 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  96 if test $gdb_cv_have_fpregset_t = yes; then
  97   AC_DEFINE(HAVE_FPREGSET_T)
  98 fi
  99
 100 dnl See if host has libm.  This is usually needed by simulators.
 101 AC_CHECK_LIB(m, main)
 102
 103 dnl See if compiler supports "long long" type.
 104
 105 AC_MSG_CHECKING(for long long support in compiler)
 106 AC_CACHE_VAL(gdb_cv_c_long_long,
 107 [AC_TRY_COMPILE(, [
 108   extern long long foo;
 109   switch (foo & 2) { case 0: return 1; }
 110 ],
 111 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 112 AC_MSG_RESULT($gdb_cv_c_long_long)
 113 if test $gdb_cv_c_long_long = yes; then
 114   AC_DEFINE(CC_HAS_LONG_LONG)
 115 fi
 116
 117 dnl See if the compiler and runtime support printing long long
 118
 119 AC_MSG_CHECKING(for long long support in printf)
 120 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 121 [AC_TRY_RUN([
 122 int main () {
 123   char buf[32];
 124   long long l = 0;
 125   l = (l << 16) + 0x0123;
 126   l = (l << 16) + 0x4567;
 127   l = (l << 16) + 0x89ab;
 128   l = (l << 16) + 0xcdef;
 129   sprintf (buf, "0x%016llx", l);
 130   return (strcmp ("0x0123456789abcdef", buf));
 131 }],
 132 gdb_cv_printf_has_long_long=yes,
 133 gdb_cv_printf_has_long_long=no,
 134 gdb_cv_printf_has_long_long=no)])
 135 if test $gdb_cv_printf_has_long_long = yes; then
 136   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 137 fi
 138 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 139
 140 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 141 dnl because autoconf complains about cross-compilation issues.  However, this
 142 dnl code uses the same variables as the macro for compatibility.
 143
 144 AC_MSG_CHECKING(for long double support in compiler)
 145 AC_CACHE_VAL(ac_cv_c_long_double,
 146 [AC_TRY_COMPILE(, [long double foo;],
 147 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 148 AC_MSG_RESULT($ac_cv_c_long_double)
 149 if test $ac_cv_c_long_double = yes; then
 150   AC_DEFINE(HAVE_LONG_DOUBLE)
 151 fi
 152
 153 dnl See if the compiler and runtime support printing long doubles
 154
 155 AC_MSG_CHECKING(for long double support in printf)
 156 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 157 [AC_TRY_RUN([
 158 int main () {
 159   char buf[16];
 160   long double f = 3.141592653;
 161   sprintf (buf, "%Lg", f);
 162   return (strncmp ("3.14159", buf, 7));
 163 }],
 164 gdb_cv_printf_has_long_double=yes,
 165 gdb_cv_printf_has_long_double=no,
 166 gdb_cv_printf_has_long_double=no)])
 167 if test $gdb_cv_printf_has_long_double = yes; then
 168   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 169 fi
 170 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 171
 172 dnl See if the compiler and runtime support scanning long doubles
 173
 174 AC_MSG_CHECKING(for long double support in scanf)
 175 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 176 [AC_TRY_RUN([
 177 int main () {
 178   char *buf = "3.141592653";
 179   long double f = 0;
 180   sscanf (buf, "%Lg", &f);
 181   return !(f > 3.14159 && f < 3.14160);
 182 }],
 183 gdb_cv_scanf_has_long_double=yes,
 184 gdb_cv_scanf_has_long_double=no,
 185 gdb_cv_scanf_has_long_double=no)])
 186 if test $gdb_cv_scanf_has_long_double = yes; then
 187   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 188 fi
 189 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 190
 191 AC_FUNC_MMAP
 192
 193 BFD_NEED_DECLARATION(malloc)
 194 BFD_NEED_DECLARATION(realloc)
 195 BFD_NEED_DECLARATION(free)
 196
 197 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 198 dnl we must explicitly test for version 1 of the library because version 0
 199 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 200
 201 dnl Note that we only want this if we are both native (host == target), and
 202 dnl not doing a canadian cross build (build == host).
 203
 204 if test ${build} = ${host} -a ${host} = ${target} ; then
 205         case ${host_os} in
 206         hpux*)
 207                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 208                 if test -f /usr/include/dce/cma_config.h ; then
 209                         if test "$GCC" = "yes" ; then
 210                                 AC_MSG_RESULT(yes)
 211                                 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 212                                 CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 213                         else
 214                                 AC_MSG_RESULT(no (suppressed because you are not using GCC))
 215                         fi
 216                 else
 217                         AC_MSG_RESULT(no)
 218                 fi
 219                 ;;
 220         solaris*)
 221                 AC_MSG_CHECKING(for Solaris thread debugging library)
 222                 if test -f /usr/lib/libthread_db.so.1 ; then
 223                         AC_MSG_RESULT(yes)
 224                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 225                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 226                         AC_CHECK_LIB(dl, dlopen)
 227                         if test "$GCC" = "yes" ; then
 228                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 229                         fi
 230                 else
 231                         AC_MSG_RESULT(no)
 232                 fi
 233                 ;;
 234         esac
 235         AC_SUBST(CONFIG_LDFLAGS)
 236 fi
 237
 238 dnl Handle optional features that can be enabled.
 239 ENABLE_CFLAGS=
 240
 241 AC_ARG_ENABLE(netrom,
 242 [  --enable-netrom ],
 243 [case "${enableval}" in
 244 yes)    enable_netrom=yes ;;
 245 no)     enable_netrom=no ;;
 246 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 247 esac])
 248
 249 if test "${enable_netrom}" = "yes"; then
 250         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 251 fi
 252
 253 MMALLOC_CFLAGS=
 254 MMALLOC=
 255 AC_SUBST(MMALLOC_CFLAGS)
 256 AC_SUBST(MMALLOC)
 257
 258 AC_ARG_WITH(mmalloc,
 259 [  --with-mmalloc             use memory mapped malloc package],
 260 [case "${withval}" in
 261   yes)  want_mmalloc=true ;;
 262   no)   want_mmalloc=false;;
 263   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 264 esac],[want_mmalloc=false])dnl
 265
 266 if test x$want_mmalloc = xtrue; then
 267    AC_DEFINE(USE_MMALLOC)
 268    AC_DEFINE(FORCE_MMCHECK)
 269    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 270    MMALLOC='../mmalloc/libmmalloc.a'
 271 fi
 272
 273 # start-sanitize-gdbtk
 274 ENABLE_IDE=
 275 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 276 if test "$enable_ide" = yes; then
 277    enable_ide=yes
 278    ENABLE_IDE=1
 279 else
 280    enable_ide=no
 281 fi
 282 AC_SUBST(ENABLE_IDE)
 283
 284 ENABLE_GDBTK=
 285
 286 AC_ARG_ENABLE(gdbtk,
 287 [  --enable-gdbtk ],
 288 [case "${enableval}" in
 289     yes)
 290         case "$host" in
 291         *go32*)
 292             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 293             enable_gdbtk=no ;;
 294         *windows*)
 295             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 296             enable_gdbtk=no ;;
 297         *)
 298             enable_gdbtk=yes ;;
 299         esac ;;
 300     no)
 301         enable_gdbtk=no  ;;
 302     *)
 303         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 304 esac],
 305 [
 306 # Default is on for everything but go32 and cygwin32
 307 case "$host" in
 308     *go32* | *windows*)
 309         ;;
 310     *)
 311         enable_gdbtk=yes ;;
 312     esac
 313 ])
 314
 315 # In the cygwin32 environment, we need some additional flags.
 316 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 317 [AC_EGREP_CPP(lose, [
 318 #ifdef __CYGWIN32__
 319 lose
 320 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 321
 322 WIN32LIBS=
 323 WIN32LDAPP=
 324 AC_SUBST(WIN32LIBS)
 325 AC_SUBST(WIN32LDAPP)
 326
 327 if test x$gdb_cv_os_cygwin32 = xyes; then
 328     if test x$enable_ide = xyes; then
 329         WIN32LIBS="-ladvapi32"
 330     fi
 331 fi
 332
 333 configdir="unix"
 334
 335 if test "${enable_gdbtk}" = "yes"; then
 336
 337     CY_AC_PATH_TCLCONFIG
 338     if test -z "${no_tcl}"; then
 339         CY_AC_LOAD_TCLCONFIG
 340         CY_AC_PATH_TKCONFIG
 341
 342         # If $no_tk is nonempty, then we can't do Tk, and there is no
 343         # point to doing Tcl.
 344         if test -z "${no_tk}"; then
 345            CY_AC_LOAD_TKCONFIG
 346            CY_AC_PATH_TCLH
 347            CY_AC_PATH_TKH
 348            CY_AC_PATH_ITCLH
 349            CY_AC_PATH_TIX
 350
 351            # now look for tix library stuff
 352            TIXVERSION=4.1.8.0
 353            . ${ac_cv_c_tclconfig}/tclConfig.sh
 354            case "${host}" in
 355            *-*-cygwin32*)
 356                 tixdir=../tix/win/tcl8.0
 357                 ;;
 358            *)
 359                 tixdir=../tix/unix/tk8.0
 360                 ;;
 361            esac
 362            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 363                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 364                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}.a"
 365            else
 366                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 367                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`.a"
 368            fi
 369
 370            ENABLE_GDBTK=1
 371
 372            # Include some libraries that Tcl and Tk want.
 373            if test "${enable_ide}" = "yes"; then
 374               TCL_LIBS='$(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 375               CONFIG_DEPS='$(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 376            else
 377               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 378               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 379            fi
 380            # Yes, the ordering seems wrong here.  But it isn't.
 381            # TK_LIBS is the list of libraries that need to be linked
 382            # after Tcl/Tk.
 383            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 384            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 385
 386            if test x$gdb_cv_os_cygwin32 = xyes; then
 387               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 388               WIN32LDAPP="-Wl,--subsystem,windows"
 389            fi
 390         fi
 391     fi
 392 fi
 393
 394 AC_SUBST(ENABLE_GDBTK)
 395 AC_SUBST(X_CFLAGS)
 396 AC_SUBST(X_LDFLAGS)
 397 AC_SUBST(X_LIBS)
 398 AC_SUBST(TIXLIB)
 399 AC_SUBST(TIX_DEPS)
 400 # end-sanitize-gdbtk
 401
 402 AC_SUBST(ENABLE_CFLAGS)
 403
 404 AC_SUBST(CONFIG_OBS)
 405 AC_SUBST(CONFIG_DEPS)
 406
 407 # Begin stuff to support --enable-shared
 408 AC_ARG_ENABLE(shared,
 409 [  --enable-shared         use shared libraries],
 410 [case "${enableval}" in
 411   yes) shared=true ;;
 412   no)  shared=false ;;
 413   *) shared=true ;;
 414 esac])dnl
 415
 416 HLDFLAGS=
 417 HLDENV=
 418 # If we have shared libraries, try to set rpath reasonably.
 419 if test "${shared}" = "true"; then
 420   case "${host}" in
 421   *-*-hpux*)
 422     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 423     ;;
 424   *-*-irix5* | *-*-irix6*)
 425     HLDFLAGS='-Wl,-rpath,$(libdir)'
 426     ;;
 427   *-*-linux*aout*)
 428     ;;
 429   *-*-linux* | *-pc-linux-gnu)
 430     HLDFLAGS='-Wl,-rpath,$(libdir)'
 431     ;;
 432   *-*-solaris*)
 433     HLDFLAGS='-R $(libdir)'
 434     ;;
 435   *-*-sysv4*)
 436     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 437     ;;
 438   esac
 439 fi
 440
 441 # On SunOS, if the linker supports the -rpath option, use it to
 442 # prevent ../bfd and ../opcodes from being included in the run time
 443 # search path.
 444 case "${host}" in
 445   *-*-sunos*)
 446     echo 'main () { }' > conftest.c
 447     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 448     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 449       :
 450     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 451       :
 452     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 453       :
 454     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 455       :
 456     elif test "${shared}" = "true"; then
 457       HLDFLAGS='-Wl,-rpath=$(libdir)'
 458     else
 459       HLDFLAGS='-Wl,-rpath='
 460     fi
 461     rm -f conftest.t conftest.c conftest
 462     ;;
 463 esac
 464 AC_SUBST(HLDFLAGS)
 465 AC_SUBST(HLDENV)
 466 # End stuff to support --enable-shared
 467
 468 # target_subdir is used by the testsuite to find the target libraries.
 469 target_subdir=
 470 if test "${host}" != "${target}"; then
 471     target_subdir="${target_alias}/"
 472 fi
 473 AC_SUBST(target_subdir)
 474
 475 frags=
 476 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 477 if test ! -f ${host_makefile_frag}; then
 478 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 479 fi
 480 frags="$frags $host_makefile_frag"
 481
 482 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 483 if test ! -f ${target_makefile_frag}; then
 484 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 485 fi
 486 frags="$frags $target_makefile_frag"
 487
 488 AC_SUBST_FILE(host_makefile_frag)
 489 AC_SUBST_FILE(target_makefile_frag)
 490 AC_SUBST(frags)
 491
 492 changequote(,)dnl
 493 hostfile=`sed -n '
 494 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 495 ' ${host_makefile_frag}`
 496
 497 targetfile=`sed -n '
 498 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 499 ' ${target_makefile_frag}`
 500
 501 # these really aren't orthogonal true/false values of the same condition,
 502 # but shells are slow enough that I like to reuse the test conditions
 503 # whenever possible
 504 if test "${target}" = "${host}"; then
 505 nativefile=`sed -n '
 506 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 507 ' ${host_makefile_frag}`
 508 # else
 509 # GDBserver is only useful in a "native" enviroment
 510 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 511 fi
 512 changequote([,])
 513
 514 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 515 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 516 # corresponding links.  But we have to remove the xm.h files and tm.h
 517 # files anyway, e.g. when switching from "configure host" to
 518 # "configure none".
 519
 520 files=
 521 links=
 522 rm -f xm.h
 523 if test "${hostfile}" != ""; then
 524 files="${files} config/${gdb_host_cpu}/${hostfile}"
 525 links="${links} xm.h"
 526 fi
 527 rm -f tm.h
 528 if test "${targetfile}" != ""; then
 529 files="${files} config/${gdb_target_cpu}/${targetfile}"
 530 links="${links} tm.h"
 531 fi
 532 rm -f nm.h
 533 if test "${nativefile}" != ""; then
 534 files="${files} config/${gdb_host_cpu}/${nativefile}"
 535 links="${links} nm.h"
 536 else
 537 # A cross-only configuration.
 538 files="${files} config/nm-empty.h"
 539 links="${links} nm.h"
 540 fi
 541 # start-sanitize-gdbtk
 542 AC_PROG_LN_S
 543 # Make it possible to use the GUI without doing a full install
 544 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 545   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 546   echo linking $srcdir/gdbtcl to gdbtcl
 547   $LN_S $srcdir/gdbtcl gdbtcl
 548   else
 549   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 550   echo "         " make install before you are able to run the GUI.
 551   fi
 552 fi
 553 # end-sanitize-gdbtk
 554
 555 AC_LINK_FILES($files, $links)
 556
 557 dnl Check for exe extension set on certain hosts (e.g. Win32)
 558 AM_EXEEXT
 559
 560 AC_CONFIG_SUBDIRS($configdirs)
 561 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 562 [
 563 dnl Autoconf doesn't provide a mechanism for modifying definitions
 564 dnl provided by makefile fragments.
 565 dnl
 566 if test "${nativefile}" = ""; then
 567 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 568         < Makefile > Makefile.tem
 569 mv -f Makefile.tem Makefile
 570 fi
 571
 572 changequote(,)dnl
 573 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 574 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 575 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 576 mv -f Makefile.tmp Makefile
 577 changequote([,])dnl
 578
 579 case x$CONFIG_HEADERS in
 580 xconfig.h:config.in)
 581 echo > stamp-h ;;
 582 esac
 583 ],
 584 [
 585 gdb_host_cpu=$gdb_host_cpu
 586 gdb_target_cpu=$gdb_target_cpu
 587 nativefile=$nativefile
 588 ])
 589
 590 exit 0
 591