gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2017 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 AC_HEADER_STDC
  46
  47 # Set the 'development' global.
  48 . $srcdir/../../bfd/development.sh
  49
  50 # Enable -lmcheck by default (it provides cheap-enough memory
  51 # mangling), but turn it off for releases.
  52 if $development; then
  53   libmcheck_default=yes
  54 else
  55   libmcheck_default=no
  56 fi
  57 GDB_AC_LIBMCHECK(${libmcheck_default})
  58
  59 if $development; then
  60   AC_DEFINE(GDB_SELF_TEST, 1,
  61             [Define if self-testing features should be enabled])
  62 fi
  63
  64 ACX_NONCANONICAL_TARGET
  65 ACX_NONCANONICAL_HOST
  66
  67 # Dependency checking.
  68 ZW_CREATE_DEPDIR
  69 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  70
  71 gnulib_extra_configure_args=
  72 # If large-file support is disabled, make sure gnulib does the same.
  73 if test "$enable_largefile" = no; then
  74 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  75 fi
  76
  77 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  78 # to find the the source subdir to be configured directly under
  79 # gdbserver/.  We need to build gnulib under some other directory not
  80 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  81 # build it in the same directory, when building in the source dir.
  82 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  83                   ["$gnulib_extra_configure_args"])
  84
  85 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  86
  87 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  88                  proc_service.h sys/procfs.h linux/elf.h dnl
  89                  fcntl.h signal.h sys/file.h dnl
  90                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  91                  netinet/tcp.h arpa/inet.h)
  92 AC_FUNC_FORK
  93 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
  94
  95 GDB_AC_COMMON
  96
  97 # Check the return and argument types of ptrace.
  98 GDB_AC_PTRACE
  99
 100 # Check for UST
 101 ustlibs=""
 102 ustinc=""
 103
 104 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 105                           Equivalent to --with-ust-include=PATH/include
 106                           plus --with-ust-lib=PATH/lib])
 107 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 108 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 109
 110 case $with_ust in
 111   no)
 112     ustlibs=
 113     ustinc=
 114     ;;
 115   "" | yes)
 116     ustlibs=" -lust "
 117     ustinc=""
 118     ;;
 119   *)
 120     ustlibs="-L$with_ust/lib -lust"
 121     ustinc="-I$with_ust/include "
 122     ;;
 123 esac
 124 if test "x$with_ust_include" != x; then
 125   ustinc="-I$with_ust_include "
 126 fi
 127 if test "x$with_ust_lib" != x; then
 128   ustlibs="-L$with_ust_lib -lust"
 129 fi
 130
 131 if test "x$with_ust" != "xno"; then
 132   saved_CFLAGS="$CFLAGS"
 133   CFLAGS="$CFLAGS $ustinc"
 134   AC_MSG_CHECKING([for ust])
 135   AC_TRY_COMPILE([
 136 #define CONFIG_UST_GDB_INTEGRATION
 137 #include <ust/ust.h>
 138   ],[],
 139   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 140   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 141   CFLAGS="$saved_CFLAGS"
 142 fi
 143
 144 # Flags needed for UST
 145 AC_SUBST(ustlibs)
 146 AC_SUBST(ustinc)
 147
 148 AM_GDB_WARNINGS
 149 dnl The codebase isn't clean yet with this flag.
 150 case " $WARN_CFLAGS " in
 151 *" -Wmissing-prototypes "*)
 152   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 153   ;;
 154 esac
 155
 156 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 157 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 158 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 159 dnl augment LIBS.
 160 old_LIBS="$LIBS"
 161 LIBS="$LIBS -ldl"
 162 AC_CHECK_FUNCS(dladdr)
 163 LIBS="$old_LIBS"
 164
 165 libiberty_INIT
 166
 167 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 168
 169 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 170
 171 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 172 # Older amd64 Linux's don't have the fs_base and gs_base members of
 173 # `struct user_regs_struct'.
 174 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 175                  [], [], [#include <sys/user.h>])
 176
 177
 178 AC_CHECK_TYPES(socklen_t, [], [],
 179 [#include <sys/types.h>
 180 #include <sys/socket.h>
 181 ])
 182
 183 case "${target}" in
 184   *-android*)
 185     # Starting with NDK version 9, <elf.h> actually includes definitions
 186     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 187     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 188     # leading to conflicts with the defintions from <linux/elf.h>.
 189     # This makes it impossible for us to include both <elf.h> and
 190     # <linux/elf.h>, which means that, in practice, we do not have
 191     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 192     # Therefore, do not try to auto-detect availability, as it would
 193     # get it wrong on this platform.
 194     ;;
 195   *)
 196     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 197     #include <elf.h>
 198     )
 199 esac
 200
 201 ACX_PKGVERSION([GDB])
 202 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 203 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 204 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 205
 206 # Check for various supplementary target information (beyond the
 207 # triplet) which might affect the choices in configure.srv.
 208 case "${target}" in
 209 changequote(,)dnl
 210   i[34567]86-*-linux*)
 211 changequote([,])dnl
 212     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 213                    [save_CPPFLAGS="$CPPFLAGS"
 214                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 215                     AC_EGREP_CPP([got it], [
 216 #if __x86_64__
 217 got it
 218 #endif
 219                  ], [gdb_cv_i386_is_x86_64=yes],
 220                     [gdb_cv_i386_is_x86_64=no])
 221                     CPPFLAGS="$save_CPPFLAGS"])
 222     ;;
 223
 224   x86_64-*-linux*)
 225     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 226                    [save_CPPFLAGS="$CPPFLAGS"
 227                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 228                     AC_EGREP_CPP([got it], [
 229 #if __x86_64__ && __ILP32__
 230 got it
 231 #endif
 232                  ], [gdb_cv_x86_is_x32=yes],
 233                     [gdb_cv_x86_is_x32=no])
 234                     CPPFLAGS="$save_CPPFLAGS"])
 235     ;;
 236
 237   m68k-*-*)
 238     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 239                    [save_CPPFLAGS="$CPPFLAGS"
 240                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 241                     AC_EGREP_CPP([got it], [
 242 #ifdef __mcoldfire__
 243 got it
 244 #endif
 245                  ], [gdb_cv_m68k_is_coldfire=yes],
 246                     [gdb_cv_m68k_is_coldfire=no])
 247                     CPPFLAGS="$save_CPPFLAGS"])
 248     ;;
 249 esac
 250
 251 . ${srcdir}/configure.srv
 252
 253 # Add in the common host objects.
 254 . ${srcdir}/../common/common.host
 255 srv_host_obs="$common_host_obs"
 256
 257 if test "${srv_mingwce}" = "yes"; then
 258   LIBS="$LIBS -lws2"
 259 elif test "${srv_mingw}" = "yes"; then
 260   LIBS="$LIBS -lws2_32"
 261 elif test "${srv_qnx}" = "yes"; then
 262   LIBS="$LIBS -lsocket"
 263 elif test "${srv_lynxos}" = "yes"; then
 264   LIBS="$LIBS -lnetinet"
 265 fi
 266
 267 if test "${srv_mingw}" = "yes"; then
 268   AC_DEFINE(USE_WIN32API, 1,
 269             [Define if we should use the Windows API, instead of the
 270              POSIX API.  On Windows, we use the Windows API when
 271              building for MinGW, but the POSIX API when building
 272              for Cygwin.])
 273 fi
 274
 275 if test "${srv_linux_usrregs}" = "yes"; then
 276   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 277             [Define if the target supports PTRACE_PEEKUSR for register ]
 278             [access.])
 279 fi
 280
 281 if test "${srv_linux_regsets}" = "yes"; then
 282   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 283             [Define if the target supports register sets.])
 284
 285   AC_MSG_CHECKING(for PTRACE_GETREGS)
 286   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 287   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 288                   [PTRACE_GETREGS;],
 289                   [gdbsrv_cv_have_ptrace_getregs=yes],
 290                   [gdbsrv_cv_have_ptrace_getregs=no])])
 291   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 292   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 293     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 294               [Define if the target supports PTRACE_GETREGS for register ]
 295               [access.])
 296   fi
 297
 298   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 299   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 300   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 301                   [PTRACE_GETFPXREGS;],
 302                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 303                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 304   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 305   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 306     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 307               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 308               [register access.])
 309   fi
 310 fi
 311
 312 if test "${srv_linux_btrace}" = "yes"; then
 313   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 314             [Define if the target supports branch tracing.])
 315 fi
 316
 317 if test "$ac_cv_header_sys_procfs_h" = yes; then
 318   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 319   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 320   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 321   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 322   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 323 fi
 324
 325 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 326 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 327   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 328 fi
 329
 330 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 331 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 332   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 333 fi
 334
 335 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 336 dnl needs it (and gdbreplay doesn't).
 337 old_LIBS="$LIBS"
 338 AC_CHECK_LIB(dl, dlopen)
 339 LIBS="$old_LIBS"
 340
 341 srv_thread_depfiles=
 342 srv_libs=
 343
 344 if test "$srv_linux_thread_db" = "yes"; then
 345   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 346     srv_libs="-ldl"
 347     AC_MSG_CHECKING(for the dynamic export flag)
 348     old_LDFLAGS="$LDFLAGS"
 349     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 350     # supported there.
 351     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 352     LDFLAGS="$LDFLAGS $RDYNAMIC"
 353     AC_TRY_LINK([], [],
 354                 [found="-Wl,--dynamic-list"
 355                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 356                 [RDYNAMIC="-rdynamic"
 357                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 358                  AC_TRY_LINK([], [],
 359                              [found="-rdynamic"],
 360                              [found="no"
 361                               RDYNAMIC=""])])
 362     AC_SUBST(RDYNAMIC)
 363     LDFLAGS="$old_LDFLAGS"
 364     AC_MSG_RESULT($found)
 365   else
 366     srv_libs="-lthread_db"
 367   fi
 368
 369   srv_thread_depfiles="thread-db.o proc-service.o"
 370   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 371   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 372   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 373                   [gdbsrv_cv_have_td_version=yes],
 374                   [gdbsrv_cv_have_td_version=no])])
 375   if test $gdbsrv_cv_have_td_version = yes; then
 376     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 377   fi
 378 fi
 379
 380 AC_ARG_WITH(libthread-db,
 381 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 382 [srv_libthread_db_path="${withval}"
 383   srv_libs="$srv_libthread_db_path"
 384 ])
 385
 386 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 387   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 388 fi
 389
 390 if test "$srv_xmlfiles" != ""; then
 391   srv_xmlbuiltin="xml-builtin.o"
 392   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 393
 394   tmp_xmlfiles=$srv_xmlfiles
 395   srv_xmlfiles=""
 396   for f in $tmp_xmlfiles; do
 397     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 398   done
 399 fi
 400
 401 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs"
 402 GDBSERVER_LIBS="$srv_libs"
 403
 404 dnl Check whether the target supports __sync_*_compare_and_swap.
 405 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 406                 gdbsrv_cv_have_sync_builtins, [
 407 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 408                 gdbsrv_cv_have_sync_builtins=yes,
 409                 gdbsrv_cv_have_sync_builtins=no)])
 410 if test $gdbsrv_cv_have_sync_builtins = yes; then
 411   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 412     [Define to 1 if the target supports __sync_*_compare_and_swap])
 413 fi
 414
 415 dnl Check for -fvisibility=hidden support in the compiler.
 416 saved_cflags="$CFLAGS"
 417 CFLAGS="$CFLAGS -fvisibility=hidden"
 418 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 419                         [gdbsrv_cv_have_visibility_hidden=yes],
 420                         [gdbsrv_cv_have_visibility_hidden=no])
 421 CFLAGS="$saved_cflags"
 422
 423 dnl Check if we can disable the virtual address space randomization.
 424 dnl The functionality of setarch -R.
 425 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 426 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 427 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 428 #       define ADDR_NO_RANDOMIZE 0x0040000
 429 #      endif
 430        /* Test the flag could be set and stays set.  */
 431        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 432        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 433            return 1])])
 434 AC_RUN_IFELSE([PERSONALITY_TEST],
 435               [gdbsrv_cv_have_personality=true],
 436               [gdbsrv_cv_have_personality=false],
 437               [AC_LINK_IFELSE([PERSONALITY_TEST],
 438                               [gdbsrv_cv_have_personality=true],
 439                               [gdbsrv_cv_have_personality=false])])
 440 if $gdbsrv_cv_have_personality
 441 then
 442     AC_DEFINE([HAVE_PERSONALITY], 1,
 443               [Define if you support the personality syscall.])
 444 fi
 445
 446
 447 IPA_DEPFILES=""
 448 extra_libraries=""
 449
 450 # check whether to enable the inprocess agent
 451 if test "$ipa_obj" != "" \
 452    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 453    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 454    have_ipa=true
 455 else
 456    have_ipa=false
 457 fi
 458
 459 AC_ARG_ENABLE(inprocess-agent,
 460 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 461 [case "$enableval" in
 462   yes) want_ipa=true ;;
 463   no) want_ipa=false ;;
 464   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 465 esac],
 466 [want_ipa=$have_ipa])
 467
 468 if $want_ipa ; then
 469    if $have_ipa ; then
 470      IPA_DEPFILES="$ipa_obj"
 471      extra_libraries="$extra_libraries libinproctrace.so"
 472    else
 473      AC_MSG_ERROR([inprocess agent not supported for this target])
 474    fi
 475 fi
 476
 477 AC_SUBST(GDBSERVER_DEPFILES)
 478 AC_SUBST(GDBSERVER_LIBS)
 479 AC_SUBST(srv_xmlbuiltin)
 480 AC_SUBST(srv_xmlfiles)
 481 AC_SUBST(IPA_DEPFILES)
 482 AC_SUBST(extra_libraries)
 483
 484 GNULIB=build-gnulib-gdbserver/import
 485
 486 GNULIB_STDINT_H=
 487 if test x"$STDINT_H" != x; then
 488   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 489 fi
 490 AC_SUBST(GNULIB_STDINT_H)
 491
 492 AC_CONFIG_FILES([Makefile],
 493 [case x$CONFIG_HEADERS in
 494 xconfig.h:config.in)
 495 echo > stamp-h ;;
 496 esac
 497 ])
 498
 499 AC_OUTPUT