gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h limits.h link.h \
  72                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  73                  string.h strings.h sys/procfs.h sys/ptrace.h sys/reg.h \
  74                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  75                  wchar.h wctype.h)
  76
  77 AC_HEADER_STAT
  78
  79 AC_C_CONST
  80
  81 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction isascii bzero bcopy memcpy btowc)
  82 AC_FUNC_ALLOCA
  83
  84 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  85 if test "${target}" = "${host}"; then
  86   case "${host}" in
  87   i[[3456]]86-*-linux*)
  88         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  89         AC_DEFINE(sys_quotactl)
  90         ;;
  91   esac
  92 fi
  93
  94 AC_MSG_CHECKING([for gregset_t type])
  95 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  96 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  97 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  98 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  99 if test $gdb_cv_have_gregset_t = yes; then
 100   AC_DEFINE(HAVE_GREGSET_T)
 101 fi
 102
 103 AC_MSG_CHECKING([for fpregset_t type])
 104 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 105 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 106 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 107 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 108 if test $gdb_cv_have_fpregset_t = yes; then
 109   AC_DEFINE(HAVE_FPREGSET_T)
 110 fi
 111
 112 dnl See if host has libm.  This is usually needed by simulators.
 113 AC_CHECK_LIB(m, main)
 114
 115 dnl See if compiler supports "long long" type.
 116
 117 AC_MSG_CHECKING(for long long support in compiler)
 118 AC_CACHE_VAL(gdb_cv_c_long_long,
 119 [AC_TRY_COMPILE(, [
 120   extern long long foo;
 121   switch (foo & 2) { case 0: return 1; }
 122 ],
 123 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 124 AC_MSG_RESULT($gdb_cv_c_long_long)
 125 if test $gdb_cv_c_long_long = yes; then
 126   AC_DEFINE(CC_HAS_LONG_LONG)
 127 fi
 128
 129 dnl See if the compiler and runtime support printing long long
 130
 131 AC_MSG_CHECKING(for long long support in printf)
 132 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 133 [AC_TRY_RUN([
 134 int main () {
 135   char buf[32];
 136   long long l = 0;
 137   l = (l << 16) + 0x0123;
 138   l = (l << 16) + 0x4567;
 139   l = (l << 16) + 0x89ab;
 140   l = (l << 16) + 0xcdef;
 141   sprintf (buf, "0x%016llx", l);
 142   return (strcmp ("0x0123456789abcdef", buf));
 143 }],
 144 gdb_cv_printf_has_long_long=yes,
 145 gdb_cv_printf_has_long_long=no,
 146 gdb_cv_printf_has_long_long=no)])
 147 if test $gdb_cv_printf_has_long_long = yes; then
 148   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 149 fi
 150 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 151
 152 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 153 dnl because autoconf complains about cross-compilation issues.  However, this
 154 dnl code uses the same variables as the macro for compatibility.
 155
 156 AC_MSG_CHECKING(for long double support in compiler)
 157 AC_CACHE_VAL(ac_cv_c_long_double,
 158 [AC_TRY_COMPILE(, [long double foo;],
 159 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 160 AC_MSG_RESULT($ac_cv_c_long_double)
 161 if test $ac_cv_c_long_double = yes; then
 162   AC_DEFINE(HAVE_LONG_DOUBLE)
 163 fi
 164
 165 dnl See if the compiler and runtime support printing long doubles
 166
 167 AC_MSG_CHECKING(for long double support in printf)
 168 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 169 [AC_TRY_RUN([
 170 int main () {
 171   char buf[16];
 172   long double f = 3.141592653;
 173   sprintf (buf, "%Lg", f);
 174   return (strncmp ("3.14159", buf, 7));
 175 }],
 176 gdb_cv_printf_has_long_double=yes,
 177 gdb_cv_printf_has_long_double=no,
 178 gdb_cv_printf_has_long_double=no)])
 179 if test $gdb_cv_printf_has_long_double = yes; then
 180   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 181 fi
 182 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 183
 184 dnl See if the compiler and runtime support scanning long doubles
 185
 186 AC_MSG_CHECKING(for long double support in scanf)
 187 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 188 [AC_TRY_RUN([
 189 int main () {
 190   char *buf = "3.141592653";
 191   long double f = 0;
 192   sscanf (buf, "%Lg", &f);
 193   return !(f > 3.14159 && f < 3.14160);
 194 }],
 195 gdb_cv_scanf_has_long_double=yes,
 196 gdb_cv_scanf_has_long_double=no,
 197 gdb_cv_scanf_has_long_double=no)])
 198 if test $gdb_cv_scanf_has_long_double = yes; then
 199   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 200 fi
 201 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 202
 203 AC_FUNC_MMAP
 204
 205 BFD_NEED_DECLARATION(malloc)
 206 BFD_NEED_DECLARATION(realloc)
 207 BFD_NEED_DECLARATION(free)
 208
 209 BFD_NEED_DECLARATION(strerror)
 210
 211 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 212 dnl we must explicitly test for version 1 of the library because version 0
 213 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 214
 215 dnl Note that we only want this if we are both native (host == target), and
 216 dnl not doing a canadian cross build (build == host).
 217
 218 if test ${build} = ${host} -a ${host} = ${target} ; then
 219    case ${host_os} in
 220    hpux*)
 221       AC_MSG_CHECKING(for HPUX/OSF thread support)
 222       if test -f /usr/include/dce/cma_config.h ; then
 223          if test "$GCC" = "yes" ; then
 224             AC_MSG_RESULT(yes)
 225             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 226             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 227             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 228          else
 229             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 230          fi
 231       else
 232          AC_MSG_RESULT(no)
 233       fi
 234       ;;
 235    solaris*)
 236       AC_MSG_CHECKING(for Solaris thread debugging library)
 237       if test -f /usr/lib/libthread_db.so.1 ; then
 238          AC_MSG_RESULT(yes)
 239          AC_DEFINE(HAVE_THREAD_DB_LIB)
 240          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 241          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 242          AC_CHECK_LIB(dl, dlopen)
 243          if test "$GCC" = "yes" ; then
 244             # The GNU linker requires the -export-dynamic option to make
 245             # all symbols visible in the dynamic symbol table.
 246             hold_ldflags=$LDFLAGS
 247             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 248             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 249             AC_TRY_LINK(, [int i;], found=yes, found=no)
 250             LDFLAGS=$hold_ldflags
 251             AC_MSG_RESULT($found)
 252             if test $found = yes; then
 253                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 254             fi
 255          fi
 256       else
 257          AC_MSG_RESULT(no)
 258       fi
 259       ;;
 260    esac
 261    AC_SUBST(CONFIG_LDFLAGS)
 262 fi
 263
 264 dnl Handle optional features that can be enabled.
 265 ENABLE_CFLAGS=
 266
 267 AC_ARG_ENABLE(netrom,
 268 [  --enable-netrom ],
 269 [case "${enableval}" in
 270 yes)    enable_netrom=yes ;;
 271 no)     enable_netrom=no ;;
 272 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 273 esac])
 274
 275 if test "${enable_netrom}" = "yes"; then
 276         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 277         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 278 fi
 279
 280 MMALLOC_CFLAGS=
 281 MMALLOC=
 282 AC_SUBST(MMALLOC_CFLAGS)
 283 AC_SUBST(MMALLOC)
 284
 285 AC_ARG_WITH(mmalloc,
 286 [  --with-mmalloc             use memory mapped malloc package],
 287 [case "${withval}" in
 288   yes)  want_mmalloc=true ;;
 289   no)   want_mmalloc=false;;
 290   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 291 esac],[want_mmalloc=false])dnl
 292
 293 if test x$want_mmalloc = xtrue; then
 294    AC_DEFINE(USE_MMALLOC)
 295    AC_DEFINE(MMCHECK_FORCE)
 296    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 297    MMALLOC='../mmalloc/libmmalloc.a'
 298 fi
 299
 300 # start-sanitize-gdbtk
 301 ENABLE_IDE=
 302 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 303 if test "$enable_ide" = yes; then
 304    enable_ide=yes
 305    ENABLE_IDE=1
 306 else
 307    enable_ide=no
 308 fi
 309 AC_SUBST(ENABLE_IDE)
 310
 311 AC_ARG_WITH(foundry-libs,
 312 [  --with-foundry-libs=directory       use the Foundry SDK in directory],
 313 [FOUNDRY_LIB_BASE=${withval}])
 314 AC_SUBST(FOUNDRY_LIB_BASE)
 315
 316 #
 317 # This is the Foundry SDK
 318 #
 319 # These variables are used to determine where the Foundry libs and
 320 # header files are located.
 321 #
 322 if test "$FOUNDRY_LIB_BASE" != ""; then
 323     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 324     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 325     if test x$enable_ide = xyes; then
 326         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 327         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 328     else
 329         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 330     fi
 331     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 332     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 333     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 334 else
 335     LIBGUI="../libgui/src/libgui.a"
 336     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 337     if test x$enable_ide = xyes; then
 338         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 339         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 340     else
 341         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 342     fi
 343     LIBIDETCL="../libidetcl/src/libidetcl.a"
 344     LIBIDE="../libide/src/libide.a"
 345     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 346 fi
 347 AC_SUBST(LIBGUI)
 348 AC_SUBST(GUI_CFLAGS_X)
 349 AC_SUBST(IDE_CFLAGS_X)
 350 AC_SUBST(IDE_X)
 351 AC_SUBST(LIBIDETCL)
 352 AC_SUBST(LIBIDE)
 353 AC_SUBST(IDE_DEPS)
 354
 355 ENABLE_GDBTK=
 356
 357 AC_ARG_ENABLE(gdbtk,
 358 [  --enable-gdbtk ],
 359 [case "${enableval}" in
 360     yes)
 361         case "$host" in
 362         *go32*)
 363             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 364             enable_gdbtk=no ;;
 365         *windows*)
 366             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 367             enable_gdbtk=no ;;
 368         *)
 369             enable_gdbtk=yes ;;
 370         esac ;;
 371     no)
 372         enable_gdbtk=no  ;;
 373     *)
 374         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 375 esac],
 376 [
 377 # Default is on for everything but go32 and cygwin32
 378 case "$host" in
 379     *go32* | *windows*)
 380         ;;
 381     *)
 382         enable_gdbtk=yes ;;
 383     esac
 384 ])
 385
 386 # In the cygwin32 environment, we need some additional flags.
 387 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 388 [AC_EGREP_CPP(lose, [
 389 #ifdef __CYGWIN32__
 390 lose
 391 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 392
 393 WIN32LIBS=
 394 WIN32LDAPP=
 395 AC_SUBST(WIN32LIBS)
 396 AC_SUBST(WIN32LDAPP)
 397
 398 WINDRES=${WINDRES-windres}
 399 AC_SUBST(WINDRES)
 400
 401 if test x$gdb_cv_os_cygwin32 = xyes; then
 402     if test x$enable_ide = xyes; then
 403         WIN32LIBS="-ladvapi32"
 404     fi
 405 fi
 406
 407 configdir="unix"
 408
 409 GDBTKLIBS=
 410 if test "${enable_gdbtk}" = "yes"; then
 411
 412     CY_AC_PATH_TCLCONFIG
 413     if test -z "${no_tcl}"; then
 414         CY_AC_LOAD_TCLCONFIG
 415         CY_AC_PATH_TKCONFIG
 416
 417         # If $no_tk is nonempty, then we can't do Tk, and there is no
 418         # point to doing Tcl.
 419         if test -z "${no_tk}"; then
 420            CY_AC_LOAD_TKCONFIG
 421            CY_AC_PATH_TCLH
 422            CY_AC_PATH_TKH
 423            CY_AC_PATH_ITCLH
 424            CY_AC_PATH_TIX
 425
 426            # now look for tix library stuff
 427            TIXVERSION=4.1.8.0
 428            . ${ac_cv_c_tclconfig}/tclConfig.sh
 429            case "${host}" in
 430            *-*-cygwin32*)
 431                 tixdir=../tix/win/tcl8.0
 432                 ;;
 433            *)
 434                 tixdir=../tix/unix/tk8.0
 435                 ;;
 436            esac
 437            if test "${TCL_SHARED_BUILD}" = "1"; then
 438                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 439
 440                 # Can't win them all: SunOS 4 (others?) appends a version
 441                 # number after the ".so"
 442                 case "${host}" in
 443                 *-*-sunos4*)
 444                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 445                 esac
 446
 447            else
 448                 TIX_LIB_EXT=".a"
 449            fi
 450
 451            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 452                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 453                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 454            else
 455                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 456                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 457            fi
 458
 459            ENABLE_GDBTK=1
 460            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 461
 462            # Include some libraries that Tcl and Tk want.
 463            if test "${enable_ide}" = "yes"; then
 464               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 465               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 466            else
 467               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 468               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 469            fi
 470            # Yes, the ordering seems wrong here.  But it isn't.
 471            # TK_LIBS is the list of libraries that need to be linked
 472            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 473            # were in LIBS then any link tests after this point would
 474            # try to include things like `$(LIBGUI)', which wouldn't work.
 475            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 476            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 477
 478            if test x$gdb_cv_os_cygwin32 = xyes; then
 479               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 480               WIN32LDAPP="-Wl,--subsystem,console"
 481               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 482            fi
 483         fi
 484     fi
 485 fi
 486
 487 AC_SUBST(ENABLE_GDBTK)
 488 AC_SUBST(X_CFLAGS)
 489 AC_SUBST(X_LDFLAGS)
 490 AC_SUBST(X_LIBS)
 491 AC_SUBST(TIXLIB)
 492 AC_SUBST(TIX_DEPS)
 493 AC_SUBST(GDBTKLIBS)
 494 # end-sanitize-gdbtk
 495
 496 AC_PATH_X
 497 # start-sanitize-sky
 498 # Enable GPU2 library for MIPS simulator
 499 AC_ARG_WITH(sim-gpu2,
 500 [  --with-sim-gpu2=path                 Use GPU2 library under given directory],
 501 [case "${target}" in
 502   mips*-sky-*)
 503     if test -d "${withval}"
 504     then
 505       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 506     else
 507       AC_MSG_WARN([Directory ${withval} does not exist.])
 508     fi ;;
 509   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 510 esac])dnl
 511
 512 # Enable target accurate FP library
 513 AC_ARG_WITH(sim-funit,
 514 [  --with-sim-funit=path                Use target FP lib under given directory],
 515 [case "${target}" in
 516   mips*-sky-*)
 517     if test -d "${withval}"
 518     then
 519       LIBS="${LIBS} -L${withval}/lib -lfunit"
 520     else
 521       AC_MSG_WARN([Directory ${withval} does not exist.])
 522     fi ;;
 523   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 524 esac])dnl
 525 # end-sanitize-sky
 526
 527 dnl Solaris puts wctype in /usr/lib/libw.a
 528 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 529
 530 AC_SUBST(ENABLE_CFLAGS)
 531
 532 AC_SUBST(CONFIG_OBS)
 533 AC_SUBST(CONFIG_DEPS)
 534 AC_SUBST(CONFIG_SRCS)
 535
 536 # Begin stuff to support --enable-shared
 537 AC_ARG_ENABLE(shared,
 538 [  --enable-shared         use shared libraries],
 539 [case "${enableval}" in
 540   yes) shared=true ;;
 541   no)  shared=false ;;
 542   *) shared=true ;;
 543 esac])dnl
 544
 545 HLDFLAGS=
 546 HLDENV=
 547 # If we have shared libraries, try to set rpath reasonably.
 548 if test "${shared}" = "true"; then
 549   case "${host}" in
 550   *-*-hpux*)
 551     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 552     ;;
 553   *-*-irix5* | *-*-irix6*)
 554     HLDFLAGS='-Wl,-rpath,$(libdir)'
 555     ;;
 556   *-*-linux*aout*)
 557     ;;
 558   *-*-linux* | *-pc-linux-gnu)
 559     HLDFLAGS='-Wl,-rpath,$(libdir)'
 560     ;;
 561   *-*-solaris*)
 562     HLDFLAGS='-R $(libdir)'
 563     ;;
 564   *-*-sysv4*)
 565     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 566     ;;
 567   esac
 568 fi
 569
 570 # On SunOS, if the linker supports the -rpath option, use it to
 571 # prevent ../bfd and ../opcodes from being included in the run time
 572 # search path.
 573 case "${host}" in
 574   *-*-sunos*)
 575     echo 'main () { }' > conftest.c
 576     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 577     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 578       :
 579     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 580       :
 581     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 582       :
 583     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 584       :
 585     elif test "${shared}" = "true"; then
 586       HLDFLAGS='-Wl,-rpath=$(libdir)'
 587     else
 588       HLDFLAGS='-Wl,-rpath='
 589     fi
 590     rm -f conftest.t conftest.c conftest
 591     ;;
 592 esac
 593 AC_SUBST(HLDFLAGS)
 594 AC_SUBST(HLDENV)
 595 # End stuff to support --enable-shared
 596
 597 # target_subdir is used by the testsuite to find the target libraries.
 598 target_subdir=
 599 if test "${host}" != "${target}"; then
 600     target_subdir="${target_alias}/"
 601 fi
 602 AC_SUBST(target_subdir)
 603
 604 frags=
 605 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 606 if test ! -f ${host_makefile_frag}; then
 607 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 608 fi
 609 frags="$frags $host_makefile_frag"
 610
 611 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 612 if test ! -f ${target_makefile_frag}; then
 613 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 614 fi
 615 frags="$frags $target_makefile_frag"
 616
 617 AC_SUBST_FILE(host_makefile_frag)
 618 AC_SUBST_FILE(target_makefile_frag)
 619 AC_SUBST(frags)
 620
 621 changequote(,)dnl
 622 hostfile=`sed -n '
 623 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 624 ' ${host_makefile_frag}`
 625
 626 targetfile=`sed -n '
 627 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 628 ' ${target_makefile_frag}`
 629
 630 # these really aren't orthogonal true/false values of the same condition,
 631 # but shells are slow enough that I like to reuse the test conditions
 632 # whenever possible
 633 if test "${target}" = "${host}"; then
 634 nativefile=`sed -n '
 635 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 636 ' ${host_makefile_frag}`
 637 # else
 638 # GDBserver is only useful in a "native" enviroment
 639 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 640 fi
 641 changequote([,])
 642
 643 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 644 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 645 # corresponding links.  But we have to remove the xm.h files and tm.h
 646 # files anyway, e.g. when switching from "configure host" to
 647 # "configure none".
 648
 649 files=
 650 links=
 651 rm -f xm.h
 652 if test "${hostfile}" != ""; then
 653 files="${files} config/${gdb_host_cpu}/${hostfile}"
 654 links="${links} xm.h"
 655 fi
 656 rm -f tm.h
 657 if test "${targetfile}" != ""; then
 658 files="${files} config/${gdb_target_cpu}/${targetfile}"
 659 links="${links} tm.h"
 660 fi
 661 rm -f nm.h
 662 if test "${nativefile}" != ""; then
 663 files="${files} config/${gdb_host_cpu}/${nativefile}"
 664 links="${links} nm.h"
 665 else
 666 # A cross-only configuration.
 667 files="${files} config/nm-empty.h"
 668 links="${links} nm.h"
 669 fi
 670 # start-sanitize-gdbtk
 671 AC_PROG_LN_S
 672 # Make it possible to use the GUI without doing a full install
 673 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 674   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 675   echo linking $srcdir/gdbtcl to gdbtcl
 676   $LN_S $srcdir/gdbtcl gdbtcl
 677   else
 678   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 679   echo "         " make install before you are able to run the GUI.
 680   fi
 681 fi
 682 # end-sanitize-gdbtk
 683
 684 AC_LINK_FILES($files, $links)
 685
 686 dnl Check for exe extension set on certain hosts (e.g. Win32)
 687 AM_EXEEXT
 688
 689 AC_CONFIG_SUBDIRS($configdirs)
 690 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 691 [
 692 dnl Autoconf doesn't provide a mechanism for modifying definitions
 693 dnl provided by makefile fragments.
 694 dnl
 695 if test "${nativefile}" = ""; then
 696 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 697         < Makefile > Makefile.tem
 698 mv -f Makefile.tem Makefile
 699 fi
 700
 701 changequote(,)dnl
 702 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 703 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 704 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 705 mv -f Makefile.tmp Makefile
 706 changequote([,])dnl
 707
 708 case x$CONFIG_HEADERS in
 709 xconfig.h:config.in)
 710 echo > stamp-h ;;
 711 esac
 712 ],
 713 [
 714 gdb_host_cpu=$gdb_host_cpu
 715 gdb_target_cpu=$gdb_target_cpu
 716 nativefile=$nativefile
 717 ])
 718
 719 exit 0
 720