gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-flags ""
  36 set link-flags ""
  37
  38 switch -glob -- [istarget] {
  39     "alpha*-*-*" {
  40         set asm-arch alpha
  41         # ??? Won't work with ecoff systems like Tru64, but then we also
  42         # don't have any other -g flag that creates mdebug output.
  43         set asm-flags "-gdwarf2 -no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  44     }
  45     "*arm-*-*" {
  46         set asm-arch arm
  47     }
  48     "xscale-*-*" {
  49         set asm-arch arm
  50     }
  51     "d10v-*-*" {
  52         set asm-arch d10v
  53     }
  54     "s390-*-*" {
  55         set asm-arch s390
  56     }
  57     "s390x-*-*" {
  58         set asm-arch s390x
  59     }
  60     "x86_64-*-*" {
  61         set asm-arch x86_64
  62         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  63     }
  64     "i\[3456\]86-*-*" {
  65         set asm-arch i386
  66         if [istarget "*-*-cygwin*"] then {
  67             set link-flags "--entry _start"
  68         }
  69     }
  70     "m32r*-*" {
  71         set asm-arch m32r
  72     }
  73     "m6811-*-*" {
  74         set asm-arch m68hc11
  75         set asm-flags "-mshort-double -m68hc11 -gdwarf2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  76     }
  77     "m6812-*-*" {
  78         set asm-arch m68hc11
  79         set asm-flags "-mshort-double -m68hc12 -gdwarf2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  80     }
  81     "mips*-*" {
  82         set asm-arch mips
  83     }
  84     "powerpc*-*" {
  85         set asm-arch powerpc
  86     }
  87     "sparc-*-*" {
  88         set asm-arch sparc
  89     }
  90     "sparc64-*-*" {
  91         set asm-arch sparc64
  92         set asm-flags "-xarch=v9 -gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  93     }
  94     "xstormy16-*-*" {
  95         set asm-arch xstormy16
  96         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  97     }
  98     "v850-*-*" {
  99         set asm-arch v850
 100         set gdb_wrapper_initialized 1
 101     }
 102     "m68k-*-*" {
 103         set asm-arch m68k
 104     }
 105 }
 106
 107 if { "${asm-arch}" == "" } {
 108     gdb_suppress_entire_file "Assembly source test -- not implemented for this target."
 109 }
 110
 111 # On FreeBSD, crt1.o the final link will fail because of unresolved
 112 # symbols.  It turns out that libc.so references symbols that are
 113 # normally provided by crt1.o, which isn't linked in since we specify
 114 # -nostartfiles.  Using -nostdlib doesn't help since target_compile
 115 # automatically adds -lm.  Linking statically avoids this mess.
 116 if [istarget "*-*-freebsd*"] then {
 117     set link-flags "-static"
 118 }
 119
 120 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 121 # switches according to compiler syntax.  If we pass these options straight
 122 # to the assembler, they won't always make sense.  If we don't pass them to
 123 # the assembler, the final link will complain that the object files were
 124 # built with different defaults.  So no matter what we do, we lose.  We may as
 125 # well get out of this test sooner rather than later.
 126 set dest [target_info name]
 127 if [board_info $dest exists multilib_flags] {
 128         set multilib_flags [board_info $dest multilib_flags]
 129         if { "${multilib_flags}" != "" } {
 130            gdb_suppress_entire_file "Assembly source test -- multilibs not supported by this test."
 131            return;
 132          }
 133 }
 134
 135 set testfile "asm-source"
 136 set binfile ${objdir}/${subdir}/${testfile}
 137 set srcfile1 asmsrc1.s
 138 set srcfile2 asmsrc2.s
 139
 140 remote_exec build "rm -f ${subdir}/arch.inc"
 141 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 142
 143 if { "${asm-flags}" == "" } {
 144     #set asm-flags "-Wa,-gstabs,-I${srcdir}/${subdir},-I${objdir}/${subdir}"
 145     set asm-flags "-gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 146 }
 147
 148 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags}"] != ""} then {
 149      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 150 }
 151 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags}"] != ""} then {
 152      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 153 }
 154
 155 set opts "debug ldflags=-nostartfiles"
 156 foreach i ${link-flags} {
 157     append opts " ldflags=$i"
 158 }
 159 if { [gdb_compile "asmsrc1.o asmsrc2.o" "${binfile}" executable $opts] != "" } {
 160      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 161 }
 162
 163 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 164
 165
 166 gdb_start
 167 gdb_reinitialize_dir $srcdir/$subdir
 168 gdb_load ${binfile}
 169
 170 #
 171 # Run to `main' where we begin our tests.
 172 #
 173
 174 if ![runto_main] then {
 175     gdb_suppress_tests
 176 }
 177
 178 # Execute the `f' command and see if the result includes source info.
 179 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 180
 181 # See if we properly `next' over a macro with several insns.
 182 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 183
 184 # See if we can properly `step' into a subroutine call.
 185 gdb_test "s" "8\[       \]*.*" "step into foo2"
 186
 187 # Test 'info target', and incidentally capture the entry point address.
 188 set entry_point 0
 189 send_gdb "info target\n"
 190 gdb_expect {
 191     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 192         set entry_point $expect_out(1,string)
 193         pass "info target"
 194     }
 195     -re ".*$gdb_prompt $" {
 196         fail "info target"
 197     }
 198     timeout {
 199         fail "info target (timeout)"
 200     }
 201 }
 202
 203 # Capture the start symbol (may be '_start' or 'start')
 204 set entry_symbol ""
 205 send_gdb "info symbol 0x$entry_point\n"
 206 gdb_expect {
 207     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 208         # We match the echoed `info symbol' command here, to help us
 209         # reliably identify the beginning of the start symbol in the
 210         # command's output.  You might think we could just use '^' to
 211         # start matching at the beginning of the line, but
 212         # unfortunately, in Expect, '^' matches the beginning of the
 213         # input that hasn't been matched by any expect clause yet.  If
 214         # every expect clause consumes a complete line, along with its
 215         # terminating CR/LF, this is equivalent to the beginning of a
 216         # line.  But expect clauses that end with `.*' will consume as
 217         # much as happened to arrive from the TTY --- exactly where
 218         # they leave you depends on inter-process timing.  :(
 219         set entry_symbol $expect_out(1,string)
 220         pass "info symbol"
 221     }
 222     -re ".*$gdb_prompt $" {
 223         fail "info symbol"
 224     }
 225     timeout {
 226         fail "info symbol (timeout)"
 227     }
 228 }
 229
 230 # Now try a 'list' from the other source file.
 231 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 232
 233 # Now try a source file search
 234 gdb_test "search A routine for foo2 to call" \
 235         "40\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 236
 237 # See if `f' prints the right source file.
 238 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 239
 240 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 241 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 242
 243 # See if a simple `bt' prints the right source files and
 244 # doesn't fall off the stack.
 245
 246 gdb_test "bt 10" \
 247         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33" \
 248         "bt ALL in foo2"
 249
 250 # See if a capped `bt' prints the right source files.
 251 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 252
 253 # Step into another subroutine which lives back in the first source file.
 254 gdb_test "s" "" "s 2"
 255
 256 # Next over insns to set up the stack frame.
 257 gdb_test "n" "" "n 2"
 258
 259 # Now see if a capped `bt' is correct.
 260 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:45.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 261
 262 # Try 'info source' from asmsrc1.s
 263 gdb_test "info source" \
 264         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 265         "info source asmsrc1.s"
 266
 267 # Try 'finishing' from foo3
 268 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 269         "finish from foo3"
 270
 271 # Try 'info source' from asmsrc2.s
 272 gdb_test "info source" \
 273         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 274         "info source asmsrc2.s"
 275
 276 # Try 'info sources'.  This can produce a lot of output on systems
 277 # with dynamic linking, where the system's shared libc was compiled
 278 # with debugging info; for example, on Linux, this produces 47kb of
 279 # output.  So we consume it as we go.
 280 send_gdb "info sources\n"
 281 set seen_asmsrc_1 0
 282 set seen_asmsrc_2 0
 283 gdb_expect {
 284     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 285         set seen_asmsrc_1 1
 286         exp_continue
 287     }
 288     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 289         set seen_asmsrc_2 1
 290         exp_continue
 291     }
 292     -re ", " {
 293         exp_continue
 294     }
 295     -re "$gdb_prompt $" {
 296         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 297             pass "info sources"
 298         } else {
 299             fail "info sources"
 300         }
 301     }
 302     timeout {
 303             fail "info sources (timeout)"
 304     }
 305 }
 306
 307
 308 # Try 'info line'
 309 gdb_test "info line" \
 310         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 311         "info line"
 312
 313 # Try 'nexting' over next call to foo3
 314 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 315
 316 # Try 'return' from foo2
 317 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 318         "Make (foo2|selected stack frame) return now\?.*" "y"
 319
 320 # Disassemble something, check the output
 321 proc test_dis { command var } {
 322     global gdb_prompt
 323     send_gdb "${command}\n"
 324     gdb_expect {
 325         -re "${var}.*:.*(Cannot access|Bad address)" {
 326             # The "disassembler" was only accessing the local
 327             # executable and that would cause attempts to disassemble
 328             # variables to fail (memory not valid).
 329             fail "${command} (memory read error)"
 330         }
 331         -re "${var}.*:.*${gdb_prompt}" {
 332             pass "${command}"
 333         }
 334         timeout {
 335             fail "${command} (timeout)"
 336         }
 337     }
 338 }
 339
 340 # See if we can look at a global variable, three ways
 341 gdb_test "print globalvar" ".* = 11" "look at global variable"
 342 test_dis "x/i &globalvar" "globalvar"
 343 test_dis "disassem &globalvar &globalvar+1" "globalvar"
 344
 345 # See if we can look at a static variable, three ways
 346 gdb_test "print staticvar" ".* = 5" "look at static variable"
 347 test_dis "x/i &staticvar" "staticvar"
 348 test_dis "disassem &staticvar &staticvar+1" "staticvar"
 349
 350 # See if we can look at a static function
 351 gdb_test "disassem foostatic" ".*<foostatic\\+0>:.*End of assembler dump." \
 352         "look at static function"
 353
 354 remote_exec build "rm -f ${subdir}/arch.inc"