gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-flags ""
  36 set link-flags ""
  37
  38 switch -glob -- [istarget] {
  39     "alpha*-*-*" {
  40         set asm-arch alpha
  41         # ??? Won't work with ecoff systems like Tru64, but then we also
  42         # don't have any other -g flag that creates mdebug output.
  43         set asm-flags "-gdwarf2 -no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  44     }
  45     "*arm-*-*" {
  46         set asm-arch arm
  47     }
  48     "xscale-*-*" {
  49         set asm-arch arm
  50     }
  51     "d10v-*-*" {
  52         set asm-arch d10v
  53     }
  54     "s390-*-*" {
  55         set asm-arch s390
  56     }
  57     "s390x-*-*" {
  58         set asm-arch s390x
  59     }
  60     "x86_64-*-*" {
  61         set asm-arch x86_64
  62         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  63     }
  64     "i\[3456\]86-*-*" {
  65         set asm-arch i386
  66         if [istarget "*-*-cygwin*"] then {
  67             set link-flags "--entry _start"
  68         }
  69     }
  70     "m32r*-*" {
  71         set asm-arch m32r
  72     }
  73     "m6811-*-*" {
  74         set asm-arch m68hc11
  75         set asm-flags "-mshort-double -m68hc11 -gdwarf2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  76     }
  77     "m6812-*-*" {
  78         set asm-arch m68hc11
  79         set asm-flags "-mshort-double -m68hc12 -gdwarf2 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  80     }
  81     "mips*-*" {
  82         set asm-arch mips
  83     }
  84     "powerpc*-*" {
  85         set asm-arch powerpc
  86     }
  87     "sparc-*-*" {
  88         set asm-arch sparc
  89     }
  90     "sparc64-*-*" {
  91         set asm-arch sparc64
  92         set asm-flags "-xarch=v9 -gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  93     }
  94     "xstormy16-*-*" {
  95         set asm-arch xstormy16
  96         set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  97     }
  98     "v850-*-*" {
  99         set asm-arch v850
 100         set gdb_wrapper_initialized 1
 101     }
 102 }
 103
 104 if { "${asm-arch}" == "" } {
 105     gdb_suppress_entire_file "Assembly source test -- not implemented for this target."
 106 }
 107
 108 # On FreeBSD, crt1.o the final link will fail because of unresolved
 109 # symbols.  It turns out that libc.so references symbols that are
 110 # normally provided by crt1.o, which isn't linked in since we specify
 111 # -nostartfiles.  Using -nostdlib doesn't help since target_compile
 112 # automatically adds -lm.  Linking statically avoids this mess.
 113 if [istarget "*-*-freebsd*"] then {
 114     set link-flags "-static"
 115 }
 116
 117 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 118 # switches according to compiler syntax.  If we pass these options straight
 119 # to the assembler, they won't always make sense.  If we don't pass them to
 120 # the assembler, the final link will complain that the object files were
 121 # built with different defaults.  So no matter what we do, we lose.  We may as
 122 # well get out of this test sooner rather than later.
 123 set dest [target_info name]
 124 if [board_info $dest exists multilib_flags] {
 125         set multilib_flags [board_info $dest multilib_flags]
 126         if { "${multilib_flags}" != "" } {
 127            gdb_suppress_entire_file "Assembly source test -- multilibs not supported by this test."
 128            return;
 129          }
 130 }
 131
 132 set testfile "asm-source"
 133 set binfile ${objdir}/${subdir}/${testfile}
 134 set srcfile1 asmsrc1.s
 135 set srcfile2 asmsrc2.s
 136
 137 remote_exec build "rm -f ${subdir}/arch.inc"
 138 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 139
 140 if { "${asm-flags}" == "" } {
 141     #set asm-flags "-Wa,-gstabs,-I${srcdir}/${subdir},-I${objdir}/${subdir}"
 142     set asm-flags "-gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 143 }
 144
 145 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags}"] != ""} then {
 146      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 147 }
 148 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags}"] != ""} then {
 149      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 150 }
 151
 152 set opts "debug ldflags=-nostartfiles"
 153 foreach i ${link-flags} {
 154     append opts " ldflags=$i"
 155 }
 156 if { [gdb_compile "asmsrc1.o asmsrc2.o" "${binfile}" executable $opts] != "" } {
 157      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 158 }
 159
 160 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 161
 162
 163 gdb_start
 164 gdb_reinitialize_dir $srcdir/$subdir
 165 gdb_load ${binfile}
 166
 167 #
 168 # Run to `main' where we begin our tests.
 169 #
 170
 171 if ![runto_main] then {
 172     gdb_suppress_tests
 173 }
 174
 175 # Execute the `f' command and see if the result includes source info.
 176 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 177
 178 # See if we properly `next' over a macro with several insns.
 179 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 180
 181 # See if we can properly `step' into a subroutine call.
 182 gdb_test "s" "8\[       \]*.*" "step into foo2"
 183
 184 # Test 'info target', and incidentally capture the entry point address.
 185 set entry_point 0
 186 send_gdb "info target\n"
 187 gdb_expect {
 188     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 189         set entry_point $expect_out(1,string)
 190         pass "info target"
 191     }
 192     -re ".*$gdb_prompt $" {
 193         fail "info target"
 194     }
 195     timeout {
 196         fail "info target (timeout)"
 197     }
 198 }
 199
 200 # Capture the start symbol (may be '_start' or 'start')
 201 set entry_symbol ""
 202 send_gdb "info symbol 0x$entry_point\n"
 203 gdb_expect {
 204     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 205         # We match the echoed `info symbol' command here, to help us
 206         # reliably identify the beginning of the start symbol in the
 207         # command's output.  You might think we could just use '^' to
 208         # start matching at the beginning of the line, but
 209         # unfortunately, in Expect, '^' matches the beginning of the
 210         # input that hasn't been matched by any expect clause yet.  If
 211         # every expect clause consumes a complete line, along with its
 212         # terminating CR/LF, this is equivalent to the beginning of a
 213         # line.  But expect clauses that end with `.*' will consume as
 214         # much as happened to arrive from the TTY --- exactly where
 215         # they leave you depends on inter-process timing.  :(
 216         set entry_symbol $expect_out(1,string)
 217         pass "info symbol"
 218     }
 219     -re ".*$gdb_prompt $" {
 220         fail "info symbol"
 221     }
 222     timeout {
 223         fail "info symbol (timeout)"
 224     }
 225 }
 226
 227 # Now try a 'list' from the other source file.
 228 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 229
 230 # Now try a source file search
 231 gdb_test "search A routine for foo2 to call" \
 232         "40\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 233
 234 # See if `f' prints the right source file.
 235 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 236
 237 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 238 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 239
 240 # See if a simple `bt' prints the right source files and
 241 # doesn't fall off the stack.
 242
 243 gdb_test "bt 10" \
 244         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33(.*\#2.*start\[^\r\n\]*)?" \
 245         "bt ALL in foo2"
 246
 247 # See if a capped `bt' prints the right source files.
 248 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 249
 250 # Step into another subroutine which lives back in the first source file.
 251 gdb_test "s" "" "s 2"
 252
 253 # Next over insns to set up the stack frame.
 254 gdb_test "n" "" "n 2"
 255
 256 # Now see if a capped `bt' is correct.
 257 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:45.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 258
 259 # Try 'info source' from asmsrc1.s
 260 gdb_test "info source" \
 261         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 262         "info source asmsrc1.s"
 263
 264 # Try 'finishing' from foo3
 265 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 266         "finish from foo3"
 267
 268 # Try 'info source' from asmsrc2.s
 269 gdb_test "info source" \
 270         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 271         "info source asmsrc2.s"
 272
 273 # Try 'info sources'.  This can produce a lot of output on systems
 274 # with dynamic linking, where the system's shared libc was compiled
 275 # with debugging info; for example, on Linux, this produces 47kb of
 276 # output.  So we consume it as we go.
 277 send_gdb "info sources\n"
 278 set seen_asmsrc_1 0
 279 set seen_asmsrc_2 0
 280 gdb_expect {
 281     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 282         set seen_asmsrc_1 1
 283         exp_continue
 284     }
 285     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 286         set seen_asmsrc_2 1
 287         exp_continue
 288     }
 289     -re ", " {
 290         exp_continue
 291     }
 292     -re "$gdb_prompt $" {
 293         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 294             pass "info sources"
 295         } else {
 296             fail "info sources"
 297         }
 298     }
 299     timeout {
 300             fail "info sources (timeout)"
 301     }
 302 }
 303
 304
 305 # Try 'info line'
 306 gdb_test "info line" \
 307         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 308         "info line"
 309
 310 # Try 'nexting' over next call to foo3
 311 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 312
 313 # Try 'return' from foo2
 314 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 315         "Make (foo2|selected stack frame) return now\?.*" "y"
 316
 317 # Disassemble something, check the output
 318 proc test_dis { command var } {
 319     global gdb_prompt
 320     send_gdb "${command}\n"
 321     gdb_expect {
 322         -re "${var}.*:.*(Cannot access|Bad address)" {
 323             # The "disassembler" was only accessing the local
 324             # executable and that would cause attempts to disassemble
 325             # variables to fail (memory not valid).
 326             fail "${command} (memory read error)"
 327         }
 328         -re "${var}.*:.*${gdb_prompt}" {
 329             pass "${command}"
 330         }
 331         timeout {
 332             fail "${command} (timeout)"
 333         }
 334     }
 335 }
 336
 337 # See if we can look at a global variable, three ways
 338 gdb_test "print globalvar" ".* = 11" "look at global variable"
 339 test_dis "x/i globalvar" "globalvar"
 340 test_dis "disassem &globalvar &globalvar+1" "globalvar"
 341
 342 # See if we can look at a static variable, three ways
 343 gdb_test "print staticvar" ".* = 5" "look at static variable"
 344 test_dis "x/i &staticvar" "staticvar"
 345 test_dis "disassem &staticvar &staticvar+1" "staticvar"
 346
 347 # See if we can look at a static function
 348 gdb_test "disassem foostatic" ".*<foostatic\\+0>:.*End of assembler dump." \
 349         "look at static function"
 350
 351 remote_exec build "rm -f ${subdir}/arch.inc"