gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000, 2002-2012 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_GNU_SOURCE
  30
  31 AC_CANONICAL_SYSTEM
  32
  33 AC_PROG_INSTALL
  34 AC_PROG_RANLIB
  35
  36 AC_ARG_PROGRAM
  37
  38 AC_HEADER_STDC
  39 AC_HEADER_DIRENT
  40
  41 AC_FUNC_ALLOCA
  42
  43 # Dependency checking.
  44 ZW_CREATE_DEPDIR
  45 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  46
  47 # Check for the 'make' the user wants to use.
  48 AC_CHECK_PROGS(MAKE, make)
  49 MAKE_IS_GNU=
  50 case "`$MAKE --version 2>&1 | sed 1q`" in
  51   *GNU*)
  52     MAKE_IS_GNU=yes
  53     ;;
  54 esac
  55 AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
  56 AC_PROG_MAKE_SET
  57
  58 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  59 # to find the the source subdir to be configured directly under
  60 # gdbserver/.  We need to build gnulib under some other directory not
  61 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  62 # build it in the same directory, when building in the source dir.
  63 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"])
  64
  65 AC_CHECK_HEADERS(sgtty.h termio.h termios.h sys/reg.h string.h dnl
  66                  proc_service.h sys/procfs.h thread_db.h linux/elf.h dnl
  67                  stdlib.h unistd.h dnl
  68                  errno.h fcntl.h signal.h sys/file.h malloc.h dnl
  69                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
  70                  netinet/tcp.h arpa/inet.h sys/wait.h wait.h sys/un.h dnl
  71                  linux/perf_event.h)
  72 AC_CHECK_FUNCS(pread pwrite pread64 readlink)
  73 AC_REPLACE_FUNCS(vasprintf vsnprintf)
  74
  75 # Check for UST
  76 ustlibs=""
  77 ustinc=""
  78
  79 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
  80                           Equivalent to --with-ust-include=PATH/include
  81                           plus --with-ust-lib=PATH/lib])
  82 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
  83 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
  84
  85 case $with_ust in
  86   no)
  87     ustlibs=
  88     ustinc=
  89     ;;
  90   "" | yes)
  91     ustlibs=" -lust "
  92     ustinc=""
  93     ;;
  94   *)
  95     ustlibs="-L$with_ust/lib -lust"
  96     ustinc="-I$with_ust/include "
  97     ;;
  98 esac
  99 if test "x$with_ust_include" != x; then
 100   ustinc="-I$with_ust_include "
 101 fi
 102 if test "x$with_ust_lib" != x; then
 103   ustlibs="-L$with_ust_lib -lust"
 104 fi
 105
 106 if test "x$with_ust" != "xno"; then
 107   saved_CFLAGS="$CFLAGS"
 108   CFLAGS="$CFLAGS $ustinc"
 109   AC_MSG_CHECKING([for ust])
 110   AC_TRY_COMPILE([
 111 #define CONFIG_UST_GDB_INTEGRATION
 112 #include <ust/ust.h>
 113   ],[],
 114   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 115   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 116   CFLAGS="$saved_CFLAGS"
 117 fi
 118
 119 # Flags needed for UST
 120 AC_SUBST(ustlibs)
 121 AC_SUBST(ustinc)
 122
 123 AC_ARG_ENABLE(werror,
 124   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
 125   [case "${enableval}" in
 126      yes | y) ERROR_ON_WARNING="yes" ;;
 127      no | n)  ERROR_ON_WARNING="no" ;;
 128      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
 129    esac])
 130
 131 # Enable -Werror by default when using gcc
 132 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" ; then
 133     ERROR_ON_WARNING=yes
 134 fi
 135
 136 WERROR_CFLAGS=""
 137 if test "${ERROR_ON_WARNING}" = yes ; then
 138     WERROR_CFLAGS="-Werror"
 139 fi
 140
 141 build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \
 142 -Wformat-nonliteral -Wno-char-subscripts -Wempty-body"
 143
 144 WARN_CFLAGS=""
 145 if test "x$GCC" = xyes
 146 then
 147     AC_MSG_CHECKING(compiler warning flags)
 148     # Separate out the -Werror flag as some files just cannot be
 149     # compiled with it enabled.
 150     for w in ${build_warnings}; do
 151         case $w in
 152         -Werr*) WERROR_CFLAGS=-Werror ;;
 153         *) # Check that GCC accepts it
 154             saved_CFLAGS="$CFLAGS"
 155             CFLAGS="$CFLAGS $w"
 156             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 157             CFLAGS="$saved_CFLAGS"
 158         esac
 159     done
 160     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 161 fi
 162 AC_SUBST(WARN_CFLAGS)
 163 AC_SUBST(WERROR_CFLAGS)
 164
 165 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 166 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 167 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 168 dnl augment LIBS.
 169 old_LIBS="$LIBS"
 170 LIBS="$LIBS -ldl"
 171 AC_CHECK_FUNCS(dladdr)
 172 LIBS="$old_LIBS"
 173
 174 have_errno=no
 175 AC_MSG_CHECKING(for errno)
 176 AC_TRY_LINK([
 177 #if HAVE_ERRNO_H
 178 #include <errno.h>
 179 #endif], [static int x; x = errno;],
 180   [AC_MSG_RESULT(yes - in errno.h); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) have_errno=yes])
 181 if test $have_errno = no; then
 182 AC_TRY_LINK([
 183 #if HAVE_ERRNO_H
 184 #include <errno.h>
 185 #endif], [extern int errno; static int x; x = errno;],
 186   [AC_MSG_RESULT(yes - must define); AC_DEFINE(HAVE_ERRNO, 1, [Define if errno is available]) AC_DEFINE(MUST_DEFINE_ERRNO, 1, [Checking if errno must be defined])],
 187   [AC_MSG_RESULT(no)])
 188 fi
 189
 190 AC_CHECK_DECLS([strerror, strstr, perror, vasprintf, vsnprintf])
 191
 192 AC_CHECK_TYPES(socklen_t, [], [],
 193 [#include <sys/types.h>
 194 #include <sys/socket.h>
 195 ])
 196
 197 AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 198 #include <elf.h>
 199 )
 200
 201 ACX_PKGVERSION([GDB])
 202 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 203 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 204 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 205
 206 # Check for various supplementary target information (beyond the
 207 # triplet) which might affect the choices in configure.srv.
 208 case "${target}" in
 209 changequote(,)dnl
 210   i[34567]86-*-linux*)
 211 changequote([,])dnl
 212     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 213                    [save_CPPFLAGS="$CPPFLAGS"
 214                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 215                     AC_EGREP_CPP([got it], [
 216 #if __x86_64__
 217 got it
 218 #endif
 219                  ], [gdb_cv_i386_is_x86_64=yes],
 220                     [gdb_cv_i386_is_x86_64=no])
 221                     CPPFLAGS="$save_CPPFLAGS"])
 222     ;;
 223   m68k-*-*)
 224     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 225                    [save_CPPFLAGS="$CPPFLAGS"
 226                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 227                     AC_EGREP_CPP([got it], [
 228 #ifdef __mcoldfire__
 229 got it
 230 #endif
 231                  ], [gdb_cv_m68k_is_coldfire=yes],
 232                     [gdb_cv_m68k_is_coldfire=no])
 233                     CPPFLAGS="$save_CPPFLAGS"])
 234     ;;
 235 esac
 236
 237 . ${srcdir}/configure.srv
 238
 239 if test "${srv_mingwce}" = "yes"; then
 240   LIBS="$LIBS -lws2"
 241 elif test "${srv_mingw}" = "yes"; then
 242   LIBS="$LIBS -lws2_32"
 243 elif test "${srv_qnx}" = "yes"; then
 244   LIBS="$LIBS -lsocket"
 245 elif test "${srv_lynxos}" = "yes"; then
 246   LIBS="$LIBS -lnetinet"
 247 fi
 248
 249 if test "${srv_mingw}" = "yes"; then
 250   AC_DEFINE(USE_WIN32API, 1,
 251             [Define if we should use the Windows API, instead of the
 252              POSIX API.  On Windows, we use the Windows API when
 253              building for MinGW, but the POSIX API when building
 254              for Cygwin.])
 255 fi
 256
 257 if test "${srv_linux_usrregs}" = "yes"; then
 258   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 259             [Define if the target supports PTRACE_PEEKUSR for register ]
 260             [access.])
 261 fi
 262
 263 if test "${srv_linux_regsets}" = "yes"; then
 264   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 265             [Define if the target supports register sets.])
 266
 267   AC_MSG_CHECKING(for PTRACE_GETREGS)
 268   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 269   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 270                   [PTRACE_GETREGS;],
 271                   [gdbsrv_cv_have_ptrace_getregs=yes],
 272                   [gdbsrv_cv_have_ptrace_getregs=no])])
 273   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 274   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 275     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 276               [Define if the target supports PTRACE_GETREGS for register ]
 277               [access.])
 278   fi
 279
 280   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 281   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 282   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 283                   [PTRACE_GETFPXREGS;],
 284                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 285                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 286   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 287   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 288     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 289               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 290               [register access.])
 291   fi
 292 fi
 293
 294 if test "$ac_cv_header_sys_procfs_h" = yes; then
 295   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 296   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 297   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 298   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 299 fi
 300
 301 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 302 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 303   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 304 fi
 305
 306 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 307 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 308   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 309 fi
 310
 311 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 312 dnl needs it (and gdbreplay doesn't).
 313 old_LIBS="$LIBS"
 314 AC_CHECK_LIB(dl, dlopen)
 315 LIBS="$old_LIBS"
 316
 317 srv_thread_depfiles=
 318 srv_libs=
 319 USE_THREAD_DB=
 320
 321 if test "$srv_linux_thread_db" = "yes"; then
 322   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 323     srv_libs="-ldl"
 324     AC_MSG_CHECKING(for the dynamic export flag)
 325     old_LDFLAGS="$LDFLAGS"
 326     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 327     # supported there.
 328     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 329     LDFLAGS="$LDFLAGS $RDYNAMIC"
 330     AC_TRY_LINK([], [],
 331                 [found="-Wl,--dynamic-list"
 332                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 333                 [RDYNAMIC="-rdynamic"
 334                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 335                  AC_TRY_LINK([], [],
 336                              [found="-rdynamic"],
 337                              [found="no"
 338                               RDYNAMIC=""])])
 339     AC_SUBST(RDYNAMIC)
 340     LDFLAGS="$old_LDFLAGS"
 341     AC_MSG_RESULT($found)
 342   else
 343     srv_libs="-lthread_db"
 344   fi
 345
 346   srv_thread_depfiles="thread-db.o proc-service.o"
 347   USE_THREAD_DB="-DUSE_THREAD_DB"
 348   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 349   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 350                   [gdbsrv_cv_have_td_version=yes],
 351                   [gdbsrv_cv_have_td_version=no])])
 352   if test $gdbsrv_cv_have_td_version = yes; then
 353     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 354   fi
 355 fi
 356
 357 AC_ARG_WITH(libthread-db,
 358 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 359 [srv_libthread_db_path="${withval}"
 360   srv_libs="$srv_libthread_db_path"
 361 ])
 362
 363 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 364   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 365 fi
 366
 367 if test "$srv_xmlfiles" != ""; then
 368   srv_xmlbuiltin="xml-builtin.o"
 369   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 370
 371   tmp_xmlfiles=$srv_xmlfiles
 372   srv_xmlfiles=""
 373   for f in $tmp_xmlfiles; do
 374     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 375   done
 376 fi
 377
 378 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles"
 379 GDBSERVER_LIBS="$srv_libs"
 380
 381 dnl Check whether the target supports __sync_*_compare_and_swap.
 382 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 383                 gdbsrv_cv_have_sync_builtins, [
 384 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 385                 gdbsrv_cv_have_sync_builtins=yes,
 386                 gdbsrv_cv_have_sync_builtins=no)])
 387 if test $gdbsrv_cv_have_sync_builtins = yes; then
 388   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 389     [Define to 1 if the target supports __sync_*_compare_and_swap])
 390 fi
 391
 392 dnl Check for -fvisibility=hidden support in the compiler.
 393 saved_cflags="$CFLAGS"
 394 CFLAGS="$CFLAGS -fvisibility=hidden"
 395 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 396                         [gdbsrv_cv_have_visibility_hidden=yes],
 397                         [gdbsrv_cv_have_visibility_hidden=no])
 398 CFLAGS="$saved_cflags"
 399
 400 dnl Check if we can disable the virtual address space randomization.
 401 dnl The functionality of setarch -R.
 402 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 403 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 404 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 405 #       define ADDR_NO_RANDOMIZE 0x0040000
 406 #      endif
 407        /* Test the flag could be set and stays set.  */
 408        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 409        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 410            return 1])])
 411 AC_RUN_IFELSE([PERSONALITY_TEST],
 412               [gdbsrv_cv_have_personality=true],
 413               [gdbsrv_cv_have_personality=false],
 414               [AC_LINK_IFELSE([PERSONALITY_TEST],
 415                               [gdbsrv_cv_have_personality=true],
 416                               [gdbsrv_cv_have_personality=false])])
 417 if $gdbsrv_cv_have_personality
 418 then
 419     AC_DEFINE([HAVE_PERSONALITY], 1,
 420               [Define if you support the personality syscall.])
 421 fi
 422
 423
 424 IPA_DEPFILES=""
 425 extra_libraries=""
 426
 427 # check whether to enable the inprocess agent
 428 if test "$ipa_obj" != "" \
 429    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 430    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 431    have_ipa=true
 432 else
 433    have_ipa=false
 434 fi
 435
 436 AC_ARG_ENABLE(inprocess-agent,
 437 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 438 [case "$enableval" in
 439   yes) want_ipa=true ;;
 440   no) want_ipa=false ;;
 441   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 442 esac],
 443 [want_ipa=$have_ipa])
 444
 445 if $want_ipa ; then
 446    if $have_ipa ; then
 447      IPA_DEPFILES="$ipa_obj"
 448      extra_libraries="$extra_libraries libinproctrace.so"
 449    else
 450      AC_MSG_ERROR([inprocess agent not supported for this target])
 451    fi
 452 fi
 453
 454 AC_SUBST(GDBSERVER_DEPFILES)
 455 AC_SUBST(GDBSERVER_LIBS)
 456 AC_SUBST(USE_THREAD_DB)
 457 AC_SUBST(srv_xmlbuiltin)
 458 AC_SUBST(srv_xmlfiles)
 459 AC_SUBST(IPA_DEPFILES)
 460 AC_SUBST(extra_libraries)
 461
 462 GNULIB=build-gnulib-gdbserver/import
 463
 464 GNULIB_STDINT_H=
 465 if test x"$STDINT_H" != x; then
 466   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 467 fi
 468 AC_SUBST(GNULIB_STDINT_H)
 469
 470 AC_OUTPUT(Makefile,
 471 [case x$CONFIG_HEADERS in
 472 xconfig.h:config.in)
 473 echo > stamp-h ;;
 474 esac
 475 ])