gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40
  41 configdirs="doc testsuite"
  42
  43 dnl
  44 changequote(,)dnl
  45
  46 . ${srcdir}/configure.host
  47
  48 . ${srcdir}/configure.tgt
  49
  50 dnl
  51 changequote([,])dnl
  52
  53 AC_PROG_INSTALL
  54 AC_CHECK_TOOL(AR, ar)
  55 AC_CHECK_TOOL(RANLIB, ranlib, :)
  56 AC_PROG_YACC
  57 AC_PROG_AWK
  58
  59 AC_ARG_PROGRAM
  60
  61 AC_TYPE_SIGNAL
  62
  63 AC_HEADER_STDC
  64 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  65 AC_HEADER_STAT
  66
  67 AC_C_CONST
  68
  69 AC_CHECK_FUNCS(setpgid sbrk select poll)
  70
  71 # If we are configured native on Linux, work around problems with sys/procfs.h
  72 if test "${target}" = "${host}"; then
  73   case "${host}" in
  74   i[3456]86-*-linux*)
  75         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,"2")
  76         AC_DEFINE(sys_quotactl)
  77         ;;
  78   esac
  79 fi
  80
  81 AC_MSG_CHECKING([for gregset_t type])
  82 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  83 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  84 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  85 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  86 if test $gdb_cv_have_gregset_t = yes; then
  87   AC_DEFINE(HAVE_GREGSET_T)
  88 fi
  89
  90 AC_MSG_CHECKING([for fpregset_t type])
  91 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  92 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  93 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  94 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  95 if test $gdb_cv_have_fpregset_t = yes; then
  96   AC_DEFINE(HAVE_FPREGSET_T)
  97 fi
  98
  99 dnl See if host has libm.  This is usually needed by simulators.
 100 AC_CHECK_LIB(m, main)
 101
 102 dnl See if compiler supports "long long" type.
 103
 104 AC_MSG_CHECKING(for long long support in compiler)
 105 AC_CACHE_VAL(gdb_cv_c_long_long,
 106 [AC_TRY_COMPILE(, [
 107   extern long long foo;
 108   switch (foo & 2) { case 0: return 1; }
 109 ],
 110 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 111 AC_MSG_RESULT($gdb_cv_c_long_long)
 112 if test $gdb_cv_c_long_long = yes; then
 113   AC_DEFINE(CC_HAS_LONG_LONG)
 114 fi
 115
 116 dnl See if the compiler and runtime support printing long long
 117
 118 AC_MSG_CHECKING(for long long support in printf)
 119 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 120 [AC_TRY_RUN([
 121 int main () {
 122   char buf[16];
 123   long long l = 0x12345;
 124   sprintf (buf, "%llx", l);
 125   return (strcmp ("12345", buf));
 126 }],
 127 gdb_cv_printf_has_long_long=yes,
 128 gdb_cv_printf_has_long_long=no,
 129 gdb_cv_printf_has_long_long=no)])
 130 if test $gdb_cv_printf_has_long_long = yes; then
 131   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 132 fi
 133 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 134
 135 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 136 dnl because autoconf complains about cross-compilation issues.  However, this
 137 dnl code uses the same variables as the macro for compatibility.
 138
 139 AC_MSG_CHECKING(for long double support in compiler)
 140 AC_CACHE_VAL(ac_cv_c_long_double,
 141 [AC_TRY_COMPILE(, [long double foo;],
 142 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 143 AC_MSG_RESULT($ac_cv_c_long_double)
 144 if test $ac_cv_c_long_double = yes; then
 145   AC_DEFINE(HAVE_LONG_DOUBLE)
 146 fi
 147
 148 dnl See if the compiler and runtime support printing long doubles
 149
 150 AC_MSG_CHECKING(for long double support in printf)
 151 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 152 [AC_TRY_RUN([
 153 int main () {
 154   char buf[16];
 155   long double f = 3.141592653;
 156   sprintf (buf, "%Lg", f);
 157   return (strncmp ("3.14159", buf, 7));
 158 }],
 159 gdb_cv_printf_has_long_double=yes,
 160 gdb_cv_printf_has_long_double=no,
 161 gdb_cv_printf_has_long_double=no)])
 162 if test $gdb_cv_printf_has_long_double = yes; then
 163   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 164 fi
 165 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 166
 167 AC_FUNC_MMAP
 168
 169 BFD_NEED_DECLARATION(malloc)
 170 BFD_NEED_DECLARATION(realloc)
 171 BFD_NEED_DECLARATION(free)
 172
 173 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 174 dnl we must explicitly test for version 1 of the library because version 0
 175 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 176
 177 dnl Note that we only want this if we are both native (host == target), and
 178 dnl not doing a canadian cross build (build == host).
 179
 180 if test ${build} = ${host} -a ${host} = ${target} ; then
 181         case ${host_os} in
 182         hpux*)
 183                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 184                 if test -f /usr/include/dce/cma_config.h ; then
 185                         if test "$GCC" = "yes" ; then
 186                                 AC_MSG_RESULT(yes)
 187                                 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 188                                 CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 189                         else
 190                                 AC_MSG_RESULT(no (suppressed because you are not using GCC))
 191                         fi
 192                 else
 193                         AC_MSG_RESULT(no)
 194                 fi
 195                 ;;
 196         solaris*)
 197                 AC_MSG_CHECKING(for Solaris thread debugging library)
 198                 if test -f /usr/lib/libthread_db.so.1 ; then
 199                         AC_MSG_RESULT(yes)
 200                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 201                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 202                         AC_CHECK_LIB(dl, dlopen)
 203                         if test "$GCC" = "yes" ; then
 204                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 205                         fi
 206                 else
 207                         AC_MSG_RESULT(no)
 208                 fi
 209                 ;;
 210         esac
 211         AC_SUBST(CONFIG_LDFLAGS)
 212 fi
 213
 214 dnl Handle optional features that can be enabled.
 215 ENABLE_CFLAGS=
 216
 217 AC_ARG_ENABLE(netrom,
 218 [  --enable-netrom ],
 219 [case "${enableval}" in
 220 yes)    enable_netrom=yes ;;
 221 no)     enable_netrom=no ;;
 222 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 223 esac])
 224
 225 if test "${enable_netrom}" = "yes"; then
 226         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 227 fi
 228
 229 # start-sanitize-gdbtk
 230 ENABLE_IDE=
 231 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 232 if test "$enable_ide" = yes; then
 233    enable_ide=yes
 234    ENABLE_IDE=1
 235 else
 236    enable_ide=no
 237 fi
 238 AC_SUBST(ENABLE_IDE)
 239
 240 ENABLE_GDBTK=
 241
 242 AC_ARG_ENABLE(gdbtk,
 243 [  --enable-gdbtk ],
 244 [case "${enableval}" in
 245     yes)
 246         case "$host" in
 247         *go32*)
 248             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 249             enable_gdbtk=no ;;
 250         *windows*)
 251             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 252             enable_gdbtk=no ;;
 253         *)
 254             enable_gdbtk=yes ;;
 255         esac ;;
 256     no)
 257         enable_gdbtk=no  ;;
 258     *)
 259         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 260 esac],
 261 [
 262 # Default is on for everything but go32 and cygwin32
 263 case "$host" in
 264     *go32* | *windows*)
 265         ;;
 266     *)
 267         enable_gdbtk=yes ;;
 268     esac
 269 ])
 270
 271 # In the cygwin32 environment, we need some additional flags.
 272 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 273 [AC_EGREP_CPP(lose, [
 274 #ifdef __CYGWIN32__
 275 lose
 276 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 277
 278 WIN32LIBS=
 279 WIN32LDAPP=
 280 AC_SUBST(WIN32LIBS)
 281 AC_SUBST(WIN32LDAPP)
 282
 283 if test x$gdb_cv_os_cygwin32 = xyes; then
 284     if test x$enable_ide = xyes; then
 285         WIN32LIBS="-ladvapi32"
 286     fi
 287 fi
 288
 289 configdir="unix"
 290
 291 if test "${enable_gdbtk}" = "yes"; then
 292
 293     CY_AC_PATH_TCLCONFIG
 294     if test -z "${no_tcl}"; then
 295         CY_AC_LOAD_TCLCONFIG
 296         CY_AC_PATH_TKCONFIG
 297
 298         # If $no_tk is nonempty, then we can't do Tk, and there is no
 299         # point to doing Tcl.
 300         if test -z "${no_tk}"; then
 301            CY_AC_LOAD_TKCONFIG
 302            CY_AC_PATH_TCLH
 303            CY_AC_PATH_TKH
 304            CY_AC_PATH_ITCLH
 305            CY_AC_PATH_TIX
 306
 307            # now look for tix library stuff
 308            TIXVERSION=4.1.8.0
 309            . ${ac_cv_c_tclconfig}/tclConfig.sh
 310            case "${host}" in
 311            *-*-cygwin32*)
 312                 tixdir=../tix/win/tcl8.0
 313                 ;;
 314            *)
 315                 tixdir=../tix/unix/tk8.0
 316                 ;;
 317            esac
 318            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 319                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 320            else
 321                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 322            fi
 323
 324            ENABLE_GDBTK=1
 325
 326            # Include some libraries that Tcl and Tk want.
 327            if test "${enable_ide}" = "yes"; then
 328               TCL_LIBS='$(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 329            else
 330               TCL_LIBS='$(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 331            fi
 332            # Yes, the ordering seems wrong here.  But it isn't.
 333            # TK_LIBS is the list of libraries that need to be linked
 334            # after Tcl/Tk.
 335            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 336            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 337
 338            if test x$gdb_cv_os_cygwin32 = xyes; then
 339               WIN32LIBS="${WIN32LIBS} -luser32"
 340               WIN32LDAPP="-Wl,--subsystem,windows"
 341            fi
 342         fi
 343     fi
 344 fi
 345
 346 AC_SUBST(ENABLE_GDBTK)
 347 AC_SUBST(X_CFLAGS)
 348 AC_SUBST(X_LDFLAGS)
 349 AC_SUBST(X_LIBS)
 350 AC_SUBST(TIXLIB)
 351 # end-sanitize-gdbtk
 352
 353 AC_SUBST(ENABLE_CFLAGS)
 354
 355 AC_SUBST(CONFIG_OBS)
 356
 357 # Begin stuff to support --enable-shared
 358 AC_ARG_ENABLE(shared,
 359 [  --enable-shared         use shared libraries],
 360 [case "${enableval}" in
 361   yes) shared=true ;;
 362   no)  shared=false ;;
 363   *) shared=true ;;
 364 esac])dnl
 365
 366 HLDFLAGS=
 367 HLDENV=
 368 # If we have shared libraries, try to set rpath reasonably.
 369 if test "${shared}" = "true"; then
 370   case "${host}" in
 371   *-*-hpux*)
 372     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 373     ;;
 374   *-*-irix5* | *-*-irix6*)
 375     HLDFLAGS='-Wl,-rpath,$(libdir)'
 376     ;;
 377   *-*-linux*aout*)
 378     ;;
 379   *-*-linux* | *-pc-linux-gnu)
 380     HLDFLAGS='-Wl,-rpath,$(libdir)'
 381     ;;
 382   *-*-solaris*)
 383     HLDFLAGS='-R $(libdir)'
 384     ;;
 385   *-*-sysv4*)
 386     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 387     ;;
 388   esac
 389 fi
 390
 391 # On SunOS, if the linker supports the -rpath option, use it to
 392 # prevent ../bfd and ../opcodes from being included in the run time
 393 # search path.
 394 case "${host}" in
 395   *-*-sunos*)
 396     echo 'main () { }' > conftest.c
 397     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 398     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 399       :
 400     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 401       :
 402     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 403       :
 404     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 405       :
 406     elif test "${shared}" = "true"; then
 407       HLDFLAGS='-Wl,-rpath=$(libdir)'
 408     else
 409       HLDFLAGS='-Wl,-rpath='
 410     fi
 411     rm -f conftest.t conftest.c conftest
 412     ;;
 413 esac
 414 AC_SUBST(HLDFLAGS)
 415 AC_SUBST(HLDENV)
 416 # End stuff to support --enable-shared
 417
 418 # target_subdir is used by the testsuite to find the target libraries.
 419 target_subdir=
 420 if test "${host}" != "${target}"; then
 421     target_subdir="${target_alias}/"
 422 fi
 423 AC_SUBST(target_subdir)
 424
 425 frags=
 426 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 427 if test ! -f ${host_makefile_frag}; then
 428 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 429 fi
 430 frags="$frags $host_makefile_frag"
 431
 432 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 433 if test ! -f ${target_makefile_frag}; then
 434 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 435 fi
 436 frags="$frags $target_makefile_frag"
 437
 438 AC_SUBST_FILE(host_makefile_frag)
 439 AC_SUBST_FILE(target_makefile_frag)
 440 AC_SUBST(frags)
 441
 442 changequote(,)dnl
 443 hostfile=`sed -n '
 444 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 445 ' ${host_makefile_frag}`
 446
 447 targetfile=`sed -n '
 448 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 449 ' ${target_makefile_frag}`
 450
 451 # these really aren't orthogonal true/false values of the same condition,
 452 # but shells are slow enough that I like to reuse the test conditions
 453 # whenever possible
 454 if test "${target}" = "${host}"; then
 455 nativefile=`sed -n '
 456 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 457 ' ${host_makefile_frag}`
 458 # else
 459 # GDBserver is only useful in a "native" enviroment
 460 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 461 fi
 462 changequote([,])
 463
 464 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 465 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 466 # corresponding links.  But we have to remove the xm.h files and tm.h
 467 # files anyway, e.g. when switching from "configure host" to
 468 # "configure none".
 469
 470 files=
 471 links=
 472 rm -f xm.h
 473 if test "${hostfile}" != ""; then
 474 files="${files} config/${gdb_host_cpu}/${hostfile}"
 475 links="${links} xm.h"
 476 fi
 477 rm -f tm.h
 478 if test "${targetfile}" != ""; then
 479 files="${files} config/${gdb_target_cpu}/${targetfile}"
 480 links="${links} tm.h"
 481 fi
 482 rm -f nm.h
 483 if test "${nativefile}" != ""; then
 484 files="${files} config/${gdb_host_cpu}/${nativefile}"
 485 links="${links} nm.h"
 486 else
 487 # A cross-only configuration.
 488 files="${files} config/nm-empty.h"
 489 links="${links} nm.h"
 490 fi
 491 # start-sanitize-gdbtk
 492 AC_PROG_LN_S
 493 # Make it possible to use the GUI without doing a full install
 494 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 495   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 496   echo linking $srcdir/gdbtcl to gdbtcl
 497   $LN_S $srcdir/gdbtcl gdbtcl
 498   else
 499   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 500   echo "         " make install before you are able to run the GUI.
 501   fi
 502 fi
 503 # end-sanitize-gdbtk
 504
 505 AC_LINK_FILES($files, $links)
 506
 507 AC_CONFIG_SUBDIRS($configdirs)
 508 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 509 [
 510 dnl Autoconf doesn't provide a mechanism for modifying definitions
 511 dnl provided by makefile fragments.
 512 dnl
 513 if test "${nativefile}" = ""; then
 514 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 515         < Makefile > Makefile.tem
 516 mv -f Makefile.tem Makefile
 517 fi
 518
 519 changequote(,)dnl
 520 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 521 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 522 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 523 mv -f Makefile.tmp Makefile
 524 changequote([,])dnl
 525
 526 case x$CONFIG_HEADERS in
 527 xconfig.h:config.in)
 528 echo > stamp-h ;;
 529 esac
 530 ],
 531 [
 532 gdb_host_cpu=$gdb_host_cpu
 533 gdb_target_cpu=$gdb_target_cpu
 534 nativefile=$nativefile
 535 ])
 536
 537 exit 0
 538