gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h limits.h link.h \
  72                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  73                  string.h strings.h sys/procfs.h sys/ptrace.h sys/reg.h \
  74                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  75                  wchar.h wctype.h asm/debugreg.h)
  76
  77 AC_HEADER_STAT
  78
  79 AC_C_CONST
  80
  81 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction isascii bzero bcopy \
  82                memcpy btowc)
  83 AC_FUNC_ALLOCA
  84
  85 BFD_NEED_DECLARATION(malloc)
  86 BFD_NEED_DECLARATION(realloc)
  87 BFD_NEED_DECLARATION(free)
  88 BFD_NEED_DECLARATION(strerror)
  89 BFD_NEED_DECLARATION(strdup)
  90
  91 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  92 if test "${target}" = "${host}"; then
  93   case "${host}" in
  94   i[[3456]]86-*-linux*)
  95         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  96         AC_DEFINE(sys_quotactl)
  97         ;;
  98   esac
  99 fi
 100
 101 AC_MSG_CHECKING([for gregset_t type])
 102 AC_CACHE_VAL(gdb_cv_have_gregset_t,
 103 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
 104 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
 105 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 106 if test $gdb_cv_have_gregset_t = yes; then
 107   AC_DEFINE(HAVE_GREGSET_T)
 108 fi
 109
 110 AC_MSG_CHECKING([for fpregset_t type])
 111 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 112 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 113 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 114 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 115 if test $gdb_cv_have_fpregset_t = yes; then
 116   AC_DEFINE(HAVE_FPREGSET_T)
 117 fi
 118
 119 dnl See if host has libm.  This is usually needed by simulators.
 120 AC_CHECK_LIB(m, main)
 121
 122 dnl See if compiler supports "long long" type.
 123
 124 AC_MSG_CHECKING(for long long support in compiler)
 125 AC_CACHE_VAL(gdb_cv_c_long_long,
 126 [AC_TRY_COMPILE(, [
 127   extern long long foo;
 128   switch (foo & 2) { case 0: return 1; }
 129 ],
 130 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 131 AC_MSG_RESULT($gdb_cv_c_long_long)
 132 if test $gdb_cv_c_long_long = yes; then
 133   AC_DEFINE(CC_HAS_LONG_LONG)
 134 fi
 135
 136 dnl See if the compiler and runtime support printing long long
 137
 138 AC_MSG_CHECKING(for long long support in printf)
 139 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 140 [AC_TRY_RUN([
 141 int main () {
 142   char buf[32];
 143   long long l = 0;
 144   l = (l << 16) + 0x0123;
 145   l = (l << 16) + 0x4567;
 146   l = (l << 16) + 0x89ab;
 147   l = (l << 16) + 0xcdef;
 148   sprintf (buf, "0x%016llx", l);
 149   return (strcmp ("0x0123456789abcdef", buf));
 150 }],
 151 gdb_cv_printf_has_long_long=yes,
 152 gdb_cv_printf_has_long_long=no,
 153 gdb_cv_printf_has_long_long=no)])
 154 if test $gdb_cv_printf_has_long_long = yes; then
 155   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 156 fi
 157 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 158
 159 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 160 dnl because autoconf complains about cross-compilation issues.  However, this
 161 dnl code uses the same variables as the macro for compatibility.
 162
 163 AC_MSG_CHECKING(for long double support in compiler)
 164 AC_CACHE_VAL(ac_cv_c_long_double,
 165 [AC_TRY_COMPILE(, [long double foo;],
 166 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 167 AC_MSG_RESULT($ac_cv_c_long_double)
 168 if test $ac_cv_c_long_double = yes; then
 169   AC_DEFINE(HAVE_LONG_DOUBLE)
 170 fi
 171
 172 dnl See if the compiler and runtime support printing long doubles
 173
 174 AC_MSG_CHECKING(for long double support in printf)
 175 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 176 [AC_TRY_RUN([
 177 int main () {
 178   char buf[16];
 179   long double f = 3.141592653;
 180   sprintf (buf, "%Lg", f);
 181   return (strncmp ("3.14159", buf, 7));
 182 }],
 183 gdb_cv_printf_has_long_double=yes,
 184 gdb_cv_printf_has_long_double=no,
 185 gdb_cv_printf_has_long_double=no)])
 186 if test $gdb_cv_printf_has_long_double = yes; then
 187   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 188 fi
 189 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 190
 191 dnl See if the compiler and runtime support scanning long doubles
 192
 193 AC_MSG_CHECKING(for long double support in scanf)
 194 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 195 [AC_TRY_RUN([
 196 int main () {
 197   char *buf = "3.141592653";
 198   long double f = 0;
 199   sscanf (buf, "%Lg", &f);
 200   return !(f > 3.14159 && f < 3.14160);
 201 }],
 202 gdb_cv_scanf_has_long_double=yes,
 203 gdb_cv_scanf_has_long_double=no,
 204 gdb_cv_scanf_has_long_double=no)])
 205 if test $gdb_cv_scanf_has_long_double = yes; then
 206   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 207 fi
 208 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 209
 210 AC_FUNC_MMAP
 211
 212 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 213 dnl we must explicitly test for version 1 of the library because version 0
 214 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 215
 216 dnl Note that we only want this if we are both native (host == target), and
 217 dnl not doing a canadian cross build (build == host).
 218
 219 if test ${build} = ${host} -a ${host} = ${target} ; then
 220    case ${host_os} in
 221    hpux*)
 222       AC_MSG_CHECKING(for HPUX/OSF thread support)
 223       if test -f /usr/include/dce/cma_config.h ; then
 224          if test "$GCC" = "yes" ; then
 225             AC_MSG_RESULT(yes)
 226             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 227             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 228             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 229          else
 230             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 231          fi
 232       else
 233          AC_MSG_RESULT(no)
 234       fi
 235       ;;
 236    solaris*)
 237       AC_MSG_CHECKING(for Solaris thread debugging library)
 238       if test -f /usr/lib/libthread_db.so.1 ; then
 239          AC_MSG_RESULT(yes)
 240          AC_DEFINE(HAVE_THREAD_DB_LIB)
 241          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 242          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 243          AC_CHECK_LIB(dl, dlopen)
 244          if test "$GCC" = "yes" ; then
 245             # The GNU linker requires the -export-dynamic option to make
 246             # all symbols visible in the dynamic symbol table.
 247             hold_ldflags=$LDFLAGS
 248             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 249             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 250             AC_TRY_LINK(, [int i;], found=yes, found=no)
 251             LDFLAGS=$hold_ldflags
 252             AC_MSG_RESULT($found)
 253             if test $found = yes; then
 254                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 255             fi
 256          fi
 257       else
 258          AC_MSG_RESULT(no)
 259       fi
 260       ;;
 261    esac
 262    AC_SUBST(CONFIG_LDFLAGS)
 263 fi
 264
 265 dnl Handle optional features that can be enabled.
 266 ENABLE_CFLAGS=
 267
 268 AC_ARG_ENABLE(netrom,
 269 [  --enable-netrom ],
 270 [case "${enableval}" in
 271 yes)    enable_netrom=yes ;;
 272 no)     enable_netrom=no ;;
 273 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 274 esac])
 275
 276 if test "${enable_netrom}" = "yes"; then
 277         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 278         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 279 fi
 280
 281 AC_ARG_ENABLE(warnings,
 282 [  --enable-build-warnings Enable compiler warnings if gcc is used],
 283 [case "${enableval}" in
 284 yes)    enable_build_warnings=yes ;;
 285 no)     enable_build_warnings=no ;;
 286 *)      AC_MSG_ERROR(bad value ${enableval} given for warnings options) ;;
 287 esac])
 288
 289 if test "x$enable_build_warnings" = xyes -a "x$GCC" = xyes
 290 then
 291    WARN_CFLAGS="-Wall -Wstrict-prototypes -Wmissing-prototypes"
 292 else
 293    WARN_CFLAGS=""
 294 fi
 295 AC_SUBST(WARN_CFLAGS)
 296
 297 MMALLOC_CFLAGS=
 298 MMALLOC=
 299 AC_SUBST(MMALLOC_CFLAGS)
 300 AC_SUBST(MMALLOC)
 301
 302 AC_ARG_WITH(mmalloc,
 303 [  --with-mmalloc          Use memory mapped malloc package],
 304 [case "${withval}" in
 305   yes)  want_mmalloc=true ;;
 306   no)   want_mmalloc=false;;
 307   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 308 esac],[want_mmalloc=false])dnl
 309
 310 if test x$want_mmalloc = xtrue; then
 311    AC_DEFINE(USE_MMALLOC)
 312    AC_DEFINE(MMCHECK_FORCE)
 313    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 314    MMALLOC='../mmalloc/libmmalloc.a'
 315 fi
 316
 317 # start-sanitize-carp
 318 # The below takes an educated guess at the targets that
 319 # should be built.  It is an interum version that provides
 320 # significant backward compatibility.
 321
 322 AC_ARG_ENABLE(carp,
 323 [  --enable-carp        Configure alternative readaptive paradigm ],
 324 [case "${enableval}" in
 325   yes) enable_carp=yes ;;
 326   no)  enable_carp=no ;;
 327   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 328 esac],[enable_carp=no])dnl
 329
 330 AC_ARG_ENABLE(targets,
 331 [  --enable-targets        alternative target configurations],
 332 [case "${enableval}" in
 333   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 334             ;;
 335   no)       enable_targets= ;;
 336   *)        enable_targets="$enableval" ;;
 337 esac])dnl
 338
 339 # Canonicalize the secondary target names.
 340 all_targets=false
 341 if test -n "$enable_targets" ; then
 342     if test "$enable_targets" = all ; then
 343         all_targets=true
 344     else
 345         for targ in `echo $enable_targets | sed 's/,/ /g'`
 346         do
 347             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 348             if test -n "$result" ; then
 349                 canon_targets="$canon_targets $result"
 350             fi
 351         done
 352     fi
 353 fi
 354
 355 # Convert the target names into GDB [*]-tdep.c names
 356 changequote(,)dnl
 357 selarchs=
 358 for targ in $target $canon_targets
 359 do
 360     if test "x$targ" = "xall" ; then
 361         all_targets=true
 362     else
 363         t_cpu=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 364         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 365         t_os=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 366         mt=`
 367 target=$targ
 368 target_cpu=$t_cpu
 369 target_vendor=$t_vendor
 370 target_os=$t_os
 371 . ${srcdir}/configure.tgt
 372 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 373         if test -r ${mt} ; then
 374             # This gets confused over .mt files that have multiple -tdep.o
 375             tdep=`sed -n '
 376 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 377 ' $mt`
 378             selarchs="$selarchs $tdep"
 379         fi
 380     fi
 381 done
 382 changequote([,])dnl
 383
 384 # We don't do any links based on the target system, just makefile config.
 385
 386 if test x${all_targets} = xfalse ; then
 387
 388     # Target architecture .o files.
 389     ta=
 390
 391     for arch in $selarchs
 392     do
 393         archdefs="$archdefs -DARCH_$arch"
 394         ta="$ta ${arch}-tdep.o"
 395         # Special cases
 396         case "$arch" in
 397         dvp)            ta="$ta mips-tdep.o dvp-tdep.o" ;;
 398         esac
 399     done
 400
 401     # Weed out duplicate .o files.
 402     f=""
 403     for i in $ta ; do
 404         case " $f " in
 405         *" $i "*) ;;
 406         *) f="$f $i" ;;
 407         esac
 408     done
 409     ta="$f"
 410
 411     # And duplicate -D flags.
 412     f=""
 413     for i in $archdefs ; do
 414         case " $f " in
 415         *" $i "*) ;;
 416         *) f="$f $i" ;;
 417         esac
 418     done
 419     archdefs="$f"
 420
 421     MACHINE_OBS="$ta"
 422
 423 else    # all_targets is true
 424     archdefs=-DARCH_all
 425     MACHINE_OBS='$(ALL_MACHINES)'
 426 fi
 427
 428 dnl Don't define an archdefs list
 429 dnl AC_SUBST(archdefs)
 430 dnl XXXX this name will change several more times
 431 if test "${enable_carp}" = yes ; then
 432     gdb_target=carp
 433     gdb_target_cpu=carp
 434 else
 435     MACHINE_OBS="# $MACHINE_OBS"
 436 fi
 437 AC_SUBST(MACHINE_OBS)
 438
 439 # end-sanitize-carp
 440 # start-sanitize-gdbtk
 441 # start-sanitize-ide
 442 ENABLE_IDE=
 443 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 444 if test "$enable_ide" = yes; then
 445    enable_ide=yes
 446    ENABLE_IDE=1
 447 else
 448    enable_ide=no
 449 fi
 450 AC_SUBST(ENABLE_IDE)
 451
 452 AC_ARG_WITH(foundry-libs,
 453 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 454 [FOUNDRY_LIB_BASE=${withval}])
 455 AC_SUBST(FOUNDRY_LIB_BASE)
 456
 457 #
 458 # This is the Foundry SDK
 459 #
 460 # These variables are used to determine where the Foundry libs and
 461 # header files are located.
 462 #
 463 if test "$FOUNDRY_LIB_BASE" != ""; then
 464     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 465     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 466     if test x$enable_ide = xyes; then
 467         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 468         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 469     else
 470         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 471     fi
 472     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 473     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 474     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 475 else
 476     LIBGUI="../libgui/src/libgui.a"
 477     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 478     if test x$enable_ide = xyes; then
 479         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 480         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 481     else
 482         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 483     fi
 484     LIBIDETCL="../libidetcl/src/libidetcl.a"
 485     LIBIDE="../libide/src/libide.a"
 486     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 487 fi
 488 AC_SUBST(LIBGUI)
 489 AC_SUBST(GUI_CFLAGS_X)
 490 AC_SUBST(IDE_CFLAGS_X)
 491 AC_SUBST(IDE_X)
 492 AC_SUBST(LIBIDETCL)
 493 AC_SUBST(LIBIDE)
 494 AC_SUBST(IDE_DEPS)
 495 # end-sanitize-ide
 496
 497 ENABLE_GDBTK=
 498
 499 AC_ARG_ENABLE(gdbtk,
 500 [  --enable-gdbtk          Enable GDBTK GUI front end],
 501 [case "${enableval}" in
 502     yes)
 503         case "$host" in
 504         *go32*)
 505             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 506             enable_gdbtk=no ;;
 507         *windows*)
 508             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 509             enable_gdbtk=no ;;
 510         *)
 511             enable_gdbtk=yes ;;
 512         esac ;;
 513     no)
 514         enable_gdbtk=no  ;;
 515     *)
 516         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 517 esac],
 518 [
 519 # Default is on for everything but go32 and cygwin32
 520 case "$host" in
 521     *go32* | *windows*)
 522         ;;
 523     *)
 524         enable_gdbtk=yes ;;
 525     esac
 526 ])
 527
 528 # In the cygwin32 environment, we need some additional flags.
 529 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 530 [AC_EGREP_CPP(lose, [
 531 #ifdef __CYGWIN32__
 532 lose
 533 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 534
 535 WIN32LIBS=
 536 WIN32LDAPP=
 537 AC_SUBST(WIN32LIBS)
 538 AC_SUBST(WIN32LDAPP)
 539
 540 WINDRES=${WINDRES-windres}
 541 AC_SUBST(WINDRES)
 542
 543 if test x$gdb_cv_os_cygwin32 = xyes; then
 544     if test x$enable_ide = xyes; then
 545         WIN32LIBS="-ladvapi32"
 546     fi
 547 fi
 548
 549 configdir="unix"
 550
 551 GDBTKLIBS=
 552 if test "${enable_gdbtk}" = "yes"; then
 553
 554     CY_AC_PATH_TCLCONFIG
 555     if test -z "${no_tcl}"; then
 556         CY_AC_LOAD_TCLCONFIG
 557         CY_AC_PATH_TKCONFIG
 558
 559         # If $no_tk is nonempty, then we can't do Tk, and there is no
 560         # point to doing Tcl.
 561         if test -z "${no_tk}"; then
 562            CY_AC_LOAD_TKCONFIG
 563            CY_AC_PATH_TCLH
 564            CY_AC_PATH_TKH
 565            CY_AC_PATH_ITCLH
 566            CY_AC_PATH_TIX
 567
 568            # now look for tix library stuff
 569            TIXVERSION=4.1.8.0
 570            . ${ac_cv_c_tclconfig}/tclConfig.sh
 571            case "${host}" in
 572            *-*-cygwin32*)
 573                 tixdir=../tix/win/tcl8.0
 574                 ;;
 575            *)
 576                 tixdir=../tix/unix/tk8.0
 577                 ;;
 578            esac
 579            if test "${TCL_SHARED_BUILD}" = "1"; then
 580                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 581
 582                 # Can't win them all: SunOS 4 (others?) appends a version
 583                 # number after the ".so"
 584                 case "${host}" in
 585                 *-*-sunos4*)
 586                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 587                 esac
 588
 589            else
 590                 TIX_LIB_EXT=".a"
 591            fi
 592
 593            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 594                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 595                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 596            else
 597                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 598                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 599            fi
 600
 601            ENABLE_GDBTK=1
 602            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 603
 604            # Include some libraries that Tcl and Tk want.
 605            if test "${enable_ide}" = "yes"; then
 606               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 607               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 608            else
 609               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 610               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 611            fi
 612            # Yes, the ordering seems wrong here.  But it isn't.
 613            # TK_LIBS is the list of libraries that need to be linked
 614            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 615            # were in LIBS then any link tests after this point would
 616            # try to include things like `$(LIBGUI)', which wouldn't work.
 617            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 618            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 619
 620            if test x$gdb_cv_os_cygwin32 = xyes; then
 621               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 622               WIN32LDAPP="-Wl,--subsystem,console"
 623               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 624            fi
 625         fi
 626     fi
 627 fi
 628
 629 AC_SUBST(ENABLE_GDBTK)
 630 AC_SUBST(X_CFLAGS)
 631 AC_SUBST(X_LDFLAGS)
 632 AC_SUBST(X_LIBS)
 633 AC_SUBST(TIXLIB)
 634 AC_SUBST(TIX_DEPS)
 635 AC_SUBST(GDBTKLIBS)
 636 # end-sanitize-gdbtk
 637
 638 AC_PATH_X
 639 # start-sanitize-sky
 640 # Enable GPU2 library for MIPS simulator
 641 AC_ARG_WITH(sim-gpu2,
 642 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 643 [case "${target}" in
 644   mips*-sky-*)
 645     if test -d "${withval}"
 646     then
 647       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 648     else
 649       AC_MSG_WARN([Directory ${withval} does not exist.])
 650     fi ;;
 651   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 652 esac])dnl
 653
 654 # Enable target accurate FP library
 655 AC_ARG_WITH(sim-funit,
 656 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 657 [case "${target}" in
 658   mips*-sky-*)
 659     if test -d "${withval}"
 660     then
 661       LIBS="${LIBS} -L${withval}/lib -lfunit"
 662     else
 663       AC_MSG_WARN([Directory ${withval} does not exist.])
 664     fi ;;
 665   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 666 esac])dnl
 667 # end-sanitize-sky
 668
 669 dnl Solaris puts wctype in /usr/lib/libw.a
 670 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 671
 672 AC_SUBST(ENABLE_CFLAGS)
 673
 674 AC_SUBST(CONFIG_OBS)
 675 AC_SUBST(CONFIG_DEPS)
 676 AC_SUBST(CONFIG_SRCS)
 677
 678 # Begin stuff to support --enable-shared
 679 AC_ARG_ENABLE(shared,
 680 [  --enable-shared         Use shared libraries],
 681 [case "${enableval}" in
 682   yes) shared=true ;;
 683   no)  shared=false ;;
 684   *) shared=true ;;
 685 esac])dnl
 686
 687 HLDFLAGS=
 688 HLDENV=
 689 # If we have shared libraries, try to set rpath reasonably.
 690 if test "${shared}" = "true"; then
 691   case "${host}" in
 692   *-*-hpux*)
 693     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 694     ;;
 695   *-*-irix5* | *-*-irix6*)
 696     HLDFLAGS='-Wl,-rpath,$(libdir)'
 697     ;;
 698   *-*-linux*aout*)
 699     ;;
 700   *-*-linux* | *-pc-linux-gnu)
 701     HLDFLAGS='-Wl,-rpath,$(libdir)'
 702     ;;
 703   *-*-solaris*)
 704     HLDFLAGS='-R $(libdir)'
 705     ;;
 706   *-*-sysv4*)
 707     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 708     ;;
 709   esac
 710 fi
 711
 712 # On SunOS, if the linker supports the -rpath option, use it to
 713 # prevent ../bfd and ../opcodes from being included in the run time
 714 # search path.
 715 case "${host}" in
 716   *-*-sunos*)
 717     echo 'main () { }' > conftest.c
 718     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 719     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 720       :
 721     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 722       :
 723     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 724       :
 725     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 726       :
 727     elif test "${shared}" = "true"; then
 728       HLDFLAGS='-Wl,-rpath=$(libdir)'
 729     else
 730       HLDFLAGS='-Wl,-rpath='
 731     fi
 732     rm -f conftest.t conftest.c conftest
 733     ;;
 734 esac
 735 AC_SUBST(HLDFLAGS)
 736 AC_SUBST(HLDENV)
 737 # End stuff to support --enable-shared
 738
 739 # target_subdir is used by the testsuite to find the target libraries.
 740 target_subdir=
 741 if test "${host}" != "${target}"; then
 742     target_subdir="${target_alias}/"
 743 fi
 744 AC_SUBST(target_subdir)
 745
 746 frags=
 747 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 748 if test ! -f ${host_makefile_frag}; then
 749 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 750 fi
 751 frags="$frags $host_makefile_frag"
 752
 753 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 754 if test ! -f ${target_makefile_frag}; then
 755 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 756 fi
 757 frags="$frags $target_makefile_frag"
 758
 759 AC_SUBST_FILE(host_makefile_frag)
 760 AC_SUBST_FILE(target_makefile_frag)
 761 AC_SUBST(frags)
 762
 763 changequote(,)dnl
 764 hostfile=`sed -n '
 765 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 766 ' ${host_makefile_frag}`
 767
 768 targetfile=`sed -n '
 769 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 770 ' ${target_makefile_frag}`
 771
 772 # these really aren't orthogonal true/false values of the same condition,
 773 # but shells are slow enough that I like to reuse the test conditions
 774 # whenever possible
 775 if test "${target}" = "${host}"; then
 776 nativefile=`sed -n '
 777 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 778 ' ${host_makefile_frag}`
 779 # else
 780 # GDBserver is only useful in a "native" enviroment
 781 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 782 fi
 783 changequote([,])
 784
 785 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 786 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 787 # corresponding links.  But we have to remove the xm.h files and tm.h
 788 # files anyway, e.g. when switching from "configure host" to
 789 # "configure none".
 790
 791 files=
 792 links=
 793 rm -f xm.h
 794 if test "${hostfile}" != ""; then
 795 files="${files} config/${gdb_host_cpu}/${hostfile}"
 796 links="${links} xm.h"
 797 fi
 798 rm -f tm.h
 799 if test "${targetfile}" != ""; then
 800 files="${files} config/${gdb_target_cpu}/${targetfile}"
 801 links="${links} tm.h"
 802 fi
 803 rm -f nm.h
 804 if test "${nativefile}" != ""; then
 805 files="${files} config/${gdb_host_cpu}/${nativefile}"
 806 links="${links} nm.h"
 807 else
 808 # A cross-only configuration.
 809 files="${files} config/nm-empty.h"
 810 links="${links} nm.h"
 811 fi
 812 # start-sanitize-gdbtk
 813 AC_PROG_LN_S
 814 # Make it possible to use the GUI without doing a full install
 815 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 816   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 817   echo linking $srcdir/gdbtcl2 to gdbtcl2
 818   $LN_S $srcdir/gdbtcl2 gdbtcl2
 819   else
 820   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 821   echo "         " make install before you are able to run the GUI.
 822   fi
 823 fi
 824 # end-sanitize-gdbtk
 825
 826 AC_LINK_FILES($files, $links)
 827
 828 dnl Check for exe extension set on certain hosts (e.g. Win32)
 829 AM_EXEEXT
 830
 831 AC_CONFIG_SUBDIRS($configdirs)
 832 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 833 [
 834 dnl Autoconf doesn't provide a mechanism for modifying definitions
 835 dnl provided by makefile fragments.
 836 dnl
 837 if test "${nativefile}" = ""; then
 838 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 839         < Makefile > Makefile.tem
 840 mv -f Makefile.tem Makefile
 841 fi
 842
 843 changequote(,)dnl
 844 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 845 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 846 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 847 mv -f Makefile.tmp Makefile
 848 changequote([,])dnl
 849
 850 case x$CONFIG_HEADERS in
 851 xconfig.h:config.in)
 852 echo > stamp-h ;;
 853 esac
 854 ],
 855 [
 856 gdb_host_cpu=$gdb_host_cpu
 857 gdb_target_cpu=$gdb_target_cpu
 858 nativefile=$nativefile
 859 ])
 860
 861 exit 0
 862