gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2016 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 AC_HEADER_STDC
  46
  47 # Set the 'development' global.
  48 . $srcdir/../../bfd/development.sh
  49
  50 # Enable -lmcheck by default (it provides cheap-enough memory
  51 # mangling), but turn it off for releases.
  52 if $development; then
  53   libmcheck_default=yes
  54 else
  55   libmcheck_default=no
  56 fi
  57 GDB_AC_LIBMCHECK(${libmcheck_default})
  58
  59 ACX_NONCANONICAL_TARGET
  60 ACX_NONCANONICAL_HOST
  61
  62 # Dependency checking.
  63 ZW_CREATE_DEPDIR
  64 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  65
  66 # Check for the 'make' the user wants to use.
  67 AC_CHECK_PROGS(MAKE, make)
  68 MAKE_IS_GNU=
  69 case "`$MAKE --version 2>&1 | sed 1q`" in
  70   *GNU*)
  71     MAKE_IS_GNU=yes
  72     ;;
  73 esac
  74 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  75 AC_PROG_MAKE_SET
  76
  77 gnulib_extra_configure_args=
  78 # If large-file support is disabled, make sure gnulib does the same.
  79 if test "$enable_largefile" = no; then
  80 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  81 fi
  82
  83 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  84 # to find the the source subdir to be configured directly under
  85 # gdbserver/.  We need to build gnulib under some other directory not
  86 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  87 # build it in the same directory, when building in the source dir.
  88 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  89                   ["$gnulib_extra_configure_args"])
  90
  91 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  92
  93 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  94                  proc_service.h sys/procfs.h linux/elf.h dnl
  95                  fcntl.h signal.h sys/file.h dnl
  96                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  97                  netinet/tcp.h arpa/inet.h)
  98 AC_FUNC_FORK
  99 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
 100
 101 GDB_AC_COMMON
 102
 103 # Check the return and argument types of ptrace.
 104 GDB_AC_PTRACE
 105
 106 # Check for UST
 107 ustlibs=""
 108 ustinc=""
 109
 110 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 111                           Equivalent to --with-ust-include=PATH/include
 112                           plus --with-ust-lib=PATH/lib])
 113 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 114 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 115
 116 case $with_ust in
 117   no)
 118     ustlibs=
 119     ustinc=
 120     ;;
 121   "" | yes)
 122     ustlibs=" -lust "
 123     ustinc=""
 124     ;;
 125   *)
 126     ustlibs="-L$with_ust/lib -lust"
 127     ustinc="-I$with_ust/include "
 128     ;;
 129 esac
 130 if test "x$with_ust_include" != x; then
 131   ustinc="-I$with_ust_include "
 132 fi
 133 if test "x$with_ust_lib" != x; then
 134   ustlibs="-L$with_ust_lib -lust"
 135 fi
 136
 137 if test "x$with_ust" != "xno"; then
 138   saved_CFLAGS="$CFLAGS"
 139   CFLAGS="$CFLAGS $ustinc"
 140   AC_MSG_CHECKING([for ust])
 141   AC_TRY_COMPILE([
 142 #define CONFIG_UST_GDB_INTEGRATION
 143 #include <ust/ust.h>
 144   ],[],
 145   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 146   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 147   CFLAGS="$saved_CFLAGS"
 148 fi
 149
 150 # Flags needed for UST
 151 AC_SUBST(ustlibs)
 152 AC_SUBST(ustinc)
 153
 154 AM_GDB_WARNINGS
 155 dnl The codebase isn't clean yet with this flag.
 156 case " $WARN_CFLAGS " in
 157 *" -Wmissing-prototypes "*)
 158   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 159   ;;
 160 esac
 161
 162 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 163 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 164 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 165 dnl augment LIBS.
 166 old_LIBS="$LIBS"
 167 LIBS="$LIBS -ldl"
 168 AC_CHECK_FUNCS(dladdr)
 169 LIBS="$old_LIBS"
 170
 171 libiberty_INIT
 172
 173 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 174
 175 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 176
 177 AC_CHECK_TYPES(socklen_t, [], [],
 178 [#include <sys/types.h>
 179 #include <sys/socket.h>
 180 ])
 181
 182 case "${target}" in
 183   *-android*)
 184     # Starting with NDK version 9, <elf.h> actually includes definitions
 185     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 186     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 187     # leading to conflicts with the defintions from <linux/elf.h>.
 188     # This makes it impossible for us to include both <elf.h> and
 189     # <linux/elf.h>, which means that, in practice, we do not have
 190     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 191     # Therefore, do not try to auto-detect availability, as it would
 192     # get it wrong on this platform.
 193     ;;
 194   *)
 195     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 196     #include <elf.h>
 197     )
 198 esac
 199
 200 ACX_PKGVERSION([GDB])
 201 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 202 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 203 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 204
 205 # Check for various supplementary target information (beyond the
 206 # triplet) which might affect the choices in configure.srv.
 207 case "${target}" in
 208 changequote(,)dnl
 209   i[34567]86-*-linux*)
 210 changequote([,])dnl
 211     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 212                    [save_CPPFLAGS="$CPPFLAGS"
 213                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 214                     AC_EGREP_CPP([got it], [
 215 #if __x86_64__
 216 got it
 217 #endif
 218                  ], [gdb_cv_i386_is_x86_64=yes],
 219                     [gdb_cv_i386_is_x86_64=no])
 220                     CPPFLAGS="$save_CPPFLAGS"])
 221     ;;
 222
 223   x86_64-*-linux*)
 224     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 225                    [save_CPPFLAGS="$CPPFLAGS"
 226                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 227                     AC_EGREP_CPP([got it], [
 228 #if __x86_64__ && __ILP32__
 229 got it
 230 #endif
 231                  ], [gdb_cv_x86_is_x32=yes],
 232                     [gdb_cv_x86_is_x32=no])
 233                     CPPFLAGS="$save_CPPFLAGS"])
 234     ;;
 235
 236   m68k-*-*)
 237     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 238                    [save_CPPFLAGS="$CPPFLAGS"
 239                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 240                     AC_EGREP_CPP([got it], [
 241 #ifdef __mcoldfire__
 242 got it
 243 #endif
 244                  ], [gdb_cv_m68k_is_coldfire=yes],
 245                     [gdb_cv_m68k_is_coldfire=no])
 246                     CPPFLAGS="$save_CPPFLAGS"])
 247     ;;
 248 esac
 249
 250 . ${srcdir}/configure.srv
 251
 252 # Add in the common host objects.
 253 . ${srcdir}/../common/common.host
 254 srv_host_obs="$common_host_obs"
 255
 256 if test "${srv_mingwce}" = "yes"; then
 257   LIBS="$LIBS -lws2"
 258 elif test "${srv_mingw}" = "yes"; then
 259   LIBS="$LIBS -lws2_32"
 260 elif test "${srv_qnx}" = "yes"; then
 261   LIBS="$LIBS -lsocket"
 262 elif test "${srv_lynxos}" = "yes"; then
 263   LIBS="$LIBS -lnetinet"
 264 fi
 265
 266 if test "${srv_mingw}" = "yes"; then
 267   AC_DEFINE(USE_WIN32API, 1,
 268             [Define if we should use the Windows API, instead of the
 269              POSIX API.  On Windows, we use the Windows API when
 270              building for MinGW, but the POSIX API when building
 271              for Cygwin.])
 272 fi
 273
 274 if test "${srv_linux_usrregs}" = "yes"; then
 275   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 276             [Define if the target supports PTRACE_PEEKUSR for register ]
 277             [access.])
 278 fi
 279
 280 if test "${srv_linux_regsets}" = "yes"; then
 281   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 282             [Define if the target supports register sets.])
 283
 284   AC_MSG_CHECKING(for PTRACE_GETREGS)
 285   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 286   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 287                   [PTRACE_GETREGS;],
 288                   [gdbsrv_cv_have_ptrace_getregs=yes],
 289                   [gdbsrv_cv_have_ptrace_getregs=no])])
 290   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 291   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 292     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 293               [Define if the target supports PTRACE_GETREGS for register ]
 294               [access.])
 295   fi
 296
 297   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 298   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 299   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 300                   [PTRACE_GETFPXREGS;],
 301                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 302                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 303   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 304   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 305     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 306               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 307               [register access.])
 308   fi
 309 fi
 310
 311 if test "${srv_linux_btrace}" = "yes"; then
 312   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 313             [Define if the target supports branch tracing.])
 314 fi
 315
 316 if test "$ac_cv_header_sys_procfs_h" = yes; then
 317   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 318   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 319   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 320   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 321   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 322 fi
 323
 324 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 325 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 326   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 327 fi
 328
 329 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 330 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 331   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 332 fi
 333
 334 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 335 dnl needs it (and gdbreplay doesn't).
 336 old_LIBS="$LIBS"
 337 AC_CHECK_LIB(dl, dlopen)
 338 LIBS="$old_LIBS"
 339
 340 srv_thread_depfiles=
 341 srv_libs=
 342
 343 if test "$srv_linux_thread_db" = "yes"; then
 344   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 345     srv_libs="-ldl"
 346     AC_MSG_CHECKING(for the dynamic export flag)
 347     old_LDFLAGS="$LDFLAGS"
 348     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 349     # supported there.
 350     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 351     LDFLAGS="$LDFLAGS $RDYNAMIC"
 352     AC_TRY_LINK([], [],
 353                 [found="-Wl,--dynamic-list"
 354                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 355                 [RDYNAMIC="-rdynamic"
 356                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 357                  AC_TRY_LINK([], [],
 358                              [found="-rdynamic"],
 359                              [found="no"
 360                               RDYNAMIC=""])])
 361     AC_SUBST(RDYNAMIC)
 362     LDFLAGS="$old_LDFLAGS"
 363     AC_MSG_RESULT($found)
 364   else
 365     srv_libs="-lthread_db"
 366   fi
 367
 368   srv_thread_depfiles="thread-db.o proc-service.o"
 369   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 370   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 371   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 372                   [gdbsrv_cv_have_td_version=yes],
 373                   [gdbsrv_cv_have_td_version=no])])
 374   if test $gdbsrv_cv_have_td_version = yes; then
 375     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 376   fi
 377 fi
 378
 379 AC_ARG_WITH(libthread-db,
 380 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 381 [srv_libthread_db_path="${withval}"
 382   srv_libs="$srv_libthread_db_path"
 383 ])
 384
 385 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 386   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 387 fi
 388
 389 if test "$srv_xmlfiles" != ""; then
 390   srv_xmlbuiltin="xml-builtin.o"
 391   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 392
 393   tmp_xmlfiles=$srv_xmlfiles
 394   srv_xmlfiles=""
 395   for f in $tmp_xmlfiles; do
 396     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 397   done
 398 fi
 399
 400 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 401 GDBSERVER_LIBS="$srv_libs"
 402
 403 dnl Check whether the target supports __sync_*_compare_and_swap.
 404 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 405                 gdbsrv_cv_have_sync_builtins, [
 406 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 407                 gdbsrv_cv_have_sync_builtins=yes,
 408                 gdbsrv_cv_have_sync_builtins=no)])
 409 if test $gdbsrv_cv_have_sync_builtins = yes; then
 410   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 411     [Define to 1 if the target supports __sync_*_compare_and_swap])
 412 fi
 413
 414 dnl Check for -fvisibility=hidden support in the compiler.
 415 saved_cflags="$CFLAGS"
 416 CFLAGS="$CFLAGS -fvisibility=hidden"
 417 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 418                         [gdbsrv_cv_have_visibility_hidden=yes],
 419                         [gdbsrv_cv_have_visibility_hidden=no])
 420 CFLAGS="$saved_cflags"
 421
 422 dnl Check if we can disable the virtual address space randomization.
 423 dnl The functionality of setarch -R.
 424 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 425 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 426 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 427 #       define ADDR_NO_RANDOMIZE 0x0040000
 428 #      endif
 429        /* Test the flag could be set and stays set.  */
 430        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 431        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 432            return 1])])
 433 AC_RUN_IFELSE([PERSONALITY_TEST],
 434               [gdbsrv_cv_have_personality=true],
 435               [gdbsrv_cv_have_personality=false],
 436               [AC_LINK_IFELSE([PERSONALITY_TEST],
 437                               [gdbsrv_cv_have_personality=true],
 438                               [gdbsrv_cv_have_personality=false])])
 439 if $gdbsrv_cv_have_personality
 440 then
 441     AC_DEFINE([HAVE_PERSONALITY], 1,
 442               [Define if you support the personality syscall.])
 443 fi
 444
 445
 446 IPA_DEPFILES=""
 447 extra_libraries=""
 448
 449 # check whether to enable the inprocess agent
 450 if test "$ipa_obj" != "" \
 451    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 452    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 453    have_ipa=true
 454 else
 455    have_ipa=false
 456 fi
 457
 458 AC_ARG_ENABLE(inprocess-agent,
 459 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 460 [case "$enableval" in
 461   yes) want_ipa=true ;;
 462   no) want_ipa=false ;;
 463   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 464 esac],
 465 [want_ipa=$have_ipa])
 466
 467 if $want_ipa ; then
 468    if $have_ipa ; then
 469      IPA_DEPFILES="$ipa_obj"
 470      extra_libraries="$extra_libraries libinproctrace.so"
 471    else
 472      AC_MSG_ERROR([inprocess agent not supported for this target])
 473    fi
 474 fi
 475
 476 AC_SUBST(GDBSERVER_DEPFILES)
 477 AC_SUBST(GDBSERVER_LIBS)
 478 AC_SUBST(srv_xmlbuiltin)
 479 AC_SUBST(srv_xmlfiles)
 480 AC_SUBST(IPA_DEPFILES)
 481 AC_SUBST(extra_libraries)
 482
 483 GNULIB=build-gnulib-gdbserver/import
 484
 485 GNULIB_STDINT_H=
 486 if test x"$STDINT_H" != x; then
 487   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 488 fi
 489 AC_SUBST(GNULIB_STDINT_H)
 490
 491 AC_CONFIG_FILES([Makefile],
 492 [case x$CONFIG_HEADERS in
 493 xconfig.h:config.in)
 494 echo > stamp-h ;;
 495 esac
 496 ])
 497
 498 AC_OUTPUT