gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2002 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16 #
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # bug-gdb@prep.ai.mit.edu
  19 #
  20 # This file was written by Kendra.
  21
  22 if $tracelevel then {
  23     strace $tracelevel
  24 }
  25
  26 #
  27 # Test debugging assembly level programs.
  28 # This file uses asmsrc[12].s for input.
  29 #
  30
  31 set prms_id 0
  32 set bug_id 0
  33
  34 set asm-arch ""
  35 set asm-flags ""
  36 set link-flags ""
  37
  38 if [istarget "*arm-*-*"] then {
  39     set asm-arch arm
  40 }
  41 if [istarget "xscale-*-*"] then {
  42     set asm-arch arm
  43 }
  44 if [istarget "d10v-*-*"] then {
  45     set asm-arch d10v
  46 }
  47 if [istarget "s390-*-*"] then {
  48     set asm-arch s390
  49 }
  50 if [istarget "i\[3456\]86-*-*"] then {
  51     set asm-arch i386
  52 }
  53 if [istarget "m32r*-*"] then {
  54     set asm-arch m32r
  55 }
  56 if [istarget "powerpc*-*"] then {
  57     set asm-arch powerpc
  58 }
  59 if [istarget "sparc-*-*"] then {
  60     set asm-arch sparc
  61 }
  62 if [istarget "sparc64-*-*"] then {
  63     set asm-arch sparc64
  64     set asm-flags "-xarch=v9 -gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  65 }
  66 if [istarget "xstormy16-*-*"] then {
  67     set asm-arch xstormy16
  68     set asm-flags "-gdwarf2 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  69 }
  70 if { "${asm-arch}" == "" } {
  71     gdb_suppress_entire_file "Assembly source test -- not implemented for this target."
  72 }
  73
  74 # Watch out, we are invoking the assembler, but the testsuite sets multilib
  75 # switches according to compiler syntax.  If we pass these options straight
  76 # to the assembler, they won't always make sense.  If we don't pass them to
  77 # the assembler, the final link will complain that the object files were
  78 # built with different defaults.  So no matter what we do, we lose.  We may as
  79 # well get out of this test sooner rather than later.
  80 set dest [target_info name]
  81 if [board_info $dest exists multilib_flags] {
  82         set multilib_flags [board_info $dest multilib_flags]
  83         if { "${multilib_flags}" != "" } {
  84            gdb_suppress_entire_file "Assembly source test -- multilibs not supported by this test."
  85            return;
  86          }
  87 }
  88
  89 set testfile "asm-source"
  90 set binfile ${objdir}/${subdir}/${testfile}
  91 set src1 ${srcdir}/${subdir}/asmsrc1.s
  92 set src2 ${srcdir}/${subdir}/asmsrc2.s
  93
  94 remote_exec build "rm -f ${subdir}/arch.inc"
  95 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
  96
  97 if { "${asm-flags}" == "" } {
  98     #set asm-flags "-Wa,-gstabs,-I${srcdir}/${subdir},-I${objdir}/${subdir}"
  99     set asm-flags "-gstabs -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 100 }
 101
 102 if {[target_assemble ${src1} asmsrc1.o "${asm-flags}"] != ""} then {
 103      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 104 }
 105 if {[target_assemble ${src2} asmsrc2.o "${asm-flags}"] != ""} then {
 106      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 107 }
 108
 109 set opts "debug ldflags=-nostartfiles"
 110 foreach i ${link-flags} {
 111     append opts " ldflags=$i"
 112 }
 113 if { [gdb_compile "asmsrc1.o asmsrc2.o" "${binfile}" executable $opts] != "" } {
 114      gdb_suppress_entire_file "Testcase compile failed, so all tests in this file will automatically fail."
 115 }
 116
 117 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 118
 119
 120 gdb_start
 121 gdb_reinitialize_dir $srcdir/$subdir
 122 gdb_load ${binfile}
 123
 124 #
 125 # Run to `main' where we begin our tests.
 126 #
 127
 128 if ![runto_main] then {
 129     gdb_suppress_tests
 130 }
 131
 132 # Execute the `f' command and see if the result includes source info.
 133 gdb_test "f" "asmsrc1\[.\]s:29.*several_nops" "f at main"
 134
 135 # See if we properly `next' over a macro with several insns.
 136 gdb_test "n" "33\[      \]*.*foo2" "next over macro"
 137
 138 # See if we can properly `step' into a subroutine call.
 139 gdb_test "s" "8\[       \]*.*" "step into foo2"
 140
 141 # Test 'info target', and incidentally capture the entry point address.
 142 set entry_point 0
 143 send_gdb "info target\n"
 144 gdb_expect {
 145     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 146         set entry_point $expect_out(1,string)
 147         pass "info target"
 148     }
 149     -re ".*$gdb_prompt $" {
 150         fail "info target"
 151     }
 152     timeout {
 153         fail "info target (timeout)"
 154     }
 155 }
 156
 157 # Capture the start symbol (may be '_start' or 'start')
 158 set entry_symbol ""
 159 send_gdb "info symbol 0x$entry_point\n"
 160 gdb_expect {
 161     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 162         # We match the echoed `info symbol' command here, to help us
 163         # reliably identify the beginning of the start symbol in the
 164         # command's output.  You might think we could just use '^' to
 165         # start matching at the beginning of the line, but
 166         # unfortunately, in Expect, '^' matches the beginning of the
 167         # input that hasn't been matched by any expect clause yet.  If
 168         # every expect clause consumes a complete line, along with its
 169         # terminating CR/LF, this is equivalent to the beginning of a
 170         # line.  But expect clauses that end with `.*' will consume as
 171         # much as happened to arrive from the TTY --- exactly where
 172         # they leave you depends on inter-process timing.  :(
 173         set entry_symbol $expect_out(1,string)
 174         pass "info symbol"
 175     }
 176     -re ".*$gdb_prompt $" {
 177         fail "info symbol"
 178     }
 179     timeout {
 180         fail "info symbol (timeout)"
 181     }
 182 }
 183
 184 # Now try a 'list' from the other source file.
 185 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 186
 187 # Now try a source file search
 188 gdb_test "search A routine for foo2 to call" \
 189         "39\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 190
 191 # See if `f' prints the right source file.
 192 gdb_test "f" ".*asmsrc2\[.\]s:8.*" "f in foo2"
 193
 194 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 195 gdb_test "n" "12\[      \]*.*foo3" "n in foo2"
 196
 197 # See if a simple `bt' prints the right source files and
 198 # doesn't fall off the stack.
 199
 200 gdb_test "bt 10" \
 201         "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33(.*\#2.*start\[^\r\n\]*)?" \
 202         "bt ALL in foo2"
 203
 204 # See if a capped `bt' prints the right source files.
 205 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:12.*\#1.*main.*asmsrc1\[.\]s:33.*" "bt 2 in foo2"
 206
 207 # Step into another subroutine which lives back in the first source file.
 208 gdb_test "s" "" "s 2"
 209
 210 # Next over insns to set up the stack frame.
 211 gdb_test "n" "" "n 2"
 212
 213 # Now see if a capped `bt' is correct.
 214 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:44.*\#1.*foo2.*asmsrc2\[.\]s:12.*\#2.*main.*asmsrc1\[.\]s:33.*" "bt 3 in foo3"
 215
 216 # Try 'info source' from asmsrc1.s
 217 gdb_test "info source" \
 218         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 219         "info source asmsrc1.s"
 220
 221 # Try 'finishing' from foo3
 222 gdb_test "finish" "Run till exit from.*\[\r\n\]13\[ \t\]+gdbasm_call foo3" \
 223         "finish from foo3"
 224
 225 # Try 'info source' from asmsrc2.s
 226 gdb_test "info source" \
 227         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 228         "info source asmsrc2.s"
 229
 230 # Try 'info sources'.  This can produce a lot of output on systems
 231 # with dynamic linking, where the system's shared libc was compiled
 232 # with debugging info; for example, on Linux, this produces 47kb of
 233 # output.  So we consume it as we go.
 234 send_gdb "info sources\n"
 235 set seen_asmsrc_1 0
 236 set seen_asmsrc_2 0
 237 gdb_expect {
 238     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 239         set seen_asmsrc_1 1
 240         exp_continue
 241     }
 242     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 243         set seen_asmsrc_2 1
 244         exp_continue
 245     }
 246     -re ", " {
 247         exp_continue
 248     }
 249     -re "$gdb_prompt $" {
 250         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 251             pass "info sources"
 252         } else {
 253             fail "info sources"
 254         }
 255     }
 256     timeout {
 257             fail "info sources (timeout)"
 258     }
 259 }
 260
 261
 262 # Try 'info line'
 263 gdb_test "info line" \
 264         "Line 13 of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 265         "info line"
 266
 267 # Try 'nexting' over next call to foo3
 268 gdb_test "next" "17\[ \t\]+gdbasm_leave" "next over foo3"
 269
 270 # Try 'return' from foo2
 271 gdb_test "return" "\#0  main .*37\[ \t\]+gdbasm_exit0" "return from foo2" \
 272         "Make selected stack frame return now\?.*" "y"
 273
 274 # See if we can look at a global variable
 275 gdb_test "print globalvar" ".* = 11" "look at global variable"
 276
 277 # See if we can look at a static variable
 278 gdb_test "print staticvar" ".* = 5" "look at static variable"
 279
 280 # See if we can look at a static function
 281 gdb_test "disassem foostatic" ".*<foostatic>:.*End of assembler dump." \
 282         "look at static function"
 283
 284 remote_exec build "rm -f ${subdir}/arch.inc"