ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 # PR gas/19109
 146 # Decide the default method for compressing debug sections.
 147 ac_default_compressed_debug_sections=unset
 148 # Provide a configure time option to override our default.
 149 AC_ARG_ENABLE(compressed_debug_sections,
 150               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 151               [compress debug sections by default])],
 152 [case ,"${enableval}", in
 153   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 154   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 155 esac])dnl
 156
 157 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 158 ac_default_new_dtags=unset
 159 # Provide a configure time option to override our default.
 160 AC_ARG_ENABLE(new_dtags,
 161               AS_HELP_STRING([--enable-new-dtags],
 162               [set DT_RUNPATH instead of DT_RPATH by default])],
 163 [case "${enableval}" in
 164   yes) ac_default_new_dtags=1 ;;
 165   no) ac_default_new_dtags=0 ;;
 166 esac])dnl
 167
 168 # Decide if -z relro should be enabled in ELF linker by default.
 169 ac_default_ld_z_relro=unset
 170 # Provide a configure time option to override our default.
 171 AC_ARG_ENABLE(relro,
 172               AS_HELP_STRING([--enable-relro],
 173               [enable -z relro in ELF linker by default]),
 174 [case "${enableval}" in
 175   yes)  ac_default_ld_z_relro=1 ;;
 176   no)  ac_default_ld_z_relro=0 ;;
 177 esac])dnl
 178
 179 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 180 ac_default_ld_textrel_check=unset
 181 AC_ARG_ENABLE([textrel-check],
 182               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 183                              [enable DT_TEXTREL check in ELF linker]),
 184 [case "${enableval}" in
 185   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 186 esac])
 187
 188 # Decide if -z separate-code should be enabled in ELF linker by default.
 189 ac_default_ld_z_separate_code=unset
 190 AC_ARG_ENABLE(separate-code,
 191               AS_HELP_STRING([--enable-separate-code],
 192               [enable -z separate-code in ELF linker by default]),
 193 [case "${enableval}" in
 194   yes) ac_default_ld_z_separate_code=1 ;;
 195   no) ac_default_ld_z_separate_code=0 ;;
 196 esac])
 197
 198 # Decide which "--hash-style" to use by default
 199 # Provide a configure time option to override our default.
 200 AC_ARG_ENABLE([default-hash-style],
 201 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 202                [use this default hash style]),
 203 [case "${enable_default_hash_style}" in
 204   sysv | gnu | both) ;;
 205   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 206 esac],
 207 [case "${target}" in
 208   # Enable gnu hash only on GNU targets, but not mips
 209   mips*-*-*) enable_default_hash_style=sysv ;;
 210   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 211   *) enable_default_hash_style=sysv ;;
 212 esac])
 213
 214 case "${enable_default_hash_style}" in
 215   sysv | both) ac_default_emit_sysv_hash=1 ;;
 216   *) ac_default_emit_sysv_hash=0 ;;
 217 esac
 218
 219 case "${enable_default_hash_style}" in
 220   gnu | both) ac_default_emit_gnu_hash=1 ;;
 221   *) ac_default_emit_gnu_hash=0 ;;
 222 esac
 223
 224 AM_BINUTILS_WARNINGS
 225
 226 AM_LC_MESSAGES
 227
 228 AC_CONFIG_HEADERS([config.h:config.in])
 229
 230 # PR 14072
 231 AH_VERBATIM([00_CONFIG_H_CHECK],
 232 [/* Check that config.h is #included before system headers
 233    (this works only for glibc, but that should be enough).  */
 234 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 235 #  error config.h must be #included before system headers
 236 #endif
 237 #define __CONFIG_H__ 1])
 238
 239 if test -z "$target" ; then
 240     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 241 fi
 242 if test -z "$host" ; then
 243     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 244 fi
 245
 246 # host-specific stuff:
 247
 248 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 249 ZW_GNU_GETTEXT_SISTER_DIR
 250 AM_PO_SUBDIRS
 251
 252 AC_EXEEXT
 253
 254 AC_PROG_YACC
 255 AM_PROG_LEX
 256
 257 AM_MAINTAINER_MODE
 258 AM_CONDITIONAL(GENINSRC_NEVER, false)
 259 ACX_PROG_CMP_IGNORE_INITIAL
 260
 261 . ${srcdir}/configure.host
 262
 263 AC_SUBST(HDEFINES)
 264 AC_SUBST(NATIVE_LIB_DIRS)
 265
 266 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 267 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 268 ACX_HEADER_STRING
 269 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 270 AC_CHECK_FUNCS(open lseek close)
 271 AC_HEADER_DIRENT
 272
 273 dnl AC_CHECK_HEADERS(sys/mman.h)
 274 AC_FUNC_MMAP
 275
 276 AC_SEARCH_LIBS([dlopen], [dl])
 277
 278 AC_ARG_ENABLE(initfini-array,
 279 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 280 [case "${enableval}" in
 281  yes|no) ;;
 282  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 283  esac], [enable_initfini_array=yes])
 284 AC_SUBST(enable_initfini_array)
 285 if test $enable_initfini_array = yes; then
 286   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 287     [Define .init_array/.fini_array sections are available and working.])
 288 fi
 289
 290 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 291 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 292 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 293 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 294 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 295 if test $ld_cv_decl_getopt_unistd_h = yes; then
 296   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 297             [Is the prototype for getopt in <unistd.h> in the expected format?])
 298 fi
 299
 300 BFD_BINARY_FOPEN
 301
 302 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 303
 304 # Link in zlib if we can.  This allows us to read and write
 305 # compressed CTF sections.
 306 AM_ZLIB
 307
 308 # When converting linker scripts into strings for use in emulation
 309 # files, use astring.sed if the compiler supports ANSI string
 310 # concatenation, or ostring.sed otherwise.  This is to support the
 311 # broken Microsoft MSVC compiler, which limits the length of string
 312 # constants, while still supporting pre-ANSI compilers which do not
 313 # support string concatenation.
 314 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 315 AC_CACHE_VAL(ld_cv_string_concatenation,
 316 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 317   ld_cv_string_concatenation=yes,
 318   ld_cv_string_concatenation=no)])
 319 AC_MSG_RESULT($ld_cv_string_concatenation)
 320 if test "$ld_cv_string_concatenation" = "yes"; then
 321   STRINGIFY=astring.sed
 322 else
 323   STRINGIFY=ostring.sed
 324 fi
 325 AC_SUBST(STRINGIFY)
 326
 327 # target-specific stuff:
 328
 329 all_targets=
 330 EMUL=
 331 all_emuls=
 332 all_emul_extras=
 333 all_libpath=
 334 TDIRS=
 335
 336 # If the host is 64-bit, then we enable 64-bit targets by default.
 337 # This is consistent with what ../bfd/configure.ac does.
 338 if test x${want64} = xfalse; then
 339   AC_CHECK_SIZEOF(void *)
 340   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 341     want64=true
 342   fi
 343 fi
 344
 345 elf_list_options=FALSE
 346 elf_shlib_list_options=FALSE
 347 elf_plt_unwind_list_options=FALSE
 348 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 349 do
 350   if test "$targ_alias" = "all"; then
 351     all_targets=true
 352     elf_list_options=TRUE
 353     elf_shlib_list_options=TRUE
 354     elf_plt_unwind_list_options=TRUE
 355   else
 356     # Canonicalize the secondary target names.
 357     result=`$ac_config_sub $targ_alias 2>/dev/null`
 358     if test -n "$result"; then
 359         targ=$result
 360     else
 361         targ=$targ_alias
 362     fi
 363
 364     . ${srcdir}/configure.tgt
 365
 366     if test "$targ" = "$target"; then
 367       EMUL=$targ_emul
 368     fi
 369
 370     if test x${want64} = xfalse; then
 371       . ${srcdir}/../bfd/config.bfd
 372     fi
 373
 374     if test x${want64} = xtrue; then
 375       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 376       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 377     fi
 378
 379     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 380         case " $all_emuls " in
 381         *" e${i}.o "*) ;;
 382         *)
 383           all_emuls="$all_emuls e${i}.o"
 384           eval result=\$tdir_$i
 385           test -z "$result" && result=$targ_alias
 386           TDIRS="$TDIRS
 387 tdir_$i=$result"
 388           case "${i}" in
 389           *elf*)
 390             elf_list_options=TRUE
 391             ;;
 392           *)
 393             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 394               elf_list_options=TRUE
 395             fi
 396             ;;
 397           esac
 398           if test "$elf_list_options" = "TRUE"; then
 399             source_sh()
 400             {
 401               . $1
 402             }
 403             source_sh ${srcdir}/emulparams/${i}.sh
 404             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 405               elf_shlib_list_options=TRUE
 406             fi
 407             if test x${PLT_UNWIND} = xyes; then
 408               elf_plt_unwind_list_options=TRUE
 409             fi
 410           fi
 411           ;;
 412         esac
 413     done
 414
 415     for i in $targ_emul $targ_extra_libpath; do
 416         case " $all_libpath " in
 417         *" ${i} "*) ;;
 418         *)
 419           if test -z "$all_libpath"; then
 420             all_libpath=${i}
 421           else
 422             all_libpath="$all_libpath ${i}"
 423           fi
 424           ;;
 425         esac
 426     done
 427
 428     for i in $targ_extra_ofiles; do
 429         case " $all_emul_extras " in
 430         *" ${i} "*) ;;
 431         *)
 432           all_emul_extras="$all_emul_extras ${i}"
 433           ;;
 434         esac
 435     done
 436
 437   fi
 438 done
 439
 440 if test x$ac_default_compressed_debug_sections = xyes ; then
 441   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 442 fi
 443
 444 if test "${ac_default_new_dtags}" = unset; then
 445   ac_default_new_dtags=0
 446 fi
 447 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 448   $ac_default_new_dtags,
 449   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 450
 451 if test "${ac_default_ld_z_relro}" = unset; then
 452   ac_default_ld_z_relro=0
 453 fi
 454 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 455   $ac_default_ld_z_relro,
 456   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 457
 458 ac_default_ld_textrel_check_warning=0
 459 case "${ac_default_ld_textrel_check}" in
 460   unset|no)
 461     ac_default_ld_textrel_check=textrel_check_none
 462     ;;
 463   yes|warning)
 464     ac_default_ld_textrel_check=textrel_check_warning
 465     ac_default_ld_textrel_check_warning=1
 466     ;;
 467   error)
 468     ac_default_ld_textrel_check=textrel_check_error
 469     ;;
 470 esac
 471 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 472   $ac_default_ld_textrel_check,
 473   [The default method for DT_TEXTREL check in ELF linker.])
 474 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 475   $ac_default_ld_textrel_check_warning,
 476   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 477
 478 if test "${ac_default_ld_z_separate_code}" = unset; then
 479   ac_default_ld_z_separate_code=0
 480 fi
 481 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 482   $ac_default_ld_z_separate_code,
 483   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 484
 485 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 486   [$ac_default_emit_sysv_hash],
 487   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 488
 489 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 490   [$ac_default_emit_gnu_hash],
 491   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 492
 493 AC_SUBST(elf_list_options)
 494 AC_SUBST(elf_shlib_list_options)
 495 AC_SUBST(elf_plt_unwind_list_options)
 496 AC_SUBST(EMUL)
 497
 498 AC_SUBST(TDIRS)
 499 AM_SUBST_NOTMAKE(TDIRS)
 500
 501 if test x${all_targets} = xtrue; then
 502   if test x${want64} = xtrue; then
 503     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 504     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 505   else
 506     EMULATION_OFILES='$(ALL_EMULATIONS)'
 507     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 508   fi
 509 else
 510   EMULATION_OFILES=$all_emuls
 511   EMUL_EXTRA_OFILES=$all_emul_extras
 512 fi
 513 AC_SUBST(EMULATION_OFILES)
 514 AC_SUBST(EMUL_EXTRA_OFILES)
 515 AC_SUBST(LIB_PATH)
 516
 517 EMULATION_LIBPATH=$all_libpath
 518 AC_SUBST(EMULATION_LIBPATH)
 519
 520 if test x${enable_static} = xno; then
 521   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 522   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 523 else
 524   TESTBFDLIB="../bfd/.libs/libbfd.a"
 525   TESTCTFLIB="../libctf/.libs/libctf.a"
 526 fi
 527 AC_SUBST(TESTBFDLIB)
 528 AC_SUBST(TESTCTFLIB)
 529
 530 target_vendor=${target_vendor=$host_vendor}
 531 case "$target_vendor" in
 532   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 533   *)  EXTRA_SHLIB_EXTENSION= ;;
 534 esac
 535
 536 case "$target_os" in
 537   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 538 esac
 539
 540 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 541   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 542    [Additional extension a shared object might have.])
 543 fi
 544
 545 AC_CONFIG_COMMANDS([default],
 546 [[
 547 case "$srcdir" in
 548   .) srcdirpre= ;;
 549   *) srcdirpre='$(srcdir)/' ;;
 550 esac
 551 POFILES=
 552 GMOFILES=
 553 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 554   if test $lang != dummy; then
 555     POFILES="$POFILES $srcdirpre$lang.po"
 556     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 557   fi
 558 done
 559 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 560     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 561     -e "s,@POFILES@,$POFILES," \
 562     -e "s,@GMOFILES@,$GMOFILES," \
 563     po/Makefile.in > po/Makefile]],[[]])
 564
 565 dnl Required by html, pdf, install-pdf and install-html
 566 AC_SUBST(datarootdir)
 567 AC_SUBST(docdir)
 568 AC_SUBST(htmldir)
 569 AC_SUBST(pdfdir)
 570
 571 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 572 AC_OUTPUT