gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-note "empty"
  36 set asm-flags ""
  37 set link-flags "-e _start"
  38 set debug-flags ""
  39
  40 switch -glob -- [istarget] {
  41     "alpha*-*-*" {
  42         set asm-arch alpha
  43         # ??? Won't work with ecoff systems like Tru64, but then we also
  44         # don't have any other -g flag that creates mdebug output.
  45         set asm-flags "-no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  46         set debug-flags "-gdwarf-2"
  47     }
  48     "*arm-*-*" {
  49         set asm-arch arm
  50     }
  51     "xscale-*-*" {
  52         set asm-arch arm
  53     }
  54     "d10v-*-*" {
  55         set asm-arch d10v
  56     }
  57     "frv-*-*" {
  58         set asm-arch frv
  59     }
  60     "s390-*-*" {
  61         set asm-arch s390
  62     }
  63     "s390x-*-*" {
  64         set asm-arch s390x
  65     }
  66     "x86_64-*-*" {
  67         set asm-arch x86_64
  68         set debug-flags "-gdwarf-2"
  69     }
  70     "i\[3456\]86-*-*" {
  71         set asm-arch i386
  72     }
  73     "m32r*-linux*" {
  74         set asm-arch m32r-linux
  75     }
  76     "m32c-*-*" {
  77         set asm-arch m32c
  78     }
  79     "m32r*-*" {
  80         set asm-arch m32r
  81         append link-flags "--whole-archive -lgloss --no-whole-archive"
  82     }
  83     "m6811-*-*" {
  84         set asm-arch m68hc11
  85         set asm-flags "-mshort-double -m68hc11 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  86         set debug-flags "-gdwarf-2"
  87         # This asm test is specific and uses the linker directly.
  88         # We must not use the target board linker script defined for other
  89         # tests.  Remove it and restore it later on.
  90         set board [target_info name]
  91         set old_ldscript [board_info $board ldscript]
  92         unset_board_info "ldscript"
  93     }
  94     "m6812-*-*" {
  95         set asm-arch m68hc11
  96         set asm-flags "-mshort-double -m68hc12 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  97         set debug-flags "-gdwarf-2"
  98         # This asm test is specific and uses the linker directly.
  99         # We must not use the target board linker script defined for other
 100         # tests.  Remove it and restore it later on.
 101         set board [target_info name]
 102         set old_ldscript [board_info $board ldscript]
 103         set_board_info ldscript ""
 104     }
 105     "mips*-*" {
 106         set asm-arch mips
 107     }
 108     "powerpc*-*" {
 109         set asm-arch powerpc
 110     }
 111     "sh*-*-*" {
 112         set asm-arch sh
 113         set debug-flags "-gdwarf-2"
 114     }
 115     "sparc-*-*" {
 116         set asm-arch sparc
 117     }
 118     "sparc64-*-*" {
 119         set asm-arch sparc64
 120         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 121         set debug-flags "-gdwarf-2"
 122     }
 123     "xstormy16-*-*" {
 124         set asm-arch xstormy16
 125         set debug-flags "-gdwarf-2"
 126     }
 127     "v850-*-*" {
 128         set asm-arch v850
 129         set gdb_wrapper_initialized 1
 130     }
 131     "m68k-*-*" {
 132         set asm-arch m68k
 133     }
 134     "ia64-*-*" {
 135         set asm-arch ia64
 136         set debug-flags "-gdwarf-2"
 137     }
 138     "iq2000-*-*" {
 139         set asm-arch iq2000
 140     }
 141     "hppa*-linux-*" {
 142         set asm-arch pa
 143         set debug-flags "-gdwarf-2"
 144     }
 145     "hppa-*-openbsd*" {
 146         set asm-arch pa
 147         set debug-flags "-gdwarf-2"
 148     }
 149     "hppa64-*-hpux*" {
 150         set asm-arch pa64
 151         set debug-flags "-gdwarf-2"
 152     }
 153     "h83*-*" {
 154         set asm-arch h8300
 155         set debug-flags "-gdwarf-2"
 156     }
 157 }
 158
 159 if { "${asm-arch}" == "" } {
 160     untested asm-source.exp
 161     return -1
 162 }
 163
 164 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 165 if { [istarget "*-*-netbsdelf*"]
 166      || [istarget "alpha-*-netbsd*"]
 167      || [istarget "mips*-*-netbsd*"]
 168      || [istarget "powerpc-*-netbsd*"]
 169      || [istarget "x86_64-*-netbsd*"] } then {
 170     set asm-note "netbsd"
 171 }
 172
 173 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 174 # of handing a.out here since most OpenBSD/a.out systems use a rather
 175 # outdated assembler that doesn't assemble this test's code anyway.
 176 if { [istarget "*-*-openbsd*"] } then {
 177     set asm-note "openbsd"
 178 }
 179
 180 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 181 # switches according to compiler syntax.  If we pass these options straight
 182 # to the assembler, they won't always make sense.  If we don't pass them to
 183 # the assembler, the final link will complain that the object files were
 184 # built with different defaults.  So no matter what we do, we lose.  We may as
 185 # well get out of this test sooner rather than later.
 186 set dest [target_info name]
 187 if [board_info $dest exists multilib_flags] {
 188         set multilib_flags [board_info $dest multilib_flags]
 189         if { "${multilib_flags}" != "" } {
 190            untested asm-source.exp
 191            return -1
 192            return;
 193          }
 194 }
 195
 196 set testfile "asm-source"
 197 set binfile ${objdir}/${subdir}/${testfile}
 198 set srcfile1 asmsrc1.s
 199 set srcfile2 asmsrc2.s
 200
 201 remote_exec build "rm -f ${subdir}/arch.inc"
 202 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 203 remote_exec build "rm -f ${subdir}/note.inc"
 204 remote_download host ${srcdir}/${subdir}/${asm-note}.inc ${subdir}/note.inc
 205
 206 if { [string equal ${asm-flags} ""] } {
 207     set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 208 }
 209
 210 if { [string equal ${debug-flags} ""] } {
 211     set debug-flags "-gstabs"
 212 }
 213
 214 # Allow the target board to override the debug flags.
 215 if { [board_info $dest exists debug_flags] } then {
 216     set debug-flags "[board_info $dest debug_flags]"
 217 }
 218
 219 # The debug flags are in the format that gcc expects:
 220 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 221 # other languages in the test suite, we accept this input format.
 222 # So the user can run the test suite with:
 223 #
 224 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 225 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 226 #
 227 # However, the GNU assembler has different spellings than gcc.
 228 # So I adjust the debug flags here.
 229
 230 # The GNU assembler spells "dwarf-2" as "dwarf2".
 231 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 232
 233 # The GNU assembler before 2.15 did not support "stabs+".
 234 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 235
 236 # The GNU assembler does not support level options like "-g2" or "-g3".
 237 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 238
 239 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags} ${debug-flags}"] != ""} then {
 240      untested asm-source.exp
 241      return -1
 242 }
 243 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags} ${debug-flags}"] != ""} then {
 244      untested asm-source.exp
 245      return -1
 246 }
 247
 248 # We deliberately don't use gdb_compile here to link together the
 249 # assembled object files.  Using gdb_compile, and therefore the C
 250 # compiler, is conceptually wrong, since we're testing raw assembler
 251 # code here that provides its own startup code.  Using target_link
 252 # also avoids a lot of problems on many systems, most notably on
 253 # *-*-*bsd* and *-*-solaris2*.
 254 if {[target_link "asmsrc1.o asmsrc2.o" "${binfile}" ${link-flags}] != "" } then {
 255      untested asm-source.exp
 256      return -1
 257 }
 258
 259 # Restore the target board linker script for HC11/HC12.
 260 if { [istarget "m6811-*-*"] || [istarget "m6812-*-*"] } {
 261     set_board_info ldscript $old_ldscript
 262 }
 263
 264 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 265
 266
 267 gdb_start
 268 gdb_reinitialize_dir $srcdir/$subdir
 269 gdb_load ${binfile}
 270
 271 #
 272 # Run to `main' where we begin our tests.
 273 #
 274
 275 if ![runto_main] then {
 276     gdb_suppress_tests
 277 }
 278
 279 # Execute the `f' command and see if the result includes source info.
 280 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 281
 282 # See if we properly `next' over a macro with several insns.
 283 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 284
 285 # See if we can properly `step' into a subroutine call.
 286 gdb_test "s" "8\[       \]*.*" "step into foo2"
 287
 288 # Test 'info target', and incidentally capture the entry point address.
 289 set entry_point 0
 290 send_gdb "info target\n"
 291 gdb_expect {
 292     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 293         set entry_point $expect_out(1,string)
 294         pass "info target"
 295     }
 296     -re ".*$gdb_prompt $" {
 297         fail "info target"
 298     }
 299     timeout {
 300         fail "info target (timeout)"
 301     }
 302 }
 303
 304 # Capture the start symbol (may be '_start' or 'start')
 305 set entry_symbol ""
 306 send_gdb "info symbol 0x$entry_point\n"
 307 gdb_expect {
 308     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 309         # We match the echoed `info symbol' command here, to help us
 310         # reliably identify the beginning of the start symbol in the
 311         # command's output.  You might think we could just use '^' to
 312         # start matching at the beginning of the line, but
 313         # unfortunately, in Expect, '^' matches the beginning of the
 314         # input that hasn't been matched by any expect clause yet.  If
 315         # every expect clause consumes a complete line, along with its
 316         # terminating CR/LF, this is equivalent to the beginning of a
 317         # line.  But expect clauses that end with `.*' will consume as
 318         # much as happened to arrive from the TTY --- exactly where
 319         # they leave you depends on inter-process timing.  :(
 320         set entry_symbol $expect_out(1,string)
 321         pass "info symbol"
 322     }
 323     -re ".*$gdb_prompt $" {
 324         fail "info symbol"
 325     }
 326     timeout {
 327         fail "info symbol (timeout)"
 328     }
 329 }
 330
 331 # Now try a 'list' from the other source file.
 332 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 333
 334 # Now try a source file search
 335 gdb_test "search A routine for foo2 to call" \
 336         "40\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 337
 338 # See if `f' prints the right source file.
 339 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 340
 341 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 342 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 343
 344 # See if a simple `bt' prints the right source files and
 345 # doesn't fall off the stack.
 346
 347 gdb_test "bt 10" \
 348         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33" \
 349         "bt ALL in foo2"
 350
 351 # See if a capped `bt' prints the right source files.
 352 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 353
 354 # Step into another subroutine which lives back in the first source file.
 355 gdb_test "s" "" "s 2"
 356
 357 # Next over insns to set up the stack frame.
 358 gdb_test "n" "" "n 2"
 359
 360 # Now see if a capped `bt' is correct.
 361 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:45.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 362
 363 # Try 'info source' from asmsrc1.s
 364 gdb_test "info source" \
 365         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 366         "info source asmsrc1.s"
 367
 368 # Try 'finishing' from foo3
 369 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 370         "finish from foo3"
 371
 372 # Try 'info source' from asmsrc2.s
 373 gdb_test "info source" \
 374         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 375         "info source asmsrc2.s"
 376
 377 # Try 'info sources'.  This can produce a lot of output on systems
 378 # with dynamic linking, where the system's shared libc was compiled
 379 # with debugging info; for example, on Linux, this produces 47kb of
 380 # output.  So we consume it as we go.
 381 send_gdb "info sources\n"
 382 set seen_asmsrc_1 0
 383 set seen_asmsrc_2 0
 384 gdb_expect {
 385     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 386         set seen_asmsrc_1 1
 387         exp_continue
 388     }
 389     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 390         set seen_asmsrc_2 1
 391         exp_continue
 392     }
 393     -re ", " {
 394         exp_continue
 395     }
 396     -re "$gdb_prompt $" {
 397         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 398             pass "info sources"
 399         } else {
 400             fail "info sources"
 401         }
 402     }
 403     timeout {
 404             fail "info sources (timeout)"
 405     }
 406 }
 407
 408
 409 # Try 'info line'
 410 gdb_test "info line" \
 411         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 412         "info line"
 413
 414 # Try 'nexting' over next call to foo3
 415 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 416
 417 # Try 'return' from foo2
 418 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 419         "Make (foo2|selected stack frame) return now\?.*" "y"
 420
 421 # Disassemble something, check the output
 422 proc test_dis { command var } {
 423     global gdb_prompt
 424     send_gdb "${command}\n"
 425     gdb_expect {
 426         -re "${var}.*:.*(Cannot access|Bad address)" {
 427             # The "disassembler" was only accessing the local
 428             # executable and that would cause attempts to disassemble
 429             # variables to fail (memory not valid).
 430             fail "${command} (memory read error)"
 431         }
 432         -re "${var}.*:.*${gdb_prompt}" {
 433             pass "${command}"
 434         }
 435         timeout {
 436             fail "${command} (timeout)"
 437         }
 438     }
 439 }
 440
 441 # See if we can look at a global variable, three ways
 442 gdb_test "print globalvar" ".* = 11" "look at global variable"
 443 test_dis "x/i &globalvar" "globalvar"
 444 test_dis "disassem &globalvar &globalvar+1" "globalvar"
 445
 446 # See if we can look at a static variable, three ways
 447 gdb_test "print staticvar" ".* = 5" "look at static variable"
 448 test_dis "x/i &staticvar" "staticvar"
 449 test_dis "disassem &staticvar &staticvar+1" "staticvar"
 450
 451 # See if we can look at a static function
 452 gdb_test "disassem foostatic" ".*<foostatic\\+0>:.*End of assembler dump." \
 453         "look at static function"
 454
 455 remote_exec build "rm -f ${subdir}/arch.inc"
 456 remote_exec build "rm -f ${subdir}/note.inc"