gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34 AC_CHECK_TOOL(AR, ar)
  35 AC_CHECK_TOOL(RANLIB, ranlib, :)
  36 AC_PROG_YACC
  37 AC_PROG_AWK
  38
  39 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  40 AC_ARG_PROGRAM
  41
  42 AC_HEADER_STDC
  43 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  44 AC_HEADER_STAT
  45
  46 AC_C_CONST
  47
  48 AC_CHECK_FUNCS(setpgid sbrk select poll)
  49
  50 dnl List of object files added by configuire.
  51
  52 CONFIG_OBS=
  53
  54 # If we are configured native on Linux, work around problems with sys/procfs.h
  55 if test "${target}" = "${host}"; then
  56   case "${host}" in
  57   i[3456]86-*-linux*)
  58         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,"2")
  59         AC_DEFINE(sys_quotactl)
  60         ;;
  61   esac
  62 fi
  63
  64 AC_MSG_CHECKING([for gregset_t type])
  65 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  66 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  67 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  68 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  69 if test $gdb_cv_have_gregset_t = yes; then
  70   AC_DEFINE(HAVE_GREGSET_T)
  71 fi
  72
  73 AC_MSG_CHECKING([for fpregset_t type])
  74 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  75 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  76 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  77 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  78 if test $gdb_cv_have_fpregset_t = yes; then
  79   AC_DEFINE(HAVE_FPREGSET_T)
  80 fi
  81
  82 dnl See if host has libm.  This is usually needed by simulators.
  83 AC_CHECK_LIB(m, main)
  84
  85 dnl See if compiler supports "long long" type.
  86
  87 AC_MSG_CHECKING(for long long support in compiler)
  88 AC_CACHE_VAL(gdb_cv_c_long_long,
  89 [AC_TRY_COMPILE(, [
  90   extern long long foo;
  91   switch (foo & 2) { case 0: return 1; }
  92 ],
  93 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
  94 AC_MSG_RESULT($gdb_cv_c_long_long)
  95 if test $gdb_cv_c_long_long = yes; then
  96   AC_DEFINE(CC_HAS_LONG_LONG)
  97 fi
  98
  99 dnl See if the compiler and runtime support printing long long
 100
 101 AC_MSG_CHECKING(for long long support in printf)
 102 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 103 [AC_TRY_RUN([
 104 int main () {
 105   char buf[16];
 106   long long l = 0x12345;
 107   sprintf (buf, "%llx", l);
 108   return (strcmp ("12345", buf));
 109 }],
 110 gdb_cv_printf_has_long_long=yes,
 111 gdb_cv_printf_has_long_long=no,
 112 gdb_cv_printf_has_long_long=no)])
 113 if test $gdb_cv_printf_has_long_long = yes; then
 114   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 115 fi
 116 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 117
 118 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 119 dnl because autoconf complains about cross-compilation issues.  However, this
 120 dnl code uses the same variables as the macro for compatibility.
 121
 122 AC_MSG_CHECKING(for long double support in compiler)
 123 AC_CACHE_VAL(ac_cv_c_long_double,
 124 [AC_TRY_COMPILE(, [long double foo;],
 125 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 126 AC_MSG_RESULT($ac_cv_c_long_double)
 127 if test $ac_cv_c_long_double = yes; then
 128   AC_DEFINE(HAVE_LONG_DOUBLE)
 129 fi
 130
 131 dnl See if the compiler and runtime support printing long doubles
 132
 133 AC_MSG_CHECKING(for long double support in printf)
 134 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 135 [AC_TRY_RUN([
 136 int main () {
 137   char buf[16];
 138   long double f = 3.141592653;
 139   sprintf (buf, "%Lg", f);
 140   return (strncmp ("3.14159", buf, 7));
 141 }],
 142 gdb_cv_printf_has_long_double=yes,
 143 gdb_cv_printf_has_long_double=no,
 144 gdb_cv_printf_has_long_double=no)])
 145 if test $gdb_cv_printf_has_long_double = yes; then
 146   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 147 fi
 148 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 149
 150 AC_FUNC_MMAP
 151
 152 BFD_NEED_DECLARATION(malloc)
 153 BFD_NEED_DECLARATION(realloc)
 154 BFD_NEED_DECLARATION(free)
 155
 156 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 157 dnl we must explicitly test for version 1 of the library because version 0
 158 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 159
 160 dnl Note that we only want this if we are both native (host == target), and
 161 dnl not doing a canadian cross build (build == host).
 162
 163 if test ${build} = ${host} -a ${host} = ${target} ; then
 164         case ${host_os} in
 165         hpux*)
 166                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 167                 if test -f /usr/include/dce/cma_config.h ; then
 168                         AC_MSG_RESULT(yes)
 169                         AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 170                         CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 171                 else
 172                         AC_MSG_RESULT(no)
 173                 fi
 174                 ;;
 175         solaris*)
 176                 AC_MSG_CHECKING(for Solaris thread debugging library)
 177                 if test -f /usr/lib/libthread_db.so.1 ; then
 178                         AC_MSG_RESULT(yes)
 179                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 180                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 181                         AC_CHECK_LIB(dl, dlopen)
 182                         if test "$GCC" = "yes" ; then
 183                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 184                         fi
 185                 else
 186                         AC_MSG_RESULT(no)
 187                 fi
 188                 ;;
 189         esac
 190         AC_SUBST(CONFIG_LDFLAGS)
 191 fi
 192
 193 dnl Handle optional features that can be enabled.
 194 ENABLE_CFLAGS=
 195
 196 AC_ARG_ENABLE(netrom,
 197 [  --enable-netrom ],
 198 [case "${enableval}" in
 199 yes)    enable_netrom=yes ;;
 200 no)     enable_netrom=no ;;
 201 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 202 esac])
 203
 204 if test "${enable_netrom}" = "yes"; then
 205         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 206 fi
 207
 208 # start-sanitize-gm
 209 ENABLE_GM=
 210
 211 AC_ARG_ENABLE(gm,
 212 [  --enable-gm ],
 213 [case "${enableval}" in
 214 yes)    CONFIG_OBS="${CONFIG_OBS} gmagic.o"
 215         ENABLE_CFLAGS=-DGENERAL_MAGIC
 216         ;;
 217 no)     ;;
 218 *)      AC_MSG_ERROR(bad value ${enableval} given for gm option) ;;
 219 esac])
 220
 221 # end-sanitize-gm
 222
 223 AC_ARG_ENABLE(sim-powerpc,
 224 [  --enable-sim-powerpc ],
 225 [case "${enableval}" in
 226 yes)    powerpc_sim=yes ;;
 227 no)     powerpc_sim=no ;;
 228 *)      AC_MSG_ERROR(bad value ${enableval} given for sim-powerpc option) ;;
 229 esac],[if test x"$GCC" != x""; then powerpc_sim=yes; else powerpc_sim=no; fi])
 230
 231 # start-sanitize-gdbtk
 232 ENABLE_GDBTK=
 233
 234 AC_ARG_ENABLE(gdbtk,
 235 [  --enable-gdbtk ],
 236 [case "${enableval}" in
 237     yes)
 238         case "$host" in
 239         *go32*)
 240             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 241             enable_gdbtk=no ;;
 242         *cygwin32* | *windows*)
 243             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 244             enable_gdbtk=no ;;
 245         *)
 246             enable_gdbtk=yes ;;
 247         esac ;;
 248     no)
 249         enable_gdbtk=no  ;;
 250     *)
 251         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 252 esac],
 253 [
 254 # Default is on for everything but go32 and cygwin32
 255 case "$host" in
 256     *go32* | *cygwin32* | *windows*)
 257         ;;
 258     *)
 259         enable_gdbtk=yes ;;
 260     esac
 261 ])
 262
 263 if test "${enable_gdbtk}" = "yes"; then
 264
 265     CY_AC_PATH_TCLCONFIG
 266     if test -z "${no_tcl}"; then
 267         CY_AC_LOAD_TCLCONFIG
 268         CY_AC_PATH_TKCONFIG
 269
 270         # If $no_tk is nonempty, then we can't do Tk, and there is no
 271         # point to doing Tcl.
 272         if test -z "${no_tk}"; then
 273            CY_AC_LOAD_TKCONFIG
 274            CY_AC_PATH_TCLH
 275            CY_AC_PATH_TKH
 276
 277            ENABLE_GDBTK=1
 278
 279            # Include some libraries that Tcl and Tk want.
 280            TCL_LIBS='$(TCL) $(TK) $(X11_LDFLAGS) $(X11_LIBS)'
 281            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 282            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 283         fi
 284     fi
 285 fi
 286
 287 AC_SUBST(ENABLE_GDBTK)
 288 AC_SUBST(X_CFLAGS)
 289 AC_SUBST(X_LDFLAGS)
 290 AC_SUBST(X_LIBS)
 291 # end-sanitize-gdbtk
 292
 293 AC_SUBST(ENABLE_CFLAGS)
 294
 295 AC_SUBST(CONFIG_OBS)
 296
 297 # Begin stuff to support --enable-shared
 298 AC_ARG_ENABLE(shared,
 299 [  --enable-shared         use shared libraries],
 300 [case "${enableval}" in
 301   yes) shared=true ;;
 302   no)  shared=false ;;
 303   *) shared=true ;;
 304 esac])dnl
 305
 306 HLDFLAGS=
 307 HLDENV=
 308 # If we have shared libraries, try to set rpath reasonably.
 309 if test "${shared}" = "true"; then
 310   case "${host}" in
 311   *-*-hpux*)
 312     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 313     ;;
 314   *-*-irix5* | *-*-irix6*)
 315     HLDFLAGS='-Wl,-rpath,$(libdir)'
 316     ;;
 317   *-*-linux*aout*)
 318     ;;
 319   *-*-linux* | *-pc-linux-gnu)
 320     HLDFLAGS='-Wl,-rpath,$(libdir)'
 321     ;;
 322   *-*-solaris*)
 323     HLDFLAGS='-R $(libdir)'
 324     ;;
 325   *-*-sysv4*)
 326     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 327     ;;
 328   esac
 329 fi
 330
 331 # On SunOS, if the linker supports the -rpath option, use it to
 332 # prevent ../bfd and ../opcodes from being included in the run time
 333 # search path.
 334 case "${host}" in
 335   *-*-sunos*)
 336     echo 'main () { }' > conftest.c
 337     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 338     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 339       :
 340     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 341       :
 342     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 343       :
 344     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 345       :
 346     elif test "${shared}" = "true"; then
 347       HLDFLAGS='-Wl,-rpath=$(libdir)'
 348     else
 349       HLDFLAGS='-Wl,-rpath='
 350     fi
 351     rm -f conftest.t conftest.c conftest
 352     ;;
 353 esac
 354 AC_SUBST(HLDFLAGS)
 355 AC_SUBST(HLDENV)
 356 # End stuff to support --enable-shared
 357
 358 # target_subdir is used by the testsuite to find the target libraries.
 359 target_subdir=
 360 if test "${host}" != "${target}"; then
 361     target_subdir="${target_alias}/"
 362 fi
 363 AC_SUBST(target_subdir)
 364
 365 configdirs="doc testsuite"
 366
 367 dnl
 368 changequote(,)dnl
 369
 370 . ${srcdir}/configure.host
 371
 372 . ${srcdir}/configure.tgt
 373
 374 dnl
 375 changequote([,])dnl
 376
 377 frags=
 378 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 379 if test ! -f ${host_makefile_frag}; then
 380 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 381 fi
 382 frags="$frags $host_makefile_frag"
 383
 384 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 385 if test ! -f ${target_makefile_frag}; then
 386 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 387 fi
 388 frags="$frags $target_makefile_frag"
 389
 390 AC_SUBST_FILE(host_makefile_frag)
 391 AC_SUBST_FILE(target_makefile_frag)
 392 AC_SUBST(frags)
 393
 394 changequote(,)dnl
 395 hostfile=`sed -n '
 396 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 397 ' ${host_makefile_frag}`
 398
 399 targetfile=`sed -n '
 400 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 401 ' ${target_makefile_frag}`
 402
 403 # these really aren't orthogonal true/false values of the same condition,
 404 # but shells are slow enough that I like to reuse the test conditions
 405 # whenever possible
 406 if test "${target}" = "${host}"; then
 407 nativefile=`sed -n '
 408 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 409 ' ${host_makefile_frag}`
 410 else
 411 # GDBserver is only useful in a "native" enviroment
 412 configdirs=`echo $configdirs | sed 's/gdbserver//'`
 413 fi
 414 changequote([,])
 415
 416 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 417 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 418 # corresponding links.  But we have to remove the xm.h files and tm.h
 419 # files anyway, e.g. when switching from "configure host" to
 420 # "configure none".
 421
 422 files=
 423 links=
 424 rm -f xm.h
 425 if test "${hostfile}" != ""; then
 426 files="${files} config/${gdb_host_cpu}/${hostfile}"
 427 links="${links} xm.h"
 428 fi
 429 rm -f tm.h
 430 if test "${targetfile}" != ""; then
 431 files="${files} config/${gdb_target_cpu}/${targetfile}"
 432 links="${links} tm.h"
 433 fi
 434 rm -f nm.h
 435 if test "${nativefile}" != ""; then
 436 files="${files} config/${gdb_host_cpu}/${nativefile}"
 437 links="${links} nm.h"
 438 else
 439 # A cross-only configuration.
 440 files="${files} config/nm-empty.h"
 441 links="${links} nm.h"
 442 fi
 443 # start-sanitize-gdbtk
 444
 445 # Make it possible to use the GUI without doing a full install
 446 if test "${enable_gdbtk}" = "yes" -a ! -f gdbtk.tcl ; then
 447 files="${files} gdbtk.tcl"
 448 links="${links} gdbtk.tcl"
 449 fi
 450 # end-sanitize-gdbtk
 451
 452 AC_LINK_FILES($files, $links)
 453
 454 AC_CONFIG_SUBDIRS($configdirs)
 455 AC_OUTPUT(Makefile,
 456 [
 457 dnl Autoconf doesn't provide a mechanism for modifying definitions
 458 dnl provided by makefile fragments.
 459 dnl
 460 if test "${nativefile}" = ""; then
 461 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 462         < Makefile > Makefile.tem
 463 mv -f Makefile.tem Makefile
 464 fi
 465
 466 changequote(,)dnl
 467 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 468 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 469 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 470 mv -f Makefile.tmp Makefile
 471 changequote([,])dnl
 472
 473 case ${srcdir} in
 474 .)
 475 ;;
 476 *)
 477 grep "source ${srcdir}/.gdbinit" .gdbinit >/dev/null 2>/dev/null || \
 478 echo "source ${srcdir}/.gdbinit" >> .gdbinit
 479 esac
 480
 481 case x$CONFIG_HEADERS in
 482 xconfig.h:config.in)
 483 echo > stamp-h ;;
 484 esac
 485 ],
 486 [
 487 gdb_host_cpu=$gdb_host_cpu
 488 gdb_target_cpu=$gdb_target_cpu
 489 nativefile=$nativefile
 490 ])
 491
 492 exit 0
 493