gdb/testsuite/lib/gdbserver-support.exp

   1 # Copyright 2000, 2002, 2003, 2004, 2005, 2006, 2007, 2008
   2 # Free Software Foundation, Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # This file is based on config/gdbserver.exp, which was written by
  18 # Michael Snyder (msnyder@redhat.com).
  19
  20 #
  21 # To be addressed or set in your baseboard config file:
  22 #
  23 #   set_board_info gdb_protocol "remote"
  24 #       Unles you have a gdbserver that uses a different protocol...
  25 #
  26 #   set_board_info gdb_server_prog
  27 #       This will be the path to the gdbserver program you want to test.
  28 #       Defaults to "gdbserver".
  29 #
  30 #   set_board_info sockethost
  31 #       The name of the host computer whose socket is being used.
  32 #       Defaults to "localhost".  Note: old gdbserver requires
  33 #       that you define this, but libremote/gdbserver does not.
  34 #
  35 #   set_board_info gdb,socketport
  36 #       Port id to use for socket connection.  If not set explicitly,
  37 #       it will start at "2345" and increment for each use.
  38 #
  39
  40 #
  41 # gdb_target_cmd
  42 # Send gdb the "target" command
  43 #
  44 proc gdb_target_cmd { targetname serialport } {
  45     global gdb_prompt
  46
  47     set serialport_re [string_to_regexp $serialport]
  48     for {set i 1} {$i <= 3} {incr i} {
  49         send_gdb "target $targetname $serialport\n"
  50         gdb_expect 60 {
  51             -re "A program is being debugged already.*ill it.*y or n. $" {
  52                 send_gdb "y\n"
  53                 exp_continue
  54             }
  55             -re "unknown host.*$gdb_prompt" {
  56                 verbose "Couldn't look up $serialport"
  57             }
  58             -re "Couldn't establish connection to remote.*$gdb_prompt $" {
  59                 verbose "Connection failed"
  60             }
  61             -re "Remote MIPS debugging.*$gdb_prompt" {
  62                 verbose "Set target to $targetname"
  63                 return 0
  64             }
  65             -re "Remote debugging using .*$serialport_re.*$gdb_prompt $" {
  66                 verbose "Set target to $targetname"
  67                 return 0
  68             }
  69             -re "Remote target $targetname connected to.*$gdb_prompt $" {
  70                 verbose "Set target to $targetname"
  71                 return 0
  72             }
  73             -re "Connected to.*$gdb_prompt $" {
  74                 verbose "Set target to $targetname"
  75                 return 0
  76             }
  77             -re "Ending remote.*$gdb_prompt $" { }
  78             -re "Connection refused.*$gdb_prompt $" {
  79                 verbose "Connection refused by remote target.  Pausing, and trying again."
  80                 sleep 30
  81                 continue
  82             }
  83             -re "Timeout reading from remote system.*$gdb_prompt $" {
  84                 verbose "Got timeout error from gdb."
  85             }
  86             -notransfer -re "Remote debugging using .*\r\n> $" {
  87                 # We got an unexpected prompt while creating the target.
  88                 # Leave it there for the test to diagnose.
  89                 return 1
  90             }
  91             timeout {
  92                 send_gdb "\ 3"
  93                 break
  94             }
  95         }
  96     }
  97     return 1
  98 }
  99
 100
 101 global portnum
 102 set portnum "2345"
 103
 104 # Locate the gdbserver binary.  Returns "" if gdbserver could not be found.
 105
 106 proc find_gdbserver { } {
 107   global GDB
 108
 109   if [target_info exists gdb_server_prog] {
 110     return [target_info gdb_server_prog]
 111   }
 112
 113   set gdbserver "${GDB}server"
 114   if { [file isdirectory $gdbserver] } {
 115     append gdbserver "/gdbserver"
 116   }
 117
 118   if { [file executable $gdbserver] } {
 119     return $gdbserver
 120   }
 121
 122   return ""
 123 }
 124
 125 # Return non-zero if we should skip gdbserver-specific tests.
 126
 127 proc skip_gdbserver_tests { } {
 128   if { [find_gdbserver] == "" } {
 129     return 1
 130   }
 131
 132   return 0
 133 }
 134
 135 # Download the currently loaded program to the target if necessary.
 136 # Return the target system filename.
 137
 138 proc gdbserver_download { } {
 139     global gdbserver_host_exec
 140     global gdbserver_host_mtime
 141     global gdbserver_server_exec
 142     global last_loaded_file
 143
 144     set host_exec $last_loaded_file
 145
 146     # If we already downloaded a file to the target, see if we can reuse it.
 147     set reuse 0
 148     if { [info exists gdbserver_server_exec] } {
 149         set reuse 1
 150
 151         # If the file has changed, we can not.
 152         if { $host_exec != $gdbserver_host_exec } {
 153             set reuse 0
 154         }
 155
 156         # If the mtime has changed, we can not.
 157         if { [file mtime $host_exec] != $gdbserver_host_mtime } {
 158             set reuse 0
 159         }
 160     }
 161
 162     if { $reuse == 0 } {
 163         set gdbserver_host_exec $host_exec
 164         set gdbserver_host_mtime [file mtime $host_exec]
 165         if [is_remote target] {
 166             set gdbserver_server_exec [gdb_download $host_exec]
 167         } else {
 168             set gdbserver_server_exec $host_exec
 169         }
 170     }
 171
 172     return $gdbserver_server_exec
 173 }
 174
 175 # Start a gdbserver process with initial OPTIONS and trailing ARGUMENTS.
 176 # The port will be filled in between them automatically.
 177 #
 178 # Returns the target protocol and socket to connect to.
 179
 180 proc gdbserver_start { options arguments } {
 181     global portnum
 182
 183     # Port id -- either specified in baseboard file, or managed here.
 184     if [target_info exists gdb,socketport] {
 185         set portnum [target_info gdb,socketport]
 186     } else {
 187         # Bump the port number to avoid conflicts with hung ports.
 188         incr portnum
 189     }
 190
 191     # Extract the local and remote host ids from the target board struct.
 192     if [target_info exists sockethost] {
 193         set debughost [target_info sockethost]
 194     } else {
 195         set debughost "localhost:"
 196     }
 197
 198     # Extract the protocol
 199     if [target_info exists gdb_protocol] {
 200         set protocol [target_info gdb_protocol]
 201     } else {
 202         set protocol "remote"
 203     }
 204
 205     set gdbserver [find_gdbserver]
 206
 207     # Export the host:port pair.
 208     set gdbport $debughost$portnum
 209
 210     # Fire off the debug agent.
 211     set gdbserver_command "$gdbserver"
 212     if { $options != "" } {
 213         append gdbserver_command " $options"
 214     }
 215     append gdbserver_command " :$portnum"
 216     if { $arguments != "" } {
 217         append gdbserver_command " $arguments"
 218     }
 219
 220     set server_spawn_id [remote_spawn target $gdbserver_command]
 221
 222     # Wait for the server to open its TCP socket, so that GDB can connect.
 223     expect {
 224         -i $server_spawn_id
 225         -notransfer
 226         -re "Listening on" { }
 227     }
 228
 229     # We can't just call close, because if gdbserver is local then that means
 230     # that it will get a SIGHUP.  Doing it this way could also allow us to
 231     # get at the inferior's input or output if necessary, and means that we
 232     # don't need to redirect output.
 233     expect_background {
 234         -i $server_spawn_id
 235         full_buffer { }
 236         eof {
 237             # The spawn ID is already closed now (but not yet waited for).
 238             wait -i $expect_out(spawn_id)
 239         }
 240     }
 241
 242     return [list $protocol $gdbport]
 243 }
 244
 245 # Start a gdbserver process running SERVER_EXEC, and connect GDB
 246 # to it.  CHILD_ARGS are passed to the inferior.
 247 #
 248 # Returns the target protocol and socket to connect to.
 249
 250 proc gdbserver_spawn { child_args } {
 251     set target_exec [gdbserver_download]
 252
 253     # Fire off the debug agent.  This flavour of gdbserver takes as
 254     # arguments the port information, the name of the executable file to
 255     # be debugged, and any arguments.
 256     set arguments "$target_exec"
 257     if { $child_args != "" } {
 258         append arguments " $child_args"
 259     }
 260     return [gdbserver_start "" $arguments]
 261 }
 262
 263 # Start a gdbserver process running HOST_EXEC and pass CHILD_ARGS
 264 # to it.  Return 0 on success, or non-zero on failure.
 265
 266 proc gdbserver_run { child_args } {
 267     global gdbserver_protocol
 268     global gdbserver_gdbport
 269
 270     # Kill anything running before we try to start gdbserver, in case
 271     # we are sharing a serial connection.
 272     global gdb_prompt
 273     send_gdb "kill\n"
 274     gdb_expect 120 {
 275         -re "Kill the program being debugged. .y or n. $" {
 276             send_gdb "y\n"
 277             verbose "\t\tKilling previous program being debugged"
 278             exp_continue
 279         }
 280         -re "$gdb_prompt $" {
 281             # OK.
 282         }
 283     }
 284
 285     set res [gdbserver_spawn $child_args]
 286     set gdbserver_protocol [lindex $res 0]
 287     set gdbserver_gdbport [lindex $res 1]
 288
 289     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 290 }
 291
 292 # Reconnect to the previous gdbserver session.
 293
 294 proc gdbserver_reconnect { } {
 295     global gdbserver_protocol
 296     global gdbserver_gdbport
 297
 298     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 299 }
 300
 301 # Start and connect to a gdbserver in extended mode.
 302 proc gdbserver_start_extended { } {
 303     set res [gdbserver_start "--multi" ""]
 304     set gdbserver_protocol "extended-[lindex $res 0]"
 305     set gdbserver_gdbport [lindex $res 1]
 306
 307     return [gdb_target_cmd $gdbserver_protocol $gdbserver_gdbport]
 308 }