gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41
  42 configdirs="doc testsuite"
  43
  44 dnl
  45 changequote(,)dnl
  46
  47 . ${srcdir}/configure.host
  48
  49 . ${srcdir}/configure.tgt
  50
  51 dnl
  52 changequote([,])dnl
  53
  54 AC_PROG_INSTALL
  55 AC_CHECK_TOOL(AR, ar)
  56 AC_CHECK_TOOL(RANLIB, ranlib, :)
  57 AC_PROG_YACC
  58 AC_PROG_AWK
  59
  60 AC_ARG_PROGRAM
  61
  62 AC_TYPE_SIGNAL
  63
  64 AC_HEADER_STDC
  65 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  66 AC_HEADER_STAT
  67
  68 AC_C_CONST
  69
  70 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction)
  71
  72 # If we are configured native on Linux, work around problems with sys/procfs.h
  73 if test "${target}" = "${host}"; then
  74   case "${host}" in
  75   i[[3456]]86-*-linux*)
  76         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  77         AC_DEFINE(sys_quotactl)
  78         ;;
  79   esac
  80 fi
  81
  82 AC_MSG_CHECKING([for gregset_t type])
  83 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  84 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  85 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  86 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  87 if test $gdb_cv_have_gregset_t = yes; then
  88   AC_DEFINE(HAVE_GREGSET_T)
  89 fi
  90
  91 AC_MSG_CHECKING([for fpregset_t type])
  92 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  93 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  94 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  95 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  96 if test $gdb_cv_have_fpregset_t = yes; then
  97   AC_DEFINE(HAVE_FPREGSET_T)
  98 fi
  99
 100 dnl See if host has libm.  This is usually needed by simulators.
 101 AC_CHECK_LIB(m, main)
 102
 103 dnl See if compiler supports "long long" type.
 104
 105 AC_MSG_CHECKING(for long long support in compiler)
 106 AC_CACHE_VAL(gdb_cv_c_long_long,
 107 [AC_TRY_COMPILE(, [
 108   extern long long foo;
 109   switch (foo & 2) { case 0: return 1; }
 110 ],
 111 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 112 AC_MSG_RESULT($gdb_cv_c_long_long)
 113 if test $gdb_cv_c_long_long = yes; then
 114   AC_DEFINE(CC_HAS_LONG_LONG)
 115 fi
 116
 117 dnl See if the compiler and runtime support printing long long
 118
 119 AC_MSG_CHECKING(for long long support in printf)
 120 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 121 [AC_TRY_RUN([
 122 int main () {
 123   char buf[32];
 124   long long l = 0;
 125   l = (l << 16) + 0x0123;
 126   l = (l << 16) + 0x4567;
 127   l = (l << 16) + 0x89ab;
 128   l = (l << 16) + 0xcdef;
 129   sprintf (buf, "0x%016llx", l);
 130   return (strcmp ("0x0123456789abcdef", buf));
 131 }],
 132 gdb_cv_printf_has_long_long=yes,
 133 gdb_cv_printf_has_long_long=no,
 134 gdb_cv_printf_has_long_long=no)])
 135 if test $gdb_cv_printf_has_long_long = yes; then
 136   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 137 fi
 138 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 139
 140 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 141 dnl because autoconf complains about cross-compilation issues.  However, this
 142 dnl code uses the same variables as the macro for compatibility.
 143
 144 AC_MSG_CHECKING(for long double support in compiler)
 145 AC_CACHE_VAL(ac_cv_c_long_double,
 146 [AC_TRY_COMPILE(, [long double foo;],
 147 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 148 AC_MSG_RESULT($ac_cv_c_long_double)
 149 if test $ac_cv_c_long_double = yes; then
 150   AC_DEFINE(HAVE_LONG_DOUBLE)
 151 fi
 152
 153 dnl See if the compiler and runtime support printing long doubles
 154
 155 AC_MSG_CHECKING(for long double support in printf)
 156 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 157 [AC_TRY_RUN([
 158 int main () {
 159   char buf[16];
 160   long double f = 3.141592653;
 161   sprintf (buf, "%Lg", f);
 162   return (strncmp ("3.14159", buf, 7));
 163 }],
 164 gdb_cv_printf_has_long_double=yes,
 165 gdb_cv_printf_has_long_double=no,
 166 gdb_cv_printf_has_long_double=no)])
 167 if test $gdb_cv_printf_has_long_double = yes; then
 168   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 169 fi
 170 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 171
 172 dnl See if the compiler and runtime support scanning long doubles
 173
 174 AC_MSG_CHECKING(for long double support in scanf)
 175 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 176 [AC_TRY_RUN([
 177 int main () {
 178   char *buf = "3.141592653";
 179   long double f = 0;
 180   sscanf (buf, "%Lg", &f);
 181   return !(f > 3.14159 && f < 3.14160);
 182 }],
 183 gdb_cv_scanf_has_long_double=yes,
 184 gdb_cv_scanf_has_long_double=no,
 185 gdb_cv_scanf_has_long_double=no)])
 186 if test $gdb_cv_scanf_has_long_double = yes; then
 187   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 188 fi
 189 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 190
 191 AC_FUNC_MMAP
 192
 193 BFD_NEED_DECLARATION(malloc)
 194 BFD_NEED_DECLARATION(realloc)
 195 BFD_NEED_DECLARATION(free)
 196
 197 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 198 dnl we must explicitly test for version 1 of the library because version 0
 199 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 200
 201 dnl Note that we only want this if we are both native (host == target), and
 202 dnl not doing a canadian cross build (build == host).
 203
 204 if test ${build} = ${host} -a ${host} = ${target} ; then
 205    case ${host_os} in
 206    hpux*)
 207       AC_MSG_CHECKING(for HPUX/OSF thread support)
 208       if test -f /usr/include/dce/cma_config.h ; then
 209          if test "$GCC" = "yes" ; then
 210             AC_MSG_RESULT(yes)
 211             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 212             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 213          else
 214             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 215          fi
 216       else
 217          AC_MSG_RESULT(no)
 218       fi
 219       ;;
 220    solaris*)
 221       AC_MSG_CHECKING(for Solaris thread debugging library)
 222       if test -f /usr/lib/libthread_db.so.1 ; then
 223          AC_MSG_RESULT(yes)
 224          AC_DEFINE(HAVE_THREAD_DB_LIB)
 225          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 226          AC_CHECK_LIB(dl, dlopen)
 227          if test "$GCC" = "yes" ; then
 228             # The GNU linker requires the -export-dynamic option to make
 229             # all symbols visible in the dynamic symbol table.
 230             hold_ldflags=$LDFLAGS
 231             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 232             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 233             AC_TRY_LINK(, [int i;], found=yes, found=no)
 234             LDFLAGS=$hold_ldflags
 235             AC_MSG_RESULT($found)
 236             if test $found = yes; then
 237                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 238             fi
 239          fi
 240       else
 241          AC_MSG_RESULT(no)
 242       fi
 243       ;;
 244    esac
 245    AC_SUBST(CONFIG_LDFLAGS)
 246 fi
 247
 248 dnl Handle optional features that can be enabled.
 249 ENABLE_CFLAGS=
 250
 251 AC_ARG_ENABLE(netrom,
 252 [  --enable-netrom ],
 253 [case "${enableval}" in
 254 yes)    enable_netrom=yes ;;
 255 no)     enable_netrom=no ;;
 256 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 257 esac])
 258
 259 if test "${enable_netrom}" = "yes"; then
 260         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 261 fi
 262
 263 MMALLOC_CFLAGS=
 264 MMALLOC=
 265 AC_SUBST(MMALLOC_CFLAGS)
 266 AC_SUBST(MMALLOC)
 267
 268 AC_ARG_WITH(mmalloc,
 269 [  --with-mmalloc             use memory mapped malloc package],
 270 [case "${withval}" in
 271   yes)  want_mmalloc=true ;;
 272   no)   want_mmalloc=false;;
 273   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 274 esac],[want_mmalloc=false])dnl
 275
 276 if test x$want_mmalloc = xtrue; then
 277    AC_DEFINE(USE_MMALLOC)
 278    AC_DEFINE(FORCE_MMCHECK)
 279    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 280    MMALLOC='../mmalloc/libmmalloc.a'
 281 fi
 282
 283 # start-sanitize-gdbtk
 284 ENABLE_IDE=
 285 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 286 if test "$enable_ide" = yes; then
 287    enable_ide=yes
 288    ENABLE_IDE=1
 289 else
 290    enable_ide=no
 291 fi
 292 AC_SUBST(ENABLE_IDE)
 293
 294 ENABLE_GDBTK=
 295
 296 AC_ARG_ENABLE(gdbtk,
 297 [  --enable-gdbtk ],
 298 [case "${enableval}" in
 299     yes)
 300         case "$host" in
 301         *go32*)
 302             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 303             enable_gdbtk=no ;;
 304         *windows*)
 305             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 306             enable_gdbtk=no ;;
 307         *)
 308             enable_gdbtk=yes ;;
 309         esac ;;
 310     no)
 311         enable_gdbtk=no  ;;
 312     *)
 313         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 314 esac],
 315 [
 316 # Default is on for everything but go32 and cygwin32
 317 case "$host" in
 318     *go32* | *windows*)
 319         ;;
 320     *)
 321         enable_gdbtk=yes ;;
 322     esac
 323 ])
 324
 325 # In the cygwin32 environment, we need some additional flags.
 326 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 327 [AC_EGREP_CPP(lose, [
 328 #ifdef __CYGWIN32__
 329 lose
 330 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 331
 332 WIN32LIBS=
 333 WIN32LDAPP=
 334 AC_SUBST(WIN32LIBS)
 335 AC_SUBST(WIN32LDAPP)
 336
 337 if test x$gdb_cv_os_cygwin32 = xyes; then
 338     if test x$enable_ide = xyes; then
 339         WIN32LIBS="-ladvapi32"
 340     fi
 341 fi
 342
 343 configdir="unix"
 344
 345 if test "${enable_gdbtk}" = "yes"; then
 346
 347     CY_AC_PATH_TCLCONFIG
 348     if test -z "${no_tcl}"; then
 349         CY_AC_LOAD_TCLCONFIG
 350         CY_AC_PATH_TKCONFIG
 351
 352         # If $no_tk is nonempty, then we can't do Tk, and there is no
 353         # point to doing Tcl.
 354         if test -z "${no_tk}"; then
 355            CY_AC_LOAD_TKCONFIG
 356            CY_AC_PATH_TCLH
 357            CY_AC_PATH_TKH
 358            CY_AC_PATH_ITCLH
 359            CY_AC_PATH_TIX
 360
 361            # now look for tix library stuff
 362            TIXVERSION=4.1.8.0
 363            . ${ac_cv_c_tclconfig}/tclConfig.sh
 364            case "${host}" in
 365            *-*-cygwin32*)
 366                 tixdir=../tix/win/tcl8.0
 367                 ;;
 368            *)
 369                 tixdir=../tix/unix/tk8.0
 370                 ;;
 371            esac
 372            if test "${TCL_SHARED_BUILD}" = "1"; then
 373                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 374
 375                 # Can't win them all: SunOS 4 (others?) appends a version
 376                 # number after the ".so"
 377                 case "${host}" in
 378                 *-*-sunos4*)
 379                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 380                 esac
 381
 382            else
 383                 TIX_LIB_EXT=".a"
 384            fi
 385
 386            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 387                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 388                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 389            else
 390                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 391                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 392            fi
 393
 394            ENABLE_GDBTK=1
 395
 396            # Include some libraries that Tcl and Tk want.
 397            if test "${enable_ide}" = "yes"; then
 398               TCL_LIBS='$(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 399               CONFIG_DEPS='$(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 400            else
 401               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 402               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 403            fi
 404            # Yes, the ordering seems wrong here.  But it isn't.
 405            # TK_LIBS is the list of libraries that need to be linked
 406            # after Tcl/Tk.
 407            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 408            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 409
 410            if test x$gdb_cv_os_cygwin32 = xyes; then
 411               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 412               WIN32LDAPP="-Wl,--subsystem,windows"
 413            fi
 414         fi
 415     fi
 416 fi
 417
 418 AC_SUBST(ENABLE_GDBTK)
 419 AC_SUBST(X_CFLAGS)
 420 AC_SUBST(X_LDFLAGS)
 421 AC_SUBST(X_LIBS)
 422 AC_SUBST(TIXLIB)
 423 AC_SUBST(TIX_DEPS)
 424 # end-sanitize-gdbtk
 425
 426 AC_SUBST(ENABLE_CFLAGS)
 427
 428 AC_SUBST(CONFIG_OBS)
 429 AC_SUBST(CONFIG_DEPS)
 430
 431 # Begin stuff to support --enable-shared
 432 AC_ARG_ENABLE(shared,
 433 [  --enable-shared         use shared libraries],
 434 [case "${enableval}" in
 435   yes) shared=true ;;
 436   no)  shared=false ;;
 437   *) shared=true ;;
 438 esac])dnl
 439
 440 HLDFLAGS=
 441 HLDENV=
 442 # If we have shared libraries, try to set rpath reasonably.
 443 if test "${shared}" = "true"; then
 444   case "${host}" in
 445   *-*-hpux*)
 446     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 447     ;;
 448   *-*-irix5* | *-*-irix6*)
 449     HLDFLAGS='-Wl,-rpath,$(libdir)'
 450     ;;
 451   *-*-linux*aout*)
 452     ;;
 453   *-*-linux* | *-pc-linux-gnu)
 454     HLDFLAGS='-Wl,-rpath,$(libdir)'
 455     ;;
 456   *-*-solaris*)
 457     HLDFLAGS='-R $(libdir)'
 458     ;;
 459   *-*-sysv4*)
 460     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 461     ;;
 462   esac
 463 fi
 464
 465 # On SunOS, if the linker supports the -rpath option, use it to
 466 # prevent ../bfd and ../opcodes from being included in the run time
 467 # search path.
 468 case "${host}" in
 469   *-*-sunos*)
 470     echo 'main () { }' > conftest.c
 471     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 472     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 473       :
 474     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 475       :
 476     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 477       :
 478     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 479       :
 480     elif test "${shared}" = "true"; then
 481       HLDFLAGS='-Wl,-rpath=$(libdir)'
 482     else
 483       HLDFLAGS='-Wl,-rpath='
 484     fi
 485     rm -f conftest.t conftest.c conftest
 486     ;;
 487 esac
 488 AC_SUBST(HLDFLAGS)
 489 AC_SUBST(HLDENV)
 490 # End stuff to support --enable-shared
 491
 492 # target_subdir is used by the testsuite to find the target libraries.
 493 target_subdir=
 494 if test "${host}" != "${target}"; then
 495     target_subdir="${target_alias}/"
 496 fi
 497 AC_SUBST(target_subdir)
 498
 499 frags=
 500 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 501 if test ! -f ${host_makefile_frag}; then
 502 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 503 fi
 504 frags="$frags $host_makefile_frag"
 505
 506 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 507 if test ! -f ${target_makefile_frag}; then
 508 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 509 fi
 510 frags="$frags $target_makefile_frag"
 511
 512 AC_SUBST_FILE(host_makefile_frag)
 513 AC_SUBST_FILE(target_makefile_frag)
 514 AC_SUBST(frags)
 515
 516 changequote(,)dnl
 517 hostfile=`sed -n '
 518 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 519 ' ${host_makefile_frag}`
 520
 521 targetfile=`sed -n '
 522 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 523 ' ${target_makefile_frag}`
 524
 525 # these really aren't orthogonal true/false values of the same condition,
 526 # but shells are slow enough that I like to reuse the test conditions
 527 # whenever possible
 528 if test "${target}" = "${host}"; then
 529 nativefile=`sed -n '
 530 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 531 ' ${host_makefile_frag}`
 532 # else
 533 # GDBserver is only useful in a "native" enviroment
 534 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 535 fi
 536 changequote([,])
 537
 538 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 539 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 540 # corresponding links.  But we have to remove the xm.h files and tm.h
 541 # files anyway, e.g. when switching from "configure host" to
 542 # "configure none".
 543
 544 files=
 545 links=
 546 rm -f xm.h
 547 if test "${hostfile}" != ""; then
 548 files="${files} config/${gdb_host_cpu}/${hostfile}"
 549 links="${links} xm.h"
 550 fi
 551 rm -f tm.h
 552 if test "${targetfile}" != ""; then
 553 files="${files} config/${gdb_target_cpu}/${targetfile}"
 554 links="${links} tm.h"
 555 fi
 556 rm -f nm.h
 557 if test "${nativefile}" != ""; then
 558 files="${files} config/${gdb_host_cpu}/${nativefile}"
 559 links="${links} nm.h"
 560 else
 561 # A cross-only configuration.
 562 files="${files} config/nm-empty.h"
 563 links="${links} nm.h"
 564 fi
 565 # start-sanitize-gdbtk
 566 AC_PROG_LN_S
 567 # Make it possible to use the GUI without doing a full install
 568 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 569   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 570   echo linking $srcdir/gdbtcl to gdbtcl
 571   $LN_S $srcdir/gdbtcl gdbtcl
 572   else
 573   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 574   echo "         " make install before you are able to run the GUI.
 575   fi
 576 fi
 577 # end-sanitize-gdbtk
 578
 579 AC_LINK_FILES($files, $links)
 580
 581 dnl Check for exe extension set on certain hosts (e.g. Win32)
 582 AM_EXEEXT
 583
 584 AC_CONFIG_SUBDIRS($configdirs)
 585 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 586 [
 587 dnl Autoconf doesn't provide a mechanism for modifying definitions
 588 dnl provided by makefile fragments.
 589 dnl
 590 if test "${nativefile}" = ""; then
 591 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 592         < Makefile > Makefile.tem
 593 mv -f Makefile.tem Makefile
 594 fi
 595
 596 changequote(,)dnl
 597 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 598 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 599 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 600 mv -f Makefile.tmp Makefile
 601 changequote([,])dnl
 602
 603 case x$CONFIG_HEADERS in
 604 xconfig.h:config.in)
 605 echo > stamp-h ;;
 606 esac
 607 ],
 608 [
 609 gdb_host_cpu=$gdb_host_cpu
 610 gdb_target_cpu=$gdb_target_cpu
 611 nativefile=$nativefile
 612 ])
 613
 614 exit 0
 615