gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl List of object files added by configure.
  38
  39 CONFIG_OBS=
  40
  41 configdirs="doc testsuite"
  42
  43 dnl
  44 changequote(,)dnl
  45
  46 . ${srcdir}/configure.host
  47
  48 . ${srcdir}/configure.tgt
  49
  50 dnl
  51 changequote([,])dnl
  52
  53 AC_PROG_INSTALL
  54 AC_CHECK_TOOL(AR, ar)
  55 AC_CHECK_TOOL(RANLIB, ranlib, :)
  56 AC_PROG_YACC
  57 AC_PROG_AWK
  58
  59 AC_ARG_PROGRAM
  60
  61 AC_TYPE_SIGNAL
  62
  63 AC_HEADER_STDC
  64 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  65 AC_HEADER_STAT
  66
  67 AC_C_CONST
  68
  69 AC_CHECK_FUNCS(setpgid sbrk select poll)
  70
  71 # If we are configured native on Linux, work around problems with sys/procfs.h
  72 if test "${target}" = "${host}"; then
  73   case "${host}" in
  74   i[3456]86-*-linux*)
  75         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,"2")
  76         AC_DEFINE(sys_quotactl)
  77         ;;
  78   esac
  79 fi
  80
  81 AC_MSG_CHECKING([for gregset_t type])
  82 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  83 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  84 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  85 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  86 if test $gdb_cv_have_gregset_t = yes; then
  87   AC_DEFINE(HAVE_GREGSET_T)
  88 fi
  89
  90 AC_MSG_CHECKING([for fpregset_t type])
  91 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  92 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
  93 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
  94 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
  95 if test $gdb_cv_have_fpregset_t = yes; then
  96   AC_DEFINE(HAVE_FPREGSET_T)
  97 fi
  98
  99 dnl See if host has libm.  This is usually needed by simulators.
 100 AC_CHECK_LIB(m, main)
 101
 102 dnl See if compiler supports "long long" type.
 103
 104 AC_MSG_CHECKING(for long long support in compiler)
 105 AC_CACHE_VAL(gdb_cv_c_long_long,
 106 [AC_TRY_COMPILE(, [
 107   extern long long foo;
 108   switch (foo & 2) { case 0: return 1; }
 109 ],
 110 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 111 AC_MSG_RESULT($gdb_cv_c_long_long)
 112 if test $gdb_cv_c_long_long = yes; then
 113   AC_DEFINE(CC_HAS_LONG_LONG)
 114 fi
 115
 116 dnl See if the compiler and runtime support printing long long
 117
 118 AC_MSG_CHECKING(for long long support in printf)
 119 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 120 [AC_TRY_RUN([
 121 int main () {
 122   char buf[32];
 123   long long l = 0;
 124   l = (l << 16) + 0x0123;
 125   l = (l << 16) + 0x4567;
 126   l = (l << 16) + 0x89ab;
 127   l = (l << 16) + 0xcdef;
 128   sprintf (buf, "0x%016llx", l);
 129   return (strcmp ("0x0123456789abcdef", buf));
 130 }],
 131 gdb_cv_printf_has_long_long=yes,
 132 gdb_cv_printf_has_long_long=no,
 133 gdb_cv_printf_has_long_long=no)])
 134 if test $gdb_cv_printf_has_long_long = yes; then
 135   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 136 fi
 137 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 138
 139 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 140 dnl because autoconf complains about cross-compilation issues.  However, this
 141 dnl code uses the same variables as the macro for compatibility.
 142
 143 AC_MSG_CHECKING(for long double support in compiler)
 144 AC_CACHE_VAL(ac_cv_c_long_double,
 145 [AC_TRY_COMPILE(, [long double foo;],
 146 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 147 AC_MSG_RESULT($ac_cv_c_long_double)
 148 if test $ac_cv_c_long_double = yes; then
 149   AC_DEFINE(HAVE_LONG_DOUBLE)
 150 fi
 151
 152 dnl See if the compiler and runtime support printing long doubles
 153
 154 AC_MSG_CHECKING(for long double support in printf)
 155 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 156 [AC_TRY_RUN([
 157 int main () {
 158   char buf[16];
 159   long double f = 3.141592653;
 160   sprintf (buf, "%Lg", f);
 161   return (strncmp ("3.14159", buf, 7));
 162 }],
 163 gdb_cv_printf_has_long_double=yes,
 164 gdb_cv_printf_has_long_double=no,
 165 gdb_cv_printf_has_long_double=no)])
 166 if test $gdb_cv_printf_has_long_double = yes; then
 167   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 168 fi
 169 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 170
 171 dnl See if the compiler and runtime support scanning long doubles
 172
 173 AC_MSG_CHECKING(for long double support in scanf)
 174 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 175 [AC_TRY_RUN([
 176 int main () {
 177   char *buf = "3.141592653";
 178   long double f = 0;
 179   sscanf (buf, "%Lg", &f);
 180   return !(f > 3.14159 && f < 3.14160);
 181 }],
 182 gdb_cv_scanf_has_long_double=yes,
 183 gdb_cv_scanf_has_long_double=no,
 184 gdb_cv_scanf_has_long_double=no)])
 185 if test $gdb_cv_scanf_has_long_double = yes; then
 186   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 187 fi
 188 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 189
 190 AC_FUNC_MMAP
 191
 192 BFD_NEED_DECLARATION(malloc)
 193 BFD_NEED_DECLARATION(realloc)
 194 BFD_NEED_DECLARATION(free)
 195
 196 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 197 dnl we must explicitly test for version 1 of the library because version 0
 198 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 199
 200 dnl Note that we only want this if we are both native (host == target), and
 201 dnl not doing a canadian cross build (build == host).
 202
 203 if test ${build} = ${host} -a ${host} = ${target} ; then
 204         case ${host_os} in
 205         hpux*)
 206                 AC_MSG_CHECKING(for HPUX/OSF thread support)
 207                 if test -f /usr/include/dce/cma_config.h ; then
 208                         if test "$GCC" = "yes" ; then
 209                                 AC_MSG_RESULT(yes)
 210                                 AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 211                                 CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 212                         else
 213                                 AC_MSG_RESULT(no (suppressed because you are not using GCC))
 214                         fi
 215                 else
 216                         AC_MSG_RESULT(no)
 217                 fi
 218                 ;;
 219         solaris*)
 220                 AC_MSG_CHECKING(for Solaris thread debugging library)
 221                 if test -f /usr/lib/libthread_db.so.1 ; then
 222                         AC_MSG_RESULT(yes)
 223                         AC_DEFINE(HAVE_THREAD_DB_LIB)
 224                         CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 225                         AC_CHECK_LIB(dl, dlopen)
 226                         if test "$GCC" = "yes" ; then
 227                                 CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Xlinker -export-dynamic"
 228                         fi
 229                 else
 230                         AC_MSG_RESULT(no)
 231                 fi
 232                 ;;
 233         esac
 234         AC_SUBST(CONFIG_LDFLAGS)
 235 fi
 236
 237 dnl Handle optional features that can be enabled.
 238 ENABLE_CFLAGS=
 239
 240 AC_ARG_ENABLE(netrom,
 241 [  --enable-netrom ],
 242 [case "${enableval}" in
 243 yes)    enable_netrom=yes ;;
 244 no)     enable_netrom=no ;;
 245 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 246 esac])
 247
 248 if test "${enable_netrom}" = "yes"; then
 249         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 250 fi
 251
 252 # start-sanitize-gdbtk
 253 ENABLE_IDE=
 254 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 255 if test "$enable_ide" = yes; then
 256    enable_ide=yes
 257    ENABLE_IDE=1
 258 else
 259    enable_ide=no
 260 fi
 261 AC_SUBST(ENABLE_IDE)
 262
 263 ENABLE_GDBTK=
 264
 265 AC_ARG_ENABLE(gdbtk,
 266 [  --enable-gdbtk ],
 267 [case "${enableval}" in
 268     yes)
 269         case "$host" in
 270         *go32*)
 271             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 272             enable_gdbtk=no ;;
 273         *windows*)
 274             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 275             enable_gdbtk=no ;;
 276         *)
 277             enable_gdbtk=yes ;;
 278         esac ;;
 279     no)
 280         enable_gdbtk=no  ;;
 281     *)
 282         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 283 esac],
 284 [
 285 # Default is on for everything but go32 and cygwin32
 286 case "$host" in
 287     *go32* | *windows*)
 288         ;;
 289     *)
 290         enable_gdbtk=yes ;;
 291     esac
 292 ])
 293
 294 # In the cygwin32 environment, we need some additional flags.
 295 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 296 [AC_EGREP_CPP(lose, [
 297 #ifdef __CYGWIN32__
 298 lose
 299 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 300
 301 WIN32LIBS=
 302 WIN32LDAPP=
 303 AC_SUBST(WIN32LIBS)
 304 AC_SUBST(WIN32LDAPP)
 305
 306 if test x$gdb_cv_os_cygwin32 = xyes; then
 307     if test x$enable_ide = xyes; then
 308         WIN32LIBS="-ladvapi32"
 309     fi
 310 fi
 311
 312 configdir="unix"
 313
 314 if test "${enable_gdbtk}" = "yes"; then
 315
 316     CY_AC_PATH_TCLCONFIG
 317     if test -z "${no_tcl}"; then
 318         CY_AC_LOAD_TCLCONFIG
 319         CY_AC_PATH_TKCONFIG
 320
 321         # If $no_tk is nonempty, then we can't do Tk, and there is no
 322         # point to doing Tcl.
 323         if test -z "${no_tk}"; then
 324            CY_AC_LOAD_TKCONFIG
 325            CY_AC_PATH_TCLH
 326            CY_AC_PATH_TKH
 327            CY_AC_PATH_ITCLH
 328            CY_AC_PATH_TIX
 329
 330            # now look for tix library stuff
 331            TIXVERSION=4.1.8.0
 332            . ${ac_cv_c_tclconfig}/tclConfig.sh
 333            case "${host}" in
 334            *-*-cygwin32*)
 335                 tixdir=../tix/win/tcl8.0
 336                 ;;
 337            *)
 338                 tixdir=../tix/unix/tk8.0
 339                 ;;
 340            esac
 341            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 342                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 343            else
 344                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 345            fi
 346
 347            ENABLE_GDBTK=1
 348
 349            # Include some libraries that Tcl and Tk want.
 350            if test "${enable_ide}" = "yes"; then
 351               TCL_LIBS='$(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 352            else
 353               TCL_LIBS='$(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 354            fi
 355            # Yes, the ordering seems wrong here.  But it isn't.
 356            # TK_LIBS is the list of libraries that need to be linked
 357            # after Tcl/Tk.
 358            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 359            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 360
 361            if test x$gdb_cv_os_cygwin32 = xyes; then
 362               WIN32LIBS="${WIN32LIBS} -luser32"
 363               WIN32LDAPP="-Wl,--subsystem,windows"
 364            fi
 365         fi
 366     fi
 367 fi
 368
 369 AC_SUBST(ENABLE_GDBTK)
 370 AC_SUBST(X_CFLAGS)
 371 AC_SUBST(X_LDFLAGS)
 372 AC_SUBST(X_LIBS)
 373 AC_SUBST(TIXLIB)
 374 # end-sanitize-gdbtk
 375
 376 AC_SUBST(ENABLE_CFLAGS)
 377
 378 AC_SUBST(CONFIG_OBS)
 379
 380 # Begin stuff to support --enable-shared
 381 AC_ARG_ENABLE(shared,
 382 [  --enable-shared         use shared libraries],
 383 [case "${enableval}" in
 384   yes) shared=true ;;
 385   no)  shared=false ;;
 386   *) shared=true ;;
 387 esac])dnl
 388
 389 HLDFLAGS=
 390 HLDENV=
 391 # If we have shared libraries, try to set rpath reasonably.
 392 if test "${shared}" = "true"; then
 393   case "${host}" in
 394   *-*-hpux*)
 395     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 396     ;;
 397   *-*-irix5* | *-*-irix6*)
 398     HLDFLAGS='-Wl,-rpath,$(libdir)'
 399     ;;
 400   *-*-linux*aout*)
 401     ;;
 402   *-*-linux* | *-pc-linux-gnu)
 403     HLDFLAGS='-Wl,-rpath,$(libdir)'
 404     ;;
 405   *-*-solaris*)
 406     HLDFLAGS='-R $(libdir)'
 407     ;;
 408   *-*-sysv4*)
 409     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 410     ;;
 411   esac
 412 fi
 413
 414 # On SunOS, if the linker supports the -rpath option, use it to
 415 # prevent ../bfd and ../opcodes from being included in the run time
 416 # search path.
 417 case "${host}" in
 418   *-*-sunos*)
 419     echo 'main () { }' > conftest.c
 420     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 421     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 422       :
 423     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 424       :
 425     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 426       :
 427     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 428       :
 429     elif test "${shared}" = "true"; then
 430       HLDFLAGS='-Wl,-rpath=$(libdir)'
 431     else
 432       HLDFLAGS='-Wl,-rpath='
 433     fi
 434     rm -f conftest.t conftest.c conftest
 435     ;;
 436 esac
 437 AC_SUBST(HLDFLAGS)
 438 AC_SUBST(HLDENV)
 439 # End stuff to support --enable-shared
 440
 441 # target_subdir is used by the testsuite to find the target libraries.
 442 target_subdir=
 443 if test "${host}" != "${target}"; then
 444     target_subdir="${target_alias}/"
 445 fi
 446 AC_SUBST(target_subdir)
 447
 448 frags=
 449 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 450 if test ! -f ${host_makefile_frag}; then
 451 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 452 fi
 453 frags="$frags $host_makefile_frag"
 454
 455 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 456 if test ! -f ${target_makefile_frag}; then
 457 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 458 fi
 459 frags="$frags $target_makefile_frag"
 460
 461 AC_SUBST_FILE(host_makefile_frag)
 462 AC_SUBST_FILE(target_makefile_frag)
 463 AC_SUBST(frags)
 464
 465 changequote(,)dnl
 466 hostfile=`sed -n '
 467 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 468 ' ${host_makefile_frag}`
 469
 470 targetfile=`sed -n '
 471 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 472 ' ${target_makefile_frag}`
 473
 474 # these really aren't orthogonal true/false values of the same condition,
 475 # but shells are slow enough that I like to reuse the test conditions
 476 # whenever possible
 477 if test "${target}" = "${host}"; then
 478 nativefile=`sed -n '
 479 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 480 ' ${host_makefile_frag}`
 481 # else
 482 # GDBserver is only useful in a "native" enviroment
 483 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 484 fi
 485 changequote([,])
 486
 487 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 488 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 489 # corresponding links.  But we have to remove the xm.h files and tm.h
 490 # files anyway, e.g. when switching from "configure host" to
 491 # "configure none".
 492
 493 files=
 494 links=
 495 rm -f xm.h
 496 if test "${hostfile}" != ""; then
 497 files="${files} config/${gdb_host_cpu}/${hostfile}"
 498 links="${links} xm.h"
 499 fi
 500 rm -f tm.h
 501 if test "${targetfile}" != ""; then
 502 files="${files} config/${gdb_target_cpu}/${targetfile}"
 503 links="${links} tm.h"
 504 fi
 505 rm -f nm.h
 506 if test "${nativefile}" != ""; then
 507 files="${files} config/${gdb_host_cpu}/${nativefile}"
 508 links="${links} nm.h"
 509 else
 510 # A cross-only configuration.
 511 files="${files} config/nm-empty.h"
 512 links="${links} nm.h"
 513 fi
 514 # start-sanitize-gdbtk
 515 AC_PROG_LN_S
 516 # Make it possible to use the GUI without doing a full install
 517 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 518   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 519   echo linking $srcdir/gdbtcl to gdbtcl
 520   $LN_S $srcdir/gdbtcl gdbtcl
 521   else
 522   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 523   echo "         " make install before you are able to run the GUI.
 524   fi
 525 fi
 526 # end-sanitize-gdbtk
 527
 528 AC_LINK_FILES($files, $links)
 529
 530 dnl Check for exe extension set on certain hosts (e.g. Win32)
 531 AM_EXEEXT
 532
 533 AC_CONFIG_SUBDIRS($configdirs)
 534 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 535 [
 536 dnl Autoconf doesn't provide a mechanism for modifying definitions
 537 dnl provided by makefile fragments.
 538 dnl
 539 if test "${nativefile}" = ""; then
 540 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 541         < Makefile > Makefile.tem
 542 mv -f Makefile.tem Makefile
 543 fi
 544
 545 changequote(,)dnl
 546 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 547 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 548 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 549 mv -f Makefile.tmp Makefile
 550 changequote([,])dnl
 551
 552 case x$CONFIG_HEADERS in
 553 xconfig.h:config.in)
 554 echo > stamp-h ;;
 555 esac
 556 ],
 557 [
 558 gdb_host_cpu=$gdb_host_cpu
 559 gdb_target_cpu=$gdb_target_cpu
 560 nativefile=$nativefile
 561 ])
 562
 563 exit 0
 564