gdb/gdbserver/configure.ac

   1 dnl Autoconf configure script for GDB server.
   2 dnl Copyright (C) 2000-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)dnl
  22
  23 AC_INIT(server.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30 AC_GNU_SOURCE
  31 AC_SYS_LARGEFILE
  32
  33 AC_CANONICAL_SYSTEM
  34
  35 AC_PROG_INSTALL
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_PROG_RANLIB
  38
  39 AC_ARG_PROGRAM
  40
  41 # We require a C++11 compiler.  Check if one is available, and if
  42 # necessary, set CXX_DIALECT to some -std=xxx switch.
  43 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  44
  45 AC_HEADER_STDC
  46
  47 # Set the 'development' global.
  48 . $srcdir/../../bfd/development.sh
  49
  50 # Enable -lmcheck by default (it provides cheap-enough memory
  51 # mangling), but turn it off for releases.
  52 if $development; then
  53   libmcheck_default=yes
  54 else
  55   libmcheck_default=no
  56 fi
  57 GDB_AC_LIBMCHECK(${libmcheck_default})
  58
  59 if $development; then
  60   srv_selftest_objs="selftest.o"
  61   AC_DEFINE(GDB_SELF_TEST, 1,
  62             [Define if self-testing features should be enabled])
  63 fi
  64
  65 ACX_NONCANONICAL_TARGET
  66 ACX_NONCANONICAL_HOST
  67
  68 # Dependency checking.
  69 ZW_CREATE_DEPDIR
  70
  71 # Create sub-directories for objects and dependencies.
  72 CONFIG_SRC_SUBDIR="arch"
  73 AC_SUBST(CONFIG_SRC_SUBDIR)
  74
  75 AC_CONFIG_COMMANDS([gdbdepdir],[
  76   for subdir in ${CONFIG_SRC_SUBDIR}
  77   do
  78       $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR
  79   done],
  80   [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"])
  81
  82 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  83
  84 gnulib_extra_configure_args=
  85 # If large-file support is disabled, make sure gnulib does the same.
  86 if test "$enable_largefile" = no; then
  87 gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile"
  88 fi
  89
  90 # Configure gnulib.  We can't use AC_CONFIG_SUBDIRS as that'd expect
  91 # to find the the source subdir to be configured directly under
  92 # gdbserver/.  We need to build gnulib under some other directory not
  93 # "gnulib", to avoid the problem of both GDB and GDBserver wanting to
  94 # build it in the same directory, when building in the source dir.
  95 ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"],
  96                   ["$gnulib_extra_configure_args"])
  97
  98 ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"])
  99
 100 AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl
 101                  proc_service.h sys/procfs.h linux/elf.h dnl
 102                  fcntl.h signal.h sys/file.h dnl
 103                  sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl
 104                  netinet/tcp.h arpa/inet.h)
 105 AC_FUNC_FORK
 106 AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns)
 107
 108 GDB_AC_COMMON
 109
 110 # Check the return and argument types of ptrace.
 111 GDB_AC_PTRACE
 112
 113 # Check for UST
 114 ustlibs=""
 115 ustinc=""
 116
 117 AC_ARG_WITH(ust, [  --with-ust=PATH       Specify prefix directory for the installed UST package
 118                           Equivalent to --with-ust-include=PATH/include
 119                           plus --with-ust-lib=PATH/lib])
 120 AC_ARG_WITH(ust_include, [  --with-ust-include=PATH Specify directory for installed UST include files])
 121 AC_ARG_WITH(ust_lib, [  --with-ust-lib=PATH   Specify the directory for the installed UST library])
 122
 123 case $with_ust in
 124   no)
 125     ustlibs=
 126     ustinc=
 127     ;;
 128   "" | yes)
 129     ustlibs=" -lust "
 130     ustinc=""
 131     ;;
 132   *)
 133     ustlibs="-L$with_ust/lib -lust"
 134     ustinc="-I$with_ust/include "
 135     ;;
 136 esac
 137 if test "x$with_ust_include" != x; then
 138   ustinc="-I$with_ust_include "
 139 fi
 140 if test "x$with_ust_lib" != x; then
 141   ustlibs="-L$with_ust_lib -lust"
 142 fi
 143
 144 if test "x$with_ust" != "xno"; then
 145   saved_CFLAGS="$CFLAGS"
 146   CFLAGS="$CFLAGS $ustinc"
 147   AC_MSG_CHECKING([for ust])
 148   AC_TRY_COMPILE([
 149 #define CONFIG_UST_GDB_INTEGRATION
 150 #include <ust/ust.h>
 151   ],[],
 152   [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])],
 153   [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ])
 154   CFLAGS="$saved_CFLAGS"
 155 fi
 156
 157 # Flags needed for UST
 158 AC_SUBST(ustlibs)
 159 AC_SUBST(ustinc)
 160
 161 AM_GDB_WARNINGS
 162 dnl The codebase isn't clean yet with this flag.
 163 case " $WARN_CFLAGS " in
 164 *" -Wmissing-prototypes "*)
 165   WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes"
 166   ;;
 167 esac
 168
 169 dnl dladdr is glibc-specific.  It is used by thread-db.c but only for
 170 dnl debugging messages.  It lives in -ldl which is handled below so we don't
 171 dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here.  Instead we just temporarily
 172 dnl augment LIBS.
 173 old_LIBS="$LIBS"
 174 LIBS="$LIBS -ldl"
 175 AC_CHECK_FUNCS(dladdr)
 176 LIBS="$old_LIBS"
 177
 178 libiberty_INIT
 179
 180 AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf])
 181
 182 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
 183
 184 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
 185 # Older amd64 Linux's don't have the fs_base and gs_base members of
 186 # `struct user_regs_struct'.
 187 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
 188                  [], [], [#include <sys/user.h>])
 189
 190
 191 AC_CHECK_TYPES(socklen_t, [], [],
 192 [#include <sys/types.h>
 193 #include <sys/socket.h>
 194 ])
 195
 196 case "${target}" in
 197   *-android*)
 198     # Starting with NDK version 9, <elf.h> actually includes definitions
 199     # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes
 200     # <sys/exec_elf.h> which defines some of the ELF types incorrectly,
 201     # leading to conflicts with the defintions from <linux/elf.h>.
 202     # This makes it impossible for us to include both <elf.h> and
 203     # <linux/elf.h>, which means that, in practice, we do not have
 204     # access to Elf32_auxv_t and Elf64_auxv_t on this platform.
 205     # Therefore, do not try to auto-detect availability, as it would
 206     # get it wrong on this platform.
 207     ;;
 208   *)
 209     AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [],
 210     #include <elf.h>
 211     )
 212 esac
 213
 214 ACX_PKGVERSION([GDB])
 215 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 216 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 217 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 218
 219 # Check for various supplementary target information (beyond the
 220 # triplet) which might affect the choices in configure.srv.
 221 case "${target}" in
 222 changequote(,)dnl
 223   i[34567]86-*-linux*)
 224 changequote([,])dnl
 225     AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64],
 226                    [save_CPPFLAGS="$CPPFLAGS"
 227                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 228                     AC_EGREP_CPP([got it], [
 229 #if __x86_64__
 230 got it
 231 #endif
 232                  ], [gdb_cv_i386_is_x86_64=yes],
 233                     [gdb_cv_i386_is_x86_64=no])
 234                     CPPFLAGS="$save_CPPFLAGS"])
 235     ;;
 236
 237   x86_64-*-linux*)
 238     AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32],
 239                    [save_CPPFLAGS="$CPPFLAGS"
 240                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 241                     AC_EGREP_CPP([got it], [
 242 #if __x86_64__ && __ILP32__
 243 got it
 244 #endif
 245                  ], [gdb_cv_x86_is_x32=yes],
 246                     [gdb_cv_x86_is_x32=no])
 247                     CPPFLAGS="$save_CPPFLAGS"])
 248     ;;
 249
 250   m68k-*-*)
 251     AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire],
 252                    [save_CPPFLAGS="$CPPFLAGS"
 253                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 254                     AC_EGREP_CPP([got it], [
 255 #ifdef __mcoldfire__
 256 got it
 257 #endif
 258                  ], [gdb_cv_m68k_is_coldfire=yes],
 259                     [gdb_cv_m68k_is_coldfire=no])
 260                     CPPFLAGS="$save_CPPFLAGS"])
 261     ;;
 262 esac
 263
 264 . ${srcdir}/configure.srv
 265
 266 # Add in the common host objects.
 267 . ${srcdir}/../common/common.host
 268 srv_host_obs="$common_host_obs"
 269
 270 if test "${srv_mingwce}" = "yes"; then
 271   LIBS="$LIBS -lws2"
 272 elif test "${srv_mingw}" = "yes"; then
 273   LIBS="$LIBS -lws2_32"
 274 elif test "${srv_qnx}" = "yes"; then
 275   LIBS="$LIBS -lsocket"
 276 elif test "${srv_lynxos}" = "yes"; then
 277   LIBS="$LIBS -lnetinet"
 278 fi
 279
 280 if test "${srv_mingw}" = "yes"; then
 281   AC_DEFINE(USE_WIN32API, 1,
 282             [Define if we should use the Windows API, instead of the
 283              POSIX API.  On Windows, we use the Windows API when
 284              building for MinGW, but the POSIX API when building
 285              for Cygwin.])
 286 fi
 287
 288 if test "${srv_linux_usrregs}" = "yes"; then
 289   AC_DEFINE(HAVE_LINUX_USRREGS, 1,
 290             [Define if the target supports PTRACE_PEEKUSR for register ]
 291             [access.])
 292 fi
 293
 294 if test "${srv_linux_regsets}" = "yes"; then
 295   AC_DEFINE(HAVE_LINUX_REGSETS, 1,
 296             [Define if the target supports register sets.])
 297
 298   AC_MSG_CHECKING(for PTRACE_GETREGS)
 299   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs,
 300   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 301                   [PTRACE_GETREGS;],
 302                   [gdbsrv_cv_have_ptrace_getregs=yes],
 303                   [gdbsrv_cv_have_ptrace_getregs=no])])
 304   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs)
 305   if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then
 306     AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
 307               [Define if the target supports PTRACE_GETREGS for register ]
 308               [access.])
 309   fi
 310
 311   AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
 312   AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs,
 313   [AC_TRY_COMPILE([#include <sys/ptrace.h>],
 314                   [PTRACE_GETFPXREGS;],
 315                   [gdbsrv_cv_have_ptrace_getfpxregs=yes],
 316                   [gdbsrv_cv_have_ptrace_getfpxregs=no])])
 317   AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs)
 318   if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then
 319     AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
 320               [Define if the target supports PTRACE_GETFPXREGS for extended ]
 321               [register access.])
 322   fi
 323 fi
 324
 325 if test "${srv_linux_btrace}" = "yes"; then
 326   AC_DEFINE(HAVE_LINUX_BTRACE, 1,
 327             [Define if the target supports branch tracing.])
 328 fi
 329
 330 if test "$ac_cv_header_sys_procfs_h" = yes; then
 331   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
 332   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
 333   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
 334   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
 335   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
 336 fi
 337
 338 dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h.
 339 if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then
 340   GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t)
 341 fi
 342
 343 dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h.
 344 if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then
 345   GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t)
 346 fi
 347
 348 dnl Check for libdl, but do not add it to LIBS as only gdbserver
 349 dnl needs it (and gdbreplay doesn't).
 350 old_LIBS="$LIBS"
 351 AC_CHECK_LIB(dl, dlopen)
 352 LIBS="$old_LIBS"
 353
 354 srv_thread_depfiles=
 355 srv_libs=
 356
 357 if test "$srv_linux_thread_db" = "yes"; then
 358   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 359     srv_libs="-ldl"
 360     AC_MSG_CHECKING(for the dynamic export flag)
 361     old_LDFLAGS="$LDFLAGS"
 362     # Older GNU ld supports --export-dynamic but --dynamic-list may not be
 363     # supported there.
 364     RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
 365     LDFLAGS="$LDFLAGS $RDYNAMIC"
 366     AC_TRY_LINK([], [],
 367                 [found="-Wl,--dynamic-list"
 368                  RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'],
 369                 [RDYNAMIC="-rdynamic"
 370                  LDFLAGS="$old_LDFLAGS $RDYNAMIC"
 371                  AC_TRY_LINK([], [],
 372                              [found="-rdynamic"],
 373                              [found="no"
 374                               RDYNAMIC=""])])
 375     AC_SUBST(RDYNAMIC)
 376     LDFLAGS="$old_LDFLAGS"
 377     AC_MSG_RESULT($found)
 378   else
 379     srv_libs="-lthread_db"
 380   fi
 381
 382   srv_thread_depfiles="thread-db.o proc-service.o"
 383   AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.])
 384   AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version,
 385   [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;],
 386                   [gdbsrv_cv_have_td_version=yes],
 387                   [gdbsrv_cv_have_td_version=no])])
 388   if test $gdbsrv_cv_have_td_version = yes; then
 389     AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.])
 390   fi
 391 fi
 392
 393 AC_ARG_WITH(libthread-db,
 394 AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]),
 395 [srv_libthread_db_path="${withval}"
 396   srv_libs="$srv_libthread_db_path"
 397 ])
 398
 399 if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then
 400   AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.])
 401 fi
 402
 403 if test "$srv_xmlfiles" != ""; then
 404   srv_xmlbuiltin="xml-builtin.o"
 405   AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.])
 406
 407   tmp_xmlfiles=$srv_xmlfiles
 408   srv_xmlfiles=""
 409   for f in $tmp_xmlfiles; do
 410     srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f"
 411   done
 412 fi
 413
 414 GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs $srv_selftest_objs"
 415 GDBSERVER_LIBS="$srv_libs"
 416
 417 dnl Check whether the target supports __sync_*_compare_and_swap.
 418 AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap],
 419                 gdbsrv_cv_have_sync_builtins, [
 420 AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);],
 421                 gdbsrv_cv_have_sync_builtins=yes,
 422                 gdbsrv_cv_have_sync_builtins=no)])
 423 if test $gdbsrv_cv_have_sync_builtins = yes; then
 424   AC_DEFINE(HAVE_SYNC_BUILTINS, 1,
 425     [Define to 1 if the target supports __sync_*_compare_and_swap])
 426 fi
 427
 428 dnl Check for -fvisibility=hidden support in the compiler.
 429 saved_cflags="$CFLAGS"
 430 CFLAGS="$CFLAGS -fvisibility=hidden"
 431 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 432                         [gdbsrv_cv_have_visibility_hidden=yes],
 433                         [gdbsrv_cv_have_visibility_hidden=no])
 434 CFLAGS="$saved_cflags"
 435
 436 dnl Check if we can disable the virtual address space randomization.
 437 dnl The functionality of setarch -R.
 438 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
 439 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
 440 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
 441 #       define ADDR_NO_RANDOMIZE 0x0040000
 442 #      endif
 443        /* Test the flag could be set and stays set.  */
 444        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
 445        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
 446            return 1])])
 447 AC_RUN_IFELSE([PERSONALITY_TEST],
 448               [gdbsrv_cv_have_personality=true],
 449               [gdbsrv_cv_have_personality=false],
 450               [AC_LINK_IFELSE([PERSONALITY_TEST],
 451                               [gdbsrv_cv_have_personality=true],
 452                               [gdbsrv_cv_have_personality=false])])
 453 if $gdbsrv_cv_have_personality
 454 then
 455     AC_DEFINE([HAVE_PERSONALITY], 1,
 456               [Define if you support the personality syscall.])
 457 fi
 458
 459
 460 IPA_DEPFILES=""
 461 extra_libraries=""
 462
 463 # check whether to enable the inprocess agent
 464 if test "$ipa_obj" != "" \
 465    -a "$gdbsrv_cv_have_sync_builtins" = yes \
 466    -a "$gdbsrv_cv_have_visibility_hidden" = yes; then
 467    have_ipa=true
 468 else
 469    have_ipa=false
 470 fi
 471
 472 AC_ARG_ENABLE(inprocess-agent,
 473 AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]),
 474 [case "$enableval" in
 475   yes) want_ipa=true ;;
 476   no) want_ipa=false ;;
 477   *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;;
 478 esac],
 479 [want_ipa=$have_ipa])
 480
 481 if $want_ipa ; then
 482    if $have_ipa ; then
 483      IPA_DEPFILES="$ipa_obj"
 484      extra_libraries="$extra_libraries libinproctrace.so"
 485    else
 486      AC_MSG_ERROR([inprocess agent not supported for this target])
 487    fi
 488 fi
 489
 490 AC_SUBST(GDBSERVER_DEPFILES)
 491 AC_SUBST(GDBSERVER_LIBS)
 492 AC_SUBST(srv_xmlbuiltin)
 493 AC_SUBST(srv_xmlfiles)
 494 AC_SUBST(IPA_DEPFILES)
 495 AC_SUBST(extra_libraries)
 496
 497 GNULIB=build-gnulib-gdbserver/import
 498
 499 GNULIB_STDINT_H=
 500 if test x"$STDINT_H" != x; then
 501   GNULIB_STDINT_H=$GNULIB/$STDINT_H
 502 fi
 503 AC_SUBST(GNULIB_STDINT_H)
 504
 505 AC_CONFIG_FILES([Makefile],
 506 [case x$CONFIG_HEADERS in
 507 xconfig.h:config.in)
 508 echo > stamp-h ;;
 509 esac
 510 ])
 511
 512 AC_OUTPUT