gdb/testsuite/configure.in

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright 2002, 2003
   5 # Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22 AC_PREREQ(2.13)
  23 AC_INIT(gdb.base)
  24
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_TARGET
  28
  29 # Directories that need to be configured in all configurations.
  30 configdirs=
  31
  32 # Add HP-specific tests when appropriate.
  33 case $target in
  34   hppa*-*-hpux*)
  35     configdirs="$configdirs gdb.hp" ;;
  36 esac
  37
  38 # With stabs.
  39 AC_ARG_WITH(stabs,
  40 [  --with-stabs            arrange to use stabs instead of host debug format],,
  41 [# We enable stabs tests by default on selected targets.
  42 case $target in
  43    powerpc-*-aix* \
  44  | rs6000-*-aix*  \
  45  | *-*-bsd*       \
  46  | *-*-go32*      \
  47  | *-*-linux*     \
  48  | *-*-lynxos*    \
  49  | *-sun-*        \
  50  | hppa*-*-*      \
  51  | *-*-elf*       \
  52  )
  53     with_stabs=yes ;;
  54  *)
  55     with_stabs=no ;;
  56 esac])
  57
  58 # Add stabs tests when appropriate.
  59 if test $with_stabs = yes; then
  60   configdirs="$configdirs gdb.stabs"
  61 fi
  62
  63 # Enable gdbtk.
  64 AC_ARG_ENABLE(gdbtk,
  65 [  --enable-gtk            enable gdbtk graphical user interface (GUI)],,
  66   [if test -d $srcdir/gdb.gdbtk; then
  67     enable_gdbtk=yes
  68   else
  69     enable_gdbtk=no
  70   fi])
  71 # We unconditionally disable gdbtk tests on selected platforms.
  72 case $host_os in
  73   go32* | windows*)
  74     enable_gdbtk=no ;;
  75 esac
  76
  77 # Add gdbtk tests when appropriate.
  78 if test $enable_gdbtk = yes; then
  79   configdirs="$configdirs gdb.gdbtk"
  80 fi
  81
  82 # Enable shared libraries.
  83 AC_ARG_ENABLE(shared,
  84 [  --enable-shared         build shared libraries [deault=yes]],,
  85   enable_shared=yes)
  86
  87 # If we have shared libraries, try to set RPATH_ENVVAR reasonably,
  88 # such that we can find the shared libraries in the build tree.
  89 if test $enable_shared = no; then
  90   # The variable `RPATH_ENVVAR' itself is not likely to be used on any
  91   # platform.
  92   RPATH_ENVVAR=RPATH_ENVVAR
  93 else
  94   # The variable `LD_LIBRARY_PATH' is used on most platforms.
  95   RPATH_ENVVAR=LD_LIBRARY_PATH
  96   # The following exceptions are taken from Libtool 1.4.3.
  97   case $host_os in
  98     aix*)
  99       if test $host_cpu != ia64; then
 100         RPATH_ENVVAR=LIBPATH
 101       fi ;;
 102     darwin* | rhapsody*)
 103       RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
 104     hpux*)
 105       RPATH_ENVVAR=SHLIB_PATH ;;
 106   esac
 107 fi
 108 AC_SUBST(RPATH_ENVVAR)
 109
 110 AC_CHECK_HEADERS(pthread.h)
 111
 112 AC_EXEEXT
 113
 114 AC_CONFIG_SUBDIRS($configdirs)
 115 AC_OUTPUT([Makefile gdb.arch/Makefile gdb.asm/Makefile gdb.base/Makefile \
 116   gdb.cp/Makefile gdb.disasm/Makefile gdb.java/Makefile gdb.mi/Makefile \
 117   gdb.objc/Makefile gdb.threads/Makefile gdb.trace/Makefile])