gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 dnl Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is part of GDB.
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2 of the License, or
  10 dnl (at your option) any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 dnl Process this file with autoconf to produce a configure script.
  22
  23 AC_PREREQ(2.13)dnl
  24 AC_INIT(main.c)
  25 AC_CONFIG_HEADER(config.h:config.in)
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30 AC_AIX
  31 AC_ISC_POSIX
  32 AM_PROG_CC_STDC
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 # FIXME: kettenis/20030102: The AC_PROG_RANLIB from Autoconf 2.13
  38 # doesn't support cross-compilation, but the one from Autoconf 2.5x
  39 # does.  Override RANLIB here (i.e. before running AC_PROG_RANLIB) to
  40 # deal with the lossage.  Note that CY_GNU_GETTEXT currently calls
  41 # AC_PROG_RANLIB.  This can be removed when we switch to Autoconf
  42 # 2.5x.
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Set up for gettext.  PACKAGE is used when we call bindtextdomain.
  46 ALL_LINGUAS=
  47 CY_GNU_GETTEXT
  48 AC_DEFINE(PACKAGE, "gdb", [Name of this package. ])
  49
  50 debugdir=${libdir}/debug
  51
  52 AC_ARG_WITH(separate-debug-dir,
  53 [  --with-separate-debug-dir=path   Look for global separate debug info in this path [LIBDIR/debug]],
  54 [debugdir="${withval}"])
  55
  56 AC_DEFINE_DIR(DEBUGDIR, debugdir,
  57               [Global directory for separate debug files. ])
  58 #AC_DEFINE_UNQUOTED(DEBUGDIR, "$debugdir"),
  59
  60 dnl List of object files added by configure.
  61
  62 CONFIG_OBS=
  63 CONFIG_LIB_OBS=
  64 CONFIG_DEPS=
  65 CONFIG_SRCS=
  66 CONFIG_INITS=
  67 ENABLE_CFLAGS=
  68 CONFIG_ALL=
  69 CONFIG_CLEAN=
  70 CONFIG_INSTALL=
  71 CONFIG_UNINSTALL=
  72
  73 AC_CONFIG_SUBDIRS(doc testsuite)
  74 configdirs=
  75
  76 . $srcdir/configure.host
  77
  78 . $srcdir/configure.tgt
  79
  80 # Fetch the default architecture and default target vector from BFD.
  81 targ=$target; . $srcdir/../bfd/config.bfd
  82
  83 # We only want the first architecture, so strip off the others if
  84 # there is more than one.
  85 targ_archs=`echo $targ_archs | sed 's/ .*//'`
  86
  87 if test "x$targ_archs" != x; then
  88   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
  89     [Define to BFD's default architecture. ])
  90 fi
  91 if test "x$targ_defvec" != x; then
  92   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
  93     [Define to BFD's default target vector. ])
  94 fi
  95
  96 AC_ARG_PROGRAM
  97
  98 # The CLI cannot be disabled yet, but may be in the future.
  99
 100 # Enable CLI.
 101 AC_ARG_ENABLE(gdbcli,
 102 [  --disable-gdbcli        disable command-line interface (CLI)],
 103   [case $enableval in
 104     yes)
 105       ;;
 106     no)
 107       AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;;
 108     *)
 109       AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;;
 110   esac],
 111   [enable_gdbcli=yes])
 112 if test x"$enable_gdbcli" = xyes; then
 113   if test -d $srcdir/cli; then
 114     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)"
 115     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)"
 116     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)"
 117     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_CLI_INITS)"
 118     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)"
 119     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_CLI_ALL)"
 120     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_CLI_CLEAN)"
 121     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_CLI_INSTALL)"
 122     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_CLI_UNINSTALL)"
 123   fi
 124 fi
 125
 126 # Enable MI.
 127 AC_ARG_ENABLE(gdbmi,
 128 [  --disable-gdbmi         disable machine-interface (MI)],
 129   [case $enableval in
 130     yes | no)
 131       ;;
 132     *)
 133       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 134   esac],
 135   [enable_gdbmi=yes])
 136 if test x"$enable_gdbmi" = xyes; then
 137   if test -d $srcdir/mi; then
 138     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 139     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 140     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 141     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_MI_INITS)"
 142     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 143     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_MI_ALL)"
 144     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_MI_CLEAN)"
 145     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_MI_INSTALL)"
 146     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_MI_UNINSTALL)"
 147   fi
 148 fi
 149
 150 # Enable TUI.
 151 AC_ARG_ENABLE(tui,
 152 [  --enable-tui            enable full-screen terminal user interface (TUI)],
 153   [case $enableval in
 154     yes | no)
 155       ;;
 156     *)
 157       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 158   esac])
 159 if test x"$enable_tui" = xyes; then
 160   if test -d $srcdir/tui; then
 161     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 162     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 163     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 164     CONFIG_INITS="$CONFIG_INITS \$(SUBDIR_TUI_INITS)"
 165     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 166     CONFIG_ALL="$CONFIG_ALL \$(SUBDIR_TUI_ALL)"
 167     CONFIG_CLEAN="$CONFIG_CLEAN \$(SUBDIR_TUI_CLEAN)"
 168     CONFIG_INSTALL="$CONFIG_INSTALL \$(SUBDIR_TUI_INSTALL)"
 169     CONFIG_UNINSTALL="$CONFIG_UNINSTALL \$(SUBDIR_TUI_UNINSTALL)"
 170     need_curses=yes
 171   fi
 172 fi
 173
 174 # Enable gdbtk.
 175 AC_ARG_ENABLE(gdbtk,
 176 [  --enable-gdbtk          enable gdbtk graphical user interface (GUI)],
 177   [case $enableval in
 178     yes | no)
 179       ;;
 180     *)
 181       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 182   esac],
 183   [if test -d $srcdir/gdbtk; then
 184     enable_gdbtk=yes
 185   else
 186     enable_gdbtk=no
 187   fi])
 188 # We unconditionally disable gdbtk tests on selected platforms.
 189 case $host_os in
 190   go32* | windows*)
 191     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 192     enable_gdbtk=no ;;
 193 esac
 194
 195 # Profiling support.
 196 AC_ARG_ENABLE(profiling,
 197 [  --enable-profiling      enable profiling of GDB],
 198   [case $enableval in
 199     yes | no)
 200       ;;
 201     *)
 202       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 203   esac],
 204  [enable_profiling=no])
 205
 206 AC_CHECK_FUNCS(monstartup _mcleanup)
 207 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 208 [AC_TRY_LINK(
 209 [#include <stdlib.h>
 210 extern char _etext;
 211 ],
 212 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 213 if test $ac_cv_var__etext = yes; then
 214   AC_DEFINE(HAVE__ETEXT, 1,
 215             [Define to 1 if your system has the _etext variable. ])
 216 fi
 217 if test "$enable_profiling" = yes ; then
 218   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 219     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 220   fi
 221   PROFILE_CFLAGS=-pg
 222   OLD_CFLAGS="$CFLAGS"
 223   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 224
 225   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 226     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 227      ac_cv_cc_supports_pg=no)])
 228
 229   if test $ac_cv_cc_supports_pg = no; then
 230     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 231   fi
 232
 233   CFLAGS="$OLD_CFLAGS"
 234 fi
 235
 236 # --------------------- #
 237 # Checks for programs.  #
 238 # --------------------- #
 239
 240 AC_PROG_AWK
 241 AC_PROG_INSTALL
 242 AC_PROG_LN_S
 243 AC_PROG_RANLIB
 244 AC_PROG_YACC
 245
 246 AC_CHECK_TOOL(AR, ar)
 247 AC_CHECK_TOOL(DLLTOOL, dlltool)
 248 AC_CHECK_TOOL(WINDRES, windres)
 249
 250 # Needed for GNU/Hurd.
 251 AC_CHECK_TOOL(MIG, mig)
 252
 253 # ---------------------- #
 254 # Checks for libraries.  #
 255 # ---------------------- #
 256
 257 # We might need to link with -lm; most simulators need it.
 258 AC_CHECK_LIB(m, main)
 259
 260 # We need to link with -lw to get `wctype' on Solaris before Solaris
 261 # 2.6.  Solaris 2.6 and beyond have this function in libc, and have a
 262 # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1
 263 # is known to have this problem).  Therefore we avoid libw if we can.
 264 AC_CHECK_FUNC(wctype, [],
 265   [AC_CHECK_LIB(w, wctype)])
 266
 267 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 268 AC_SEARCH_LIBS(gethostbyname, nsl)
 269
 270 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 271 AC_SEARCH_LIBS(socketpair, socket)
 272
 273 # Since GDB uses Readline, we need termcap functionality, so we need
 274 # to find a library that provides that.  When GDB is configured with
 275 # --enable-tui, we need full curses functionality.
 276 #
 277 # FIXME: kettenis/20030102: We seem to prefer HP curses (Hcurses) over
 278 # Xcurses on HP-UX; see the `-D__HP_CURSES' in the relevant host
 279 # Makefile fragments.  That's why we need to have `Hcurses' before
 280 # `curses'.  I don't see why we should use HP curses if a more
 281 # standard curses is available, except that according to HP's
 282 # documentation one needs to compile `-D_XOPEN_SOURCE_EXTENDED' on
 283 # HP-UX 10.10 and 10.20.
 284
 285 if test "$need_curses" = yes; then
 286   AC_SEARCH_LIBS(initscr, [ncurses Hcurses curses], [],
 287     [AC_MSG_ERROR([no curses library found])])
 288 fi
 289
 290 case $host_os in
 291   cygwin*)
 292     if test -d $srcdir/libtermcap; then
 293       LIBS="../libtermcap/libtermcap.a $LIBS"
 294       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 295     fi ;;
 296   go32*)
 297     # ??? Is this really true?
 298     ac_cv_search_tgetent="none required"
 299     ;;
 300   aix*)
 301     # Readline prefers curses over termcap on AIX.
 302     # ??? Why?
 303     AC_SEARCH_LIBS(tgetent, [tinfo ncurses curses termcap])
 304     ;;
 305 esac
 306
 307 # Note: We used to check for libtermlib and libterminfo too, but
 308 # Readline doesn't, so I think we're safe with leaving them out.
 309 AC_SEARCH_LIBS(tgetent, [termcap tinfo ncurses Hcurses curses])
 310
 311 if test "$ac_cv_search_tgetent" = no; then
 312   AC_MSG_ERROR([no termcap library found])
 313 fi
 314
 315 # ------------------------- #
 316 # Checks for header files.  #
 317 # ------------------------- #
 318
 319 AC_HEADER_DIRENT
 320 AC_HEADER_STAT
 321 AC_HEADER_STDC
 322 AC_CHECK_HEADERS(link.h)
 323 AC_CHECK_HEADERS(nlist.h)
 324 AC_CHECK_HEADERS(poll.h sys/poll.h)
 325 AC_CHECK_HEADERS(proc_service.h thread_db.h)
 326 AC_CHECK_HEADERS(stddef.h)
 327 AC_CHECK_HEADERS(stdlib.h)
 328 AC_CHECK_HEADERS(stdint.h)
 329 AC_CHECK_HEADERS(string.h memory.h strings.h)
 330 AC_CHECK_HEADERS(sys/fault.h)
 331 AC_CHECK_HEADERS(sys/file.h)
 332 AC_CHECK_HEADERS(sys/filio.h)
 333 AC_CHECK_HEADERS(sys/ioctl.h)
 334 AC_CHECK_HEADERS(sys/param.h)
 335 AC_CHECK_HEADERS(sys/proc.h)
 336 AC_CHECK_HEADERS(sys/procfs.h)
 337 AC_CHECK_HEADERS(sys/ptrace.h ptrace.h)
 338 AC_CHECK_HEADERS(sys/reg.h sys/debugreg.h)
 339 AC_CHECK_HEADERS(sys/select.h)
 340 AC_CHECK_HEADERS(sys/syscall.h)
 341 AC_CHECK_HEADERS(sys/user.h)
 342 AC_CHECK_HEADERS(sys/wait.h wait.h)
 343 AC_CHECK_HEADERS(termios.h termio.h sgtty.h)
 344 AC_CHECK_HEADERS(unistd.h)
 345
 346 # On Solaris 2.[78], we need to define _MSE_INT_H to avoid a clash
 347 # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to
 348 # think that we don't have <curses.h> if we're using GCC.
 349 case $host_os in
 350   solaris2.[[78]])
 351     if test "$GCC" = yes; then
 352       AC_DEFINE(_MSE_INT_H, 1,
 353         [[Define to 1 to avoid a clash between <widec.h> and <wchar.h> on
 354    Solaris 2.[78] when using GCC. ]])
 355     fi ;;
 356 esac
 357 AC_CHECK_HEADERS(curses.h ncurses.h term.h)
 358
 359 # FIXME: kettenis/20030102: In most cases we include these
 360 # unconditionally, so what's the point in checking these?
 361 AC_CHECK_HEADERS(ctype.h time.h)
 362
 363 # ------------------------- #
 364 # Checks for declarations.  #
 365 # ------------------------- #
 366
 367 gcc_AC_CHECK_DECLS(getopt)
 368
 369 # ------------------ #
 370 # Checks for types.  #
 371 # ------------------ #
 372
 373 AC_TYPE_SIGNAL
 374
 375 # ------------------------------------- #
 376 # Checks for compiler characteristics.  #
 377 # ------------------------------------- #
 378
 379 AC_C_CONST
 380 AC_C_INLINE
 381
 382 # ------------------------------ #
 383 # Checks for library functions.  #
 384 # ------------------------------ #
 385
 386 AC_FUNC_ALLOCA
 387 AC_FUNC_MMAP
 388 AC_FUNC_VFORK
 389 AC_CHECK_FUNCS(canonicalize_file_name realpath)
 390 AC_CHECK_FUNCS(poll)
 391 AC_CHECK_FUNCS(pread64)
 392 AC_CHECK_FUNCS(sbrk)
 393 AC_CHECK_FUNCS(setpgid setpgrp)
 394 AC_CHECK_FUNCS(sigaction sigprocmask sigsetmask)
 395 AC_CHECK_FUNCS(socketpair)
 396 AC_CHECK_FUNCS(syscall)
 397
 398 dnl AC_FUNC_SETPGRP does not work when cross compiling
 399 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
 400 if test "$cross_compiling" = no; then
 401   AC_FUNC_SETPGRP
 402 else
 403   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
 404     [AC_TRY_COMPILE([
 405 #include <unistd.h>
 406 ], [
 407   if (setpgrp(1,1) == -1)
 408     exit (0);
 409   else
 410     exit (1);
 411 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
 412 if test $ac_cv_func_setpgrp_void = yes; then
 413   AC_DEFINE(SETPGRP_VOID, 1)
 414 fi
 415 fi
 416
 417 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
 418 # since sigsetjmp might only be defined as a macro.
 419 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
 420 [AC_TRY_COMPILE([
 421 #include <setjmp.h>
 422 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 423 gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)])
 424 if test $gdb_cv_func_sigsetjmp = yes; then
 425   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 426 fi
 427
 428 # Assume we'll default to using the included libiberty regex.
 429 gdb_use_included_regex=yes
 430
 431 # However, if the system regex is GNU regex, then default to *not*
 432 # using the included regex.
 433 AC_CACHE_CHECK(
 434   [for GNU regex],
 435   [gdb_cv_have_gnu_regex],
 436   [AC_TRY_COMPILE(
 437     [#include <gnu-versions.h>],
 438     [#define REGEX_INTERFACE_VERSION 1
 439 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
 440 # error "Version mismatch"
 441 #endif],
 442     gdb_cv_have_gnu_regex=yes,
 443     gdb_cv_have_gnu_regex=no)])
 444 if test $gdb_cv_have_gnu_regex = yes; then
 445   gdb_use_included_regex=no
 446 fi
 447
 448 AC_ARG_WITH(included-regex,
 449   [  --without-included-regex don't use included regex; this is the default
 450                           on systems with version 2 of the GNU C library
 451                           (use with caution on other system)],
 452   gdb_with_regex=$withval,
 453   gdb_with_regex=$gdb_use_included_regex)
 454 if test "$gdb_with_regex" = yes; then
 455   AC_DEFINE(USE_INCLUDED_REGEX, 1,
 456     [Define to 1 if the regex included in libiberty should be used.])
 457 fi
 458
 459 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
 460 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
 461 AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs,
 462 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;],
 463 gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)])
 464 if test $gdb_cv_struct_reg_r_fs = yes; then
 465   AC_DEFINE(HAVE_STRUCT_REG_R_FS)
 466 fi
 467 AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs,
 468 [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;],
 469 gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)])
 470 if test $gdb_cv_struct_reg_r_gs = yes; then
 471   AC_DEFINE(HAVE_STRUCT_REG_R_GS)
 472 fi
 473
 474 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
 475 AC_MSG_CHECKING(for PTRACE_GETREGS)
 476 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
 477 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 478                 [PTRACE_GETREGS;],
 479                 [gdb_cv_have_ptrace_getregs=yes],
 480                 [gdb_cv_have_ptrace_getregs=no])])
 481 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
 482 if test $gdb_cv_have_ptrace_getregs = yes; then
 483   AC_DEFINE(HAVE_PTRACE_GETREGS)
 484 fi
 485
 486 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
 487 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 488 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
 489 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 490                 [PTRACE_GETFPXREGS;],
 491                 [gdb_cv_have_ptrace_getfpxregs=yes],
 492                 [gdb_cv_have_ptrace_getfpxregs=no])])
 493 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
 494 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
 495   AC_DEFINE(HAVE_PTRACE_GETFPXREGS)
 496 fi
 497
 498 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
 499 AC_MSG_CHECKING(for PT_GETDBREGS)
 500 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
 501 [AC_TRY_COMPILE([#include <sys/types.h>
 502 #include <sys/ptrace.h>],
 503                 [PT_GETDBREGS;],
 504                 [gdb_cv_have_pt_getdbregs=yes],
 505                 [gdb_cv_have_pt_getdbregs=no])])
 506 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
 507 if test $gdb_cv_have_pt_getdbregs = yes; then
 508   AC_DEFINE(HAVE_PT_GETDBREGS)
 509 fi
 510
 511 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
 512 AC_MSG_CHECKING(for PT_GETXMMREGS)
 513 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
 514 [AC_TRY_COMPILE([#include <sys/types.h>
 515 #include <sys/ptrace.h>],
 516                 [PT_GETXMMREGS;],
 517                 [gdb_cv_have_pt_getxmmregs=yes],
 518                 [gdb_cv_have_pt_getxmmregs=no])])
 519 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
 520 if test $gdb_cv_have_pt_getxmmregs = yes; then
 521   AC_DEFINE(HAVE_PT_GETXMMREGS)
 522 fi
 523
 524 # See if stdint.h provides the uintptr_t type.
 525 # Autoconf 2.5X has an improved AC_CHECK_TYPE which will simplify this.
 526 AC_CACHE_CHECK([for uintptr_t in stdint.h], gdb_cv_have_uintptr_t,
 527   [AC_TRY_COMPILE(
 528     [#include <stdint.h>],
 529     [uintptr_t foo = 0;],
 530     gdb_cv_have_uintptr_t=yes,
 531     gdb_cv_have_uintptr_t=no)])
 532 if test $gdb_cv_have_uintptr_t = yes; then
 533   AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if <stdint.h> provides the uintptr_t type.])
 534 fi
 535
 536 BFD_NEED_DECLARATION(malloc)
 537 BFD_NEED_DECLARATION(realloc)
 538 BFD_NEED_DECLARATION(free)
 539 BFD_NEED_DECLARATION(strerror)
 540 BFD_NEED_DECLARATION(strdup)
 541 BFD_NEED_DECLARATION(strstr)
 542 BFD_NEED_DECLARATION(canonicalize_file_name)
 543
 544 # The following save_state_t checkery is only necessary for HPUX
 545 # versions earlier than 10.20.  When those fade from memory, this
 546 # could be expunged. --jsm 1999-03-22
 547
 548 AC_MSG_CHECKING(for HPUX save_state structure)
 549 AC_EGREP_HEADER(save_state_t, machine/save_state.h,
 550                 gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no)
 551 AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes,
 552                 gdb_cv_hpux_sswide=no)
 553 if test $gdb_cv_hpux_savestate = yes
 554 then
 555   AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1)
 556 fi
 557 if test $gdb_cv_hpux_sswide = yes
 558 then
 559   AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1)
 560 fi
 561 AC_MSG_RESULT($gdb_cv_hpux_sswide)
 562
 563
 564 # If we are configured native on GNU/Linux, work around problems with
 565 # sys/procfs.h
 566 # Also detect which type of /proc is in use, such as for Unixware or Solaris.
 567
 568 if test "${target}" = "${host}"; then
 569   case "${host}" in
 570   i[[3456]]86-*-linux*)
 571         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
 572         AC_DEFINE(sys_quotactl)
 573         ;;
 574   ia64-*-aix*)
 575       AC_DEFINE(NEW_PROC_API)
 576       ;;
 577   *-*-unixware* | *-*-sysv4.2* | *-*-sysv5* | *-*-interix* )
 578       AC_DEFINE(NEW_PROC_API)
 579       ;;
 580   *-*-solaris2.[[678]])
 581       AC_DEFINE(NEW_PROC_API)
 582       ;;
 583   esac
 584 fi
 585
 586 if test "$ac_cv_header_sys_procfs_h" = yes; then
 587   BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 588   BFD_HAVE_SYS_PROCFS_TYPE(prrun_t)
 589   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
 590   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
 591   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 592   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 593   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
 594   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t)
 595   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 596   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 597   BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t)
 598   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t)
 599   BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t)
 600   BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t)
 601
 602
 603   dnl Check for broken prfpregset_t type
 604
 605   dnl For Linux/i386, glibc 2.1.3 was released with a bogus
 606   dnl prfpregset_t type (it's a typedef for the pointer to a struct
 607   dnl instead of the struct itself).  We detect this here, and work
 608   dnl around it in gdb_proc_service.h.
 609
 610   if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then
 611     AC_MSG_CHECKING(whether prfpregset_t type is broken)
 612     AC_CACHE_VAL(gdb_cv_prfpregset_t_broken,
 613       [AC_TRY_RUN([#include <sys/procfs.h>
 614        int main ()
 615        {
 616          if (sizeof (prfpregset_t) == sizeof (void *))
 617            return 1;
 618          return 0;
 619        }],
 620        gdb_cv_prfpregset_t_broken=no,
 621        gdb_cv_prfpregset_t_broken=yes,
 622        gdb_cv_prfpregset_t_broken=yes)])
 623     AC_MSG_RESULT($gdb_cv_prfpregset_t_broken)
 624     if test $gdb_cv_prfpregset_t_broken = yes; then
 625       AC_DEFINE(PRFPREGSET_T_BROKEN)
 626     fi
 627   fi
 628
 629   dnl Check for PIOCSET ioctl entry
 630
 631   AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h)
 632   AC_CACHE_VAL(gdb_cv_have_procfs_piocset,
 633   [AC_TRY_COMPILE([#include <unistd.h>
 634 #include <sys/types.h>
 635 #include <sys/procfs.h>
 636 ], [
 637     int dummy;;
 638     dummy = ioctl(0, PIOCSET, &dummy);
 639   ],
 640   gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)])
 641   AC_MSG_RESULT($gdb_cv_have_procfs_piocset)
 642   if test $gdb_cv_have_procfs_piocset = yes; then
 643     AC_DEFINE(HAVE_PROCFS_PIOCSET)
 644   fi
 645 fi
 646
 647 dnl For native ports (host == target), check to see what kind of
 648 dnl legacy link.h support is needed.  (See solib-legacy.c.)
 649 if test ${host} = ${target} ; then
 650   dnl Check for struct link_map with l_ members which are indicative
 651   dnl of SVR4-like shared libraries
 652
 653   AC_MSG_CHECKING(for member l_addr in struct link_map)
 654   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_l_members,
 655     [AC_TRY_COMPILE([#include <link.h>],
 656                     [struct link_map lm; (void) lm.l_addr;],
 657                     gdb_cv_have_struct_link_map_with_l_members=yes,
 658                     gdb_cv_have_struct_link_map_with_l_members=no)])
 659   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_l_members)
 660   if test $gdb_cv_have_struct_link_map_with_l_members = yes; then
 661     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_L_MEMBERS)
 662   fi
 663
 664   dnl Check for struct link_map with lm_ members which are indicative
 665   dnl of SunOS-like shared libraries
 666
 667   AC_MSG_CHECKING(for member lm_addr in struct link_map)
 668   AC_CACHE_VAL(gdb_cv_have_struct_link_map_with_lm_members,
 669     [AC_TRY_COMPILE([#include <sys/types.h>
 670 #include <link.h>],
 671                     [struct link_map lm; (void) lm.lm_addr;],
 672                     gdb_cv_have_struct_link_map_with_lm_members=yes,
 673                     gdb_cv_have_struct_link_map_with_lm_members=no)])
 674   AC_MSG_RESULT($gdb_cv_have_struct_link_map_with_lm_members)
 675   if test $gdb_cv_have_struct_link_map_with_lm_members = yes; then
 676     AC_DEFINE(HAVE_STRUCT_LINK_MAP_WITH_LM_MEMBERS)
 677   fi
 678
 679   dnl Check for struct so_map with som_ members which are found on
 680   dnl some *BSD systems.
 681
 682   AC_MSG_CHECKING(for member som_addr in struct so_map)
 683   AC_CACHE_VAL(gdb_cv_have_struct_so_map_with_som_members,
 684     [AC_TRY_COMPILE([#include <sys/types.h>
 685 #ifdef HAVE_NLIST_H
 686 #include <nlist.h>
 687 #endif
 688 #include <link.h>],
 689                     [struct so_map lm; (void) lm.som_addr;],
 690                     gdb_cv_have_struct_so_map_with_som_members=yes,
 691                     gdb_cv_have_struct_so_map_with_som_members=no)])
 692   AC_MSG_RESULT($gdb_cv_have_struct_so_map_with_som_members)
 693   if test $gdb_cv_have_struct_so_map_with_som_members = yes; then
 694     AC_DEFINE(HAVE_STRUCT_SO_MAP_WITH_SOM_MEMBERS)
 695   fi
 696
 697   dnl Check for struct link_map32 type, which allows a 64-bit Solaris
 698   dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries.
 699
 700   AC_MSG_CHECKING(for struct link_map32 in sys/link.h)
 701   AC_CACHE_VAL(gdb_cv_have_struct_link_map32,
 702     [AC_TRY_COMPILE([#define _SYSCALL32
 703 #include <sys/link.h>], [struct link_map32 l;],
 704      gdb_cv_have_struct_link_map32=yes,
 705      gdb_cv_have_struct_link_map32=no)])
 706   AC_MSG_RESULT($gdb_cv_have_struct_link_map32)
 707   if test $gdb_cv_have_struct_link_map32 = yes; then
 708     AC_DEFINE(HAVE_STRUCT_LINK_MAP32)
 709     AC_DEFINE(_SYSCALL32)
 710   fi
 711 fi
 712
 713 dnl See if compiler supports "long long" type.
 714
 715 AC_MSG_CHECKING(for long long support in compiler)
 716 AC_CACHE_VAL(gdb_cv_c_long_long,
 717 [AC_TRY_COMPILE(, [
 718   extern long long foo;
 719   switch (foo & 2) { case 0: return 1; }
 720 ],
 721 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 722 AC_MSG_RESULT($gdb_cv_c_long_long)
 723 if test $gdb_cv_c_long_long = yes; then
 724   AC_DEFINE(CC_HAS_LONG_LONG)
 725 fi
 726
 727 dnl See if the compiler and runtime support printing long long
 728
 729 AC_MSG_CHECKING(for long long support in printf)
 730 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 731 [AC_TRY_RUN([
 732 int main () {
 733   char buf[32];
 734   long long l = 0;
 735   l = (l << 16) + 0x0123;
 736   l = (l << 16) + 0x4567;
 737   l = (l << 16) + 0x89ab;
 738   l = (l << 16) + 0xcdef;
 739   sprintf (buf, "0x%016llx", l);
 740   return (strcmp ("0x0123456789abcdef", buf));
 741 }],
 742 gdb_cv_printf_has_long_long=yes,
 743 gdb_cv_printf_has_long_long=no,
 744 gdb_cv_printf_has_long_long=no)])
 745 if test $gdb_cv_printf_has_long_long = yes; then
 746   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 747 fi
 748 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 749
 750 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 751 dnl because autoconf complains about cross-compilation issues.  However, this
 752 dnl code uses the same variables as the macro for compatibility.
 753
 754 AC_MSG_CHECKING(for long double support in compiler)
 755 AC_CACHE_VAL(ac_cv_c_long_double,
 756 [AC_TRY_COMPILE(, [long double foo;],
 757 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 758 AC_MSG_RESULT($ac_cv_c_long_double)
 759 if test $ac_cv_c_long_double = yes; then
 760   AC_DEFINE(HAVE_LONG_DOUBLE)
 761 fi
 762
 763 dnl See if the compiler and runtime support printing long doubles
 764
 765 AC_MSG_CHECKING(for long double support in printf)
 766 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 767 [AC_TRY_RUN([
 768 int main () {
 769   char buf[16];
 770   long double f = 3.141592653;
 771   sprintf (buf, "%Lg", f);
 772   return (strncmp ("3.14159", buf, 7));
 773 }],
 774 gdb_cv_printf_has_long_double=yes,
 775 gdb_cv_printf_has_long_double=no,
 776 gdb_cv_printf_has_long_double=no)])
 777 if test $gdb_cv_printf_has_long_double = yes; then
 778   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 779 fi
 780 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 781
 782 dnl See if the compiler and runtime support scanning long doubles
 783
 784 AC_MSG_CHECKING(for long double support in scanf)
 785 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 786 [AC_TRY_RUN([
 787 int main () {
 788   char *buf = "3.141592653";
 789   long double f = 0;
 790   sscanf (buf, "%Lg", &f);
 791   return !(f > 3.14159 && f < 3.14160);
 792 }],
 793 gdb_cv_scanf_has_long_double=yes,
 794 gdb_cv_scanf_has_long_double=no,
 795 gdb_cv_scanf_has_long_double=no)])
 796 if test $gdb_cv_scanf_has_long_double = yes; then
 797   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 798 fi
 799 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 800
 801 case ${host_os} in
 802 aix*)
 803   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
 804     SAVE_LDFLAGS=$LDFLAGS
 805
 806     case $GCC in
 807     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
 808     *) gdb_cv_bigtoc=-bbigtoc ;;
 809     esac
 810
 811     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
 812     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
 813   ])
 814   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
 815   ;;
 816 esac
 817
 818
 819 dnl For certain native configurations, we need to check whether thread
 820 dnl support can be built in or not.
 821 dnl
 822 dnl Note that we only want this if we are both native (host == target),
 823 dnl and not doing a canadian cross build (build == host).
 824
 825 if test ${build} = ${host} -a ${host} = ${target} ; then
 826    case ${host_os} in
 827    hpux*)
 828       AC_MSG_CHECKING(for HPUX/OSF thread support)
 829       if test -f /usr/include/dce/cma_config.h ; then
 830          if test "$GCC" = "yes" ; then
 831             AC_MSG_RESULT(yes)
 832             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 833             CONFIG_LIB_OBS="${CONFIG_LIB_OBS} hpux-thread.o"
 834             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 835          else
 836             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 837          fi
 838       else
 839          AC_MSG_RESULT(no)
 840       fi
 841       ;;
 842    solaris*)
 843       # See if thread_db library is around for Solaris thread debugging.
 844       # Note that we must explicitly test for version 1 of the library
 845       # because version 0 (present on Solaris 2.4 or earlier) doesn't have
 846       # the same API.
 847       AC_MSG_CHECKING(for Solaris thread debugging library)
 848       if test -f /usr/lib/libthread_db.so.1 ; then
 849          AC_MSG_RESULT(yes)
 850          AC_DEFINE(HAVE_THREAD_DB_LIB)
 851          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} sol-thread.o"
 852          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 853          AC_CHECK_LIB(dl, dlopen)
 854          if test "$GCC" = "yes" ; then
 855             # The GNU linker requires the -export-dynamic option to make
 856             # all symbols visible in the dynamic symbol table.
 857             hold_ldflags=$LDFLAGS
 858             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 859             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 860             AC_TRY_LINK(, [int i;], found=yes, found=no)
 861             LDFLAGS=$hold_ldflags
 862             AC_MSG_RESULT($found)
 863             if test $found = yes; then
 864                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 865             fi
 866          fi
 867          # Sun randomly tweaked the prototypes in <proc_service.h>
 868          # at one point.
 869          AC_MSG_CHECKING(if <proc_service.h> is old)
 870          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 871             AC_TRY_COMPILE([
 872                 #include <proc_service.h>
 873                 ps_err_e ps_pdwrite
 874                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 875             ],, gdb_cv_proc_service_is_old=no,
 876                 gdb_cv_proc_service_is_old=yes)
 877          ])
 878          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 879          if test $gdb_cv_proc_service_is_old = yes; then
 880             AC_DEFINE(PROC_SERVICE_IS_OLD)
 881          fi
 882       else
 883          AC_MSG_RESULT(no)
 884       fi
 885       ;;
 886    aix*)
 887       AC_MSG_CHECKING(for AiX thread debugging library)
 888       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
 889                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
 890                                    [#ifndef PTHDB_VERSION_3
 891                                     #error
 892                                     #endif],
 893                                    gdb_cv_have_aix_thread_debug=yes,
 894                                    gdb_cv_have_aix_thread_debug=no)])
 895       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
 896       if test $gdb_cv_have_aix_thread_debug = yes; then
 897          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
 898          CONFIG_LIB_OBS="${CONFIG_LIB_OBS} aix-thread.o"
 899          CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -lpthdebug"
 900       fi
 901       ;;
 902    esac
 903    AC_SUBST(CONFIG_LDFLAGS)
 904 fi
 905
 906 dnl See if we have a thread_db header file that has TD_NOTALLOC.
 907 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
 908    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
 909                   gdb_cv_thread_db_h_has_td_notalloc,
 910      AC_TRY_COMPILE(
 911        [#include <thread_db.h>],
 912        [int i = TD_NOTALLOC;],
 913        gdb_cv_thread_db_h_has_td_notalloc=yes,
 914        gdb_cv_thread_db_h_has_td_notalloc=no
 915      )
 916    )
 917 fi
 918 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
 919   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
 920             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
 921 fi
 922
 923 dnl See if we have a sys/syscall header file that has __NR_tkill.
 924 if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then
 925    AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill],
 926                   gdb_cv_sys_syscall_h_has_tkill,
 927      AC_TRY_COMPILE(
 928        [#include <sys/syscall.h>],
 929        [int i = __NR_tkill;],
 930        gdb_cv_sys_syscall_h_has_tkill=yes,
 931        gdb_cv_sys_syscall_h_has_tkill=no
 932      )
 933    )
 934 fi
 935 dnl See if we can issue tkill syscall.
 936 if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes" && test "x$ac_cv_func_syscall" = "xyes"; then
 937   AC_DEFINE(HAVE_TKILL_SYSCALL, 1,
 938             [Define if we can use the tkill syscall.])
 939 fi
 940
 941 dnl Handle optional features that can be enabled.
 942
 943 AC_ARG_WITH(sysroot,
 944 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
 945 [
 946  case ${with_sysroot} in
 947  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
 948  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 949  esac
 950
 951  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 952
 953  if test "x$exec_prefix" = xNONE; then
 954   if test "x$prefix" = xNONE; then
 955    test_prefix=/usr/local
 956   else
 957    test_prefix=$prefix
 958   fi
 959  else
 960   test_prefix=$exec_prefix
 961  fi
 962  case ${TARGET_SYSTEM_ROOT} in
 963  "${test_prefix}"|"${test_prefix}/"*|\
 964  '${exec_prefix}'|'${exec_prefix}/'*)
 965    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 966    TARGET_SYSTEM_ROOT_DEFINE="$t"
 967    ;;
 968  esac
 969 ], [
 970  TARGET_SYSTEM_ROOT=
 971  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 972 ])
 973 AC_SUBST(TARGET_SYSTEM_ROOT)
 974 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 975
 976 # NOTE: Don't add -Wall or -Wunused, they both include
 977 # -Wunused-parameter which reports bogus warnings.
 978 # NOTE: If you add to this list, remember to update
 979 # gdb/doc/gdbint.texinfo.
 980 build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \
 981 -Wformat -Wparentheses -Wpointer-arith -Wuninitialized -Wformat-nonliteral"
 982 # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs
 983 # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value
 984 # -Wchar-subscripts -Wtraditional -Wshadow -Wcast-qual
 985 # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes
 986 # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls
 987 # -Woverloaded-virtual -Winline -Werror"
 988 AC_ARG_ENABLE(build-warnings,
 989 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 990 [case "${enableval}" in
 991   yes)  ;;
 992   no)   build_warnings="-w";;
 993   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 994         build_warnings="${build_warnings} ${t}";;
 995   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 996         build_warnings="${t} ${build_warnings}";;
 997   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 998 esac
 999 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1000   echo "Setting compiler warning flags = $build_warnings" 6>&1
1001 fi])dnl
1002 AC_ARG_ENABLE(gdb-build-warnings,
1003 [  --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used],
1004 [case "${enableval}" in
1005   yes)  ;;
1006   no)   build_warnings="-w";;
1007   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1008         build_warnings="${build_warnings} ${t}";;
1009   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
1010         build_warnings="${t} ${build_warnings}";;
1011   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
1012 esac
1013 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
1014   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
1015 fi])dnl
1016 WARN_CFLAGS=""
1017 WERROR_CFLAGS=""
1018 if test "x${build_warnings}" != x -a "x$GCC" = xyes
1019 then
1020     AC_MSG_CHECKING(compiler warning flags)
1021     # Separate out the -Werror flag as some files just cannot be
1022     # compiled with it enabled.
1023     for w in ${build_warnings}; do
1024         case $w in
1025         -Werr*) WERROR_CFLAGS=-Werror ;;
1026         *) # Check that GCC accepts it
1027             saved_CFLAGS="$CFLAGS"
1028             CFLAGS="$CFLAGS $w"
1029             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
1030             CFLAGS="$saved_CFLAGS"
1031         esac
1032     done
1033     AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS})
1034 fi
1035 AC_SUBST(WARN_CFLAGS)
1036 AC_SUBST(WERROR_CFLAGS)
1037
1038 MMALLOC_CFLAGS=
1039 MMALLOC=
1040 AC_SUBST(MMALLOC_CFLAGS)
1041 AC_SUBST(MMALLOC)
1042
1043 AC_ARG_WITH(mmalloc,
1044 [  --with-mmalloc          Use memory mapped malloc package],
1045 [case "${withval}" in
1046   yes)  want_mmalloc=true ;;
1047   no)   want_mmalloc=false;;
1048   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
1049 esac],[want_mmalloc=false])dnl
1050
1051 if test x$want_mmalloc = xtrue; then
1052    AC_DEFINE(USE_MMALLOC)
1053    AC_DEFINE(MMCHECK_FORCE)
1054    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
1055    MMALLOC='../mmalloc/libmmalloc.a'
1056 fi
1057
1058 # In the Cygwin environment, we need some additional flags.
1059 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1060 [AC_EGREP_CPP(lose, [
1061 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1062 lose
1063 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1064
1065
1066 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1067 SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o"
1068 case ${host} in
1069   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1070   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1071 esac
1072 AC_SUBST(SER_HARDWIRE)
1073
1074 # libreadline needs libuser32.a in a cygwin environment
1075 WIN32LIBS=
1076 if test x$gdb_cv_os_cygwin = xyes; then
1077     WIN32LIBS="-luser32"
1078     case "${target}" in
1079         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1080         ;;
1081     esac
1082 fi
1083 AC_SUBST(WIN32LIBS)
1084
1085 LIBGUI="../libgui/src/libgui.a"
1086 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1087 AC_SUBST(LIBGUI)
1088 AC_SUBST(GUI_CFLAGS_X)
1089
1090 WIN32LDAPP=
1091 AC_SUBST(WIN32LIBS)
1092 AC_SUBST(WIN32LDAPP)
1093
1094 configdir="unix"
1095
1096 GDBTKLIBS=
1097 if test "${enable_gdbtk}" = "yes"; then
1098
1099     # Gdbtk must have an absolute path to srcdir in order to run
1100     # properly when not installed.
1101     here=`pwd`
1102     cd ${srcdir}
1103     GDBTK_SRC_DIR=`pwd`
1104     cd $here
1105
1106     CY_AC_PATH_TCLCONFIG
1107     if test -z "${no_tcl}"; then
1108         CY_AC_LOAD_TCLCONFIG
1109         CY_AC_PATH_TKCONFIG
1110
1111         # now look for Tcl library stuff
1112
1113         case "${host}" in
1114         *-*-cygwin*)
1115             tcldir=../tcl/win/
1116             ;;
1117         *)
1118             tcldir=../tcl/unix/
1119             ;;
1120         esac
1121
1122         TCL_DEPS="${tcldir}${TCL_LIB_FILE}"
1123
1124         # If $no_tk is nonempty, then we can't do Tk, and there is no
1125         # point to doing Tcl.
1126         if test -z "${no_tk}"; then
1127            CY_AC_LOAD_TKCONFIG
1128            CY_AC_PATH_TCLH
1129            CY_AC_PATH_TKH
1130            CY_AC_PATH_ITCLH
1131            CY_AC_PATH_ITKH
1132
1133
1134            # now look for Tk library stuff
1135
1136            case "${host}" in
1137            *-*-cygwin*)
1138                tkdir=../tk/win/
1139                ;;
1140            *)
1141                tkdir=../tk/unix/
1142                ;;
1143            esac
1144
1145            TK_DEPS="${tkdir}${TK_LIB_FILE}"
1146
1147            # now look for Itcl library stuff
1148
1149            CY_AC_PATH_ITCLCONFIG
1150            if test -z "${no_itcl}"; then
1151              CY_AC_LOAD_ITCLCONFIG
1152
1153              ITCLLIB="${ITCL_BUILD_LIB_SPEC}"
1154              ITCL_DEPS="${ITCL_LIB_FULL_PATH}"
1155            fi
1156
1157
1158            # now look for Itk library stuff
1159            CY_AC_PATH_ITKCONFIG
1160            if test -z "${no_itcl}"; then
1161              CY_AC_LOAD_ITKCONFIG
1162
1163              ITKLIB="${ITK_BUILD_LIB_SPEC}"
1164              ITK_DEPS="${ITK_LIB_FULL_PATH}"
1165            fi
1166
1167            ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1168            # Tcl/Tk 8.1 require -fwritable strings.  I don't
1169            # know whether 8.2 will or not, but I bet it will.
1170            # I don't have to worry about 7.x since we don't support it.
1171            GDBTK_CFLAGS=""
1172            if test "$GCC" = "yes"; then
1173                if test "$TCL_VERSION" != "8.0" ; then
1174                    GDBTK_CFLAGS="-fwritable-strings"
1175                fi
1176            fi
1177
1178            # Include some libraries that Tcl and Tk want.
1179            TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1180            # Yes, the ordering seems wrong here.  But it isn't.
1181            # TK_LIBS is the list of libraries that need to be linked
1182            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1183            # were in LIBS then any link tests after this point would
1184            # try to include things like `$(LIBGUI)', which wouldn't work.
1185            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1186
1187            CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1188            CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1189            CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1190            CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_GDBTK_INITS)"
1191            CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)"
1192            CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)"
1193            CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)"
1194            CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)"
1195
1196            if test x$gdb_cv_os_cygwin = xyes; then
1197               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1198               WIN32LDAPP="-Wl,--subsystem,console"
1199               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1200            fi
1201         fi
1202     fi
1203
1204     configdirs="${configdirs} gdbtk"
1205 fi
1206
1207 AC_SUBST(X_CFLAGS)
1208 AC_SUBST(X_LDFLAGS)
1209 AC_SUBST(X_LIBS)
1210 AC_SUBST(TCL_DEPS)
1211 AC_SUBST(TK_DEPS)
1212 AC_SUBST(ITCLLIB)
1213 AC_SUBST(ITCL_DEPS)
1214 AC_SUBST(ITKLIB)
1215 AC_SUBST(ITK_DEPS)
1216 AC_SUBST(GDBTKLIBS)
1217 AC_SUBST(GDBTK_CFLAGS)
1218 AC_SUBST(GDBTK_SRC_DIR)
1219
1220 AC_PATH_X
1221
1222
1223 # Unlike the sim directory, whether a simulator is linked is controlled by
1224 # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file.
1225 # This code just checks for a few cases where we'd like to ignore those
1226 # definitions, even when they're present in the '.mt' file.  These cases
1227 # are when --disable-sim is specified, or if the simulator directory is
1228 # not part of the source tree.
1229 #
1230 AC_ARG_ENABLE(sim,
1231 [  --enable-sim            Link gdb with simulator],
1232 [echo "enable_sim = $enable_sim";
1233  echo "enableval = ${enableval}";
1234  case "${enableval}" in
1235   yes) ignore_sim=false ;;
1236   no)  ignore_sim=true ;;
1237   *)   ignore_sim=false ;;
1238  esac],
1239 [ignore_sim=false])
1240
1241 if test ! -d "${srcdir}/../sim"; then
1242   ignore_sim=true
1243 fi
1244
1245 if test "${ignore_sim}" = "true"; then
1246     IGNORE_SIM="SIM="
1247     IGNORE_SIM_OBS="SIM_OBS="
1248 else
1249     IGNORE_SIM=""
1250     IGNORE_SIM_OBS=""
1251     AC_DEFINE(WITH_SIM)
1252 fi
1253 AC_SUBST(IGNORE_SIM)
1254 AC_SUBST(IGNORE_SIM_OBS)
1255
1256 AC_SUBST(ENABLE_CFLAGS)
1257 AC_SUBST(PROFILE_CFLAGS)
1258
1259 AC_SUBST(CONFIG_OBS)
1260 AC_SUBST(CONFIG_LIB_OBS)
1261 AC_SUBST(CONFIG_DEPS)
1262 AC_SUBST(CONFIG_SRCS)
1263 AC_SUBST(CONFIG_INITS)
1264 AC_SUBST(CONFIG_ALL)
1265 AC_SUBST(CONFIG_CLEAN)
1266 AC_SUBST(CONFIG_INSTALL)
1267 AC_SUBST(CONFIG_UNINSTALL)
1268
1269 # target_subdir is used by the testsuite to find the target libraries.
1270 target_subdir=
1271 if test "${host}" != "${target}"; then
1272     target_subdir="${target_alias}/"
1273 fi
1274 AC_SUBST(target_subdir)
1275
1276 frags=
1277 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
1278 if test ! -f ${host_makefile_frag}; then
1279     # When building a native debuger the .mh file containing things
1280     # like NATDEPFILES is needed.  Cross debuggers don't need .mh
1281     # since it no longer contains anything useful.
1282     if test "${target}" = "${host}"; then
1283         AC_MSG_ERROR("*** Gdb does not support native target ${host}")
1284     else
1285         host_makefile_frag=/dev/null
1286     fi
1287 fi
1288 frags="$frags $host_makefile_frag"
1289
1290 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
1291 if test ! -f ${target_makefile_frag}; then
1292 AC_MSG_ERROR("*** Gdb does not support target ${target}")
1293 fi
1294 frags="$frags $target_makefile_frag"
1295
1296 AC_SUBST_FILE(host_makefile_frag)
1297 AC_SUBST_FILE(target_makefile_frag)
1298 AC_SUBST(frags)
1299
1300 changequote(,)dnl
1301 hostfile=`sed -n '
1302 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1303 ' ${host_makefile_frag}`
1304
1305 targetfile=`sed -n '
1306 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
1307 ' ${target_makefile_frag}`
1308
1309 GDB_MULTI_ARCH=`sed -n '
1310 s/GDB_MULTI_ARCH[       ]*=[    ]*\([^  ]*\)[   ]*/\1/p
1311 ' ${target_makefile_frag}`
1312
1313 if test "${target}" = "${host}"; then
1314 # We pick this up from the host configuration file (.mh) because we
1315 # do not have a native configuration Makefile fragment.
1316 nativefile=`sed -n '
1317 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
1318 ' ${host_makefile_frag}`
1319 fi
1320 changequote([,])
1321
1322 # New targets should just set gdb_multi_arch=yes in configure.tgt.
1323 # Old targets being converted can either do that or set GDB_MULTI_ARCH
1324 # in the target specific makefile frag.  Eventually gdb_multi_arch=yes
1325 # will be the default.
1326 if test x"${GDB_MULTI_ARCH}" = x ; then
1327     case "${gdb_multi_arch}" in
1328     yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;;
1329     no ) GDB_MULTI_ARCH=0 ;;
1330     0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;;
1331     esac
1332 fi
1333 if test x"${GDB_MULTI_ARCH}" != x ; then
1334     AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH})
1335 fi
1336 # Warn the user when they use an old practice
1337 case "${GDB_MULTI_ARCH}" in
1338     "" ) ;;
1339     0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 )
1340         AC_MSG_WARN("GDB: Target is not pure multi-arch") ;;
1341     GDB_MULTI_ARCH_PURE )
1342         if test x"${targetfile}" != x ; then
1343             AC_MSG_WARN("GDB: Ignoring TM_FILE in ${target_makefile_frag}")
1344             targetfile=""
1345         fi ;;
1346     *)  AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");;
1347 esac
1348
1349 if test x"${gdb_osabi}" != x ; then
1350     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
1351                        [Define to the default OS ABI for this configuration.])
1352 fi
1353
1354 # Enable multi-ice-gdb-server.
1355 AC_ARG_ENABLE(multi-ice,
1356 [  --enable-multi-ice      build the multi-ice-gdb-server],
1357   [case $enableval in
1358     yes | no)
1359       ;;
1360     *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;;
1361   esac])
1362 if test "x$enable_multi_ice" = xyes; then
1363   configdirs="$configdirs multi-ice"
1364 fi
1365
1366 # We only build gdbserver automatically if host and target are the same.
1367 if test "x$target" = "x$host"; then
1368   AC_MSG_CHECKING(whether gdbserver is supported on this host)
1369   if test "x$build_gdbserver" = xyes; then
1370     configdirs="$configdirs gdbserver"
1371     AC_MSG_RESULT(yes)
1372   else
1373     AC_MSG_RESULT(no)
1374   fi
1375 fi
1376
1377 AC_CONFIG_SUBDIRS($configdirs)
1378
1379 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
1380 # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty
1381 # version.
1382
1383 files=
1384 links=
1385
1386 rm -f xm.h
1387 xm_h=""
1388 if test "${hostfile}" != ""; then
1389     xm_h=xm.h
1390     GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}"
1391     files="${files} ${GDB_XM_FILE}"
1392     links="${links} xm.h"
1393     AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE})
1394 fi
1395 AC_SUBST(xm_h)
1396
1397 rm -f tm.h
1398 tm_h=""
1399 if test "${targetfile}" != ""; then
1400     tm_h=tm.h
1401     GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}"
1402     files="${files} ${GDB_TM_FILE}"
1403     links="${links} tm.h"
1404     AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE})
1405 fi
1406 AC_SUBST(tm_h)
1407
1408 rm -f nm.h
1409 nm_h=""
1410 if test "${nativefile}" != ""; then
1411     nm_h=nm.h
1412     GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}"
1413     files="${files} ${GDB_NM_FILE}"
1414     links="${links} nm.h"
1415     AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE})
1416 fi
1417 AC_SUBST(nm_h)
1418
1419 AC_LINK_FILES($files, $links)
1420
1421 dnl Check for exe extension set on certain hosts (e.g. Win32)
1422 AC_EXEEXT
1423
1424 dnl  Detect the character set used by this host.
1425
1426 dnl  At the moment, we just assume it's ISO-8859-1 (which is a
1427 dnl  superset of ASCII containing the characters needed for French,
1428 dnl  German, Spanish, Italian, and possibly others), but if were
1429 dnl  *were* to support any host character sets other than ISO-8859-1,
1430 dnl  here's where we'd detect it.
1431 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "ISO-8859-1",
1432           [Define to be a string naming the default host character set.])
1433
1434 AM_ICONV
1435
1436 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
1437 [
1438 dnl Autoconf doesn't provide a mechanism for modifying definitions
1439 dnl provided by makefile fragments.
1440 dnl
1441 if test "${nativefile}" = ""; then
1442         < Makefile \
1443         sed -e '/^NATDEPFILES[[         ]]*=.*\\$/,/[[^\\]]$/s/^/# /' \
1444             -e '/^NATDEPFILES[[         ]]*=/s/^/# /' \
1445         | sed -e '/^\(NATDEPFILES[[     ]]*[[+]]=[[     ]]*\)/s//# \1/' \
1446         > Makefile.tem
1447 mv -f Makefile.tem Makefile
1448 fi
1449
1450 changequote(,)dnl
1451 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
1452 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
1453 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
1454 mv -f Makefile.tmp Makefile
1455 changequote([,])dnl
1456
1457
1458 case x$CONFIG_HEADERS in
1459 xconfig.h:config.in)
1460 echo > stamp-h ;;
1461 esac
1462 ],
1463 [
1464 gdb_host_cpu=$gdb_host_cpu
1465 gdb_target_cpu=$gdb_target_cpu
1466 nativefile=$nativefile
1467 ])
1468
1469 exit 0