gdb/gdbserver/acinclude.m4

   1 dnl gdb/gdbserver/configure.in uses BFD_HAVE_SYS_PROCFS_TYPE.
   2 sinclude(../../bfd/bfd.m4)
   3
   4 dnl This gets autoconf bugfixes
   5 sinclude(../../config/override.m4)
   6
   7 AC_DEFUN([SRV_CHECK_THREAD_DB],
   8 [AC_CACHE_CHECK([for libthread_db],[srv_cv_thread_db],
   9  [old_LIBS="$LIBS"
  10   LIBS="$LIBS -lthread_db"
  11   AC_TRY_LINK(
  12   [void ps_pglobal_lookup() {}
  13    void ps_pdread() {}
  14    void ps_pdwrite() {}
  15    void ps_lgetregs() {}
  16    void ps_lsetregs() {}
  17    void ps_lgetfpregs() {}
  18    void ps_lsetfpregs() {}
  19    void ps_get_thread_area() {}
  20    void ps_getpid() {}],
  21   [td_ta_new();],
  22   [srv_cv_thread_db="-lthread_db"],
  23   [srv_cv_thread_db=no
  24
  25  if test "$prefix" = "/usr" || test "$prefix" = "NONE"; then
  26   thread_db="/lib/libthread_db.so.1"
  27  else
  28   thread_db='$prefix/lib/libthread_db.so.1'
  29  fi
  30  LIBS="$old_LIBS `eval echo "$thread_db"`"
  31  AC_TRY_LINK(
  32   [void ps_pglobal_lookup() {}
  33    void ps_pdread() {}
  34    void ps_pdwrite() {}
  35    void ps_lgetregs() {}
  36    void ps_lsetregs() {}
  37    void ps_lgetfpregs() {}
  38    void ps_lsetfpregs() {}
  39    void ps_get_thread_area() {}
  40    void ps_getpid() {}],
  41   [td_ta_new();],
  42   [srv_cv_thread_db="$thread_db"],
  43   [srv_cv_thread_db=no])
  44   ])
  45  LIBS="$old_LIBS"
  46 ])])
  47
  48 AC_DEFUN([SRV_CHECK_TLS_GET_ADDR],
  49 [AC_CACHE_CHECK([for thread_db_tls_get_addr],[srv_cv_tls_get_addr],
  50  [old_LIBS="$LIBS"
  51   LIBS="$LIBS $srv_cv_thread_db"
  52   AC_TRY_LINK(
  53    [void ps_pglobal_lookup() {}
  54     void ps_pdread() {}
  55     void ps_pdwrite() {}
  56     void ps_lgetregs() {}
  57     void ps_lsetregs() {}
  58     void ps_lgetfpregs() {}
  59     void ps_lsetfpregs() {}
  60     void ps_get_thread_area() {}
  61     void ps_getpid() {}],
  62    [td_thr_tls_get_addr();],
  63    [srv_cv_tls_get_addr=yes],
  64    [srv_cv_tls_get_addr=no])
  65   LIBS="$old_LIBS"
  66 ])])