gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-note "empty"
  36 set asm-flags ""
  37 set link-flags "-e _start"
  38 set debug-flags ""
  39
  40 switch -glob -- [istarget] {
  41     "alpha*-*-*" {
  42         set asm-arch alpha
  43         # ??? Won't work with ecoff systems like Tru64, but then we also
  44         # don't have any other -g flag that creates mdebug output.
  45         set asm-flags "-no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  46         set debug-flags "-gdwarf-2"
  47     }
  48     "*arm-*-*" {
  49         set asm-arch arm
  50     }
  51     "xscale-*-*" {
  52         set asm-arch arm
  53     }
  54     "d10v-*-*" {
  55         set asm-arch d10v
  56     }
  57     "frv-*-*" {
  58         set asm-arch frv
  59     }
  60     "s390-*-*" {
  61         set asm-arch s390
  62     }
  63     "s390x-*-*" {
  64         set asm-arch s390x
  65     }
  66     "x86_64-*-*" {
  67         set asm-arch x86_64
  68         set debug-flags "-gdwarf-2"
  69     }
  70     "i\[3456\]86-*-*" {
  71         set asm-arch i386
  72     }
  73     "m32r*-linux*" {
  74         set asm-arch m32r-linux
  75     }
  76     "m32c-*-*" {
  77         set asm-arch m32c
  78     }
  79     "m32r*-*" {
  80         set asm-arch m32r
  81         append link-flags "--whole-archive -lgloss --no-whole-archive"
  82     }
  83     "m6811-*-*" {
  84         set asm-arch m68hc11
  85         set asm-flags "-mshort-double -m68hc11 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  86         set debug-flags "-gdwarf-2"
  87         # This asm test is specific and uses the linker directly.
  88         # We must not use the target board linker script defined for other
  89         # tests.  Remove it and restore it later on.
  90         set board [target_info name]
  91         set old_ldscript [board_info $board ldscript]
  92         unset_board_info "ldscript"
  93     }
  94     "m6812-*-*" {
  95         set asm-arch m68hc11
  96         set asm-flags "-mshort-double -m68hc12 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  97         set debug-flags "-gdwarf-2"
  98         # This asm test is specific and uses the linker directly.
  99         # We must not use the target board linker script defined for other
 100         # tests.  Remove it and restore it later on.
 101         set board [target_info name]
 102         set old_ldscript [board_info $board ldscript]
 103         set_board_info ldscript ""
 104     }
 105     "mips*-*" {
 106         set asm-arch mips
 107     }
 108     "powerpc*-*" {
 109         set asm-arch powerpc
 110     }
 111     "sh*-*-*" {
 112         set asm-arch sh
 113         set debug-flags "-gdwarf-2"
 114     }
 115     "sparc-*-*" {
 116         set asm-arch sparc
 117     }
 118     "sparc64-*-*" {
 119         set asm-arch sparc64
 120         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 121         set debug-flags "-gdwarf-2"
 122     }
 123     "xstormy16-*-*" {
 124         set asm-arch xstormy16
 125         set debug-flags "-gdwarf-2"
 126     }
 127     "v850-*-*" {
 128         set asm-arch v850
 129         set gdb_wrapper_initialized 1
 130     }
 131     "m68k-*-*" {
 132         set asm-arch m68k
 133     }
 134     "ia64-*-*" {
 135         set asm-arch ia64
 136         set debug-flags "-gdwarf-2"
 137     }
 138     "iq2000-*-*" {
 139         set asm-arch iq2000
 140     }
 141     "hppa*-linux-*" {
 142         set asm-arch pa
 143         set debug-flags "-gdwarf-2"
 144     }
 145     "hppa-*-openbsd*" {
 146         set asm-arch pa
 147         set debug-flags "-gdwarf-2"
 148     }
 149     "hppa64-*-hpux*" {
 150         set asm-arch pa64
 151         set debug-flags "-gdwarf-2"
 152     }
 153     "h83*-*" {
 154         set asm-arch h8300
 155         set debug-flags "-gdwarf-2"
 156     }
 157 }
 158
 159 if { "${asm-arch}" == "" } {
 160     gdb_suppress_entire_file "Assembly source test -- not implemented for this target."
 161 }
 162
 163 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 164 if { [istarget "*-*-netbsdelf*"]
 165      || [istarget "mips*-*-netbsd*"]
 166      || [istarget "powerpc-*-netbsd*"]
 167      || [istarget "x86_64-*-netbsd*"] } then {
 168     set asm-note "netbsd"
 169 }
 170
 171 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 172 # of handing a.out here since most OpenBSD/a.out systems use a rather
 173 # outdated assembler that doesn't assemble this test's code anyway.
 174 if { [istarget "*-*-openbsd*"] } then {
 175     set asm-note "openbsd"
 176 }
 177
 178 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 179 # switches according to compiler syntax.  If we pass these options straight
 180 # to the assembler, they won't always make sense.  If we don't pass them to
 181 # the assembler, the final link will complain that the object files were
 182 # built with different defaults.  So no matter what we do, we lose.  We may as
 183 # well get out of this test sooner rather than later.
 184 set dest [target_info name]
 185 if [board_info $dest exists multilib_flags] {
 186         set multilib_flags [board_info $dest multilib_flags]
 187         if { "${multilib_flags}" != "" } {
 188            gdb_suppress_entire_file "Assembly source test -- multilibs not supported by this test."
 189            return;
 190          }
 191 }
 192
 193 set testfile "asm-source"
 194 set binfile ${objdir}/${subdir}/${testfile}
 195 set srcfile1 asmsrc1.s
 196 set srcfile2 asmsrc2.s
 197
 198 remote_exec build "rm -f ${subdir}/arch.inc"
 199 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 200 remote_exec build "rm -f ${subdir}/note.inc"
 201 remote_download host ${srcdir}/${subdir}/${asm-note}.inc ${subdir}/note.inc
 202
 203 if { [string equal ${asm-flags} ""] } {
 204     set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 205 }
 206
 207 if { [string equal ${debug-flags} ""] } {
 208     set debug-flags "-gstabs"
 209 }
 210
 211 # Allow the target board to override the debug flags.
 212 if { [board_info $dest exists debug_flags] } then {
 213     set debug-flags "[board_info $dest debug_flags]"
 214 }
 215
 216 # The debug flags are in the format that gcc expects:
 217 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 218 # other languages in the test suite, we accept this input format.
 219 # So the user can run the test suite with:
 220 #
 221 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 222 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 223 #
 224 # However, the GNU assembler has different spellings than gcc.
 225 # So I adjust the debug flags here.
 226
 227 # The GNU assembler spells "dwarf-2" as "dwarf2".
 228 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 229
 230 # The GNU assembler before 2.15 did not support "stabs+".
 231 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 232
 233 # The GNU assembler does not support level options like "-g2" or "-g3".
 234 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 235
 236 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags} ${debug-flags}"] != ""} then {
 237      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 238 }
 239 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags} ${debug-flags}"] != ""} then {
 240      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 241 }
 242
 243 # We deliberately don't use gdb_compile here to link together the
 244 # assembled object files.  Using gdb_compile, and therefore the C
 245 # compiler, is conceptually wrong, since we're testing raw assembler
 246 # code here that provides its own startup code.  Using target_link
 247 # also avoids a lot of problems on many systems, most notably on
 248 # *-*-*bsd* and *-*-solaris2*.
 249 if {[target_link "asmsrc1.o asmsrc2.o" "${binfile}" ${link-flags}] != "" } then {
 250      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 251 }
 252
 253 # Restore the target board linker script for HC11/HC12.
 254 if { [istarget "m6811-*-*"] || [istarget "m6812-*-*"] } {
 255     set_board_info ldscript $old_ldscript
 256 }
 257
 258 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 259
 260
 261 gdb_start
 262 gdb_reinitialize_dir $srcdir/$subdir
 263 gdb_load ${binfile}
 264
 265 #
 266 # Run to `main' where we begin our tests.
 267 #
 268
 269 if ![runto_main] then {
 270     gdb_suppress_tests
 271 }
 272
 273 # Execute the `f' command and see if the result includes source info.
 274 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 275
 276 # See if we properly `next' over a macro with several insns.
 277 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 278
 279 # See if we can properly `step' into a subroutine call.
 280 gdb_test "s" "8\[       \]*.*" "step into foo2"
 281
 282 # Test 'info target', and incidentally capture the entry point address.
 283 set entry_point 0
 284 send_gdb "info target\n"
 285 gdb_expect {
 286     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 287         set entry_point $expect_out(1,string)
 288         pass "info target"
 289     }
 290     -re ".*$gdb_prompt $" {
 291         fail "info target"
 292     }
 293     timeout {
 294         fail "info target (timeout)"
 295     }
 296 }
 297
 298 # Capture the start symbol (may be '_start' or 'start')
 299 set entry_symbol ""
 300 send_gdb "info symbol 0x$entry_point\n"
 301 gdb_expect {
 302     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 303         # We match the echoed `info symbol' command here, to help us
 304         # reliably identify the beginning of the start symbol in the
 305         # command's output.  You might think we could just use '^' to
 306         # start matching at the beginning of the line, but
 307         # unfortunately, in Expect, '^' matches the beginning of the
 308         # input that hasn't been matched by any expect clause yet.  If
 309         # every expect clause consumes a complete line, along with its
 310         # terminating CR/LF, this is equivalent to the beginning of a
 311         # line.  But expect clauses that end with `.*' will consume as
 312         # much as happened to arrive from the TTY --- exactly where
 313         # they leave you depends on inter-process timing.  :(
 314         set entry_symbol $expect_out(1,string)
 315         pass "info symbol"
 316     }
 317     -re ".*$gdb_prompt $" {
 318         fail "info symbol"
 319     }
 320     timeout {
 321         fail "info symbol (timeout)"
 322     }
 323 }
 324
 325 # Now try a 'list' from the other source file.
 326 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 327
 328 # Now try a source file search
 329 gdb_test "search A routine for foo2 to call" \
 330         "40\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 331
 332 # See if `f' prints the right source file.
 333 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 334
 335 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 336 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 337
 338 # See if a simple `bt' prints the right source files and
 339 # doesn't fall off the stack.
 340
 341 gdb_test "bt 10" \
 342         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33" \
 343         "bt ALL in foo2"
 344
 345 # See if a capped `bt' prints the right source files.
 346 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 347
 348 # Step into another subroutine which lives back in the first source file.
 349 gdb_test "s" "" "s 2"
 350
 351 # Next over insns to set up the stack frame.
 352 gdb_test "n" "" "n 2"
 353
 354 # Now see if a capped `bt' is correct.
 355 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:45.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 356
 357 # Try 'info source' from asmsrc1.s
 358 gdb_test "info source" \
 359         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 360         "info source asmsrc1.s"
 361
 362 # Try 'finishing' from foo3
 363 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 364         "finish from foo3"
 365
 366 # Try 'info source' from asmsrc2.s
 367 gdb_test "info source" \
 368         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 369         "info source asmsrc2.s"
 370
 371 # Try 'info sources'.  This can produce a lot of output on systems
 372 # with dynamic linking, where the system's shared libc was compiled
 373 # with debugging info; for example, on Linux, this produces 47kb of
 374 # output.  So we consume it as we go.
 375 send_gdb "info sources\n"
 376 set seen_asmsrc_1 0
 377 set seen_asmsrc_2 0
 378 gdb_expect {
 379     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 380         set seen_asmsrc_1 1
 381         exp_continue
 382     }
 383     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 384         set seen_asmsrc_2 1
 385         exp_continue
 386     }
 387     -re ", " {
 388         exp_continue
 389     }
 390     -re "$gdb_prompt $" {
 391         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 392             pass "info sources"
 393         } else {
 394             fail "info sources"
 395         }
 396     }
 397     timeout {
 398             fail "info sources (timeout)"
 399     }
 400 }
 401
 402
 403 # Try 'info line'
 404 gdb_test "info line" \
 405         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 406         "info line"
 407
 408 # Try 'nexting' over next call to foo3
 409 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 410
 411 # Try 'return' from foo2
 412 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 413         "Make (foo2|selected stack frame) return now\?.*" "y"
 414
 415 # Disassemble something, check the output
 416 proc test_dis { command var } {
 417     global gdb_prompt
 418     send_gdb "${command}\n"
 419     gdb_expect {
 420         -re "${var}.*:.*(Cannot access|Bad address)" {
 421             # The "disassembler" was only accessing the local
 422             # executable and that would cause attempts to disassemble
 423             # variables to fail (memory not valid).
 424             fail "${command} (memory read error)"
 425         }
 426         -re "${var}.*:.*${gdb_prompt}" {
 427             pass "${command}"
 428         }
 429         timeout {
 430             fail "${command} (timeout)"
 431         }
 432     }
 433 }
 434
 435 # See if we can look at a global variable, three ways
 436 gdb_test "print globalvar" ".* = 11" "look at global variable"
 437 test_dis "x/i &globalvar" "globalvar"
 438 test_dis "disassem &globalvar &globalvar+1" "globalvar"
 439
 440 # See if we can look at a static variable, three ways
 441 gdb_test "print staticvar" ".* = 5" "look at static variable"
 442 test_dis "x/i &staticvar" "staticvar"
 443 test_dis "disassem &staticvar &staticvar+1" "staticvar"
 444
 445 # See if we can look at a static function
 446 gdb_test "disassem foostatic" ".*<foostatic\\+0>:.*End of assembler dump." \
 447         "look at static function"
 448
 449 remote_exec build "rm -f ${subdir}/arch.inc"
 450 remote_exec build "rm -f ${subdir}/note.inc"