gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-flags ""
  36 set link-flags ""
  37
  38 switch -glob -- [istarget] {
  39     "alpha*-*-*" {
  40         set asm-arch alpha
  41         # ??? Won't work with ecoff systems like Tru64, but then we also
  42         # don't have any other -g flag that creates mdebug output.
  43         set asm-flags "-gdwarf2 -no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  44     }
  45     "*arm-*-*" {
  46         set asm-arch arm
  47     }
  48     "xscale-*-*" {
  49         set asm-arch arm
  50     }
  51     "d10v-*-*" {
  52         set asm-arch d10v
  53     }
  54     "s390-*-*" {
  55         set asm-arch s390
  56     }
  57     "s390x-*-*" {
  58         set asm-arch s390x
  59     }
  60     "x86_64-*-*" {
  61         set asm-arch x86_64
  62         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  63     }
  64     "i\[3456\]86-*-*" {
  65         set asm-arch i386
  66         if [istarget "*-*-cygwin*"] then {
  67             set link-flags "--entry _start"
  68         }
  69     }
  70     "m32r*-*" {
  71         set asm-arch m32r
  72         set link-flags "-Wl,--whole-archive -lgloss -Wl,--no-whole-archive"
  73     }
  74     "m6811-*-*" {
  75         set asm-arch m68hc11
  76         set asm-flags "-mshort-double -m68hc11 -gdwarf2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  77     }
  78     "m6812-*-*" {
  79         set asm-arch m68hc11
  80         set asm-flags "-mshort-double -m68hc12 -gdwarf2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  81     }
  82     "mips*-*" {
  83         set asm-arch mips
  84     }
  85     "powerpc*-*" {
  86         set asm-arch powerpc
  87     }
  88     "sparc-*-*" {
  89         set asm-arch sparc
  90     }
  91     "sparc64-*-*" {
  92         set asm-arch sparc64
  93         set asm-flags "-xarch=v9 -gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  94     }
  95     "xstormy16-*-*" {
  96         set asm-arch xstormy16
  97         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  98     }
  99     "v850-*-*" {
 100         set asm-arch v850
 101         set gdb_wrapper_initialized 1
 102     }
 103     "m68k-*-*" {
 104         set asm-arch m68k
 105     }
 106     "ia64-*-*" {
 107         set asm-arch ia64
 108         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 109     }
 110 }
 111
 112 if { "${asm-arch}" == "" } {
 113     gdb_suppress_entire_file "Assembly source test -- not implemented for this target."
 114 }
 115
 116 # On FreeBSD, crt1.o the final link will fail because of unresolved
 117 # symbols.  It turns out that libc.so references symbols that are
 118 # normally provided by crt1.o, which isn't linked in since we specify
 119 # -nostartfiles.  Using -nostdlib doesn't help since target_compile
 120 # automatically adds -lm.  Linking statically avoids this mess.
 121 if [istarget "*-*-freebsd*"] then {
 122     set link-flags "-static"
 123 }
 124
 125 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 126 # switches according to compiler syntax.  If we pass these options straight
 127 # to the assembler, they won't always make sense.  If we don't pass them to
 128 # the assembler, the final link will complain that the object files were
 129 # built with different defaults.  So no matter what we do, we lose.  We may as
 130 # well get out of this test sooner rather than later.
 131 set dest [target_info name]
 132 if [board_info $dest exists multilib_flags] {
 133         set multilib_flags [board_info $dest multilib_flags]
 134         if { "${multilib_flags}" != "" } {
 135            gdb_suppress_entire_file "Assembly source test -- multilibs not supported by this test."
 136            return;
 137          }
 138 }
 139
 140 set testfile "asm-source"
 141 set binfile ${objdir}/${subdir}/${testfile}
 142 set srcfile1 asmsrc1.s
 143 set srcfile2 asmsrc2.s
 144
 145 remote_exec build "rm -f ${subdir}/arch.inc"
 146 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 147
 148 if { "${asm-flags}" == "" } {
 149     #set asm-flags "-Wa,-gstabs,-I${srcdir}/${subdir},-I${objdir}/${subdir}"
 150     set asm-flags "-gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 151 }
 152
 153 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags}"] != ""} then {
 154      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 155 }
 156 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags}"] != ""} then {
 157      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 158 }
 159
 160 set opts "debug ldflags=-nostartfiles"
 161 foreach i ${link-flags} {
 162     append opts " ldflags=$i"
 163 }
 164 if { [gdb_compile "asmsrc1.o asmsrc2.o" "${binfile}" executable $opts] != "" } {
 165      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 166 }
 167
 168 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 169
 170
 171 gdb_start
 172 gdb_reinitialize_dir $srcdir/$subdir
 173 gdb_load ${binfile}
 174
 175 #
 176 # Run to `main' where we begin our tests.
 177 #
 178
 179 if ![runto_main] then {
 180     gdb_suppress_tests
 181 }
 182
 183 # Execute the `f' command and see if the result includes source info.
 184 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 185
 186 # See if we properly `next' over a macro with several insns.
 187 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 188
 189 # See if we can properly `step' into a subroutine call.
 190 gdb_test "s" "8\[       \]*.*" "step into foo2"
 191
 192 # Test 'info target', and incidentally capture the entry point address.
 193 set entry_point 0
 194 send_gdb "info target\n"
 195 gdb_expect {
 196     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 197         set entry_point $expect_out(1,string)
 198         pass "info target"
 199     }
 200     -re ".*$gdb_prompt $" {
 201         fail "info target"
 202     }
 203     timeout {
 204         fail "info target (timeout)"
 205     }
 206 }
 207
 208 # Capture the start symbol (may be '_start' or 'start')
 209 set entry_symbol ""
 210 send_gdb "info symbol 0x$entry_point\n"
 211 gdb_expect {
 212     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 213         # We match the echoed `info symbol' command here, to help us
 214         # reliably identify the beginning of the start symbol in the
 215         # command's output.  You might think we could just use '^' to
 216         # start matching at the beginning of the line, but
 217         # unfortunately, in Expect, '^' matches the beginning of the
 218         # input that hasn't been matched by any expect clause yet.  If
 219         # every expect clause consumes a complete line, along with its
 220         # terminating CR/LF, this is equivalent to the beginning of a
 221         # line.  But expect clauses that end with `.*' will consume as
 222         # much as happened to arrive from the TTY --- exactly where
 223         # they leave you depends on inter-process timing.  :(
 224         set entry_symbol $expect_out(1,string)
 225         pass "info symbol"
 226     }
 227     -re ".*$gdb_prompt $" {
 228         fail "info symbol"
 229     }
 230     timeout {
 231         fail "info symbol (timeout)"
 232     }
 233 }
 234
 235 # Now try a 'list' from the other source file.
 236 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 237
 238 # Now try a source file search
 239 gdb_test "search A routine for foo2 to call" \
 240         "40\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 241
 242 # See if `f' prints the right source file.
 243 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 244
 245 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 246 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 247
 248 # See if a simple `bt' prints the right source files and
 249 # doesn't fall off the stack.
 250
 251 gdb_test "bt 10" \
 252         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33" \
 253         "bt ALL in foo2"
 254
 255 # See if a capped `bt' prints the right source files.
 256 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 257
 258 # Step into another subroutine which lives back in the first source file.
 259 gdb_test "s" "" "s 2"
 260
 261 # Next over insns to set up the stack frame.
 262 gdb_test "n" "" "n 2"
 263
 264 # Now see if a capped `bt' is correct.
 265 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:45.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 266
 267 # Try 'info source' from asmsrc1.s
 268 gdb_test "info source" \
 269         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 270         "info source asmsrc1.s"
 271
 272 # Try 'finishing' from foo3
 273 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 274         "finish from foo3"
 275
 276 # Try 'info source' from asmsrc2.s
 277 gdb_test "info source" \
 278         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 279         "info source asmsrc2.s"
 280
 281 # Try 'info sources'.  This can produce a lot of output on systems
 282 # with dynamic linking, where the system's shared libc was compiled
 283 # with debugging info; for example, on Linux, this produces 47kb of
 284 # output.  So we consume it as we go.
 285 send_gdb "info sources\n"
 286 set seen_asmsrc_1 0
 287 set seen_asmsrc_2 0
 288 gdb_expect {
 289     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 290         set seen_asmsrc_1 1
 291         exp_continue
 292     }
 293     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 294         set seen_asmsrc_2 1
 295         exp_continue
 296     }
 297     -re ", " {
 298         exp_continue
 299     }
 300     -re "$gdb_prompt $" {
 301         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 302             pass "info sources"
 303         } else {
 304             fail "info sources"
 305         }
 306     }
 307     timeout {
 308             fail "info sources (timeout)"
 309     }
 310 }
 311
 312
 313 # Try 'info line'
 314 gdb_test "info line" \
 315         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 316         "info line"
 317
 318 # Try 'nexting' over next call to foo3
 319 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 320
 321 # Try 'return' from foo2
 322 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 323         "Make (foo2|selected stack frame) return now\?.*" "y"
 324
 325 # Disassemble something, check the output
 326 proc test_dis { command var } {
 327     global gdb_prompt
 328     send_gdb "${command}\n"
 329     gdb_expect {
 330         -re "${var}.*:.*(Cannot access|Bad address)" {
 331             # The "disassembler" was only accessing the local
 332             # executable and that would cause attempts to disassemble
 333             # variables to fail (memory not valid).
 334             fail "${command} (memory read error)"
 335         }
 336         -re "${var}.*:.*${gdb_prompt}" {
 337             pass "${command}"
 338         }
 339         timeout {
 340             fail "${command} (timeout)"
 341         }
 342     }
 343 }
 344
 345 # See if we can look at a global variable, three ways
 346 gdb_test "print globalvar" ".* = 11" "look at global variable"
 347 test_dis "x/i &globalvar" "globalvar"
 348 test_dis "disassem &globalvar &globalvar+1" "globalvar"
 349
 350 # See if we can look at a static variable, three ways
 351 gdb_test "print staticvar" ".* = 5" "look at static variable"
 352 test_dis "x/i &staticvar" "staticvar"
 353 test_dis "disassem &staticvar &staticvar+1" "staticvar"
 354
 355 # See if we can look at a static function
 356 gdb_test "disassem foostatic" ".*<foostatic\\+0>:.*End of assembler dump." \
 357         "look at static function"
 358
 359 remote_exec build "rm -f ${subdir}/arch.inc"