gdb/testsuite/lib/mi-support.exp

   1 # Copyright 1999-2014 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # This file was based on a file written by Fred Fish. (fnf@cygnus.com)
  17
  18 # Test setup routines that work with the MI interpreter.
  19
  20 # The variable mi_gdb_prompt is a regexp which matches the gdb mi prompt.
  21 # Set it if it is not already set.
  22 global mi_gdb_prompt
  23 if ![info exists mi_gdb_prompt] then {
  24     set mi_gdb_prompt "\[(\]gdb\[)\] \r\n"
  25 }
  26
  27 global mi_inferior_spawn_id
  28 global mi_inferior_tty_name
  29
  30 set MIFLAGS "-i=mi"
  31
  32 set thread_selected_re "=thread-selected,id=\"\[0-9\]+\"\r\n"
  33 set gdbindex_warning_re "&\"warning: Skipping \[^\r\n\]+ \.gdb_index section in \[^\r\n\]+\"\r\n(?:&\"\\\\n\"\r\n)?"
  34 set library_loaded_re "=library-loaded\[^\n\]+\"\r\n(?:$gdbindex_warning_re)?"
  35 set breakpoint_re "=(?:breakpoint-created|breakpoint-deleted)\[^\n\]+\"\r\n"
  36
  37 #
  38 # mi_gdb_exit -- exit the GDB, killing the target program if necessary
  39 #
  40 proc mi_gdb_exit {} {
  41     catch mi_uncatched_gdb_exit
  42 }
  43
  44 proc mi_uncatched_gdb_exit {} {
  45     global GDB
  46     global INTERNAL_GDBFLAGS GDBFLAGS
  47     global verbose
  48     global gdb_spawn_id
  49     global gdb_prompt
  50     global mi_gdb_prompt
  51     global MIFLAGS
  52
  53     gdb_stop_suppressing_tests
  54
  55     if { [info procs sid_exit] != "" } {
  56         sid_exit
  57     }
  58
  59     if ![info exists gdb_spawn_id] {
  60         return
  61     }
  62
  63     verbose "Quitting $GDB $INTERNAL_GDBFLAGS $GDBFLAGS $MIFLAGS"
  64
  65     if { [is_remote host] && [board_info host exists fileid] } {
  66         send_gdb "999-gdb-exit\n"
  67         gdb_expect 10 {
  68             -re "y or n" {
  69                 send_gdb "y\n"
  70                 exp_continue
  71             }
  72             -re "Undefined command.*$gdb_prompt $" {
  73                 send_gdb "quit\n"
  74                 exp_continue
  75             }
  76             -re "DOSEXIT code" { }
  77             default { }
  78         }
  79     }
  80
  81     if ![is_remote host] {
  82         remote_close host
  83     }
  84     unset gdb_spawn_id
  85 }
  86
  87 #
  88 # default_mi_gdb_start [INFERIOR_PTY] -- start gdb running, default procedure
  89 #
  90 # INFERIOR_PTY should be set to separate-inferior-tty to have the inferior work
  91 # with it's own PTY. If set to same-inferior-tty, the inferior shares GDB's PTY.
  92 # The default value is same-inferior-tty.
  93 #
  94 # When running over NFS, particularly if running many simultaneous
  95 # tests on different hosts all using the same server, things can
  96 # get really slow.  Give gdb at least 3 minutes to start up.
  97 #
  98 proc default_mi_gdb_start { args } {
  99     global verbose use_gdb_stub
 100     global GDB
 101     global INTERNAL_GDBFLAGS GDBFLAGS
 102     global gdb_prompt
 103     global mi_gdb_prompt
 104     global timeout
 105     global gdb_spawn_id
 106     global MIFLAGS
 107
 108     gdb_stop_suppressing_tests
 109     set inferior_pty no-tty
 110
 111     # Set the default value, it may be overriden later by specific testfile.
 112     set use_gdb_stub [target_info exists use_gdb_stub]
 113
 114     if { [llength $args] == 1} {
 115         set inferior_pty [lindex $args 0]
 116     }
 117
 118     set separate_inferior_pty [string match $inferior_pty separate-inferior-tty]
 119
 120     # Start SID.
 121     if { [info procs sid_start] != "" } {
 122         verbose "Spawning SID"
 123         sid_start
 124     }
 125
 126     verbose "Spawning $GDB $INTERNAL_GDBFLAGS $GDBFLAGS $MIFLAGS"
 127
 128     if [info exists gdb_spawn_id] {
 129         return 0
 130     }
 131
 132     if ![is_remote host] {
 133         if { [which $GDB] == 0 } then {
 134             perror "$GDB does not exist."
 135             exit 1
 136         }
 137     }
 138
 139     # Create the new PTY for the inferior process.
 140     if { $separate_inferior_pty } {
 141         spawn -pty
 142         global mi_inferior_spawn_id
 143         global mi_inferior_tty_name
 144         set mi_inferior_spawn_id $spawn_id
 145         set mi_inferior_tty_name $spawn_out(slave,name)
 146     }
 147
 148     set res [remote_spawn host "$GDB $INTERNAL_GDBFLAGS $GDBFLAGS $MIFLAGS [host_info gdb_opts]"]
 149     if { $res < 0 || $res == "" } {
 150         perror "Spawning $GDB failed."
 151         return 1
 152     }
 153     gdb_expect {
 154         -re "~\"GNU.*\r\n~\".*$mi_gdb_prompt$" {
 155             # We have a new format mi startup prompt.  If we are
 156             # running mi1, then this is an error as we should be
 157             # using the old-style prompt.
 158             if { $MIFLAGS == "-i=mi1" } {
 159                 perror "(mi startup) Got unexpected new mi prompt."
 160                 remote_close host
 161                 return -1
 162             }
 163             verbose "GDB initialized."
 164         }
 165         -re "\[^~\].*$mi_gdb_prompt$" {
 166             # We have an old format mi startup prompt.  If we are
 167             # not running mi1, then this is an error as we should be
 168             # using the new-style prompt.
 169             if { $MIFLAGS != "-i=mi1" } {
 170                 perror "(mi startup) Got unexpected old mi prompt."
 171                 remote_close host
 172                 return -1
 173             }
 174             verbose "GDB initialized."
 175         }
 176         -re ".*unrecognized option.*for a complete list of options." {
 177             untested "Skip mi tests (not compiled with mi support)."
 178             remote_close host
 179             return -1
 180         }
 181         -re ".*Interpreter `mi' unrecognized." {
 182             untested "Skip mi tests (not compiled with mi support)."
 183             remote_close host
 184             return -1
 185         }
 186         timeout {
 187             perror "(timeout) GDB never initialized after 10 seconds."
 188             remote_close host
 189             return -1
 190         }
 191     }
 192     set gdb_spawn_id -1
 193
 194     # FIXME: mi output does not go through pagers, so these can be removed.
 195     # force the height to "unlimited", so no pagers get used
 196     send_gdb "100-gdb-set height 0\n"
 197     gdb_expect 10 {
 198         -re ".*100-gdb-set height 0\r\n100\\\^done\r\n$mi_gdb_prompt$" {
 199             verbose "Setting height to 0." 2
 200         }
 201         timeout {
 202             warning "Couldn't set the height to 0"
 203         }
 204     }
 205     # force the width to "unlimited", so no wraparound occurs
 206     send_gdb "101-gdb-set width 0\n"
 207     gdb_expect 10 {
 208         -re ".*101-gdb-set width 0\r\n101\\\^done\r\n$mi_gdb_prompt$" {
 209             verbose "Setting width to 0." 2
 210         }
 211         timeout {
 212             warning "Couldn't set the width to 0."
 213         }
 214     }
 215     # If allowing the inferior to have its own PTY then assign the inferior
 216     # its own terminal device here.
 217     if { $separate_inferior_pty } {
 218         send_gdb "102-inferior-tty-set $mi_inferior_tty_name\n"
 219         gdb_expect 10 {
 220             -re ".*102\\\^done\r\n$mi_gdb_prompt$" {
 221                 verbose "redirect inferior output to new terminal device."
 222             }
 223             timeout {
 224                 warning "Couldn't redirect inferior output." 2
 225             }
 226         }
 227     }
 228
 229     mi_detect_async
 230
 231     return 0
 232 }
 233
 234 #
 235 # Overridable function. You can override this function in your
 236 # baseboard file.
 237 #
 238 proc mi_gdb_start { args } {
 239   return [default_mi_gdb_start $args]
 240 }
 241
 242 # Many of the tests depend on setting breakpoints at various places and
 243 # running until that breakpoint is reached.  At times, we want to start
 244 # with a clean-slate with respect to breakpoints, so this utility proc
 245 # lets us do this without duplicating this code everywhere.
 246 #
 247
 248 proc mi_delete_breakpoints {} {
 249     global mi_gdb_prompt
 250
 251 # FIXME: The mi operation won't accept a prompt back and will use the 'all' arg
 252     send_gdb "102-break-delete\n"
 253     gdb_expect 30 {
 254          -re "Delete all breakpoints.*y or n.*$" {
 255             send_gdb "y\n"
 256             exp_continue
 257          }
 258          -re "102-break-delete\r\n102\\\^done\r\n$mi_gdb_prompt$" {
 259              # This happens if there were no breakpoints
 260          }
 261          timeout { perror "Delete all breakpoints in mi_delete_breakpoints (timeout)" ; return }
 262     }
 263
 264 # The correct output is not "No breakpoints or watchpoints." but an
 265 # empty BreakpointTable. Also, a query is not acceptable with mi.
 266     send_gdb "103-break-list\n"
 267     gdb_expect 30 {
 268          -re "103-break-list\r\n103\\\^done,BreakpointTable=\{\}\r\n$mi_gdb_prompt$" {}
 269          -re "103-break-list\r\n103\\\^done,BreakpointTable=\{nr_rows=\".\",nr_cols=\".\",hdr=\\\[\{width=\".*\",alignment=\".*\",col_name=\"number\",colhdr=\"Num\"\}.*colhdr=\"Type\".*colhdr=\"Disp\".*colhdr=\"Enb\".*colhdr=\"Address\".*colhdr=\"What\".*\\\],body=\\\[\\\]\}\r\n$mi_gdb_prompt$" {}
 270          -re "103-break-list\r\n103\\\^doneNo breakpoints or watchpoints.\r\n\r\n$mi_gdb_prompt$" {warning "Unexpected console text received"}
 271          -re "$mi_gdb_prompt$" { perror "Breakpoints not deleted" ; return }
 272          -re "Delete all breakpoints.*or n.*$" {
 273             warning "Unexpected prompt for breakpoints deletion"
 274             send_gdb "y\n"
 275             exp_continue
 276         }
 277          timeout { perror "-break-list (timeout)" ; return }
 278     }
 279 }
 280
 281 proc mi_gdb_reinitialize_dir { subdir } {
 282     global mi_gdb_prompt
 283     global MIFLAGS
 284
 285     global suppress_flag
 286     if { $suppress_flag } {
 287         return
 288     }
 289
 290     if [is_remote host] {
 291         return ""
 292     }
 293
 294     if { $MIFLAGS == "-i=mi1" } {
 295       send_gdb "104-environment-directory\n"
 296       gdb_expect 60 {
 297         -re ".*Reinitialize source path to empty.*y or n. " {
 298             warning "Got confirmation prompt for dir reinitialization."
 299             send_gdb "y\n"
 300             gdb_expect 60 {
 301                 -re "$mi_gdb_prompt$" {}
 302                 timeout {error "Dir reinitialization failed (timeout)"}
 303             }
 304         }
 305         -re "$mi_gdb_prompt$" {}
 306           timeout {error "Dir reinitialization failed (timeout)"}
 307       }
 308     } else {
 309         send_gdb "104-environment-directory -r\n"
 310         gdb_expect 60 {
 311             -re "104\\\^done,source-path=.*\r\n$mi_gdb_prompt$" {}
 312             -re "$mi_gdb_prompt$" {}
 313             timeout {error "Dir reinitialization failed (timeout)"}
 314       }
 315     }
 316
 317     send_gdb "105-environment-directory $subdir\n"
 318     gdb_expect 60 {
 319         -re "Source directories searched.*$mi_gdb_prompt$" {
 320             verbose "Dir set to $subdir"
 321         }
 322         -re "105\\\^done.*\r\n$mi_gdb_prompt$" {
 323             # FIXME: We return just the prompt for now.
 324             verbose "Dir set to $subdir"
 325             # perror "Dir \"$subdir\" failed."
 326         }
 327     }
 328 }
 329
 330 # Send GDB the "target" command.
 331 # FIXME: Some of these patterns are not appropriate for MI.  Based on
 332 # config/monitor.exp:gdb_target_command.
 333 proc mi_gdb_target_cmd { targetname serialport } {
 334     global mi_gdb_prompt
 335
 336     set serialport_re [string_to_regexp $serialport]
 337     for {set i 1} {$i <= 3} {incr i} {
 338         send_gdb "47-target-select $targetname $serialport\n"
 339         gdb_expect 60 {
 340             -re "47\\^connected.*$mi_gdb_prompt" {
 341                 verbose "Set target to $targetname"
 342                 return 0
 343             }
 344             -re "unknown host.*$mi_gdb_prompt" {
 345                 verbose "Couldn't look up $serialport"
 346             }
 347             -re "Couldn't establish connection to remote.*$mi_gdb_prompt$" {
 348                 verbose "Connection failed"
 349             }
 350             -re "Remote MIPS debugging.*$mi_gdb_prompt$" {
 351                 verbose "Set target to $targetname"
 352                 return 0
 353             }
 354             -re "Remote debugging using .*$serialport_re.*$mi_gdb_prompt$" {
 355                 verbose "Set target to $targetname"
 356                 return 0
 357             }
 358             -re "Remote target $targetname connected to.*$mi_gdb_prompt$" {
 359                 verbose "Set target to $targetname"
 360                 return 0
 361             }
 362             -re "Connected to.*$mi_gdb_prompt$" {
 363                 verbose "Set target to $targetname"
 364                 return 0
 365             }
 366             -re "Ending remote.*$mi_gdb_prompt$" { }
 367             -re "Connection refused.*$mi_gdb_prompt$" {
 368                 verbose "Connection refused by remote target.  Pausing, and trying again."
 369                 sleep 5
 370                 continue
 371             }
 372             -re "Non-stop mode requested, but remote does not support non-stop.*$mi_gdb_prompt" {
 373                 unsupported "Non-stop mode not supported"
 374                 return 1
 375             }
 376             -re "Timeout reading from remote system.*$mi_gdb_prompt$" {
 377                 verbose "Got timeout error from gdb."
 378             }
 379             timeout {
 380                 send_gdb "\ 3"
 381                 break
 382             }
 383         }
 384     }
 385     return 1
 386 }
 387
 388 #
 389 # load a file into the debugger (file command only).
 390 # return a -1 if anything goes wrong.
 391 #
 392 proc mi_gdb_file_cmd { arg } {
 393     global verbose
 394     global loadpath
 395     global loadfile
 396     global GDB
 397     global mi_gdb_prompt
 398     global last_loaded_file
 399     upvar timeout timeout
 400
 401     set last_loaded_file $arg
 402
 403     if [is_remote host] {
 404         set arg [remote_download host $arg]
 405         if { $arg == "" } {
 406             error "download failed"
 407             return -1
 408         }
 409     }
 410
 411 # FIXME: Several of these patterns are only acceptable for console
 412 # output.  Queries are an error for mi.
 413     send_gdb "105-file-exec-and-symbols $arg\n"
 414     gdb_expect 120 {
 415         -re "Reading symbols from.*done.*$mi_gdb_prompt$" {
 416             verbose "\t\tLoaded $arg into the $GDB"
 417             return 0
 418         }
 419         -re "has no symbol-table.*$mi_gdb_prompt$" {
 420             perror "$arg wasn't compiled with \"-g\""
 421             return -1
 422         }
 423         -re "Load new symbol table from \".*\".*y or n. $" {
 424             send_gdb "y\n"
 425             gdb_expect 120 {
 426                 -re "Reading symbols from.*done.*$mi_gdb_prompt$" {
 427                     verbose "\t\tLoaded $arg with new symbol table into $GDB"
 428                     # All OK
 429                 }
 430                 timeout {
 431                     perror "(timeout) Couldn't load $arg, other program already loaded."
 432                     return -1
 433                 }
 434             }
 435         }
 436         -re "No such file or directory.*$mi_gdb_prompt$" {
 437             perror "($arg) No such file or directory\n"
 438             return -1
 439         }
 440         -re "105-file-exec-and-symbols .*\r\n105\\\^done\r\n$mi_gdb_prompt$" {
 441             # We (MI) are just giving the prompt back for now, instead of giving
 442             # some acknowledgement.
 443             return 0
 444         }
 445         timeout {
 446             perror "couldn't load $arg into $GDB (timed out)."
 447             return -1
 448         }
 449         eof {
 450             # This is an attempt to detect a core dump, but seems not to
 451             # work.  Perhaps we need to match .* followed by eof, in which
 452             # gdb_expect does not seem to have a way to do that.
 453             perror "couldn't load $arg into $GDB (end of file)."
 454             return -1
 455         }
 456     }
 457 }
 458
 459 #
 460 # connect to the target and download a file, if necessary.
 461 # return a -1 if anything goes wrong.
 462 #
 463 proc mi_gdb_target_load { } {
 464     global verbose
 465     global loadpath
 466     global loadfile
 467     global GDB
 468     global mi_gdb_prompt
 469
 470     if [target_info exists gdb_load_timeout] {
 471         set loadtimeout [target_info gdb_load_timeout]
 472     } else {
 473         set loadtimeout 1600
 474     }
 475
 476     if { [info procs gdbserver_gdb_load] != "" } {
 477         mi_gdb_test "kill" ".*" ""
 478         set res [gdbserver_gdb_load]
 479         set protocol [lindex $res 0]
 480         set gdbport [lindex $res 1]
 481
 482         if { [mi_gdb_target_cmd $protocol $gdbport] != 0 } {
 483             return -1
 484         }
 485     } elseif { [info procs send_target_sid] != "" } {
 486         # For SID, things get complex
 487         send_gdb "kill\n"
 488         gdb_expect 10 {
 489             -re ".*$mi_gdb_prompt$"
 490         }
 491         send_target_sid
 492         gdb_expect $loadtimeout {
 493             -re "\\^done.*$mi_gdb_prompt$" {
 494             }
 495             timeout {
 496                 perror "Unable to connect to SID target (timeout)"
 497                 return -1
 498             }
 499         }
 500         send_gdb "48-target-download\n"
 501         gdb_expect $loadtimeout {
 502             -re "48\\^done.*$mi_gdb_prompt$" {
 503             }
 504             timeout {
 505                 perror "Unable to download to SID target (timeout)"
 506                 return -1
 507             }
 508         }
 509     } elseif { [target_info protocol] == "sim" } {
 510         # For the simulator, just connect to it directly.
 511         send_gdb "47-target-select sim\n"
 512         gdb_expect $loadtimeout {
 513             -re "47\\^connected.*$mi_gdb_prompt$" {
 514             }
 515             timeout {
 516                 perror "Unable to select sim target (timeout)"
 517                 return -1
 518             }
 519         }
 520         send_gdb "48-target-download\n"
 521         gdb_expect $loadtimeout {
 522             -re "48\\^done.*$mi_gdb_prompt$" {
 523             }
 524             timeout {
 525                 perror "Unable to download to sim target (timeout)"
 526                 return -1
 527             }
 528         }
 529     } elseif { [target_info gdb_protocol] == "remote" } {
 530         # remote targets
 531         if { [mi_gdb_target_cmd "remote" [target_info netport]] != 0 } {
 532             perror "Unable to connect to remote target"
 533             return -1
 534         }
 535         send_gdb "48-target-download\n"
 536         gdb_expect $loadtimeout {
 537             -re "48\\^done.*$mi_gdb_prompt$" {
 538             }
 539             timeout {
 540                 perror "Unable to download to remote target (timeout)"
 541                 return -1
 542             }
 543         }
 544     }
 545     return 0
 546 }
 547
 548 #
 549 # load a file into the debugger.
 550 # return a -1 if anything goes wrong.
 551 #
 552 proc mi_gdb_load { arg } {
 553     if { $arg != "" } {
 554         return [mi_gdb_file_cmd $arg]
 555     }
 556     return 0
 557 }
 558
 559 # mi_gdb_test COMMAND PATTERN MESSAGE [IPATTERN] -- send a command to gdb;
 560 #   test the result.
 561 #
 562 # COMMAND is the command to execute, send to GDB with send_gdb.  If
 563 #   this is the null string no command is sent.
 564 # PATTERN is the pattern to match for a PASS, and must NOT include
 565 #   the \r\n sequence immediately before the gdb prompt.
 566 # MESSAGE is the message to be printed.  (If this is the empty string,
 567 #   then sometimes we don't call pass or fail at all; I don't
 568 #   understand this at all.)
 569 # IPATTERN is the pattern to match for the inferior's output.  This parameter
 570 #   is optional.  If present, it will produce a PASS if the match is
 571 #   successful, and a FAIL if unsuccessful.
 572 #
 573 # Returns:
 574 #    1 if the test failed,
 575 #    0 if the test passes,
 576 #   -1 if there was an internal error.
 577 #
 578 proc mi_gdb_test { args } {
 579     global verbose
 580     global mi_gdb_prompt
 581     global GDB expect_out
 582     global inferior_exited_re async
 583     upvar timeout timeout
 584
 585     set command [lindex $args 0]
 586     set pattern [lindex $args 1]
 587     set message [lindex $args 2]
 588
 589     if [llength $args]==4 {
 590         set ipattern [lindex $args 3]
 591     }
 592
 593     if [llength $args]==5 {
 594         set question_string [lindex $args 3]
 595         set response_string [lindex $args 4]
 596     } else {
 597         set question_string "^FOOBAR$"
 598     }
 599
 600     if $verbose>2 then {
 601         send_user "Sending \"$command\" to gdb\n"
 602         send_user "Looking to match \"$pattern\"\n"
 603         send_user "Message is \"$message\"\n"
 604     }
 605
 606     set result -1
 607     set string "${command}\n"
 608     set string_regex [string_to_regexp $command]
 609
 610     if { $command != "" } {
 611         while { "$string" != "" } {
 612             set foo [string first "\n" "$string"]
 613             set len [string length "$string"]
 614             if { $foo < [expr $len - 1] } {
 615                 set str [string range "$string" 0 $foo]
 616                 if { [send_gdb "$str"] != "" } {
 617                     global suppress_flag
 618
 619                     if { ! $suppress_flag } {
 620                         perror "Couldn't send $command to GDB."
 621                     }
 622                     fail "$message"
 623                     return $result
 624                 }
 625                 gdb_expect 2 {
 626                     -re "\[\r\n\]" { }
 627                     timeout { }
 628                 }
 629                 set string [string range "$string" [expr $foo + 1] end]
 630             } else {
 631                 break
 632             }
 633         }
 634         if { "$string" != "" } {
 635             if { [send_gdb "$string"] != "" } {
 636                 global suppress_flag
 637
 638                 if { ! $suppress_flag } {
 639                     perror "Couldn't send $command to GDB."
 640                 }
 641                 fail "$message"
 642                 return $result
 643             }
 644         }
 645     }
 646
 647     if [info exists timeout] {
 648         set tmt $timeout
 649     } else {
 650         global timeout
 651         if [info exists timeout] {
 652             set tmt $timeout
 653         } else {
 654             set tmt 60
 655         }
 656     }
 657     if {$async} {
 658         # With $prompt_re "" there may come arbitrary asynchronous response
 659         # from the previous command, before or after $string_regex.
 660         set string_regex ".*"
 661     }
 662     verbose -log "Expecting: ^($string_regex\[\r\n\]+)?($pattern\[\r\n\]+$mi_gdb_prompt\[ \]*)"
 663     gdb_expect $tmt {
 664          -re "\\*\\*\\* DOSEXIT code.*" {
 665              if { $message != "" } {
 666                  fail "$message"
 667              }
 668              gdb_suppress_entire_file "GDB died"
 669              return -1
 670          }
 671          -re "Ending remote debugging.*$mi_gdb_prompt\[ \]*$" {
 672             if ![isnative] then {
 673                 warning "Can`t communicate to remote target."
 674             }
 675             gdb_exit
 676             gdb_start
 677             set result -1
 678         }
 679          -re "^($string_regex\[\r\n\]+)?($pattern\[\r\n\]+$mi_gdb_prompt\[ \]*)" {
 680             # At this point, $expect_out(1,string) is the MI input command.
 681             # and $expect_out(2,string) is the MI output command.
 682             # If $expect_out(1,string) is "", then there was no MI input command here.
 683
 684             # NOTE, there is no trailing anchor because with GDB/MI,
 685             # asynchronous responses can happen at any point, causing more
 686             # data to be available.  Normally an anchor is used to make
 687             # sure the end of the output is matched, however, $mi_gdb_prompt
 688             # is just as good of an anchor since mi_gdb_test is meant to
 689             # match a single mi output command.  If a second GDB/MI output
 690             # response is sent, it will be in the buffer for the next
 691             # time mi_gdb_test is called.
 692             if ![string match "" $message] then {
 693                 pass "$message"
 694             }
 695             set result 0
 696         }
 697          -re "(${question_string})$" {
 698             send_gdb "$response_string\n"
 699             exp_continue
 700         }
 701          -re "Undefined.* command:.*$mi_gdb_prompt\[ \]*$" {
 702             perror "Undefined command \"$command\"."
 703              fail "$message"
 704             set result 1
 705         }
 706          -re "Ambiguous command.*$mi_gdb_prompt\[ \]*$" {
 707             perror "\"$command\" is not a unique command name."
 708              fail "$message"
 709             set result 1
 710         }
 711          -re "$inferior_exited_re with code \[0-9\]+.*$mi_gdb_prompt\[ \]*$" {
 712             if ![string match "" $message] then {
 713                 set errmsg "$message (the program exited)"
 714             } else {
 715                 set errmsg "$command (the program exited)"
 716             }
 717             fail "$errmsg"
 718             return -1
 719         }
 720          -re "The program is not being run.*$mi_gdb_prompt\[ \]*$" {
 721             if ![string match "" $message] then {
 722                 set errmsg "$message (the program is no longer running)"
 723             } else {
 724                 set errmsg "$command (the program is no longer running)"
 725             }
 726             fail "$errmsg"
 727             return -1
 728         }
 729          -re ".*$mi_gdb_prompt\[ \]*$" {
 730             if ![string match "" $message] then {
 731                 fail "$message"
 732             }
 733             set result 1
 734         }
 735          "<return>" {
 736             send_gdb "\n"
 737             perror "Window too small."
 738              fail "$message"
 739         }
 740          -re "\\(y or n\\) " {
 741             send_gdb "n\n"
 742             perror "Got interactive prompt."
 743              fail "$message"
 744         }
 745          eof {
 746              perror "Process no longer exists"
 747              if { $message != "" } {
 748                  fail "$message"
 749              }
 750              return -1
 751         }
 752          full_buffer {
 753             perror "internal buffer is full."
 754              fail "$message"
 755         }
 756         timeout {
 757             if ![string match "" $message] then {
 758                 fail "$message (timeout)"
 759             }
 760             set result 1
 761         }
 762     }
 763
 764     # If the GDB output matched, compare the inferior output.
 765     if { $result == 0 } {
 766         if [ info exists ipattern ] {
 767             if { ![target_info exists gdb,noinferiorio] } {
 768                 if { [target_info gdb_protocol] == "remote"
 769                     || [target_info gdb_protocol] == "extended-remote"
 770                     || [target_info protocol] == "sim"} {
 771
 772                     gdb_expect {
 773                         -re "$ipattern" {
 774                             pass "$message inferior output"
 775                         }
 776                         timeout {
 777                             fail "$message inferior output (timeout)"
 778                             set result 1
 779                         }
 780                     }
 781                 } else {
 782                     global mi_inferior_spawn_id
 783                     expect {
 784                         -i $mi_inferior_spawn_id -re "$ipattern" {
 785                             pass "$message inferior output"
 786                         }
 787                         timeout {
 788                             fail "$message inferior output (timeout)"
 789                             set result 1
 790                         }
 791                     }
 792                 }
 793             } else {
 794                 unsupported "$message inferior output"
 795             }
 796         }
 797     }
 798
 799     return $result
 800 }
 801
 802 # Collect output sent to the console output stream until UNTIL is
 803 # seen.  UNTIL is a regular expression.  MESSAGE is the message to be
 804 # printed in case of timeout.
 805
 806 proc mi_gdb_expect_cli_output {until message} {
 807
 808     set output ""
 809     gdb_expect {
 810         -re "~\"(\[^\r\n\]+)\"\r\n" {
 811             append output $expect_out(1,string)
 812             exp_continue
 813         }
 814         -notransfer -re "$until" {
 815             # Done
 816         }
 817         timeout {
 818             fail "$message (timeout)"
 819             return ""
 820         }
 821     }
 822
 823     return $output
 824 }
 825
 826 #
 827 # MI run command.  (A modified version of gdb_run_cmd)
 828 #
 829
 830 # In patterns, the newline sequence ``\r\n'' is matched explicitly as
 831 # ``.*$'' could swallow up output that we attempt to match elsewhere.
 832
 833 # Send the command to run the test program.
 834 #
 835 # If USE_MI_COMMAND is true, the "-exec-run" command is used.
 836 # Otherwise, the "run" (CLI) command is used.  If the global USE_GDB_STUB is
 837 # true, -exec-continue and continue are used instead of their run counterparts.
 838 #
 839 # ARGS is passed as argument to the command used to run the test program.
 840 # Beware that arguments to "-exec-run" do not have the same semantics as
 841 # arguments to the "run" command, so USE_MI_COMMAND influences the meaning
 842 # of ARGS.  If USE_MI_COMMAND is true, they are arguments to -exec-run.
 843 # If USE_MI_COMMAND is false, they are effectively arguments passed
 844 # to the test program.  If the global USE_GDB_STUB is true, ARGS is not used.
 845 proc mi_run_cmd_full {use_mi_command args} {
 846     global suppress_flag
 847     if { $suppress_flag } {
 848         return -1
 849     }
 850     global mi_gdb_prompt use_gdb_stub
 851     global thread_selected_re
 852     global library_loaded_re
 853
 854     if {$use_mi_command} {
 855         set run_prefix "220-exec-"
 856         set run_match "220"
 857     } else {
 858         set run_prefix ""
 859         set run_match ""
 860     }
 861
 862     if [target_info exists gdb_init_command] {
 863         send_gdb "[target_info gdb_init_command]\n"
 864         gdb_expect 30 {
 865             -re "$mi_gdb_prompt$" { }
 866             default {
 867                 perror "gdb_init_command for target failed"
 868                 return -1
 869             }
 870         }
 871     }
 872
 873     if { [mi_gdb_target_load] < 0 } {
 874         return -1
 875     }
 876
 877     if $use_gdb_stub {
 878         if [target_info exists gdb,do_reload_on_run] {
 879             send_gdb "${run_prefix}continue\n"
 880             gdb_expect 60 {
 881                 -re "${run_match}\\^running\[\r\n\]+\\*running,thread-id=\"\[^\"\]+\"\r\n$mi_gdb_prompt" {}
 882                 -re "${run_match}\\^error.*$mi_gdb_prompt" {return -1}
 883                 default {}
 884             }
 885             return 0
 886         }
 887
 888         if [target_info exists gdb,start_symbol] {
 889             set start [target_info gdb,start_symbol]
 890         } else {
 891             set start "start"
 892         }
 893
 894         # HACK: Should either use 000-jump or fix the target code
 895         # to better handle RUN.
 896         send_gdb  "jump *$start\n"
 897         warning "Using CLI jump command, expect run-to-main FAIL"
 898         return 0
 899     }
 900
 901     send_gdb "${run_prefix}run $args\n"
 902     gdb_expect {
 903         -re "${run_match}\\^running\r\n(\\*running,thread-id=\"\[^\"\]+\"\r\n|=thread-created,id=\"1\",group-id=\"\[0-9\]+\"\r\n)*(${library_loaded_re})*(${thread_selected_re})?${mi_gdb_prompt}" {
 904         }
 905         -re "\\^error,msg=\"The target does not support running in non-stop mode.\"" {
 906             unsupported "Non-stop mode not supported"
 907             return -1
 908         }
 909         timeout {
 910             perror "Unable to start target"
 911             return -1
 912         }
 913     }
 914     # NOTE: Shortly after this there will be a ``000*stopped,...(gdb)''
 915
 916     return 0
 917 }
 918
 919 # A wrapper for mi_run_cmd_full which uses -exec-run and
 920 # -exec-continue, as appropriate.  ARGS are passed verbatim to
 921 # mi_run_cmd_full.
 922 proc mi_run_cmd {args} {
 923     return [eval mi_run_cmd_full 1 $args]
 924 }
 925
 926 # A wrapper for mi_run_cmd_full which uses the CLI commands 'run' and
 927 # 'continue', as appropriate.  ARGS are passed verbatim to
 928 # mi_run_cmd_full.
 929 proc mi_run_with_cli {args} {
 930     return [eval mi_run_cmd_full 0 $args]
 931 }
 932
 933 #
 934 # Just like run-to-main but works with the MI interface
 935 #
 936
 937 proc mi_run_to_main { } {
 938     global suppress_flag
 939     if { $suppress_flag } {
 940         return -1
 941     }
 942
 943     global srcdir
 944     global subdir
 945     global binfile
 946     global srcfile
 947
 948     mi_delete_breakpoints
 949     mi_gdb_reinitialize_dir $srcdir/$subdir
 950     mi_gdb_load ${binfile}
 951
 952     mi_runto main
 953 }
 954
 955
 956 # Just like gdb's "runto" proc, it will run the target to a given
 957 # function.  The big difference here between mi_runto and mi_execute_to
 958 # is that mi_execute_to must have the inferior running already.  This
 959 # proc will (like gdb's runto) (re)start the inferior, too.
 960 #
 961 # FUNC is the linespec of the place to stop (it inserts a breakpoint here).
 962 # It returns:
 963 #   -1  if test suppressed, failed, timedout
 964 #    0  if test passed
 965
 966 proc mi_runto_helper {func run_or_continue} {
 967   global suppress_flag
 968   if { $suppress_flag } {
 969     return -1
 970   }
 971
 972   global mi_gdb_prompt expect_out
 973   global hex decimal fullname_syntax
 974
 975   set test "mi runto $func"
 976   set bp [mi_make_breakpoint -type breakpoint -disp del \
 977               -func $func\(\\\(.*\\\)\)?]
 978   mi_gdb_test "200-break-insert -t $func" "200\\^done,$bp" \
 979       "breakpoint at $func"
 980
 981   if {$run_or_continue == "run"} {
 982       if { [mi_run_cmd] < 0 } {
 983           return -1
 984       }
 985   } else {
 986       mi_send_resuming_command "exec-continue" "$test"
 987   }
 988
 989   mi_expect_stop "breakpoint-hit" $func ".*" ".*" "\[0-9\]+" { "" "disp=\"del\"" } $test
 990 }
 991
 992 proc mi_runto {func} {
 993     return [mi_runto_helper $func "run"]
 994 }
 995
 996 # Next to the next statement
 997 # For return values, see mi_execute_to_helper
 998
 999 proc mi_next { test } {
1000   return [mi_next_to {.*} {.*} {.*} {.*} $test]
1001 }
1002
1003
1004 # Step to the next statement
1005 # For return values, see mi_execute_to_helper
1006
1007 proc mi_step { test } {
1008   return [mi_step_to {.*} {.*} {.*} {.*} $test]
1009 }
1010
1011 set async "unknown"
1012
1013 proc mi_detect_async {} {
1014     global async
1015     global mi_gdb_prompt
1016
1017     send_gdb "show target-async\n"
1018
1019     gdb_expect {
1020         -re ".*Controlling the inferior in asynchronous mode is on...*$mi_gdb_prompt$" {
1021             set async 1
1022         }
1023         -re ".*$mi_gdb_prompt$" {
1024             set async 0
1025         }
1026         timeout {
1027             set async 0
1028         }
1029     }
1030     return $async
1031 }
1032
1033 # Wait for MI *stopped notification to appear.
1034 # The REASON, FUNC, ARGS, FILE and LINE are regular expressions
1035 # to match against whatever is output in *stopped.  FILE may also match
1036 # filename of a file without debug info.  ARGS should not include [] the
1037 # list of argument is enclosed in, and other regular expressions should
1038 # not include quotes.
1039 # If EXTRA is a list of one element, it's the regular expression
1040 # for output expected right after *stopped, and before GDB prompt.
1041 # If EXTRA is a list of two elements, the first element is for
1042 # output right after *stopped, and the second element is output
1043 # right after reason field.  The regex after reason should not include
1044 # the comma separating it from the following fields.
1045 #
1046 # When we fail to match output at all, -1 is returned.  If FILE does
1047 # match and the target system has no debug info for FILE return 0.
1048 # Otherwise, the line at which we stop is returned.  This is useful when
1049 # exact line is not possible to specify for some reason -- one can pass
1050 # the .* or "\[0-9\]*" regexps for line, and then check the line
1051 # programmatically.
1052 #
1053 # Do not pass .* for any argument if you are expecting more than one stop.
1054 proc mi_expect_stop { reason func args file line extra test } {
1055
1056     global mi_gdb_prompt
1057     global hex
1058     global decimal
1059     global fullname_syntax
1060     global async
1061     global thread_selected_re
1062     global breakpoint_re
1063
1064     set any "\[^\n\]*"
1065
1066     set after_stopped ""
1067     set after_reason ""
1068     if { [llength $extra] == 2 } {
1069         set after_stopped [lindex $extra 0]
1070         set after_reason [lindex $extra 1]
1071         set after_reason "${after_reason},"
1072     } elseif { [llength $extra] == 1 } {
1073         set after_stopped [lindex $extra 0]
1074     }
1075
1076     if {$async} {
1077         set prompt_re ""
1078     } else {
1079         set prompt_re "$mi_gdb_prompt$"
1080     }
1081
1082     if { $reason == "really-no-reason" } {
1083         gdb_expect {
1084             -re "\\*stopped\r\n$prompt_re" {
1085                 pass "$test"
1086             }
1087             timeout {
1088                 fail "$test (timeout)"
1089             }
1090         }
1091         return
1092     }
1093
1094     if { $reason == "exited-normally" } {
1095
1096         gdb_expect {
1097             -re "\\*stopped,reason=\"exited-normally\"\r\n$prompt_re" {
1098                 pass "$test"
1099             }
1100             -re ".*$mi_gdb_prompt$" {fail "continue to end (2)"}
1101             timeout {
1102                 fail "$test (timeout)"
1103             }
1104         }
1105         return
1106     }
1107     if { $reason == "exited" } {
1108         gdb_expect {
1109             -re "\\*stopped,reason=\"exited\",exit-code=\"\[0-7\]+\"\r\n$prompt_re" {
1110                 pass "$test"
1111             }
1112             -re ".*$mi_gdb_prompt$" {
1113                 fail "$test (inferior not stopped)"
1114             }
1115             timeout {
1116                 fail "$test (timeout)"
1117             }
1118         }
1119         return
1120     }
1121
1122     if { $reason == "solib-event" } {
1123         set pattern "\\*stopped,reason=\"solib-event\",thread-id=\"$decimal\",stopped-threads=$any\r\n($thread_selected_re|$breakpoint_re)*$prompt_re"
1124         verbose -log "mi_expect_stop: expecting: $pattern"
1125         gdb_expect {
1126             -re "$pattern" {
1127                 pass "$test"
1128             }
1129             timeout {
1130                 fail "$test (timeout)"
1131             }
1132         }
1133         return
1134     }
1135
1136     set args "\\\[$args\\\]"
1137
1138     set bn ""
1139     if { $reason == "breakpoint-hit" } {
1140         set bn {bkptno="[0-9]+",}
1141     } elseif { $reason == "solib-event" } {
1142         set bn ".*"
1143     }
1144
1145     set r ""
1146     if { $reason != "" } {
1147         set r "reason=\"$reason\","
1148     }
1149
1150
1151     set a $after_reason
1152
1153     verbose -log "mi_expect_stop: expecting: \\*stopped,${r}${a}${bn}frame=\{addr=\"$hex\",func=\"$func\",args=$args,(?:file=\"$any$file\",fullname=\"${fullname_syntax}$file\",line=\"$line\"|from=\"$file\")\}$after_stopped,thread-id=\"$decimal\",stopped-threads=$any\r\n($thread_selected_re|$breakpoint_re)*$prompt_re"
1154     gdb_expect {
1155         -re "\\*stopped,${r}${a}${bn}frame=\{addr=\"$hex\",func=\"$func\",args=$args,(?:file=\"$any$file\",fullname=\"${fullname_syntax}$file\",line=\"($line)\"|from=\"$file\")\}$after_stopped,thread-id=\"$decimal\",stopped-threads=$any\r\n($thread_selected_re|$breakpoint_re)*$prompt_re" {
1156             pass "$test"
1157             if {[array names expect_out "2,string"] != ""} {
1158                 return $expect_out(2,string)
1159             }
1160             # No debug info available but $file does match.
1161             return 0
1162         }
1163         -re "\\*stopped,${r}${a}${bn}frame=\{addr=\"$hex\",func=\"$any\",args=\[\\\[\{\]$any\[\\\]\}\],file=\"$any\",fullname=\"${fullname_syntax}$any\",line=\"\[0-9\]*\"\}$after_stopped,thread-id=\"$decimal\",stopped-threads=$any\r\n($thread_selected_re|$breakpoint_re)*$prompt_re" {
1164             verbose -log "got $expect_out(buffer)"
1165             fail "$test (stopped at wrong place)"
1166             return -1
1167         }
1168         -re ".*\r\n$mi_gdb_prompt$" {
1169             verbose -log "got $expect_out(buffer)"
1170             fail "$test (unknown output after running)"
1171             return -1
1172         }
1173         timeout {
1174             fail "$test (timeout)"
1175             return -1
1176         }
1177     }
1178 }
1179
1180 # Wait for MI *stopped notification related to an interrupt request to
1181 # appear.
1182 proc mi_expect_interrupt { test } {
1183     global mi_gdb_prompt
1184     global decimal
1185     global async
1186
1187     if {$async} {
1188         set prompt_re ""
1189     } else {
1190         set prompt_re "$mi_gdb_prompt$"
1191     }
1192
1193     set r "reason=\"signal-received\",signal-name=\"0\",signal-meaning=\"Signal 0\""
1194
1195     set any "\[^\n\]*"
1196
1197     # A signal can land anywhere, just ignore the location
1198     verbose -log "mi_expect_interrupt: expecting: \\*stopped,${r}$any\r\n$prompt_re"
1199     gdb_expect {
1200         -re "\\*stopped,${r}$any\r\n$prompt_re" {
1201             pass "$test"
1202             return 0
1203         }
1204         -re ".*\r\n$mi_gdb_prompt$" {
1205             verbose -log "got $expect_out(buffer)"
1206             fail "$test (unknown output after running)"
1207             return -1
1208         }
1209         timeout {
1210             fail "$test (timeout)"
1211             return -1
1212         }
1213     }
1214 }
1215
1216 # cmd should not include the number or newline (i.e. "exec-step 3", not
1217 # "220-exec-step 3\n"
1218
1219 # Can not match -re ".*\r\n${mi_gdb_prompt}", because of false positives
1220 # after the first prompt is printed.
1221
1222 proc mi_execute_to { cmd reason func args file line extra test } {
1223     global suppress_flag
1224     if { $suppress_flag } {
1225         return -1
1226     }
1227
1228     mi_send_resuming_command "$cmd" "$test"
1229     set r [mi_expect_stop $reason $func $args $file $line $extra $test]
1230     return $r
1231 }
1232
1233 proc mi_next_to { func args file line test } {
1234     mi_execute_to "exec-next" "end-stepping-range" "$func" "$args" \
1235         "$file" "$line" "" "$test"
1236 }
1237
1238 proc mi_step_to { func args file line test } {
1239     mi_execute_to "exec-step" "end-stepping-range" "$func" "$args" \
1240         "$file" "$line" "" "$test"
1241 }
1242
1243 proc mi_finish_to { func args file line result ret test } {
1244     mi_execute_to "exec-finish" "function-finished" "$func" "$args" \
1245         "$file" "$line" \
1246         ",gdb-result-var=\"$result\",return-value=\"$ret\"" \
1247         "$test"
1248 }
1249
1250 proc mi_continue_to {func} {
1251     mi_runto_helper $func "continue"
1252 }
1253
1254 proc mi0_execute_to { cmd reason func args file line extra test } {
1255     mi_execute_to_helper "$cmd" "$reason" "$func" "\{$args\}" \
1256         "$file" "$line" "$extra" "$test"
1257 }
1258
1259 proc mi0_next_to { func args file line test } {
1260     mi0_execute_to "exec-next" "end-stepping-range" "$func" "$args" \
1261         "$file" "$line" "" "$test"
1262 }
1263
1264 proc mi0_step_to { func args file line test } {
1265     mi0_execute_to "exec-step" "end-stepping-range" "$func" "$args" \
1266         "$file" "$line" "" "$test"
1267 }
1268
1269 proc mi0_finish_to { func args file line result ret test } {
1270     mi0_execute_to "exec-finish" "function-finished" "$func" "$args" \
1271         "$file" "$line" \
1272         ",gdb-result-var=\"$result\",return-value=\"$ret\"" \
1273         "$test"
1274 }
1275
1276 proc mi0_continue_to { bkptno func args file line test } {
1277     mi0_execute_to "exec-continue" "breakpoint-hit\",bkptno=\"$bkptno" \
1278         "$func" "$args" "$file" "$line" "" "$test"
1279 }
1280
1281 # Creates a breakpoint and checks the reported fields are as expected.
1282 # This procedure takes the same options as mi_make_breakpoint and
1283 # returns the breakpoint regexp from that procedure.
1284
1285 proc mi_create_breakpoint {location test args} {
1286     set bp [eval mi_make_breakpoint $args]
1287     mi_gdb_test "222-break-insert $location" "222\\^done,$bp" $test
1288     return $bp
1289 }
1290
1291 # Creates varobj named NAME for EXPRESSION.
1292 # Name cannot be "-".
1293 proc mi_create_varobj { name expression testname } {
1294     mi_gdb_test "-var-create $name * $expression" \
1295         "\\^done,name=\"$name\",numchild=\"\[0-9\]+\",value=\".*\",type=.*,has_more=\"0\"" \
1296         $testname
1297 }
1298
1299 proc mi_create_floating_varobj { name expression testname } {
1300     mi_gdb_test "-var-create $name @ $expression" \
1301         "\\^done,name=\"$name\",numchild=\"\(-1\|\[0-9\]+\)\",value=\".*\",type=.*" \
1302         $testname
1303 }
1304
1305
1306 # Same as mi_create_varobj, but also checks the reported type
1307 # of the varobj.
1308 proc mi_create_varobj_checked { name expression type testname } {
1309     mi_gdb_test "-var-create $name * $expression" \
1310         "\\^done,name=\"$name\",numchild=\"\[0-9\]+\",value=\".*\",type=\"$type\".*" \
1311         $testname
1312 }
1313
1314 # Same as mi_create_floating_varobj, but assumes the test is creating
1315 # a dynamic varobj that has children, so the value must be "{...}".
1316 # The "has_more" attribute is checked.
1317 proc mi_create_dynamic_varobj {name expression has_more testname} {
1318     mi_gdb_test "-var-create $name @ $expression" \
1319         "\\^done,name=\"$name\",numchild=\"0\",value=\"{\\.\\.\\.}\",type=.*,has_more=\"${has_more}\"" \
1320         $testname
1321 }
1322
1323 # Deletes the specified NAME.
1324 proc mi_delete_varobj { name testname } {
1325     mi_gdb_test "-var-delete $name" \
1326         "\\^done,ndeleted=.*" \
1327         $testname
1328 }
1329
1330 # Updates varobj named NAME and checks that all varobjs in EXPECTED
1331 # are reported as updated, and no other varobj is updated.
1332 # Assumes that no varobj is out of scope and that no varobj changes
1333 # types.
1334 proc mi_varobj_update { name expected testname } {
1335     set er "\\^done,changelist=\\\["
1336     set first 1
1337     foreach item $expected {
1338         set v "{name=\"$item\",in_scope=\"true\",type_changed=\"false\",has_more=\".\"}"
1339         if {$first == 1} {
1340             set er "$er$v"
1341             set first 0
1342         } else {
1343             set er "$er,$v"
1344         }
1345     }
1346     set er "$er\\\]"
1347
1348     verbose -log "Expecting: $er" 2
1349     mi_gdb_test "-var-update $name" $er $testname
1350 }
1351
1352 proc mi_varobj_update_with_child_type_change { name child_name new_type new_children testname } {
1353     set v "{name=\"$child_name\",in_scope=\"true\",type_changed=\"true\",new_type=\"$new_type\",new_num_children=\"$new_children\",has_more=\".\"}"
1354     set er "\\^done,changelist=\\\[$v\\\]"
1355     verbose -log "Expecting: $er"
1356     mi_gdb_test "-var-update $name" $er $testname
1357 }
1358
1359 proc mi_varobj_update_with_type_change { name new_type new_children testname } {
1360     mi_varobj_update_with_child_type_change $name $name $new_type $new_children $testname
1361 }
1362
1363 # A helper that turns a key/value list into a regular expression
1364 # matching some MI output.
1365 proc mi_varobj_update_kv_helper {list} {
1366     set first 1
1367     set rx ""
1368     foreach {key value} $list {
1369         if {!$first} {
1370             append rx ,
1371         }
1372         set first 0
1373         if {$key == "new_children"} {
1374             append rx "$key=\\\[$value\\\]"
1375         } else {
1376             append rx "$key=\"$value\""
1377         }
1378     }
1379     return $rx
1380 }
1381
1382 # A helper for mi_varobj_update_dynamic that computes a match
1383 # expression given a child list.
1384 proc mi_varobj_update_dynamic_helper {children} {
1385     set crx ""
1386
1387     set first 1
1388     foreach child $children {
1389         if {!$first} {
1390             append crx ,
1391         }
1392         set first 0
1393         append crx "{"
1394         append crx [mi_varobj_update_kv_helper $child]
1395         append crx "}"
1396     }
1397
1398     return $crx
1399 }
1400
1401 # Update a dynamic varobj named NAME.  CHILDREN is a list of children
1402 # that have been updated; NEW_CHILDREN is a list of children that were
1403 # added to the primary varobj.  Each child is a list of key/value
1404 # pairs that are expected.  SELF is a key/value list holding
1405 # information about the varobj itself.  TESTNAME is the name of the
1406 # test.
1407 proc mi_varobj_update_dynamic {name testname self children new_children} {
1408     if {[llength $new_children]} {
1409         set newrx [mi_varobj_update_dynamic_helper $new_children]
1410         lappend self new_children $newrx
1411     }
1412     set selfrx [mi_varobj_update_kv_helper $self]
1413     set crx [mi_varobj_update_dynamic_helper $children]
1414
1415     set er "\\^done,changelist=\\\[\{name=\"$name\",in_scope=\"true\""
1416     append er ",$selfrx\}"
1417     if {"$crx" != ""} {
1418         append er ",$crx"
1419     }
1420     append er "\\\]"
1421
1422     verbose -log "Expecting: $er"
1423     mi_gdb_test "-var-update $name" $er $testname
1424 }
1425
1426 proc mi_check_varobj_value { name value testname } {
1427
1428     mi_gdb_test "-var-evaluate-expression $name" \
1429         "\\^done,value=\"$value\"" \
1430         $testname
1431 }
1432
1433 # Helper proc which constructs a child regexp for
1434 # mi_list_varobj_children and mi_varobj_update_dynamic.
1435 proc mi_child_regexp {children add_child} {
1436     set children_exp {}
1437
1438     if {$add_child} {
1439         set pre "child="
1440     } else {
1441         set pre ""
1442     }
1443
1444     foreach item $children {
1445
1446         set name [lindex $item 0]
1447         set exp [lindex $item  1]
1448         set numchild [lindex $item 2]
1449         if {[llength $item] == 5} {
1450             set type [lindex $item 3]
1451             set value [lindex $item 4]
1452
1453             lappend children_exp\
1454                 "$pre{name=\"$name\",exp=\"$exp\",numchild=\"$numchild\",value=\"$value\",type=\"$type\"(,thread-id=\"\[0-9\]+\")?}"
1455         } elseif {[llength $item] == 4} {
1456             set type [lindex $item 3]
1457
1458             lappend children_exp\
1459                 "$pre{name=\"$name\",exp=\"$exp\",numchild=\"$numchild\",type=\"$type\"(,thread-id=\"\[0-9\]+\")?}"
1460         } else {
1461             lappend children_exp\
1462                 "$pre{name=\"$name\",exp=\"$exp\",numchild=\"$numchild\"(,thread-id=\"\[0-9\]+\")?}"
1463         }
1464     }
1465     return [join $children_exp ","]
1466 }
1467
1468 # Check the results of the:
1469 #
1470 #   -var-list-children VARNAME
1471 #
1472 # command.  The CHILDREN parement should be a list of lists.
1473 # Each inner list can have either 3 or 4 elements, describing
1474 # fields that gdb is expected to report for child variable object,
1475 # in the following order
1476 #
1477 #   - Name
1478 #   - Expression
1479 #   - Number of children
1480 #   - Type
1481 #
1482 # If inner list has 3 elements, the gdb is expected to output no
1483 # type for a child and no value.
1484 #
1485 # If the inner list has 4 elements, gdb output is expected to
1486 # have no value.
1487 #
1488 proc mi_list_varobj_children { varname children testname } {
1489     mi_list_varobj_children_range $varname "" "" [llength $children] $children \
1490       $testname
1491 }
1492
1493 # Like mi_list_varobj_children, but sets a subrange.  NUMCHILDREN is
1494 # the total number of children.
1495 proc mi_list_varobj_children_range {varname from to numchildren children testname} {
1496     set options ""
1497     if {[llength $varname] == 2} {
1498         set options [lindex $varname 1]
1499         set varname [lindex $varname 0]
1500     }
1501
1502     set children_exp_j [mi_child_regexp $children 1]
1503     if {$numchildren} {
1504         set expected "\\^done,numchild=\".*\",children=\\\[$children_exp_j.*\\\]"
1505     } {
1506         set expected "\\^done,numchild=\"0\""
1507     }
1508
1509     if {"$to" == ""} {
1510         append expected ",has_more=\"0\""
1511     } elseif {$to >= 0 && $numchildren > $to} {
1512         append expected ",has_more=\"1\""
1513     } else {
1514         append expected ",has_more=\"0\""
1515     }
1516
1517     verbose -log "Expecting: $expected"
1518
1519     mi_gdb_test "-var-list-children $options $varname $from $to" \
1520       $expected $testname
1521 }
1522
1523 # Verifies that variable object VARNAME has NUMBER children,
1524 # where each one is named $VARNAME.<index-of-child> and has type TYPE.
1525 proc mi_list_array_varobj_children { varname number type testname } {
1526     mi_list_array_varobj_children_with_index $varname $number 0 $type $testname
1527 }
1528
1529 # Same as mi_list_array_varobj_children, but allowing to pass a start index
1530 # for an array.
1531 proc mi_list_array_varobj_children_with_index { varname number start_index \
1532   type testname } {
1533     set t {}
1534     set index $start_index
1535     for {set i 0} {$i < $number} {incr i} {
1536         lappend t [list $varname.$index $index 0 $type]
1537         incr index
1538     }
1539     mi_list_varobj_children $varname $t $testname
1540 }
1541
1542 # A list of two-element lists.  First element of each list is
1543 # a Tcl statement, and the second element is the line
1544 # number of source C file where the statement originates.
1545 set mi_autotest_data ""
1546 # The name of the source file for autotesting.
1547 set mi_autotest_source ""
1548
1549 proc count_newlines { string } {
1550     return [regexp -all "\n" $string]
1551 }
1552
1553 # Prepares for running inline tests in FILENAME.
1554 # See comments for mi_run_inline_test for detailed
1555 # explanation of the idea and syntax.
1556 proc mi_prepare_inline_tests { filename } {
1557
1558     global srcdir
1559     global subdir
1560     global mi_autotest_source
1561     global mi_autotest_data
1562
1563     set mi_autotest_data {}
1564
1565     set mi_autotest_source $filename
1566
1567     if { ! [regexp "^/" "$filename"] } then {
1568         set filename "$srcdir/$subdir/$filename"
1569     }
1570
1571     set chan [open $filename]
1572     set content [read $chan]
1573     set line_number 1
1574     while {1} {
1575         set start [string first "/*:" $content]
1576         if {$start != -1} {
1577             set end [string first ":*/" $content]
1578             if {$end == -1} {
1579                 error "Unterminated special comment in $filename"
1580             }
1581
1582             set prefix [string range $content 0 $start]
1583             set prefix_newlines [count_newlines $prefix]
1584
1585             set line_number [expr $line_number+$prefix_newlines]
1586             set comment_line $line_number
1587
1588             set comment [string range $content [expr $start+3] [expr $end-1]]
1589
1590             set comment_newlines [count_newlines $comment]
1591             set line_number [expr $line_number+$comment_newlines]
1592
1593             set comment [string trim $comment]
1594             set content [string range $content [expr $end+3] \
1595                              [string length $content]]
1596             lappend mi_autotest_data [list $comment $comment_line]
1597         } else {
1598             break
1599         }
1600     }
1601     close $chan
1602 }
1603
1604 # Helper to mi_run_inline_test below.
1605 # Return the list of all (statement,line_number) lists
1606 # that comprise TESTCASE.  The begin and end markers
1607 # are not included.
1608 proc mi_get_inline_test {testcase} {
1609
1610     global mi_gdb_prompt
1611     global mi_autotest_data
1612     global mi_autotest_source
1613
1614     set result {}
1615
1616     set seen_begin 0
1617     set seen_end 0
1618     foreach l $mi_autotest_data {
1619
1620         set comment [lindex $l 0]
1621
1622         if {$comment == "BEGIN: $testcase"} {
1623             set seen_begin 1
1624         } elseif {$comment == "END: $testcase"} {
1625             set seen_end 1
1626             break
1627         } elseif {$seen_begin==1} {
1628             lappend result $l
1629         }
1630     }
1631
1632     if {$seen_begin == 0} {
1633         error "Autotest $testcase not found"
1634     }
1635
1636     if {$seen_begin == 1 && $seen_end == 0} {
1637         error "Missing end marker for test $testcase"
1638     }
1639
1640     return $result
1641 }
1642
1643 # Sets temporary breakpoint at LOCATION.
1644 proc mi_tbreak {location} {
1645
1646     global mi_gdb_prompt
1647
1648     mi_gdb_test "-break-insert -t $location" \
1649         {\^done,bkpt=.*} \
1650         "run to $location (set breakpoint)"
1651 }
1652
1653 # Send COMMAND that must be a command that resumes
1654 # the inferior (run/continue/next/etc) and consumes
1655 # the "^running" output from it.
1656 proc mi_send_resuming_command_raw {command test} {
1657
1658     global mi_gdb_prompt
1659     global thread_selected_re
1660     global library_loaded_re
1661
1662     send_gdb "$command\n"
1663     gdb_expect {
1664         -re "\\^running\r\n\\*running,thread-id=\"\[^\"\]+\"\r\n($library_loaded_re)*($thread_selected_re)?${mi_gdb_prompt}" {
1665             # Note that lack of 'pass' call here -- this works around limitation
1666             # in DejaGNU xfail mechanism. mi-until.exp has this:
1667             #
1668             #     setup_kfail gdb/2104 "*-*-*"
1669             #     mi_execute_to ...
1670             #
1671             # and mi_execute_to uses mi_send_resuming_command.  If we use 'pass' here,
1672             # it will reset kfail, so when the actual test fails, it will be flagged
1673             # as real failure.
1674             return 0
1675         }
1676         -re "\\^error,msg=\"Displaced stepping is only supported in ARM mode\".*" {
1677             unsupported "$test (Thumb mode)"
1678             return -1
1679         }
1680         -re "\\^error,msg=.*" {
1681             fail "$test (MI error)"
1682             return -1
1683         }
1684         -re ".*${mi_gdb_prompt}" {
1685             fail "$test (failed to resume)"
1686             return -1
1687         }
1688         timeout {
1689             fail "$test"
1690             return -1
1691         }
1692     }
1693 }
1694
1695 proc mi_send_resuming_command {command test} {
1696     mi_send_resuming_command_raw -$command $test
1697 }
1698
1699 # Helper to mi_run_inline_test below.
1700 # Sets a temporary breakpoint at LOCATION and runs
1701 # the program using COMMAND.  When the program is stopped
1702 # returns the line at which it.  Returns -1 if line cannot
1703 # be determined.
1704 # Does not check that the line is the same as requested.
1705 # The caller can check itself if required.
1706 proc mi_continue_to_line {location test} {
1707
1708     mi_tbreak $location
1709     mi_send_resuming_command "exec-continue" "run to $location (exec-continue)"
1710     return [mi_get_stop_line $test]
1711 }
1712
1713 # Wait until gdb prints the current line.
1714 proc mi_get_stop_line {test} {
1715
1716   global mi_gdb_prompt
1717   global async
1718
1719   if {$async} {
1720       set prompt_re ""
1721   } else {
1722       set prompt_re "$mi_gdb_prompt$"
1723   }
1724
1725   gdb_expect {
1726       -re ".*line=\"(\[0-9\]*)\".*\r\n$prompt_re" {
1727           return $expect_out(1,string)
1728       }
1729       -re ".*$mi_gdb_prompt" {
1730           fail "wait for stop ($test)"
1731       }
1732       timeout {
1733           fail "wait for stop ($test)"
1734       }
1735   }
1736 }
1737
1738 # Run a MI test embedded in comments in a C file.
1739 # The C file should contain special comments in the following
1740 # three forms:
1741 #
1742 #    /*: BEGIN: testname :*/
1743 #    /*:  <Tcl statements> :*/
1744 #    /*: END: testname :*/
1745 #
1746 # This procedure find the begin and end marker for the requested
1747 # test. Then, a temporary breakpoint is set at the begin
1748 # marker and the program is run (from start).
1749 #
1750 # After that, for each special comment between the begin and end
1751 # marker, the Tcl statements are executed.  It is assumed that
1752 # for each comment, the immediately preceding line is executable
1753 # C statement.  Then, gdb will be single-stepped until that
1754 # preceding C statement is executed, and after that the
1755 # Tcl statements in the comment will be executed.
1756 #
1757 # For example:
1758 #
1759 #     /*: BEGIN: assignment-test :*/
1760 #     v = 10;
1761 #     /*: <Tcl code to check that 'v' is indeed 10 :*/
1762 #     /*: END: assignment-test :*/
1763 #
1764 # The mi_prepare_inline_tests function should be called before
1765 # calling this function.  A given C file can contain several
1766 # inline tests.  The names of the tests must be unique within one
1767 # C file.
1768 #
1769 proc mi_run_inline_test { testcase } {
1770
1771     global mi_gdb_prompt
1772     global hex
1773     global decimal
1774     global fullname_syntax
1775     global mi_autotest_source
1776
1777     set commands [mi_get_inline_test $testcase]
1778
1779     set first 1
1780     set line_now 1
1781
1782     foreach c $commands {
1783         set statements [lindex $c 0]
1784         set line [lindex $c 1]
1785         set line [expr $line-1]
1786
1787         # We want gdb to be stopped at the expression immediately
1788         # before the comment.  If this is the first comment, the
1789         # program is either not started yet or is in some random place,
1790         # so we run it.  For further comments, we might be already
1791         # standing at the right line. If not continue till the
1792         # right line.
1793
1794         if {$first==1} {
1795             # Start the program afresh.
1796             mi_tbreak "$mi_autotest_source:$line"
1797             mi_run_cmd
1798             set line_now [mi_get_stop_line "$testcase: step to $line"]
1799             set first 0
1800         } elseif {$line_now!=$line} {
1801             set line_now [mi_continue_to_line "$mi_autotest_source:$line" "continue to $line"]
1802         }
1803
1804         if {$line_now!=$line} {
1805             fail "$testcase: go to line $line"
1806         }
1807
1808         # We're not at the statement right above the comment.
1809         # Execute that statement so that the comment can test
1810         # the state after the statement is executed.
1811
1812         # Single-step past the line.
1813         if { [mi_send_resuming_command "exec-next" "$testcase: step over $line"] != 0 } {
1814             return -1
1815         }
1816         set line_now [mi_get_stop_line "$testcase: step over $line"]
1817
1818         # We probably want to use 'uplevel' so that statements
1819         # have direct access to global variables that the
1820         # main 'exp' file has set up.  But it's not yet clear,
1821         # will need more experience to be sure.
1822         eval $statements
1823     }
1824 }
1825
1826 proc get_mi_thread_list {name} {
1827   global expect_out
1828
1829   # MI will return a list of thread ids:
1830   #
1831   # -thread-list-ids
1832   # ^done,thread-ids=[thread-id="1",thread-id="2",...],number-of-threads="N"
1833   # (gdb)
1834   mi_gdb_test "-thread-list-ids" \
1835     {.*\^done,thread-ids={(thread-id="[0-9]+"(,)?)+},current-thread-id="[0-9]+",number-of-threads="[0-9]+"} \
1836     "-thread_list_ids ($name)"
1837
1838   set output {}
1839   if {[info exists expect_out(buffer)]} {
1840     set output $expect_out(buffer)
1841   }
1842
1843   set thread_list {}
1844   if {![regexp {thread-ids=\{(thread-id="[0-9]+"(,)?)*\}} $output threads]} {
1845     fail "finding threads in MI output ($name)"
1846   } else {
1847     pass "finding threads in MI output ($name)"
1848
1849     # Make list of console threads
1850     set start [expr {[string first \{ $threads] + 1}]
1851     set end   [expr {[string first \} $threads] - 1}]
1852     set threads [string range $threads $start $end]
1853     foreach thread [split $threads ,] {
1854       if {[scan $thread {thread-id="%d"} num]} {
1855         lappend thread_list $num
1856       }
1857     }
1858   }
1859
1860   return $thread_list
1861 }
1862
1863 # Check that MI and the console know of the same threads.
1864 # Appends NAME to all test names.
1865 proc check_mi_and_console_threads {name} {
1866   global expect_out
1867
1868   mi_gdb_test "-thread-list-ids" \
1869     {.*\^done,thread-ids={(thread-id="[0-9]+"(,)*)+},current-thread-id="[0-9]+",number-of-threads="[0-9]+"} \
1870     "-thread-list-ids ($name)"
1871   set mi_output {}
1872   if {[info exists expect_out(buffer)]} {
1873     set mi_output $expect_out(buffer)
1874   }
1875
1876   # GDB will return a list of thread ids and some more info:
1877   #
1878   # (gdb)
1879   # -interpreter-exec console "info threads"
1880   # ~"  4 Thread 2051 (LWP 7734)  0x401166b1 in __libc_nanosleep () at __libc_nanosleep:-1"
1881   # ~"  3 Thread 1026 (LWP 7733)   () at __libc_nanosleep:-1"
1882   # ~"  2 Thread 2049 (LWP 7732)  0x401411f8 in __poll (fds=0x804bb24, nfds=1, timeout=2000) at ../sysdeps/unix/sysv/linux/poll.c:63"
1883   # ~"* 1 Thread 1024 (LWP 7731)  main (argc=1, argv=0xbfffdd94) at ../../../src/gdb/testsuite/gdb.mi/pthreads.c:160"
1884   # FIXME: kseitz/2002-09-05: Don't use the hack-cli method.
1885   mi_gdb_test "info threads" \
1886     {.*(~".*"[\r\n]*)+.*} \
1887     "info threads ($name)"
1888   set console_output {}
1889   if {[info exists expect_out(buffer)]} {
1890     set console_output $expect_out(buffer)
1891   }
1892
1893   # Make a list of all known threads to console (gdb's thread IDs)
1894   set console_thread_list {}
1895   foreach line [split $console_output \n] {
1896     if {[string index $line 0] == "~"} {
1897       # This is a line from the console; trim off "~", " ", "*", and "\""
1898       set line [string trim $line ~\ \"\*]
1899       if {[scan $line "%d" id] == 1} {
1900         lappend console_thread_list $id
1901       }
1902     }
1903   }
1904
1905   # Now find the result string from MI
1906   set mi_result ""
1907   foreach line [split $mi_output \n] {
1908     if {[string range $line 0 4] == "^done"} {
1909       set mi_result $line
1910     }
1911   }
1912   if {$mi_result == ""} {
1913     fail "finding MI result string ($name)"
1914   } else {
1915     pass "finding MI result string ($name)"
1916   }
1917
1918   # Finally, extract the thread ids and compare them to the console
1919   set num_mi_threads_str ""
1920   if {![regexp {number-of-threads="[0-9]+"} $mi_result num_mi_threads_str]} {
1921     fail "finding number of threads in MI output ($name)"
1922   } else {
1923     pass "finding number of threads in MI output ($name)"
1924
1925     # Extract the number of threads from the MI result
1926     if {![scan $num_mi_threads_str {number-of-threads="%d"} num_mi_threads]} {
1927       fail "got number of threads from MI ($name)"
1928     } else {
1929       pass "got number of threads from MI ($name)"
1930
1931       # Check if MI and console have same number of threads
1932       if {$num_mi_threads != [llength $console_thread_list]} {
1933         fail "console and MI have same number of threads ($name)"
1934       } else {
1935         pass "console and MI have same number of threads ($name)"
1936
1937         # Get MI thread list
1938         set mi_thread_list [get_mi_thread_list $name]
1939
1940         # Check if MI and console have the same threads
1941         set fails 0
1942         foreach ct [lsort $console_thread_list] mt [lsort $mi_thread_list] {
1943           if {$ct != $mt} {
1944             incr fails
1945           }
1946         }
1947         if {$fails > 0} {
1948           fail "MI and console have same threads ($name)"
1949
1950           # Send a list of failures to the log
1951           send_log "Console has thread ids: $console_thread_list\n"
1952           send_log "MI has thread ids: $mi_thread_list\n"
1953         } else {
1954           pass "MI and console have same threads ($name)"
1955         }
1956       }
1957     }
1958   }
1959 }
1960
1961 # Download shared libraries to the target.
1962 proc mi_load_shlibs { args } {
1963     if {![is_remote target]} {
1964         return
1965     }
1966
1967     foreach file $args {
1968         gdb_download [shlib_target_file $file]
1969     }
1970
1971     # Even if the target supplies full paths for shared libraries,
1972     # they may not be paths for this system.
1973     mi_gdb_test "set solib-search-path [file dirname [lindex $args 0]]" "\^done" ""
1974 }
1975
1976 proc mi_reverse_list { list } {
1977     if { [llength $list] <= 1 } {
1978         return $list
1979     }
1980     set tail [lrange $list 1 [llength $list]]
1981     set rtail [mi_reverse_list $tail]
1982     lappend rtail [lindex $list 0]
1983     return $rtail
1984 }
1985
1986 proc mi_check_thread_states { xstates test } {
1987     global expect_out
1988     set states [mi_reverse_list $xstates]
1989     set pattern ".*\\^done,threads=\\\["
1990     foreach s $states {
1991         set pattern "${pattern}(.*)state=\"$s\""
1992     }
1993     set pattern "${pattern}(,core=\"\[0-9\]*\")?\\\}\\\].*"
1994
1995     verbose -log "expecting: $pattern"
1996     mi_gdb_test "-thread-info" $pattern $test
1997 }
1998
1999 # Return a list of MI features supported by this gdb.
2000 proc mi_get_features {} {
2001     global expect_out mi_gdb_prompt
2002
2003     send_gdb "-list-features\n"
2004
2005     gdb_expect {
2006         -re "\\^done,features=\\\[(.*)\\\]\r\n$mi_gdb_prompt$" {
2007             regsub -all -- \" $expect_out(1,string) "" features
2008             return [split $features ,]
2009         }
2010         -re ".*\r\n$mi_gdb_prompt$" {
2011             verbose -log "got $expect_out(buffer)"
2012             return ""
2013         }
2014         timeout {
2015             verbose -log "timeout in mi_gdb_prompt"
2016             return ""
2017         }
2018     }
2019 }
2020
2021 # Variable Object Trees
2022 #
2023 # Yet another way to check varobjs. Pass mi_walk_varobj_tree a "list" of
2024 # variables (not unlike the actual source code definition), and it will
2025 # automagically test the children for you (by default).
2026 #
2027 # Example:
2028 #
2029 # source code:
2030 # struct bar {
2031 #   union {
2032 #     int integer;
2033 #     void *ptr;
2034 #   };
2035 #   const int *iPtr;
2036 # };
2037 #
2038 # class foo {
2039 # public:
2040 #   int a;
2041 #   struct {
2042 #     int b;
2043 #     struct bar *c;
2044 #   };
2045 # };
2046 #
2047 # foo *f = new foo (); <-- break here
2048 #
2049 # We want to check all the children of "f".
2050 #
2051 # Translate the above structures into the following tree:
2052 #
2053 # set tree {
2054 #   foo f {
2055 #     {} public {
2056 #       int a {}
2057 #       anonymous struct {
2058 #         {} public {
2059 #           int b {}
2060 #           {bar *} c {
2061 #             {} public {
2062 #               anonymous union {
2063 #                 {} public {
2064 #                   int integer {}
2065 #                   {void *} ptr {}
2066 #                 }
2067 #               }
2068 #               {const int *} iPtr {
2069 #                 {const int} {*iPtr} {}
2070 #               }
2071 #             }
2072 #           }
2073 #         }
2074 #       }
2075 #     }
2076 #   }
2077 # }
2078 #
2079 # mi_walk_varobj_tree c++ $tree
2080 #
2081 # If you'd prefer to walk the tree using your own callback,
2082 # simply pass the name of the callback to mi_walk_varobj_tree.
2083 #
2084 # This callback should take one argument, the name of the variable
2085 # to process.  This name is the name of a global array holding the
2086 # variable's properties (object name, type, etc).
2087 #
2088 # An example callback:
2089 #
2090 # proc my_callback {var} {
2091 #   upvar #0 $var varobj
2092 #
2093 #   puts "my_callback: called on varobj $varobj(obj_name)"
2094 # }
2095 #
2096 # The arrays created for each variable object contain the following
2097 # members:
2098 #
2099 # obj_name     - the object name for accessing this variable via MI
2100 # display_name - the display name for this variable (exp="display_name" in
2101 #                the output of -var-list-children)
2102 # type         - the type of this variable (type="type" in the output
2103 #                of -var-list-children, or the special tag "anonymous"
2104 # path_expr    - the "-var-info-path-expression" for this variable
2105 #                NOTE: This member cannot be used reliably with typedefs.
2106 #                Use with caution!
2107 #                See notes inside get_path_expr for more.
2108 # parent       - the variable name of the parent varobj
2109 # children     - a list of children variable names (which are the
2110 #                names Tcl arrays, not object names)
2111 #
2112 # For each variable object, an array containing the above fields will
2113 # be created under the root node (conveniently called, "root").  For example,
2114 # a variable object with handle "OBJ.public.0_anonymous.a" will have
2115 # a corresponding global Tcl variable named "root.OBJ.public.0_anonymous.a".
2116 #
2117 # Note that right now, this mechanism cannot be used for recursive data
2118 # structures like linked lists.
2119
2120 namespace eval ::varobj_tree {
2121   # An index which is appended to root varobjs to ensure uniqueness.
2122   variable _root_idx 0
2123
2124   # A procedure to help with debuggging varobj trees.
2125   # VARIABLE_NAME is the name of the variable to dump.
2126   # CMD, if present, is the name of the callback to output the contstructed
2127   #   strings. By default, it uses expect's "send_log" command.
2128   # TERM, if present, is a terminating character. By default it is the newline.
2129   #
2130   # To output to the terminal (not the expect log), use
2131   # mi_varobj_tree_dump_variable my_variable puts ""
2132
2133   proc mi_varobj_tree_dump_variable {variable_name {cmd send_log} {term "\n"}} {
2134     upvar #0 $variable_name varobj
2135
2136     eval "$cmd \"VAR = $variable_name$term\""
2137
2138     # Explicitly encode the array indices, since outputting them
2139     # in some logical order is better than what "array names" might
2140     # return.
2141     foreach idx {obj_name parent display_name type path_expr} {
2142       eval "$cmd \"\t$idx = $varobj($idx)$term\""
2143     }
2144
2145     # Output children
2146     set num [llength $varobj(children)]
2147     eval "$cmd \"\tnum_children = $num$term\""
2148     if {$num > 0} {
2149       eval "$cmd \"\tchildren = $varobj(children)$term\""
2150     }
2151   }
2152
2153   # The default callback used by mi_walk_varobj_tree.  This callback
2154   # simply checks all of VAR's children.  It specifically does not test
2155   # path expressions, since that is very problematic.
2156   #
2157   # This procedure may be used in custom callbacks.
2158   proc test_children_callback {variable_name} {
2159     upvar #0 $variable_name varobj
2160
2161     if {[llength $varobj(children)] > 0} {
2162       # Construct the list of children the way mi_list_varobj_children
2163       # expects to get it:
2164       # { {obj_name display_name num_children type} ... }
2165       set children_list {}
2166       foreach child $varobj(children) {
2167         upvar #0 $child c
2168         set clist [list [string_to_regexp $c(obj_name)] \
2169                        [string_to_regexp $c(display_name)] \
2170                        [llength $c(children)]]
2171         if {[string length $c(type)] > 0} {
2172           lappend clist [string_to_regexp $c(type)]
2173         }
2174         lappend children_list $clist
2175       }
2176
2177       mi_list_varobj_children $varobj(obj_name) $children_list \
2178           "VT: list children of $varobj(obj_name)"
2179     }
2180   }
2181
2182   # Set the properties of the varobj represented by
2183   # PARENT_VARIABLE - the name of the parent's variable
2184   # OBJNAME         - the MI object name of this variable
2185   # DISP_NAME       - the display name of this variable
2186   # TYPE            - the type of this variable
2187   # PATH            - the path expression for this variable
2188   # CHILDREN        - a list of the variable's children
2189   proc create_varobj {parent_variable objname disp_name \
2190                           type path children} {
2191     upvar #0 $parent_variable parent
2192
2193     set var_name "root.$objname"
2194     global $var_name
2195     array set $var_name [list obj_name $objname]
2196     array set $var_name [list display_name $disp_name]
2197     array set $var_name [list type $type]
2198     array set $var_name [list path_expr $path]
2199     array set $var_name [list parent "$parent_variable"]
2200     array set $var_name [list children \
2201                              [get_tree_children $var_name $children]]
2202     return $var_name
2203   }
2204
2205   # Should VARIABLE be used in path expressions?  The CPLUS_FAKE_CHILD
2206   # varobjs and anonymous structs/unions are not used for path expressions.
2207   proc is_path_expr_parent {variable} {
2208     upvar #0 $variable varobj
2209
2210     # If the varobj's type is "", it is a CPLUS_FAKE_CHILD.
2211     # If the tail of the varobj's object name is "%d_anonymous",
2212     # then it represents an anonymous struct or union.
2213     if {[string length $varobj(type)] == 0 \
2214             || [regexp {[0-9]+_anonymous$} $varobj(obj_name)]} {
2215       return false
2216     }
2217
2218     return true
2219   }
2220
2221   # Return the path expression for the variable named NAME in
2222   # parent varobj whose variable name is given by PARENT_VARIABLE.
2223   proc get_path_expr {parent_variable name type} {
2224     upvar #0 $parent_variable parent
2225     upvar #0 $parent_variable path_parent
2226
2227     # If TYPE is "", this is one of the CPLUS_FAKE_CHILD varobjs,
2228     # which has no path expression.  Likewsise for anonymous structs
2229     # and unions.
2230     if {[string length $type] == 0 \
2231             || [string compare $type "anonymous"] == 0} {
2232       return ""
2233     }
2234
2235     # Find the path parent variable.
2236     while {![is_path_expr_parent $parent_variable]} {
2237       set parent_variable $path_parent(parent)
2238       upvar #0 $parent_variable path_parent
2239     }
2240
2241     # This is where things get difficult.  We do not actually know
2242     # the real type for variables defined via typedefs, so we don't actually
2243     # know whether the parent is a structure/union or not.
2244     #
2245     # So we assume everything that isn't a simple type is a compound type.
2246     set stars ""
2247     regexp {\*+} $parent(type) stars
2248     set is_compound 1
2249     if {[string index $name 0] == "*"} {
2250       set is_compound 0
2251     }
2252
2253     if {[string index $parent(type) end] == "\]"} {
2254       # Parent is an array.
2255       return "($path_parent(path_expr))\[$name\]"
2256     } elseif {$is_compound} {
2257       # Parent is a structure or union or a pointer to one.
2258       if {[string length $stars]} {
2259         set join "->"
2260       } else {
2261         set join "."
2262       }
2263
2264       global root
2265
2266       # To make matters even more hideous, varobj.c has slightly different
2267       # path expressions for C and C++.
2268       set path_expr "($path_parent(path_expr))$join$name"
2269       if {[string compare -nocase $root(language) "c"] == 0} {
2270         return $path_expr
2271       } else {
2272         return "($path_expr)"
2273       }
2274     } else {
2275       # Parent is a pointer.
2276       return "*($path_parent(path_expr))"
2277     }
2278   }
2279
2280   # Process the CHILDREN (a list of varobj_tree elements) of the variable
2281   # given by PARENT_VARIABLE.  Returns a list of children variables.
2282   proc get_tree_children {parent_variable children} {
2283     upvar #0 $parent_variable parent
2284
2285     set field_idx 0
2286     set children_list {}
2287     foreach {type name children} $children {
2288       if {[string compare $parent_variable "root"] == 0} {
2289         # Root variable
2290         variable _root_idx
2291         incr _root_idx
2292         set objname "$name$_root_idx"
2293         set disp_name "$name"
2294         set path_expr "$name"
2295       } elseif {[string compare $type "anonymous"] == 0} {
2296         # Special case: anonymous types.  In this case, NAME will either be
2297         # "struct" or "union".
2298         set objname "$parent(obj_name).${field_idx}_anonymous"
2299         set disp_name "<anonymous $name>"
2300         set path_expr ""
2301         set type "$name {...}"
2302       } else {
2303         set objname "$parent(obj_name).$name"
2304         set disp_name $name
2305         set path_expr [get_path_expr $parent_variable $name $type]
2306       }
2307
2308       lappend children_list [create_varobj $parent_variable $objname \
2309                                  $disp_name $type $path_expr $children]
2310       incr field_idx
2311     }
2312
2313     return $children_list
2314   }
2315
2316   # The main procedure to call the given CALLBACK on the elements of the
2317   # given varobj TREE.  See detailed explanation above.
2318   proc walk_tree {language tree callback} {
2319     global root
2320     variable _root_idx
2321
2322     if {[llength $tree] < 3} {
2323       error "tree does not contain enough elements"
2324     }
2325
2326     set _root_idx 0
2327
2328     # Create root node and process the tree.
2329     array set root [list language $language]
2330     array set root [list obj_name "root"]
2331     array set root [list display_name "root"]
2332     array set root [list type "root"]
2333     array set root [list path_expr "root"]
2334     array set root [list parent "root"]
2335     array set root [list children [get_tree_children root $tree]]
2336
2337     # Walk the tree
2338     set all_nodes $root(children); # a stack of nodes
2339     while {[llength $all_nodes] > 0} {
2340       # "Pop" the name of the global variable containing this varobj's
2341       # information from the stack of nodes.
2342       set var_name [lindex $all_nodes 0]
2343       set all_nodes [lreplace $all_nodes 0 0]
2344
2345       # Bring the global named in VAR_NAME into scope as the local variable
2346       # VAROBJ.
2347       upvar #0 $var_name varobj
2348
2349       # Append any children of VAROBJ to the list of nodes to walk.
2350       if {[llength $varobj(children)] > 0} {
2351         set all_nodes [concat $all_nodes $varobj(children)]
2352       }
2353
2354       # If this is a root variable, create the variable object for it.
2355       if {[string compare $varobj(parent) "root"] == 0} {
2356         mi_create_varobj $varobj(obj_name) $varobj(display_name) \
2357             "VT: create root varobj for $varobj(display_name)"
2358       }
2359
2360       # Now call the callback for VAROBJ.
2361       uplevel #0 $callback $var_name
2362     }
2363   }
2364 }
2365
2366 # The default varobj tree callback, which simply tests -var-list-children.
2367 proc mi_varobj_tree_test_children_callback {variable} {
2368   ::varobj_tree::test_children_callback $variable
2369 }
2370
2371 # Walk the variable object tree given by TREE, calling the specified
2372 # CALLBACK.  By default this uses mi_varobj_tree_test_children_callback.
2373 proc mi_walk_varobj_tree {language tree \
2374                               {callback \
2375                                    mi_varobj_tree_test_children_callback}} {
2376   ::varobj_tree::walk_tree $language $tree $callback
2377 }
2378
2379 # Build a list of key-value pairs given by the list ATTR_LIST.  Flatten
2380 # this list using the optional JOINER, a comma by default.
2381 #
2382 # The list must contain an even number of elements, which are the key-value
2383 # pairs.  Each value will be surrounded by quotes, according to the grammar,
2384 # except if the value starts with \[ or \{, when the quotes will be omitted.
2385 #
2386 # Example: mi_build_kv_pairs {a b c d e f g \[.*\]}
2387 # returns a=\"b\",c=\"d\",e=\"f\",g=\[.*\]
2388 proc mi_build_kv_pairs {attr_list {joiner ,}} {
2389     set l {}
2390     foreach {var value} $attr_list {
2391         if {[string range $value 0 1] == "\\\["
2392             || [string range $value 0 1] == "\\\{"} {
2393             lappend l "$var=$value"
2394         } else {
2395             lappend l "$var=\"$value\""
2396         }
2397     }
2398     return "[join $l $joiner]"
2399 }
2400
2401 # Construct a breakpoint regexp.  This may be used to test the output of
2402 # -break-insert, -dprintf-insert, or -break-info.
2403 #
2404 # All arguments for the breakpoint may be specified using the options
2405 # number, type, disp, enabled, addr, func, file, fullanme, line,
2406 # thread-groups, times, ignore, script, and original-location.
2407 #
2408 # Only if -script and -ignore are given will they appear in the output.
2409 # Otherwise, this procedure will skip them using ".*".
2410 #
2411 # Example: mi_make_breakpoint -number 2 -file ".*/myfile.c" -line 3
2412 # will return the breakpoint:
2413 # bkpt={number="2",type=".*",disp=".*",enabled=".*",addr=".*",func=".*",
2414 #       file=".*/myfile.c",fullname=".*",line="3",thread-groups=\[.*\],
2415 #       times="0".*original-location=".*"}
2416
2417 proc mi_make_breakpoint {args} {
2418     parse_args {{number .*} {type .*} {disp .*} {enabled .*} {addr .*}
2419         {func .*} {file .*} {fullname .*} {line .*}
2420         {thread-groups \\\[.*\\\]} {times .*} {ignore 0}
2421         {script ""} {original-location .*}}
2422
2423     set attr_list {}
2424     foreach attr [list number type disp enabled addr func file \
2425                       fullname line thread-groups times] {
2426         lappend attr_list $attr [set $attr]
2427     }
2428
2429     set result "bkpt={[mi_build_kv_pairs $attr_list]"
2430
2431     # There are always exceptions.
2432     # If SCRIPT and IGNORE are not present, do not output them.
2433     if {$ignore != 0} {
2434         append result ","
2435         append result [mi_build_kv_pairs [list "ignore" $ignore]]
2436         append result ","
2437     }
2438     if {[string length $script] > 0} {
2439         append result ","
2440         append result [mi_build_kv_pairs [list "script" $script]]
2441         append result ","
2442     } else {
2443         # Allow anything up until the next "official"/required attribute.
2444         # This pattern skips over script/ignore if matches on those
2445         # were not specifically required by the caller.
2446         append result ".*"
2447     }
2448     append result [mi_build_kv_pairs \
2449                        [list "original-location" ${original-location}]]
2450     append result "}"
2451     return $result
2452 }
2453
2454 # Build a breakpoint table regexp given the list of breakpoints in `bp_list',
2455 # constructed by mi_make_breakpoint.
2456 #
2457 # Example:  Construct a breakpoint table where the only attributes we
2458 # test for are the existence of three breakpoints numbered 1, 2, and 3.
2459 #
2460 # set bps {}
2461 # lappend bps [mi_make_breakpoint -number 1]
2462 # lappend bps [mi_make_breakpoint -number 2]
2463 # lappned bps [mi_make_breakpoint -number 3]
2464 # mi_make_breakpoint_table $bps
2465 # will return (abbreviated for clarity):
2466 # BreakpointTable={nr_rows="3",nr_cols="6",hdr=[{width=".*",...} ...],
2467 #   body=[bkpt={number="1",...},bkpt={number="2",...},bkpt={number="3",...}]}
2468
2469 proc mi_make_breakpoint_table {bp_list} {
2470     # Build header -- assume a standard header for all breakpoint tables.
2471     set hl {}
2472     foreach {nm hdr} [list number Num type Type disp Disp enabled Enb \
2473                           addr Address what What] {
2474         # The elements here are the MI table headers, which have the
2475         # format:
2476         # {width="7",alignment="-1",col_name="number",colhdr="Num"}
2477         lappend hl "{[mi_build_kv_pairs [list width .* alignment .* \
2478                                        col_name $nm colhdr $hdr]]}"
2479     }
2480     set header "hdr=\\\[[join $hl ,]\\\]"
2481
2482     # The caller has implicitly supplied the number of columns and rows.
2483     set nc [llength $hl]
2484     set nr [llength $bp_list]
2485
2486     # Build body -- mi_make_breakpoint has done most of the work.
2487     set body "body=\\\[[join $bp_list ,]\\\]"
2488
2489     # Assemble the final regexp.
2490     return "BreakpointTable={nr_rows=\"$nr\",nr_cols=\"$nc\",$header,$body}"
2491 }