gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40 CONFIG_DEPS=
  41
  42 configdirs="doc testsuite"
  43
  44 dnl
  45 changequote(,)dnl
  46
  47 . ${srcdir}/configure.host
  48
  49 . ${srcdir}/configure.tgt
  50
  51 dnl
  52 changequote([,])dnl
  53
  54 AC_PROG_INSTALL
  55 AC_CHECK_TOOL(AR, ar)
  56 AC_CHECK_TOOL(RANLIB, ranlib, :)
  57 AC_PROG_YACC
  58 AC_PROG_AWK
  59
  60 AC_ARG_PROGRAM
  61
  62 AC_TYPE_SIGNAL
  63
  64 AC_HEADER_STDC
  65 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  66 AC_HEADER_STAT
  67
  68 AC_C_CONST
  69
  70 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction)
  71
  72 # If we are configured native on Linux, work around problems with sys/procfs.h
  73 if test "${target}" = "${host}"; then
  74   case "${host}" in
  75   i[[3456]]86-*-linux*)
  76         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  77         AC_DEFINE(sys_quotactl)
  78         ;;
  79   esac
  80 fi
  81
  82 AC_MSG_CHECKING([for gregset_t type])
  83 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  84 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  85 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  86 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  87 if test $gdb_cv_have_gregset_t = yes; then
  88   AC_DEFINE(HAVE_GREGSET_T)
  89 fi
  90
  91 AC_MSG_CHECKING([for fpregset_t type])
  92 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  93 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  94 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  95 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  96 if test $gdb_cv_have_fpregset_t = yes; then
  97   AC_DEFINE(HAVE_FPREGSET_T)
  98 fi
  99
 100 dnl See if host has libm.  This is usually needed by simulators.
 101 AC_CHECK_LIB(m, main)
 102
 103 dnl See if compiler supports "long long" type.
 104
 105 AC_MSG_CHECKING(for long long support in compiler)
 106 AC_CACHE_VAL(gdb_cv_c_long_long,
 107 [AC_TRY_COMPILE(, [
 108   extern long long foo;
 109   switch (foo & 2) { case 0: return 1; }
 110 ],
 111 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 112 AC_MSG_RESULT($gdb_cv_c_long_long)
 113 if test $gdb_cv_c_long_long = yes; then
 114   AC_DEFINE(CC_HAS_LONG_LONG)
 115 fi
 116
 117 dnl See if the compiler and runtime support printing long long
 118
 119 AC_MSG_CHECKING(for long long support in printf)
 120 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 121 [AC_TRY_RUN([
 122 int main () {
 123   char buf[32];
 124   long long l = 0;
 125   l = (l << 16) + 0x0123;
 126   l = (l << 16) + 0x4567;
 127   l = (l << 16) + 0x89ab;
 128   l = (l << 16) + 0xcdef;
 129   sprintf (buf, "0x%016llx", l);
 130   return (strcmp ("0x0123456789abcdef", buf));
 131 }],
 132 gdb_cv_printf_has_long_long=yes,
 133 gdb_cv_printf_has_long_long=no,
 134 gdb_cv_printf_has_long_long=no)])
 135 if test $gdb_cv_printf_has_long_long = yes; then
 136   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 137 fi
 138 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 139
 140 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 141 dnl because autoconf complains about cross-compilation issues.  However, this
 142 dnl code uses the same variables as the macro for compatibility.
 143
 144 AC_MSG_CHECKING(for long double support in compiler)
 145 AC_CACHE_VAL(ac_cv_c_long_double,
 146 [AC_TRY_COMPILE(, [long double foo;],
 147 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 148 AC_MSG_RESULT($ac_cv_c_long_double)
 149 if test $ac_cv_c_long_double = yes; then
 150   AC_DEFINE(HAVE_LONG_DOUBLE)
 151 fi
 152
 153 dnl See if the compiler and runtime support printing long doubles
 154
 155 AC_MSG_CHECKING(for long double support in printf)
 156 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 157 [AC_TRY_RUN([
 158 int main () {
 159   char buf[16];
 160   long double f = 3.141592653;
 161   sprintf (buf, "%Lg", f);
 162   return (strncmp ("3.14159", buf, 7));
 163 }],
 164 gdb_cv_printf_has_long_double=yes,
 165 gdb_cv_printf_has_long_double=no,
 166 gdb_cv_printf_has_long_double=no)])
 167 if test $gdb_cv_printf_has_long_double = yes; then
 168   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 169 fi
 170 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 171
 172 dnl See if the compiler and runtime support scanning long doubles
 173
 174 AC_MSG_CHECKING(for long double support in scanf)
 175 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 176 [AC_TRY_RUN([
 177 int main () {
 178   char *buf = "3.141592653";
 179   long double f = 0;
 180   sscanf (buf, "%Lg", &f);
 181   return !(f > 3.14159 && f < 3.14160);
 182 }],
 183 gdb_cv_scanf_has_long_double=yes,
 184 gdb_cv_scanf_has_long_double=no,
 185 gdb_cv_scanf_has_long_double=no)])
 186 if test $gdb_cv_scanf_has_long_double = yes; then
 187   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 188 fi
 189 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 190
 191 AC_FUNC_MMAP
 192
 193 BFD_NEED_DECLARATION(malloc)
 194 BFD_NEED_DECLARATION(realloc)
 195 BFD_NEED_DECLARATION(free)
 196
 197 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 198 dnl we must explicitly test for version 1 of the library because version 0
 199 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 200
 201 dnl Note that we only want this if we are both native (host == target), and
 202 dnl not doing a canadian cross build (build == host).
 203
 204 if test ${build} = ${host} -a ${host} = ${target} ; then
 205         case ${host_os} in
 206         hpux*)
 207                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 208                 if test -f /usr/include/dce/cma_config.h ; then
 209                         if test "$GCC" = "yes" ; then
 210                                 AC_MSG_RESULT(yes)
 211                                 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 212                                 CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 213                         else
 214                                 AC_MSG_RESULT(no (suppressed because you are not using GCC))
 215                         fi
 216                 else
 217                         AC_MSG_RESULT(no)
 218                 fi
 219                 ;;
 220         solaris*)
 221                 AC_MSG_CHECKING(for Solaris thread debugging library)
 222                 if test -f /usr/lib/libthread_db.so.1 ; then
 223                         AC_MSG_RESULT(yes)
 224                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 225                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 226                         AC_CHECK_LIB(dl, dlopen)
 227                         if test "$GCC" = "yes" ; then
 228                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 229                         fi
 230                 else
 231                         AC_MSG_RESULT(no)
 232                 fi
 233                 ;;
 234         esac
 235         AC_SUBST(CONFIG_LDFLAGS)
 236 fi
 237
 238 dnl Handle optional features that can be enabled.
 239 ENABLE_CFLAGS=
 240
 241 AC_ARG_ENABLE(netrom,
 242 [  --enable-netrom ],
 243 [case "${enableval}" in
 244 yes)    enable_netrom=yes ;;
 245 no)     enable_netrom=no ;;
 246 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 247 esac])
 248
 249 if test "${enable_netrom}" = "yes"; then
 250         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 251 fi
 252
 253 MMALLOC_CFLAGS=
 254 MMALLOC=
 255 AC_SUBST(MMALLOC_CFLAGS)
 256 AC_SUBST(MMALLOC)
 257
 258 AC_ARG_WITH(mmalloc,
 259 [  --with-mmalloc             use memory mapped malloc package],
 260 [case "${withval}" in
 261   yes)  want_mmalloc=true ;;
 262   no)   want_mmalloc=false;;
 263   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 264 esac],[want_mmalloc=false])dnl
 265
 266 if test x$want_mmalloc = xtrue; then
 267    AC_DEFINE(USE_MMALLOC)
 268    AC_DEFINE(FORCE_MMCHECK)
 269    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 270    MMALLOC='../mmalloc/libmmalloc.a'
 271 fi
 272
 273 # start-sanitize-gdbtk
 274 ENABLE_IDE=
 275 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 276 if test "$enable_ide" = yes; then
 277    enable_ide=yes
 278    ENABLE_IDE=1
 279 else
 280    enable_ide=no
 281 fi
 282 AC_SUBST(ENABLE_IDE)
 283
 284 ENABLE_GDBTK=
 285
 286 AC_ARG_ENABLE(gdbtk,
 287 [  --enable-gdbtk ],
 288 [case "${enableval}" in
 289     yes)
 290         case "$host" in
 291         *go32*)
 292             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 293             enable_gdbtk=no ;;
 294         *windows*)
 295             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 296             enable_gdbtk=no ;;
 297         *)
 298             enable_gdbtk=yes ;;
 299         esac ;;
 300     no)
 301         enable_gdbtk=no  ;;
 302     *)
 303         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 304 esac],
 305 [
 306 # Default is on for everything but go32 and cygwin32
 307 case "$host" in
 308     *go32* | *windows*)
 309         ;;
 310     *)
 311         enable_gdbtk=yes ;;
 312     esac
 313 ])
 314
 315 # In the cygwin32 environment, we need some additional flags.
 316 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 317 [AC_EGREP_CPP(lose, [
 318 #ifdef __CYGWIN32__
 319 lose
 320 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 321
 322 WIN32LIBS=
 323 WIN32LDAPP=
 324 AC_SUBST(WIN32LIBS)
 325 AC_SUBST(WIN32LDAPP)
 326
 327 if test x$gdb_cv_os_cygwin32 = xyes; then
 328     if test x$enable_ide = xyes; then
 329         WIN32LIBS="-ladvapi32"
 330     fi
 331 fi
 332
 333 configdir="unix"
 334
 335 if test "${enable_gdbtk}" = "yes"; then
 336
 337     CY_AC_PATH_TCLCONFIG
 338     if test -z "${no_tcl}"; then
 339         CY_AC_LOAD_TCLCONFIG
 340         CY_AC_PATH_TKCONFIG
 341
 342         # If $no_tk is nonempty, then we can't do Tk, and there is no
 343         # point to doing Tcl.
 344         if test -z "${no_tk}"; then
 345            CY_AC_LOAD_TKCONFIG
 346            CY_AC_PATH_TCLH
 347            CY_AC_PATH_TKH
 348            CY_AC_PATH_ITCLH
 349            CY_AC_PATH_TIX
 350
 351            # now look for tix library stuff
 352            TIXVERSION=4.1.8.0
 353            . ${ac_cv_c_tclconfig}/tclConfig.sh
 354            case "${host}" in
 355            *-*-cygwin32*)
 356                 tixdir=../tix/win/tcl8.0
 357                 ;;
 358            *)
 359                 tixdir=../tix/unix/tk8.0
 360                 ;;
 361            esac
 362            if test "${TCL_SHARED_BUILD}" = "1"; then
 363                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 364
 365                 # Can't win them all: SunOS 4 (others?) appends a version
 366                 # number after the ".so"
 367                 case "${host}" in
 368                 *-*-sunos4*)
 369                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 370                 esac
 371
 372            else
 373                 TIX_LIB_EXT=".a"
 374            fi
 375
 376            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 377                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 378                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 379            else
 380                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 381                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 382            fi
 383
 384            ENABLE_GDBTK=1
 385
 386            # Include some libraries that Tcl and Tk want.
 387            if test "${enable_ide}" = "yes"; then
 388               TCL_LIBS='$(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 389               CONFIG_DEPS='$(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 390            else
 391               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 392               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 393            fi
 394            # Yes, the ordering seems wrong here.  But it isn't.
 395            # TK_LIBS is the list of libraries that need to be linked
 396            # after Tcl/Tk.
 397            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 398            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 399
 400            if test x$gdb_cv_os_cygwin32 = xyes; then
 401               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 402               WIN32LDAPP="-Wl,--subsystem,windows"
 403            fi
 404         fi
 405     fi
 406 fi
 407
 408 AC_SUBST(ENABLE_GDBTK)
 409 AC_SUBST(X_CFLAGS)
 410 AC_SUBST(X_LDFLAGS)
 411 AC_SUBST(X_LIBS)
 412 AC_SUBST(TIXLIB)
 413 AC_SUBST(TIX_DEPS)
 414 # end-sanitize-gdbtk
 415
 416 AC_SUBST(ENABLE_CFLAGS)
 417
 418 AC_SUBST(CONFIG_OBS)
 419 AC_SUBST(CONFIG_DEPS)
 420
 421 # Begin stuff to support --enable-shared
 422 AC_ARG_ENABLE(shared,
 423 [  --enable-shared         use shared libraries],
 424 [case "${enableval}" in
 425   yes) shared=true ;;
 426   no)  shared=false ;;
 427   *) shared=true ;;
 428 esac])dnl
 429
 430 HLDFLAGS=
 431 HLDENV=
 432 # If we have shared libraries, try to set rpath reasonably.
 433 if test "${shared}" = "true"; then
 434   case "${host}" in
 435   *-*-hpux*)
 436     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 437     ;;
 438   *-*-irix5* | *-*-irix6*)
 439     HLDFLAGS='-Wl,-rpath,$(libdir)'
 440     ;;
 441   *-*-linux*aout*)
 442     ;;
 443   *-*-linux* | *-pc-linux-gnu)
 444     HLDFLAGS='-Wl,-rpath,$(libdir)'
 445     ;;
 446   *-*-solaris*)
 447     HLDFLAGS='-R $(libdir)'
 448     ;;
 449   *-*-sysv4*)
 450     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 451     ;;
 452   esac
 453 fi
 454
 455 # On SunOS, if the linker supports the -rpath option, use it to
 456 # prevent ../bfd and ../opcodes from being included in the run time
 457 # search path.
 458 case "${host}" in
 459   *-*-sunos*)
 460     echo 'main () { }' > conftest.c
 461     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 462     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 463       :
 464     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 465       :
 466     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 467       :
 468     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 469       :
 470     elif test "${shared}" = "true"; then
 471       HLDFLAGS='-Wl,-rpath=$(libdir)'
 472     else
 473       HLDFLAGS='-Wl,-rpath='
 474     fi
 475     rm -f conftest.t conftest.c conftest
 476     ;;
 477 esac
 478 AC_SUBST(HLDFLAGS)
 479 AC_SUBST(HLDENV)
 480 # End stuff to support --enable-shared
 481
 482 # target_subdir is used by the testsuite to find the target libraries.
 483 target_subdir=
 484 if test "${host}" != "${target}"; then
 485     target_subdir="${target_alias}/"
 486 fi
 487 AC_SUBST(target_subdir)
 488
 489 frags=
 490 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 491 if test ! -f ${host_makefile_frag}; then
 492 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 493 fi
 494 frags="$frags $host_makefile_frag"
 495
 496 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 497 if test ! -f ${target_makefile_frag}; then
 498 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 499 fi
 500 frags="$frags $target_makefile_frag"
 501
 502 AC_SUBST_FILE(host_makefile_frag)
 503 AC_SUBST_FILE(target_makefile_frag)
 504 AC_SUBST(frags)
 505
 506 changequote(,)dnl
 507 hostfile=`sed -n '
 508 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 509 ' ${host_makefile_frag}`
 510
 511 targetfile=`sed -n '
 512 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 513 ' ${target_makefile_frag}`
 514
 515 # these really aren't orthogonal true/false values of the same condition,
 516 # but shells are slow enough that I like to reuse the test conditions
 517 # whenever possible
 518 if test "${target}" = "${host}"; then
 519 nativefile=`sed -n '
 520 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 521 ' ${host_makefile_frag}`
 522 # else
 523 # GDBserver is only useful in a "native" enviroment
 524 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 525 fi
 526 changequote([,])
 527
 528 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 529 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 530 # corresponding links.  But we have to remove the xm.h files and tm.h
 531 # files anyway, e.g. when switching from "configure host" to
 532 # "configure none".
 533
 534 files=
 535 links=
 536 rm -f xm.h
 537 if test "${hostfile}" != ""; then
 538 files="${files} config/${gdb_host_cpu}/${hostfile}"
 539 links="${links} xm.h"
 540 fi
 541 rm -f tm.h
 542 if test "${targetfile}" != ""; then
 543 files="${files} config/${gdb_target_cpu}/${targetfile}"
 544 links="${links} tm.h"
 545 fi
 546 rm -f nm.h
 547 if test "${nativefile}" != ""; then
 548 files="${files} config/${gdb_host_cpu}/${nativefile}"
 549 links="${links} nm.h"
 550 else
 551 # A cross-only configuration.
 552 files="${files} config/nm-empty.h"
 553 links="${links} nm.h"
 554 fi
 555 # start-sanitize-gdbtk
 556 AC_PROG_LN_S
 557 # Make it possible to use the GUI without doing a full install
 558 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 559   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 560   echo linking $srcdir/gdbtcl to gdbtcl
 561   $LN_S $srcdir/gdbtcl gdbtcl
 562   else
 563   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 564   echo "         " make install before you are able to run the GUI.
 565   fi
 566 fi
 567 # end-sanitize-gdbtk
 568
 569 AC_LINK_FILES($files, $links)
 570
 571 dnl Check for exe extension set on certain hosts (e.g. Win32)
 572 AM_EXEEXT
 573
 574 AC_CONFIG_SUBDIRS($configdirs)
 575 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 576 [
 577 dnl Autoconf doesn't provide a mechanism for modifying definitions
 578 dnl provided by makefile fragments.
 579 dnl
 580 if test "${nativefile}" = ""; then
 581 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 582         < Makefile > Makefile.tem
 583 mv -f Makefile.tem Makefile
 584 fi
 585
 586 changequote(,)dnl
 587 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 588 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 589 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 590 mv -f Makefile.tmp Makefile
 591 changequote([,])dnl
 592
 593 case x$CONFIG_HEADERS in
 594 xconfig.h:config.in)
 595 echo > stamp-h ;;
 596 esac
 597 ],
 598 [
 599 gdb_host_cpu=$gdb_host_cpu
 600 gdb_target_cpu=$gdb_target_cpu
 601 nativefile=$nativefile
 602 ])
 603
 604 exit 0
 605