gdb/testsuite/gdb.server/stop-reply-no-thread.exp

   1 # This testcase is part of GDB, the GNU debugger.
   2 #
   3 # Copyright 2018-2020 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Test backward compatibility with older GDBservers which did not
  19 # include ";thread:NNN" in T stop replies when debugging
  20 # single-threaded programs, even though they'd list the main thread in
  21 # response to qfThreadInfo/qsThreadInfo.  See PR remote/22597.
  22
  23 load_lib gdbserver-support.exp
  24
  25 if { [skip_gdbserver_tests] } {
  26     verbose "skipping gdbserver tests"
  27     return -1
  28 }
  29
  30 standard_testfile
  31 if [prepare_for_testing "failed to prepare" $testfile $srcfile] {
  32     return -1
  33 }
  34
  35 # Run the tests with different features of GDBserver disabled.
  36 proc run_test { disable_feature } {
  37     global binfile gdb_prompt decimal
  38
  39     clean_restart ${binfile}
  40
  41     # Make sure we're disconnected, in case we're testing with an
  42     # extended-remote board, therefore already connected.
  43     gdb_test "disconnect" ".*"
  44
  45     set res [gdbserver_start "--disable-packet=${disable_feature}" $binfile]
  46     set gdbserver_protocol [lindex $res 0]
  47     set gdbserver_gdbport [lindex $res 1]
  48
  49     # Disable XML-based thread listing, and multi-process extensions.
  50     gdb_test_no_output "set remote threads-packet off"
  51     gdb_test_no_output "set remote multiprocess-feature-packet off"
  52
  53     set res [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
  54     if ![gdb_assert {$res == 0} "connect"] {
  55         return
  56     }
  57
  58     # There should be only one thread listed.
  59     set test "info threads"
  60     gdb_test_multiple $test $test {
  61         -re "2 Thread.*$gdb_prompt $" {
  62             fail $test
  63         }
  64         -re "has terminated.*$gdb_prompt $" {
  65             fail $test
  66         }
  67         -re "\\\* 1\[\t \]*Thread\[^\r\n\]*\r\n$gdb_prompt $" {
  68             pass $test
  69         }
  70     }
  71
  72     gdb_breakpoint "main"
  73
  74     # Bad GDB behaved like this:
  75     #  (gdb) c
  76     #  Cannot execute this command without a live selected thread.
  77     #  (gdb)
  78     gdb_test "c" "Breakpoint $decimal, main.*" "continue to main"
  79 }
  80
  81 # Disable different features within gdbserver:
  82 #
  83 # Tthread: Start GDBserver, with ";thread:NNN" in T stop replies disabled,
  84 #          emulating old gdbservers when debugging single-threaded programs.
  85 #
  86 # T: Start GDBserver with the entire 'T' stop reply packet disabled,
  87 #    GDBserver will instead send the 'S' stop reply.
  88 foreach_with_prefix to_disable { Tthread T } {
  89     run_test $to_disable
  90 }