gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29
  30 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  31 AC_CANONICAL_SYSTEM
  32
  33 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  34 dnl link with the correct libraries.
  35 ALL_LINGUAS=
  36 CY_GNU_GETTEXT
  37
  38 dnl List of object files added by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43
  44 configdirs="doc testsuite"
  45
  46 dnl
  47 changequote(,)dnl
  48
  49 . ${srcdir}/configure.host
  50
  51 . ${srcdir}/configure.tgt
  52
  53 dnl
  54 changequote([,])dnl
  55
  56 AC_PROG_INSTALL
  57 AC_CHECK_TOOL(AR, ar)
  58 AC_CHECK_TOOL(RANLIB, ranlib, :)
  59 AC_PROG_YACC
  60
  61 AC_ARG_PROGRAM
  62
  63 AC_TYPE_SIGNAL
  64
  65 AC_HEADER_STDC
  66 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h link.h \
  67                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  68                  string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  69                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  70                  wchar.h wctype.h asm/debugreg.h)
  71
  72 AC_HEADER_STAT
  73
  74 AC_C_CONST
  75
  76 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc)
  77 AC_FUNC_ALLOCA
  78
  79 BFD_NEED_DECLARATION(malloc)
  80 BFD_NEED_DECLARATION(realloc)
  81 BFD_NEED_DECLARATION(free)
  82 BFD_NEED_DECLARATION(strerror)
  83 BFD_NEED_DECLARATION(strdup)
  84
  85 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  86 if test "${target}" = "${host}"; then
  87   case "${host}" in
  88   i[[3456]]86-*-linux*)
  89         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  90         AC_DEFINE(sys_quotactl)
  91         ;;
  92   esac
  93 fi
  94
  95 AC_MSG_CHECKING([for gregset_t type])
  96 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  97 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  98 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  99 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 100 if test $gdb_cv_have_gregset_t = yes; then
 101   AC_DEFINE(HAVE_GREGSET_T)
 102 fi
 103
 104 AC_MSG_CHECKING([for fpregset_t type])
 105 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 106 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 107 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 108 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 109 if test $gdb_cv_have_fpregset_t = yes; then
 110   AC_DEFINE(HAVE_FPREGSET_T)
 111 fi
 112
 113 dnl See if host has libm.  This is usually needed by simulators.
 114 AC_CHECK_LIB(m, main)
 115
 116 dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6.
 117 dnl
 118 dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw
 119 dnl under Solaris 2.6 because it is some funky empty library.
 120 dnl So only link in libw if we have to.
 121 AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype))
 122
 123 dnl See if compiler supports "long long" type.
 124
 125 AC_MSG_CHECKING(for long long support in compiler)
 126 AC_CACHE_VAL(gdb_cv_c_long_long,
 127 [AC_TRY_COMPILE(, [
 128   extern long long foo;
 129   switch (foo & 2) { case 0: return 1; }
 130 ],
 131 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 132 AC_MSG_RESULT($gdb_cv_c_long_long)
 133 if test $gdb_cv_c_long_long = yes; then
 134   AC_DEFINE(CC_HAS_LONG_LONG)
 135 fi
 136
 137 dnl See if the compiler and runtime support printing long long
 138
 139 AC_MSG_CHECKING(for long long support in printf)
 140 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 141 [AC_TRY_RUN([
 142 int main () {
 143   char buf[32];
 144   long long l = 0;
 145   l = (l << 16) + 0x0123;
 146   l = (l << 16) + 0x4567;
 147   l = (l << 16) + 0x89ab;
 148   l = (l << 16) + 0xcdef;
 149   sprintf (buf, "0x%016llx", l);
 150   return (strcmp ("0x0123456789abcdef", buf));
 151 }],
 152 gdb_cv_printf_has_long_long=yes,
 153 gdb_cv_printf_has_long_long=no,
 154 gdb_cv_printf_has_long_long=no)])
 155 if test $gdb_cv_printf_has_long_long = yes; then
 156   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 157 fi
 158 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 159
 160 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 161 dnl because autoconf complains about cross-compilation issues.  However, this
 162 dnl code uses the same variables as the macro for compatibility.
 163
 164 AC_MSG_CHECKING(for long double support in compiler)
 165 AC_CACHE_VAL(ac_cv_c_long_double,
 166 [AC_TRY_COMPILE(, [long double foo;],
 167 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 168 AC_MSG_RESULT($ac_cv_c_long_double)
 169 if test $ac_cv_c_long_double = yes; then
 170   AC_DEFINE(HAVE_LONG_DOUBLE)
 171 fi
 172
 173 dnl See if the compiler and runtime support printing long doubles
 174
 175 AC_MSG_CHECKING(for long double support in printf)
 176 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 177 [AC_TRY_RUN([
 178 int main () {
 179   char buf[16];
 180   long double f = 3.141592653;
 181   sprintf (buf, "%Lg", f);
 182   return (strncmp ("3.14159", buf, 7));
 183 }],
 184 gdb_cv_printf_has_long_double=yes,
 185 gdb_cv_printf_has_long_double=no,
 186 gdb_cv_printf_has_long_double=no)])
 187 if test $gdb_cv_printf_has_long_double = yes; then
 188   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 189 fi
 190 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 191
 192 dnl See if the compiler and runtime support scanning long doubles
 193
 194 AC_MSG_CHECKING(for long double support in scanf)
 195 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 196 [AC_TRY_RUN([
 197 int main () {
 198   char *buf = "3.141592653";
 199   long double f = 0;
 200   sscanf (buf, "%Lg", &f);
 201   return !(f > 3.14159 && f < 3.14160);
 202 }],
 203 gdb_cv_scanf_has_long_double=yes,
 204 gdb_cv_scanf_has_long_double=no,
 205 gdb_cv_scanf_has_long_double=no)])
 206 if test $gdb_cv_scanf_has_long_double = yes; then
 207   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 208 fi
 209 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 210
 211 AC_FUNC_MMAP
 212
 213 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 214 dnl we must explicitly test for version 1 of the library because version 0
 215 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 216
 217 dnl Note that we only want this if we are both native (host == target), and
 218 dnl not doing a canadian cross build (build == host).
 219
 220 if test ${build} = ${host} -a ${host} = ${target} ; then
 221    case ${host_os} in
 222    hpux*)
 223       AC_MSG_CHECKING(for HPUX/OSF thread support)
 224       if test -f /usr/include/dce/cma_config.h ; then
 225          if test "$GCC" = "yes" ; then
 226             AC_MSG_RESULT(yes)
 227             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 228             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 229             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 230          else
 231             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 232          fi
 233       else
 234          AC_MSG_RESULT(no)
 235       fi
 236       ;;
 237    solaris*)
 238       AC_MSG_CHECKING(for Solaris thread debugging library)
 239       if test -f /usr/lib/libthread_db.so.1 ; then
 240          AC_MSG_RESULT(yes)
 241          AC_DEFINE(HAVE_THREAD_DB_LIB)
 242          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 243          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 244          AC_CHECK_LIB(dl, dlopen)
 245          if test "$GCC" = "yes" ; then
 246             # The GNU linker requires the -export-dynamic option to make
 247             # all symbols visible in the dynamic symbol table.
 248             hold_ldflags=$LDFLAGS
 249             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 250             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 251             AC_TRY_LINK(, [int i;], found=yes, found=no)
 252             LDFLAGS=$hold_ldflags
 253             AC_MSG_RESULT($found)
 254             if test $found = yes; then
 255                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 256             fi
 257          fi
 258          # Sun randomly tweaked the prototypes in <proc_service.h>
 259          # at one point.
 260          AC_MSG_CHECKING(if <proc_service.h> is old)
 261          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 262             AC_TRY_COMPILE([
 263                 #include <proc_service.h>
 264                 ps_err_e ps_pdwrite
 265                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 266             ],, gdb_cv_proc_service_is_old=no,
 267                 gdb_cv_proc_service_is_old=yes)
 268          ])
 269          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 270          if test $gdb_cv_proc_service_is_old = yes; then
 271             AC_DEFINE(PROC_SERVICE_IS_OLD)
 272          fi
 273       else
 274          AC_MSG_RESULT(no)
 275       fi
 276       ;;
 277    esac
 278    AC_SUBST(CONFIG_LDFLAGS)
 279 fi
 280
 281 dnl Handle optional features that can be enabled.
 282 ENABLE_CFLAGS=
 283
 284 AC_ARG_ENABLE(netrom,
 285 [  --enable-netrom ],
 286 [case "${enableval}" in
 287 yes)    enable_netrom=yes ;;
 288 no)     enable_netrom=no ;;
 289 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 290 esac])
 291
 292 if test "${enable_netrom}" = "yes"; then
 293         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 294         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 295 fi
 296
 297 AC_ARG_ENABLE(warnings,
 298 [  --enable-build-warnings Enable compiler warnings if gcc is used],
 299 [case "${enableval}" in
 300 yes)    enable_build_warnings=yes ;;
 301 no)     enable_build_warnings=no ;;
 302 *)      AC_MSG_ERROR(bad value ${enableval} given for warnings options) ;;
 303 esac])
 304
 305 if test "x$enable_build_warnings" = xyes -a "x$GCC" = xyes
 306 then
 307    WARN_CFLAGS="-Wall -Wstrict-prototypes -Wmissing-prototypes"
 308 else
 309    WARN_CFLAGS=""
 310 fi
 311 AC_SUBST(WARN_CFLAGS)
 312
 313 MMALLOC_CFLAGS=
 314 MMALLOC=
 315 AC_SUBST(MMALLOC_CFLAGS)
 316 AC_SUBST(MMALLOC)
 317
 318 AC_ARG_WITH(mmalloc,
 319 [  --with-mmalloc          Use memory mapped malloc package],
 320 [case "${withval}" in
 321   yes)  want_mmalloc=true ;;
 322   no)   want_mmalloc=false;;
 323   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 324 esac],[want_mmalloc=false])dnl
 325
 326 if test x$want_mmalloc = xtrue; then
 327    AC_DEFINE(USE_MMALLOC)
 328    AC_DEFINE(MMCHECK_FORCE)
 329    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 330    MMALLOC='../mmalloc/libmmalloc.a'
 331 fi
 332
 333 # start-sanitize-carp
 334 # The below takes an educated guess at the targets that
 335 # should be built.  It is an interum version that provides
 336 # significant backward compatibility.
 337
 338 AC_ARG_ENABLE(carp,
 339 [  --enable-carp        Configure alternative readaptive paradigm ],
 340 [case "${enableval}" in
 341   yes) enable_carp=yes ;;
 342   no)  enable_carp=no ;;
 343   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 344 esac],[enable_carp=no])dnl
 345
 346 AC_ARG_ENABLE(targets,
 347 [  --enable-targets        alternative target configurations],
 348 [case "${enableval}" in
 349   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 350             ;;
 351   no)       enable_targets= ;;
 352   *)        enable_targets="$enableval" ;;
 353 esac])dnl
 354
 355 # Canonicalize the secondary target names.
 356 all_targets=false
 357 if test -n "$enable_targets" ; then
 358     if test "$enable_targets" = all ; then
 359         all_targets=true
 360     else
 361         for targ in `echo $enable_targets | sed 's/,/ /g'`
 362         do
 363             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 364             if test -n "$result" ; then
 365                 canon_targets="$canon_targets $result"
 366             fi
 367         done
 368     fi
 369 fi
 370
 371 # Convert the target names into GDB [*]-tdep.c names
 372 changequote(,)dnl
 373 selarchs=
 374 for targ in $target $canon_targets
 375 do
 376     if test "x$targ" = "xall" ; then
 377         all_targets=true
 378     else
 379         t_cpu=`echo $targ    | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 380         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 381         t_os=`echo $targ     | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 382         mt=`
 383 target=$targ
 384 target_cpu=$t_cpu
 385 target_vendor=$t_vendor
 386 target_os=$t_os
 387 . ${srcdir}/configure.tgt
 388 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 389         if test -r ${mt} ; then
 390             # This gets confused over .mt files that have multiple -tdep.o
 391             tdep=`sed -n '
 392 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 393 ' $mt`
 394             selarchs="$selarchs $tdep"
 395         fi
 396     fi
 397 done
 398 changequote([,])dnl
 399
 400 # We don't do any links based on the target system, just makefile config.
 401
 402 if test x${all_targets} = xfalse ; then
 403
 404     # Target architecture .o files.
 405     ta=
 406
 407     for arch in $selarchs
 408     do
 409         archdefs="$archdefs -DARCH_$arch"
 410         ta="$ta ${arch}-tdep.o"
 411         # Special cases
 412         case "$arch" in
 413             dvp)  ta="$ta mips-tdep.o dvp-tdep.o" ;;
 414         esac
 415     done
 416
 417     # Weed out duplicate .o files.
 418     f=""
 419     for i in $ta ; do
 420         case " $f " in
 421             *" $i "*) ;;
 422             *) f="$f $i" ;;
 423         esac
 424     done
 425     ta="$f"
 426
 427     # And duplicate -D flags.
 428     f=""
 429     for i in $archdefs ; do
 430         case " $f " in
 431             *" $i "*) ;;
 432             *) f="$f $i" ;;
 433         esac
 434     done
 435     archdefs="$f"
 436
 437     MACHINE_OBS="$ta"
 438
 439 else    # all_targets is true
 440     archdefs=-DARCH_all
 441     MACHINE_OBS='$(ALL_MACHINES)'
 442 fi
 443
 444 dnl Don't define an archdefs list
 445 dnl AC_SUBST(archdefs)
 446 dnl XXXX this name will change several more times
 447 if test "${enable_carp}" = yes ; then
 448     gdb_target=carp
 449     gdb_target_cpu=carp
 450 else
 451     MACHINE_OBS="# $MACHINE_OBS"
 452 fi
 453 AC_SUBST(MACHINE_OBS)
 454
 455 # end-sanitize-carp
 456 # start-sanitize-gdbtk
 457 # start-sanitize-ide
 458 ENABLE_IDE=
 459 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 460 if test "$enable_ide" = yes; then
 461    enable_ide=yes
 462    ENABLE_IDE=1
 463 else
 464    enable_ide=no
 465 fi
 466 AC_SUBST(ENABLE_IDE)
 467
 468 AC_ARG_WITH(foundry-libs,
 469 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 470 [FOUNDRY_LIB_BASE=${withval}])
 471 AC_SUBST(FOUNDRY_LIB_BASE)
 472
 473 #
 474 # This is the Foundry SDK
 475 #
 476 # These variables are used to determine where the Foundry libs and
 477 # header files are located.
 478 #
 479 if test "$FOUNDRY_LIB_BASE" != ""; then
 480     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 481     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 482     if test x$enable_ide = xyes; then
 483         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 484         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 485     else
 486         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 487     fi
 488     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 489     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 490     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 491 else
 492     LIBGUI="../libgui/src/libgui.a"
 493     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 494     if test x$enable_ide = xyes; then
 495         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 496         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 497     else
 498         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 499     fi
 500     LIBIDETCL="../libidetcl/src/libidetcl.a"
 501     LIBIDE="../libide/src/libide.a"
 502     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 503 fi
 504 AC_SUBST(LIBGUI)
 505 AC_SUBST(GUI_CFLAGS_X)
 506 AC_SUBST(IDE_CFLAGS_X)
 507 AC_SUBST(IDE_X)
 508 AC_SUBST(LIBIDETCL)
 509 AC_SUBST(LIBIDE)
 510 AC_SUBST(IDE_DEPS)
 511 # end-sanitize-ide
 512
 513 ENABLE_GDBTK=
 514
 515 AC_ARG_ENABLE(gdbtk,
 516 [  --enable-gdbtk          Enable GDBTK GUI front end],
 517 [case "${enableval}" in
 518     yes)
 519         case "$host" in
 520         *go32*)
 521             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 522             enable_gdbtk=no ;;
 523         *windows*)
 524             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 525             enable_gdbtk=no ;;
 526         *)
 527             enable_gdbtk=yes ;;
 528         esac ;;
 529     no)
 530         enable_gdbtk=no  ;;
 531     *)
 532         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 533 esac],
 534 [
 535 # Default is on for everything but go32 and cygwin32
 536 case "$host" in
 537     *go32* | *windows*)
 538         ;;
 539     *)
 540         enable_gdbtk=yes ;;
 541     esac
 542 ])
 543
 544 # In the cygwin32 environment, we need some additional flags.
 545 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 546 [AC_EGREP_CPP(lose, [
 547 #ifdef __CYGWIN32__
 548 lose
 549 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 550
 551 WIN32LIBS=
 552 WIN32LDAPP=
 553 AC_SUBST(WIN32LIBS)
 554 AC_SUBST(WIN32LDAPP)
 555
 556 DLLTOOL=${DLLTOOL-dlltool}
 557 WINDRES=${WINDRES-windres}
 558 AC_SUBST(DLLTOOL)
 559 AC_SUBST(WINDRES)
 560
 561 if test x$gdb_cv_os_cygwin32 = xyes; then
 562     if test x$enable_ide = xyes; then
 563         WIN32LIBS="-ladvapi32"
 564     fi
 565 fi
 566
 567 configdir="unix"
 568
 569 GDBTKLIBS=
 570 if test "${enable_gdbtk}" = "yes"; then
 571
 572     CY_AC_PATH_TCLCONFIG
 573     if test -z "${no_tcl}"; then
 574         CY_AC_LOAD_TCLCONFIG
 575         CY_AC_PATH_TKCONFIG
 576
 577         # If $no_tk is nonempty, then we can't do Tk, and there is no
 578         # point to doing Tcl.
 579         if test -z "${no_tk}"; then
 580            CY_AC_LOAD_TKCONFIG
 581            CY_AC_PATH_TCLH
 582            CY_AC_PATH_TKH
 583            CY_AC_PATH_ITCLH
 584            CY_AC_PATH_TIX
 585
 586            # now look for tix library stuff
 587            TIXVERSION=4.1.8.0
 588            . ${ac_cv_c_tclconfig}/tclConfig.sh
 589            case "${host}" in
 590            *-*-cygwin32*)
 591                 tixdir=../tix/win/tcl8.0
 592                 ;;
 593            *)
 594                 tixdir=../tix/unix/tk8.0
 595                 ;;
 596            esac
 597            if test "${TCL_SHARED_BUILD}" = "1"; then
 598                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 599
 600                 # Can't win them all: SunOS 4 (others?) appends a version
 601                 # number after the ".so"
 602                 case "${host}" in
 603                 *-*-sunos4*)
 604                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 605                 esac
 606
 607            else
 608                 TIX_LIB_EXT=".a"
 609            fi
 610
 611            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 612                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 613                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 614            else
 615                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 616                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 617            fi
 618
 619            ENABLE_GDBTK=1
 620            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 621
 622            # Include some libraries that Tcl and Tk want.
 623            if test "${enable_ide}" = "yes"; then
 624               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 625               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 626            else
 627               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 628               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 629            fi
 630            # Yes, the ordering seems wrong here.  But it isn't.
 631            # TK_LIBS is the list of libraries that need to be linked
 632            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 633            # were in LIBS then any link tests after this point would
 634            # try to include things like `$(LIBGUI)', which wouldn't work.
 635            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 636            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 637
 638            if test x$gdb_cv_os_cygwin32 = xyes; then
 639               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 640               WIN32LDAPP="-Wl,--subsystem,console"
 641               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 642            fi
 643         fi
 644     fi
 645 fi
 646
 647 AC_SUBST(ENABLE_GDBTK)
 648 AC_SUBST(X_CFLAGS)
 649 AC_SUBST(X_LDFLAGS)
 650 AC_SUBST(X_LIBS)
 651 AC_SUBST(TIXLIB)
 652 AC_SUBST(TIX_DEPS)
 653 AC_SUBST(GDBTKLIBS)
 654 # end-sanitize-gdbtk
 655
 656 AC_PATH_X
 657 # start-sanitize-sky
 658 # Enable GPU2 library for MIPS simulator
 659 AC_ARG_WITH(sim-gpu2,
 660 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 661 [case "${target}" in
 662   mips*-sky-*)
 663     if test -d "${withval}"
 664     then
 665       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 666     else
 667       AC_MSG_WARN([Directory ${withval} does not exist.])
 668     fi ;;
 669   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 670 esac])dnl
 671
 672 # Enable target accurate FP library
 673 AC_ARG_WITH(sim-funit,
 674 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 675 [case "${target}" in
 676   mips*-sky-*)
 677     if test -d "${withval}"
 678     then
 679       LIBS="${LIBS} -L${withval}/lib -lfunit"
 680     else
 681       AC_MSG_WARN([Directory ${withval} does not exist.])
 682     fi ;;
 683   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 684 esac])dnl
 685 # end-sanitize-sky
 686
 687 AC_SUBST(ENABLE_CFLAGS)
 688
 689 AC_SUBST(CONFIG_OBS)
 690 AC_SUBST(CONFIG_DEPS)
 691 AC_SUBST(CONFIG_SRCS)
 692
 693 # Begin stuff to support --enable-shared
 694 AC_ARG_ENABLE(shared,
 695 [  --enable-shared         Use shared libraries],
 696 [case "${enableval}" in
 697   yes) shared=true ;;
 698   no)  shared=false ;;
 699   *) shared=true ;;
 700 esac])dnl
 701
 702 HLDFLAGS=
 703 HLDENV=
 704 # If we have shared libraries, try to set rpath reasonably.
 705 if test "${shared}" = "true"; then
 706   case "${host}" in
 707   *-*-hpux*)
 708     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 709     ;;
 710   *-*-irix5* | *-*-irix6*)
 711     HLDFLAGS='-Wl,-rpath,$(libdir)'
 712     ;;
 713   *-*-linux*aout*)
 714     ;;
 715   *-*-linux* | *-pc-linux-gnu)
 716     HLDFLAGS='-Wl,-rpath,$(libdir)'
 717     ;;
 718   *-*-solaris*)
 719     HLDFLAGS='-R $(libdir)'
 720     ;;
 721   *-*-sysv4*)
 722     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 723     ;;
 724   esac
 725 fi
 726
 727 # On SunOS, if the linker supports the -rpath option, use it to
 728 # prevent ../bfd and ../opcodes from being included in the run time
 729 # search path.
 730 case "${host}" in
 731   *-*-sunos*)
 732     echo 'main () { }' > conftest.c
 733     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 734     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 735       :
 736     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 737       :
 738     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 739       :
 740     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 741       :
 742     elif test "${shared}" = "true"; then
 743       HLDFLAGS='-Wl,-rpath=$(libdir)'
 744     else
 745       HLDFLAGS='-Wl,-rpath='
 746     fi
 747     rm -f conftest.t conftest.c conftest
 748     ;;
 749 esac
 750 AC_SUBST(HLDFLAGS)
 751 AC_SUBST(HLDENV)
 752 # End stuff to support --enable-shared
 753
 754 # target_subdir is used by the testsuite to find the target libraries.
 755 target_subdir=
 756 if test "${host}" != "${target}"; then
 757     target_subdir="${target_alias}/"
 758 fi
 759 AC_SUBST(target_subdir)
 760
 761 frags=
 762 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 763 if test ! -f ${host_makefile_frag}; then
 764 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 765 fi
 766 frags="$frags $host_makefile_frag"
 767
 768 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 769 if test ! -f ${target_makefile_frag}; then
 770 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 771 fi
 772 frags="$frags $target_makefile_frag"
 773
 774 AC_SUBST_FILE(host_makefile_frag)
 775 AC_SUBST_FILE(target_makefile_frag)
 776 AC_SUBST(frags)
 777
 778 changequote(,)dnl
 779 hostfile=`sed -n '
 780 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 781 ' ${host_makefile_frag}`
 782
 783 targetfile=`sed -n '
 784 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 785 ' ${target_makefile_frag}`
 786
 787 # these really aren't orthogonal true/false values of the same condition,
 788 # but shells are slow enough that I like to reuse the test conditions
 789 # whenever possible
 790 if test "${target}" = "${host}"; then
 791 nativefile=`sed -n '
 792 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 793 ' ${host_makefile_frag}`
 794 # else
 795 # GDBserver is only useful in a "native" enviroment
 796 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 797 fi
 798 changequote([,])
 799
 800 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 801 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 802 # corresponding links.  But we have to remove the xm.h files and tm.h
 803 # files anyway, e.g. when switching from "configure host" to
 804 # "configure none".
 805
 806 files=
 807 links=
 808 rm -f xm.h
 809 if test "${hostfile}" != ""; then
 810 files="${files} config/${gdb_host_cpu}/${hostfile}"
 811 links="${links} xm.h"
 812 fi
 813 rm -f tm.h
 814 if test "${targetfile}" != ""; then
 815 files="${files} config/${gdb_target_cpu}/${targetfile}"
 816 links="${links} tm.h"
 817 fi
 818 rm -f nm.h
 819 if test "${nativefile}" != ""; then
 820 files="${files} config/${gdb_host_cpu}/${nativefile}"
 821 links="${links} nm.h"
 822 else
 823 # A cross-only configuration.
 824 files="${files} config/nm-empty.h"
 825 links="${links} nm.h"
 826 fi
 827 # start-sanitize-gdbtk
 828 AC_PROG_LN_S
 829 # Make it possible to use the GUI without doing a full install
 830 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 831   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 832   echo linking $srcdir/gdbtcl2 to gdbtcl2
 833   $LN_S $srcdir/gdbtcl2 gdbtcl2
 834   else
 835   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 836   echo "         " make install before you are able to run the GUI.
 837   fi
 838 fi
 839 # end-sanitize-gdbtk
 840
 841 AC_LINK_FILES($files, $links)
 842
 843 dnl Check for exe extension set on certain hosts (e.g. Win32)
 844 AM_EXEEXT
 845
 846 AC_CONFIG_SUBDIRS($configdirs)
 847 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 848 [
 849 dnl Autoconf doesn't provide a mechanism for modifying definitions
 850 dnl provided by makefile fragments.
 851 dnl
 852 if test "${nativefile}" = ""; then
 853 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 854         < Makefile > Makefile.tem
 855 mv -f Makefile.tem Makefile
 856 fi
 857
 858 changequote(,)dnl
 859 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 860 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 861 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 862 mv -f Makefile.tmp Makefile
 863 changequote([,])dnl
 864
 865 case x$CONFIG_HEADERS in
 866 xconfig.h:config.in)
 867 echo > stamp-h ;;
 868 esac
 869 ],
 870 [
 871 gdb_host_cpu=$gdb_host_cpu
 872 gdb_target_cpu=$gdb_target_cpu
 873 nativefile=$nativefile
 874 ])
 875
 876 exit 0