gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 dnl List of object files added by configure.
  34
  35 CONFIG_OBS=
  36
  37 configdirs="doc testsuite"
  38
  39 dnl
  40 changequote(,)dnl
  41
  42 . ${srcdir}/configure.host
  43
  44 . ${srcdir}/configure.tgt
  45
  46 dnl
  47 changequote([,])dnl
  48
  49 AC_PROG_INSTALL
  50 AC_CHECK_TOOL(AR, ar)
  51 AC_CHECK_TOOL(RANLIB, ranlib, :)
  52 AC_PROG_YACC
  53 AC_PROG_AWK
  54
  55 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  56 AC_ARG_PROGRAM
  57
  58 AC_HEADER_STDC
  59 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  60 AC_HEADER_STAT
  61
  62 AC_C_CONST
  63
  64 AC_CHECK_FUNCS(setpgid sbrk select poll)
  65
  66 # If we are configured native on Linux, work around problems with sys/procfs.h
  67 if test "${target}" = "${host}"; then
  68   case "${host}" in
  69   i[3456]86-*-linux*)
  70         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,"2")
  71         AC_DEFINE(sys_quotactl)
  72         ;;
  73   esac
  74 fi
  75
  76 AC_MSG_CHECKING([for gregset_t type])
  77 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  78 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  79 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  80 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  81 if test $gdb_cv_have_gregset_t = yes; then
  82   AC_DEFINE(HAVE_GREGSET_T)
  83 fi
  84
  85 AC_MSG_CHECKING([for fpregset_t type])
  86 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  87 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  88 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  89 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  90 if test $gdb_cv_have_fpregset_t = yes; then
  91   AC_DEFINE(HAVE_FPREGSET_T)
  92 fi
  93
  94 dnl See if host has libm.  This is usually needed by simulators.
  95 AC_CHECK_LIB(m, main)
  96
  97 dnl See if compiler supports "long long" type.
  98
  99 AC_MSG_CHECKING(for long long support in compiler)
 100 AC_CACHE_VAL(gdb_cv_c_long_long,
 101 [AC_TRY_COMPILE(, [
 102   extern long long foo;
 103   switch (foo & 2) { case 0: return 1; }
 104 ],
 105 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 106 AC_MSG_RESULT($gdb_cv_c_long_long)
 107 if test $gdb_cv_c_long_long = yes; then
 108   AC_DEFINE(CC_HAS_LONG_LONG)
 109 fi
 110
 111 dnl See if the compiler and runtime support printing long long
 112
 113 AC_MSG_CHECKING(for long long support in printf)
 114 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 115 [AC_TRY_RUN([
 116 int main () {
 117   char buf[16];
 118   long long l = 0x12345;
 119   sprintf (buf, "%llx", l);
 120   return (strcmp ("12345", buf));
 121 }],
 122 gdb_cv_printf_has_long_long=yes,
 123 gdb_cv_printf_has_long_long=no,
 124 gdb_cv_printf_has_long_long=no)])
 125 if test $gdb_cv_printf_has_long_long = yes; then
 126   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 127 fi
 128 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 129
 130 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 131 dnl because autoconf complains about cross-compilation issues.  However, this
 132 dnl code uses the same variables as the macro for compatibility.
 133
 134 AC_MSG_CHECKING(for long double support in compiler)
 135 AC_CACHE_VAL(ac_cv_c_long_double,
 136 [AC_TRY_COMPILE(, [long double foo;],
 137 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 138 AC_MSG_RESULT($ac_cv_c_long_double)
 139 if test $ac_cv_c_long_double = yes; then
 140   AC_DEFINE(HAVE_LONG_DOUBLE)
 141 fi
 142
 143 dnl See if the compiler and runtime support printing long doubles
 144
 145 AC_MSG_CHECKING(for long double support in printf)
 146 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 147 [AC_TRY_RUN([
 148 int main () {
 149   char buf[16];
 150   long double f = 3.141592653;
 151   sprintf (buf, "%Lg", f);
 152   return (strncmp ("3.14159", buf, 7));
 153 }],
 154 gdb_cv_printf_has_long_double=yes,
 155 gdb_cv_printf_has_long_double=no,
 156 gdb_cv_printf_has_long_double=no)])
 157 if test $gdb_cv_printf_has_long_double = yes; then
 158   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 159 fi
 160 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 161
 162 AC_FUNC_MMAP
 163
 164 BFD_NEED_DECLARATION(malloc)
 165 BFD_NEED_DECLARATION(realloc)
 166 BFD_NEED_DECLARATION(free)
 167
 168 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 169 dnl we must explicitly test for version 1 of the library because version 0
 170 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 171
 172 dnl Note that we only want this if we are both native (host == target), and
 173 dnl not doing a canadian cross build (build == host).
 174
 175 if test ${build} = ${host} -a ${host} = ${target} ; then
 176         case ${host_os} in
 177         hpux*)
 178                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 179                 if test -f /usr/include/dce/cma_config.h ; then
 180                         AC_MSG_RESULT(yes)
 181                         AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 182                         CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 183                 else
 184                         AC_MSG_RESULT(no)
 185                 fi
 186                 ;;
 187         solaris*)
 188                 AC_MSG_CHECKING(for Solaris thread debugging library)
 189                 if test -f /usr/lib/libthread_db.so.1 ; then
 190                         AC_MSG_RESULT(yes)
 191                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 192                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 193                         AC_CHECK_LIB(dl, dlopen)
 194                         if test "$GCC" = "yes" ; then
 195                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 196                         fi
 197                 else
 198                         AC_MSG_RESULT(no)
 199                 fi
 200                 ;;
 201         esac
 202         AC_SUBST(CONFIG_LDFLAGS)
 203 fi
 204
 205 dnl Handle optional features that can be enabled.
 206 ENABLE_CFLAGS=
 207
 208 AC_ARG_ENABLE(netrom,
 209 [  --enable-netrom ],
 210 [case "${enableval}" in
 211 yes)    enable_netrom=yes ;;
 212 no)     enable_netrom=no ;;
 213 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 214 esac])
 215
 216 if test "${enable_netrom}" = "yes"; then
 217         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 218 fi
 219
 220 # start-sanitize-gm
 221 ENABLE_GM=
 222
 223 AC_ARG_ENABLE(gm,
 224 [  --enable-gm ],
 225 [case "${enableval}" in
 226 yes)    CONFIG_OBS="${CONFIG_OBS} gmagic.o"
 227         ENABLE_CFLAGS=-DGENERAL_MAGIC
 228         ;;
 229 no)     ;;
 230 *)      AC_MSG_ERROR(bad value ${enableval} given for gm option) ;;
 231 esac])
 232
 233 # end-sanitize-gm
 234
 235 AC_ARG_ENABLE(sim-powerpc,
 236 [  --enable-sim-powerpc ],
 237 [case "${enableval}" in
 238 yes)    powerpc_sim=yes ;;
 239 no)     powerpc_sim=no ;;
 240 *)      AC_MSG_ERROR(bad value ${enableval} given for sim-powerpc option) ;;
 241 esac],[if test x"$GCC" != x""; then powerpc_sim=yes; else powerpc_sim=no; fi])
 242
 243 # start-sanitize-gdbtk
 244 ENABLE_GDBTK=
 245
 246 AC_ARG_ENABLE(gdbtk,
 247 [  --enable-gdbtk ],
 248 [case "${enableval}" in
 249     yes)
 250         case "$host" in
 251         *go32*)
 252             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 253             enable_gdbtk=no ;;
 254         *cygwin32* | *windows*)
 255             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 256             enable_gdbtk=no ;;
 257         *)
 258             enable_gdbtk=yes ;;
 259         esac ;;
 260     no)
 261         enable_gdbtk=no  ;;
 262     *)
 263         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 264 esac],
 265 [
 266 # Default is on for everything but go32 and cygwin32
 267 case "$host" in
 268     *go32* | *cygwin32* | *windows*)
 269         ;;
 270     *)
 271         enable_gdbtk=yes ;;
 272     esac
 273 ])
 274
 275 if test "${enable_gdbtk}" = "yes"; then
 276
 277     CY_AC_PATH_TCLCONFIG
 278     if test -z "${no_tcl}"; then
 279         CY_AC_LOAD_TCLCONFIG
 280         CY_AC_PATH_TKCONFIG
 281
 282         # If $no_tk is nonempty, then we can't do Tk, and there is no
 283         # point to doing Tcl.
 284         if test -z "${no_tk}"; then
 285            CY_AC_LOAD_TKCONFIG
 286            CY_AC_PATH_TCLH
 287            CY_AC_PATH_TKH
 288
 289            ENABLE_GDBTK=1
 290
 291            # Include some libraries that Tcl and Tk want.
 292            TCL_LIBS='$(TCL) $(TK) $(X11_LDFLAGS) $(X11_LIBS)'
 293            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 294            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 295         fi
 296     fi
 297 fi
 298
 299 AC_SUBST(ENABLE_GDBTK)
 300 AC_SUBST(X_CFLAGS)
 301 AC_SUBST(X_LDFLAGS)
 302 AC_SUBST(X_LIBS)
 303 # end-sanitize-gdbtk
 304
 305 AC_SUBST(ENABLE_CFLAGS)
 306
 307 AC_SUBST(CONFIG_OBS)
 308
 309 # Begin stuff to support --enable-shared
 310 AC_ARG_ENABLE(shared,
 311 [  --enable-shared         use shared libraries],
 312 [case "${enableval}" in
 313   yes) shared=true ;;
 314   no)  shared=false ;;
 315   *) shared=true ;;
 316 esac])dnl
 317
 318 HLDFLAGS=
 319 HLDENV=
 320 # If we have shared libraries, try to set rpath reasonably.
 321 if test "${shared}" = "true"; then
 322   case "${host}" in
 323   *-*-hpux*)
 324     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 325     ;;
 326   *-*-irix5* | *-*-irix6*)
 327     HLDFLAGS='-Wl,-rpath,$(libdir)'
 328     ;;
 329   *-*-linux*aout*)
 330     ;;
 331   *-*-linux* | *-pc-linux-gnu)
 332     HLDFLAGS='-Wl,-rpath,$(libdir)'
 333     ;;
 334   *-*-solaris*)
 335     HLDFLAGS='-R $(libdir)'
 336     ;;
 337   *-*-sysv4*)
 338     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 339     ;;
 340   esac
 341 fi
 342
 343 # On SunOS, if the linker supports the -rpath option, use it to
 344 # prevent ../bfd and ../opcodes from being included in the run time
 345 # search path.
 346 case "${host}" in
 347   *-*-sunos*)
 348     echo 'main () { }' > conftest.c
 349     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 350     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 351       :
 352     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 353       :
 354     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 355       :
 356     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 357       :
 358     elif test "${shared}" = "true"; then
 359       HLDFLAGS='-Wl,-rpath=$(libdir)'
 360     else
 361       HLDFLAGS='-Wl,-rpath='
 362     fi
 363     rm -f conftest.t conftest.c conftest
 364     ;;
 365 esac
 366 AC_SUBST(HLDFLAGS)
 367 AC_SUBST(HLDENV)
 368 # End stuff to support --enable-shared
 369
 370 # target_subdir is used by the testsuite to find the target libraries.
 371 target_subdir=
 372 if test "${host}" != "${target}"; then
 373     target_subdir="${target_alias}/"
 374 fi
 375 AC_SUBST(target_subdir)
 376
 377 frags=
 378 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 379 if test ! -f ${host_makefile_frag}; then
 380 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 381 fi
 382 frags="$frags $host_makefile_frag"
 383
 384 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 385 if test ! -f ${target_makefile_frag}; then
 386 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 387 fi
 388 frags="$frags $target_makefile_frag"
 389
 390 AC_SUBST_FILE(host_makefile_frag)
 391 AC_SUBST_FILE(target_makefile_frag)
 392 AC_SUBST(frags)
 393
 394 changequote(,)dnl
 395 hostfile=`sed -n '
 396 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 397 ' ${host_makefile_frag}`
 398
 399 targetfile=`sed -n '
 400 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 401 ' ${target_makefile_frag}`
 402
 403 # these really aren't orthogonal true/false values of the same condition,
 404 # but shells are slow enough that I like to reuse the test conditions
 405 # whenever possible
 406 if test "${target}" = "${host}"; then
 407 nativefile=`sed -n '
 408 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 409 ' ${host_makefile_frag}`
 410 else
 411 # GDBserver is only useful in a "native" enviroment
 412 configdirs=`echo $configdirs | sed 's/gdbserver//'`
 413 fi
 414 changequote([,])
 415
 416 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 417 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 418 # corresponding links.  But we have to remove the xm.h files and tm.h
 419 # files anyway, e.g. when switching from "configure host" to
 420 # "configure none".
 421
 422 files=
 423 links=
 424 rm -f xm.h
 425 if test "${hostfile}" != ""; then
 426 files="${files} config/${gdb_host_cpu}/${hostfile}"
 427 links="${links} xm.h"
 428 fi
 429 rm -f tm.h
 430 if test "${targetfile}" != ""; then
 431 files="${files} config/${gdb_target_cpu}/${targetfile}"
 432 links="${links} tm.h"
 433 fi
 434 rm -f nm.h
 435 if test "${nativefile}" != ""; then
 436 files="${files} config/${gdb_host_cpu}/${nativefile}"
 437 links="${links} nm.h"
 438 else
 439 # A cross-only configuration.
 440 files="${files} config/nm-empty.h"
 441 links="${links} nm.h"
 442 fi
 443 # start-sanitize-gdbtk
 444
 445 # Make it possible to use the GUI without doing a full install
 446 if test "${enable_gdbtk}" = "yes" -a ! -f gdbtk.tcl ; then
 447 files="${files} gdbtk.tcl"
 448 links="${links} gdbtk.tcl"
 449 fi
 450 # end-sanitize-gdbtk
 451
 452 AC_LINK_FILES($files, $links)
 453
 454 AC_CONFIG_SUBDIRS($configdirs)
 455 AC_OUTPUT(Makefile,
 456 [
 457 dnl Autoconf doesn't provide a mechanism for modifying definitions
 458 dnl provided by makefile fragments.
 459 dnl
 460 if test "${nativefile}" = ""; then
 461 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 462         < Makefile > Makefile.tem
 463 mv -f Makefile.tem Makefile
 464 fi
 465
 466 changequote(,)dnl
 467 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 468 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 469 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 470 mv -f Makefile.tmp Makefile
 471 changequote([,])dnl
 472
 473 case ${srcdir} in
 474 .)
 475 ;;
 476 *)
 477 grep "source ${srcdir}/.gdbinit" .gdbinit >/dev/null 2>/dev/null || \
 478 echo "source ${srcdir}/.gdbinit" >> .gdbinit
 479 esac
 480
 481 case x$CONFIG_HEADERS in
 482 xconfig.h:config.in)
 483 echo > stamp-h ;;
 484 esac
 485 ],
 486 [
 487 gdb_host_cpu=$gdb_host_cpu
 488 gdb_target_cpu=$gdb_target_cpu
 489 nativefile=$nativefile
 490 ])
 491
 492 exit 0
 493