gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h)
  72 AC_HEADER_STAT
  73
  74 AC_C_CONST
  75
  76 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction)
  77
  78 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  79 if test "${target}" = "${host}"; then
  80   case "${host}" in
  81   i[[3456]]86-*-linux*)
  82         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  83         AC_DEFINE(sys_quotactl)
  84         ;;
  85   esac
  86 fi
  87
  88 AC_MSG_CHECKING([for gregset_t type])
  89 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  90 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  91 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  92 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  93 if test $gdb_cv_have_gregset_t = yes; then
  94   AC_DEFINE(HAVE_GREGSET_T)
  95 fi
  96
  97 AC_MSG_CHECKING([for fpregset_t type])
  98 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
  99 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 100 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 101 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 102 if test $gdb_cv_have_fpregset_t = yes; then
 103   AC_DEFINE(HAVE_FPREGSET_T)
 104 fi
 105
 106 dnl See if host has libm.  This is usually needed by simulators.
 107 AC_CHECK_LIB(m, main)
 108
 109 dnl See if compiler supports "long long" type.
 110
 111 AC_MSG_CHECKING(for long long support in compiler)
 112 AC_CACHE_VAL(gdb_cv_c_long_long,
 113 [AC_TRY_COMPILE(, [
 114   extern long long foo;
 115   switch (foo & 2) { case 0: return 1; }
 116 ],
 117 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 118 AC_MSG_RESULT($gdb_cv_c_long_long)
 119 if test $gdb_cv_c_long_long = yes; then
 120   AC_DEFINE(CC_HAS_LONG_LONG)
 121 fi
 122
 123 dnl See if the compiler and runtime support printing long long
 124
 125 AC_MSG_CHECKING(for long long support in printf)
 126 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 127 [AC_TRY_RUN([
 128 int main () {
 129   char buf[32];
 130   long long l = 0;
 131   l = (l << 16) + 0x0123;
 132   l = (l << 16) + 0x4567;
 133   l = (l << 16) + 0x89ab;
 134   l = (l << 16) + 0xcdef;
 135   sprintf (buf, "0x%016llx", l);
 136   return (strcmp ("0x0123456789abcdef", buf));
 137 }],
 138 gdb_cv_printf_has_long_long=yes,
 139 gdb_cv_printf_has_long_long=no,
 140 gdb_cv_printf_has_long_long=no)])
 141 if test $gdb_cv_printf_has_long_long = yes; then
 142   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 143 fi
 144 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 145
 146 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 147 dnl because autoconf complains about cross-compilation issues.  However, this
 148 dnl code uses the same variables as the macro for compatibility.
 149
 150 AC_MSG_CHECKING(for long double support in compiler)
 151 AC_CACHE_VAL(ac_cv_c_long_double,
 152 [AC_TRY_COMPILE(, [long double foo;],
 153 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 154 AC_MSG_RESULT($ac_cv_c_long_double)
 155 if test $ac_cv_c_long_double = yes; then
 156   AC_DEFINE(HAVE_LONG_DOUBLE)
 157 fi
 158
 159 dnl See if the compiler and runtime support printing long doubles
 160
 161 AC_MSG_CHECKING(for long double support in printf)
 162 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 163 [AC_TRY_RUN([
 164 int main () {
 165   char buf[16];
 166   long double f = 3.141592653;
 167   sprintf (buf, "%Lg", f);
 168   return (strncmp ("3.14159", buf, 7));
 169 }],
 170 gdb_cv_printf_has_long_double=yes,
 171 gdb_cv_printf_has_long_double=no,
 172 gdb_cv_printf_has_long_double=no)])
 173 if test $gdb_cv_printf_has_long_double = yes; then
 174   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 175 fi
 176 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 177
 178 dnl See if the compiler and runtime support scanning long doubles
 179
 180 AC_MSG_CHECKING(for long double support in scanf)
 181 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 182 [AC_TRY_RUN([
 183 int main () {
 184   char *buf = "3.141592653";
 185   long double f = 0;
 186   sscanf (buf, "%Lg", &f);
 187   return !(f > 3.14159 && f < 3.14160);
 188 }],
 189 gdb_cv_scanf_has_long_double=yes,
 190 gdb_cv_scanf_has_long_double=no,
 191 gdb_cv_scanf_has_long_double=no)])
 192 if test $gdb_cv_scanf_has_long_double = yes; then
 193   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 194 fi
 195 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 196
 197 AC_FUNC_MMAP
 198
 199 BFD_NEED_DECLARATION(malloc)
 200 BFD_NEED_DECLARATION(realloc)
 201 BFD_NEED_DECLARATION(free)
 202
 203 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 204 dnl we must explicitly test for version 1 of the library because version 0
 205 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 206
 207 dnl Note that we only want this if we are both native (host == target), and
 208 dnl not doing a canadian cross build (build == host).
 209
 210 if test ${build} = ${host} -a ${host} = ${target} ; then
 211    case ${host_os} in
 212    hpux*)
 213       AC_MSG_CHECKING(for HPUX/OSF thread support)
 214       if test -f /usr/include/dce/cma_config.h ; then
 215          if test "$GCC" = "yes" ; then
 216             AC_MSG_RESULT(yes)
 217             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 218             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 219             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 220          else
 221             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 222          fi
 223       else
 224          AC_MSG_RESULT(no)
 225       fi
 226       ;;
 227    solaris*)
 228       AC_MSG_CHECKING(for Solaris thread debugging library)
 229       if test -f /usr/lib/libthread_db.so.1 ; then
 230          AC_MSG_RESULT(yes)
 231          AC_DEFINE(HAVE_THREAD_DB_LIB)
 232          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 233          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 234          AC_CHECK_LIB(dl, dlopen)
 235          if test "$GCC" = "yes" ; then
 236             # The GNU linker requires the -export-dynamic option to make
 237             # all symbols visible in the dynamic symbol table.
 238             hold_ldflags=$LDFLAGS
 239             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 240             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 241             AC_TRY_LINK(, [int i;], found=yes, found=no)
 242             LDFLAGS=$hold_ldflags
 243             AC_MSG_RESULT($found)
 244             if test $found = yes; then
 245                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 246             fi
 247          fi
 248       else
 249          AC_MSG_RESULT(no)
 250       fi
 251       ;;
 252    esac
 253    AC_SUBST(CONFIG_LDFLAGS)
 254 fi
 255
 256 dnl Handle optional features that can be enabled.
 257 ENABLE_CFLAGS=
 258
 259 AC_ARG_ENABLE(netrom,
 260 [  --enable-netrom ],
 261 [case "${enableval}" in
 262 yes)    enable_netrom=yes ;;
 263 no)     enable_netrom=no ;;
 264 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 265 esac])
 266
 267 if test "${enable_netrom}" = "yes"; then
 268         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 269         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 270 fi
 271
 272 MMALLOC_CFLAGS=
 273 MMALLOC=
 274 AC_SUBST(MMALLOC_CFLAGS)
 275 AC_SUBST(MMALLOC)
 276
 277 AC_ARG_WITH(mmalloc,
 278 [  --with-mmalloc             use memory mapped malloc package],
 279 [case "${withval}" in
 280   yes)  want_mmalloc=true ;;
 281   no)   want_mmalloc=false;;
 282   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 283 esac],[want_mmalloc=false])dnl
 284
 285 if test x$want_mmalloc = xtrue; then
 286    AC_DEFINE(USE_MMALLOC)
 287    AC_DEFINE(MMCHECK_FORCE)
 288    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 289    MMALLOC='../mmalloc/libmmalloc.a'
 290 fi
 291
 292 # start-sanitize-gdbtk
 293 ENABLE_IDE=
 294 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 295 if test "$enable_ide" = yes; then
 296    enable_ide=yes
 297    ENABLE_IDE=1
 298 else
 299    enable_ide=no
 300 fi
 301 AC_SUBST(ENABLE_IDE)
 302
 303 ENABLE_GDBTK=
 304
 305 AC_ARG_ENABLE(gdbtk,
 306 [  --enable-gdbtk ],
 307 [case "${enableval}" in
 308     yes)
 309         case "$host" in
 310         *go32*)
 311             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 312             enable_gdbtk=no ;;
 313         *windows*)
 314             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 315             enable_gdbtk=no ;;
 316         *)
 317             enable_gdbtk=yes ;;
 318         esac ;;
 319     no)
 320         enable_gdbtk=no  ;;
 321     *)
 322         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 323 esac],
 324 [
 325 # Default is on for everything but go32 and cygwin32
 326 case "$host" in
 327     *go32* | *windows*)
 328         ;;
 329     *)
 330         enable_gdbtk=yes ;;
 331     esac
 332 ])
 333
 334 # In the cygwin32 environment, we need some additional flags.
 335 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 336 [AC_EGREP_CPP(lose, [
 337 #ifdef __CYGWIN32__
 338 lose
 339 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 340
 341 WIN32LIBS=
 342 WIN32LDAPP=
 343 AC_SUBST(WIN32LIBS)
 344 AC_SUBST(WIN32LDAPP)
 345
 346 WINDRES=${WINDRES-windres}
 347 AC_SUBST(WINDRES)
 348
 349 if test x$gdb_cv_os_cygwin32 = xyes; then
 350     if test x$enable_ide = xyes; then
 351         WIN32LIBS="-ladvapi32"
 352     fi
 353 fi
 354
 355 configdir="unix"
 356
 357 if test "${enable_gdbtk}" = "yes"; then
 358
 359     CY_AC_PATH_TCLCONFIG
 360     if test -z "${no_tcl}"; then
 361         CY_AC_LOAD_TCLCONFIG
 362         CY_AC_PATH_TKCONFIG
 363
 364         # If $no_tk is nonempty, then we can't do Tk, and there is no
 365         # point to doing Tcl.
 366         if test -z "${no_tk}"; then
 367            CY_AC_LOAD_TKCONFIG
 368            CY_AC_PATH_TCLH
 369            CY_AC_PATH_TKH
 370            CY_AC_PATH_ITCLH
 371            CY_AC_PATH_TIX
 372
 373            # now look for tix library stuff
 374            TIXVERSION=4.1.8.0
 375            . ${ac_cv_c_tclconfig}/tclConfig.sh
 376            case "${host}" in
 377            *-*-cygwin32*)
 378                 tixdir=../tix/win/tcl8.0
 379                 ;;
 380            *)
 381                 tixdir=../tix/unix/tk8.0
 382                 ;;
 383            esac
 384            if test "${TCL_SHARED_BUILD}" = "1"; then
 385                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 386
 387                 # Can't win them all: SunOS 4 (others?) appends a version
 388                 # number after the ".so"
 389                 case "${host}" in
 390                 *-*-sunos4*)
 391                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 392                 esac
 393
 394            else
 395                 TIX_LIB_EXT=".a"
 396            fi
 397
 398            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 399                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 400                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 401            else
 402                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 403                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 404            fi
 405
 406            ENABLE_GDBTK=1
 407
 408            # Include some libraries that Tcl and Tk want.
 409            if test "${enable_ide}" = "yes"; then
 410               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 411               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 412            else
 413               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 414               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 415            fi
 416            # Yes, the ordering seems wrong here.  But it isn't.
 417            # TK_LIBS is the list of libraries that need to be linked
 418            # after Tcl/Tk.
 419            LIBS="${LIBS} ${TCL_LIBS} ${TK_LIBS}"
 420            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 421
 422            if test x$gdb_cv_os_cygwin32 = xyes; then
 423               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 424               WIN32LDAPP="-Wl,--subsystem,windows"
 425               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 426            fi
 427         fi
 428     fi
 429 fi
 430
 431 AC_SUBST(ENABLE_GDBTK)
 432 AC_SUBST(X_CFLAGS)
 433 AC_SUBST(X_LDFLAGS)
 434 AC_SUBST(X_LIBS)
 435 AC_SUBST(TIXLIB)
 436 AC_SUBST(TIX_DEPS)
 437 # end-sanitize-gdbtk
 438
 439 AC_PATH_X
 440 # start-sanitize-sky
 441 # Enable GPU2 library for MIPS simulator
 442 AC_ARG_WITH(sim-gpu2,
 443 [  --with-sim-gpu2=path                 Use GPU2 library under given directory],
 444 [case "${target}" in
 445   mips*-sky-*)
 446     if test -d "${withval}"
 447     then
 448       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11"
 449     else
 450       AC_MSG_WARN([Directory ${withval} does not exist.])
 451     fi ;;
 452   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 453 esac])dnl
 454
 455 # Enable target accurate FP library
 456 AC_ARG_WITH(sim-funit,
 457 [  --with-sim-funit=path                Use target FP lib under given directory],
 458 [case "${target}" in
 459   mips*-sky-*)
 460     if test -d "${withval}"
 461     then
 462       LIBS="${LIBS} -L${withval}/lib -lfunit"
 463     else
 464       AC_MSG_WARN([Directory ${withval} does not exist.])
 465     fi ;;
 466   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 467 esac])dnl
 468 # end-sanitize-sky
 469
 470 AC_SUBST(ENABLE_CFLAGS)
 471
 472 AC_SUBST(CONFIG_OBS)
 473 AC_SUBST(CONFIG_DEPS)
 474 AC_SUBST(CONFIG_SRCS)
 475
 476 # Begin stuff to support --enable-shared
 477 AC_ARG_ENABLE(shared,
 478 [  --enable-shared         use shared libraries],
 479 [case "${enableval}" in
 480   yes) shared=true ;;
 481   no)  shared=false ;;
 482   *) shared=true ;;
 483 esac])dnl
 484
 485 HLDFLAGS=
 486 HLDENV=
 487 # If we have shared libraries, try to set rpath reasonably.
 488 if test "${shared}" = "true"; then
 489   case "${host}" in
 490   *-*-hpux*)
 491     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 492     ;;
 493   *-*-irix5* | *-*-irix6*)
 494     HLDFLAGS='-Wl,-rpath,$(libdir)'
 495     ;;
 496   *-*-linux*aout*)
 497     ;;
 498   *-*-linux* | *-pc-linux-gnu)
 499     HLDFLAGS='-Wl,-rpath,$(libdir)'
 500     ;;
 501   *-*-solaris*)
 502     HLDFLAGS='-R $(libdir)'
 503     ;;
 504   *-*-sysv4*)
 505     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 506     ;;
 507   esac
 508 fi
 509
 510 # On SunOS, if the linker supports the -rpath option, use it to
 511 # prevent ../bfd and ../opcodes from being included in the run time
 512 # search path.
 513 case "${host}" in
 514   *-*-sunos*)
 515     echo 'main () { }' > conftest.c
 516     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 517     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 518       :
 519     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 520       :
 521     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 522       :
 523     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 524       :
 525     elif test "${shared}" = "true"; then
 526       HLDFLAGS='-Wl,-rpath=$(libdir)'
 527     else
 528       HLDFLAGS='-Wl,-rpath='
 529     fi
 530     rm -f conftest.t conftest.c conftest
 531     ;;
 532 esac
 533 AC_SUBST(HLDFLAGS)
 534 AC_SUBST(HLDENV)
 535 # End stuff to support --enable-shared
 536
 537 # target_subdir is used by the testsuite to find the target libraries.
 538 target_subdir=
 539 if test "${host}" != "${target}"; then
 540     target_subdir="${target_alias}/"
 541 fi
 542 AC_SUBST(target_subdir)
 543
 544 frags=
 545 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 546 if test ! -f ${host_makefile_frag}; then
 547 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 548 fi
 549 frags="$frags $host_makefile_frag"
 550
 551 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 552 if test ! -f ${target_makefile_frag}; then
 553 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 554 fi
 555 frags="$frags $target_makefile_frag"
 556
 557 AC_SUBST_FILE(host_makefile_frag)
 558 AC_SUBST_FILE(target_makefile_frag)
 559 AC_SUBST(frags)
 560
 561 changequote(,)dnl
 562 hostfile=`sed -n '
 563 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 564 ' ${host_makefile_frag}`
 565
 566 targetfile=`sed -n '
 567 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 568 ' ${target_makefile_frag}`
 569
 570 # these really aren't orthogonal true/false values of the same condition,
 571 # but shells are slow enough that I like to reuse the test conditions
 572 # whenever possible
 573 if test "${target}" = "${host}"; then
 574 nativefile=`sed -n '
 575 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 576 ' ${host_makefile_frag}`
 577 # else
 578 # GDBserver is only useful in a "native" enviroment
 579 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 580 fi
 581 changequote([,])
 582
 583 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 584 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 585 # corresponding links.  But we have to remove the xm.h files and tm.h
 586 # files anyway, e.g. when switching from "configure host" to
 587 # "configure none".
 588
 589 files=
 590 links=
 591 rm -f xm.h
 592 if test "${hostfile}" != ""; then
 593 files="${files} config/${gdb_host_cpu}/${hostfile}"
 594 links="${links} xm.h"
 595 fi
 596 rm -f tm.h
 597 if test "${targetfile}" != ""; then
 598 files="${files} config/${gdb_target_cpu}/${targetfile}"
 599 links="${links} tm.h"
 600 fi
 601 rm -f nm.h
 602 if test "${nativefile}" != ""; then
 603 files="${files} config/${gdb_host_cpu}/${nativefile}"
 604 links="${links} nm.h"
 605 else
 606 # A cross-only configuration.
 607 files="${files} config/nm-empty.h"
 608 links="${links} nm.h"
 609 fi
 610 # start-sanitize-gdbtk
 611 AC_PROG_LN_S
 612 # Make it possible to use the GUI without doing a full install
 613 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 614   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 615   echo linking $srcdir/gdbtcl to gdbtcl
 616   $LN_S $srcdir/gdbtcl gdbtcl
 617   else
 618   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 619   echo "         " make install before you are able to run the GUI.
 620   fi
 621 fi
 622 # end-sanitize-gdbtk
 623
 624 AC_LINK_FILES($files, $links)
 625
 626 dnl Check for exe extension set on certain hosts (e.g. Win32)
 627 AM_EXEEXT
 628
 629 AC_CONFIG_SUBDIRS($configdirs)
 630 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 631 [
 632 dnl Autoconf doesn't provide a mechanism for modifying definitions
 633 dnl provided by makefile fragments.
 634 dnl
 635 if test "${nativefile}" = ""; then
 636 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 637         < Makefile > Makefile.tem
 638 mv -f Makefile.tem Makefile
 639 fi
 640
 641 changequote(,)dnl
 642 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 643 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 644 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 645 mv -f Makefile.tmp Makefile
 646 changequote([,])dnl
 647
 648 case x$CONFIG_HEADERS in
 649 xconfig.h:config.in)
 650 echo > stamp-h ;;
 651 esac
 652 ],
 653 [
 654 gdb_host_cpu=$gdb_host_cpu
 655 gdb_target_cpu=$gdb_target_cpu
 656 nativefile=$nativefile
 657 ])
 658
 659 exit 0
 660