gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998, 1999 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.12.1)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29 AM_PROG_CC_STDC
  30
  31 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  32 AC_CANONICAL_SYSTEM
  33
  34 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  35 dnl link with the correct libraries.
  36 ALL_LINGUAS=
  37 CY_GNU_GETTEXT
  38
  39 dnl List of object files added by configure.
  40
  41 CONFIG_OBS=
  42 CONFIG_DEPS=
  43 CONFIG_SRCS=
  44
  45 configdirs="doc testsuite"
  46
  47 dnl
  48 changequote(,)dnl
  49
  50 . ${srcdir}/configure.host
  51
  52 . ${srcdir}/configure.tgt
  53
  54 dnl
  55 changequote([,])dnl
  56
  57 AC_PROG_INSTALL
  58 AC_CHECK_TOOL(AR, ar)
  59 AC_CHECK_TOOL(RANLIB, ranlib, :)
  60 AC_PROG_YACC
  61
  62 AC_ARG_PROGRAM
  63
  64 AC_TYPE_SIGNAL
  65
  66 AC_HEADER_STDC
  67 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h link.h \
  68                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  69                  string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  70                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  71                  wchar.h wctype.h asm/debugreg.h)
  72
  73 AC_HEADER_STAT
  74
  75 AC_C_CONST
  76
  77 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc)
  78 AC_FUNC_ALLOCA
  79
  80 BFD_NEED_DECLARATION(malloc)
  81 BFD_NEED_DECLARATION(realloc)
  82 BFD_NEED_DECLARATION(free)
  83 BFD_NEED_DECLARATION(strerror)
  84 BFD_NEED_DECLARATION(strdup)
  85
  86 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  87 if test "${target}" = "${host}"; then
  88   case "${host}" in
  89   i[[3456]]86-*-linux*)
  90         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  91         AC_DEFINE(sys_quotactl)
  92         ;;
  93   esac
  94 fi
  95
  96 AC_MSG_CHECKING([for gregset_t type])
  97 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  98 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  99 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
 100 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 101 if test $gdb_cv_have_gregset_t = yes; then
 102   AC_DEFINE(HAVE_GREGSET_T)
 103 fi
 104
 105 AC_MSG_CHECKING([for fpregset_t type])
 106 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 107 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 108 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 109 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 110 if test $gdb_cv_have_fpregset_t = yes; then
 111   AC_DEFINE(HAVE_FPREGSET_T)
 112 fi
 113
 114 dnl See if host has libm.  This is usually needed by simulators.
 115 AC_CHECK_LIB(m, main)
 116
 117 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 118 dnl
 119 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 120 dnl under Solaris 2.6 because it is some funky empty library.
 121 dnl So only link in libw if we have to.
 122 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 123
 124 dnl Figure out which term library to use.
 125 TERM_LIB=
 126 AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses,
 127   AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib,
 128     AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap,
 129       AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses,
 130         AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo)))))
 131
 132 if test "x$TERM_LIB" = x
 133 then
 134   AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!)
 135 fi
 136
 137 AC_SUBST(TERM_LIB)
 138
 139 dnl See if compiler supports "long long" type.
 140
 141 AC_MSG_CHECKING(for long long support in compiler)
 142 AC_CACHE_VAL(gdb_cv_c_long_long,
 143 [AC_TRY_COMPILE(, [
 144   extern long long foo;
 145   switch (foo & 2) { case 0: return 1; }
 146 ],
 147 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 148 AC_MSG_RESULT($gdb_cv_c_long_long)
 149 if test $gdb_cv_c_long_long = yes; then
 150   AC_DEFINE(CC_HAS_LONG_LONG)
 151 fi
 152
 153 dnl See if the compiler and runtime support printing long long
 154
 155 AC_MSG_CHECKING(for long long support in printf)
 156 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 157 [AC_TRY_RUN([
 158 int main () {
 159   char buf[32];
 160   long long l = 0;
 161   l = (l << 16) + 0x0123;
 162   l = (l << 16) + 0x4567;
 163   l = (l << 16) + 0x89ab;
 164   l = (l << 16) + 0xcdef;
 165   sprintf (buf, "0x%016llx", l);
 166   return (strcmp ("0x0123456789abcdef", buf));
 167 }],
 168 gdb_cv_printf_has_long_long=yes,
 169 gdb_cv_printf_has_long_long=no,
 170 gdb_cv_printf_has_long_long=no)])
 171 if test $gdb_cv_printf_has_long_long = yes; then
 172   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 173 fi
 174 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 175
 176 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 177 dnl because autoconf complains about cross-compilation issues.  However, this
 178 dnl code uses the same variables as the macro for compatibility.
 179
 180 AC_MSG_CHECKING(for long double support in compiler)
 181 AC_CACHE_VAL(ac_cv_c_long_double,
 182 [AC_TRY_COMPILE(, [long double foo;],
 183 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 184 AC_MSG_RESULT($ac_cv_c_long_double)
 185 if test $ac_cv_c_long_double = yes; then
 186   AC_DEFINE(HAVE_LONG_DOUBLE)
 187 fi
 188
 189 dnl See if the compiler and runtime support printing long doubles
 190
 191 AC_MSG_CHECKING(for long double support in printf)
 192 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 193 [AC_TRY_RUN([
 194 int main () {
 195   char buf[16];
 196   long double f = 3.141592653;
 197   sprintf (buf, "%Lg", f);
 198   return (strncmp ("3.14159", buf, 7));
 199 }],
 200 gdb_cv_printf_has_long_double=yes,
 201 gdb_cv_printf_has_long_double=no,
 202 gdb_cv_printf_has_long_double=no)])
 203 if test $gdb_cv_printf_has_long_double = yes; then
 204   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 205 fi
 206 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 207
 208 dnl See if the compiler and runtime support scanning long doubles
 209
 210 AC_MSG_CHECKING(for long double support in scanf)
 211 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 212 [AC_TRY_RUN([
 213 int main () {
 214   char *buf = "3.141592653";
 215   long double f = 0;
 216   sscanf (buf, "%Lg", &f);
 217   return !(f > 3.14159 && f < 3.14160);
 218 }],
 219 gdb_cv_scanf_has_long_double=yes,
 220 gdb_cv_scanf_has_long_double=no,
 221 gdb_cv_scanf_has_long_double=no)])
 222 if test $gdb_cv_scanf_has_long_double = yes; then
 223   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 224 fi
 225 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 226
 227 AC_FUNC_MMAP
 228
 229 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 230 dnl we must explicitly test for version 1 of the library because version 0
 231 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 232
 233 dnl Note that we only want this if we are both native (host == target), and
 234 dnl not doing a canadian cross build (build == host).
 235
 236 if test ${build} = ${host} -a ${host} = ${target} ; then
 237    case ${host_os} in
 238    hpux*)
 239       AC_MSG_CHECKING(for HPUX/OSF thread support)
 240       if test -f /usr/include/dce/cma_config.h ; then
 241          if test "$GCC" = "yes" ; then
 242             AC_MSG_RESULT(yes)
 243             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 244             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 245             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 246          else
 247             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 248          fi
 249       else
 250          AC_MSG_RESULT(no)
 251       fi
 252       ;;
 253    solaris*)
 254       AC_MSG_CHECKING(for Solaris thread debugging library)
 255       if test -f /usr/lib/libthread_db.so.1 ; then
 256          AC_MSG_RESULT(yes)
 257          AC_DEFINE(HAVE_THREAD_DB_LIB)
 258          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 259          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 260          AC_CHECK_LIB(dl, dlopen)
 261          if test "$GCC" = "yes" ; then
 262             # The GNU linker requires the -export-dynamic option to make
 263             # all symbols visible in the dynamic symbol table.
 264             hold_ldflags=$LDFLAGS
 265             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 266             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 267             AC_TRY_LINK(, [int i;], found=yes, found=no)
 268             LDFLAGS=$hold_ldflags
 269             AC_MSG_RESULT($found)
 270             if test $found = yes; then
 271                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 272             fi
 273          fi
 274          # Sun randomly tweaked the prototypes in <proc_service.h>
 275          # at one point.
 276          AC_MSG_CHECKING(if <proc_service.h> is old)
 277          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 278             AC_TRY_COMPILE([
 279                 #include <proc_service.h>
 280                 ps_err_e ps_pdwrite
 281                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 282             ],, gdb_cv_proc_service_is_old=no,
 283                 gdb_cv_proc_service_is_old=yes)
 284          ])
 285          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 286          if test $gdb_cv_proc_service_is_old = yes; then
 287             AC_DEFINE(PROC_SERVICE_IS_OLD)
 288          fi
 289       else
 290          AC_MSG_RESULT(no)
 291       fi
 292       ;;
 293    esac
 294    AC_SUBST(CONFIG_LDFLAGS)
 295 fi
 296
 297 dnl Handle optional features that can be enabled.
 298 ENABLE_CFLAGS=
 299
 300 AC_ARG_ENABLE(tui,
 301 [  --enable-tui            Enable full-screen terminal user interface],
 302 [
 303   case "${enable_tui}" in
 304     yes | no) ;;
 305     "")  enable_tui=yes ;;
 306     *)
 307       AC_MSG_ERROR(Bad value for --enable-tui: ${enableval})
 308     ;;
 309   esac
 310 ])
 311 case ${enable_tui} in
 312   "yes" )
 313     AC_DEFINE(TUI)
 314     BUILD_TUI=all-tui
 315     TUI_LIBRARY=tui/libtui.a
 316   ;;
 317   * )
 318     BUILD_TUI=
 319     TUI_LIBRARY=
 320   ;;
 321 esac
 322 AC_SUBST(BUILD_TUI)
 323 AC_SUBST(TUI_LIBRARY)
 324
 325 AC_ARG_ENABLE(netrom,
 326 [  --enable-netrom         Enable NetROM support],
 327 [case "${enableval}" in
 328 yes)    enable_netrom=yes ;;
 329 no)     enable_netrom=no ;;
 330 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 331 esac])
 332
 333 if test "${enable_netrom}" = "yes"; then
 334         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 335         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 336 fi
 337
 338 AC_ARG_ENABLE(build-warnings,
 339 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
 340 [build_warnings="-Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations"
 341 case "${enableval}" in
 342   yes)  ;;
 343   no)   build_warnings="-w";;
 344   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 345         build_warnings="${build_warnings} ${t}";;
 346   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
 347         build_warnings="${t} ${build_warnings}";;
 348   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
 349 esac],[build_warnings=""])dnl
 350
 351 if test "x${build_warnings}" != x -a "x$GCC" = xyes
 352 then
 353    WARN_CFLAGS="${build_warnings}"
 354 else
 355    WARN_CFLAGS=""
 356 fi
 357 AC_SUBST(WARN_CFLAGS)
 358
 359 MMALLOC_CFLAGS=
 360 MMALLOC=
 361 AC_SUBST(MMALLOC_CFLAGS)
 362 AC_SUBST(MMALLOC)
 363
 364 AC_ARG_WITH(mmalloc,
 365 [  --with-mmalloc          Use memory mapped malloc package],
 366 [case "${withval}" in
 367   yes)  want_mmalloc=true ;;
 368   no)   want_mmalloc=false;;
 369   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 370 esac],[want_mmalloc=false])dnl
 371
 372 if test x$want_mmalloc = xtrue; then
 373    AC_DEFINE(USE_MMALLOC)
 374    AC_DEFINE(MMCHECK_FORCE)
 375    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 376    MMALLOC='../mmalloc/libmmalloc.a'
 377 fi
 378
 379 # start-sanitize-carp
 380 # The below takes an educated guess at the targets that
 381 # should be built.  It is an interum version that provides
 382 # significant backward compatibility.
 383
 384 AC_ARG_ENABLE(carp,
 385 [  --enable-carp           Configure alternative readaptive paradigm ],
 386 [case "${enableval}" in
 387   yes) enable_carp=yes ;;
 388   no)  enable_carp=no ;;
 389   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 390 esac],[enable_carp=no])dnl
 391
 392 AC_ARG_ENABLE(targets,
 393 [  --enable-targets        alternative target configurations],
 394 [case "${enableval}" in
 395   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 396             ;;
 397   no)       enable_targets= ;;
 398   *)        enable_targets="$enableval" ;;
 399 esac])dnl
 400
 401 # Canonicalize the secondary target names.
 402 all_targets=false
 403 if test -n "$enable_targets" ; then
 404     if test "$enable_targets" = all ; then
 405         all_targets=true
 406     else
 407         for targ in `echo $enable_targets | sed 's/,/ /g'`
 408         do
 409             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 410             if test -n "$result" ; then
 411                 canon_targets="$canon_targets $result"
 412             fi
 413         done
 414     fi
 415 fi
 416
 417 # Convert the target names into GDB [*]-tdep.c names
 418 changequote(,)dnl
 419 selarchs=
 420 for targ in $target $canon_targets
 421 do
 422     if test "x$targ" = "xall" ; then
 423         all_targets=true
 424     else
 425         t_cpu=`echo $targ    | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 426         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 427         t_os=`echo $targ     | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 428         mt=`
 429 target=$targ
 430 target_cpu=$t_cpu
 431 target_vendor=$t_vendor
 432 target_os=$t_os
 433 . ${srcdir}/configure.tgt
 434 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 435         if test -r ${mt} ; then
 436             # This gets confused over .mt files that have multiple -tdep.o
 437             tdep=`sed -n '
 438 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 439 ' $mt`
 440             selarchs="$selarchs $tdep"
 441         fi
 442     fi
 443 done
 444 changequote([,])dnl
 445
 446 # We don't do any links based on the target system, just makefile config.
 447
 448 if test x${all_targets} = xfalse ; then
 449
 450     # Target architecture .o files.
 451     ta=
 452
 453     for arch in $selarchs
 454     do
 455         archdefs="$archdefs -DARCH_$arch"
 456         ta="$ta ${arch}-tdep.o"
 457         # Special cases
 458         case "$arch" in
 459             dvp)  ta="$ta mips-tdep.o dvp-tdep.o" ;;
 460         esac
 461     done
 462
 463     # Weed out duplicate .o files.
 464     f=""
 465     for i in $ta ; do
 466         case " $f " in
 467             *" $i "*) ;;
 468             *) f="$f $i" ;;
 469         esac
 470     done
 471     ta="$f"
 472
 473     # And duplicate -D flags.
 474     f=""
 475     for i in $archdefs ; do
 476         case " $f " in
 477             *" $i "*) ;;
 478             *) f="$f $i" ;;
 479         esac
 480     done
 481     archdefs="$f"
 482
 483     MACHINE_OBS="$ta"
 484
 485 else    # all_targets is true
 486     archdefs=-DARCH_all
 487     MACHINE_OBS='$(ALL_MACHINES)'
 488 fi
 489
 490 dnl Don't define an archdefs list
 491 dnl AC_SUBST(archdefs)
 492 dnl XXXX this name will change several more times
 493 if test "${enable_carp}" = yes ; then
 494     gdb_target=carp
 495     gdb_target_cpu=carp
 496 else
 497     MACHINE_OBS="# $MACHINE_OBS"
 498 fi
 499 AC_SUBST(MACHINE_OBS)
 500
 501 # end-sanitize-carp
 502 # start-sanitize-gdbtk
 503 # start-sanitize-ide
 504 ENABLE_IDE=
 505 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 506 if test "$enable_ide" = yes; then
 507    enable_ide=yes
 508    ENABLE_IDE=1
 509 else
 510    enable_ide=no
 511 fi
 512 AC_SUBST(ENABLE_IDE)
 513
 514 AC_ARG_WITH(foundry-libs,
 515 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 516 [FOUNDRY_LIB_BASE=${withval}])
 517 AC_SUBST(FOUNDRY_LIB_BASE)
 518
 519 #
 520 # This is the Foundry SDK
 521 #
 522 # These variables are used to determine where the Foundry libs and
 523 # header files are located.
 524 #
 525 if test "$FOUNDRY_LIB_BASE" != ""; then
 526     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 527     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 528     if test x$enable_ide = xyes; then
 529         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 530         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 531     else
 532         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 533     fi
 534     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 535     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 536     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 537 else
 538 # end-sanitize-ide
 539     LIBGUI="../libgui/src/libgui.a"
 540     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 541 # start-sanitize-ide
 542     if test x$enable_ide = xyes; then
 543         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 544         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 545     else
 546         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 547     fi
 548     LIBIDETCL="../libidetcl/src/libidetcl.a"
 549     LIBIDE="../libide/src/libide.a"
 550     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 551 fi
 552
 553 # end-sanitize-ide
 554 AC_SUBST(LIBGUI)
 555 AC_SUBST(GUI_CFLAGS_X)
 556 # start-sanitize-ide
 557 AC_SUBST(IDE_CFLAGS_X)
 558 AC_SUBST(IDE_X)
 559 AC_SUBST(LIBIDETCL)
 560 AC_SUBST(LIBIDE)
 561 AC_SUBST(IDE_DEPS)
 562 # end-sanitize-ide
 563
 564 ENABLE_GDBTK=
 565
 566 AC_ARG_ENABLE(gdbtk,
 567 [  --enable-gdbtk          Enable GDBTK GUI front end],
 568 [case "${enableval}" in
 569     yes)
 570         case "$host" in
 571         *go32*)
 572             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 573             enable_gdbtk=no ;;
 574         *windows*)
 575             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 576             enable_gdbtk=no ;;
 577         *)
 578             enable_gdbtk=yes ;;
 579         esac ;;
 580     no)
 581         enable_gdbtk=no  ;;
 582     *)
 583         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 584 esac],
 585 [
 586 # Default is on for everything but go32 and Cygwin
 587 case "$host" in
 588     *go32* | *windows*)
 589         ;;
 590     *)
 591         enable_gdbtk=yes ;;
 592     esac
 593 ])
 594
 595 # In the Cygwin environment, we need some additional flags.
 596 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
 597 [AC_EGREP_CPP(lose, [
 598 #ifdef __CYGWIN32__
 599 lose
 600 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
 601
 602 WIN32LIBS=
 603 WIN32LDAPP=
 604 AC_SUBST(WIN32LIBS)
 605 AC_SUBST(WIN32LDAPP)
 606
 607 DLLTOOL=${DLLTOOL-dlltool}
 608 WINDRES=${WINDRES-windres}
 609 AC_SUBST(DLLTOOL)
 610 AC_SUBST(WINDRES)
 611
 612 if test x$gdb_cv_os_cygwin = xyes; then
 613     if test x$enable_ide = xyes; then
 614         WIN32LIBS="-ladvapi32"
 615     fi
 616 fi
 617
 618 configdir="unix"
 619
 620 GDBTKLIBS=
 621 if test "${enable_gdbtk}" = "yes"; then
 622
 623     CY_AC_PATH_TCLCONFIG
 624     if test -z "${no_tcl}"; then
 625         CY_AC_LOAD_TCLCONFIG
 626         CY_AC_PATH_TKCONFIG
 627
 628         # If $no_tk is nonempty, then we can't do Tk, and there is no
 629         # point to doing Tcl.
 630         if test -z "${no_tk}"; then
 631            CY_AC_LOAD_TKCONFIG
 632            CY_AC_PATH_TCLH
 633            CY_AC_PATH_TKH
 634            CY_AC_PATH_ITCLH
 635            CY_AC_PATH_TIX
 636
 637            # now look for tix library stuff
 638            TIXVERSION=4.1.8.0
 639            . ${ac_cv_c_tclconfig}/tclConfig.sh
 640            case "${host}" in
 641            *-*-cygwin*)
 642                 tixdir=../tix/win/tcl8.0
 643                 ;;
 644            *)
 645                 tixdir=../tix/unix/tk8.0
 646                 ;;
 647            esac
 648            if test "${TCL_SHARED_BUILD}" = "1"; then
 649                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 650
 651                 # Can't win them all: SunOS 4 (others?) appends a version
 652                 # number after the ".so"
 653                 case "${host}" in
 654                 *-*-sunos4*)
 655                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 656                 esac
 657
 658            else
 659                 TIX_LIB_EXT=".a"
 660            fi
 661
 662            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 663                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 664                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 665            else
 666                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 667                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 668            fi
 669
 670            ENABLE_GDBTK=1
 671            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 672
 673            # Include some libraries that Tcl and Tk want.
 674            if test "${enable_ide}" = "yes"; then
 675               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 676               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 677            else
 678               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 679               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 680            fi
 681            # Yes, the ordering seems wrong here.  But it isn't.
 682            # TK_LIBS is the list of libraries that need to be linked
 683            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 684            # were in LIBS then any link tests after this point would
 685            # try to include things like `$(LIBGUI)', which wouldn't work.
 686            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 687            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 688
 689            if test x$gdb_cv_os_cygwin = xyes; then
 690               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 691               WIN32LDAPP="-Wl,--subsystem,console"
 692               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 693            fi
 694         fi
 695     fi
 696 fi
 697
 698 AC_SUBST(ENABLE_GDBTK)
 699 AC_SUBST(X_CFLAGS)
 700 AC_SUBST(X_LDFLAGS)
 701 AC_SUBST(X_LIBS)
 702 AC_SUBST(TIXLIB)
 703 AC_SUBST(TIX_DEPS)
 704 AC_SUBST(GDBTKLIBS)
 705 # end-sanitize-gdbtk
 706
 707 AC_PATH_X
 708 # start-sanitize-sky
 709 # Enable GPU2 library for MIPS simulator
 710 AC_ARG_WITH(sim-gpu2,
 711 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 712 [case "${target}" in
 713   mips*-sky*-*)
 714     if test -d "${withval}"
 715     then
 716       if test x${x_libraries} != x
 717       then
 718         LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext -lm"
 719       else
 720         LIBS="${LIBS} -L${withval}/lib -lgpu2 -lX11 -lXext -lm"
 721       fi
 722     else
 723       AC_MSG_WARN([Directory ${withval} does not exist.])
 724     fi ;;
 725   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 726 esac])dnl
 727
 728 # Enable target accurate FP library
 729 AC_ARG_WITH(sim-funit,
 730 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 731 [case "${target}" in
 732   mips*-sky*-*)
 733     if test -d "${withval}"
 734     then
 735       LIBS="${LIBS} -L${withval}/lib -lfunit"
 736     else
 737       AC_MSG_WARN([Directory ${withval} does not exist.])
 738     fi ;;
 739   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 740 esac])dnl
 741 # end-sanitize-sky
 742
 743 AC_SUBST(ENABLE_CFLAGS)
 744
 745 AC_SUBST(CONFIG_OBS)
 746 AC_SUBST(CONFIG_DEPS)
 747 AC_SUBST(CONFIG_SRCS)
 748
 749 # Begin stuff to support --enable-shared
 750 AC_ARG_ENABLE(shared,
 751 [  --enable-shared         Use shared libraries],
 752 [case "${enableval}" in
 753   yes) shared=true ;;
 754   no)  shared=false ;;
 755   *) shared=true ;;
 756 esac])dnl
 757
 758 HLDFLAGS=
 759 HLDENV=
 760 # If we have shared libraries, try to set rpath reasonably.
 761 if test "${shared}" = "true"; then
 762   case "${host}" in
 763   *-*-hpux*)
 764     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 765     ;;
 766   *-*-irix5* | *-*-irix6*)
 767     HLDFLAGS='-Wl,-rpath,$(libdir)'
 768     ;;
 769   *-*-linux*aout*)
 770     ;;
 771   *-*-linux* | *-pc-linux-gnu)
 772     HLDFLAGS='-Wl,-rpath,$(libdir)'
 773     ;;
 774   *-*-solaris*)
 775     HLDFLAGS='-R $(libdir)'
 776     ;;
 777   *-*-sysv4*)
 778     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 779     ;;
 780   esac
 781 fi
 782
 783 # On SunOS, if the linker supports the -rpath option, use it to
 784 # prevent ../bfd and ../opcodes from being included in the run time
 785 # search path.
 786 case "${host}" in
 787   *-*-sunos*)
 788     echo 'main () { }' > conftest.c
 789     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 790     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 791       :
 792     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 793       :
 794     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 795       :
 796     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 797       :
 798     elif test "${shared}" = "true"; then
 799       HLDFLAGS='-Wl,-rpath=$(libdir)'
 800     else
 801       HLDFLAGS='-Wl,-rpath='
 802     fi
 803     rm -f conftest.t conftest.c conftest
 804     ;;
 805 esac
 806 AC_SUBST(HLDFLAGS)
 807 AC_SUBST(HLDENV)
 808 # End stuff to support --enable-shared
 809
 810 # target_subdir is used by the testsuite to find the target libraries.
 811 target_subdir=
 812 if test "${host}" != "${target}"; then
 813     target_subdir="${target_alias}/"
 814 fi
 815 AC_SUBST(target_subdir)
 816
 817 frags=
 818 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 819 if test ! -f ${host_makefile_frag}; then
 820 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 821 fi
 822 frags="$frags $host_makefile_frag"
 823
 824 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 825 if test ! -f ${target_makefile_frag}; then
 826 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 827 fi
 828 frags="$frags $target_makefile_frag"
 829
 830 AC_SUBST_FILE(host_makefile_frag)
 831 AC_SUBST_FILE(target_makefile_frag)
 832 AC_SUBST(frags)
 833
 834 changequote(,)dnl
 835 hostfile=`sed -n '
 836 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 837 ' ${host_makefile_frag}`
 838
 839 targetfile=`sed -n '
 840 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 841 ' ${target_makefile_frag}`
 842
 843 # these really aren't orthogonal true/false values of the same condition,
 844 # but shells are slow enough that I like to reuse the test conditions
 845 # whenever possible
 846 if test "${target}" = "${host}"; then
 847 nativefile=`sed -n '
 848 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 849 ' ${host_makefile_frag}`
 850 # else
 851 # GDBserver is only useful in a "native" enviroment
 852 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 853 fi
 854 changequote([,])
 855
 856 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 857 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 858 # corresponding links.  But we have to remove the xm.h files and tm.h
 859 # files anyway, e.g. when switching from "configure host" to
 860 # "configure none".
 861
 862 files=
 863 links=
 864 rm -f xm.h
 865 if test "${hostfile}" != ""; then
 866 files="${files} config/${gdb_host_cpu}/${hostfile}"
 867 links="${links} xm.h"
 868 fi
 869 rm -f tm.h
 870 if test "${targetfile}" != ""; then
 871 files="${files} config/${gdb_target_cpu}/${targetfile}"
 872 links="${links} tm.h"
 873 fi
 874 rm -f nm.h
 875 if test "${nativefile}" != ""; then
 876 files="${files} config/${gdb_host_cpu}/${nativefile}"
 877 links="${links} nm.h"
 878 else
 879 # A cross-only configuration.
 880 files="${files} config/nm-empty.h"
 881 links="${links} nm.h"
 882 fi
 883 # start-sanitize-gdbtk
 884 AC_PROG_LN_S
 885 # Make it possible to use the GUI without doing a full install
 886 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 887   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 888   echo linking $srcdir/gdbtcl2 to gdbtcl2
 889   $LN_S $srcdir/gdbtcl2 gdbtcl2
 890   else
 891   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 892   echo "         " make install before you are able to run the GUI.
 893   fi
 894 fi
 895 # end-sanitize-gdbtk
 896
 897 AC_LINK_FILES($files, $links)
 898
 899 dnl Check for exe extension set on certain hosts (e.g. Win32)
 900 AM_EXEEXT
 901
 902 AC_CONFIG_SUBDIRS($configdirs)
 903 AC_OUTPUT(Makefile tui/Makefile .gdbinit:gdbinit.in,
 904 [
 905 dnl Autoconf doesn't provide a mechanism for modifying definitions
 906 dnl provided by makefile fragments.
 907 dnl
 908 if test "${nativefile}" = ""; then
 909 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 910         < Makefile > Makefile.tem
 911 mv -f Makefile.tem Makefile
 912 fi
 913
 914 changequote(,)dnl
 915 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 916 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 917 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 918 mv -f Makefile.tmp Makefile
 919 changequote([,])dnl
 920
 921 case x$CONFIG_HEADERS in
 922 xconfig.h:config.in)
 923 echo > stamp-h ;;
 924 esac
 925 ],
 926 [
 927 gdb_host_cpu=$gdb_host_cpu
 928 gdb_target_cpu=$gdb_target_cpu
 929 nativefile=$nativefile
 930 ])
 931
 932 exit 0