gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h limits.h link.h \
  72                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  73                  string.h strings.h sys/procfs.h sys/ptrace.h sys/reg.h \
  74                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  75                  wchar.h wctype.h)
  76
  77 AC_HEADER_STAT
  78
  79 AC_C_CONST
  80
  81 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction isascii bzero bcopy \
  82                memcpy btowc)
  83 AC_FUNC_ALLOCA
  84
  85 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  86 if test "${target}" = "${host}"; then
  87   case "${host}" in
  88   i[[3456]]86-*-linux*)
  89         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  90         AC_DEFINE(sys_quotactl)
  91         ;;
  92   esac
  93 fi
  94
  95 AC_MSG_CHECKING([for gregset_t type])
  96 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  97 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  98 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  99 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 100 if test $gdb_cv_have_gregset_t = yes; then
 101   AC_DEFINE(HAVE_GREGSET_T)
 102 fi
 103
 104 AC_MSG_CHECKING([for fpregset_t type])
 105 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 106 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 107 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 108 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 109 if test $gdb_cv_have_fpregset_t = yes; then
 110   AC_DEFINE(HAVE_FPREGSET_T)
 111 fi
 112
 113 dnl See if host has libm.  This is usually needed by simulators.
 114 AC_CHECK_LIB(m, main)
 115
 116 dnl See if compiler supports "long long" type.
 117
 118 AC_MSG_CHECKING(for long long support in compiler)
 119 AC_CACHE_VAL(gdb_cv_c_long_long,
 120 [AC_TRY_COMPILE(, [
 121   extern long long foo;
 122   switch (foo & 2) { case 0: return 1; }
 123 ],
 124 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 125 AC_MSG_RESULT($gdb_cv_c_long_long)
 126 if test $gdb_cv_c_long_long = yes; then
 127   AC_DEFINE(CC_HAS_LONG_LONG)
 128 fi
 129
 130 dnl See if the compiler and runtime support printing long long
 131
 132 AC_MSG_CHECKING(for long long support in printf)
 133 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 134 [AC_TRY_RUN([
 135 int main () {
 136   char buf[32];
 137   long long l = 0;
 138   l = (l << 16) + 0x0123;
 139   l = (l << 16) + 0x4567;
 140   l = (l << 16) + 0x89ab;
 141   l = (l << 16) + 0xcdef;
 142   sprintf (buf, "0x%016llx", l);
 143   return (strcmp ("0x0123456789abcdef", buf));
 144 }],
 145 gdb_cv_printf_has_long_long=yes,
 146 gdb_cv_printf_has_long_long=no,
 147 gdb_cv_printf_has_long_long=no)])
 148 if test $gdb_cv_printf_has_long_long = yes; then
 149   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 150 fi
 151 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 152
 153 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 154 dnl because autoconf complains about cross-compilation issues.  However, this
 155 dnl code uses the same variables as the macro for compatibility.
 156
 157 AC_MSG_CHECKING(for long double support in compiler)
 158 AC_CACHE_VAL(ac_cv_c_long_double,
 159 [AC_TRY_COMPILE(, [long double foo;],
 160 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 161 AC_MSG_RESULT($ac_cv_c_long_double)
 162 if test $ac_cv_c_long_double = yes; then
 163   AC_DEFINE(HAVE_LONG_DOUBLE)
 164 fi
 165
 166 dnl See if the compiler and runtime support printing long doubles
 167
 168 AC_MSG_CHECKING(for long double support in printf)
 169 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 170 [AC_TRY_RUN([
 171 int main () {
 172   char buf[16];
 173   long double f = 3.141592653;
 174   sprintf (buf, "%Lg", f);
 175   return (strncmp ("3.14159", buf, 7));
 176 }],
 177 gdb_cv_printf_has_long_double=yes,
 178 gdb_cv_printf_has_long_double=no,
 179 gdb_cv_printf_has_long_double=no)])
 180 if test $gdb_cv_printf_has_long_double = yes; then
 181   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 182 fi
 183 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 184
 185 dnl See if the compiler and runtime support scanning long doubles
 186
 187 AC_MSG_CHECKING(for long double support in scanf)
 188 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 189 [AC_TRY_RUN([
 190 int main () {
 191   char *buf = "3.141592653";
 192   long double f = 0;
 193   sscanf (buf, "%Lg", &f);
 194   return !(f > 3.14159 && f < 3.14160);
 195 }],
 196 gdb_cv_scanf_has_long_double=yes,
 197 gdb_cv_scanf_has_long_double=no,
 198 gdb_cv_scanf_has_long_double=no)])
 199 if test $gdb_cv_scanf_has_long_double = yes; then
 200   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 201 fi
 202 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 203
 204 AC_FUNC_MMAP
 205
 206 BFD_NEED_DECLARATION(malloc)
 207 BFD_NEED_DECLARATION(realloc)
 208 BFD_NEED_DECLARATION(free)
 209
 210 BFD_NEED_DECLARATION(strerror)
 211
 212 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 213 dnl we must explicitly test for version 1 of the library because version 0
 214 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 215
 216 dnl Note that we only want this if we are both native (host == target), and
 217 dnl not doing a canadian cross build (build == host).
 218
 219 if test ${build} = ${host} -a ${host} = ${target} ; then
 220    case ${host_os} in
 221    hpux*)
 222       AC_MSG_CHECKING(for HPUX/OSF thread support)
 223       if test -f /usr/include/dce/cma_config.h ; then
 224          if test "$GCC" = "yes" ; then
 225             AC_MSG_RESULT(yes)
 226             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 227             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 228             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 229          else
 230             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 231          fi
 232       else
 233          AC_MSG_RESULT(no)
 234       fi
 235       ;;
 236    solaris*)
 237       AC_MSG_CHECKING(for Solaris thread debugging library)
 238       if test -f /usr/lib/libthread_db.so.1 ; then
 239          AC_MSG_RESULT(yes)
 240          AC_DEFINE(HAVE_THREAD_DB_LIB)
 241          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 242          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 243          AC_CHECK_LIB(dl, dlopen)
 244          if test "$GCC" = "yes" ; then
 245             # The GNU linker requires the -export-dynamic option to make
 246             # all symbols visible in the dynamic symbol table.
 247             hold_ldflags=$LDFLAGS
 248             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 249             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 250             AC_TRY_LINK(, [int i;], found=yes, found=no)
 251             LDFLAGS=$hold_ldflags
 252             AC_MSG_RESULT($found)
 253             if test $found = yes; then
 254                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 255             fi
 256          fi
 257       else
 258          AC_MSG_RESULT(no)
 259       fi
 260       ;;
 261    esac
 262    AC_SUBST(CONFIG_LDFLAGS)
 263 fi
 264
 265 dnl Handle optional features that can be enabled.
 266 ENABLE_CFLAGS=
 267
 268 AC_ARG_ENABLE(netrom,
 269 [  --enable-netrom ],
 270 [case "${enableval}" in
 271 yes)    enable_netrom=yes ;;
 272 no)     enable_netrom=no ;;
 273 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 274 esac])
 275
 276 if test "${enable_netrom}" = "yes"; then
 277         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 278         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 279 fi
 280
 281 AC_ARG_ENABLE(warnings,
 282 [  --enable-warnings       Enable compiler warnings if gcc is used],
 283 [case "${enableval}" in
 284 yes)    enable_warnings=yes ;;
 285 no)     enable_warnings=no ;;
 286 *)      AC_MSG_ERROR(bad value ${enableval} given for warnings options) ;;
 287 esac])
 288
 289 if test "x$enable_warnings" = xyes -a "x$GCC" = xyes
 290 then
 291    WARN_CFLAGS="-Wall -Wstrict-prototypes -Wmissing-prototypes"
 292 else
 293    WARN_CFLAGS=""
 294 fi
 295 AC_SUBST(WARN_CFLAGS)
 296
 297 MMALLOC_CFLAGS=
 298 MMALLOC=
 299 AC_SUBST(MMALLOC_CFLAGS)
 300 AC_SUBST(MMALLOC)
 301
 302 AC_ARG_WITH(mmalloc,
 303 [  --with-mmalloc          Use memory mapped malloc package],
 304 [case "${withval}" in
 305   yes)  want_mmalloc=true ;;
 306   no)   want_mmalloc=false;;
 307   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 308 esac],[want_mmalloc=false])dnl
 309
 310 if test x$want_mmalloc = xtrue; then
 311    AC_DEFINE(USE_MMALLOC)
 312    AC_DEFINE(MMCHECK_FORCE)
 313    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 314    MMALLOC='../mmalloc/libmmalloc.a'
 315 fi
 316
 317 # start-sanitize-gdbtk
 318 # start-sanitize-ide
 319 ENABLE_IDE=
 320 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 321 if test "$enable_ide" = yes; then
 322    enable_ide=yes
 323    ENABLE_IDE=1
 324 else
 325    enable_ide=no
 326 fi
 327 AC_SUBST(ENABLE_IDE)
 328
 329 AC_ARG_WITH(foundry-libs,
 330 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 331 [FOUNDRY_LIB_BASE=${withval}])
 332 AC_SUBST(FOUNDRY_LIB_BASE)
 333
 334 #
 335 # This is the Foundry SDK
 336 #
 337 # These variables are used to determine where the Foundry libs and
 338 # header files are located.
 339 #
 340 if test "$FOUNDRY_LIB_BASE" != ""; then
 341     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 342     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 343     if test x$enable_ide = xyes; then
 344         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 345         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 346     else
 347         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 348     fi
 349     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 350     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 351     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 352 else
 353     LIBGUI="../libgui/src/libgui.a"
 354     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 355     if test x$enable_ide = xyes; then
 356         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 357         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 358     else
 359         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 360     fi
 361     LIBIDETCL="../libidetcl/src/libidetcl.a"
 362     LIBIDE="../libide/src/libide.a"
 363     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 364 fi
 365 AC_SUBST(LIBGUI)
 366 AC_SUBST(GUI_CFLAGS_X)
 367 AC_SUBST(IDE_CFLAGS_X)
 368 AC_SUBST(IDE_X)
 369 AC_SUBST(LIBIDETCL)
 370 AC_SUBST(LIBIDE)
 371 AC_SUBST(IDE_DEPS)
 372 # end-sanitize-ide
 373
 374 ENABLE_GDBTK=
 375
 376 AC_ARG_ENABLE(gdbtk,
 377 [  --enable-gdbtk          Enable GDBTK GUI front end],
 378 [case "${enableval}" in
 379     yes)
 380         case "$host" in
 381         *go32*)
 382             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 383             enable_gdbtk=no ;;
 384         *windows*)
 385             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 386             enable_gdbtk=no ;;
 387         *)
 388             enable_gdbtk=yes ;;
 389         esac ;;
 390     no)
 391         enable_gdbtk=no  ;;
 392     *)
 393         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 394 esac],
 395 [
 396 # Default is on for everything but go32 and cygwin32
 397 case "$host" in
 398     *go32* | *windows*)
 399         ;;
 400     *)
 401         enable_gdbtk=yes ;;
 402     esac
 403 ])
 404
 405 # In the cygwin32 environment, we need some additional flags.
 406 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 407 [AC_EGREP_CPP(lose, [
 408 #ifdef __CYGWIN32__
 409 lose
 410 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 411
 412 WIN32LIBS=
 413 WIN32LDAPP=
 414 AC_SUBST(WIN32LIBS)
 415 AC_SUBST(WIN32LDAPP)
 416
 417 WINDRES=${WINDRES-windres}
 418 AC_SUBST(WINDRES)
 419
 420 if test x$gdb_cv_os_cygwin32 = xyes; then
 421     if test x$enable_ide = xyes; then
 422         WIN32LIBS="-ladvapi32"
 423     fi
 424 fi
 425
 426 configdir="unix"
 427
 428 GDBTKLIBS=
 429 if test "${enable_gdbtk}" = "yes"; then
 430
 431     CY_AC_PATH_TCLCONFIG
 432     if test -z "${no_tcl}"; then
 433         CY_AC_LOAD_TCLCONFIG
 434         CY_AC_PATH_TKCONFIG
 435
 436         # If $no_tk is nonempty, then we can't do Tk, and there is no
 437         # point to doing Tcl.
 438         if test -z "${no_tk}"; then
 439            CY_AC_LOAD_TKCONFIG
 440            CY_AC_PATH_TCLH
 441            CY_AC_PATH_TKH
 442            CY_AC_PATH_ITCLH
 443            CY_AC_PATH_TIX
 444
 445            # now look for tix library stuff
 446            TIXVERSION=4.1.8.0
 447            . ${ac_cv_c_tclconfig}/tclConfig.sh
 448            case "${host}" in
 449            *-*-cygwin32*)
 450                 tixdir=../tix/win/tcl8.0
 451                 ;;
 452            *)
 453                 tixdir=../tix/unix/tk8.0
 454                 ;;
 455            esac
 456            if test "${TCL_SHARED_BUILD}" = "1"; then
 457                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 458
 459                 # Can't win them all: SunOS 4 (others?) appends a version
 460                 # number after the ".so"
 461                 case "${host}" in
 462                 *-*-sunos4*)
 463                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 464                 esac
 465
 466            else
 467                 TIX_LIB_EXT=".a"
 468            fi
 469
 470            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 471                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 472                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 473            else
 474                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 475                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 476            fi
 477
 478            ENABLE_GDBTK=1
 479            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 480
 481            # Include some libraries that Tcl and Tk want.
 482            if test "${enable_ide}" = "yes"; then
 483               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 484               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 485            else
 486               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 487               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 488            fi
 489            # Yes, the ordering seems wrong here.  But it isn't.
 490            # TK_LIBS is the list of libraries that need to be linked
 491            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 492            # were in LIBS then any link tests after this point would
 493            # try to include things like `$(LIBGUI)', which wouldn't work.
 494            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 495            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 496
 497            if test x$gdb_cv_os_cygwin32 = xyes; then
 498               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 499               WIN32LDAPP="-Wl,--subsystem,console"
 500               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 501            fi
 502         fi
 503     fi
 504 fi
 505
 506 AC_SUBST(ENABLE_GDBTK)
 507 AC_SUBST(X_CFLAGS)
 508 AC_SUBST(X_LDFLAGS)
 509 AC_SUBST(X_LIBS)
 510 AC_SUBST(TIXLIB)
 511 AC_SUBST(TIX_DEPS)
 512 AC_SUBST(GDBTKLIBS)
 513 # end-sanitize-gdbtk
 514
 515 AC_PATH_X
 516 # start-sanitize-sky
 517 # Enable GPU2 library for MIPS simulator
 518 AC_ARG_WITH(sim-gpu2,
 519 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 520 [case "${target}" in
 521   mips*-sky-*)
 522     if test -d "${withval}"
 523     then
 524       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 525     else
 526       AC_MSG_WARN([Directory ${withval} does not exist.])
 527     fi ;;
 528   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 529 esac])dnl
 530
 531 # Enable target accurate FP library
 532 AC_ARG_WITH(sim-funit,
 533 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 534 [case "${target}" in
 535   mips*-sky-*)
 536     if test -d "${withval}"
 537     then
 538       LIBS="${LIBS} -L${withval}/lib -lfunit"
 539     else
 540       AC_MSG_WARN([Directory ${withval} does not exist.])
 541     fi ;;
 542   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 543 esac])dnl
 544 # end-sanitize-sky
 545
 546 dnl Solaris puts wctype in /usr/lib/libw.a
 547 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 548
 549 AC_SUBST(ENABLE_CFLAGS)
 550
 551 AC_SUBST(CONFIG_OBS)
 552 AC_SUBST(CONFIG_DEPS)
 553 AC_SUBST(CONFIG_SRCS)
 554
 555 # Begin stuff to support --enable-shared
 556 AC_ARG_ENABLE(shared,
 557 [  --enable-shared         Use shared libraries],
 558 [case "${enableval}" in
 559   yes) shared=true ;;
 560   no)  shared=false ;;
 561   *) shared=true ;;
 562 esac])dnl
 563
 564 HLDFLAGS=
 565 HLDENV=
 566 # If we have shared libraries, try to set rpath reasonably.
 567 if test "${shared}" = "true"; then
 568   case "${host}" in
 569   *-*-hpux*)
 570     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 571     ;;
 572   *-*-irix5* | *-*-irix6*)
 573     HLDFLAGS='-Wl,-rpath,$(libdir)'
 574     ;;
 575   *-*-linux*aout*)
 576     ;;
 577   *-*-linux* | *-pc-linux-gnu)
 578     HLDFLAGS='-Wl,-rpath,$(libdir)'
 579     ;;
 580   *-*-solaris*)
 581     HLDFLAGS='-R $(libdir)'
 582     ;;
 583   *-*-sysv4*)
 584     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 585     ;;
 586   esac
 587 fi
 588
 589 # On SunOS, if the linker supports the -rpath option, use it to
 590 # prevent ../bfd and ../opcodes from being included in the run time
 591 # search path.
 592 case "${host}" in
 593   *-*-sunos*)
 594     echo 'main () { }' > conftest.c
 595     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 596     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 597       :
 598     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 599       :
 600     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 601       :
 602     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 603       :
 604     elif test "${shared}" = "true"; then
 605       HLDFLAGS='-Wl,-rpath=$(libdir)'
 606     else
 607       HLDFLAGS='-Wl,-rpath='
 608     fi
 609     rm -f conftest.t conftest.c conftest
 610     ;;
 611 esac
 612 AC_SUBST(HLDFLAGS)
 613 AC_SUBST(HLDENV)
 614 # End stuff to support --enable-shared
 615
 616 # target_subdir is used by the testsuite to find the target libraries.
 617 target_subdir=
 618 if test "${host}" != "${target}"; then
 619     target_subdir="${target_alias}/"
 620 fi
 621 AC_SUBST(target_subdir)
 622
 623 frags=
 624 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 625 if test ! -f ${host_makefile_frag}; then
 626 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 627 fi
 628 frags="$frags $host_makefile_frag"
 629
 630 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 631 if test ! -f ${target_makefile_frag}; then
 632 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 633 fi
 634 frags="$frags $target_makefile_frag"
 635
 636 AC_SUBST_FILE(host_makefile_frag)
 637 AC_SUBST_FILE(target_makefile_frag)
 638 AC_SUBST(frags)
 639
 640 changequote(,)dnl
 641 hostfile=`sed -n '
 642 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 643 ' ${host_makefile_frag}`
 644
 645 targetfile=`sed -n '
 646 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 647 ' ${target_makefile_frag}`
 648
 649 # these really aren't orthogonal true/false values of the same condition,
 650 # but shells are slow enough that I like to reuse the test conditions
 651 # whenever possible
 652 if test "${target}" = "${host}"; then
 653 nativefile=`sed -n '
 654 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 655 ' ${host_makefile_frag}`
 656 # else
 657 # GDBserver is only useful in a "native" enviroment
 658 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 659 fi
 660 changequote([,])
 661
 662 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 663 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 664 # corresponding links.  But we have to remove the xm.h files and tm.h
 665 # files anyway, e.g. when switching from "configure host" to
 666 # "configure none".
 667
 668 files=
 669 links=
 670 rm -f xm.h
 671 if test "${hostfile}" != ""; then
 672 files="${files} config/${gdb_host_cpu}/${hostfile}"
 673 links="${links} xm.h"
 674 fi
 675 rm -f tm.h
 676 if test "${targetfile}" != ""; then
 677 files="${files} config/${gdb_target_cpu}/${targetfile}"
 678 links="${links} tm.h"
 679 fi
 680 rm -f nm.h
 681 if test "${nativefile}" != ""; then
 682 files="${files} config/${gdb_host_cpu}/${nativefile}"
 683 links="${links} nm.h"
 684 else
 685 # A cross-only configuration.
 686 files="${files} config/nm-empty.h"
 687 links="${links} nm.h"
 688 fi
 689 # start-sanitize-gdbtk
 690 AC_PROG_LN_S
 691 # Make it possible to use the GUI without doing a full install
 692 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 693   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 694   echo linking $srcdir/gdbtcl to gdbtcl
 695   $LN_S $srcdir/gdbtcl gdbtcl
 696   else
 697   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 698   echo "         " make install before you are able to run the GUI.
 699   fi
 700 fi
 701 # end-sanitize-gdbtk
 702
 703 AC_LINK_FILES($files, $links)
 704
 705 dnl Check for exe extension set on certain hosts (e.g. Win32)
 706 AM_EXEEXT
 707
 708 AC_CONFIG_SUBDIRS($configdirs)
 709 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 710 [
 711 dnl Autoconf doesn't provide a mechanism for modifying definitions
 712 dnl provided by makefile fragments.
 713 dnl
 714 if test "${nativefile}" = ""; then
 715 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 716         < Makefile > Makefile.tem
 717 mv -f Makefile.tem Makefile
 718 fi
 719
 720 changequote(,)dnl
 721 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 722 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 723 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 724 mv -f Makefile.tmp Makefile
 725 changequote([,])dnl
 726
 727 case x$CONFIG_HEADERS in
 728 xconfig.h:config.in)
 729 echo > stamp-h ;;
 730 esac
 731 ],
 732 [
 733 gdb_host_cpu=$gdb_host_cpu
 734 gdb_target_cpu=$gdb_target_cpu
 735 nativefile=$nativefile
 736 ])
 737
 738 exit 0
 739